C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Carp qw( croak );
  22
  23 use C4::Context;
  24 use C4::Members::Messaging;
  25 use C4::Auth qw( checkpw_internal );
  26 use Koha::Patrons;
  27 use Koha::AuthUtils qw( hash_password );
  28 use Net::LDAP;
  29 use Net::LDAP::Filter;
  30
  31 our (@ISA, @EXPORT_OK);
  32 BEGIN {
  33         require Exporter;
  34         @ISA    = qw(Exporter);
  35         @EXPORT_OK = qw( checkpw_ldap );
  36 }
  37
  38 # Redefine checkpw_ldap:
  39 # connect to LDAP (named or anonymous)
  40 # ~ retrieves $userid from KOHA_CONF mapping
  41 # ~ then compares $password with userPassword
  42 # ~ then gets the LDAP entry
  43 # ~ and calls the memberadd if necessary
  44
  45 sub ldapserver_error {
  46         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  47 }
  48
  49 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  50 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  51 # since Bug 28278 we need to skip id in <ldapserver id="ldapserver"> which generates additional hash level
  52 if ( exists $ldap->{ldapserver} ) {
  53     $ldap = $ldap->{ldapserver}         or die ldapserver_error('id="ldapserver"');
  54 }
  55 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  56 my $base      = $ldap->{base}           or die ldapserver_error('base');
  57 $ldapname     = $ldap->{user}           ;
  58 $ldappassword = $ldap->{pass}           ;
  59 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  60 my @mapkeys = keys %mapping;
  61 #warn "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  62 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  63 #warn "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  64
  65 my %categorycode_conversions;
  66 my $default_categorycode;
  67 if(defined $ldap->{categorycode_mapping}) {
  68     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  69     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  70         $categorycode_conversions{$cat->{value}} = $cat->{content};
  71     }
  72 }
  73
  74 my %config = (
  75     anonymous => defined ($ldap->{anonymous_bind}) ? $ldap->{anonymous_bind} : 1,
  76     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  77        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  78 );
  79
  80 sub description {
  81         my $result = shift or return;
  82         return "LDAP error #" . $result->code
  83                         . ": " . $result->error_name . "\n"
  84                         . "# " . $result->error_text . "\n";
  85 }
  86
  87 sub search_method {
  88     my $db     = shift or return;
  89     my $userid = shift or return;
  90         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  91         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  92         my $search = $db->search(
  93                   base => $base,
  94                 filter => $filter,
  95                 # attrs => ['*'],
  96     );
  97     die "LDAP search failed to return object : " . $search->error if $search->code;
  98
  99         my $count = $search->count;
 100         if ($search->code > 0) {
 101                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 102                 return 0;
 103         }
 104     if ($count == 0) {
 105         warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
 106         return 0;
 107     }
 108     return $search;
 109 }
 110
 111 sub checkpw_ldap {
 112     my ($userid, $password) = @_;
 113     my @hosts = split(',', $prefhost);
 114     my $db = Net::LDAP->new(\@hosts);
 115     unless ( $db ) {
 116         warn "LDAP connexion failed";
 117         return 0;
 118     }
 119
 120     my $userldapentry;
 121
 122     # first, LDAP authentication
 123     if ( $ldap->{auth_by_bind} ) {
 124         my $principal_name;
 125         if ( $config{anonymous} ) {
 126
 127             # Perform an anonymous bind
 128             my $res = $db->bind;
 129             if ( $res->code ) {
 130                 warn "Anonymous LDAP bind failed: " . description($res);
 131                 return 0;
 132             }
 133
 134             # Perform a LDAP search for the given username
 135             my $search = search_method( $db, $userid )
 136               or return 0;    # warnings are in the sub
 137             $userldapentry = $search->shift_entry;
 138             $principal_name = $userldapentry->dn;
 139         }
 140         else {
 141             $principal_name = $ldap->{principal_name};
 142             if ( $principal_name and $principal_name =~ /\%/ ) {
 143                 $principal_name = sprintf( $principal_name, $userid );
 144             }
 145             else {
 146                 $principal_name = $userid;
 147             }
 148         }
 149
 150         # Perform a LDAP bind for the given username using the matched DN
 151         my $res = $db->bind( $principal_name, password => $password );
 152         if ( $res->code ) {
 153             if ( $config{anonymous} ) {
 154                 # With anonymous_bind approach we can be sure we have found the correct user
 155                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 156                 # or password changed). We should not fall back to local accounts in this case.
 157                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 158                 return -1;
 159             } else {
 160                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 161                 # at all, and thus we should fall back to local logins to restore previous behaviour
 162                 # see bug 12831
 163                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 164                 return 0;
 165             }
 166         }
 167         if ( !defined($userldapentry)
 168             && ( $config{update} or $config{replicate} ) )
 169         {
 170             my $search = search_method( $db, $userid ) or return 0;
 171             $userldapentry = $search->shift_entry;
 172         }
 173     } else {
 174         my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 175                 if ($res->code) {               # connection refused
 176                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 177                         return 0;
 178                 }
 179         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 180         # Handle multiple branches. Same login exists several times in different branches.
 181         my $bind_ok = 0;
 182         while (my $entry = $search->shift_entry) {
 183             my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
 184             unless ($user_ldap_bind_ret->code) {
 185                 $userldapentry = $entry;
 186                 $bind_ok = 1;
 187                 last;
 188             }
 189         }
 190
 191         unless ($bind_ok) {
 192             warn "LDAP Auth rejected : invalid password for user '$userid'.";
 193             return -1;
 194         }
 195
 196
 197     }
 198
 199     # To get here, LDAP has accepted our user's login attempt.
 200     # But we still have work to do.  See perldoc below for detailed breakdown.
 201
 202     my (%borrower);
 203         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 204
 205     my $patron;
 206     if (( $borrowernumber and $config{update}   ) or
 207         (!$borrowernumber and $config{replicate})   ) {
 208         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 209         #warn "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 210     }
 211
 212     if ($borrowernumber) {
 213         if ($config{update}) { # A1, B1
 214             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 215             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 216         } else { # C1, D1
 217             # maybe update just the password?
 218                 return(1, $cardnumber, $local_userid);
 219         }
 220     } elsif ($config{replicate}) { # A2, C2
 221         my @columns = Koha::Patrons->columns;
 222         $patron = Koha::Patron->new(
 223             {
 224                 map { exists( $borrower{$_} ) ? ( $_ => $borrower{$_} ) : () } @columns
 225             }
 226         )->store;
 227         die "Insert of new patron failed" unless $patron;
 228         $borrowernumber = $patron->borrowernumber;
 229         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 230    } else {
 231         return 0;   # B2, D2
 232     }
 233     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 234         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 235         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 236         while ( my $attribute_type = $attribute_types->next ) {
 237             my $code = $attribute_type->code;
 238             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 239                 next;
 240             }
 241             $patron = Koha::Patrons->find($borrowernumber);
 242             if ( $patron ) { # Should not be needed, but we are in C4::Auth LDAP...
 243                 eval {
 244                     my $attribute = Koha::Patron::Attribute->new({code => $code, attribute => $borrower{$code}});
 245                     $patron->extended_attributes([$attribute->unblessed]);
 246                 };
 247                 if ($@) { # FIXME Test if Koha::Exceptions::Patron::Attribute::NonRepeatable
 248                     warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 249                 }
 250             }
 251         }
 252     }
 253     return(1, $cardnumber, $userid, $patron);
 254 }
 255
 256 # Pass LDAP entry object and local cardnumber (userid).
 257 # Returns borrower hash.
 258 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 259 # Ensure that mandatory fields are correctly filled!
 260 #
 261 sub ldap_entry_2_hash {
 262         my $userldapentry = shift;
 263         my %borrower = ( cardnumber => shift );
 264         my %memberhash;
 265         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 266     #foreach (keys %$userldapentry) {
 267     #    print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 268     #}
 269         my $x = $userldapentry->{attrs} or return;
 270         foreach (keys %$x) {
 271                 $memberhash{$_} = join ' ', @{$x->{$_}};
 272         #warn sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 273         }
 274     #warn "Finished \%memberhash has ", scalar(keys %memberhash), " keys\n", "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 275         foreach my $key (keys %mapping) {
 276                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 277         #warn "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 278                 unless (defined $data) {
 279             $data = $mapping{$key}->{content} || undef;
 280                 }
 281         $borrower{$key} = $data;
 282         }
 283         $borrower{initials} = $memberhash{initials} ||
 284                 ( substr($borrower{'firstname'},0,1)
 285                 . substr($borrower{ 'surname' },0,1)
 286                 . " ");
 287
 288     # categorycode conversions
 289     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 290         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 291     }
 292     elsif($default_categorycode) {
 293         $borrower{categorycode} = $default_categorycode;
 294     }
 295
 296         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 297         my $dbh = C4::Context->dbh;
 298         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 299         $sth->execute( uc($borrower{'categorycode'}) );
 300         unless ( my $row = $sth->fetchrow_hashref ) {
 301                 my $default = $mapping{'categorycode'}->{content};
 302         #warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 303                 $borrower{'categorycode'} = $default
 304         }
 305
 306         return %borrower;
 307 }
 308
 309 sub exists_local {
 310         my $arg = shift;
 311         my $dbh = C4::Context->dbh;
 312         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 313
 314         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 315         $sth->execute($arg);
 316     #warn "Userid '$arg' exists_local? %s\n", $sth->rows;
 317         ($sth->rows == 1) and return $sth->fetchrow;
 318
 319         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 320         $sth->execute($arg);
 321     #warn "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 322         ($sth->rows == 1) and return $sth->fetchrow;
 323         return 0;
 324 }
 325
 326 # This function performs a password update, given the userid, borrowerid,
 327 # and digested password. It will verify that things are correct and return the
 328 # borrowers cardnumber. The idea is that it is used to keep the local
 329 # passwords in sync with the LDAP passwords.
 330 #
 331 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 332 #
 333 # Note: if the LDAP config has the update_password tag set to a false value,
 334 # then this will not update the password, it will simply return the cardnumber.
 335 sub _do_changepassword {
 336     my ($userid, $borrowerid, $password) = @_;
 337
 338     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 339
 340         # We don't store the password in the database
 341         my $sth = C4::Context->dbh->prepare(
 342             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 343         $sth->execute($borrowerid);
 344         die "Unable to access borrowernumber "
 345             . "with userid=$userid, "
 346             . "borrowernumber=$borrowerid"
 347           if !$sth->rows;
 348         my ($cardnum) = $sth->fetchrow;
 349         $sth = C4::Context->dbh->prepare(
 350             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 351         $sth->execute($borrowerid);
 352         return $cardnum;
 353     }
 354
 355     my $digest = hash_password($password);
 356     #warn "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 357     Koha::Patrons->find($borrowerid)->set_password({ password => $password, skip_validation => 1 });
 358
 359     my ($ok, $cardnum) = checkpw_internal($userid, $password);
 360     return $cardnum if $ok;
 361
 362     warn "Password mismatch after update to borrowernumber=$borrowerid";
 363     return;
 364 }
 365
 366 sub update_local {
 367     my $userid     = shift or croak "No userid";
 368     my $password   = shift or croak "No password";
 369     my $borrowerid = shift or croak "No borrowerid";
 370     my $borrower   = shift or croak "No borrower record";
 371
 372     # skip extended patron attributes in 'borrowers' attribute update
 373     my @keys = keys %$borrower;
 374     if (C4::Context->preference('ExtendedPatronAttributes')) {
 375         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 376         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 377         while ( my $attribute_type = $attribute_types->next ) {
 378            my $code = $attribute_type->code;
 379            @keys = grep { $_ ne $code } @keys;
 380            #warn "ignoring extended patron attribute '%s' in update_local()\n", $code;
 381         }
 382     }
 383
 384     my $dbh = C4::Context->dbh;
 385     my $query = "UPDATE  borrowers\nSET     " .
 386         join(',', map {"$_=?"} @keys) .
 387         "\nWHERE   borrowernumber=? ";
 388     my $sth = $dbh->prepare($query);
 389     #warn $query, "\n", join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 390     #warn "\nuserid = $userid\n";
 391     $sth->execute(
 392         ((map {$borrower->{$_}} @keys), $borrowerid)
 393     );
 394
 395     # MODIFY PASSWORD/LOGIN if password was mapped
 396     _do_changepassword($userid, $borrowerid, $password) if exists( $borrower->{'password'} );
 397 }
 398
 399 1;
 400 __END__
 401
 402 =head1 NAME
 403
 404 C4::Auth - Authenticates Koha users
 405
 406 =head1 SYNOPSIS
 407
 408   use C4::Auth_with_ldap;
 409
 410 =head1 LDAP Configuration
 411
 412     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 413         working LDAP servers.
 414         To use it :
 415            * Modify ldapserver element in KOHA_CONF
 416            * Establish field mapping in <mapping> element.
 417
 418         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 419         the username would match the "uid" field, and the password should match the "userpassword" field.
 420
 421         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 422         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 423
 424         mysql> show COLUMNS from borrowers;
 425                 +---------------------+--------------+------+-----+---------+----------------+
 426                 | Field               | Type         | Null | Key | Default | Extra          |
 427                 +---------------------+--------------+------+-----+---------+----------------+
 428                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 429                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 430                 | surname             | mediumtext   | NO   |     | NULL    |                |
 431                 | firstname           | text         | YES  |     | NULL    |                |
 432                 | title               | mediumtext   | YES  |     | NULL    |                |
 433                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 434                 | initials            | text         | YES  |     | NULL    |                |
 435                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 436                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 437                 | address             | mediumtext   | NO   |     | NULL    |                |
 438                 | address2            | text         | YES  |     | NULL    |                |
 439                 | city                | mediumtext   | NO   |     | NULL    |                |
 440                 | state               | mediumtext   | YES  |     | NULL    |                |
 441                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 442                 | country             | text         | YES  |     | NULL    |                |
 443                 | email               | mediumtext   | YES  |     | NULL    |                |
 444                 | phone               | text         | YES  |     | NULL    |                |
 445                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 446                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 447                 | emailpro            | text         | YES  |     | NULL    |                |
 448                 | phonepro            | text         | YES  |     | NULL    |                |
 449                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 450                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 451                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 452                 | B_address2          | text         | YES  |     | NULL    |                |
 453                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 454                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 455                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 456                 | B_country           | text         | YES  |     | NULL    |                |
 457                 | B_email             | text         | YES  |     | NULL    |                |
 458                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 459                 | dateofbirth         | date         | YES  |     | NULL    |                |
 460                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 461                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 462                 | dateenrolled        | date         | YES  |     | NULL    |                |
 463                 | dateexpiry          | date         | YES  |     | NULL    |                |
 464                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 465                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 466                 | debarred            | date         | YES  |     | NULL    |                |
 467                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 468                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 469                 | contactfirstname    | text         | YES  |     | NULL    |                |
 470                 | contacttitle        | text         | YES  |     | NULL    |                |
 471                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 472                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 473                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 474                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 475                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 476                 | password            | varchar(30)  | YES  |     | NULL    |                |
 477                 | flags               | int(11)      | YES  |     | NULL    |                |
 478                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 479                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 480                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 481                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 482                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 483                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 484                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 485                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 486                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 487                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 488                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 489                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 490                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 491                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 492                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 493                 | privacy             | int(11)      | NO   |     | 1       |                |
 494                 +---------------------+--------------+------+-----+---------+----------------+
 495                 66 rows in set (0.00 sec)
 496                 Where Null="NO", the field is required.
 497
 498 =head1 KOHA_CONF and field mapping
 499
 500 Example XML stanza for LDAP configuration in KOHA_CONF.
 501
 502  <config>
 503   ...
 504   <useldapserver>1</useldapserver>
 505   <!-- LDAP SERVER (optional) -->
 506   <ldapserver id="ldapserver">
 507     <hostname>localhost</hostname>
 508     <base>dc=metavore,dc=com</base>
 509     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 510     <pass>metavore</pass>          <!-- password, if not anonymous -->
 511     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 512     <update>1</update>             <!-- update existing users in Koha database -->
 513     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 514                                         password comparison, e.g., to use Active Directory -->
 515     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 516                                             an anonymous bind, even when auth_by_bind is on -->
 517     <principal_name>%s@my_domain.com</principal_name>
 518                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 519                                         Not used with anonymous_bind. -->
 520     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 521                                               synced to the local database -->
 522     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 523       <firstname    is="givenname"      ></firstname>
 524       <surname      is="sn"             ></surname>
 525       <address      is="postaladdress"  ></address>
 526       <city         is="l"              >Athens, OH</city>
 527       <zipcode      is="postalcode"     ></zipcode>
 528       <branchcode   is="branch"         >MAIN</branchcode>
 529       <userid       is="uid"            ></userid>
 530       <password     is="userpassword"   ></password>
 531       <email        is="mail"           ></email>
 532       <categorycode is="employeetype"   >PT</categorycode>
 533       <phone        is="telephonenumber"></phone>
 534     </mapping>
 535   </ldapserver>
 536  </config>
 537
 538 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 539 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 540 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 541 patron).
 542
 543 =head1 CONFIGURATION
 544
 545 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 546 your configuration and the presence of a matching Koha user in your local DB:
 547
 548                          LOCAL_USER
 549  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 550    A1      1       1        1      OK : We're updating them anyway.
 551    A2      1       1        0      OK : We're adding them anyway.
 552    B1      1       0        1      OK : We update them.
 553    B2      1       0        0     FAIL: We cannot add new user.
 554    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 555    C2      0       1        0      OK : We add the new user.
 556    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 557    D2      0       0        0     FAIL: We cannot add new user.
 558
 559 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 560 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 561 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 562
 563 If you choose NOT to update local users, the borrowers table will not be affected at all.
 564 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 565 the local table never contained the LDAP values.
 566
 567 =head2 auth_by_bind
 568
 569 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 570
 571 =head2 principal_name
 572
 573 Provides an optional sprintf-style format for manipulating the userid before the bind.
 574 Even though the userPrincipalName is one intended target, any uniquely identifying
 575 attribute that the server allows to be used for binding could be used.
 576
 577 Currently, principal_name only operates when auth_by_bind is enabled.
 578
 579 =head2 update_password
 580
 581 If this tag is left out or set to a true value, then the user's LDAP password
 582 will be stored (hashed) in the local Koha database. If you don't want this
 583 to happen, then set the value of this to '0'. Note that if passwords are not
 584 stored locally, and the connection to the LDAP system fails, then the users
 585 will not be able to log in at all.
 586
 587 =head2 Active Directory
 588
 589 The auth_by_bind and principal_name settings are recommended for Active Directory.
 590
 591 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 592 we would typically under openldap.  Instead of:
 593
 594     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 595
 596 We might get:
 597
 598     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 599
 600 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 601 in Koha userids.  But the userPrincipalName should be consistent, something like:
 602
 603     userPrincipalName: barnes.7@my_company.com
 604
 605 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 606 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 607 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 608 like this:
 609     <principal_name>%s@core.my_company.com</principal_name>
 610
 611 The user of the previous example, barnes.7, would then attempt to bind as:
 612     barnes.7@core.my_company.com
 613
 614 =head1 SEE ALSO
 615
 616 CGI(3)
 617
 618 Net::LDAP()
 619
 620 XML::Simple()
 621
 622 Digest::MD5(3)
 623
 624 sprintf()
 625
 626 =cut
 627
 628 # For reference, here's an important difference in the data structure we rely on.
 629 # ========================================
 630 # Using attrs instead of {asn}->attributes
 631 # ========================================
 632 #
 633 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 634 #       LDAP key: ->{             cn}->{           sss} = sss
 635 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 636 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 637 #
 638 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 639 #       LDAP key: ->{      givenname}->{Steve} = Steve
 640 #