C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use Koha::DateUtils qw( dt_from_string output_pref );
  28 use C4::Context;
  29 use C4::Stats qw( UpdateStats );
  30 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest ItemsAnyAvailableAndNotRestricted );
  31 use C4::Biblio qw( UpdateTotalIssues );
  32 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  33 use C4::Accounts;
  34 use C4::ItemCirculationAlertPreference;
  35 use C4::Message;
  36 use C4::Log qw( logaction ); # logaction
  37 use C4::Overdues;
  38 use C4::RotatingCollections qw(GetCollectionItemBranches);
  39 use Algorithm::CheckDigits qw( CheckDigits );
  40
  41 use Data::Dumper qw( Dumper );
  42 use Koha::Account;
  43 use Koha::AuthorisedValues;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string output_pref );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment GetDebarments AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetOpenIssue
  99       GetUpcomingDueIssues
 100       CheckIfIssuedToPatron
 101       IsItemIssued
 102       GetAgeRestriction
 103       GetTopIssues
 104
 105       AddReturn
 106       MarkIssueReturned
 107
 108       transferbook
 109       TooMany
 110       GetTransfers
 111       GetTransfersFromTo
 112       updateWrongTransfer
 113       CalcDateDue
 114       CheckValidBarcode
 115       IsBranchTransferAllowed
 116       CreateBranchTransferLimit
 117       DeleteBranchTransferLimits
 118       TransferSlip
 119
 120       GetOfflineOperations
 121       GetOfflineOperation
 122       AddOfflineOperation
 123       DeleteOfflineOperation
 124       ProcessOfflineOperation
 125       ProcessOfflinePayment
 126     );
 127     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 128 }
 129
 130 =head1 NAME
 131
 132 C4::Circulation - Koha circulation module
 133
 134 =head1 SYNOPSIS
 135
 136 use C4::Circulation;
 137
 138 =head1 DESCRIPTION
 139
 140 The functions in this module deal with circulation, issues, and
 141 returns, as well as general information about the library.
 142 Also deals with inventory.
 143
 144 =head1 FUNCTIONS
 145
 146 =head2 barcodedecode
 147
 148   $str = &barcodedecode($barcode, [$filter]);
 149
 150 Generic filter function for barcode string.
 151 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 152 Will do some manipulation of the barcode for systems that deliver a barcode
 153 to circulation.pl that differs from the barcode stored for the item.
 154 For proper functioning of this filter, calling the function on the
 155 correct barcode string (items.barcode) should return an unaltered barcode.
 156
 157 The optional $filter argument is to allow for testing or explicit
 158 behavior that ignores the System Pref.  Valid values are the same as the
 159 System Pref options.
 160
 161 =cut
 162
 163 # FIXME -- the &decode fcn below should be wrapped into this one.
 164 # FIXME -- these plugins should be moved out of Circulation.pm
 165 #
 166 sub barcodedecode {
 167     my ($barcode, $filter) = @_;
 168     my $branch = C4::Context::mybranch();
 169     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 170     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 171     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 172         if ($filter eq 'whitespace') {
 173                 $barcode =~ s/\s//g;
 174         } elsif ($filter eq 'cuecat') {
 175                 chomp($barcode);
 176             my @fields = split( /\./, $barcode );
 177             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 178             ($#results == 2) and return $results[2];
 179         } elsif ($filter eq 'T-prefix') {
 180                 if ($barcode =~ /^[Tt](\d)/) {
 181                         (defined($1) and $1 eq '0') and return $barcode;
 182             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 183                 }
 184         return sprintf("T%07d", $barcode);
 185         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 186         # Why drop the nonzero digit after the T?
 187         # Why pass non-digits (or empty string) to "T%07d"?
 188         } elsif ($filter eq 'libsuite8') {
 189                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 190                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 191                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 192                         }else{
 193                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 194                         }
 195                 }
 196     } elsif ($filter eq 'EAN13') {
 197         my $ean = CheckDigits('ean');
 198         if ( $ean->is_valid($barcode) ) {
 199             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 200             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 201         } else {
 202             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 203         }
 204         }
 205     return $barcode;    # return barcode, modified or not
 206 }
 207
 208 =head2 _decode
 209
 210   $str = &_decode($chunk);
 211
 212 Decodes a segment of a string emitted by a CueCat barcode scanner and
 213 returns it.
 214
 215 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 216 or Javascript based decoding on the client side.
 217
 218 =cut
 219
 220 sub _decode {
 221     my ($encoded) = @_;
 222     my $seq =
 223       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 224     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 225     my $l = ( $#s + 1 ) % 4;
 226     if ($l) {
 227         if ( $l == 1 ) {
 228             # warn "Error: Cuecat decode parsing failed!";
 229             return;
 230         }
 231         $l = 4 - $l;
 232         $#s += $l;
 233     }
 234     my $r = '';
 235     while ( $#s >= 0 ) {
 236         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 237         $r .=
 238             chr( ( $n >> 16 ) ^ 67 )
 239          .chr( ( $n >> 8 & 255 ) ^ 67 )
 240          .chr( ( $n & 255 ) ^ 67 );
 241         @s = @s[ 4 .. $#s ];
 242     }
 243     $r = substr( $r, 0, length($r) - $l );
 244     return $r;
 245 }
 246
 247 =head2 transferbook
 248
 249   ($dotransfer, $messages, $iteminformation) = &transferbook({
 250                                                    from_branch => $frombranch
 251                                                    to_branch => $tobranch,
 252                                                    barcode => $barcode,
 253                                                    ignore_reserves => $ignore_reserves,
 254                                                    trigger => $trigger
 255                                                 });
 256
 257 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 258
 259 C<$fbr> is the code for the branch initiating the transfer.
 260 C<$tbr> is the code for the branch to which the item should be transferred.
 261
 262 C<$barcode> is the barcode of the item to be transferred.
 263
 264 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 265 Otherwise, if an item is reserved, the transfer fails.
 266
 267 C<$trigger> is the enum value for what triggered the transfer.
 268
 269 Returns three values:
 270
 271 =over
 272
 273 =item $dotransfer
 274
 275 is true if the transfer was successful.
 276
 277 =item $messages
 278
 279 is a reference-to-hash which may have any of the following keys:
 280
 281 =over
 282
 283 =item C<BadBarcode>
 284
 285 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 286
 287 =item C<DestinationEqualsHolding>
 288
 289 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 290
 291 =item C<WasReturned>
 292
 293 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 294
 295 =item C<ResFound>
 296
 297 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 298
 299 =item C<WasTransferred>
 300
 301 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 302
 303 =item C<RecallPlacedAtHoldingBranch>
 304
 305 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 306
 307 =item C<RecallFound>
 308
 309 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 310
 311 =back
 312
 313 =back
 314
 315 =cut
 316
 317 sub transferbook {
 318     my $params = shift;
 319     my $tbr      = $params->{to_branch};
 320     my $fbr      = $params->{from_branch};
 321     my $ignoreRs = $params->{ignore_reserves};
 322     my $barcode  = $params->{barcode};
 323     my $trigger  = $params->{trigger};
 324     my $messages;
 325     my $dotransfer      = 1;
 326     my $item = Koha::Items->find( { barcode => $barcode } );
 327
 328     Koha::Exceptions::MissingParameter->throw(
 329         "Missing mandatory parameter: from_branch")
 330       unless $fbr;
 331
 332     Koha::Exceptions::MissingParameter->throw(
 333         "Missing mandatory parameter: to_branch")
 334       unless $tbr;
 335
 336     # bad barcode..
 337     unless ( $item ) {
 338         $messages->{'BadBarcode'} = $barcode;
 339         $dotransfer = 0;
 340         return ( $dotransfer, $messages );
 341     }
 342
 343     my $itemnumber = $item->itemnumber;
 344     # get branches of book...
 345     my $hbr = $item->homebranch;
 346
 347     # if using Branch Transfer Limits
 348     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 349         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 350         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 351             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 352                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 353                 $dotransfer = 0;
 354             }
 355         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 356             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 357             $dotransfer = 0;
 358         }
 359     }
 360
 361     # can't transfer book if is already there....
 362     if ( $fbr eq $tbr ) {
 363         $messages->{'DestinationEqualsHolding'} = 1;
 364         $dotransfer = 0;
 365     }
 366
 367     # check if it is still issued to someone, return it...
 368     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 369     if ( $issue ) {
 370         AddReturn( $barcode, $fbr );
 371         $messages->{'WasReturned'} = $issue->borrowernumber;
 372     }
 373
 374     # find reserves.....
 375     # That'll save a database query.
 376     my ( $resfound, $resrec, undef ) =
 377       CheckReserves( $itemnumber );
 378     if ( $resfound ) {
 379         $resrec->{'ResFound'} = $resfound;
 380         $messages->{'ResFound'} = $resrec;
 381         $dotransfer = 0 unless $ignoreRs;
 382     }
 383
 384     # find recall
 385     if ( C4::Context->preference('UseRecalls') ) {
 386         my $recall = Koha::Recalls->find({ itemnumber => $itemnumber, status => 'in_transit' });
 387         if ( defined $recall ) {
 388             # do a transfer if the recall branch is different to the item holding branch
 389             if ( $recall->branchcode eq $fbr ) {
 390                 $dotransfer = 0;
 391                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 392             } else {
 393                 $dotransfer = 1;
 394                 $messages->{'RecallFound'} = $recall;
 395             }
 396         }
 397     }
 398
 399     #actually do the transfer....
 400     if ($dotransfer) {
 401         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 402
 403         # don't need to update MARC anymore, we do it in batch now
 404         $messages->{'WasTransfered'} = $tbr;
 405
 406     }
 407     ModDateLastSeen( $itemnumber );
 408     return ( $dotransfer, $messages );
 409 }
 410
 411
 412 sub TooMany {
 413     my $borrower        = shift;
 414     my $item_object = shift;
 415     my $params = shift;
 416     my $onsite_checkout = $params->{onsite_checkout} || 0;
 417     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 418     my $cat_borrower    = $borrower->{'categorycode'};
 419     my $dbh             = C4::Context->dbh;
 420     # Get which branchcode we need
 421     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 422     my $type = $item_object->effective_itemtype;
 423
 424     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 425     $type_object = Koha::ItemTypes->find( $type );
 426     $parent_type = $type_object->parent_type if $type_object;
 427     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 428     # Find any children if we are a parent_type;
 429
 430     # given branch, patron category, and item type, determine
 431     # applicable issuing rule
 432
 433     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 434         {
 435             categorycode => $cat_borrower,
 436             itemtype     => $parent_type,
 437             branchcode   => $branch,
 438             rule_name    => 'maxissueqty',
 439         }
 440     ) if $parent_type;
 441     # If the parent rule is for default type we discount it
 442     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 443
 444     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 445         {
 446             categorycode => $cat_borrower,
 447             itemtype     => $type,
 448             branchcode   => $branch,
 449             rule_name    => 'maxissueqty',
 450         }
 451     );
 452
 453     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 454         {
 455             categorycode => $cat_borrower,
 456             itemtype     => $type,
 457             branchcode   => $branch,
 458             rule_name    => 'maxonsiteissueqty',
 459         }
 460     );
 461
 462
 463     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 464     # if a rule is found and has a loan limit set, count
 465     # how many loans the patron already has that meet that
 466     # rule
 467     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 468
 469         my $checkouts;
 470         if ( $maxissueqty_rule->branchcode ) {
 471             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 472                 $checkouts = $patron->checkouts->search(
 473                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 474             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 475                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 476             } else {
 477                 $checkouts = $patron->checkouts->search(
 478                     { 'item.homebranch' => $maxissueqty_rule->branchcode } );
 479             }
 480         } else {
 481             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 482         }
 483         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 484
 485         my $sum_checkouts;
 486         my $rule_itemtype = $maxissueqty_rule->itemtype;
 487
 488         my @types;
 489         unless ( $rule_itemtype ) {
 490             # matching rule has the default item type, so count only
 491             # those existing loans that don't fall under a more
 492             # specific rule
 493             @types = Koha::CirculationRules->search(
 494                 {
 495                     branchcode => $maxissueqty_rule->branchcode,
 496                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 497                     itemtype  => { '!=' => undef },
 498                     rule_name => 'maxissueqty'
 499                 }
 500             )->get_column('itemtype');
 501         } else {
 502             if ( $parent_maxissueqty_rule ) {
 503                 # if we have a parent item type then we count loans of the
 504                 # specific item type or its siblings or parent
 505                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 506                 @types = $children->get_column('itemtype');
 507                 push @types, $parent_type;
 508             } elsif ( $child_types ) {
 509                 # If we are a parent type, we need to count all child types and our own type
 510                 @types = $child_types->get_column('itemtype');
 511                 push @types, $type; # And don't forget to count our own types
 512             } else {
 513                 # Otherwise only count the specific itemtype
 514                 push @types, $type;
 515             }
 516         }
 517
 518         while ( my $c = $checkouts->next ) {
 519             my $itemtype = $c->item->effective_itemtype;
 520
 521             unless ( $rule_itemtype ) {
 522                 next if grep {$_ eq $itemtype} @types;
 523             } else {
 524                 next unless grep {$_ eq $itemtype} @types;
 525             }
 526
 527             $sum_checkouts->{total}++;
 528             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 529             $sum_checkouts->{itemtype}->{$itemtype}++;
 530         }
 531
 532         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 533         my $checkout_count = $sum_checkouts->{total} || 0;
 534         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 535
 536         my $checkout_rules = {
 537             checkout_count               => $checkout_count,
 538             onsite_checkout_count        => $onsite_checkout_count,
 539             onsite_checkout              => $onsite_checkout,
 540             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 541             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 542             switch_onsite_checkout       => $switch_onsite_checkout,
 543         };
 544         # If parent rules exists
 545         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 546             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 547             my $qty_over = _check_max_qty($checkout_rules);
 548             return $qty_over if defined $qty_over;
 549
 550             # If the parent rule is less than or equal to the child, we only need check the parent
 551             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 552                 $checkout_rules->{checkout_count} = $checkout_count_type;
 553                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 554                 my $qty_over = _check_max_qty($checkout_rules);
 555                 return $qty_over if defined $qty_over;
 556             }
 557         } else {
 558             my $qty_over = _check_max_qty($checkout_rules);
 559             return $qty_over if defined $qty_over;
 560         }
 561     }
 562
 563     # Now count total loans against the limit for the branch
 564     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 565     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 566         my $checkouts;
 567         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 568             $checkouts = $patron->checkouts->search(
 569                 { 'me.branchcode' => $branch} );
 570         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 571             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 572         } else {
 573             $checkouts = $patron->checkouts->search(
 574                 { 'item.homebranch' => $branch},
 575                 { prefetch          => 'item' } );
 576         }
 577
 578         my $checkout_count = $checkouts->count;
 579         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 580         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 581         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 582
 583         my $qty_over = _check_max_qty(
 584             {
 585                 checkout_count               => $checkout_count,
 586                 onsite_checkout_count        => $onsite_checkout_count,
 587                 onsite_checkout              => $onsite_checkout,
 588                 max_checkouts_allowed        => $max_checkouts_allowed,
 589                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 590                 switch_onsite_checkout       => $switch_onsite_checkout
 591             }
 592         );
 593         return $qty_over if defined $qty_over;
 594     }
 595
 596     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 597         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 598     }
 599
 600     # OK, the patron can issue !!!
 601     return;
 602 }
 603
 604 sub _check_max_qty {
 605     my $params                       = shift;
 606     my $checkout_count               = $params->{checkout_count};
 607     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 608     my $onsite_checkout              = $params->{onsite_checkout};
 609     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 610     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 611     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 612
 613     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 614         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 615         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 616             return {
 617                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 618                 count       => $onsite_checkout_count,
 619                 max_allowed => $max_onsite_checkouts_allowed,
 620             };
 621         }
 622     }
 623     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 624         if ( $max_checkouts_allowed eq '' ) { return; }
 625         my $delta = $switch_onsite_checkout ? 1 : 0;
 626         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 627             return {
 628                 reason      => 'TOO_MANY_CHECKOUTS',
 629                 count       => $checkout_count,
 630                 max_allowed => $max_checkouts_allowed,
 631             };
 632         }
 633     }
 634     elsif ( not $onsite_checkout ) {
 635         if ( $max_checkouts_allowed eq '' ) { return; }
 636         if (
 637             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 638         {
 639             return {
 640                 reason      => 'TOO_MANY_CHECKOUTS',
 641                 count       => $checkout_count - $onsite_checkout_count,
 642                 max_allowed => $max_checkouts_allowed,
 643             };
 644         }
 645     }
 646
 647     return;
 648 }
 649
 650 =head2 CanBookBeIssued
 651
 652   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 653                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 654
 655 Check if a book can be issued.
 656
 657 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 658
 659 IMPORTANT: The assumption by users of this routine is that causes blocking
 660 the issue are keyed by uppercase labels and other returned
 661 data is keyed in lower case!
 662
 663 =over 4
 664
 665 =item C<$patron> is a Koha::Patron
 666
 667 =item C<$barcode> is the bar code of the book being issued.
 668
 669 =item C<$duedates> is a DateTime object.
 670
 671 =item C<$inprocess> boolean switch
 672
 673 =item C<$ignore_reserves> boolean switch
 674
 675 =item C<$params> Hashref of additional parameters
 676
 677 Available keys:
 678     override_high_holds - Ignore high holds
 679     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 680
 681 =back
 682
 683 Returns :
 684
 685 =over 4
 686
 687 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 688 Possible values are :
 689
 690 =back
 691
 692 =head3 INVALID_DATE
 693
 694 sticky due date is invalid
 695
 696 =head3 GNA
 697
 698 borrower gone with no address
 699
 700 =head3 CARD_LOST
 701
 702 borrower declared it's card lost
 703
 704 =head3 DEBARRED
 705
 706 borrower debarred
 707
 708 =head3 UNKNOWN_BARCODE
 709
 710 barcode unknown
 711
 712 =head3 NOT_FOR_LOAN
 713
 714 item is not for loan
 715
 716 =head3 WTHDRAWN
 717
 718 item withdrawn.
 719
 720 =head3 RESTRICTED
 721
 722 item is restricted (set by ??)
 723
 724 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 725 could be prevented, but ones that can be overriden by the operator.
 726
 727 Possible values are :
 728
 729 =head3 DEBT
 730
 731 borrower has debts.
 732
 733 =head3 RENEW_ISSUE
 734
 735 renewing, not issuing
 736
 737 =head3 ISSUED_TO_ANOTHER
 738
 739 issued to someone else.
 740
 741 =head3 RESERVED
 742
 743 reserved for someone else.
 744
 745 =head3 TRANSFERRED
 746
 747 reserved and being transferred for someone else.
 748
 749 =head3 INVALID_DATE
 750
 751 sticky due date is invalid or due date in the past
 752
 753 =head3 TOO_MANY
 754
 755 if the borrower borrows to much things
 756
 757 =head3 RECALLED
 758
 759 recalled by someone else
 760
 761 =cut
 762
 763 sub CanBookBeIssued {
 764     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 765     my %needsconfirmation;    # filled with problems that needs confirmations
 766     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 767     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 768     my %messages;             # filled with information messages that should be displayed.
 769
 770     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 771     my $override_high_holds = $params->{override_high_holds} || 0;
 772
 773     my $item_object = Koha::Items->find({barcode => $barcode });
 774
 775     # MANDATORY CHECKS - unless item exists, nothing else matters
 776     unless ( $item_object ) {
 777         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 778     }
 779     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 780
 781     my $item_unblessed = $item_object->unblessed; # Transition...
 782     my $issue = $item_object->checkout;
 783     my $biblio = $item_object->biblio;
 784
 785     my $biblioitem = $biblio->biblioitem;
 786     my $effective_itemtype = $item_object->effective_itemtype;
 787     my $dbh             = C4::Context->dbh;
 788     my $patron_unblessed = $patron->unblessed;
 789
 790     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 791     #
 792     # DUE DATE is OK ? -- should already have checked.
 793     #
 794     if ($duedate && ref $duedate ne 'DateTime') {
 795         $duedate = dt_from_string($duedate);
 796     }
 797     my $now = dt_from_string();
 798     unless ( $duedate ) {
 799         my $issuedate = $now->clone();
 800
 801         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 802
 803         # Offline circ calls AddIssue directly, doesn't run through here
 804         #  So issuingimpossible should be ok.
 805     }
 806
 807     my $fees = Koha::Charges::Fees->new(
 808         {
 809             patron    => $patron,
 810             library   => $circ_library,
 811             item      => $item_object,
 812             to_date   => $duedate,
 813         }
 814     );
 815
 816     if ($duedate) {
 817         my $today = $now->clone();
 818         $today->truncate( to => 'minute');
 819         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 820             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 821         }
 822     } else {
 823             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 824     }
 825
 826     #
 827     # BORROWER STATUS
 828     #
 829     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 830         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 831         C4::Stats::UpdateStats({
 832                      branch => C4::Context->userenv->{'branch'},
 833                      type => 'localuse',
 834                      itemnumber => $item_object->itemnumber,
 835                      itemtype => $effective_itemtype,
 836                      borrowernumber => $patron->borrowernumber,
 837                      ccode => $item_object->ccode}
 838                     );
 839         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 840         return( { STATS => 1 }, {});
 841     }
 842
 843     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 844         $issuingimpossible{GNA} = 1;
 845     }
 846
 847     if ( $patron->lost && $patron->lost == 1 ) {
 848         $issuingimpossible{CARD_LOST} = 1;
 849     }
 850     if ( $patron->is_debarred ) {
 851         $issuingimpossible{DEBARRED} = 1;
 852     }
 853
 854     if ( $patron->is_expired ) {
 855         $issuingimpossible{EXPIRED} = 1;
 856     }
 857
 858     #
 859     # BORROWER STATUS
 860     #
 861
 862     # DEBTS
 863     my $account = $patron->account;
 864     my $balance = $account->balance;
 865     my $non_issues_charges = $account->non_issues_charges;
 866     my $other_charges = $balance - $non_issues_charges;
 867
 868     my $amountlimit = C4::Context->preference("noissuescharge");
 869     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 870     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 871
 872     # Check the debt of this patrons guarantees
 873     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 874     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 875     if ( defined $no_issues_charge_guarantees ) {
 876         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 877         my $guarantees_non_issues_charges = 0;
 878         foreach my $g ( @guarantees ) {
 879             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 880         }
 881
 882         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 883             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 884         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 885             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 886         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 887             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 888         }
 889     }
 890
 891     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 892     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 893     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 894     if ( defined $no_issues_charge_guarantors ) {
 895         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 896
 897         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 898             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 899         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 900             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 901         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 902             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 903         }
 904     }
 905
 906     if ( C4::Context->preference("IssuingInProcess") ) {
 907         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 908             $issuingimpossible{DEBT} = $non_issues_charges;
 909         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 910             $needsconfirmation{DEBT} = $non_issues_charges;
 911         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 912             $needsconfirmation{DEBT} = $non_issues_charges;
 913         }
 914     }
 915     else {
 916         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 917             $needsconfirmation{DEBT} = $non_issues_charges;
 918         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 919             $issuingimpossible{DEBT} = $non_issues_charges;
 920         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 921             $needsconfirmation{DEBT} = $non_issues_charges;
 922         }
 923     }
 924
 925     if ($balance > 0 && $other_charges > 0) {
 926         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 927     }
 928
 929     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 930     $patron_unblessed = $patron->unblessed;
 931
 932     if ( my $debarred_date = $patron->is_debarred ) {
 933          # patron has accrued fine days or has a restriction. $count is a date
 934         if ($debarred_date eq '9999-12-31') {
 935             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 936         }
 937         else {
 938             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 939         }
 940     } elsif ( my $num_overdues = $patron->has_overdues ) {
 941         ## patron has outstanding overdue loans
 942         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 943             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 944         }
 945         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 946             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 947         }
 948     }
 949
 950     # Additional Materials Check
 951     if ( C4::Context->preference("CircConfirmItemParts")
 952         && $item_object->materials )
 953     {
 954         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 955     }
 956
 957     #
 958     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 959     #
 960     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 961
 962         # Already issued to current borrower.
 963         # If it is an on-site checkout if it can be switched to a normal checkout
 964         # or ask whether the loan should be renewed
 965
 966         if ( $issue->onsite_checkout
 967                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 968             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 969         } else {
 970             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 971                 $patron->borrowernumber,
 972                 $item_object->itemnumber,
 973             );
 974             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 975                 if ( $renewerror eq 'onsite_checkout' ) {
 976                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 977                 }
 978                 else {
 979                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 980                 }
 981             }
 982             else {
 983                 $needsconfirmation{RENEW_ISSUE} = 1;
 984             }
 985         }
 986     }
 987     elsif ( $issue ) {
 988
 989         # issued to someone else
 990
 991         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 992
 993         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 994
 995         unless ( $can_be_returned ) {
 996             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 997             $issuingimpossible{branch_to_return} = $message;
 998         } else {
 999             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
1000                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
1001             } else {
1002             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
1003             $needsconfirmation{issued_firstname} = $patron->firstname;
1004             $needsconfirmation{issued_surname} = $patron->surname;
1005             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
1006             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
1007             }
1008         }
1009     }
1010
1011     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1012     #
1013     my $switch_onsite_checkout = (
1014           C4::Context->preference('SwitchOnSiteCheckouts')
1015       and $issue
1016       and $issue->onsite_checkout
1017       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1018     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1019     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1020     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1021         if ( $toomany->{max_allowed} == 0 ) {
1022             $needsconfirmation{PATRON_CANT} = 1;
1023         }
1024         if ( C4::Context->preference("AllowTooManyOverride") ) {
1025             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1026             $needsconfirmation{current_loan_count} = $toomany->{count};
1027             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1028         } else {
1029             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1030             $issuingimpossible{current_loan_count} = $toomany->{count};
1031             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1032         }
1033     }
1034
1035     #
1036     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1037     #
1038     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1039     my $wants_check = $patron->wants_check_for_previous_checkout;
1040     $needsconfirmation{PREVISSUE} = 1
1041         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1042
1043     #
1044     # ITEM CHECKING
1045     #
1046     if ( $item_object->notforloan )
1047     {
1048         if(!C4::Context->preference("AllowNotForLoanOverride")){
1049             $issuingimpossible{NOT_FOR_LOAN} = 1;
1050             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1051         }else{
1052             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1053             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1054         }
1055     }
1056     else {
1057         # we have to check itemtypes.notforloan also
1058         if (C4::Context->preference('item-level_itypes')){
1059             # this should probably be a subroutine
1060             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1061             $sth->execute($effective_itemtype);
1062             my $notforloan=$sth->fetchrow_hashref();
1063             if ($notforloan->{'notforloan'}) {
1064                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1065                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1066                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1067                 } else {
1068                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1069                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1070                 }
1071             }
1072         }
1073         else {
1074             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1075             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1076                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1077                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1078                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1079                 } else {
1080                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1081                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1082                 }
1083             }
1084         }
1085     }
1086     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1087     {
1088         $issuingimpossible{WTHDRAWN} = 1;
1089     }
1090     if (   $item_object->restricted
1091         && $item_object->restricted == 1 )
1092     {
1093         $issuingimpossible{RESTRICTED} = 1;
1094     }
1095     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1096         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1097         my $code = $av->count ? $av->next->lib : '';
1098         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1099         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1100     }
1101     if ( C4::Context->preference("IndependentBranches") ) {
1102         my $userenv = C4::Context->userenv;
1103         unless ( C4::Context->IsSuperLibrarian() ) {
1104             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1105             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1106                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1107                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1108             }
1109             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1110               if ( $patron->branchcode ne $userenv->{branch} );
1111         }
1112     }
1113
1114     #
1115     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1116     #
1117     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1118     if ($rentalConfirmation) {
1119         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1120
1121         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1122         if ($itemtype_object) {
1123             my $accumulate_charge = $fees->accumulate_rentalcharge();
1124             if ( $accumulate_charge > 0 ) {
1125                 $rentalCharge += $accumulate_charge;
1126             }
1127         }
1128
1129         if ( $rentalCharge > 0 ) {
1130             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1131         }
1132     }
1133
1134     my $recall;
1135     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1136     # Only bother doing this if UseRecalls is enabled and the item is recallable
1137     # Don't look at recalls that are in transit
1138     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1139         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'recalldate' } })->filter_by_current->as_list;
1140
1141         foreach my $r ( @recalls ) {
1142             if ( $r->itemnumber and
1143                 $r->itemnumber == $item_object->itemnumber and
1144                 $r->borrowernumber == $patron->borrowernumber and
1145                 ( $r->waiting or $r->requested ) ) {
1146                 $messages{RECALLED} = $r->recall_id;
1147                 $recall = $r;
1148                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1149                 last;
1150             }
1151             elsif ( $r->itemnumber and
1152                 $r->itemnumber == $item_object->itemnumber and
1153                 $r->in_transit ) {
1154                 # recalled item is in transit
1155                 $issuingimpossible{RECALLED_INTRANSIT} = $r->branchcode;
1156             }
1157             elsif ( $r->item_level_recall and
1158                 $r->itemnumber == $item_object->itemnumber and
1159                 $r->borrowernumber != $patron->borrowernumber and
1160                 !$r->in_transit ) {
1161                 # this specific item has been recalled by a different patron
1162                 $needsconfirmation{RECALLED} = $r;
1163                 $recall = $r;
1164                 last;
1165             }
1166             elsif ( !$r->item_level_recall and
1167                 $r->borrowernumber != $patron->borrowernumber and
1168                 !$r->in_transit ) {
1169                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1170                 $needsconfirmation{RECALLED} = $r;
1171                 $recall = $r;
1172                 last;
1173             }
1174         }
1175     }
1176
1177     unless ( $ignore_reserves and defined $recall ) {
1178         # See if the item is on reserve.
1179         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1180         if ($restype) {
1181             my $resbor = $res->{'borrowernumber'};
1182             if ( $resbor ne $patron->borrowernumber ) {
1183                 my $patron = Koha::Patrons->find( $resbor );
1184                 if ( $restype eq "Waiting" )
1185                 {
1186                     # The item is on reserve and waiting, but has been
1187                     # reserved by some other patron.
1188                     $needsconfirmation{RESERVE_WAITING} = 1;
1189                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1190                     $needsconfirmation{'ressurname'} = $patron->surname;
1191                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1192                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1193                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1194                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1195                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1196                 }
1197                 elsif ( $restype eq "Reserved" ) {
1198                     # The item is on reserve for someone else.
1199                     $needsconfirmation{RESERVED} = 1;
1200                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1201                     $needsconfirmation{'ressurname'} = $patron->surname;
1202                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1203                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1204                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1205                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1206                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1207                 }
1208                 elsif ( $restype eq "Transferred" ) {
1209                     # The item is determined hold being transferred for someone else.
1210                     $needsconfirmation{TRANSFERRED} = 1;
1211                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1212                     $needsconfirmation{'ressurname'} = $patron->surname;
1213                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1214                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1215                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1216                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1217                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1218                 }
1219                 elsif ( $restype eq "Processing" ) {
1220                     # The item is determined hold being processed for someone else.
1221                     $needsconfirmation{PROCESSING} = 1;
1222                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1223                     $needsconfirmation{'ressurname'} = $patron->surname;
1224                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1225                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1226                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1227                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1228                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1229                 }
1230             }
1231         }
1232     }
1233
1234     ## CHECK AGE RESTRICTION
1235     my $agerestriction  = $biblioitem->agerestriction;
1236     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1237     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1238         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1239             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1240         }
1241         else {
1242             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1243         }
1244     }
1245
1246     ## check for high holds decreasing loan period
1247     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1248         my $check = checkHighHolds( $item_object, $patron );
1249
1250         if ( $check->{exceeded} ) {
1251             if ($override_high_holds) {
1252                 $alerts{HIGHHOLDS} = {
1253                     num_holds  => $check->{outstanding},
1254                     duration   => $check->{duration},
1255                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1256                 };
1257             }
1258             else {
1259                 $needsconfirmation{HIGHHOLDS} = {
1260                     num_holds  => $check->{outstanding},
1261                     duration   => $check->{duration},
1262                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1263                 };
1264             }
1265         }
1266     }
1267
1268     if (
1269         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1270         # don't do the multiple loans per bib check if we've
1271         # already determined that we've got a loan on the same item
1272         !$issuingimpossible{NO_MORE_RENEWALS} &&
1273         !$needsconfirmation{RENEW_ISSUE}
1274     ) {
1275         # Check if borrower has already issued an item from the same biblio
1276         # Only if it's not a subscription
1277         my $biblionumber = $item_object->biblionumber;
1278         require C4::Serials;
1279         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1280         unless ($is_a_subscription) {
1281             # FIXME Should be $patron->checkouts($args);
1282             my $checkouts = Koha::Checkouts->search(
1283                 {
1284                     borrowernumber => $patron->borrowernumber,
1285                     biblionumber   => $biblionumber,
1286                 },
1287                 {
1288                     join => 'item',
1289                 }
1290             );
1291             # if we get here, we don't already have a loan on this item,
1292             # so if there are any loans on this bib, ask for confirmation
1293             if ( $checkouts->count ) {
1294                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1295             }
1296         }
1297     }
1298
1299     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1300 }
1301
1302 =head2 CanBookBeReturned
1303
1304   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1305
1306 Check whether the item can be returned to the provided branch
1307
1308 =over 4
1309
1310 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1311
1312 =item C<$branch> is the branchcode where the return is taking place
1313
1314 =back
1315
1316 Returns:
1317
1318 =over 4
1319
1320 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1321
1322 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1323
1324 =back
1325
1326 =cut
1327
1328 sub CanBookBeReturned {
1329   my ($item, $branch) = @_;
1330   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1331
1332   # assume return is allowed to start
1333   my $allowed = 1;
1334   my $message;
1335
1336   # identify all cases where return is forbidden
1337   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1338      $allowed = 0;
1339      $message = $item->{'homebranch'};
1340   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1341      $allowed = 0;
1342      $message = $item->{'holdingbranch'};
1343   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1344      $allowed = 0;
1345      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1346   }
1347
1348   return ($allowed, $message);
1349 }
1350
1351 =head2 CheckHighHolds
1352
1353     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1354     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1355     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1356
1357 =cut
1358
1359 sub checkHighHolds {
1360     my ( $item, $patron ) = @_;
1361     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
1362
1363     my $return_data = {
1364         exceeded    => 0,
1365         outstanding => 0,
1366         duration    => 0,
1367         due_date    => undef,
1368     };
1369
1370     my $holds = Koha::Holds->search( { biblionumber => $item->biblionumber } );
1371
1372     if ( $holds->count() ) {
1373         $return_data->{outstanding} = $holds->count();
1374
1375         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1376         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1377         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1378
1379         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1380
1381         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1382
1383             # static means just more than a given number of holds on the record
1384
1385             # If the number of holds is less than the threshold, we can stop here
1386             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1387                 return $return_data;
1388             }
1389         }
1390         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1391
1392             # dynamic means X more than the number of holdable items on the record
1393
1394             # let's get the items
1395             my @items = $holds->next()->biblio()->items()->as_list;
1396
1397             # Remove any items with status defined to be ignored even if the would not make item unholdable
1398             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1399                 @items = grep { !$_->$status } @items;
1400             }
1401
1402             # Remove any items that are not holdable for this patron
1403             @items = grep { CanItemBeReserved( $patron , $_, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1404
1405             my $items_count = scalar @items;
1406
1407             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1408
1409             # If the number of holds is less than the count of items we have
1410             # plus the number of holds allowed above that count, we can stop here
1411             if ( $holds->count() <= $threshold ) {
1412                 return $return_data;
1413             }
1414         }
1415
1416         my $issuedate = dt_from_string();
1417
1418         my $itype = $item->effective_itemtype;
1419         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1420             {
1421                 categorycode => $patron->categorycode,
1422                 itemtype     => $itype,
1423                 branchcode   => $branchcode,
1424             }
1425         );
1426         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1427
1428         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron->unblessed );
1429
1430         my $rule = Koha::CirculationRules->get_effective_rule(
1431             {
1432                 categorycode => $patron->categorycode,
1433                 itemtype     => $item->effective_itemtype,
1434                 branchcode   => $branchcode,
1435                 rule_name    => 'decreaseloanholds',
1436             }
1437         );
1438
1439         my $duration;
1440         if ( defined($rule) && $rule->rule_value ne '' ){
1441             # overrides decreaseLoanHighHoldsDuration syspref
1442             $duration = $rule->rule_value;
1443         } else {
1444             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1445         }
1446         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1447         $reduced_datedue->set_hour($orig_due->hour);
1448         $reduced_datedue->set_minute($orig_due->minute);
1449         $reduced_datedue->truncate( to => 'minute' );
1450
1451         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1452             $return_data->{exceeded} = 1;
1453             $return_data->{duration} = $duration;
1454             $return_data->{due_date} = $reduced_datedue;
1455         }
1456     }
1457
1458     return $return_data;
1459 }
1460
1461 =head2 AddIssue
1462
1463   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1464
1465 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1466
1467 =over 4
1468
1469 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1470
1471 =item C<$barcode> is the barcode of the item being issued.
1472
1473 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1474 Calculated if empty.
1475
1476 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1477
1478 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1479 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1480
1481 AddIssue does the following things :
1482
1483   - step 01: check that there is a borrowernumber & a barcode provided
1484   - check for RENEWAL (book issued & being issued to the same patron)
1485       - renewal YES = Calculate Charge & renew
1486       - renewal NO  =
1487           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1488           * RESERVE PLACED ?
1489               - fill reserve if reserve to this patron
1490               - cancel reserve or not, otherwise
1491           * RECALL PLACED ?
1492               - fill recall if recall to this patron
1493               - cancel recall or not
1494               - revert recall's waiting status or not
1495           * TRANSFERT PENDING ?
1496               - complete the transfert
1497           * ISSUE THE BOOK
1498
1499 =back
1500
1501 =cut
1502
1503 sub AddIssue {
1504     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1505
1506     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1507     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1508     my $auto_renew = $params && $params->{auto_renew};
1509     my $cancel_recall = $params && $params->{cancel_recall};
1510     my $recall_id = $params && $params->{recall_id};
1511     my $dbh          = C4::Context->dbh;
1512     my $barcodecheck = CheckValidBarcode($barcode);
1513
1514     my $issue;
1515
1516     if ( $datedue && ref $datedue ne 'DateTime' ) {
1517         $datedue = dt_from_string($datedue);
1518     }
1519
1520     # $issuedate defaults to today.
1521     if ( !defined $issuedate ) {
1522         $issuedate = dt_from_string();
1523     }
1524     else {
1525         if ( ref $issuedate ne 'DateTime' ) {
1526             $issuedate = dt_from_string($issuedate);
1527
1528         }
1529     }
1530
1531     # Stop here if the patron or barcode doesn't exist
1532     if ( $borrower && $barcode && $barcodecheck ) {
1533         # find which item we issue
1534         my $item_object = Koha::Items->find({ barcode => $barcode })
1535           or return;    # if we don't get an Item, abort.
1536         my $item_unblessed = $item_object->unblessed;
1537
1538         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1539
1540         # get actual issuing if there is one
1541         my $actualissue = $item_object->checkout;
1542
1543         # check if we just renew the issue.
1544         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1545                 and not $switch_onsite_checkout ) {
1546             $datedue = AddRenewal(
1547                 $borrower->{'borrowernumber'},
1548                 $item_object->itemnumber,
1549                 $branchcode,
1550                 $datedue,
1551                 $issuedate,    # here interpreted as the renewal date
1552             );
1553         }
1554         else {
1555             unless ($datedue) {
1556                 my $itype = $item_object->effective_itemtype;
1557                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1558
1559             }
1560             $datedue->truncate( to => 'minute' );
1561
1562             my $patron = Koha::Patrons->find( $borrower );
1563             my $library = Koha::Libraries->find( $branchcode );
1564             my $fees = Koha::Charges::Fees->new(
1565                 {
1566                     patron    => $patron,
1567                     library   => $library,
1568                     item      => $item_object,
1569                     to_date   => $datedue,
1570                 }
1571             );
1572
1573             # it's NOT a renewal
1574             if ( $actualissue and not $switch_onsite_checkout ) {
1575                 # This book is currently on loan, but not to the person
1576                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1577                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1578                 return unless $allowed;
1579                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1580                 # AddReturn certainly has side-effects, like onloan => undef
1581                 $item_object->discard_changes;
1582             }
1583
1584             if ( C4::Context->preference('UseRecalls') ) {
1585                 Koha::Recalls->move_recall(
1586                     {
1587                         action         => $cancel_recall,
1588                         recall_id      => $recall_id,
1589                         item           => $item_object,
1590                         borrowernumber => $borrower->{borrowernumber},
1591                     }
1592                 );
1593             }
1594
1595             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1596
1597             # Starting process for transfer job (checking transfert and validate it if we have one)
1598             if ( my $transfer = $item_object->get_transfer ) {
1599                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1600                 $transfer->set(
1601                     {
1602                         datearrived => dt_from_string,
1603                         tobranch    => C4::Context->userenv->{branch},
1604                         comments    => 'Forced branchtransfer'
1605                     }
1606                 )->store;
1607                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1608                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1609                     if ( $hold ) { # Is this really needed?
1610                         $hold->set( { found => undef } )->store;
1611                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1612                     }
1613                 }
1614             }
1615
1616             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1617             unless ($auto_renew) {
1618                 my $rule = Koha::CirculationRules->get_effective_rule(
1619                     {
1620                         categorycode => $borrower->{categorycode},
1621                         itemtype     => $item_object->effective_itemtype,
1622                         branchcode   => $branchcode,
1623                         rule_name    => 'auto_renew'
1624                     }
1625                 );
1626
1627                 $auto_renew = $rule->rule_value if $rule;
1628             }
1629
1630             my $issue_attributes = {
1631                 borrowernumber  => $borrower->{'borrowernumber'},
1632                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1633                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1634                 branchcode      => C4::Context->userenv->{'branch'},
1635                 onsite_checkout => $onsite_checkout,
1636                 auto_renew      => $auto_renew ? 1 : 0,
1637             };
1638
1639             # Get ID of logged in user.  if called from a batch job,
1640             # no user session exists and C4::Context->userenv() returns
1641             # the scalar '0'. Only do this if the syspref says so
1642             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1643                 my $userenv = C4::Context->userenv();
1644                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1645                 if ($usernumber) {
1646                     $issue_attributes->{issuer_id} = $usernumber;
1647                 }
1648             }
1649
1650             # In the case that the borrower has an on-site checkout
1651             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1652             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1653             if ($issue) {
1654                 $issue->set($issue_attributes)->store;
1655             }
1656             else {
1657                 $issue = Koha::Checkout->new(
1658                     {
1659                         itemnumber => $item_object->itemnumber,
1660                         %$issue_attributes,
1661                     }
1662                 )->store;
1663             }
1664             $issue->discard_changes;
1665             C4::Auth::track_login_daily( $borrower->{userid} );
1666             if ( $item_object->location && $item_object->location eq 'CART'
1667                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1668             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1669                 CartToShelf( $item_object->itemnumber );
1670             }
1671
1672             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1673                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1674             }
1675
1676             # Record if item was lost
1677             my $was_lost = $item_object->itemlost;
1678
1679             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1680             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1681             $item_object->itemlost(0);
1682             $item_object->onloan($datedue->ymd());
1683             $item_object->datelastborrowed( dt_from_string()->ymd() );
1684             $item_object->datelastseen( dt_from_string()->ymd() );
1685             $item_object->store({log_action => 0});
1686
1687             # If the item was lost, it has now been found, charge the overdue if necessary
1688             if ($was_lost) {
1689                 if ( $item_object->{_charge} ) {
1690                     $actualissue //= Koha::Old::Checkouts->search(
1691                         { itemnumber => $item_unblessed->{itemnumber} },
1692                         {
1693                             order_by => { '-desc' => 'returndate' },
1694                             rows     => 1
1695                         }
1696                     )->single;
1697                     unless ( exists( $borrower->{branchcode} ) ) {
1698                         my $patron = $actualissue->patron;
1699                         $borrower = $patron->unblessed;
1700                     }
1701                     _CalculateAndUpdateFine(
1702                         {
1703                             issue       => $actualissue,
1704                             item        => $item_unblessed,
1705                             borrower    => $borrower,
1706                             return_date => $issuedate
1707                         }
1708                     );
1709                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1710                         $item_object->itemnumber, undef, 'RENEWED' );
1711                 }
1712             }
1713
1714             # If it costs to borrow this book, charge it to the patron's account.
1715             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1716             if ( $charge && $charge > 0 ) {
1717                 AddIssuingCharge( $issue, $charge, 'RENT' );
1718             }
1719
1720             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1721             if ( $itemtype_object ) {
1722                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1723                 if ( $accumulate_charge > 0 ) {
1724                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1725                     $charge += $accumulate_charge;
1726                     $item_unblessed->{charge} = $charge;
1727                 }
1728             }
1729
1730             # Record the fact that this book was issued.
1731             C4::Stats::UpdateStats(
1732                 {
1733                     branch => C4::Context->userenv->{'branch'},
1734                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1735                     amount         => $charge,
1736                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1737                     itemnumber     => $item_object->itemnumber,
1738                     itemtype       => $item_object->effective_itemtype,
1739                     location       => $item_object->location,
1740                     borrowernumber => $borrower->{'borrowernumber'},
1741                     ccode          => $item_object->ccode,
1742                 }
1743             );
1744
1745             # Send a checkout slip.
1746             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1747             my %conditions        = (
1748                 branchcode   => $branchcode,
1749                 categorycode => $borrower->{categorycode},
1750                 item_type    => $item_object->effective_itemtype,
1751                 notification => 'CHECKOUT',
1752             );
1753             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1754                 SendCirculationAlert(
1755                     {
1756                         type     => 'CHECKOUT',
1757                         item     => $item_object->unblessed,
1758                         borrower => $borrower,
1759                         branch   => $branchcode,
1760                     }
1761                 );
1762             }
1763             logaction(
1764                 "CIRCULATION", "ISSUE",
1765                 $borrower->{'borrowernumber'},
1766                 $item_object->itemnumber,
1767             ) if C4::Context->preference("IssueLog");
1768
1769             Koha::Plugins->call('after_circ_action', {
1770                 action  => 'checkout',
1771                 payload => {
1772                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1773                     checkout => $issue->get_from_storage
1774                 }
1775             });
1776         }
1777     }
1778     return $issue;
1779 }
1780
1781 =head2 GetLoanLength
1782
1783   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1784
1785 Get loan length for an itemtype, a borrower type and a branch
1786
1787 =cut
1788
1789 sub GetLoanLength {
1790     my ( $categorycode, $itemtype, $branchcode ) = @_;
1791
1792     # Initialize default values
1793     my $rules = {
1794         issuelength   => 0,
1795         renewalperiod => 0,
1796         lengthunit    => 'days',
1797     };
1798
1799     my $found = Koha::CirculationRules->get_effective_rules( {
1800         branchcode => $branchcode,
1801         categorycode => $categorycode,
1802         itemtype => $itemtype,
1803         rules => [
1804             'issuelength',
1805             'renewalperiod',
1806             'lengthunit'
1807         ],
1808     } );
1809
1810     # Search for rules!
1811     foreach my $rule_name (keys %$found) {
1812         $rules->{$rule_name} = $found->{$rule_name};
1813     }
1814
1815     return $rules;
1816 }
1817
1818
1819 =head2 GetHardDueDate
1820
1821   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1822
1823 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1824
1825 =cut
1826
1827 sub GetHardDueDate {
1828     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1829
1830     my $rules = Koha::CirculationRules->get_effective_rules(
1831         {
1832             categorycode => $borrowertype,
1833             itemtype     => $itemtype,
1834             branchcode   => $branchcode,
1835             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1836         }
1837     );
1838
1839     if ( defined( $rules->{hardduedate} ) ) {
1840         if ( $rules->{hardduedate} ) {
1841             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1842         }
1843         else {
1844             return ( undef, undef );
1845         }
1846     }
1847 }
1848
1849 =head2 GetBranchBorrowerCircRule
1850
1851   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1852
1853 Retrieves circulation rule attributes that apply to the given
1854 branch and patron category, regardless of item type.
1855 The return value is a hashref containing the following key:
1856
1857 patron_maxissueqty - maximum number of loans that a
1858 patron of the given category can have at the given
1859 branch.  If the value is undef, no limit.
1860
1861 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1862 patron of the given category can have at the given
1863 branch.  If the value is undef, no limit.
1864
1865 This will check for different branch/category combinations in the following order:
1866 branch and category
1867 branch only
1868 category only
1869 default branch and category
1870
1871 If no rule has been found in the database, it will default to
1872 the buillt in rule:
1873
1874 patron_maxissueqty - undef
1875 patron_maxonsiteissueqty - undef
1876
1877 C<$branchcode> and C<$categorycode> should contain the
1878 literal branch code and patron category code, respectively - no
1879 wildcards.
1880
1881 =cut
1882
1883 sub GetBranchBorrowerCircRule {
1884     my ( $branchcode, $categorycode ) = @_;
1885
1886     # Initialize default values
1887     my $rules = {
1888         patron_maxissueqty       => undef,
1889         patron_maxonsiteissueqty => undef,
1890     };
1891
1892     # Search for rules!
1893     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1894         my $rule = Koha::CirculationRules->get_effective_rule(
1895             {
1896                 categorycode => $categorycode,
1897                 itemtype     => undef,
1898                 branchcode   => $branchcode,
1899                 rule_name    => $rule_name,
1900             }
1901         );
1902
1903         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1904     }
1905
1906     return $rules;
1907 }
1908
1909 =head2 GetBranchItemRule
1910
1911   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1912
1913 Retrieves circulation rule attributes that apply to the given
1914 branch and item type, regardless of patron category.
1915
1916 The return value is a hashref containing the following keys:
1917
1918 holdallowed => Hold policy for this branch and itemtype. Possible values:
1919   not_allowed:           No holds allowed.
1920   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1921   from_any_library:      Holds allowed from any patron.
1922   from_local_hold_group: Holds allowed from libraries in hold group
1923
1924 returnbranch => branch to which to return item.  Possible values:
1925   noreturn: do not return, let item remain where checked in (floating collections)
1926   homebranch: return to item's home branch
1927   holdingbranch: return to issuer branch
1928
1929 This searches branchitemrules in the following order:
1930
1931   * Same branchcode and itemtype
1932   * Same branchcode, itemtype '*'
1933   * branchcode '*', same itemtype
1934   * branchcode and itemtype '*'
1935
1936 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1937
1938 =cut
1939
1940 sub GetBranchItemRule {
1941     my ( $branchcode, $itemtype ) = @_;
1942
1943     # Search for rules!
1944     my $rules = Koha::CirculationRules->get_effective_rules({
1945         branchcode => $branchcode,
1946         itemtype => $itemtype,
1947         rules => ['holdallowed', 'hold_fulfillment_policy', 'returnbranch']
1948     });
1949
1950     # built-in default circulation rule
1951     $rules->{holdallowed} //= 'from_any_library';
1952     $rules->{hold_fulfillment_policy} //= 'any';
1953     $rules->{returnbranch} //= 'homebranch';
1954
1955     return $rules;
1956 }
1957
1958 =head2 AddReturn
1959
1960   ($doreturn, $messages, $iteminformation, $borrower) =
1961       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1962
1963 Returns a book.
1964
1965 =over 4
1966
1967 =item C<$barcode> is the bar code of the book being returned.
1968
1969 =item C<$branch> is the code of the branch where the book is being returned.
1970
1971 =item C<$exemptfine> indicates that overdue charges for the item will be
1972 removed. Optional.
1973
1974 =item C<$return_date> allows the default return date to be overridden
1975 by the given return date. Optional.
1976
1977 =back
1978
1979 C<&AddReturn> returns a list of four items:
1980
1981 C<$doreturn> is true iff the return succeeded.
1982
1983 C<$messages> is a reference-to-hash giving feedback on the operation.
1984 The keys of the hash are:
1985
1986 =over 4
1987
1988 =item C<BadBarcode>
1989
1990 No item with this barcode exists. The value is C<$barcode>.
1991
1992 =item C<NotIssued>
1993
1994 The book is not currently on loan. The value is C<$barcode>.
1995
1996 =item C<withdrawn>
1997
1998 This book has been withdrawn/cancelled. The value should be ignored.
1999
2000 =item C<Wrongbranch>
2001
2002 This book has was returned to the wrong branch.  The value is a hashref
2003 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2004 contain the branchcode of the incorrect and correct return library, respectively.
2005
2006 =item C<ResFound>
2007
2008 The item was reserved. The value is a reference-to-hash whose keys are
2009 fields from the reserves table of the Koha database, and
2010 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2011 either C<Waiting>, C<Reserved>, or 0.
2012
2013 =item C<WasReturned>
2014
2015 Value 1 if return is successful.
2016
2017 =item C<NeedsTransfer>
2018
2019 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2020
2021 =item C<RecallFound>
2022
2023 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2024 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2025 branchcode.
2026
2027 =item C<TransferredRecall>
2028
2029 This item has been transferred to this branch to fill a recall. The recall object is returned.
2030
2031 =back
2032
2033 C<$iteminformation> is a reference-to-hash, giving information about the
2034 returned item from the issues table.
2035
2036 C<$borrower> is a reference-to-hash, giving information about the
2037 patron who last borrowed the book.
2038
2039 =cut
2040
2041 sub AddReturn {
2042     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2043
2044     if ($branch and not Koha::Libraries->find($branch)) {
2045         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2046         undef $branch;
2047     }
2048     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2049     my $return_date_specified = !!$return_date;
2050     $return_date //= dt_from_string();
2051     my $messages;
2052     my $patron;
2053     my $doreturn       = 1;
2054     my $validTransfer = 1;
2055     my $stat_type = 'return';
2056
2057     # get information on item
2058     my $item = Koha::Items->find({ barcode => $barcode });
2059     unless ($item) {
2060         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2061     }
2062
2063     my $itemnumber = $item->itemnumber;
2064     my $itemtype = $item->effective_itemtype;
2065
2066     my $issue  = $item->checkout;
2067     if ( $issue ) {
2068         $patron = $issue->patron
2069             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2070                 . Dumper($issue->unblessed) . "\n";
2071     } else {
2072         $messages->{'NotIssued'} = $barcode;
2073         $item->onloan(undef)->store({skip_record_index=>1}) if defined $item->onloan;
2074
2075         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2076         $doreturn = 0;
2077         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2078         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2079         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2080            $messages->{'LocalUse'} = 1;
2081            $stat_type = 'localuse';
2082         }
2083     }
2084
2085         # full item data, but no borrowernumber or checkout info (no issue)
2086     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
2087         # get the proper branch to which to return the item
2088     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2089         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2090     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2091
2092     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2093     my $patron_unblessed = $patron ? $patron->unblessed : {};
2094
2095     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2096     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2097     if ($update_loc_rules) {
2098         if (defined $update_loc_rules->{_ALL_}) {
2099             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2100             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2101             if (
2102                 ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) ||
2103                 (!defined $item->location && $update_loc_rules->{_ALL_} ne "")
2104                ) {
2105                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2106                 $item->location($update_loc_rules->{_ALL_})->store({skip_record_index=>1});
2107             }
2108         }
2109         else {
2110             foreach my $key ( keys %$update_loc_rules ) {
2111                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2112                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2113                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2114                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2115                     $item->location($update_loc_rules->{$key})->store({skip_record_index=>1});
2116                     last;
2117                 }
2118             }
2119         }
2120     }
2121
2122     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2123     if ($yaml) {
2124         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2125         my $rules;
2126         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2127         if ($@) {
2128             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2129         }
2130         else {
2131             foreach my $key ( keys %$rules ) {
2132                 if ( $item->notforloan eq $key ) {
2133                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2134                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
2135                     last;
2136                 }
2137             }
2138         }
2139     }
2140
2141     # check if the return is allowed at this branch
2142     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2143     unless ($returnallowed){
2144         $messages->{'Wrongbranch'} = {
2145             Wrongbranch => $branch,
2146             Rightbranch => $message
2147         };
2148         $doreturn = 0;
2149         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2150         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2151         return ( $doreturn, $messages, $issue, $patron_unblessed);
2152     }
2153
2154     if ( $item->withdrawn ) { # book has been cancelled
2155         $messages->{'withdrawn'} = 1;
2156         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2157     }
2158
2159     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2160         $doreturn = 0;
2161     }
2162
2163     # case of a return of document (deal with issues and holdingbranch)
2164     if ($doreturn) {
2165         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2166         $patron or warn "AddReturn without current borrower";
2167
2168         if ($patron) {
2169             eval {
2170                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1} );
2171             };
2172             unless ( $@ ) {
2173                 if (
2174                     (
2175                         C4::Context->preference('CalculateFinesOnReturn')
2176                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2177                     )
2178                     && !$item->itemlost
2179                   )
2180                 {
2181                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2182                 }
2183             } else {
2184                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2185
2186                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2187                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2188
2189                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2190             }
2191
2192             # FIXME is the "= 1" right?  This could be the borrower hash.
2193             $messages->{'WasReturned'} = 1;
2194
2195         } else {
2196             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1 });
2197         }
2198     }
2199
2200     # the holdingbranch is updated if the document is returned to another location.
2201     # this is always done regardless of whether the item was on loan or not
2202     if ($item->holdingbranch ne $branch) {
2203         $item->holdingbranch($branch)->store({ skip_record_index => 1 });
2204     }
2205
2206     my $item_was_lost = $item->itemlost;
2207     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2208     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1 } ); # will unset itemlost if needed
2209
2210     # fix up the accounts.....
2211     if ($item_was_lost) {
2212         $messages->{'WasLost'} = 1;
2213         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2214             my @object_messages = @{ $updated_item->object_messages };
2215             for my $message (@object_messages) {
2216                 $messages->{'LostItemFeeRefunded'} = 1
2217                   if $message->message eq 'lost_refunded';
2218                 $messages->{'LostItemFeeRestored'} = 1
2219                   if $message->message eq 'lost_restored';
2220
2221                 if ( $message->message eq 'lost_charge' ) {
2222                     $issue //= Koha::Old::Checkouts->search(
2223                         { itemnumber => $item->itemnumber },
2224                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2225                     )->single;
2226                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2227                         my $patron = $issue->patron;
2228                         $patron_unblessed = $patron->unblessed;
2229                     }
2230                     _CalculateAndUpdateFine(
2231                         {
2232                             issue       => $issue,
2233                             item        => $item->unblessed,
2234                             borrower    => $patron_unblessed,
2235                             return_date => $return_date
2236                         }
2237                     );
2238                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2239                         $item->itemnumber, undef, 'RETURNED' );
2240                     $messages->{'LostItemFeeCharged'} = 1;
2241                 }
2242             }
2243         }
2244     }
2245
2246     # check if we have a transfer for this document
2247     my $transfer = $item->get_transfer;
2248
2249     # if we have a transfer to complete, we update the line of transfers with the datearrived
2250     if ($transfer) {
2251         $validTransfer = 0;
2252         if ( $transfer->in_transit ) {
2253             if ( $transfer->tobranch eq $branch ) {
2254                 $transfer->receive;
2255                 $messages->{'TransferArrived'} = $transfer->frombranch;
2256                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2257                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2258             }
2259             else {
2260                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2261                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2262                 $messages->{'TransferTrigger'}   = $transfer->reason;
2263             }
2264         }
2265         else {
2266             if ( $transfer->tobranch eq $branch ) {
2267                 $transfer->receive;
2268                 $messages->{'TransferArrived'} = $transfer->frombranch;
2269                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2270                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2271             }
2272             else {
2273                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2274                 $messages->{'TransferTrigger'} = $transfer->reason;
2275             }
2276         }
2277     }
2278
2279     # fix up the overdues in accounts...
2280     if ($borrowernumber) {
2281         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2282         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2283
2284         if ( $issue and $issue->is_overdue($return_date) ) {
2285         # fix fine days
2286             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2287             if ($reminder){
2288                 $messages->{'PrevDebarred'} = $debardate;
2289             } else {
2290                 $messages->{'Debarred'} = $debardate if $debardate;
2291             }
2292         # there's no overdue on the item but borrower had been previously debarred
2293         } elsif ( $issue->date_due and $patron->debarred ) {
2294              if ( $patron->debarred eq "9999-12-31") {
2295                 $messages->{'ForeverDebarred'} = $patron->debarred;
2296              } else {
2297                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2298                   $borrower_debar_dt->truncate(to => 'day');
2299                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2300                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2301                       $messages->{'PrevDebarred'} = $patron->debarred;
2302                   }
2303              }
2304         }
2305     }
2306
2307     # find recalls...
2308     if ( C4::Context->preference('UseRecalls') ) {
2309         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2310         my $recall = undef;
2311         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2312         if ( defined $recall ) {
2313             $messages->{RecallFound} = $recall;
2314             if ( $recall->branchcode ne $branch ) {
2315                 $messages->{RecallNeedsTransfer} = $branch;
2316             }
2317         }
2318     }
2319
2320     # find reserves.....
2321     # launch the Checkreserves routine to find any holds
2322     my ($resfound, $resrec);
2323     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2324     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2325     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2326     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2327         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2328         $resfound = 'Reserved';
2329         $resrec = $hold->unblessed;
2330     }
2331     if ($resfound) {
2332           $resrec->{'ResFound'} = $resfound;
2333         $messages->{'ResFound'} = $resrec;
2334     }
2335
2336     # Record the fact that this book was returned.
2337     C4::Stats::UpdateStats({
2338         branch         => $branch,
2339         type           => $stat_type,
2340         itemnumber     => $itemnumber,
2341         itemtype       => $itemtype,
2342         location       => $item->location,
2343         borrowernumber => $borrowernumber,
2344         ccode          => $item->ccode,
2345     });
2346
2347     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2348     if ( $patron ) {
2349         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2350         my %conditions = (
2351             branchcode   => $branch,
2352             categorycode => $patron->categorycode,
2353             item_type    => $itemtype,
2354             notification => 'CHECKIN',
2355         );
2356         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2357             SendCirculationAlert({
2358                 type     => 'CHECKIN',
2359                 item     => $item->unblessed,
2360                 borrower => $patron->unblessed,
2361                 branch   => $branch,
2362                 issue    => $issue
2363             });
2364         }
2365
2366         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2367             if C4::Context->preference("ReturnLog");
2368         }
2369
2370     # Check if this item belongs to a biblio record that is attached to an
2371     # ILL request, if it is we need to update the ILL request's status
2372     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2373         my $request = Koha::Illrequests->find(
2374             { biblio_id => $item->biblio->biblionumber }
2375         );
2376         $request->status('RET') if $request;
2377     }
2378
2379     if ( C4::Context->preference('UseRecalls') ) {
2380         # all recalls that have triggered a transfer will have an allocated itemnumber
2381         my $transfer_recall = Koha::Recalls->find({ itemnumber => $item->itemnumber, status => 'in_transit' });
2382         if ( $transfer_recall and $transfer_recall->branchcode eq $branch ) {
2383             $messages->{TransferredRecall} = $transfer_recall;
2384         }
2385     }
2386
2387     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2388     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2389         && ( $doreturn or $messages->{'NotIssued'} )
2390         and !$resfound
2391         and ( $branch ne $returnbranch )
2392         and not $messages->{'WrongTransfer'}
2393         and not $messages->{'WasTransfered'}
2394         and not $messages->{TransferredRecall}
2395         and not $messages->{RecallNeedsTransfer} )
2396     {
2397         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2398         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2399             (C4::Context->preference("UseBranchTransferLimits") and
2400              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2401            )) {
2402             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2403             $messages->{'WasTransfered'} = $returnbranch;
2404             $messages->{'TransferTrigger'} = $transfer_trigger;
2405         } else {
2406             $messages->{'NeedsTransfer'} = $returnbranch;
2407             $messages->{'TransferTrigger'} = $transfer_trigger;
2408         }
2409     }
2410
2411     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2412         my $claims = Koha::Checkouts::ReturnClaims->search(
2413            {
2414                itemnumber => $item->id,
2415                resolution => undef,
2416            }
2417         );
2418
2419         if ( $claims->count ) {
2420             $messages->{ReturnClaims} = $claims;
2421         }
2422     }
2423
2424     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2425     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2426
2427     if ( $doreturn and $issue ) {
2428         my $checkin = Koha::Old::Checkouts->find($issue->id);
2429
2430         Koha::Plugins->call('after_circ_action', {
2431             action  => 'checkin',
2432             payload => {
2433                 checkout=> $checkin
2434             }
2435         });
2436     }
2437
2438     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2439 }
2440
2441 =head2 MarkIssueReturned
2442
2443   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2444
2445 Unconditionally marks an issue as being returned by
2446 moving the C<issues> row to C<old_issues> and
2447 setting C<returndate> to the current date.
2448
2449 if C<$returndate> is specified (in iso format), it is used as the date
2450 of the return.
2451
2452 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2453 the old_issue is immediately anonymised
2454
2455 Ideally, this function would be internal to C<C4::Circulation>,
2456 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2457 and offline_circ/process_koc.pl.
2458
2459 The last optional parameter allos passing skip_record_index to the item store call.
2460
2461 =cut
2462
2463 sub MarkIssueReturned {
2464     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2465
2466     # Retrieve the issue
2467     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2468
2469     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2470
2471     my $issue_id = $issue->issue_id;
2472
2473     my $schema = Koha::Database->schema;
2474
2475     # FIXME Improve the return value and handle it from callers
2476     $schema->txn_do(sub {
2477
2478         my $patron = Koha::Patrons->find( $borrowernumber );
2479
2480         # Update the returndate value
2481         if ( $returndate ) {
2482             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2483         }
2484         else {
2485             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2486         }
2487
2488         # Create the old_issues entry
2489         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2490
2491         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2492         if ( $privacy && $privacy == 2) {
2493             $old_checkout->anonymize;
2494         }
2495
2496         # And finally delete the issue
2497         $issue->delete;
2498
2499         $issue->item->onloan(undef)->store({ log_action => 0, skip_record_index => $params->{skip_record_index} });
2500
2501         if ( C4::Context->preference('StoreLastBorrower') ) {
2502             my $item = Koha::Items->find( $itemnumber );
2503             $item->last_returned_by( $patron );
2504         }
2505
2506         # Remove any OVERDUES related debarment if the borrower has no overdues
2507         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2508           && $patron->debarred
2509           && !$patron->has_overdues
2510           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2511         ) {
2512             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2513         }
2514
2515     });
2516
2517     return $issue_id;
2518 }
2519
2520 =head2 _debar_user_on_return
2521
2522     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2523
2524 C<$borrower> borrower hashref
2525
2526 C<$item> item hashref
2527
2528 C<$datedue> date due DateTime object
2529
2530 C<$returndate> DateTime object representing the return time
2531
2532 Internal function, called only by AddReturn that calculates and updates
2533  the user fine days, and debars them if necessary.
2534
2535 Should only be called for overdue returns
2536
2537 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2538 to ease testing.
2539
2540 =cut
2541
2542 sub _calculate_new_debar_dt {
2543     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2544
2545     my $branchcode = _GetCircControlBranch( $item, $borrower );
2546     my $circcontrol = C4::Context->preference('CircControl');
2547     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2548         {   categorycode => $borrower->{categorycode},
2549             itemtype     => $item->{itype},
2550             branchcode   => $branchcode,
2551             rules => [
2552                 'finedays',
2553                 'lengthunit',
2554                 'firstremind',
2555                 'maxsuspensiondays',
2556                 'suspension_chargeperiod',
2557             ]
2558         }
2559     );
2560     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2561     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2562     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2563
2564     return unless $finedays;
2565
2566     # finedays is in days, so hourly loans must multiply by 24
2567     # thus 1 hour late equals 1 day suspension * finedays rate
2568     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2569
2570     # grace period is measured in the same units as the loan
2571     my $grace =
2572       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2573
2574     my $deltadays = DateTime::Duration->new(
2575         days => $chargeable_units
2576     );
2577
2578     if ( $deltadays->subtract($grace)->is_positive() ) {
2579         my $suspension_days = $deltadays * $finedays;
2580
2581         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2582             # No need to / 1 and do not consider / 0
2583             $suspension_days = DateTime::Duration->new(
2584                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2585             );
2586         }
2587
2588         # If the max suspension days is < than the suspension days
2589         # the suspension days is limited to this maximum period.
2590         my $max_sd = $issuing_rule->{maxsuspensiondays};
2591         if ( defined $max_sd && $max_sd ne '' ) {
2592             $max_sd = DateTime::Duration->new( days => $max_sd );
2593             $suspension_days = $max_sd
2594               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2595         }
2596
2597         my ( $has_been_extended );
2598         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2599             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2600             if ( $debarment ) {
2601                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2602                 $has_been_extended = 1;
2603             }
2604         }
2605
2606         my $new_debar_dt;
2607         # Use the calendar or not to calculate the debarment date
2608         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2609             my $calendar = Koha::Calendar->new(
2610                 branchcode => $branchcode,
2611                 days_mode  => 'Calendar'
2612             );
2613             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2614         }
2615         else {
2616             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2617         }
2618         return $new_debar_dt;
2619     }
2620     return;
2621 }
2622
2623 sub _debar_user_on_return {
2624     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2625
2626     $return_date //= dt_from_string();
2627
2628     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2629
2630     return unless $new_debar_dt;
2631
2632     Koha::Patron::Debarments::AddUniqueDebarment({
2633         borrowernumber => $borrower->{borrowernumber},
2634         expiration     => $new_debar_dt->ymd(),
2635         type           => 'SUSPENSION',
2636     });
2637     # if borrower was already debarred but does not get an extra debarment
2638     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2639     my ($new_debarment_str, $is_a_reminder);
2640     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2641         $is_a_reminder = 1;
2642         $new_debarment_str = $borrower->{debarred};
2643     } else {
2644         $new_debarment_str = $new_debar_dt->ymd();
2645     }
2646     # FIXME Should return a DateTime object
2647     return $new_debarment_str, $is_a_reminder;
2648 }
2649
2650 =head2 _FixOverduesOnReturn
2651
2652    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2653
2654 C<$borrowernumber> borrowernumber
2655
2656 C<$itemnumber> itemnumber
2657
2658 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2659
2660 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2661
2662 Internal function
2663
2664 =cut
2665
2666 sub _FixOverduesOnReturn {
2667     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2668     unless( $borrowernumber ) {
2669         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2670         return;
2671     }
2672     unless( $item ) {
2673         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2674         return;
2675     }
2676     unless( $status ) {
2677         warn "_FixOverduesOnReturn() not supplied valid status";
2678         return;
2679     }
2680
2681     my $schema = Koha::Database->schema;
2682
2683     my $result = $schema->txn_do(
2684         sub {
2685             # check for overdue fine
2686             my $accountlines = Koha::Account::Lines->search(
2687                 {
2688                     borrowernumber  => $borrowernumber,
2689                     itemnumber      => $item,
2690                     debit_type_code => 'OVERDUE',
2691                     status          => 'UNRETURNED'
2692                 }
2693             );
2694             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2695
2696             my $accountline = $accountlines->next;
2697             my $payments = $accountline->credits;
2698
2699             my $amountoutstanding = $accountline->amountoutstanding;
2700             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2701                 $accountline->delete;
2702                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2703             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2704                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2705                 my $credit = $account->add_credit(
2706                     {
2707                         amount     => $amountoutstanding,
2708                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2709                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2710                         interface  => C4::Context->interface,
2711                         type       => 'FORGIVEN',
2712                         item_id    => $item
2713                     }
2714                 );
2715
2716                 $credit->apply({ debits => [ $accountline ] });
2717
2718                 if (C4::Context->preference("FinesLog")) {
2719                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2720                 }
2721             }
2722
2723             $accountline->status($status);
2724             return $accountline->store();
2725         }
2726     );
2727
2728     return $result;
2729 }
2730
2731 =head2 _GetCircControlBranch
2732
2733    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2734
2735 Internal function :
2736
2737 Return the library code to be used to determine which circulation
2738 policy applies to a transaction.  Looks up the CircControl and
2739 HomeOrHoldingBranch system preferences.
2740
2741 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2742
2743 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2744
2745 =cut
2746
2747 sub _GetCircControlBranch {
2748     my ($item, $borrower) = @_;
2749     my $circcontrol = C4::Context->preference('CircControl');
2750     my $branch;
2751
2752     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2753         $branch= C4::Context->userenv->{'branch'};
2754     } elsif ($circcontrol eq 'PatronLibrary') {
2755         $branch=$borrower->{branchcode};
2756     } else {
2757         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2758         $branch = $item->{$branchfield};
2759         # default to item home branch if holdingbranch is used
2760         # and is not defined
2761         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2762             $branch = $item->{homebranch};
2763         }
2764     }
2765     return $branch;
2766 }
2767
2768 =head2 GetOpenIssue
2769
2770   $issue = GetOpenIssue( $itemnumber );
2771
2772 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2773
2774 C<$itemnumber> is the item's itemnumber
2775
2776 Returns a hashref
2777
2778 =cut
2779
2780 sub GetOpenIssue {
2781   my ( $itemnumber ) = @_;
2782   return unless $itemnumber;
2783   my $dbh = C4::Context->dbh;
2784   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2785   $sth->execute( $itemnumber );
2786   return $sth->fetchrow_hashref();
2787
2788 }
2789
2790 =head2 GetUpcomingDueIssues
2791
2792   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2793
2794 =cut
2795
2796 sub GetUpcomingDueIssues {
2797     my $params = shift;
2798
2799     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2800     my $dbh = C4::Context->dbh;
2801     my $statement;
2802     $statement = q{
2803         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2804         FROM issues
2805         LEFT JOIN items USING (itemnumber)
2806         LEFT JOIN branches ON branches.branchcode =
2807     };
2808     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2809     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2810     my @bind_parameters = ( $params->{'days_in_advance'} );
2811
2812     my $sth = $dbh->prepare( $statement );
2813     $sth->execute( @bind_parameters );
2814     my $upcoming_dues = $sth->fetchall_arrayref({});
2815
2816     return $upcoming_dues;
2817 }
2818
2819 =head2 CanBookBeRenewed
2820
2821   ($ok,$error,$info) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2822
2823 Find out whether a borrowed item may be renewed.
2824
2825 C<$borrowernumber> is the borrower number of the patron who currently
2826 has the item on loan.
2827
2828 C<$itemnumber> is the number of the item to renew.
2829
2830 C<$override_limit>, if supplied with a true value, causes
2831 the limit on the number of times that the loan can be renewed
2832 (as controlled by the item type) to be ignored. Overriding also allows
2833 to renew sooner than "No renewal before" and to manually renew loans
2834 that are automatically renewed.
2835
2836 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2837 item must currently be on loan to the specified borrower; renewals
2838 must be allowed for the item's type; and the borrower must not have
2839 already renewed the loan.
2840     $error will contain the reason the renewal can not proceed
2841     $info will contain the soonest renewal date if the error is 'too soon'
2842
2843 =cut
2844
2845 sub CanBookBeRenewed {
2846     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2847
2848     my $auto_renew = "no";
2849     my $soonest;
2850
2851     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2852     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2853     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2854     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2855
2856     my $patron = $issue->patron or return;
2857
2858     # override_limit will override anything else except on_reserve
2859     unless ( $override_limit ){
2860         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2861         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2862             {
2863                 categorycode => $patron->categorycode,
2864                 itemtype     => $item->effective_itemtype,
2865                 branchcode   => $branchcode,
2866                 rules => [
2867                     'renewalsallowed',
2868                     'lengthunit',
2869                     'unseen_renewals_allowed'
2870                 ]
2871             }
2872         );
2873
2874         return ( 0, "too_many" )
2875           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2876
2877         return ( 0, "too_unseen" )
2878           if C4::Context->preference('UnseenRenewals') &&
2879             $issuing_rule->{unseen_renewals_allowed} &&
2880             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2881
2882         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2883         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2884         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2885         my $restricted  = $patron->is_debarred;
2886         my $hasoverdues = $patron->has_overdues;
2887
2888         if ( $restricted and $restrictionblockrenewing ) {
2889             return ( 0, 'restriction');
2890         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2891             return ( 0, 'overdue');
2892         }
2893
2894         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
2895             patron     => $patron,
2896             item       => $item,
2897             branchcode => $branchcode,
2898             issue      => $issue
2899         });
2900         return ( 0, $auto_renew, $soonest ) if $auto_renew =~ 'auto_too_soon' && $cron;
2901         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
2902         # extra notices being sent. Cron also implies no override
2903         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
2904         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
2905         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
2906     }
2907
2908     if ( C4::Context->preference('UseRecalls') ) {
2909         my $recall = undef;
2910         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2911         if ( defined $recall ) {
2912             if ( $recall->item_level_recall ) {
2913                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
2914                 return ( 0, 'recalled' ) if ( $recall->itemnumber == $item->itemnumber );
2915             } else {
2916                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
2917                 return ( 0, 'recalled' ) unless ( $recall->waiting );
2918             }
2919         }
2920     }
2921
2922     # Note: possible_reserves will contain all title level holds on this bib and item level
2923     # holds on the checked out item
2924     my ( $resfound, $resrec, $possible_reserves ) = C4::Reserves::CheckReserves($itemnumber);
2925
2926     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2927     if ( $resfound && $resrec->{non_priority} ) {
2928         $resfound = Koha::Holds->search(
2929             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2930           ->count > 0;
2931     }
2932
2933
2934
2935     # This item can fill one or more unfilled reserve, can those unfilled reserves
2936     # all be filled by other available items?
2937     if ( $resfound
2938         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2939     {
2940         my $item_holds = Koha::Holds->search( { itemnumber => $itemnumber, found => undef } )->count();
2941         if ($item_holds) {
2942             # There is an item level hold on this item, no other item can fill the hold
2943             $resfound = 1;
2944         }
2945         else {
2946
2947             # Get all other items that could possibly fill reserves
2948             # FIXME We could join reserves (or more tables) here to eliminate some checks later
2949             my $items = Koha::Items->search({
2950                 biblionumber => $resrec->{biblionumber},
2951                 onloan       => undef,
2952                 notforloan   => 0,
2953                 -not         => { itemnumber => $itemnumber }
2954             });
2955             my $item_count = $items->count();
2956
2957             # Get all other reserves that could have been filled by this item
2958             my @borrowernumbers = map { $_->{borrowernumber} } @$possible_reserves;
2959             # Note: fetching the patrons in this manner means that a patron with 2 holds will
2960             # not block renewal if one reserve can be satisfied i.e. each patron is checked once
2961             my $patrons = Koha::Patrons->search({
2962                 borrowernumber => { -in => \@borrowernumbers }
2963             });
2964             my $patron_count = $patrons->count();
2965
2966             return ( 0, "on_reserve" ) if ($patron_count > $item_count);
2967             # We cannot possibly fill all reserves if we don't have enough items
2968
2969             # If we can fill each hold that has been found with the available items on the record
2970             # then the patron can renew. If we cannot, they cannot renew.
2971             # FIXME This code does not check whether the item we are renewing can fill
2972             # any of the existing reserves.
2973             my $reservable = 0;
2974             my %matched_items;
2975             my $seen = 0;
2976             PATRON: while ( my $patron = $patrons->next ) {
2977                 # If there is a reserve that cannot be filled we are done
2978                 return ( 0, "on_reserve" ) if ( $seen > $reservable );
2979                 my $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron });
2980                 while ( my $other_item = $items->next ) {
2981                     next if defined $matched_items{$other_item->itemnumber};
2982                     next if IsItemOnHoldAndFound( $other_item->itemnumber );
2983                     next unless IsAvailableForItemLevelRequest($other_item, $patron, undef, $items_any_available);
2984                     next unless CanItemBeReserved($patron,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
2985                     # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
2986                     # CanItemBeReserved checks 'rules' and 'policies' which means
2987                     # items will fill holds at checkin that are rejected here
2988                     $reservable++;
2989                     if ($reservable >= $patron_count) {
2990                         $resfound = 0;
2991                         last PATRON;
2992                     }
2993                     $matched_items{$other_item->itemnumber} = 1;
2994                     last;
2995                 }
2996                 $items->reset;
2997                 $seen++;
2998             }
2999         }
3000     }
3001
3002     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
3003     return ( 0, $auto_renew, $soonest ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
3004     $soonest = GetSoonestRenewDate($borrowernumber, $itemnumber);
3005     if ( $soonest > dt_from_string() ){
3006         return (0, "too_soon", $soonest ) unless $override_limit;
3007     }
3008
3009     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
3010
3011     return ( 1, undef );
3012 }
3013
3014 =head2 AddRenewal
3015
3016   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
3017
3018 Renews a loan.
3019
3020 C<$borrowernumber> is the borrower number of the patron who currently
3021 has the item.
3022
3023 C<$itemnumber> is the number of the item to renew.
3024
3025 C<$branch> is the library where the renewal took place (if any).
3026            The library that controls the circ policies for the renewal is retrieved from the issues record.
3027
3028 C<$datedue> can be a DateTime object used to set the due date.
3029
3030 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3031 this parameter is not supplied, lastreneweddate is set to the current date.
3032
3033 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3034 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3035 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3036 syspref)
3037
3038 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3039 from the book's item type.
3040
3041 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3042 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3043 fallback to a true value
3044
3045 =cut
3046
3047 sub AddRenewal {
3048     my $borrowernumber  = shift;
3049     my $itemnumber      = shift or return;
3050     my $branch          = shift;
3051     my $datedue         = shift;
3052     my $lastreneweddate = shift || dt_from_string();
3053     my $skipfinecalc    = shift;
3054     my $seen            = shift;
3055
3056     # Fallback on a 'seen' renewal
3057     $seen = defined $seen && $seen == 0 ? 0 : 1;
3058
3059     my $item_object   = Koha::Items->find($itemnumber) or return;
3060     my $biblio = $item_object->biblio;
3061     my $issue  = $item_object->checkout;
3062     my $item_unblessed = $item_object->unblessed;
3063
3064     my $dbh = C4::Context->dbh;
3065
3066     return unless $issue;
3067
3068     $borrowernumber ||= $issue->borrowernumber;
3069
3070     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3071         carp 'Invalid date passed to AddRenewal.';
3072         return;
3073     }
3074
3075     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3076     my $patron_unblessed = $patron->unblessed;
3077
3078     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3079
3080     my $schema = Koha::Database->schema;
3081     $schema->txn_do(sub{
3082
3083         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3084             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3085         }
3086         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3087
3088         # If the due date wasn't specified, calculate it by adding the
3089         # book's loan length to today's date or the current due date
3090         # based on the value of the RenewalPeriodBase syspref.
3091         my $itemtype = $item_object->effective_itemtype;
3092         unless ($datedue) {
3093
3094             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3095                                             dt_from_string( $issue->date_due, 'sql' ) :
3096                                             dt_from_string();
3097             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3098         }
3099
3100         my $fees = Koha::Charges::Fees->new(
3101             {
3102                 patron    => $patron,
3103                 library   => $circ_library,
3104                 item      => $item_object,
3105                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3106                 to_date   => dt_from_string($datedue),
3107             }
3108         );
3109
3110         # Increment the unseen renewals, if appropriate
3111         # We only do so if the syspref is enabled and
3112         # a maximum value has been set in the circ rules
3113         my $unseen_renewals = $issue->unseen_renewals;
3114         if (C4::Context->preference('UnseenRenewals')) {
3115             my $rule = Koha::CirculationRules->get_effective_rule(
3116                 {   categorycode => $patron->categorycode,
3117                     itemtype     => $item_object->effective_itemtype,
3118                     branchcode   => $circ_library->branchcode,
3119                     rule_name    => 'unseen_renewals_allowed'
3120                 }
3121             );
3122             if (!$seen && $rule && $rule->rule_value) {
3123                 $unseen_renewals++;
3124             } else {
3125                 # If the renewal is seen, unseen should revert to 0
3126                 $unseen_renewals = 0;
3127             }
3128         }
3129
3130         # Update the issues record to have the new due date, and a new count
3131         # of how many times it has been renewed.
3132         my $renews = ( $issue->renewals || 0 ) + 1;
3133         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3134
3135         eval{
3136             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3137         };
3138         if( $sth->err ){
3139             Koha::Exceptions::Checkout::FailedRenewal->throw(
3140                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3141             );
3142         }
3143
3144         # Update the renewal count on the item, and tell zebra to reindex
3145         $renews = ( $item_object->renewals || 0 ) + 1;
3146         $item_object->renewals($renews);
3147         $item_object->onloan($datedue);
3148         $item_object->store({ log_action => 0 });
3149
3150         # Charge a new rental fee, if applicable
3151         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3152         if ( $charge > 0 ) {
3153             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3154         }
3155
3156         # Charge a new accumulate rental fee, if applicable
3157         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3158         if ( $itemtype_object ) {
3159             my $accumulate_charge = $fees->accumulate_rentalcharge();
3160             if ( $accumulate_charge > 0 ) {
3161                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3162             }
3163             $charge += $accumulate_charge;
3164         }
3165
3166         # Send a renewal slip according to checkout alert preferencei
3167         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3168             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3169             my %conditions        = (
3170                 branchcode   => $branch,
3171                 categorycode => $patron->categorycode,
3172                 item_type    => $itemtype,
3173                 notification => 'CHECKOUT',
3174             );
3175             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3176                 SendCirculationAlert(
3177                     {
3178                         type     => 'RENEWAL',
3179                         item     => $item_unblessed,
3180                         borrower => $patron->unblessed,
3181                         branch   => $branch,
3182                     }
3183                 );
3184             }
3185         }
3186
3187         # Remove any OVERDUES related debarment if the borrower has no overdues
3188         if ( $patron
3189           && $patron->is_debarred
3190           && ! $patron->has_overdues
3191           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3192         ) {
3193             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3194         }
3195
3196         # Add the renewal to stats
3197         C4::Stats::UpdateStats(
3198             {
3199                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3200                 type           => 'renew',
3201                 amount         => $charge,
3202                 itemnumber     => $itemnumber,
3203                 itemtype       => $itemtype,
3204                 location       => $item_object->location,
3205                 borrowernumber => $borrowernumber,
3206                 ccode          => $item_object->ccode,
3207             }
3208         );
3209
3210         #Log the renewal
3211         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3212
3213         Koha::Plugins->call('after_circ_action', {
3214             action  => 'renewal',
3215             payload => {
3216                 checkout  => $issue->get_from_storage
3217             }
3218         });
3219     });
3220
3221     return $datedue;
3222 }
3223
3224 sub GetRenewCount {
3225     # check renewal status
3226     my ( $bornum, $itemno ) = @_;
3227     my $dbh           = C4::Context->dbh;
3228     my $renewcount    = 0;
3229     my $unseencount    = 0;
3230     my $renewsallowed = 0;
3231     my $unseenallowed = 0;
3232     my $renewsleft    = 0;
3233     my $unseenleft    = 0;
3234
3235     my $patron = Koha::Patrons->find( $bornum );
3236     my $item   = Koha::Items->find($itemno);
3237
3238     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3239
3240     # Look in the issues table for this item, lent to this borrower,
3241     # and not yet returned.
3242
3243     # FIXME - I think this function could be redone to use only one SQL call.
3244     my $sth = $dbh->prepare(
3245         "select * from issues
3246                                 where (borrowernumber = ?)
3247                                 and (itemnumber = ?)"
3248     );
3249     $sth->execute( $bornum, $itemno );
3250     my $data = $sth->fetchrow_hashref;
3251     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3252     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3253     # $item and $borrower should be calculated
3254     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3255
3256     my $rules = Koha::CirculationRules->get_effective_rules(
3257         {
3258             categorycode => $patron->categorycode,
3259             itemtype     => $item->effective_itemtype,
3260             branchcode   => $branchcode,
3261             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3262         }
3263     );
3264     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3265     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3266         $rules->{unseen_renewals_allowed} :
3267         0;
3268     $renewsleft    = $renewsallowed - $renewcount;
3269     $unseenleft    = $unseenallowed - $unseencount;
3270     if($renewsleft < 0){ $renewsleft = 0; }
3271     if($unseenleft < 0){ $unseenleft = 0; }
3272     return (
3273         $renewcount,
3274         $renewsallowed,
3275         $renewsleft,
3276         $unseencount,
3277         $unseenallowed,
3278         $unseenleft
3279     );
3280 }
3281
3282 =head2 GetSoonestRenewDate
3283
3284   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3285
3286 Find out the soonest possible renew date of a borrowed item.
3287
3288 C<$borrowernumber> is the borrower number of the patron who currently
3289 has the item on loan.
3290
3291 C<$itemnumber> is the number of the item to renew.
3292
3293 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3294 renew date, based on the value "No renewal before" of the applicable
3295 issuing rule. Returns the current date if the item can already be
3296 renewed, and returns undefined if the borrower, loan, or item
3297 cannot be found.
3298
3299 =cut
3300
3301 sub GetSoonestRenewDate {
3302     my ( $borrowernumber, $itemnumber ) = @_;
3303
3304     my $dbh = C4::Context->dbh;
3305
3306     my $item      = Koha::Items->find($itemnumber)      or return;
3307     my $itemissue = $item->checkout or return;
3308
3309     $borrowernumber ||= $itemissue->borrowernumber;
3310     my $patron = Koha::Patrons->find( $borrowernumber )
3311       or return;
3312
3313     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3314     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3315         {   categorycode => $patron->categorycode,
3316             itemtype     => $item->effective_itemtype,
3317             branchcode   => $branchcode,
3318             rules => [
3319                 'norenewalbefore',
3320                 'lengthunit',
3321             ]
3322         }
3323     );
3324
3325     my $now = dt_from_string;
3326
3327     if ( defined $issuing_rule->{norenewalbefore}
3328         and $issuing_rule->{norenewalbefore} ne "" )
3329     {
3330         my $soonestrenewal =
3331           dt_from_string( $itemissue->date_due )->subtract(
3332             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3333
3334         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3335             and $issuing_rule->{lengthunit} eq 'days' )
3336         {
3337             $soonestrenewal->truncate( to => 'day' );
3338         }
3339         return $soonestrenewal if $now < $soonestrenewal;
3340     } elsif ( $itemissue->auto_renew && $patron->autorenew_checkouts ) {
3341         # Checkouts with auto-renewing fall back to due date
3342         my $soonestrenewal = dt_from_string( $itemissue->date_due );
3343         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3344             and $issuing_rule->{lengthunit} eq 'days' )
3345         {
3346             $soonestrenewal->truncate( to => 'day' );
3347         }
3348         return $soonestrenewal;
3349     }
3350     return $now;
3351 }
3352
3353 =head2 GetLatestAutoRenewDate
3354
3355   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3356
3357 Find out the latest possible auto renew date of a borrowed item.
3358
3359 C<$borrowernumber> is the borrower number of the patron who currently
3360 has the item on loan.
3361
3362 C<$itemnumber> is the number of the item to renew.
3363
3364 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3365 auto renew date, based on the value "No auto renewal after" and the "No auto
3366 renewal after (hard limit) of the applicable issuing rule.
3367 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3368 or item cannot be found.
3369
3370 =cut
3371
3372 sub GetLatestAutoRenewDate {
3373     my ( $borrowernumber, $itemnumber ) = @_;
3374
3375     my $dbh = C4::Context->dbh;
3376
3377     my $item      = Koha::Items->find($itemnumber)  or return;
3378     my $itemissue = $item->checkout                 or return;
3379
3380     $borrowernumber ||= $itemissue->borrowernumber;
3381     my $patron = Koha::Patrons->find( $borrowernumber )
3382       or return;
3383
3384     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3385     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3386         {
3387             categorycode => $patron->categorycode,
3388             itemtype     => $item->effective_itemtype,
3389             branchcode   => $branchcode,
3390             rules => [
3391                 'no_auto_renewal_after',
3392                 'no_auto_renewal_after_hard_limit',
3393                 'lengthunit',
3394             ]
3395         }
3396     );
3397
3398     return unless $circulation_rules;
3399     return
3400       if ( not $circulation_rules->{no_auto_renewal_after}
3401             or $circulation_rules->{no_auto_renewal_after} eq '' )
3402       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3403              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3404
3405     my $maximum_renewal_date;
3406     if ( $circulation_rules->{no_auto_renewal_after} ) {
3407         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3408         $maximum_renewal_date->add(
3409             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3410         );
3411     }
3412
3413     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3414         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3415         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3416     }
3417     return $maximum_renewal_date;
3418 }
3419
3420
3421 =head2 GetIssuingCharges
3422
3423   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3424
3425 Calculate how much it would cost for a given patron to borrow a given
3426 item, including any applicable discounts.
3427
3428 C<$itemnumber> is the item number of item the patron wishes to borrow.
3429
3430 C<$borrowernumber> is the patron's borrower number.
3431
3432 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3433 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3434 if it's a video).
3435
3436 =cut
3437
3438 sub GetIssuingCharges {
3439
3440     # calculate charges due
3441     my ( $itemnumber, $borrowernumber ) = @_;
3442     my $charge = 0;
3443     my $dbh    = C4::Context->dbh;
3444     my $item_type;
3445
3446     # Get the book's item type and rental charge (via its biblioitem).
3447     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3448         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3449     $charge_query .= (C4::Context->preference('item-level_itypes'))
3450         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3451         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3452
3453     $charge_query .= ' WHERE items.itemnumber =?';
3454
3455     my $sth = $dbh->prepare($charge_query);
3456     $sth->execute($itemnumber);
3457     if ( my $item_data = $sth->fetchrow_hashref ) {
3458         $item_type = $item_data->{itemtype};
3459         $charge    = $item_data->{rentalcharge};
3460         if ($charge) {
3461             # FIXME This should follow CircControl
3462             my $branch = C4::Context::mybranch();
3463             my $patron = Koha::Patrons->find( $borrowernumber );
3464             my $discount = Koha::CirculationRules->get_effective_rule({
3465                 categorycode => $patron->categorycode,
3466                 branchcode   => $branch,
3467                 itemtype     => $item_type,
3468                 rule_name    => 'rentaldiscount'
3469             });
3470             if ($discount) {
3471                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3472             }
3473             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3474         }
3475     }
3476
3477     return ( $charge, $item_type );
3478 }
3479
3480 =head2 AddIssuingCharge
3481
3482   &AddIssuingCharge( $checkout, $charge, $type )
3483
3484 =cut
3485
3486 sub AddIssuingCharge {
3487     my ( $checkout, $charge, $type ) = @_;
3488
3489     # FIXME What if checkout does not exist?
3490
3491     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3492     my $accountline = $account->add_debit(
3493         {
3494             amount      => $charge,
3495             note        => undef,
3496             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3497             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3498             interface   => C4::Context->interface,
3499             type        => $type,
3500             item_id     => $checkout->itemnumber,
3501             issue_id    => $checkout->issue_id,
3502         }
3503     );
3504 }
3505
3506 =head2 GetTransfers
3507
3508   GetTransfers($itemnumber);
3509
3510 =cut
3511
3512 sub GetTransfers {
3513     my ($itemnumber) = @_;
3514
3515     my $dbh = C4::Context->dbh;
3516
3517     my $query = '
3518         SELECT datesent,
3519                frombranch,
3520                tobranch,
3521                branchtransfer_id,
3522                daterequested,
3523                reason
3524         FROM branchtransfers
3525         WHERE itemnumber = ?
3526           AND datearrived IS NULL
3527           AND datecancelled IS NULL
3528         ';
3529     my $sth = $dbh->prepare($query);
3530     $sth->execute($itemnumber);
3531     my @row = $sth->fetchrow_array();
3532     return @row;
3533 }
3534
3535 =head2 GetTransfersFromTo
3536
3537   @results = GetTransfersFromTo($frombranch,$tobranch);
3538
3539 Returns the list of pending transfers between $from and $to branch
3540
3541 =cut
3542
3543 sub GetTransfersFromTo {
3544     my ( $frombranch, $tobranch ) = @_;
3545     return unless ( $frombranch && $tobranch );
3546     my $dbh   = C4::Context->dbh;
3547     my $query = "
3548         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3549         FROM   branchtransfers
3550         WHERE  frombranch=?
3551           AND  tobranch=?
3552           AND datecancelled IS NULL
3553           AND datesent IS NOT NULL
3554           AND datearrived IS NULL
3555     ";
3556     my $sth = $dbh->prepare($query);
3557     $sth->execute( $frombranch, $tobranch );
3558     my @gettransfers;
3559
3560     while ( my $data = $sth->fetchrow_hashref ) {
3561         push @gettransfers, $data;
3562     }
3563     return (@gettransfers);
3564 }
3565
3566 =head2 SendCirculationAlert
3567
3568 Send out a C<check-in> or C<checkout> alert using the messaging system.
3569
3570 B<Parameters>:
3571
3572 =over 4
3573
3574 =item type
3575
3576 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3577
3578 =item item
3579
3580 Hashref of information about the item being checked in or out.
3581
3582 =item borrower
3583
3584 Hashref of information about the borrower of the item.
3585
3586 =item branch
3587
3588 The branchcode from where the checkout or check-in took place.
3589
3590 =back
3591
3592 B<Example>:
3593
3594     SendCirculationAlert({
3595         type     => 'CHECKOUT',
3596         item     => $item,
3597         borrower => $borrower,
3598         branch   => $branch,
3599     });
3600
3601 =cut
3602
3603 sub SendCirculationAlert {
3604     my ($opts) = @_;
3605     my ($type, $item, $borrower, $branch, $issue) =
3606         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3607     my %message_name = (
3608         CHECKIN  => 'Item_Check_in',
3609         CHECKOUT => 'Item_Checkout',
3610         RENEWAL  => 'Item_Checkout',
3611     );
3612     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3613         borrowernumber => $borrower->{borrowernumber},
3614         message_name   => $message_name{$type},
3615     });
3616
3617
3618     my $tables = {
3619         items => $item->{itemnumber},
3620         biblio      => $item->{biblionumber},
3621         biblioitems => $item->{biblionumber},
3622         borrowers   => $borrower,
3623         branches    => $branch,
3624     };
3625
3626     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3627     # See C4::Letters:: _parseletter_sth
3628     if( $type eq 'CHECKIN' ){
3629         $tables->{old_issues} = $issue->issue_id;
3630     } else {
3631         $tables->{issues} = $item->{itemnumber};
3632     }
3633
3634     my $schema = Koha::Database->new->schema;
3635     my @transports = keys %{ $borrower_preferences->{transports} };
3636
3637     # From the MySQL doc:
3638     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3639     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3640     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3641     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3642
3643     for my $mtt (@transports) {
3644         my $letter =  C4::Letters::GetPreparedLetter (
3645             module => 'circulation',
3646             letter_code => $type,
3647             branchcode => $branch,
3648             message_transport_type => $mtt,
3649             lang => $borrower->{lang},
3650             tables => $tables,
3651         ) or next;
3652
3653         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3654         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3655         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3656         unless ( $message ) {
3657             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3658             C4::Message->enqueue($letter, $borrower, $mtt);
3659         } else {
3660             $message->append($letter);
3661             $message->update;
3662         }
3663         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3664     }
3665
3666     return;
3667 }
3668
3669 =head2 updateWrongTransfer
3670
3671   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3672
3673 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3674
3675 =cut
3676
3677 sub updateWrongTransfer {
3678         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3679
3680     # first step: cancel the original transfer
3681     my $item = Koha::Items->find($itemNumber);
3682     my $transfer = $item->get_transfer;
3683     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3684
3685     # second step: create a new transfer to the right location
3686     my $new_transfer = $item->request_transfer(
3687         {
3688             to            => $transfer->to_library,
3689             reason        => $transfer->reason,
3690             comment       => $transfer->comments,
3691             ignore_limits => 1,
3692             enqueue       => 1
3693         }
3694     );
3695
3696     return $new_transfer;
3697 }
3698
3699 =head2 CalcDateDue
3700
3701 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3702
3703 this function calculates the due date given the start date and configured circulation rules,
3704 checking against the holidays calendar as per the daysmode circulation rule.
3705 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3706 C<$itemtype>  = itemtype code of item in question
3707 C<$branch>  = location whose calendar to use
3708 C<$borrower> = Borrower object
3709 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3710
3711 =cut
3712
3713 sub CalcDateDue {
3714     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3715
3716     $isrenewal ||= 0;
3717
3718     # loanlength now a href
3719     my $loanlength =
3720             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3721
3722     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3723             ? qq{renewalperiod}
3724             : qq{issuelength};
3725
3726     my $datedue;
3727     if ( $startdate ) {
3728         if (ref $startdate ne 'DateTime' ) {
3729             $datedue = dt_from_string($datedue);
3730         } else {
3731             $datedue = $startdate->clone;
3732         }
3733     } else {
3734         $datedue = dt_from_string()->truncate( to => 'minute' );
3735     }
3736
3737
3738     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3739         {
3740             categorycode => $borrower->{categorycode},
3741             itemtype     => $itemtype,
3742             branchcode   => $branch,
3743         }
3744     );
3745
3746     # calculate the datedue as normal
3747     if ( $daysmode eq 'Days' )
3748     {    # ignoring calendar
3749         if ( $loanlength->{lengthunit} eq 'hours' ) {
3750             $datedue->add( hours => $loanlength->{$length_key} );
3751         } else {    # days
3752             $datedue->add( days => $loanlength->{$length_key} );
3753             $datedue->set_hour(23);
3754             $datedue->set_minute(59);
3755         }
3756     } else {
3757         my $dur;
3758         if ($loanlength->{lengthunit} eq 'hours') {
3759             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3760         }
3761         else { # days
3762             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3763         }
3764         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3765         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3766         if ($loanlength->{lengthunit} eq 'days') {
3767             $datedue->set_hour(23);
3768             $datedue->set_minute(59);
3769         }
3770     }
3771
3772     # if Hard Due Dates are used, retrieve them and apply as necessary
3773     my ( $hardduedate, $hardduedatecompare ) =
3774       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3775     if ($hardduedate) {    # hardduedates are currently dates
3776         $hardduedate->truncate( to => 'minute' );
3777         $hardduedate->set_hour(23);
3778         $hardduedate->set_minute(59);
3779         my $cmp = DateTime->compare( $hardduedate, $datedue );
3780
3781 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3782 # if the calculated date is before the 'after' Hard Due Date (floor), override
3783 # if the hard due date is set to 'exactly', overrride
3784         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3785             $datedue = $hardduedate->clone;
3786         }
3787
3788         # in all other cases, keep the date due as it is
3789
3790     }
3791
3792     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3793     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3794         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3795         if( $expiry_dt ) { #skip empty expiry date..
3796             $expiry_dt->set( hour => 23, minute => 59);
3797             my $d1= $datedue->clone->set_time_zone('floating');
3798             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3799                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3800             }
3801         }
3802         if ( $daysmode ne 'Days' ) {
3803           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3804           if ( $calendar->is_holiday($datedue) ) {
3805               # Don't return on a closed day
3806               $datedue = $calendar->prev_open_days( $datedue, 1 );
3807           }
3808         }
3809     }
3810
3811     return $datedue;
3812 }
3813
3814
3815 sub CheckValidBarcode{
3816 my ($barcode) = @_;
3817 my $dbh = C4::Context->dbh;
3818 my $query=qq|SELECT count(*)
3819              FROM items
3820              WHERE barcode=?
3821             |;
3822 my $sth = $dbh->prepare($query);
3823 $sth->execute($barcode);
3824 my $exist=$sth->fetchrow ;
3825 return $exist;
3826 }
3827
3828 =head2 IsBranchTransferAllowed
3829
3830   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3831
3832 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3833
3834 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3835 Koha::Item->can_be_transferred.
3836
3837 =cut
3838
3839 sub IsBranchTransferAllowed {
3840         my ( $toBranch, $fromBranch, $code ) = @_;
3841
3842         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3843
3844         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3845         my $dbh = C4::Context->dbh;
3846
3847         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3848         $sth->execute( $toBranch, $fromBranch, $code );
3849         my $limit = $sth->fetchrow_hashref();
3850
3851         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3852         if ( $limit->{'limitId'} ) {
3853                 return 0;
3854         } else {
3855                 return 1;
3856         }
3857 }
3858
3859 =head2 CreateBranchTransferLimit
3860
3861   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3862
3863 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3864
3865 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3866
3867 =cut
3868
3869 sub CreateBranchTransferLimit {
3870    my ( $toBranch, $fromBranch, $code ) = @_;
3871    return unless defined($toBranch) && defined($fromBranch);
3872    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3873
3874    my $dbh = C4::Context->dbh;
3875
3876    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3877    return $sth->execute( $code, $toBranch, $fromBranch );
3878 }
3879
3880 =head2 DeleteBranchTransferLimits
3881
3882     my $result = DeleteBranchTransferLimits($frombranch);
3883
3884 Deletes all the library transfer limits for one library.  Returns the
3885 number of limits deleted, 0e0 if no limits were deleted, or undef if
3886 no arguments are supplied.
3887
3888 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3889     fromBranch => $fromBranch
3890     })->delete.
3891
3892 =cut
3893
3894 sub DeleteBranchTransferLimits {
3895     my $branch = shift;
3896     return unless defined $branch;
3897     my $dbh    = C4::Context->dbh;
3898     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3899     return $sth->execute($branch);
3900 }
3901
3902 sub ReturnLostItem{
3903     my ( $borrowernumber, $itemnum ) = @_;
3904     MarkIssueReturned( $borrowernumber, $itemnum );
3905 }
3906
3907 =head2 LostItem
3908
3909   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3910
3911 The final optional parameter, C<$params>, expected to contain
3912 'skip_record_index' key, which relayed down to Koha::Item/store,
3913 there it prevents calling of ModZebra index_records,
3914 which takes most of the time in batch adds/deletes: index_records better
3915 to be called later in C<additem.pl> after the whole loop.
3916
3917 $params:
3918     skip_record_index => 1|0
3919
3920 =cut
3921
3922 sub LostItem{
3923     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3924
3925     unless ( $mark_lost_from ) {
3926         # Temporary check to avoid regressions
3927         die q|LostItem called without $mark_lost_from, check the API.|;
3928     }
3929
3930     my $mark_returned;
3931     if ( $force_mark_returned ) {
3932         $mark_returned = 1;
3933     } else {
3934         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3935         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3936     }
3937
3938     my $dbh = C4::Context->dbh();
3939     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3940                            FROM issues
3941                            JOIN items USING (itemnumber)
3942                            JOIN biblio USING (biblionumber)
3943                            WHERE issues.itemnumber=?");
3944     $sth->execute($itemnumber);
3945     my $issues=$sth->fetchrow_hashref();
3946
3947     # If a borrower lost the item, add a replacement cost to the their record
3948     if ( my $borrowernumber = $issues->{borrowernumber} ){
3949         my $patron = Koha::Patrons->find( $borrowernumber );
3950
3951         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3952         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3953
3954         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3955             C4::Accounts::chargelostitem(
3956                 $borrowernumber,
3957                 $itemnumber,
3958                 $issues->{'replacementprice'},
3959                 sprintf( "%s %s %s",
3960                     $issues->{'title'}          || q{},
3961                     $issues->{'barcode'}        || q{},
3962                     $issues->{'itemcallnumber'} || q{},
3963                 ),
3964             );
3965             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3966             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3967         }
3968
3969         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
3970     }
3971
3972     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
3973     my $item = Koha::Items->find($itemnumber);
3974     my $transfers = $item->get_transfers;
3975     while (my $transfer = $transfers->next) {
3976         $transfer->cancel({ reason => 'ItemLost', force => 1 });
3977     }
3978 }
3979
3980 sub GetOfflineOperations {
3981     my $dbh = C4::Context->dbh;
3982     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3983     $sth->execute(C4::Context->userenv->{'branch'});
3984     my $results = $sth->fetchall_arrayref({});
3985     return $results;
3986 }
3987
3988 sub GetOfflineOperation {
3989     my $operationid = shift;
3990     return unless $operationid;
3991     my $dbh = C4::Context->dbh;
3992     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3993     $sth->execute( $operationid );
3994     return $sth->fetchrow_hashref;
3995 }
3996
3997 sub AddOfflineOperation {
3998     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3999     my $dbh = C4::Context->dbh;
4000     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
4001     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
4002     return "Added.";
4003 }
4004
4005 sub DeleteOfflineOperation {
4006     my $dbh = C4::Context->dbh;
4007     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
4008     $sth->execute( shift );
4009     return "Deleted.";
4010 }
4011
4012 sub ProcessOfflineOperation {
4013     my $operation = shift;
4014
4015     my $report;
4016     if ( $operation->{action} eq 'return' ) {
4017         $report = ProcessOfflineReturn( $operation );
4018     } elsif ( $operation->{action} eq 'issue' ) {
4019         $report = ProcessOfflineIssue( $operation );
4020     } elsif ( $operation->{action} eq 'payment' ) {
4021         $report = ProcessOfflinePayment( $operation );
4022     }
4023
4024     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4025
4026     return $report;
4027 }
4028
4029 sub ProcessOfflineReturn {
4030     my $operation = shift;
4031
4032     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4033
4034     if ( $item ) {
4035         my $itemnumber = $item->itemnumber;
4036         my $issue = GetOpenIssue( $itemnumber );
4037         if ( $issue ) {
4038             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4039             ModDateLastSeen( $itemnumber, $leave_item_lost );
4040             MarkIssueReturned(
4041                 $issue->{borrowernumber},
4042                 $itemnumber,
4043                 $operation->{timestamp},
4044             );
4045             $item->renewals(0);
4046             $item->onloan(undef);
4047             $item->store({ log_action => 0 });
4048             return "Success.";
4049         } else {
4050             return "Item not issued.";
4051         }
4052     } else {
4053         return "Item not found.";
4054     }
4055 }
4056
4057 sub ProcessOfflineIssue {
4058     my $operation = shift;
4059
4060     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4061
4062     if ( $patron ) {
4063         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4064         unless ($item) {
4065             return "Barcode not found.";
4066         }
4067         my $itemnumber = $item->itemnumber;
4068         my $issue = GetOpenIssue( $itemnumber );
4069
4070         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4071             MarkIssueReturned(
4072                 $issue->{borrowernumber},
4073                 $itemnumber,
4074                 $operation->{timestamp},
4075             );
4076         }
4077         AddIssue(
4078             $patron->unblessed,
4079             $operation->{'barcode'},
4080             undef,
4081             undef,
4082             $operation->{timestamp},
4083             undef,
4084         );
4085         return "Success.";
4086     } else {
4087         return "Borrower not found.";
4088     }
4089 }
4090
4091 sub ProcessOfflinePayment {
4092     my $operation = shift;
4093
4094     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4095
4096     $patron->account->pay(
4097         {
4098             amount     => $operation->{amount},
4099             library_id => $operation->{branchcode},
4100             interface  => 'koc'
4101         }
4102     );
4103
4104     return "Success.";
4105 }
4106
4107 =head2 TransferSlip
4108
4109   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4110
4111   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4112
4113 =cut
4114
4115 sub TransferSlip {
4116     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4117
4118     my $item =
4119       $itemnumber
4120       ? Koha::Items->find($itemnumber)
4121       : Koha::Items->find( { barcode => $barcode } );
4122
4123     $item or return;
4124
4125     return C4::Letters::GetPreparedLetter (
4126         module => 'circulation',
4127         letter_code => 'TRANSFERSLIP',
4128         branchcode => $branch,
4129         tables => {
4130             'branches'    => $to_branch,
4131             'biblio'      => $item->biblionumber,
4132             'items'       => $item->unblessed,
4133         },
4134     );
4135 }
4136
4137 =head2 CheckIfIssuedToPatron
4138
4139   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4140
4141   Return 1 if any record item is issued to patron, otherwise return 0
4142
4143 =cut
4144
4145 sub CheckIfIssuedToPatron {
4146     my ($borrowernumber, $biblionumber) = @_;
4147
4148     my $dbh = C4::Context->dbh;
4149     my $query = q|
4150         SELECT COUNT(*) FROM issues
4151         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4152         WHERE items.biblionumber = ?
4153         AND issues.borrowernumber = ?
4154     |;
4155     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4156     return 1 if $is_issued;
4157     return;
4158 }
4159
4160 =head2 IsItemIssued
4161
4162   IsItemIssued( $itemnumber )
4163
4164   Return 1 if the item is on loan, otherwise return 0
4165
4166 =cut
4167
4168 sub IsItemIssued {
4169     my $itemnumber = shift;
4170     my $dbh = C4::Context->dbh;
4171     my $sth = $dbh->prepare(q{
4172         SELECT COUNT(*)
4173         FROM issues
4174         WHERE itemnumber = ?
4175     });
4176     $sth->execute($itemnumber);
4177     return $sth->fetchrow;
4178 }
4179
4180 =head2 GetAgeRestriction
4181
4182   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4183   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4184
4185   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4186   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4187
4188 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4189 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4190 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4191          Negative days mean the borrower has gone past the age restriction age.
4192
4193 =cut
4194
4195 sub GetAgeRestriction {
4196     my ($record_restrictions, $borrower) = @_;
4197     my $markers = C4::Context->preference('AgeRestrictionMarker');
4198
4199     return unless $record_restrictions;
4200     # Split $record_restrictions to something like FSK 16 or PEGI 6
4201     my @values = split ' ', uc($record_restrictions);
4202     return unless @values;
4203
4204     # Search first occurrence of one of the markers
4205     my @markers = split /\|/, uc($markers);
4206     return unless @markers;
4207
4208     my $index            = 0;
4209     my $restriction_year = 0;
4210     for my $value (@values) {
4211         $index++;
4212         for my $marker (@markers) {
4213             $marker =~ s/^\s+//;    #remove leading spaces
4214             $marker =~ s/\s+$//;    #remove trailing spaces
4215             if ( $marker eq $value ) {
4216                 if ( $index <= $#values ) {
4217                     $restriction_year += $values[$index];
4218                 }
4219                 last;
4220             }
4221             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4222
4223                 # Perhaps it is something like "K16" (as in Finland)
4224                 $restriction_year += $1;
4225                 last;
4226             }
4227         }
4228         last if ( $restriction_year > 0 );
4229     }
4230
4231     #Check if the borrower is age restricted for this material and for how long.
4232     if ($restriction_year && $borrower) {
4233         if ( $borrower->{'dateofbirth'} ) {
4234             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4235             $alloweddate[0] += $restriction_year;
4236
4237             #Prevent runime eror on leap year (invalid date)
4238             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4239                 $alloweddate[2] = 28;
4240             }
4241
4242             #Get how many days the borrower has to reach the age restriction
4243             my @Today = split /-/, dt_from_string()->ymd();
4244             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4245             #Negative days means the borrower went past the age restriction age
4246             return ($restriction_year, $daysToAgeRestriction);
4247         }
4248     }
4249
4250     return ($restriction_year);
4251 }
4252
4253
4254 =head2 GetPendingOnSiteCheckouts
4255
4256 =cut
4257
4258 sub GetPendingOnSiteCheckouts {
4259     my $dbh = C4::Context->dbh;
4260     return $dbh->selectall_arrayref(q|
4261         SELECT
4262           items.barcode,
4263           items.biblionumber,
4264           items.itemnumber,
4265           items.itemnotes,
4266           items.itemcallnumber,
4267           items.location,
4268           issues.date_due,
4269           issues.branchcode,
4270           issues.date_due < NOW() AS is_overdue,
4271           biblio.author,
4272           biblio.title,
4273           borrowers.firstname,
4274           borrowers.surname,
4275           borrowers.cardnumber,
4276           borrowers.borrowernumber
4277         FROM items
4278         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4279         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4280         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4281         WHERE issues.onsite_checkout = 1
4282     |, { Slice => {} } );
4283 }
4284
4285 sub GetTopIssues {
4286     my ($params) = @_;
4287
4288     my ($count, $branch, $itemtype, $ccode, $newness)
4289         = @$params{qw(count branch itemtype ccode newness)};
4290
4291     my $dbh = C4::Context->dbh;
4292     my $query = q{
4293         SELECT * FROM (
4294         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4295           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4296           i.ccode, SUM(i.issues) AS count
4297         FROM biblio b
4298         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4299         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4300     };
4301
4302     my (@where_strs, @where_args);
4303
4304     if ($branch) {
4305         push @where_strs, 'i.homebranch = ?';
4306         push @where_args, $branch;
4307     }
4308     if ($itemtype) {
4309         if (C4::Context->preference('item-level_itypes')){
4310             push @where_strs, 'i.itype = ?';
4311             push @where_args, $itemtype;
4312         } else {
4313             push @where_strs, 'bi.itemtype = ?';
4314             push @where_args, $itemtype;
4315         }
4316     }
4317     if ($ccode) {
4318         push @where_strs, 'i.ccode = ?';
4319         push @where_args, $ccode;
4320     }
4321     if ($newness) {
4322         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4323         push @where_args, $newness;
4324     }
4325
4326     if (@where_strs) {
4327         $query .= 'WHERE ' . join(' AND ', @where_strs);
4328     }
4329
4330     $query .= q{
4331         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4332           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4333           i.ccode
4334         ORDER BY count DESC
4335     };
4336
4337     $query .= q{ ) xxx WHERE count > 0 };
4338     $count = int($count);
4339     if ($count > 0) {
4340         $query .= "LIMIT $count";
4341     }
4342
4343     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4344
4345     return @$rows;
4346 }
4347
4348 =head2 Internal methods
4349
4350 =cut
4351
4352 sub _CalculateAndUpdateFine {
4353     my ($params) = @_;
4354
4355     my $borrower    = $params->{borrower};
4356     my $item        = $params->{item};
4357     my $issue       = $params->{issue};
4358     my $return_date = $params->{return_date};
4359
4360     unless ($borrower) { carp "No borrower passed in!" && return; }
4361     unless ($item)     { carp "No item passed in!"     && return; }
4362     unless ($issue)    { carp "No issue passed in!"    && return; }
4363
4364     my $datedue = dt_from_string( $issue->date_due );
4365
4366     # we only need to calculate and change the fines if we want to do that on return
4367     # Should be on for hourly loans
4368     my $control = C4::Context->preference('CircControl');
4369     my $control_branchcode =
4370         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4371       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4372       :                                     $issue->branchcode;
4373
4374     my $date_returned = $return_date ? $return_date : dt_from_string();
4375
4376     my ( $amount, $unitcounttotal, $unitcount  ) =
4377       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4378
4379     if ( C4::Context->preference('finesMode') eq 'production' ) {
4380         if ( $amount > 0 ) {
4381             C4::Overdues::UpdateFine({
4382                 issue_id       => $issue->issue_id,
4383                 itemnumber     => $issue->itemnumber,
4384                 borrowernumber => $issue->borrowernumber,
4385                 amount         => $amount,
4386                 due            => output_pref($datedue),
4387             });
4388         }
4389         elsif ($return_date) {
4390
4391             # Backdated returns may have fines that shouldn't exist,
4392             # so in this case, we need to drop those fines to 0
4393
4394             C4::Overdues::UpdateFine({
4395                 issue_id       => $issue->issue_id,
4396                 itemnumber     => $issue->itemnumber,
4397                 borrowernumber => $issue->borrowernumber,
4398                 amount         => 0,
4399                 due            => output_pref($datedue),
4400             });
4401         }
4402     }
4403 }
4404
4405 sub _CanBookBeAutoRenewed {
4406     my ( $params ) = @_;
4407     my $patron = $params->{patron};
4408     my $item = $params->{item};
4409     my $branchcode = $params->{branchcode};
4410     my $issue = $params->{issue};
4411
4412     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4413
4414     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4415         {
4416             categorycode => $patron->categorycode,
4417             itemtype     => $item->effective_itemtype,
4418             branchcode   => $branchcode,
4419             rules => [
4420                 'no_auto_renewal_after',
4421                 'no_auto_renewal_after_hard_limit',
4422                 'lengthunit',
4423                 'norenewalbefore',
4424             ]
4425         }
4426     );
4427
4428     if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
4429         return 'auto_account_expired';
4430     }
4431
4432     if ( defined $issuing_rule->{no_auto_renewal_after}
4433             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4434         # Get issue_date and add no_auto_renewal_after
4435         # If this is greater than today, it's too late for renewal.
4436         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4437         $maximum_renewal_date->add(
4438             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4439         );
4440         my $now = dt_from_string;
4441         if ( $now >= $maximum_renewal_date ) {
4442             return "auto_too_late";
4443         }
4444     }
4445     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4446                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4447         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4448         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4449             return "auto_too_late";
4450         }
4451     }
4452
4453     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4454         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4455         my $amountoutstanding =
4456           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4457           ? $patron->account->balance
4458           : $patron->account->outstanding_debits->total_outstanding;
4459         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4460             return "auto_too_much_oweing";
4461         }
4462     }
4463
4464     my $soonest = GetSoonestRenewDate($patron->id, $item->id);
4465     if ( $soonest > dt_from_string() )
4466     {
4467         return ( "auto_too_soon", $soonest );
4468     }
4469
4470     return "ok";
4471 }
4472
4473 sub _item_denied_renewal {
4474     my ($params) = @_;
4475
4476     my $item = $params->{item};
4477     return unless $item;
4478
4479     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4480     return unless $denyingrules;
4481     foreach my $field (keys %$denyingrules) {
4482         my $val = $item->$field;
4483         if( !defined $val) {
4484             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4485                 return 1;
4486             }
4487         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4488            # If the results matches the values in the syspref
4489            # We return true if match found
4490             return 1;
4491         }
4492     }
4493     return 0;
4494 }
4495
4496 1;
4497
4498 __END__
4499
4500 =head1 AUTHOR
4501
4502 Koha Development Team <http://koha-community.org/>
4503
4504 =cut