C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use C4::Context;
  28 use C4::Stats qw( UpdateStats );
  29 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest ItemsAnyAvailableAndNotRestricted );
  30 use C4::Biblio qw( UpdateTotalIssues );
  31 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Log qw( logaction ); # logaction
  36 use C4::Overdues;
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits qw( CheckDigits );
  39
  40 use Data::Dumper qw( Dumper );
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetUpcomingDueIssues
  99       CheckIfIssuedToPatron
 100       IsItemIssued
 101       GetAgeRestriction
 102       GetTopIssues
 103
 104       AddReturn
 105       MarkIssueReturned
 106
 107       transferbook
 108       TooMany
 109       GetTransfersFromTo
 110       updateWrongTransfer
 111       CalcDateDue
 112       CheckValidBarcode
 113       IsBranchTransferAllowed
 114       CreateBranchTransferLimit
 115       DeleteBranchTransferLimits
 116       TransferSlip
 117
 118       GetOfflineOperations
 119       GetOfflineOperation
 120       AddOfflineOperation
 121       DeleteOfflineOperation
 122       ProcessOfflineOperation
 123       ProcessOfflinePayment
 124       ProcessOfflineIssue
 125     );
 126     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 127 }
 128
 129 =head1 NAME
 130
 131 C4::Circulation - Koha circulation module
 132
 133 =head1 SYNOPSIS
 134
 135 use C4::Circulation;
 136
 137 =head1 DESCRIPTION
 138
 139 The functions in this module deal with circulation, issues, and
 140 returns, as well as general information about the library.
 141 Also deals with inventory.
 142
 143 =head1 FUNCTIONS
 144
 145 =head2 barcodedecode
 146
 147   $str = &barcodedecode($barcode, [$filter]);
 148
 149 Generic filter function for barcode string.
 150 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 151 Will do some manipulation of the barcode for systems that deliver a barcode
 152 to circulation.pl that differs from the barcode stored for the item.
 153 For proper functioning of this filter, calling the function on the
 154 correct barcode string (items.barcode) should return an unaltered barcode.
 155 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 156
 157 The optional $filter argument is to allow for testing or explicit
 158 behavior that ignores the System Pref.  Valid values are the same as the
 159 System Pref options.
 160
 161 =cut
 162
 163 # FIXME -- the &decode fcn below should be wrapped into this one.
 164 # FIXME -- these plugins should be moved out of Circulation.pm
 165 #
 166 sub barcodedecode {
 167     my ($barcode, $filter) = @_;
 168
 169     return unless defined $barcode;
 170
 171     my $branch = C4::Context::mybranch();
 172     $barcode =~ s/^\s+|\s+$//g;
 173     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 174     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 175     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 176         if ($filter eq 'whitespace') {
 177                 $barcode =~ s/\s//g;
 178         } elsif ($filter eq 'cuecat') {
 179                 chomp($barcode);
 180             my @fields = split( /\./, $barcode );
 181             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 182             ($#results == 2) and return $results[2];
 183         } elsif ($filter eq 'T-prefix') {
 184                 if ($barcode =~ /^[Tt](\d)/) {
 185                         (defined($1) and $1 eq '0') and return $barcode;
 186             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 187                 }
 188         return sprintf("T%07d", $barcode);
 189         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 190         # Why drop the nonzero digit after the T?
 191         # Why pass non-digits (or empty string) to "T%07d"?
 192         } elsif ($filter eq 'libsuite8') {
 193                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 194                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 195                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 196                         }else{
 197                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 198                         }
 199                 }
 200     } elsif ($filter eq 'EAN13') {
 201         my $ean = CheckDigits('ean');
 202         if ( $ean->is_valid($barcode) ) {
 203             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 204             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 205         } else {
 206             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 207         }
 208         }
 209     return $barcode;    # return barcode, modified or not
 210 }
 211
 212 =head2 _decode
 213
 214   $str = &_decode($chunk);
 215
 216 Decodes a segment of a string emitted by a CueCat barcode scanner and
 217 returns it.
 218
 219 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 220 or Javascript based decoding on the client side.
 221
 222 =cut
 223
 224 sub _decode {
 225     my ($encoded) = @_;
 226     my $seq =
 227       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 228     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 229     my $l = ( $#s + 1 ) % 4;
 230     if ($l) {
 231         if ( $l == 1 ) {
 232             # warn "Error: Cuecat decode parsing failed!";
 233             return;
 234         }
 235         $l = 4 - $l;
 236         $#s += $l;
 237     }
 238     my $r = '';
 239     while ( $#s >= 0 ) {
 240         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 241         $r .=
 242             chr( ( $n >> 16 ) ^ 67 )
 243          .chr( ( $n >> 8 & 255 ) ^ 67 )
 244          .chr( ( $n & 255 ) ^ 67 );
 245         @s = @s[ 4 .. $#s ];
 246     }
 247     $r = substr( $r, 0, length($r) - $l );
 248     return $r;
 249 }
 250
 251 =head2 transferbook
 252
 253   ($dotransfer, $messages, $iteminformation) = &transferbook({
 254                                                    from_branch => $frombranch
 255                                                    to_branch => $tobranch,
 256                                                    barcode => $barcode,
 257                                                    ignore_reserves => $ignore_reserves,
 258                                                    trigger => $trigger
 259                                                 });
 260
 261 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 262
 263 C<$fbr> is the code for the branch initiating the transfer.
 264 C<$tbr> is the code for the branch to which the item should be transferred.
 265
 266 C<$barcode> is the barcode of the item to be transferred.
 267
 268 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 269 Otherwise, if an item is reserved, the transfer fails.
 270
 271 C<$trigger> is the enum value for what triggered the transfer.
 272
 273 Returns three values:
 274
 275 =over
 276
 277 =item $dotransfer
 278
 279 is true if the transfer was successful.
 280
 281 =item $messages
 282
 283 is a reference-to-hash which may have any of the following keys:
 284
 285 =over
 286
 287 =item C<BadBarcode>
 288
 289 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 290
 291 =item C<DestinationEqualsHolding>
 292
 293 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 294
 295 =item C<WasReturned>
 296
 297 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 298
 299 =item C<ResFound>
 300
 301 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 302
 303 =item C<WasTransferred>
 304
 305 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 306
 307 =item C<RecallPlacedAtHoldingBranch>
 308
 309 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 310
 311 =item C<RecallFound>
 312
 313 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 314
 315 =back
 316
 317 =back
 318
 319 =cut
 320
 321 sub transferbook {
 322     my $params = shift;
 323     my $tbr      = $params->{to_branch};
 324     my $fbr      = $params->{from_branch};
 325     my $ignoreRs = $params->{ignore_reserves};
 326     my $barcode  = $params->{barcode};
 327     my $trigger  = $params->{trigger};
 328     my $messages;
 329     my $dotransfer      = 1;
 330     my $item = Koha::Items->find( { barcode => $barcode } );
 331
 332     Koha::Exceptions::MissingParameter->throw(
 333         "Missing mandatory parameter: from_branch")
 334       unless $fbr;
 335
 336     Koha::Exceptions::MissingParameter->throw(
 337         "Missing mandatory parameter: to_branch")
 338       unless $tbr;
 339
 340     # bad barcode..
 341     unless ( $item ) {
 342         $messages->{'BadBarcode'} = $barcode;
 343         $dotransfer = 0;
 344         return ( $dotransfer, $messages );
 345     }
 346
 347     my $itemnumber = $item->itemnumber;
 348     # get branches of book...
 349     my $hbr = $item->homebranch;
 350
 351     # if using Branch Transfer Limits
 352     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 353         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 354         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 355             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 356                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 357                 $dotransfer = 0;
 358             }
 359         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 360             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 361             $dotransfer = 0;
 362         }
 363     }
 364
 365     # can't transfer book if is already there....
 366     if ( $fbr eq $tbr ) {
 367         $messages->{'DestinationEqualsHolding'} = 1;
 368         $dotransfer = 0;
 369     }
 370
 371     # check if it is still issued to someone, return it...
 372     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 373     if ( $issue ) {
 374         AddReturn( $barcode, $fbr );
 375         $messages->{'WasReturned'} = $issue->borrowernumber;
 376     }
 377
 378     # find reserves.....
 379     # That'll save a database query.
 380     my ( $resfound, $resrec, undef ) =
 381       CheckReserves( $itemnumber );
 382     if ( $resfound ) {
 383         $resrec->{'ResFound'} = $resfound;
 384         $messages->{'ResFound'} = $resrec;
 385         $dotransfer = 0 unless $ignoreRs;
 386     }
 387
 388     # find recall
 389     if ( C4::Context->preference('UseRecalls') ) {
 390         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 391         if ( defined $recall ) {
 392             # do a transfer if the recall branch is different to the item holding branch
 393             if ( $recall->pickup_library_id eq $fbr ) {
 394                 $dotransfer = 0;
 395                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 396             } else {
 397                 $dotransfer = 1;
 398                 $messages->{'RecallFound'} = $recall;
 399             }
 400         }
 401     }
 402
 403     #actually do the transfer....
 404     if ($dotransfer) {
 405         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 406
 407         # don't need to update MARC anymore, we do it in batch now
 408         $messages->{'WasTransfered'} = $tbr;
 409
 410     }
 411     ModDateLastSeen( $itemnumber );
 412     return ( $dotransfer, $messages );
 413 }
 414
 415
 416 sub TooMany {
 417     my $borrower        = shift;
 418     my $item_object = shift;
 419     my $params = shift;
 420     my $onsite_checkout = $params->{onsite_checkout} || 0;
 421     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 422     my $cat_borrower    = $borrower->{'categorycode'};
 423     my $dbh             = C4::Context->dbh;
 424     # Get which branchcode we need
 425     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 426     my $type = $item_object->effective_itemtype;
 427
 428     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 429     $type_object = Koha::ItemTypes->find( $type );
 430     $parent_type = $type_object->parent_type if $type_object;
 431     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 432     # Find any children if we are a parent_type;
 433
 434     # given branch, patron category, and item type, determine
 435     # applicable issuing rule
 436
 437     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 438         {
 439             categorycode => $cat_borrower,
 440             itemtype     => $parent_type,
 441             branchcode   => $branch,
 442             rule_name    => 'maxissueqty',
 443         }
 444     ) if $parent_type;
 445     # If the parent rule is for default type we discount it
 446     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 447
 448     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 449         {
 450             categorycode => $cat_borrower,
 451             itemtype     => $type,
 452             branchcode   => $branch,
 453             rule_name    => 'maxissueqty',
 454         }
 455     );
 456
 457     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 458         {
 459             categorycode => $cat_borrower,
 460             itemtype     => $type,
 461             branchcode   => $branch,
 462             rule_name    => 'maxonsiteissueqty',
 463         }
 464     );
 465
 466
 467     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 468     # if a rule is found and has a loan limit set, count
 469     # how many loans the patron already has that meet that
 470     # rule
 471     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 472
 473         my $checkouts;
 474         if ( $maxissueqty_rule->branchcode ) {
 475             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 476                 $checkouts = $patron->checkouts->search(
 477                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 478             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 479                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 480             } else {
 481                 my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 482                 $checkouts = $patron->checkouts->search(
 483                     { "item.$branch_type" => $maxissueqty_rule->branchcode } );
 484             }
 485         } else {
 486             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 487         }
 488         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 489
 490         my $sum_checkouts;
 491         my $rule_itemtype = $maxissueqty_rule->itemtype;
 492
 493         my @types;
 494         unless ( $rule_itemtype ) {
 495             # matching rule has the default item type, so count only
 496             # those existing loans that don't fall under a more
 497             # specific rule
 498             @types = Koha::CirculationRules->search(
 499                 {
 500                     branchcode => $maxissueqty_rule->branchcode,
 501                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 502                     itemtype  => { '!=' => undef },
 503                     rule_name => 'maxissueqty'
 504                 }
 505             )->get_column('itemtype');
 506         } else {
 507             if ( $parent_maxissueqty_rule ) {
 508                 # if we have a parent item type then we count loans of the
 509                 # specific item type or its siblings or parent
 510                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 511                 @types = $children->get_column('itemtype');
 512                 push @types, $parent_type;
 513             } elsif ( $child_types ) {
 514                 # If we are a parent type, we need to count all child types and our own type
 515                 @types = $child_types->get_column('itemtype');
 516                 push @types, $type; # And don't forget to count our own types
 517             } else {
 518                 # Otherwise only count the specific itemtype
 519                 push @types, $type;
 520             }
 521         }
 522
 523         while ( my $c = $checkouts->next ) {
 524             my $itemtype = $c->item->effective_itemtype;
 525
 526             unless ( $rule_itemtype ) {
 527                 next if grep {$_ eq $itemtype} @types;
 528             } else {
 529                 next unless grep {$_ eq $itemtype} @types;
 530             }
 531
 532             $sum_checkouts->{total}++;
 533             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 534             $sum_checkouts->{itemtype}->{$itemtype}++;
 535         }
 536
 537         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 538         my $checkout_count = $sum_checkouts->{total} || 0;
 539         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 540
 541         my $checkout_rules = {
 542             checkout_count               => $checkout_count,
 543             onsite_checkout_count        => $onsite_checkout_count,
 544             onsite_checkout              => $onsite_checkout,
 545             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 546             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 547             switch_onsite_checkout       => $switch_onsite_checkout,
 548         };
 549         # If parent rules exists
 550         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 551             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 552             my $qty_over = _check_max_qty($checkout_rules);
 553             return $qty_over if defined $qty_over;
 554
 555             # If the parent rule is less than or equal to the child, we only need check the parent
 556             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 557                 $checkout_rules->{checkout_count} = $checkout_count_type;
 558                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 559                 my $qty_over = _check_max_qty($checkout_rules);
 560                 return $qty_over if defined $qty_over;
 561             }
 562         } else {
 563             my $qty_over = _check_max_qty($checkout_rules);
 564             return $qty_over if defined $qty_over;
 565         }
 566     }
 567
 568     # Now count total loans against the limit for the branch
 569     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 570     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 571         my $checkouts;
 572         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 573             $checkouts = $patron->checkouts->search(
 574                 { 'me.branchcode' => $branch} );
 575         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 576             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 577         } else {
 578             my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 579             $checkouts = $patron->checkouts->search(
 580                 { "item.$branch_type" => $branch},
 581                 { prefetch            => 'item' } );
 582         }
 583
 584         my $checkout_count = $checkouts->count;
 585         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 586         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 587         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 588
 589         my $qty_over = _check_max_qty(
 590             {
 591                 checkout_count               => $checkout_count,
 592                 onsite_checkout_count        => $onsite_checkout_count,
 593                 onsite_checkout              => $onsite_checkout,
 594                 max_checkouts_allowed        => $max_checkouts_allowed,
 595                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 596                 switch_onsite_checkout       => $switch_onsite_checkout
 597             }
 598         );
 599         return $qty_over if defined $qty_over;
 600     }
 601
 602     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 603         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 604     }
 605
 606     # OK, the patron can issue !!!
 607     return;
 608 }
 609
 610 sub _check_max_qty {
 611     my $params                       = shift;
 612     my $checkout_count               = $params->{checkout_count};
 613     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 614     my $onsite_checkout              = $params->{onsite_checkout};
 615     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 616     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 617     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 618
 619     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 620         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 621         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 622             return {
 623                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 624                 count       => $onsite_checkout_count,
 625                 max_allowed => $max_onsite_checkouts_allowed,
 626             };
 627         }
 628     }
 629     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 630         if ( $max_checkouts_allowed eq '' ) { return; }
 631         my $delta = $switch_onsite_checkout ? 1 : 0;
 632         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 633             return {
 634                 reason      => 'TOO_MANY_CHECKOUTS',
 635                 count       => $checkout_count,
 636                 max_allowed => $max_checkouts_allowed,
 637             };
 638         }
 639     }
 640     elsif ( not $onsite_checkout ) {
 641         if ( $max_checkouts_allowed eq '' ) { return; }
 642         if (
 643             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 644         {
 645             return {
 646                 reason      => 'TOO_MANY_CHECKOUTS',
 647                 count       => $checkout_count - $onsite_checkout_count,
 648                 max_allowed => $max_checkouts_allowed,
 649             };
 650         }
 651     }
 652
 653     return;
 654 }
 655
 656 =head2 CanBookBeIssued
 657
 658   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 659                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 660
 661 Check if a book can be issued.
 662
 663 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 664
 665 IMPORTANT: The assumption by users of this routine is that causes blocking
 666 the issue are keyed by uppercase labels and other returned
 667 data is keyed in lower case!
 668
 669 =over 4
 670
 671 =item C<$patron> is a Koha::Patron
 672
 673 =item C<$barcode> is the bar code of the book being issued.
 674
 675 =item C<$duedates> is a DateTime object.
 676
 677 =item C<$inprocess> boolean switch
 678
 679 =item C<$ignore_reserves> boolean switch
 680
 681 =item C<$params> Hashref of additional parameters
 682
 683 Available keys:
 684     override_high_holds - Ignore high holds
 685     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 686
 687 =back
 688
 689 Returns :
 690
 691 =over 4
 692
 693 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 694 Possible values are :
 695
 696 =back
 697
 698 =head3 INVALID_DATE
 699
 700 sticky due date is invalid
 701
 702 =head3 GNA
 703
 704 borrower gone with no address
 705
 706 =head3 CARD_LOST
 707
 708 borrower declared it's card lost
 709
 710 =head3 DEBARRED
 711
 712 borrower debarred
 713
 714 =head3 UNKNOWN_BARCODE
 715
 716 barcode unknown
 717
 718 =head3 NOT_FOR_LOAN
 719
 720 item is not for loan
 721
 722 =head3 WTHDRAWN
 723
 724 item withdrawn.
 725
 726 =head3 RESTRICTED
 727
 728 item is restricted (set by ??)
 729
 730 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 731 could be prevented, but ones that can be overriden by the operator.
 732
 733 Possible values are :
 734
 735 =head3 DEBT
 736
 737 borrower has debts.
 738
 739 =head3 RENEW_ISSUE
 740
 741 renewing, not issuing
 742
 743 =head3 ISSUED_TO_ANOTHER
 744
 745 issued to someone else.
 746
 747 =head3 RESERVED
 748
 749 reserved for someone else.
 750
 751 =head3 TRANSFERRED
 752
 753 reserved and being transferred for someone else.
 754
 755 =head3 INVALID_DATE
 756
 757 sticky due date is invalid or due date in the past
 758
 759 =head3 TOO_MANY
 760
 761 if the borrower borrows to much things
 762
 763 =head3 RECALLED
 764
 765 recalled by someone else
 766
 767 =cut
 768
 769 sub CanBookBeIssued {
 770     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 771     my %needsconfirmation;    # filled with problems that needs confirmations
 772     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 773     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 774     my %messages;             # filled with information messages that should be displayed.
 775
 776     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 777     my $override_high_holds = $params->{override_high_holds} || 0;
 778
 779     my $item_object = Koha::Items->find({barcode => $barcode });
 780
 781     # MANDATORY CHECKS - unless item exists, nothing else matters
 782     unless ( $item_object ) {
 783         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 784     }
 785     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 786
 787     my $item_unblessed = $item_object->unblessed; # Transition...
 788     my $issue = $item_object->checkout;
 789     my $biblio = $item_object->biblio;
 790
 791     my $biblioitem = $biblio->biblioitem;
 792     my $effective_itemtype = $item_object->effective_itemtype;
 793     my $dbh             = C4::Context->dbh;
 794     my $patron_unblessed = $patron->unblessed;
 795
 796     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 797
 798     my $now = dt_from_string();
 799     $duedate ||= CalcDateDue( $now, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 800     if (DateTime->compare($duedate,$now) == -1 ) { # duedate cannot be before now
 801          $needsconfirmation{INVALID_DATE} = $duedate;
 802     }
 803
 804     my $fees = Koha::Charges::Fees->new(
 805         {
 806             patron    => $patron,
 807             library   => $circ_library,
 808             item      => $item_object,
 809             to_date   => $duedate,
 810         }
 811     );
 812
 813     #
 814     # BORROWER STATUS
 815     #
 816     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 817         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 818         C4::Stats::UpdateStats(
 819             {
 820                 branch         => C4::Context->userenv->{'branch'},
 821                 type           => 'localuse',
 822                 itemnumber     => $item_object->itemnumber,
 823                 itemtype       => $effective_itemtype,
 824                 borrowernumber => $patron->borrowernumber,
 825                 ccode          => $item_object->ccode,
 826                 categorycode   => $patron->categorycode,
 827             }
 828         );
 829         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 830         return( { STATS => 1 }, {});
 831     }
 832
 833     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 834         $issuingimpossible{GNA} = 1;
 835     }
 836
 837     if ( $patron->lost && $patron->lost == 1 ) {
 838         $issuingimpossible{CARD_LOST} = 1;
 839     }
 840     if ( $patron->is_debarred ) {
 841         $issuingimpossible{DEBARRED} = 1;
 842     }
 843
 844     if ( $patron->is_expired ) {
 845         $issuingimpossible{EXPIRED} = 1;
 846     }
 847
 848     #
 849     # BORROWER STATUS
 850     #
 851
 852     # DEBTS
 853     my $account = $patron->account;
 854     my $balance = $account->balance;
 855     my $non_issues_charges = $account->non_issues_charges;
 856     my $other_charges = $balance - $non_issues_charges;
 857
 858     my $amountlimit = C4::Context->preference("noissuescharge");
 859     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 860     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 861
 862     # Check the debt of this patrons guarantees
 863     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 864     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 865     if ( defined $no_issues_charge_guarantees ) {
 866         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 867         my $guarantees_non_issues_charges = 0;
 868         foreach my $g ( @guarantees ) {
 869             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 870         }
 871
 872         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 873             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 874         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 875             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 876         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 877             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 878         }
 879     }
 880
 881     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 882     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 883     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 884     if ( defined $no_issues_charge_guarantors ) {
 885         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 886
 887         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 888             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 889         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 890             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 891         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 892             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 893         }
 894     }
 895
 896     if ( C4::Context->preference("IssuingInProcess") ) {
 897         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 898             $issuingimpossible{DEBT} = $non_issues_charges;
 899         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 900             $needsconfirmation{DEBT} = $non_issues_charges;
 901         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 902             $needsconfirmation{DEBT} = $non_issues_charges;
 903         }
 904     }
 905     else {
 906         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 907             $needsconfirmation{DEBT} = $non_issues_charges;
 908         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 909             $issuingimpossible{DEBT} = $non_issues_charges;
 910         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 911             $needsconfirmation{DEBT} = $non_issues_charges;
 912         }
 913     }
 914
 915     if ($balance > 0 && $other_charges > 0) {
 916         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 917     }
 918
 919     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 920     $patron_unblessed = $patron->unblessed;
 921
 922     if ( my $debarred_date = $patron->is_debarred ) {
 923          # patron has accrued fine days or has a restriction. $count is a date
 924         if ($debarred_date eq '9999-12-31') {
 925             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 926         }
 927         else {
 928             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 929         }
 930     } elsif ( my $num_overdues = $patron->has_overdues ) {
 931         ## patron has outstanding overdue loans
 932         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 933             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 934         }
 935         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 936             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 937         }
 938     }
 939
 940     # Additional Materials Check
 941     if ( C4::Context->preference("CircConfirmItemParts")
 942         && $item_object->materials )
 943     {
 944         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 945     }
 946
 947     #
 948     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 949     #
 950     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 951
 952         # Already issued to current borrower.
 953         # If it is an on-site checkout if it can be switched to a normal checkout
 954         # or ask whether the loan should be renewed
 955
 956         if ( $issue->onsite_checkout
 957                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 958             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 959         } else {
 960             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 961                 $patron->borrowernumber,
 962                 $item_object->itemnumber,
 963             );
 964             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 965                 if ( $renewerror eq 'onsite_checkout' ) {
 966                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 967                 }
 968                 else {
 969                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 970                 }
 971             }
 972             else {
 973                 $needsconfirmation{RENEW_ISSUE} = 1;
 974             }
 975         }
 976     }
 977     elsif ( $issue ) {
 978
 979         # issued to someone else
 980
 981         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 982
 983         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 984
 985         unless ( $can_be_returned ) {
 986             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 987             $issuingimpossible{branch_to_return} = $message;
 988         } else {
 989             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 990                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 991             } else {
 992             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 993             $needsconfirmation{issued_firstname} = $patron->firstname;
 994             $needsconfirmation{issued_surname} = $patron->surname;
 995             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 996             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 997             }
 998         }
 999     }
1000
1001     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1002     #
1003     my $switch_onsite_checkout = (
1004           C4::Context->preference('SwitchOnSiteCheckouts')
1005       and $issue
1006       and $issue->onsite_checkout
1007       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1008     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1009     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1010     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1011         if ( $toomany->{max_allowed} == 0 ) {
1012             $needsconfirmation{PATRON_CANT} = 1;
1013         }
1014         if ( C4::Context->preference("AllowTooManyOverride") ) {
1015             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1016             $needsconfirmation{current_loan_count} = $toomany->{count};
1017             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1018         } else {
1019             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1020             $issuingimpossible{current_loan_count} = $toomany->{count};
1021             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1022         }
1023     }
1024
1025     #
1026     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1027     #
1028     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1029     my $wants_check = $patron->wants_check_for_previous_checkout;
1030     $needsconfirmation{PREVISSUE} = 1
1031         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1032
1033     #
1034     # ITEM CHECKING
1035     #
1036     if ( $item_object->notforloan )
1037     {
1038         if(!C4::Context->preference("AllowNotForLoanOverride")){
1039             $issuingimpossible{NOT_FOR_LOAN} = 1;
1040             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1041         }else{
1042             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1043             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1044         }
1045     }
1046     else {
1047         # we have to check itemtypes.notforloan also
1048         if (C4::Context->preference('item-level_itypes')){
1049             # this should probably be a subroutine
1050             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1051             $sth->execute($effective_itemtype);
1052             my $notforloan=$sth->fetchrow_hashref();
1053             if ($notforloan->{'notforloan'}) {
1054                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1055                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1056                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1057                 } else {
1058                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1059                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1060                 }
1061             }
1062         }
1063         else {
1064             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1065             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1066                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1067                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1068                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1069                 } else {
1070                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1071                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1072                 }
1073             }
1074         }
1075     }
1076     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1077     {
1078         $issuingimpossible{WTHDRAWN} = 1;
1079     }
1080     if (   $item_object->restricted
1081         && $item_object->restricted == 1 )
1082     {
1083         $issuingimpossible{RESTRICTED} = 1;
1084     }
1085     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1086         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1087         my $code = $av->count ? $av->next->lib : '';
1088         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1089         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1090     }
1091     if ( C4::Context->preference("IndependentBranches") ) {
1092         my $userenv = C4::Context->userenv;
1093         unless ( C4::Context->IsSuperLibrarian() ) {
1094             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1095             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1096                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1097                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1098             }
1099             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1100               if ( $patron->branchcode ne $userenv->{branch} );
1101         }
1102     }
1103
1104     #
1105     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1106     #
1107     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1108     if ($rentalConfirmation) {
1109         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1110
1111         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1112         if ($itemtype_object) {
1113             my $accumulate_charge = $fees->accumulate_rentalcharge();
1114             if ( $accumulate_charge > 0 ) {
1115                 $rentalCharge += $accumulate_charge;
1116             }
1117         }
1118
1119         if ( $rentalCharge > 0 ) {
1120             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1121         }
1122     }
1123
1124     my $recall;
1125     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1126     # Only bother doing this if UseRecalls is enabled and the item is recallable
1127     # Don't look at recalls that are in transit
1128     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1129         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1130
1131         foreach my $r ( @recalls ) {
1132             if ( $r->item_id and
1133                 $r->item_id == $item_object->itemnumber and
1134                 $r->patron_id == $patron->borrowernumber and
1135                 ( $r->waiting or $r->requested ) ) {
1136                 $messages{RECALLED} = $r->id;
1137                 $recall = $r;
1138                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1139                 last;
1140             }
1141             elsif ( $r->item_id and
1142                 $r->item_id == $item_object->itemnumber and
1143                 $r->in_transit ) {
1144                 # recalled item is in transit
1145                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1146             }
1147             elsif ( $r->item_level and
1148                 $r->item_id == $item_object->itemnumber and
1149                 $r->patron_id != $patron->borrowernumber and
1150                 !$r->in_transit ) {
1151                 # this specific item has been recalled by a different patron
1152                 $needsconfirmation{RECALLED} = $r;
1153                 $recall = $r;
1154                 last;
1155             }
1156             elsif ( !$r->item_level and
1157                 $r->patron_id != $patron->borrowernumber and
1158                 !$r->in_transit ) {
1159                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1160                 $needsconfirmation{RECALLED} = $r;
1161                 $recall = $r;
1162                 last;
1163             }
1164         }
1165     }
1166
1167     unless ( $ignore_reserves and defined $recall ) {
1168         # See if the item is on reserve.
1169         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1170         if ($restype) {
1171             my $resbor = $res->{'borrowernumber'};
1172             if ( $resbor ne $patron->borrowernumber ) {
1173                 my $patron = Koha::Patrons->find( $resbor );
1174                 if ( $restype eq "Waiting" )
1175                 {
1176                     # The item is on reserve and waiting, but has been
1177                     # reserved by some other patron.
1178                     $needsconfirmation{RESERVE_WAITING} = 1;
1179                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1180                     $needsconfirmation{'ressurname'} = $patron->surname;
1181                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1182                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1183                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1184                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1185                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1186                 }
1187                 elsif ( $restype eq "Reserved" ) {
1188                     # The item is on reserve for someone else.
1189                     $needsconfirmation{RESERVED} = 1;
1190                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1191                     $needsconfirmation{'ressurname'} = $patron->surname;
1192                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1193                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1194                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1195                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1196                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1197                 }
1198                 elsif ( $restype eq "Transferred" ) {
1199                     # The item is determined hold being transferred for someone else.
1200                     $needsconfirmation{TRANSFERRED} = 1;
1201                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1202                     $needsconfirmation{'ressurname'} = $patron->surname;
1203                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1204                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1205                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1206                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1207                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1208                 }
1209                 elsif ( $restype eq "Processing" ) {
1210                     # The item is determined hold being processed for someone else.
1211                     $needsconfirmation{PROCESSING} = 1;
1212                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1213                     $needsconfirmation{'ressurname'} = $patron->surname;
1214                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1215                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1216                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1217                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1218                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1219                 }
1220             }
1221         }
1222     }
1223
1224     ## CHECK AGE RESTRICTION
1225     my $agerestriction  = $biblioitem->agerestriction;
1226     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1227     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1228         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1229             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1230         }
1231         else {
1232             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1233         }
1234     }
1235
1236     ## check for high holds decreasing loan period
1237     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1238         my $check = checkHighHolds( $item_object, $patron );
1239
1240         if ( $check->{exceeded} ) {
1241             my $highholds = {
1242                 num_holds  => $check->{outstanding},
1243                 duration   => $check->{duration},
1244                 returndate => $check->{due_date},
1245             };
1246             if ($override_high_holds) {
1247                 $alerts{HIGHHOLDS} = $highholds;
1248             }
1249             else {
1250                 $needsconfirmation{HIGHHOLDS} = $highholds;
1251             }
1252         }
1253     }
1254
1255     if (
1256         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1257         # don't do the multiple loans per bib check if we've
1258         # already determined that we've got a loan on the same item
1259         !$issuingimpossible{NO_MORE_RENEWALS} &&
1260         !$needsconfirmation{RENEW_ISSUE}
1261     ) {
1262         # Check if borrower has already issued an item from the same biblio
1263         # Only if it's not a subscription
1264         my $biblionumber = $item_object->biblionumber;
1265         require C4::Serials;
1266         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1267         unless ($is_a_subscription) {
1268             # FIXME Should be $patron->checkouts($args);
1269             my $checkouts = Koha::Checkouts->search(
1270                 {
1271                     borrowernumber => $patron->borrowernumber,
1272                     biblionumber   => $biblionumber,
1273                 },
1274                 {
1275                     join => 'item',
1276                 }
1277             );
1278             # if we get here, we don't already have a loan on this item,
1279             # so if there are any loans on this bib, ask for confirmation
1280             if ( $checkouts->count ) {
1281                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1282             }
1283         }
1284     }
1285
1286     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1287 }
1288
1289 =head2 CanBookBeReturned
1290
1291   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1292
1293 Check whether the item can be returned to the provided branch
1294
1295 =over 4
1296
1297 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1298
1299 =item C<$branch> is the branchcode where the return is taking place
1300
1301 =back
1302
1303 Returns:
1304
1305 =over 4
1306
1307 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1308
1309 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1310
1311 =back
1312
1313 =cut
1314
1315 sub CanBookBeReturned {
1316   my ($item, $branch) = @_;
1317   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1318
1319   # assume return is allowed to start
1320   my $allowed = 1;
1321   my $message;
1322
1323   # identify all cases where return is forbidden
1324   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1325      $allowed = 0;
1326      $message = $item->{'homebranch'};
1327   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1328      $allowed = 0;
1329      $message = $item->{'holdingbranch'};
1330   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1331      $allowed = 0;
1332      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1333   }
1334
1335   return ($allowed, $message);
1336 }
1337
1338 =head2 CheckHighHolds
1339
1340     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1341     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1342     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1343
1344 =cut
1345
1346 sub checkHighHolds {
1347     my ( $item, $patron ) = @_;
1348     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
1349
1350     my $return_data = {
1351         exceeded    => 0,
1352         outstanding => 0,
1353         duration    => 0,
1354         due_date    => undef,
1355     };
1356
1357
1358     # Count holds on this record, ignoring the borrowers own holds as they would be filled by the checkout
1359     my $holds = Koha::Holds->search({
1360         biblionumber => $item->biblionumber,
1361         borrowernumber => { '!=' => $patron->borrowernumber }
1362     });
1363
1364     if ( $holds->count() ) {
1365         $return_data->{outstanding} = $holds->count();
1366
1367         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1368         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1369         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1370
1371         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1372
1373         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1374
1375             # static means just more than a given number of holds on the record
1376
1377             # If the number of holds is not above the threshold, we can stop here
1378             if ( $holds->count() <= $decreaseLoanHighHoldsValue ) {
1379                 return $return_data;
1380             }
1381         }
1382         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1383
1384             # dynamic means X more than the number of holdable items on the record
1385
1386             # let's get the items
1387             my @items = $holds->next()->biblio()->items()->as_list;
1388
1389             # Remove any items with status defined to be ignored even if the would not make item unholdable
1390             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1391                 @items = grep { !$_->$status } @items;
1392             }
1393
1394             # Remove any items that are not holdable for this patron
1395             # We need to ignore hold counts as the borrower's own hold that will be filled by the checkout
1396             # could prevent them from placing further holds
1397             @items = grep { CanItemBeReserved( $patron, $_, undef, { ignore_hold_counts => 1 } )->{status} eq 'OK' } @items;
1398
1399             my $items_count = scalar @items;
1400
1401             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1402
1403             # If the number of holds is less than the count of items we have
1404             # plus the number of holds allowed above that count, we can stop here
1405             if ( $holds->count() <= $threshold ) {
1406                 return $return_data;
1407             }
1408         }
1409
1410         my $issuedate = dt_from_string();
1411
1412         my $itype = $item->effective_itemtype;
1413         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1414             {
1415                 categorycode => $patron->categorycode,
1416                 itemtype     => $itype,
1417                 branchcode   => $branchcode,
1418             }
1419         );
1420         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1421
1422         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron->unblessed );
1423
1424         my $rule = Koha::CirculationRules->get_effective_rule_value(
1425             {
1426                 categorycode => $patron->categorycode,
1427                 itemtype     => $item->effective_itemtype,
1428                 branchcode   => $branchcode,
1429                 rule_name    => 'decreaseloanholds',
1430             }
1431         );
1432
1433         my $duration;
1434         if ( defined($rule) && $rule ne '' ){
1435             # overrides decreaseLoanHighHoldsDuration syspref
1436             $duration = $rule;
1437         } else {
1438             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1439         }
1440         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1441         $reduced_datedue->set_hour($orig_due->hour);
1442         $reduced_datedue->set_minute($orig_due->minute);
1443         $reduced_datedue->truncate( to => 'minute' );
1444
1445         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1446             $return_data->{exceeded} = 1;
1447             $return_data->{duration} = $duration;
1448             $return_data->{due_date} = $reduced_datedue;
1449         }
1450     }
1451
1452     return $return_data;
1453 }
1454
1455 =head2 AddIssue
1456
1457   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1458
1459 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1460
1461 =over 4
1462
1463 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1464
1465 =item C<$barcode> is the barcode of the item being issued.
1466
1467 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1468 Calculated if empty.
1469
1470 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1471
1472 =item C<$issuedate> is a DateTime object for the date to issue the item (optional).
1473 Defaults to today.
1474
1475 AddIssue does the following things :
1476
1477   - step 01: check that there is a borrowernumber & a barcode provided
1478   - check for RENEWAL (book issued & being issued to the same patron)
1479       - renewal YES = Calculate Charge & renew
1480       - renewal NO  =
1481           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1482           * RESERVE PLACED ?
1483               - fill reserve if reserve to this patron
1484               - cancel reserve or not, otherwise
1485           * RECALL PLACED ?
1486               - fill recall if recall to this patron
1487               - cancel recall or not
1488               - revert recall's waiting status or not
1489           * TRANSFERT PENDING ?
1490               - complete the transfert
1491           * ISSUE THE BOOK
1492
1493 =back
1494
1495 =cut
1496
1497 sub AddIssue {
1498     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1499
1500     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1501     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1502     my $auto_renew = $params && $params->{auto_renew};
1503     my $cancel_recall = $params && $params->{cancel_recall};
1504     my $recall_id = $params && $params->{recall_id};
1505     my $dbh          = C4::Context->dbh;
1506     my $barcodecheck = CheckValidBarcode($barcode);
1507
1508     my $issue;
1509
1510     if ( $datedue && ref $datedue ne 'DateTime' ) {
1511         $datedue = dt_from_string($datedue);
1512     }
1513
1514     # $issuedate defaults to today.
1515     if ( !defined $issuedate ) {
1516         $issuedate = dt_from_string();
1517     }
1518     else {
1519         if ( ref $issuedate ne 'DateTime' ) {
1520             $issuedate = dt_from_string($issuedate);
1521
1522         }
1523     }
1524
1525     # Stop here if the patron or barcode doesn't exist
1526     if ( $borrower && $barcode && $barcodecheck ) {
1527         # find which item we issue
1528         my $item_object = Koha::Items->find({ barcode => $barcode })
1529           or return;    # if we don't get an Item, abort.
1530         my $item_unblessed = $item_object->unblessed;
1531
1532         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1533
1534         # get actual issuing if there is one
1535         my $actualissue = $item_object->checkout;
1536
1537         # check if we just renew the issue.
1538         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1539                 and not $switch_onsite_checkout ) {
1540             $datedue = AddRenewal(
1541                 $borrower->{'borrowernumber'},
1542                 $item_object->itemnumber,
1543                 $branchcode,
1544                 $datedue,
1545                 $issuedate,    # here interpreted as the renewal date
1546             );
1547         }
1548         else {
1549
1550             unless ($datedue) {
1551                 my $itype = $item_object->effective_itemtype;
1552                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1553
1554             }
1555
1556             # Check if we need to use an exact due date set by the ILL module
1557             if ( C4::Context->preference('ILLModule') ) {
1558                 # Check if there is an ILL connected with the biblio of the item we are issuing
1559                 my $ill_request = Koha::Illrequests->search({
1560                     biblio_id => $item_object->biblionumber,
1561                     borrowernumber => $borrower->{'borrowernumber'},
1562                     completed => undef,
1563                     due_date => { '!=', undef },
1564                 })->next;
1565
1566                 if ( $ill_request and length( $ill_request->due_date ) > 0 ) {
1567                     my $ill_dt = dt_from_string( $ill_request->due_date );
1568                     $ill_dt->set_hour(23);
1569                     $ill_dt->set_minute(59);
1570                     $datedue = $ill_dt;
1571                 }
1572             }
1573
1574             $datedue->truncate( to => 'minute' );
1575
1576             my $patron = Koha::Patrons->find( $borrower );
1577             my $library = Koha::Libraries->find( $branchcode );
1578             my $fees = Koha::Charges::Fees->new(
1579                 {
1580                     patron    => $patron,
1581                     library   => $library,
1582                     item      => $item_object,
1583                     to_date   => $datedue,
1584                 }
1585             );
1586
1587             # it's NOT a renewal
1588             if ( $actualissue and not $switch_onsite_checkout ) {
1589                 # This book is currently on loan, but not to the person
1590                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1591                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1592                 return unless $allowed;
1593                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1594                 # AddReturn certainly has side-effects, like onloan => undef
1595                 $item_object->discard_changes;
1596             }
1597
1598             if ( C4::Context->preference('UseRecalls') ) {
1599                 Koha::Recalls->move_recall(
1600                     {
1601                         action         => $cancel_recall,
1602                         recall_id      => $recall_id,
1603                         item           => $item_object,
1604                         borrowernumber => $borrower->{borrowernumber},
1605                     }
1606                 );
1607             }
1608
1609             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1610
1611             # Starting process for transfer job (checking transfert and validate it if we have one)
1612             if ( my $transfer = $item_object->get_transfer ) {
1613                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1614                 $transfer->set(
1615                     {
1616                         datearrived => dt_from_string,
1617                         tobranch    => C4::Context->userenv->{branch},
1618                         comments    => 'Forced branchtransfer'
1619                     }
1620                 )->store;
1621                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1622                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1623                     if ( $hold ) { # Is this really needed?
1624                         $hold->set( { found => undef } )->store;
1625                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1626                     }
1627                 }
1628             }
1629
1630             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1631             unless ($auto_renew) {
1632                 my $rule = Koha::CirculationRules->get_effective_rule_value(
1633                     {
1634                         categorycode => $borrower->{categorycode},
1635                         itemtype     => $item_object->effective_itemtype,
1636                         branchcode   => $branchcode,
1637                         rule_name    => 'auto_renew'
1638                     }
1639                 );
1640
1641                 $auto_renew = $rule if defined $rule && $rule ne '';
1642             }
1643
1644             my $issue_attributes = {
1645                 borrowernumber  => $borrower->{'borrowernumber'},
1646                 issuedate       => $issuedate,
1647                 date_due        => $datedue,
1648                 branchcode      => C4::Context->userenv->{'branch'},
1649                 onsite_checkout => $onsite_checkout,
1650                 auto_renew      => $auto_renew ? 1 : 0,
1651             };
1652
1653             # Get ID of logged in user.  if called from a batch job,
1654             # no user session exists and C4::Context->userenv() returns
1655             # the scalar '0'. Only do this if the syspref says so
1656             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1657                 my $userenv = C4::Context->userenv();
1658                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1659                 if ($usernumber) {
1660                     $issue_attributes->{issuer_id} = $usernumber;
1661                 }
1662             }
1663
1664             # In the case that the borrower has an on-site checkout
1665             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1666             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1667             if ($issue) {
1668                 $issue->set($issue_attributes)->store;
1669             }
1670             else {
1671                 $issue = Koha::Checkout->new(
1672                     {
1673                         itemnumber => $item_object->itemnumber,
1674                         %$issue_attributes,
1675                     }
1676                 )->store;
1677             }
1678             $issue->discard_changes;
1679             C4::Auth::track_login_daily( $borrower->{userid} );
1680             if ( $item_object->location && $item_object->location eq 'CART'
1681                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1682             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1683                 CartToShelf( $item_object->itemnumber );
1684             }
1685
1686             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1687                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1688             }
1689
1690             # Record if item was lost
1691             my $was_lost = $item_object->itemlost;
1692
1693             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1694             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1695             $item_object->itemlost(0);
1696             $item_object->onloan($datedue->ymd());
1697             $item_object->datelastborrowed( dt_from_string()->ymd() );
1698             $item_object->datelastseen( dt_from_string()->ymd() );
1699             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1700
1701             # If the item was lost, it has now been found, charge the overdue if necessary
1702             if ($was_lost) {
1703                 if ( $item_object->{_charge} ) {
1704                     $actualissue //= Koha::Old::Checkouts->search(
1705                         { itemnumber => $item_unblessed->{itemnumber} },
1706                         {
1707                             order_by => { '-desc' => 'returndate' },
1708                             rows     => 1
1709                         }
1710                     )->single;
1711                     unless ( exists( $borrower->{branchcode} ) ) {
1712                         my $patron = $actualissue->patron;
1713                         $borrower = $patron->unblessed;
1714                     }
1715                     _CalculateAndUpdateFine(
1716                         {
1717                             issue       => $actualissue,
1718                             item        => $item_unblessed,
1719                             borrower    => $borrower,
1720                             return_date => $issuedate
1721                         }
1722                     );
1723                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1724                         $item_object->itemnumber, undef, 'RENEWED' );
1725                 }
1726             }
1727
1728             # If it costs to borrow this book, charge it to the patron's account.
1729             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1730             if ( $charge && $charge > 0 ) {
1731                 AddIssuingCharge( $issue, $charge, 'RENT' );
1732             }
1733
1734             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1735             if ( $itemtype_object ) {
1736                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1737                 if ( $accumulate_charge > 0 ) {
1738                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1739                     $charge += $accumulate_charge;
1740                     $item_unblessed->{charge} = $charge;
1741                 }
1742             }
1743
1744             # Record the fact that this book was issued.
1745             C4::Stats::UpdateStats(
1746                 {
1747                     branch => C4::Context->userenv->{'branch'},
1748                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1749                     amount         => $charge,
1750                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1751                     itemnumber     => $item_object->itemnumber,
1752                     itemtype       => $item_object->effective_itemtype,
1753                     location       => $item_object->location,
1754                     borrowernumber => $borrower->{'borrowernumber'},
1755                     ccode          => $item_object->ccode,
1756                     categorycode   => $borrower->{'categorycode'}
1757                 }
1758             );
1759
1760             # Send a checkout slip.
1761             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1762             my %conditions        = (
1763                 branchcode   => $branchcode,
1764                 categorycode => $borrower->{categorycode},
1765                 item_type    => $item_object->effective_itemtype,
1766                 notification => 'CHECKOUT',
1767             );
1768             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1769                 SendCirculationAlert(
1770                     {
1771                         type     => 'CHECKOUT',
1772                         item     => $item_object->unblessed,
1773                         borrower => $borrower,
1774                         branch   => $branchcode,
1775                     }
1776                 );
1777             }
1778             logaction(
1779                 "CIRCULATION", "ISSUE",
1780                 $borrower->{'borrowernumber'},
1781                 $item_object->itemnumber,
1782             ) if C4::Context->preference("IssueLog");
1783
1784             Koha::Plugins->call('after_circ_action', {
1785                 action  => 'checkout',
1786                 payload => {
1787                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1788                     checkout => $issue->get_from_storage
1789                 }
1790             });
1791
1792             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1793                 {
1794                     biblio_ids => [ $item_object->biblionumber ]
1795                 }
1796             ) if C4::Context->preference('RealTimeHoldsQueue');
1797         }
1798     }
1799     return $issue;
1800 }
1801
1802 =head2 GetLoanLength
1803
1804   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1805
1806 Get loan length for an itemtype, a borrower type and a branch
1807
1808 =cut
1809
1810 sub GetLoanLength {
1811     my ( $categorycode, $itemtype, $branchcode ) = @_;
1812
1813     # Initialize default values
1814     my $rules = {
1815         issuelength   => 0,
1816         renewalperiod => 0,
1817         lengthunit    => 'days',
1818     };
1819
1820     my $found = Koha::CirculationRules->get_effective_rules( {
1821         branchcode => $branchcode,
1822         categorycode => $categorycode,
1823         itemtype => $itemtype,
1824         rules => [
1825             'issuelength',
1826             'renewalperiod',
1827             'lengthunit'
1828         ],
1829     } );
1830
1831     # Search for rules!
1832     foreach my $rule_name (keys %$found) {
1833         $rules->{$rule_name} = $found->{$rule_name};
1834     }
1835
1836     return $rules;
1837 }
1838
1839
1840 =head2 GetHardDueDate
1841
1842   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1843
1844 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1845
1846 =cut
1847
1848 sub GetHardDueDate {
1849     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1850
1851     my $rules = Koha::CirculationRules->get_effective_rules(
1852         {
1853             categorycode => $borrowertype,
1854             itemtype     => $itemtype,
1855             branchcode   => $branchcode,
1856             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1857         }
1858     );
1859
1860     if ( defined( $rules->{hardduedate} ) ) {
1861         if ( $rules->{hardduedate} ) {
1862             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1863         }
1864         else {
1865             return ( undef, undef );
1866         }
1867     }
1868 }
1869
1870 =head2 GetBranchBorrowerCircRule
1871
1872   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1873
1874 Retrieves circulation rule attributes that apply to the given
1875 branch and patron category, regardless of item type.
1876 The return value is a hashref containing the following key:
1877
1878 patron_maxissueqty - maximum number of loans that a
1879 patron of the given category can have at the given
1880 branch.  If the value is undef, no limit.
1881
1882 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1883 patron of the given category can have at the given
1884 branch.  If the value is undef, no limit.
1885
1886 This will check for different branch/category combinations in the following order:
1887 branch and category
1888 branch only
1889 category only
1890 default branch and category
1891
1892 If no rule has been found in the database, it will default to
1893 the buillt in rule:
1894
1895 patron_maxissueqty - undef
1896 patron_maxonsiteissueqty - undef
1897
1898 C<$branchcode> and C<$categorycode> should contain the
1899 literal branch code and patron category code, respectively - no
1900 wildcards.
1901
1902 =cut
1903
1904 sub GetBranchBorrowerCircRule {
1905     my ( $branchcode, $categorycode ) = @_;
1906
1907     # Initialize default values
1908     my $rules = {
1909         patron_maxissueqty       => undef,
1910         patron_maxonsiteissueqty => undef,
1911     };
1912
1913     # Search for rules!
1914     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1915         my $rule = Koha::CirculationRules->get_effective_rule(
1916             {
1917                 categorycode => $categorycode,
1918                 itemtype     => undef,
1919                 branchcode   => $branchcode,
1920                 rule_name    => $rule_name,
1921             }
1922         );
1923
1924         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1925     }
1926
1927     return $rules;
1928 }
1929
1930 =head2 GetBranchItemRule
1931
1932   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1933
1934 Retrieves circulation rule attributes that apply to the given
1935 branch and item type, regardless of patron category.
1936
1937 The return value is a hashref containing the following keys:
1938
1939 holdallowed => Hold policy for this branch and itemtype. Possible values:
1940   not_allowed:           No holds allowed.
1941   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1942   from_any_library:      Holds allowed from any patron.
1943   from_local_hold_group: Holds allowed from libraries in hold group
1944
1945 This searches branchitemrules in the following order:
1946
1947   * Same branchcode and itemtype
1948   * Same branchcode, itemtype '*'
1949   * branchcode '*', same itemtype
1950   * branchcode and itemtype '*'
1951
1952 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1953
1954 =cut
1955
1956 sub GetBranchItemRule {
1957     my ( $branchcode, $itemtype ) = @_;
1958
1959     # Search for rules!
1960     my $rules = Koha::CirculationRules->get_effective_rules({
1961         branchcode => $branchcode,
1962         itemtype => $itemtype,
1963         rules => ['holdallowed', 'hold_fulfillment_policy']
1964     });
1965
1966     # built-in default circulation rule
1967     $rules->{holdallowed} //= 'from_any_library';
1968     $rules->{hold_fulfillment_policy} //= 'any';
1969
1970     return $rules;
1971 }
1972
1973 =head2 AddReturn
1974
1975   ($doreturn, $messages, $iteminformation, $borrower) =
1976       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1977
1978 Returns a book.
1979
1980 =over 4
1981
1982 =item C<$barcode> is the bar code of the book being returned.
1983
1984 =item C<$branch> is the code of the branch where the book is being returned.
1985
1986 =item C<$exemptfine> indicates that overdue charges for the item will be
1987 removed. Optional.
1988
1989 =item C<$return_date> allows the default return date to be overridden
1990 by the given return date. Optional.
1991
1992 =back
1993
1994 C<&AddReturn> returns a list of four items:
1995
1996 C<$doreturn> is true iff the return succeeded.
1997
1998 C<$messages> is a reference-to-hash giving feedback on the operation.
1999 The keys of the hash are:
2000
2001 =over 4
2002
2003 =item C<BadBarcode>
2004
2005 No item with this barcode exists. The value is C<$barcode>.
2006
2007 =item C<NotIssued>
2008
2009 The book is not currently on loan. The value is C<$barcode>.
2010
2011 =item C<withdrawn>
2012
2013 This book has been withdrawn/cancelled. The value should be ignored.
2014
2015 =item C<Wrongbranch>
2016
2017 This book has was returned to the wrong branch.  The value is a hashref
2018 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2019 contain the branchcode of the incorrect and correct return library, respectively.
2020
2021 =item C<ResFound>
2022
2023 The item was reserved. The value is a reference-to-hash whose keys are
2024 fields from the reserves table of the Koha database, and
2025 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2026 either C<Waiting>, C<Reserved>, or 0.
2027
2028 =item C<WasReturned>
2029
2030 Value 1 if return is successful.
2031
2032 =item C<NeedsTransfer>
2033
2034 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2035
2036 =item C<RecallFound>
2037
2038 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2039 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2040 branchcode.
2041
2042 =item C<TransferredRecall>
2043
2044 This item has been transferred to this branch to fill a recall. The recall object is returned.
2045
2046 =back
2047
2048 C<$iteminformation> is a reference-to-hash, giving information about the
2049 returned item from the issues table.
2050
2051 C<$borrower> is a reference-to-hash, giving information about the
2052 patron who last borrowed the book.
2053
2054 =cut
2055
2056 sub AddReturn {
2057     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2058
2059     if ($branch and not Koha::Libraries->find($branch)) {
2060         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2061         undef $branch;
2062     }
2063     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2064     my $return_date_specified = !!$return_date;
2065     $return_date //= dt_from_string();
2066     my $messages;
2067     my $patron;
2068     my $doreturn       = 1;
2069     my $validTransfer = 1;
2070     my $stat_type = 'return';
2071
2072     # get information on item
2073     my $item = Koha::Items->find({ barcode => $barcode });
2074     unless ($item) {
2075         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2076     }
2077
2078     my $itemnumber = $item->itemnumber;
2079     my $itemtype = $item->effective_itemtype;
2080
2081     my $issue  = $item->checkout;
2082     if ( $issue ) {
2083         $patron = $issue->patron
2084             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2085                 . Dumper($issue->unblessed) . "\n";
2086     } else {
2087         $messages->{'NotIssued'} = $barcode;
2088         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2089
2090         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2091         $doreturn = 0;
2092         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2093         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2094         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2095            $messages->{'LocalUse'} = 1;
2096            $stat_type = 'localuse';
2097         }
2098     }
2099
2100     if ( $item->withdrawn ) { # book has been cancelled
2101         $messages->{'withdrawn'} = 1;
2102
2103         # In the case where we block return of withdrawn, we should completely block the return
2104         # without updating item statuses, so we exit early
2105         return ( 0, $messages, $issue, ( $patron ? $patron->unblessed : {} ))
2106             if C4::Context->preference("BlockReturnOfWithdrawnItems");
2107     }
2108
2109
2110         # full item data, but no borrowernumber or checkout info (no issue)
2111     my $hbr = Koha::CirculationRules->get_return_branch_policy($item);
2112         # get the proper branch to which to return the item
2113     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2114         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2115     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2116
2117     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2118     my $patron_unblessed = $patron ? $patron->unblessed : {};
2119
2120     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2121     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2122     if ($update_loc_rules) {
2123         if (defined $update_loc_rules->{_ALL_}) {
2124             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2125             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2126             if (
2127                 ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) ||
2128                 (!defined $item->location && $update_loc_rules->{_ALL_} ne "")
2129                ) {
2130                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2131                 $item->location($update_loc_rules->{_ALL_})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2132             }
2133         }
2134         else {
2135             foreach my $key ( keys %$update_loc_rules ) {
2136                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2137                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2138                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2139                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2140                     $item->location($update_loc_rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2141                     last;
2142                 }
2143             }
2144         }
2145     }
2146
2147     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2148     if ($yaml) {
2149         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2150         my $rules;
2151         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2152         if ($@) {
2153             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2154         }
2155         else {
2156             foreach my $key ( keys %$rules ) {
2157                 if ( $item->notforloan eq $key ) {
2158                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2159                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 }) unless $rules->{$key} eq 'ONLYMESSAGE';
2160                     last;
2161                 }
2162             }
2163         }
2164     }
2165
2166     # check if the return is allowed at this branch
2167     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2168     unless ($returnallowed){
2169         $messages->{'Wrongbranch'} = {
2170             Wrongbranch => $branch,
2171             Rightbranch => $message
2172         };
2173         $doreturn = 0;
2174         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2175         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2176         return ( $doreturn, $messages, $issue, $patron_unblessed);
2177     }
2178
2179     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2180         $doreturn = 0;
2181     }
2182
2183     # case of a return of document (deal with issues and holdingbranch)
2184     if ($doreturn) {
2185         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2186         $patron or warn "AddReturn without current borrower";
2187
2188         if ($patron) {
2189             eval {
2190                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2191             };
2192             unless ( $@ ) {
2193                 if (
2194                     (
2195                         C4::Context->preference('CalculateFinesOnReturn')
2196                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2197                     )
2198                     && !$item->itemlost
2199                   )
2200                 {
2201                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2202                 }
2203             } else {
2204                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2205
2206                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2207                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2208
2209                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2210             }
2211
2212             # FIXME is the "= 1" right?  This could be the borrower hash.
2213             $messages->{'WasReturned'} = 1;
2214
2215         } else {
2216             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2217         }
2218     }
2219
2220     # the holdingbranch is updated if the document is returned to another location.
2221     # this is always done regardless of whether the item was on loan or not
2222     if ($item->holdingbranch ne $branch) {
2223         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2224     }
2225
2226     my $item_was_lost = $item->itemlost;
2227     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2228     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2229
2230     # fix up the accounts.....
2231     if ($item_was_lost) {
2232         $messages->{'WasLost'} = 1;
2233         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2234             my @object_messages = @{ $updated_item->object_messages };
2235             for my $message (@object_messages) {
2236                 $messages->{'LostItemFeeRefunded'} = 1
2237                   if $message->message eq 'lost_refunded';
2238                 $messages->{'ProcessingFeeRefunded'} = 1
2239                   if $message->message eq 'processing_refunded';
2240                 $messages->{'LostItemFeeRestored'} = 1
2241                   if $message->message eq 'lost_restored';
2242
2243                 if ( $message->message eq 'lost_charge' ) {
2244                     $issue //= Koha::Old::Checkouts->search(
2245                         { itemnumber => $item->itemnumber },
2246                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2247                     )->single;
2248                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2249                         my $patron = $issue->patron;
2250                         $patron_unblessed = $patron->unblessed;
2251                     }
2252                     _CalculateAndUpdateFine(
2253                         {
2254                             issue       => $issue,
2255                             item        => $item->unblessed,
2256                             borrower    => $patron_unblessed,
2257                             return_date => $return_date
2258                         }
2259                     );
2260                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2261                         $item->itemnumber, undef, 'RETURNED' );
2262                     $messages->{'LostItemFeeCharged'} = 1;
2263                 }
2264             }
2265         }
2266     }
2267
2268     # check if we have a transfer for this document
2269     my $transfer = $item->get_transfer;
2270
2271     # if we have a transfer to complete, we update the line of transfers with the datearrived
2272     if ($transfer) {
2273         $validTransfer = 0;
2274         if ( $transfer->in_transit ) {
2275             if ( $transfer->tobranch eq $branch ) {
2276                 $transfer->receive;
2277                 $messages->{'TransferArrived'} = $transfer->frombranch;
2278                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2279                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2280             }
2281             else {
2282                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2283                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2284                 $messages->{'TransferTrigger'}   = $transfer->reason;
2285             }
2286         }
2287         else {
2288             if ( $transfer->tobranch eq $branch ) {
2289                 $transfer->receive;
2290                 $messages->{'TransferArrived'} = $transfer->frombranch;
2291                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2292                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2293             }
2294             else {
2295                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2296                 $messages->{'TransferTrigger'} = $transfer->reason;
2297             }
2298         }
2299     }
2300
2301     # fix up the overdues in accounts...
2302     if ($borrowernumber) {
2303         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2304         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2305
2306         if ( $issue and $issue->is_overdue($return_date) ) {
2307         # fix fine days
2308             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2309             if ($debardate and $debardate ne "9999-12-31") {
2310                 if ($reminder){
2311                     $messages->{'PrevDebarred'} = $debardate;
2312                 } else {
2313                     $messages->{'Debarred'} = $debardate;
2314                 }
2315             } elsif ($patron->debarred) {
2316                 if ( $patron->debarred eq "9999-12-31") {
2317                     $messages->{'ForeverDebarred'} = $patron->debarred;
2318                 } else {
2319                     my $borrower_debar_dt = dt_from_string( $patron->debarred );
2320                     $borrower_debar_dt->truncate(to => 'day');
2321                     my $today_dt = $return_date->clone()->truncate(to => 'day');
2322                     if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2323                         $messages->{'PrevDebarred'} = $patron->debarred;
2324                     }
2325                 }
2326             }
2327         # there's no overdue on the item but borrower had been previously debarred
2328         } elsif ( $issue->date_due and $patron->debarred ) {
2329              if ( $patron->debarred eq "9999-12-31") {
2330                 $messages->{'ForeverDebarred'} = $patron->debarred;
2331              } else {
2332                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2333                   $borrower_debar_dt->truncate(to => 'day');
2334                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2335                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2336                       $messages->{'PrevDebarred'} = $patron->debarred;
2337                   }
2338              }
2339         }
2340     }
2341
2342     # find recalls...
2343     if ( C4::Context->preference('UseRecalls') ) {
2344         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2345         my $recall = undef;
2346         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2347         if ( defined $recall ) {
2348             $messages->{RecallFound} = $recall;
2349             if ( $recall->pickup_library_id ne $branch ) {
2350                 $messages->{RecallNeedsTransfer} = $branch;
2351             }
2352         }
2353     }
2354
2355     # find reserves.....
2356     # launch the Checkreserves routine to find any holds
2357     my ($resfound, $resrec);
2358     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2359     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2360     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2361     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2362         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2363         $resfound = 'Reserved';
2364         $resrec = $hold->unblessed;
2365     }
2366     if ($resfound) {
2367           $resrec->{'ResFound'} = $resfound;
2368         $messages->{'ResFound'} = $resrec;
2369     }
2370
2371     # Record the fact that this book was returned.
2372     my $categorycode = $patron_unblessed ? $patron_unblessed->{categorycode} : undef;
2373     C4::Stats::UpdateStats({
2374         branch         => $branch,
2375         type           => $stat_type,
2376         itemnumber     => $itemnumber,
2377         itemtype       => $itemtype,
2378         location       => $item->location,
2379         borrowernumber => $borrowernumber,
2380         ccode          => $item->ccode,
2381         categorycode   => $categorycode,
2382     });
2383
2384     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2385     if ( $patron ) {
2386         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2387         my %conditions = (
2388             branchcode   => $branch,
2389             categorycode => $patron->categorycode,
2390             item_type    => $itemtype,
2391             notification => 'CHECKIN',
2392         );
2393         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2394             SendCirculationAlert({
2395                 type     => 'CHECKIN',
2396                 item     => $item->unblessed,
2397                 borrower => $patron->unblessed,
2398                 branch   => $branch,
2399                 issue    => $issue
2400             });
2401         }
2402
2403         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2404             if C4::Context->preference("ReturnLog");
2405         }
2406
2407     # Check if this item belongs to a biblio record that is attached to an
2408     # ILL request, if it is we need to update the ILL request's status
2409     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2410         my $request = Koha::Illrequests->find(
2411             { biblio_id => $item->biblio->biblionumber }
2412         );
2413         $request->status('RET') if $request;
2414     }
2415
2416     if ( C4::Context->preference('UseRecalls') ) {
2417         # all recalls that have triggered a transfer will have an allocated itemnumber
2418         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2419         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2420             $messages->{TransferredRecall} = $transfer_recall;
2421         }
2422     }
2423
2424     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2425     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2426         && ( $doreturn or $messages->{'NotIssued'} )
2427         and !$resfound
2428         and ( $branch ne $returnbranch )
2429         and not $messages->{'WrongTransfer'}
2430         and not $messages->{'WasTransfered'}
2431         and not $messages->{TransferredRecall}
2432         and not $messages->{RecallNeedsTransfer} )
2433     {
2434         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2435         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2436             (C4::Context->preference("UseBranchTransferLimits") and
2437              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2438            )) {
2439             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2440             $messages->{'WasTransfered'} = $returnbranch;
2441             $messages->{'TransferTrigger'} = $transfer_trigger;
2442         } else {
2443             $messages->{'NeedsTransfer'} = $returnbranch;
2444             $messages->{'TransferTrigger'} = $transfer_trigger;
2445         }
2446     }
2447
2448     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2449         my $claims = Koha::Checkouts::ReturnClaims->search(
2450            {
2451                itemnumber => $item->id,
2452                resolution => undef,
2453            }
2454         );
2455
2456         if ( $claims->count ) {
2457             $messages->{ReturnClaims} = $claims;
2458         }
2459     }
2460
2461     # Check for bundle status
2462     if ( $item->in_bundle ) {
2463         my $host = $item->bundle_host;
2464         $messages->{InBundle} = $host;
2465     }
2466
2467     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2468     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2469
2470     if ( $doreturn and $issue ) {
2471         my $checkin = Koha::Old::Checkouts->find($issue->id);
2472
2473         Koha::Plugins->call('after_circ_action', {
2474             action  => 'checkin',
2475             payload => {
2476                 checkout=> $checkin
2477             }
2478         });
2479
2480         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2481             {
2482                 biblio_ids => [ $item->biblionumber ]
2483             }
2484         ) if C4::Context->preference('RealTimeHoldsQueue');
2485     }
2486
2487     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2488 }
2489
2490 =head2 MarkIssueReturned
2491
2492   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2493
2494 Unconditionally marks an issue as being returned by
2495 moving the C<issues> row to C<old_issues> and
2496 setting C<returndate> to the current date.
2497
2498 if C<$returndate> is specified (in iso format), it is used as the date
2499 of the return.
2500
2501 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2502 the old_issue is immediately anonymised
2503
2504 Ideally, this function would be internal to C<C4::Circulation>,
2505 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2506 and offline_circ/process_koc.pl.
2507
2508 The last optional parameter allos passing skip_record_index to the item store call.
2509
2510 =cut
2511
2512 sub MarkIssueReturned {
2513     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2514
2515     # Retrieve the issue
2516     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2517
2518     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2519
2520     my $issue_id = $issue->issue_id;
2521
2522     my $schema = Koha::Database->schema;
2523
2524     # FIXME Improve the return value and handle it from callers
2525     $schema->txn_do(sub {
2526
2527         my $patron = Koha::Patrons->find( $borrowernumber );
2528
2529         # Update the returndate value
2530         if ( $returndate ) {
2531             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2532         }
2533         else {
2534             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2535         }
2536
2537         # Create the old_issues entry
2538         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2539
2540         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2541         if ( $privacy && $privacy == 2) {
2542             $old_checkout->anonymize;
2543         }
2544
2545         # And finally delete the issue
2546         $issue->delete;
2547
2548         $issue->item->onloan(undef)->store(
2549             {   log_action        => 0,
2550                 skip_record_index => $params->{skip_record_index},
2551                 skip_holds_queue  => $params->{skip_holds_queue}
2552             }
2553         );
2554
2555         if ( C4::Context->preference('StoreLastBorrower') ) {
2556             my $item = Koha::Items->find( $itemnumber );
2557             $item->last_returned_by( $patron );
2558         }
2559
2560         # Remove any OVERDUES related debarment if the borrower has no overdues
2561         my $overdue_restrictions = $patron->restrictions->search({ type => 'OVERDUES' });
2562         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2563           && $patron->debarred
2564           && !$patron->has_overdues
2565           && $overdue_restrictions->count
2566         ) {
2567             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2568         }
2569
2570     });
2571
2572     return $issue_id;
2573 }
2574
2575 =head2 _debar_user_on_return
2576
2577     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2578
2579 C<$borrower> borrower hashref
2580
2581 C<$item> item hashref
2582
2583 C<$datedue> date due DateTime object
2584
2585 C<$returndate> DateTime object representing the return time
2586
2587 Internal function, called only by AddReturn that calculates and updates
2588  the user fine days, and debars them if necessary.
2589
2590 Should only be called for overdue returns
2591
2592 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2593 to ease testing.
2594
2595 =cut
2596
2597 sub _calculate_new_debar_dt {
2598     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2599
2600     my $branchcode = _GetCircControlBranch( $item, $borrower );
2601     my $circcontrol = C4::Context->preference('CircControl');
2602     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2603         {   categorycode => $borrower->{categorycode},
2604             itemtype     => $item->{itype},
2605             branchcode   => $branchcode,
2606             rules => [
2607                 'finedays',
2608                 'lengthunit',
2609                 'firstremind',
2610                 'maxsuspensiondays',
2611                 'suspension_chargeperiod',
2612             ]
2613         }
2614     );
2615     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2616     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2617     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2618
2619     return unless $finedays;
2620
2621     # finedays is in days, so hourly loans must multiply by 24
2622     # thus 1 hour late equals 1 day suspension * finedays rate
2623     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2624
2625     # grace period is measured in the same units as the loan
2626     my $grace =
2627       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2628
2629     my $deltadays = DateTime::Duration->new(
2630         days => $chargeable_units
2631     );
2632
2633     if ( $deltadays->subtract($grace)->is_positive() ) {
2634         my $suspension_days = $deltadays * $finedays;
2635
2636         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2637             # No need to / 1 and do not consider / 0
2638             $suspension_days = DateTime::Duration->new(
2639                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2640             );
2641         }
2642
2643         # If the max suspension days is < than the suspension days
2644         # the suspension days is limited to this maximum period.
2645         my $max_sd = $issuing_rule->{maxsuspensiondays};
2646         if ( defined $max_sd && $max_sd ne '' ) {
2647             $max_sd = DateTime::Duration->new( days => $max_sd );
2648             $suspension_days = $max_sd
2649               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2650         }
2651
2652         my ( $has_been_extended );
2653         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2654             my $patron = Koha::Patrons->find($borrower->{borrowernumber});
2655             my $debarment = $patron->restrictions->search({type => 'SUSPENSION' },{rows => 1})->single;
2656             if ( $debarment ) {
2657                 $return_date = dt_from_string( $debarment->expiration, 'sql' );
2658                 $has_been_extended = 1;
2659             }
2660         }
2661
2662         my $new_debar_dt;
2663         # Use the calendar or not to calculate the debarment date
2664         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2665             my $calendar = Koha::Calendar->new(
2666                 branchcode => $branchcode,
2667                 days_mode  => 'Calendar'
2668             );
2669             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2670         }
2671         else {
2672             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2673         }
2674         return $new_debar_dt;
2675     }
2676     return;
2677 }
2678
2679 sub _debar_user_on_return {
2680     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2681
2682     $return_date //= dt_from_string();
2683
2684     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2685
2686     return unless $new_debar_dt;
2687
2688     Koha::Patron::Debarments::AddUniqueDebarment({
2689         borrowernumber => $borrower->{borrowernumber},
2690         expiration     => $new_debar_dt->ymd(),
2691         type           => 'SUSPENSION',
2692     });
2693     # if borrower was already debarred but does not get an extra debarment
2694     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2695     my ($new_debarment_str, $is_a_reminder);
2696     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2697         $is_a_reminder = 1;
2698         $new_debarment_str = $borrower->{debarred};
2699     } else {
2700         $new_debarment_str = $new_debar_dt->ymd();
2701     }
2702     # FIXME Should return a DateTime object
2703     return $new_debarment_str, $is_a_reminder;
2704 }
2705
2706 =head2 _FixOverduesOnReturn
2707
2708    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2709
2710 C<$borrowernumber> borrowernumber
2711
2712 C<$itemnumber> itemnumber
2713
2714 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2715
2716 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2717
2718 Internal function
2719
2720 =cut
2721
2722 sub _FixOverduesOnReturn {
2723     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2724     unless( $borrowernumber ) {
2725         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2726         return;
2727     }
2728     unless( $item ) {
2729         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2730         return;
2731     }
2732     unless( $status ) {
2733         warn "_FixOverduesOnReturn() not supplied valid status";
2734         return;
2735     }
2736
2737     my $schema = Koha::Database->schema;
2738
2739     my $result = $schema->txn_do(
2740         sub {
2741             # check for overdue fine
2742             my $accountlines = Koha::Account::Lines->search(
2743                 {
2744                     borrowernumber  => $borrowernumber,
2745                     itemnumber      => $item,
2746                     debit_type_code => 'OVERDUE',
2747                     status          => 'UNRETURNED'
2748                 }
2749             );
2750             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2751
2752             my $accountline = $accountlines->next;
2753             my $payments = $accountline->credits;
2754
2755             my $amountoutstanding = $accountline->amountoutstanding;
2756             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2757                 $accountline->delete;
2758                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2759             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2760                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2761                 my $credit = $account->add_credit(
2762                     {
2763                         amount     => $amountoutstanding,
2764                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2765                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2766                         interface  => C4::Context->interface,
2767                         type       => 'FORGIVEN',
2768                         item_id    => $item
2769                     }
2770                 );
2771
2772                 $credit->apply({ debits => [ $accountline ] });
2773
2774                 if (C4::Context->preference("FinesLog")) {
2775                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2776                 }
2777             }
2778
2779             $accountline->status($status);
2780             return $accountline->store();
2781         }
2782     );
2783
2784     return $result;
2785 }
2786
2787 =head2 _GetCircControlBranch
2788
2789    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2790
2791 Internal function :
2792
2793 Return the library code to be used to determine which circulation
2794 policy applies to a transaction.  Looks up the CircControl and
2795 HomeOrHoldingBranch system preferences.
2796
2797 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2798
2799 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2800
2801 =cut
2802
2803 sub _GetCircControlBranch {
2804     my ($item, $borrower) = @_;
2805     my $circcontrol = C4::Context->preference('CircControl');
2806     my $branch;
2807
2808     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2809         $branch= C4::Context->userenv->{'branch'};
2810     } elsif ($circcontrol eq 'PatronLibrary') {
2811         $branch=$borrower->{branchcode};
2812     } else {
2813         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2814         $branch = $item->{$branchfield};
2815         # default to item home branch if holdingbranch is used
2816         # and is not defined
2817         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2818             $branch = $item->{homebranch};
2819         }
2820     }
2821     return $branch;
2822 }
2823
2824 =head2 GetUpcomingDueIssues
2825
2826   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2827
2828 =cut
2829
2830 sub GetUpcomingDueIssues {
2831     my $params = shift;
2832
2833     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2834     my $dbh = C4::Context->dbh;
2835     my $statement;
2836     $statement = q{
2837         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2838         FROM issues
2839         LEFT JOIN items USING (itemnumber)
2840         LEFT JOIN branches ON branches.branchcode =
2841     };
2842     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2843     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2844     my @bind_parameters = ( $params->{'days_in_advance'} );
2845
2846     my $sth = $dbh->prepare( $statement );
2847     $sth->execute( @bind_parameters );
2848     my $upcoming_dues = $sth->fetchall_arrayref({});
2849
2850     return $upcoming_dues;
2851 }
2852
2853 =head2 CanBookBeRenewed
2854
2855   ($ok,$error,$info) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2856
2857 Find out whether a borrowed item may be renewed.
2858
2859 C<$borrowernumber> is the borrower number of the patron who currently
2860 has the item on loan.
2861
2862 C<$itemnumber> is the number of the item to renew.
2863
2864 C<$override_limit>, if supplied with a true value, causes
2865 the limit on the number of times that the loan can be renewed
2866 (as controlled by the item type) to be ignored. Overriding also allows
2867 to renew sooner than "No renewal before" and to manually renew loans
2868 that are automatically renewed.
2869
2870 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2871 item must currently be on loan to the specified borrower; renewals
2872 must be allowed for the item's type; and the borrower must not have
2873 already renewed the loan.
2874     $error will contain the reason the renewal can not proceed
2875     $info will contain a hash of additional info
2876       currently 'soonest_renew_date' if error is 'too soon'
2877
2878 =cut
2879
2880 sub CanBookBeRenewed {
2881     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2882
2883     my $auto_renew = "no";
2884     my $soonest;
2885
2886     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2887     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2888     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2889     return ( 0, 'item_denied_renewal') if $item->is_denied_renewal;
2890
2891     my $patron = $issue->patron or return;
2892
2893     # override_limit will override anything else except on_reserve
2894     unless ( $override_limit ){
2895         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2896         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2897             {
2898                 categorycode => $patron->categorycode,
2899                 itemtype     => $item->effective_itemtype,
2900                 branchcode   => $branchcode,
2901                 rules => [
2902                     'renewalsallowed',
2903                     'lengthunit',
2904                     'unseen_renewals_allowed'
2905                 ]
2906             }
2907         );
2908
2909         return ( 0, "too_many" )
2910           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals_count;
2911
2912         return ( 0, "too_unseen" )
2913           if C4::Context->preference('UnseenRenewals') &&
2914             looks_like_number($issuing_rule->{unseen_renewals_allowed}) &&
2915             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2916
2917         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2918         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2919         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2920         my $restricted  = $patron->is_debarred;
2921         my $hasoverdues = $patron->has_overdues;
2922
2923         if ( $restricted and $restrictionblockrenewing ) {
2924             return ( 0, 'restriction');
2925         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2926             return ( 0, 'overdue');
2927         }
2928
2929         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
2930             patron     => $patron,
2931             item       => $item,
2932             branchcode => $branchcode,
2933             issue      => $issue
2934         });
2935         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
2936         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
2937         # extra notices being sent. Cron also implies no override
2938         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
2939         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
2940         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
2941     }
2942
2943     if ( C4::Context->preference('UseRecalls') ) {
2944         my $recall = undef;
2945         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2946         if ( defined $recall ) {
2947             if ( $recall->item_level ) {
2948                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
2949                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
2950             } else {
2951                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
2952                 return ( 0, 'recalled' ) unless ( $recall->waiting );
2953             }
2954         }
2955     }
2956
2957     my $fillable_holds = Koha::Holds->search(
2958         {
2959             biblionumber => $item->biblionumber,
2960             non_priority => 0,
2961             found        => undef,
2962             reservedate  => { '<=' => \'NOW()' },
2963             suspend      => 0,
2964         },
2965         { prefetch => 'patron' }
2966     );
2967     if ( $fillable_holds->count ) {
2968         if ( C4::Context->preference('AllowRenewalIfOtherItemsAvailable') ) {
2969             my @possible_holds = $fillable_holds->as_list;
2970
2971             # Get all other items that could possibly fill reserves
2972             # FIXME We could join reserves (or more tables) here to eliminate some checks later
2973             my @other_items = Koha::Items->search({
2974                 biblionumber => $item->biblionumber,
2975                 onloan       => undef,
2976                 notforloan   => 0,
2977                 -not         => { itemnumber => $itemnumber } })->as_list;
2978
2979             return ( 0, "on_reserve" ) if @possible_holds && (scalar @other_items < scalar @possible_holds);
2980
2981             my %matched_items;
2982             foreach my $possible_hold (@possible_holds) {
2983                 my $fillable = 0;
2984                 my $patron_with_reserve = Koha::Patrons->find($possible_hold->borrowernumber);
2985                 my $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron_with_reserve });
2986
2987                 # FIXME: We are not checking whether the item we are renewing can fill the hold
2988
2989                 foreach my $other_item (@other_items) {
2990                   next if defined $matched_items{$other_item->itemnumber};
2991                   next if IsItemOnHoldAndFound( $other_item->itemnumber );
2992                   next unless IsAvailableForItemLevelRequest($other_item, $patron_with_reserve, undef, $items_any_available);
2993                   next unless CanItemBeReserved($patron_with_reserve,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
2994                   # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
2995                   # CanItemBeReserved checks 'rules' and 'policies' which means
2996                   # items will fill holds at checkin that are rejected here
2997                   $fillable = 1;
2998                   $matched_items{$other_item->itemnumber} = 1;
2999                   last;
3000                 }
3001                 return ( 0, "on_reserve" ) unless $fillable;
3002             }
3003
3004         } else {
3005             my ($status, $matched_reserve, $possible_reserves) = CheckReserves($itemnumber);
3006             return ( 0, "on_reserve" ) if $status;
3007         }
3008     }
3009
3010     return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
3011     $soonest = GetSoonestRenewDate($issue);
3012     if ( $soonest > dt_from_string() ){
3013         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
3014     }
3015
3016     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
3017
3018     return ( 1, undef );
3019 }
3020
3021 =head2 AddRenewal
3022
3023   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
3024
3025 Renews a loan.
3026
3027 C<$borrowernumber> is the borrower number of the patron who currently
3028 has the item.
3029
3030 C<$itemnumber> is the number of the item to renew.
3031
3032 C<$branch> is the library where the renewal took place (if any).
3033            The library that controls the circ policies for the renewal is retrieved from the issues record.
3034
3035 C<$datedue> can be a DateTime object used to set the due date.
3036
3037 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3038 this parameter is not supplied, lastreneweddate is set to the current date.
3039
3040 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3041 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3042 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3043 syspref)
3044
3045 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3046 from the book's item type.
3047
3048 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3049 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3050 fallback to a true value
3051
3052 =cut
3053
3054 sub AddRenewal {
3055     my $borrowernumber  = shift;
3056     my $itemnumber      = shift or return;
3057     my $branch          = shift;
3058     my $datedue         = shift;
3059     my $lastreneweddate = shift || dt_from_string();
3060     my $skipfinecalc    = shift;
3061     my $seen            = shift;
3062
3063     # Fallback on a 'seen' renewal
3064     $seen = defined $seen && $seen == 0 ? 0 : 1;
3065
3066     my $item_object   = Koha::Items->find($itemnumber) or return;
3067     my $biblio = $item_object->biblio;
3068     my $issue  = $item_object->checkout;
3069     my $item_unblessed = $item_object->unblessed;
3070
3071     my ($package, $filename, $line) = caller;
3072     my $renewal_type = $filename =~ m/automatic_renewals.pl/ ? "Automatic" : "Manual";
3073
3074     my $dbh = C4::Context->dbh;
3075
3076     return unless $issue;
3077
3078     $borrowernumber ||= $issue->borrowernumber;
3079
3080     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3081         $datedue = dt_from_string($datedue, 'sql');
3082     }
3083
3084     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3085     my $patron_unblessed = $patron->unblessed;
3086
3087     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3088
3089     my $schema = Koha::Database->schema;
3090     $schema->txn_do(sub{
3091
3092         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3093             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3094         }
3095         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3096
3097         # If the due date wasn't specified, calculate it by adding the
3098         # book's loan length to today's date or the current due date
3099         # based on the value of the RenewalPeriodBase syspref.
3100         my $itemtype = $item_object->effective_itemtype;
3101         unless ($datedue) {
3102
3103             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3104                                             dt_from_string( $issue->date_due, 'sql' ) :
3105                                             dt_from_string();
3106             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3107         }
3108
3109         my $fees = Koha::Charges::Fees->new(
3110             {
3111                 patron    => $patron,
3112                 library   => $circ_library,
3113                 item      => $item_object,
3114                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3115                 to_date   => dt_from_string($datedue),
3116             }
3117         );
3118
3119         # Increment the unseen renewals, if appropriate
3120         # We only do so if the syspref is enabled and
3121         # a maximum value has been set in the circ rules
3122         my $unseen_renewals = $issue->unseen_renewals;
3123         if (C4::Context->preference('UnseenRenewals')) {
3124             my $rule = Koha::CirculationRules->get_effective_rule(
3125                 {   categorycode => $patron->categorycode,
3126                     itemtype     => $item_object->effective_itemtype,
3127                     branchcode   => $circ_library->branchcode,
3128                     rule_name    => 'unseen_renewals_allowed'
3129                 }
3130             );
3131             if (!$seen && $rule && looks_like_number($rule->rule_value)) {
3132                 $unseen_renewals++;
3133             } else {
3134                 # If the renewal is seen, unseen should revert to 0
3135                 $unseen_renewals = 0;
3136             }
3137         }
3138
3139         # Update the issues record to have the new due date, and a new count
3140         # of how many times it has been renewed.
3141         my $renews = ( $issue->renewals_count || 0 ) + 1;
3142         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals_count = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3143
3144         eval{
3145             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3146         };
3147         if( $sth->err ){
3148             Koha::Exceptions::Checkout::FailedRenewal->throw(
3149                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3150             );
3151         }
3152
3153         # Update the renewal count on the item, and tell zebra to reindex
3154         $renews = ( $item_object->renewals || 0 ) + 1;
3155         $item_object->renewals($renews);
3156         $item_object->onloan($datedue);
3157         $item_object->store({ log_action => 0 });
3158
3159         # Charge a new rental fee, if applicable
3160         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3161         if ( $charge > 0 ) {
3162             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3163         }
3164
3165         # Charge a new accumulate rental fee, if applicable
3166         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3167         if ( $itemtype_object ) {
3168             my $accumulate_charge = $fees->accumulate_rentalcharge();
3169             if ( $accumulate_charge > 0 ) {
3170                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3171             }
3172             $charge += $accumulate_charge;
3173         }
3174
3175         # Send a renewal slip according to checkout alert preferencei
3176         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3177             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3178             my %conditions        = (
3179                 branchcode   => $branch,
3180                 categorycode => $patron->categorycode,
3181                 item_type    => $itemtype,
3182                 notification => 'CHECKOUT',
3183             );
3184             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3185                 SendCirculationAlert(
3186                     {
3187                         type     => 'RENEWAL',
3188                         item     => $item_unblessed,
3189                         borrower => $patron->unblessed,
3190                         branch   => $branch,
3191                     }
3192                 );
3193             }
3194         }
3195
3196         # Remove any OVERDUES related debarment if the borrower has no overdues
3197         my $overdue_restrictions = $patron->restrictions->search({ type => 'OVERDUES' });
3198         if ( $patron
3199           && $patron->is_debarred
3200           && ! $patron->has_overdues
3201           && $overdue_restrictions->count
3202         ) {
3203             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3204         }
3205
3206         # Add renewal record
3207         my $renewal = Koha::Checkouts::Renewal->new(
3208             {
3209                 checkout_id => $issue->issue_id,
3210                 renewer_id  => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3211                 seen        => $seen,
3212                 interface   => C4::Context->interface,
3213                 renewal_type => $renewal_type
3214             }
3215         )->store();
3216
3217         # Add the renewal to stats
3218         C4::Stats::UpdateStats(
3219             {
3220                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3221                 type           => 'renew',
3222                 amount         => $charge,
3223                 itemnumber     => $itemnumber,
3224                 itemtype       => $itemtype,
3225                 location       => $item_object->location,
3226                 borrowernumber => $borrowernumber,
3227                 ccode          => $item_object->ccode,
3228                 categorycode   => $patron->categorycode,
3229             }
3230         );
3231
3232         #Log the renewal
3233         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3234
3235         Koha::Plugins->call('after_circ_action', {
3236             action  => 'renewal',
3237             payload => {
3238                 checkout  => $issue->get_from_storage
3239             }
3240         });
3241     });
3242
3243     return $datedue;
3244 }
3245
3246 sub GetRenewCount {
3247     # check renewal status
3248     my ( $bornum, $itemno ) = @_;
3249     my $dbh           = C4::Context->dbh;
3250     my $renewcount    = 0;
3251     my $unseencount    = 0;
3252     my $renewsallowed = 0;
3253     my $unseenallowed = 0;
3254     my $renewsleft    = 0;
3255     my $unseenleft    = 0;
3256
3257     my $patron = Koha::Patrons->find( $bornum );
3258     my $item   = Koha::Items->find($itemno);
3259
3260     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3261
3262     # Look in the issues table for this item, lent to this borrower,
3263     # and not yet returned.
3264
3265     # FIXME - I think this function could be redone to use only one SQL call.
3266     my $sth = $dbh->prepare(
3267         "select * from issues
3268                                 where (borrowernumber = ?)
3269                                 and (itemnumber = ?)"
3270     );
3271     $sth->execute( $bornum, $itemno );
3272     my $data = $sth->fetchrow_hashref;
3273     $renewcount = $data->{'renewals_count'} if $data->{'renewals_count'};
3274     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3275     # $item and $borrower should be calculated
3276     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3277
3278     my $rules = Koha::CirculationRules->get_effective_rules(
3279         {
3280             categorycode => $patron->categorycode,
3281             itemtype     => $item->effective_itemtype,
3282             branchcode   => $branchcode,
3283             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3284         }
3285     );
3286     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3287     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3288         $rules->{unseen_renewals_allowed} :
3289         0;
3290     $renewsleft    = $renewsallowed - $renewcount;
3291     $unseenleft    = $unseenallowed - $unseencount;
3292     if($renewsleft < 0){ $renewsleft = 0; }
3293     if($unseenleft < 0){ $unseenleft = 0; }
3294     return (
3295         $renewcount,
3296         $renewsallowed,
3297         $renewsleft,
3298         $unseencount,
3299         $unseenallowed,
3300         $unseenleft
3301     );
3302 }
3303
3304 =head2 GetSoonestRenewDate
3305
3306   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($checkout);
3307
3308 Find out the soonest possible renew date of a borrowed item.
3309
3310 C<$checkout> is the checkout object to renew.
3311
3312 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3313 renew date, based on the value "No renewal before" of the applicable
3314 issuing rule. Returns the current date if the item can already be
3315 renewed, and returns undefined if the patron, item, or checkout
3316 cannot be found.
3317
3318 =cut
3319
3320 sub GetSoonestRenewDate {
3321     my ( $checkout ) = @_;
3322
3323     my $item   = $checkout->item or return;
3324     my $patron = $checkout->patron or return;
3325
3326     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3327     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3328         {   categorycode => $patron->categorycode,
3329             itemtype     => $item->effective_itemtype,
3330             branchcode   => $branchcode,
3331             rules => [
3332                 'norenewalbefore',
3333                 'lengthunit',
3334             ]
3335         }
3336     );
3337
3338     my $now = dt_from_string;
3339
3340     if ( defined $issuing_rule->{norenewalbefore}
3341         and $issuing_rule->{norenewalbefore} ne "" )
3342     {
3343         my $soonestrenewal =
3344           dt_from_string( $checkout->date_due )->subtract(
3345             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3346
3347         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3348             and $issuing_rule->{lengthunit} eq 'days' )
3349         {
3350             $soonestrenewal->truncate( to => 'day' );
3351         }
3352         return $soonestrenewal if $now < $soonestrenewal;
3353     } elsif ( $checkout->auto_renew && $patron->autorenew_checkouts ) {
3354         # Checkouts with auto-renewing fall back to due date
3355         my $soonestrenewal = dt_from_string( $checkout->date_due );
3356         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3357             and $issuing_rule->{lengthunit} eq 'days' )
3358         {
3359             $soonestrenewal->truncate( to => 'day' );
3360         }
3361         return $soonestrenewal;
3362     }
3363     return $now;
3364 }
3365
3366 =head2 GetLatestAutoRenewDate
3367
3368   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3369
3370 Find out the latest possible auto renew date of a borrowed item.
3371
3372 C<$borrowernumber> is the borrower number of the patron who currently
3373 has the item on loan.
3374
3375 C<$itemnumber> is the number of the item to renew.
3376
3377 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3378 auto renew date, based on the value "No auto renewal after" and the "No auto
3379 renewal after (hard limit) of the applicable issuing rule.
3380 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3381 or item cannot be found.
3382
3383 =cut
3384
3385 sub GetLatestAutoRenewDate {
3386     my ( $borrowernumber, $itemnumber ) = @_;
3387
3388     my $dbh = C4::Context->dbh;
3389
3390     my $item      = Koha::Items->find($itemnumber)  or return;
3391     my $itemissue = $item->checkout                 or return;
3392
3393     $borrowernumber ||= $itemissue->borrowernumber;
3394     my $patron = Koha::Patrons->find( $borrowernumber )
3395       or return;
3396
3397     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3398     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3399         {
3400             categorycode => $patron->categorycode,
3401             itemtype     => $item->effective_itemtype,
3402             branchcode   => $branchcode,
3403             rules => [
3404                 'no_auto_renewal_after',
3405                 'no_auto_renewal_after_hard_limit',
3406                 'lengthunit',
3407             ]
3408         }
3409     );
3410
3411     return unless $circulation_rules;
3412     return
3413       if ( not $circulation_rules->{no_auto_renewal_after}
3414             or $circulation_rules->{no_auto_renewal_after} eq '' )
3415       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3416              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3417
3418     my $maximum_renewal_date;
3419     if ( $circulation_rules->{no_auto_renewal_after} ) {
3420         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3421         $maximum_renewal_date->add(
3422             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3423         );
3424     }
3425
3426     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3427         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3428         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3429     }
3430     return $maximum_renewal_date;
3431 }
3432
3433
3434 =head2 GetIssuingCharges
3435
3436   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3437
3438 Calculate how much it would cost for a given patron to borrow a given
3439 item, including any applicable discounts.
3440
3441 C<$itemnumber> is the item number of item the patron wishes to borrow.
3442
3443 C<$borrowernumber> is the patron's borrower number.
3444
3445 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3446 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3447 if it's a video).
3448
3449 =cut
3450
3451 sub GetIssuingCharges {
3452
3453     # calculate charges due
3454     my ( $itemnumber, $borrowernumber ) = @_;
3455     my $charge = 0;
3456     my $dbh    = C4::Context->dbh;
3457     my $item_type;
3458
3459     # Get the book's item type and rental charge (via its biblioitem).
3460     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3461         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3462     $charge_query .= (C4::Context->preference('item-level_itypes'))
3463         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3464         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3465
3466     $charge_query .= ' WHERE items.itemnumber =?';
3467
3468     my $sth = $dbh->prepare($charge_query);
3469     $sth->execute($itemnumber);
3470     if ( my $item_data = $sth->fetchrow_hashref ) {
3471         $item_type = $item_data->{itemtype};
3472         $charge    = $item_data->{rentalcharge};
3473         if ($charge) {
3474             # FIXME This should follow CircControl
3475             my $branch = C4::Context::mybranch();
3476             my $patron = Koha::Patrons->find( $borrowernumber );
3477             my $discount = Koha::CirculationRules->get_effective_rule({
3478                 categorycode => $patron->categorycode,
3479                 branchcode   => $branch,
3480                 itemtype     => $item_type,
3481                 rule_name    => 'rentaldiscount'
3482             });
3483             if ($discount) {
3484                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3485             }
3486             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3487         }
3488     }
3489
3490     return ( $charge, $item_type );
3491 }
3492
3493 =head2 AddIssuingCharge
3494
3495   &AddIssuingCharge( $checkout, $charge, $type )
3496
3497 =cut
3498
3499 sub AddIssuingCharge {
3500     my ( $checkout, $charge, $type ) = @_;
3501
3502     # FIXME What if checkout does not exist?
3503
3504     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3505     my $accountline = $account->add_debit(
3506         {
3507             amount      => $charge,
3508             note        => undef,
3509             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3510             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3511             interface   => C4::Context->interface,
3512             type        => $type,
3513             item_id     => $checkout->itemnumber,
3514             issue_id    => $checkout->issue_id,
3515         }
3516     );
3517 }
3518
3519 =head2 GetTransfersFromTo
3520
3521   @results = GetTransfersFromTo($frombranch,$tobranch);
3522
3523 Returns the list of pending transfers between $from and $to branch
3524
3525 =cut
3526
3527 sub GetTransfersFromTo {
3528     my ( $frombranch, $tobranch ) = @_;
3529     return unless ( $frombranch && $tobranch );
3530     my $dbh   = C4::Context->dbh;
3531     my $query = "
3532         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3533         FROM   branchtransfers
3534         WHERE  frombranch=?
3535           AND  tobranch=?
3536           AND datecancelled IS NULL
3537           AND datesent IS NOT NULL
3538           AND datearrived IS NULL
3539     ";
3540     my $sth = $dbh->prepare($query);
3541     $sth->execute( $frombranch, $tobranch );
3542     my @gettransfers;
3543
3544     while ( my $data = $sth->fetchrow_hashref ) {
3545         push @gettransfers, $data;
3546     }
3547     return (@gettransfers);
3548 }
3549
3550 =head2 SendCirculationAlert
3551
3552 Send out a C<check-in> or C<checkout> alert using the messaging system.
3553
3554 B<Parameters>:
3555
3556 =over 4
3557
3558 =item type
3559
3560 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3561
3562 =item item
3563
3564 Hashref of information about the item being checked in or out.
3565
3566 =item borrower
3567
3568 Hashref of information about the borrower of the item.
3569
3570 =item branch
3571
3572 The branchcode from where the checkout or check-in took place.
3573
3574 =back
3575
3576 B<Example>:
3577
3578     SendCirculationAlert({
3579         type     => 'CHECKOUT',
3580         item     => $item,
3581         borrower => $borrower,
3582         branch   => $branch,
3583     });
3584
3585 =cut
3586
3587 sub SendCirculationAlert {
3588     my ($opts) = @_;
3589     my ($type, $item, $borrower, $branch, $issue) =
3590         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3591     my %message_name = (
3592         CHECKIN  => 'Item_Check_in',
3593         CHECKOUT => 'Item_Checkout',
3594         RENEWAL  => 'Item_Checkout',
3595     );
3596     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3597         borrowernumber => $borrower->{borrowernumber},
3598         message_name   => $message_name{$type},
3599     });
3600
3601
3602     my $tables = {
3603         items => $item->{itemnumber},
3604         biblio      => $item->{biblionumber},
3605         biblioitems => $item->{biblionumber},
3606         borrowers   => $borrower,
3607         branches    => $branch,
3608     };
3609
3610     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3611     # See C4::Letters:: _parseletter_sth
3612     if( $type eq 'CHECKIN' ){
3613         $tables->{old_issues} = $issue->issue_id;
3614     } else {
3615         $tables->{issues} = $item->{itemnumber};
3616     }
3617
3618     my $schema = Koha::Database->new->schema;
3619     my @transports = keys %{ $borrower_preferences->{transports} };
3620
3621     # From the MySQL doc:
3622     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3623     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3624     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3625     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3626
3627     for my $mtt (@transports) {
3628         my $letter =  C4::Letters::GetPreparedLetter (
3629             module => 'circulation',
3630             letter_code => $type,
3631             branchcode => $branch,
3632             message_transport_type => $mtt,
3633             lang => $borrower->{lang},
3634             tables => $tables,
3635         ) or next;
3636
3637         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3638         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3639         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3640         unless ( $message ) {
3641             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3642             C4::Message->enqueue($letter, $borrower, $mtt);
3643         } else {
3644             $message->append($letter);
3645             $message->update;
3646         }
3647         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3648     }
3649
3650     return;
3651 }
3652
3653 =head2 updateWrongTransfer
3654
3655   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3656
3657 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3658
3659 =cut
3660
3661 sub updateWrongTransfer {
3662         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3663
3664     # first step: cancel the original transfer
3665     my $item = Koha::Items->find($itemNumber);
3666     my $transfer = $item->get_transfer;
3667     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3668
3669     # second step: create a new transfer to the right location
3670     my $new_transfer = $item->request_transfer(
3671         {
3672             to            => $transfer->to_library,
3673             reason        => $transfer->reason,
3674             comment       => $transfer->comments,
3675             ignore_limits => 1,
3676             enqueue       => 1
3677         }
3678     );
3679
3680     return $new_transfer;
3681 }
3682
3683 =head2 CalcDateDue
3684
3685 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3686
3687 this function calculates the due date given the start date and configured circulation rules,
3688 checking against the holidays calendar as per the daysmode circulation rule.
3689 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3690 C<$itemtype>  = itemtype code of item in question
3691 C<$branch>  = location whose calendar to use
3692 C<$borrower> = Borrower object
3693 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3694
3695 =cut
3696
3697 sub CalcDateDue {
3698     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3699
3700     $isrenewal ||= 0;
3701
3702     # loanlength now a href
3703     my $loanlength =
3704             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3705
3706     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3707             ? qq{renewalperiod}
3708             : qq{issuelength};
3709
3710     my $datedue;
3711     if ( $startdate ) {
3712         if (ref $startdate ne 'DateTime' ) {
3713             $datedue = dt_from_string($datedue);
3714         } else {
3715             $datedue = $startdate->clone;
3716         }
3717     } else {
3718         $datedue = dt_from_string()->truncate( to => 'minute' );
3719     }
3720
3721
3722     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3723         {
3724             categorycode => $borrower->{categorycode},
3725             itemtype     => $itemtype,
3726             branchcode   => $branch,
3727         }
3728     );
3729
3730     # calculate the datedue as normal
3731     if ( $daysmode eq 'Days' )
3732     {    # ignoring calendar
3733         if ( $loanlength->{lengthunit} eq 'hours' ) {
3734             $datedue->add( hours => $loanlength->{$length_key} );
3735         } else {    # days
3736             $datedue->add( days => $loanlength->{$length_key} );
3737             $datedue->set_hour(23);
3738             $datedue->set_minute(59);
3739         }
3740     } else {
3741         my $dur;
3742         if ($loanlength->{lengthunit} eq 'hours') {
3743             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3744         }
3745         else { # days
3746             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3747         }
3748         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3749         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3750         if ($loanlength->{lengthunit} eq 'days') {
3751             $datedue->set_hour(23);
3752             $datedue->set_minute(59);
3753         }
3754     }
3755
3756     # if Hard Due Dates are used, retrieve them and apply as necessary
3757     my ( $hardduedate, $hardduedatecompare ) =
3758       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3759     if ($hardduedate) {    # hardduedates are currently dates
3760         $hardduedate->truncate( to => 'minute' );
3761         $hardduedate->set_hour(23);
3762         $hardduedate->set_minute(59);
3763         my $cmp = DateTime->compare( $hardduedate, $datedue );
3764
3765 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3766 # if the calculated date is before the 'after' Hard Due Date (floor), override
3767 # if the hard due date is set to 'exactly', overrride
3768         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3769             $datedue = $hardduedate->clone;
3770         }
3771
3772         # in all other cases, keep the date due as it is
3773
3774     }
3775
3776     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3777     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3778         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3779         if( $expiry_dt ) { #skip empty expiry date..
3780             $expiry_dt->set( hour => 23, minute => 59);
3781             my $d1= $datedue->clone->set_time_zone('floating');
3782             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3783                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3784             }
3785         }
3786         if ( $daysmode ne 'Days' ) {
3787           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3788           if ( $calendar->is_holiday($datedue) ) {
3789               # Don't return on a closed day
3790               $datedue = $calendar->prev_open_days( $datedue, 1 );
3791           }
3792         }
3793     }
3794
3795     return $datedue;
3796 }
3797
3798
3799 sub CheckValidBarcode{
3800 my ($barcode) = @_;
3801 my $dbh = C4::Context->dbh;
3802 my $query=qq|SELECT count(*)
3803              FROM items
3804              WHERE barcode=?
3805             |;
3806 my $sth = $dbh->prepare($query);
3807 $sth->execute($barcode);
3808 my $exist=$sth->fetchrow ;
3809 return $exist;
3810 }
3811
3812 =head2 IsBranchTransferAllowed
3813
3814   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3815
3816 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3817
3818 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3819 Koha::Item->can_be_transferred.
3820
3821 =cut
3822
3823 sub IsBranchTransferAllowed {
3824         my ( $toBranch, $fromBranch, $code ) = @_;
3825
3826         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3827
3828         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3829         my $dbh = C4::Context->dbh;
3830
3831         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3832         $sth->execute( $toBranch, $fromBranch, $code );
3833         my $limit = $sth->fetchrow_hashref();
3834
3835         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3836         if ( $limit->{'limitId'} ) {
3837                 return 0;
3838         } else {
3839                 return 1;
3840         }
3841 }
3842
3843 =head2 CreateBranchTransferLimit
3844
3845   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3846
3847 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3848
3849 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3850
3851 =cut
3852
3853 sub CreateBranchTransferLimit {
3854    my ( $toBranch, $fromBranch, $code ) = @_;
3855    return unless defined($toBranch) && defined($fromBranch);
3856    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3857
3858    my $dbh = C4::Context->dbh;
3859
3860    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3861    return $sth->execute( $code, $toBranch, $fromBranch );
3862 }
3863
3864 =head2 DeleteBranchTransferLimits
3865
3866     my $result = DeleteBranchTransferLimits($frombranch);
3867
3868 Deletes all the library transfer limits for one library.  Returns the
3869 number of limits deleted, 0e0 if no limits were deleted, or undef if
3870 no arguments are supplied.
3871
3872 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3873     fromBranch => $fromBranch
3874     })->delete.
3875
3876 =cut
3877
3878 sub DeleteBranchTransferLimits {
3879     my $branch = shift;
3880     return unless defined $branch;
3881     my $dbh    = C4::Context->dbh;
3882     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3883     return $sth->execute($branch);
3884 }
3885
3886 sub ReturnLostItem{
3887     my ( $borrowernumber, $itemnum ) = @_;
3888     MarkIssueReturned( $borrowernumber, $itemnum );
3889 }
3890
3891 =head2 LostItem
3892
3893   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3894
3895 The final optional parameter, C<$params>, expected to contain
3896 'skip_record_index' key, which relayed down to Koha::Item/store,
3897 there it prevents calling of ModZebra index_records,
3898 which takes most of the time in batch adds/deletes: index_records better
3899 to be called later in C<additem.pl> after the whole loop.
3900
3901 $params:
3902     skip_record_index => 1|0
3903
3904 =cut
3905
3906 sub LostItem{
3907     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3908
3909     unless ( $mark_lost_from ) {
3910         # Temporary check to avoid regressions
3911         die q|LostItem called without $mark_lost_from, check the API.|;
3912     }
3913
3914     my $mark_returned;
3915     if ( $force_mark_returned ) {
3916         $mark_returned = 1;
3917     } else {
3918         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3919         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3920     }
3921
3922     my $dbh = C4::Context->dbh();
3923     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3924                            FROM issues
3925                            JOIN items USING (itemnumber)
3926                            JOIN biblio USING (biblionumber)
3927                            WHERE issues.itemnumber=?");
3928     $sth->execute($itemnumber);
3929     my $issues=$sth->fetchrow_hashref();
3930
3931     # If a borrower lost the item, add a replacement cost to the their record
3932     if ( my $borrowernumber = $issues->{borrowernumber} ){
3933         my $patron = Koha::Patrons->find( $borrowernumber );
3934
3935         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3936         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3937
3938         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3939             C4::Accounts::chargelostitem(
3940                 $borrowernumber,
3941                 $itemnumber,
3942                 $issues->{'replacementprice'},
3943                 sprintf( "%s %s %s",
3944                     $issues->{'title'}          || q{},
3945                     $issues->{'barcode'}        || q{},
3946                     $issues->{'itemcallnumber'} || q{},
3947                 ),
3948             );
3949             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3950             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3951         }
3952
3953         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
3954     }
3955
3956     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
3957     my $item = Koha::Items->find($itemnumber);
3958     my $transfers = $item->get_transfers;
3959     while (my $transfer = $transfers->next) {
3960         $transfer->cancel({ reason => 'ItemLost', force => 1 });
3961     }
3962 }
3963
3964 sub GetOfflineOperations {
3965     my $dbh = C4::Context->dbh;
3966     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3967     $sth->execute(C4::Context->userenv->{'branch'});
3968     my $results = $sth->fetchall_arrayref({});
3969     return $results;
3970 }
3971
3972 sub GetOfflineOperation {
3973     my $operationid = shift;
3974     return unless $operationid;
3975     my $dbh = C4::Context->dbh;
3976     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3977     $sth->execute( $operationid );
3978     return $sth->fetchrow_hashref;
3979 }
3980
3981 sub AddOfflineOperation {
3982     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3983     my $dbh = C4::Context->dbh;
3984     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3985     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3986     return "Added.";
3987 }
3988
3989 sub DeleteOfflineOperation {
3990     my $dbh = C4::Context->dbh;
3991     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3992     $sth->execute( shift );
3993     return "Deleted.";
3994 }
3995
3996 sub ProcessOfflineOperation {
3997     my $operation = shift;
3998
3999     my $report;
4000     if ( $operation->{action} eq 'return' ) {
4001         $report = ProcessOfflineReturn( $operation );
4002     } elsif ( $operation->{action} eq 'issue' ) {
4003         $report = ProcessOfflineIssue( $operation );
4004     } elsif ( $operation->{action} eq 'payment' ) {
4005         $report = ProcessOfflinePayment( $operation );
4006     }
4007
4008     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4009
4010     return $report;
4011 }
4012
4013 sub ProcessOfflineReturn {
4014     my $operation = shift;
4015
4016     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4017
4018     if ( $item ) {
4019         my $itemnumber = $item->itemnumber;
4020         my $issue = $item->checkout;
4021         if ( $issue ) {
4022             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4023             ModDateLastSeen( $itemnumber, $leave_item_lost );
4024             MarkIssueReturned(
4025                 $issue->borrowernumber,
4026                 $itemnumber,
4027                 $operation->{timestamp},
4028             );
4029             $item->renewals_count(0);
4030             $item->onloan(undef);
4031             $item->store({ log_action => 0 });
4032             return "Success.";
4033         } else {
4034             return "Item not issued.";
4035         }
4036     } else {
4037         return "Item not found.";
4038     }
4039 }
4040
4041 sub ProcessOfflineIssue {
4042     my $operation = shift;
4043
4044     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4045
4046     if ( $patron ) {
4047         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4048         unless ($item) {
4049             return "Barcode not found.";
4050         }
4051         my $itemnumber = $item->itemnumber;
4052         my $issue = $item->checkout;
4053
4054         if ( $issue and ( $issue->borrowernumber ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4055             MarkIssueReturned(
4056                 $issue->borrowernumber,
4057                 $itemnumber,
4058                 $operation->{timestamp},
4059             );
4060         }
4061         AddIssue(
4062             $patron->unblessed,
4063             $operation->{'barcode'},
4064             undef,
4065             undef,
4066             $operation->{timestamp},
4067             undef,
4068         );
4069         return "Success.";
4070     } else {
4071         return "Borrower not found.";
4072     }
4073 }
4074
4075 sub ProcessOfflinePayment {
4076     my $operation = shift;
4077
4078     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4079
4080     $patron->account->pay(
4081         {
4082             amount     => $operation->{amount},
4083             library_id => $operation->{branchcode},
4084             interface  => 'koc'
4085         }
4086     );
4087
4088     return "Success.";
4089 }
4090
4091 =head2 TransferSlip
4092
4093   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4094
4095   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4096
4097 =cut
4098
4099 sub TransferSlip {
4100     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4101
4102     my $item =
4103       $itemnumber
4104       ? Koha::Items->find($itemnumber)
4105       : Koha::Items->find( { barcode => $barcode } );
4106
4107     $item or return;
4108
4109     return C4::Letters::GetPreparedLetter (
4110         module => 'circulation',
4111         letter_code => 'TRANSFERSLIP',
4112         branchcode => $branch,
4113         tables => {
4114             'branches'    => $to_branch,
4115             'biblio'      => $item->biblionumber,
4116             'items'       => $item->unblessed,
4117         },
4118     );
4119 }
4120
4121 =head2 CheckIfIssuedToPatron
4122
4123   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4124
4125   Return 1 if any record item is issued to patron, otherwise return 0
4126
4127 =cut
4128
4129 sub CheckIfIssuedToPatron {
4130     my ($borrowernumber, $biblionumber) = @_;
4131
4132     my $dbh = C4::Context->dbh;
4133     my $query = q|
4134         SELECT COUNT(*) FROM issues
4135         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4136         WHERE items.biblionumber = ?
4137         AND issues.borrowernumber = ?
4138     |;
4139     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4140     return 1 if $is_issued;
4141     return;
4142 }
4143
4144 =head2 IsItemIssued
4145
4146   IsItemIssued( $itemnumber )
4147
4148   Return 1 if the item is on loan, otherwise return 0
4149
4150 =cut
4151
4152 sub IsItemIssued {
4153     my $itemnumber = shift;
4154     my $dbh = C4::Context->dbh;
4155     my $sth = $dbh->prepare(q{
4156         SELECT COUNT(*)
4157         FROM issues
4158         WHERE itemnumber = ?
4159     });
4160     $sth->execute($itemnumber);
4161     return $sth->fetchrow;
4162 }
4163
4164 =head2 GetAgeRestriction
4165
4166   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4167   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4168
4169   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4170   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4171
4172 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4173 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4174 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4175          Negative days mean the borrower has gone past the age restriction age.
4176
4177 =cut
4178
4179 sub GetAgeRestriction {
4180     my ($record_restrictions, $borrower) = @_;
4181     my $markers = C4::Context->preference('AgeRestrictionMarker');
4182
4183     return unless $record_restrictions;
4184     # Split $record_restrictions to something like FSK 16 or PEGI 6
4185     my @values = split ' ', uc($record_restrictions);
4186     return unless @values;
4187
4188     # Search first occurrence of one of the markers
4189     my @markers = split /\|/, uc($markers);
4190     return unless @markers;
4191
4192     my $index            = 0;
4193     my $restriction_year = 0;
4194     for my $value (@values) {
4195         $index++;
4196         for my $marker (@markers) {
4197             $marker =~ s/^\s+//;    #remove leading spaces
4198             $marker =~ s/\s+$//;    #remove trailing spaces
4199             if ( $marker eq $value ) {
4200                 if ( $index <= $#values ) {
4201                     $restriction_year += $values[$index];
4202                 }
4203                 last;
4204             }
4205             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4206
4207                 # Perhaps it is something like "K16" (as in Finland)
4208                 $restriction_year += $1;
4209                 last;
4210             }
4211         }
4212         last if ( $restriction_year > 0 );
4213     }
4214
4215     #Check if the borrower is age restricted for this material and for how long.
4216     if ($restriction_year && $borrower) {
4217         if ( $borrower->{'dateofbirth'} ) {
4218             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4219             $alloweddate[0] += $restriction_year;
4220
4221             #Prevent runime eror on leap year (invalid date)
4222             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4223                 $alloweddate[2] = 28;
4224             }
4225
4226             #Get how many days the borrower has to reach the age restriction
4227             my @Today = split /-/, dt_from_string()->ymd();
4228             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4229             #Negative days means the borrower went past the age restriction age
4230             return ($restriction_year, $daysToAgeRestriction);
4231         }
4232     }
4233
4234     return ($restriction_year);
4235 }
4236
4237
4238 =head2 GetPendingOnSiteCheckouts
4239
4240 =cut
4241
4242 sub GetPendingOnSiteCheckouts {
4243     my $dbh = C4::Context->dbh;
4244     return $dbh->selectall_arrayref(q|
4245         SELECT
4246           items.barcode,
4247           items.biblionumber,
4248           items.itemnumber,
4249           items.itemnotes,
4250           items.itemcallnumber,
4251           items.location,
4252           issues.date_due,
4253           issues.branchcode,
4254           issues.date_due < NOW() AS is_overdue,
4255           biblio.author,
4256           biblio.title,
4257           borrowers.firstname,
4258           borrowers.surname,
4259           borrowers.cardnumber,
4260           borrowers.borrowernumber
4261         FROM items
4262         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4263         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4264         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4265         WHERE issues.onsite_checkout = 1
4266     |, { Slice => {} } );
4267 }
4268
4269 sub GetTopIssues {
4270     my ($params) = @_;
4271
4272     my ($count, $branch, $itemtype, $ccode, $newness)
4273         = @$params{qw(count branch itemtype ccode newness)};
4274
4275     my $dbh = C4::Context->dbh;
4276     my $query = q{
4277         SELECT * FROM (
4278         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4279           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4280           i.ccode, SUM(i.issues) AS count
4281         FROM biblio b
4282         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4283         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4284     };
4285
4286     my (@where_strs, @where_args);
4287
4288     if ($branch) {
4289         push @where_strs, 'i.homebranch = ?';
4290         push @where_args, $branch;
4291     }
4292     if ($itemtype) {
4293         if (C4::Context->preference('item-level_itypes')){
4294             push @where_strs, 'i.itype = ?';
4295             push @where_args, $itemtype;
4296         } else {
4297             push @where_strs, 'bi.itemtype = ?';
4298             push @where_args, $itemtype;
4299         }
4300     }
4301     if ($ccode) {
4302         push @where_strs, 'i.ccode = ?';
4303         push @where_args, $ccode;
4304     }
4305     if ($newness) {
4306         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4307         push @where_args, $newness;
4308     }
4309
4310     if (@where_strs) {
4311         $query .= 'WHERE ' . join(' AND ', @where_strs);
4312     }
4313
4314     $query .= q{
4315         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4316           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4317           i.ccode
4318         ORDER BY count DESC
4319     };
4320
4321     $query .= q{ ) xxx WHERE count > 0 };
4322     $count = int($count);
4323     if ($count > 0) {
4324         $query .= "LIMIT $count";
4325     }
4326
4327     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4328
4329     return @$rows;
4330 }
4331
4332 =head2 Internal methods
4333
4334 =cut
4335
4336 sub _CalculateAndUpdateFine {
4337     my ($params) = @_;
4338
4339     my $borrower    = $params->{borrower};
4340     my $item        = $params->{item};
4341     my $issue       = $params->{issue};
4342     my $return_date = $params->{return_date};
4343
4344     unless ($borrower) { carp "No borrower passed in!" && return; }
4345     unless ($item)     { carp "No item passed in!"     && return; }
4346     unless ($issue)    { carp "No issue passed in!"    && return; }
4347
4348     my $datedue = dt_from_string( $issue->date_due );
4349
4350     # we only need to calculate and change the fines if we want to do that on return
4351     # Should be on for hourly loans
4352     my $control = C4::Context->preference('CircControl');
4353     my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
4354     my $control_branchcode =
4355         ( $control eq 'ItemHomeLibrary' ) ? $item->{$branch_type}
4356       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4357       :                                     $issue->branchcode;
4358
4359     my $date_returned = $return_date ? $return_date : dt_from_string();
4360
4361     my ( $amount, $unitcounttotal, $unitcount  ) =
4362       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4363
4364     if ( C4::Context->preference('finesMode') eq 'production' ) {
4365         if ( $amount > 0 ) {
4366             C4::Overdues::UpdateFine({
4367                 issue_id       => $issue->issue_id,
4368                 itemnumber     => $issue->itemnumber,
4369                 borrowernumber => $issue->borrowernumber,
4370                 amount         => $amount,
4371                 due            => $datedue,
4372             });
4373         }
4374         elsif ($return_date) {
4375
4376             # Backdated returns may have fines that shouldn't exist,
4377             # so in this case, we need to drop those fines to 0
4378
4379             C4::Overdues::UpdateFine({
4380                 issue_id       => $issue->issue_id,
4381                 itemnumber     => $issue->itemnumber,
4382                 borrowernumber => $issue->borrowernumber,
4383                 amount         => 0,
4384                 due            => $datedue,
4385             });
4386         }
4387     }
4388 }
4389
4390 sub _CanBookBeAutoRenewed {
4391     my ( $params ) = @_;
4392     my $patron = $params->{patron};
4393     my $item = $params->{item};
4394     my $branchcode = $params->{branchcode};
4395     my $issue = $params->{issue};
4396
4397     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4398
4399     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4400         {
4401             categorycode => $patron->categorycode,
4402             itemtype     => $item->effective_itemtype,
4403             branchcode   => $branchcode,
4404             rules => [
4405                 'no_auto_renewal_after',
4406                 'no_auto_renewal_after_hard_limit',
4407                 'lengthunit',
4408                 'norenewalbefore',
4409             ]
4410         }
4411     );
4412
4413     if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
4414         return 'auto_account_expired';
4415     }
4416
4417     if ( defined $issuing_rule->{no_auto_renewal_after}
4418             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4419         # Get issue_date and add no_auto_renewal_after
4420         # If this is greater than today, it's too late for renewal.
4421         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4422         $maximum_renewal_date->add(
4423             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4424         );
4425         my $now = dt_from_string;
4426         if ( $now >= $maximum_renewal_date ) {
4427             return "auto_too_late";
4428         }
4429     }
4430     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4431                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4432         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4433         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4434             return "auto_too_late";
4435         }
4436     }
4437
4438     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4439         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4440         my $amountoutstanding =
4441           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4442           ? $patron->account->balance
4443           : $patron->account->outstanding_debits->total_outstanding;
4444         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4445             return "auto_too_much_oweing";
4446         }
4447     }
4448
4449     my $soonest = GetSoonestRenewDate($issue);
4450     if ( $soonest > dt_from_string() )
4451     {
4452         return ( "auto_too_soon", $soonest );
4453     }
4454
4455     return "ok";
4456 }
4457
4458
4459 1;
4460
4461 __END__
4462
4463 =head1 AUTHOR
4464
4465 Koha Development Team <http://koha-community.org/>
4466
4467 =cut