C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use C4::Context;
  28 use C4::Stats qw( UpdateStats );
  29 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest );
  30 use C4::Biblio qw( UpdateTotalIssues );
  31 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Log qw( logaction ); # logaction
  36 use C4::Overdues;
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits qw( CheckDigits );
  39
  40 use Data::Dumper qw( Dumper );
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number blessed );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetUpcomingDueIssues
  99       CheckIfIssuedToPatron
 100       IsItemIssued
 101       GetAgeRestriction
 102       GetTopIssues
 103
 104       AddReturn
 105       MarkIssueReturned
 106
 107       transferbook
 108       TooMany
 109       GetTransfersFromTo
 110       updateWrongTransfer
 111       CalcDateDue
 112       CheckValidBarcode
 113       IsBranchTransferAllowed
 114       CreateBranchTransferLimit
 115       DeleteBranchTransferLimits
 116       TransferSlip
 117
 118       GetOfflineOperations
 119       GetOfflineOperation
 120       AddOfflineOperation
 121       DeleteOfflineOperation
 122       ProcessOfflineOperation
 123       ProcessOfflinePayment
 124       ProcessOfflineIssue
 125     );
 126     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 127 }
 128
 129 =head1 NAME
 130
 131 C4::Circulation - Koha circulation module
 132
 133 =head1 SYNOPSIS
 134
 135 use C4::Circulation;
 136
 137 =head1 DESCRIPTION
 138
 139 The functions in this module deal with circulation, issues, and
 140 returns, as well as general information about the library.
 141 Also deals with inventory.
 142
 143 =head1 FUNCTIONS
 144
 145 =head2 barcodedecode
 146
 147   $str = &barcodedecode($barcode, [$filter]);
 148
 149 Generic filter function for barcode string.
 150 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 151 Will do some manipulation of the barcode for systems that deliver a barcode
 152 to circulation.pl that differs from the barcode stored for the item.
 153 For proper functioning of this filter, calling the function on the
 154 correct barcode string (items.barcode) should return an unaltered barcode.
 155 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 156
 157 The optional $filter argument is to allow for testing or explicit
 158 behavior that ignores the System Pref.  Valid values are the same as the
 159 System Pref options.
 160
 161 =cut
 162
 163 # FIXME -- the &decode fcn below should be wrapped into this one.
 164 # FIXME -- these plugins should be moved out of Circulation.pm
 165 #
 166 sub barcodedecode {
 167     my ($barcode, $filter) = @_;
 168
 169     return unless defined $barcode;
 170
 171     my $branch = C4::Context::mybranch();
 172     $barcode =~ s/^\s+|\s+$//g;
 173     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 174     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 175     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 176         if ($filter eq 'whitespace') {
 177                 $barcode =~ s/\s//g;
 178         } elsif ($filter eq 'cuecat') {
 179                 chomp($barcode);
 180             my @fields = split( /\./, $barcode );
 181             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 182             ($#results == 2) and return $results[2];
 183         } elsif ($filter eq 'T-prefix') {
 184                 if ($barcode =~ /^[Tt](\d)/) {
 185                         (defined($1) and $1 eq '0') and return $barcode;
 186             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 187                 }
 188         return sprintf("T%07d", $barcode);
 189         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 190         # Why drop the nonzero digit after the T?
 191         # Why pass non-digits (or empty string) to "T%07d"?
 192         } elsif ($filter eq 'libsuite8') {
 193                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 194                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 195                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 196                         }else{
 197                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 198                         }
 199                 }
 200     } elsif ($filter eq 'EAN13') {
 201         my $ean = CheckDigits('ean');
 202         if ( $ean->is_valid($barcode) ) {
 203             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 204             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 205         } else {
 206             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 207         }
 208         }
 209     return $barcode;    # return barcode, modified or not
 210 }
 211
 212 =head2 _decode
 213
 214   $str = &_decode($chunk);
 215
 216 Decodes a segment of a string emitted by a CueCat barcode scanner and
 217 returns it.
 218
 219 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 220 or Javascript based decoding on the client side.
 221
 222 =cut
 223
 224 sub _decode {
 225     my ($encoded) = @_;
 226     my $seq =
 227       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 228     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 229     my $l = ( $#s + 1 ) % 4;
 230     if ($l) {
 231         if ( $l == 1 ) {
 232             # warn "Error: Cuecat decode parsing failed!";
 233             return;
 234         }
 235         $l = 4 - $l;
 236         $#s += $l;
 237     }
 238     my $r = '';
 239     while ( $#s >= 0 ) {
 240         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 241         $r .=
 242             chr( ( $n >> 16 ) ^ 67 )
 243          .chr( ( $n >> 8 & 255 ) ^ 67 )
 244          .chr( ( $n & 255 ) ^ 67 );
 245         @s = @s[ 4 .. $#s ];
 246     }
 247     $r = substr( $r, 0, length($r) - $l );
 248     return $r;
 249 }
 250
 251 =head2 transferbook
 252
 253   ($dotransfer, $messages, $iteminformation) = &transferbook({
 254                                                    from_branch => $frombranch
 255                                                    to_branch => $tobranch,
 256                                                    barcode => $barcode,
 257                                                    ignore_reserves => $ignore_reserves,
 258                                                    trigger => $trigger
 259                                                 });
 260
 261 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 262
 263 C<$fbr> is the code for the branch initiating the transfer.
 264 C<$tbr> is the code for the branch to which the item should be transferred.
 265
 266 C<$barcode> is the barcode of the item to be transferred.
 267
 268 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 269 Otherwise, if an item is reserved, the transfer fails.
 270
 271 C<$trigger> is the enum value for what triggered the transfer.
 272
 273 Returns three values:
 274
 275 =over
 276
 277 =item $dotransfer
 278
 279 is true if the transfer was successful.
 280
 281 =item $messages
 282
 283 is a reference-to-hash which may have any of the following keys:
 284
 285 =over
 286
 287 =item C<BadBarcode>
 288
 289 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 290
 291 =item C<DestinationEqualsHolding>
 292
 293 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 294
 295 =item C<WasReturned>
 296
 297 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 298
 299 =item C<ResFound>
 300
 301 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 302
 303 =item C<WasTransferred>
 304
 305 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 306
 307 =item C<RecallPlacedAtHoldingBranch>
 308
 309 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 310
 311 =item C<RecallFound>
 312
 313 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 314
 315 =back
 316
 317 =back
 318
 319 =cut
 320
 321 sub transferbook {
 322     my $params = shift;
 323     my $tbr      = $params->{to_branch};
 324     my $fbr      = $params->{from_branch};
 325     my $ignoreRs = $params->{ignore_reserves};
 326     my $barcode  = $params->{barcode};
 327     my $trigger  = $params->{trigger};
 328     my $messages;
 329     my $dotransfer      = 1;
 330     my $item = $barcode ? Koha::Items->find( { barcode => $barcode } ) : undef;
 331
 332     Koha::Exceptions::MissingParameter->throw(
 333         "Missing mandatory parameter: from_branch")
 334       unless $fbr;
 335
 336     Koha::Exceptions::MissingParameter->throw(
 337         "Missing mandatory parameter: to_branch")
 338       unless $tbr;
 339
 340     # bad barcode..
 341     unless ( $item ) {
 342         $messages->{'BadBarcode'} = $barcode;
 343         $dotransfer = 0;
 344         return ( $dotransfer, $messages );
 345     }
 346
 347     my $itemnumber = $item->itemnumber;
 348     # get branches of book...
 349     my $hbr = $item->homebranch;
 350
 351     # if using Branch Transfer Limits
 352     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 353         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 354         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 355             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 356                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 357                 $dotransfer = 0;
 358             }
 359         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 360             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 361             $dotransfer = 0;
 362         }
 363     }
 364
 365     # can't transfer book if is already there....
 366     if ( $fbr eq $tbr ) {
 367         $messages->{'DestinationEqualsHolding'} = 1;
 368         $dotransfer = 0;
 369     }
 370
 371     # check if it is still issued to someone, return it...
 372     my $issue = $item->checkout;
 373     if ( $issue ) {
 374         AddReturn( $barcode, $fbr );
 375         $messages->{'WasReturned'} = $issue->borrowernumber;
 376     }
 377
 378     # find reserves.....
 379     # That'll save a database query.
 380     my ( $resfound, $resrec, undef ) =
 381       CheckReserves( $item );
 382     if ( $resfound ) {
 383         $resrec->{'ResFound'} = $resfound;
 384         $messages->{'ResFound'} = $resrec;
 385         $dotransfer = 0 unless $ignoreRs;
 386     }
 387
 388     # find recall
 389     if ( C4::Context->preference('UseRecalls') ) {
 390         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 391         if ( defined $recall ) {
 392             # do a transfer if the recall branch is different to the item holding branch
 393             if ( $recall->pickup_library_id eq $fbr ) {
 394                 $dotransfer = 0;
 395                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 396             } else {
 397                 $dotransfer = 1;
 398                 $messages->{'RecallFound'} = $recall;
 399             }
 400         }
 401     }
 402
 403     #actually do the transfer....
 404     if ($dotransfer) {
 405         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 406
 407         # don't need to update MARC anymore, we do it in batch now
 408         $messages->{'WasTransfered'} = $tbr;
 409
 410     }
 411     ModDateLastSeen( $itemnumber );
 412     return ( $dotransfer, $messages );
 413 }
 414
 415
 416 sub TooMany {
 417     my ($patron, $item, $params) = @_;
 418     my $onsite_checkout = $params->{onsite_checkout} || 0;
 419     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 420     my $cat_borrower    = $patron->categorycode;
 421     my $dbh             = C4::Context->dbh;
 422     # Get which branchcode we need
 423     my $branch = _GetCircControlBranch($item, $patron);
 424     my $type = $item->effective_itemtype;
 425
 426     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 427     $type_object = Koha::ItemTypes->find( $type );
 428     $parent_type = $type_object->parent_type if $type_object;
 429     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 430     # Find any children if we are a parent_type;
 431
 432     # given branch, patron category, and item type, determine
 433     # applicable issuing rule
 434
 435     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 436         {
 437             categorycode => $cat_borrower,
 438             itemtype     => $parent_type,
 439             branchcode   => $branch,
 440             rule_name    => 'maxissueqty',
 441         }
 442     ) if $parent_type;
 443     # If the parent rule is for default type we discount it
 444     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 445
 446     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 447         {
 448             categorycode => $cat_borrower,
 449             itemtype     => $type,
 450             branchcode   => $branch,
 451             rule_name    => 'maxissueqty',
 452         }
 453     );
 454
 455     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 456         {
 457             categorycode => $cat_borrower,
 458             itemtype     => $type,
 459             branchcode   => $branch,
 460             rule_name    => 'maxonsiteissueqty',
 461         }
 462     );
 463
 464     # if a rule is found and has a loan limit set, count
 465     # how many loans the patron already has that meet that
 466     # rule
 467     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 468
 469         my $checkouts;
 470         if ( $maxissueqty_rule->branchcode ) {
 471             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 472                 $checkouts = $patron->checkouts->search(
 473                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 474             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 475                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 476             } else {
 477                 my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 478                 $checkouts = $patron->checkouts->search(
 479                     { "item.$branch_type" => $maxissueqty_rule->branchcode } );
 480             }
 481         } else {
 482             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 483         }
 484         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 485
 486         my $sum_checkouts;
 487         my $rule_itemtype = $maxissueqty_rule->itemtype;
 488
 489         my @types;
 490         unless ( $rule_itemtype ) {
 491             # matching rule has the default item type, so count only
 492             # those existing loans that don't fall under a more
 493             # specific rule
 494             @types = Koha::CirculationRules->search(
 495                 {
 496                     branchcode => $maxissueqty_rule->branchcode,
 497                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 498                     itemtype  => { '!=' => undef },
 499                     rule_name => 'maxissueqty'
 500                 }
 501             )->get_column('itemtype');
 502         } else {
 503             if ( $parent_maxissueqty_rule ) {
 504                 # if we have a parent item type then we count loans of the
 505                 # specific item type or its siblings or parent
 506                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 507                 @types = $children->get_column('itemtype');
 508                 push @types, $parent_type;
 509             } elsif ( $child_types ) {
 510                 # If we are a parent type, we need to count all child types and our own type
 511                 @types = $child_types->get_column('itemtype');
 512                 push @types, $type; # And don't forget to count our own types
 513             } else {
 514                 # Otherwise only count the specific itemtype
 515                 push @types, $type;
 516             }
 517         }
 518
 519         while ( my $c = $checkouts->next ) {
 520             my $itemtype = $c->item->effective_itemtype;
 521
 522             unless ( $rule_itemtype ) {
 523                 next if grep {$_ eq $itemtype} @types;
 524             } else {
 525                 next unless grep {$_ eq $itemtype} @types;
 526             }
 527
 528             $sum_checkouts->{total}++;
 529             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 530             $sum_checkouts->{itemtype}->{$itemtype}++;
 531         }
 532
 533         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 534         my $checkout_count = $sum_checkouts->{total} || 0;
 535         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 536
 537         my $checkout_rules = {
 538             checkout_count               => $checkout_count,
 539             onsite_checkout_count        => $onsite_checkout_count,
 540             onsite_checkout              => $onsite_checkout,
 541             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 542             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 543             switch_onsite_checkout       => $switch_onsite_checkout,
 544             circulation_rule             => $maxissueqty_rule,
 545             onsite_circulation_rule      => $maxonsiteissueqty_rule,
 546         };
 547         # If parent rules exists
 548         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 549             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 550             my $qty_over = _check_max_qty($checkout_rules);
 551             return $qty_over if defined $qty_over;
 552
 553             # If the parent rule is less than or equal to the child, we only need check the parent
 554             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 555                 $checkout_rules->{checkout_count} = $checkout_count_type;
 556                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 557                 my $qty_over = _check_max_qty($checkout_rules);
 558                 return $qty_over if defined $qty_over;
 559             }
 560         } else {
 561             my $qty_over = _check_max_qty($checkout_rules);
 562             return $qty_over if defined $qty_over;
 563         }
 564     }
 565
 566     # Now count total loans against the limit for the branch
 567     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 568     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 569         my $checkouts;
 570         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 571             $checkouts = $patron->checkouts->search(
 572                 { 'me.branchcode' => $branch} );
 573         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 574             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 575         } else {
 576             my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
 577             $checkouts = $patron->checkouts->search(
 578                 { "item.$branch_type" => $branch},
 579                 { prefetch            => 'item' } );
 580         }
 581
 582         my $checkout_count = $checkouts->count;
 583         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 584         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 585         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 586
 587         my $qty_over = _check_max_qty(
 588             {
 589                 checkout_count               => $checkout_count,
 590                 onsite_checkout_count        => $onsite_checkout_count,
 591                 onsite_checkout              => $onsite_checkout,
 592                 max_checkouts_allowed        => $max_checkouts_allowed,
 593                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 594                 switch_onsite_checkout       => $switch_onsite_checkout,
 595                 circulation_rule             => $branch_borrower_circ_rule,
 596             }
 597         );
 598         return $qty_over if defined $qty_over;
 599     }
 600
 601     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 602         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 603     }
 604
 605     # OK, the patron can issue !!!
 606     return;
 607 }
 608
 609 sub _check_max_qty {
 610     my $params                       = shift;
 611     my $checkout_count               = $params->{checkout_count};
 612     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 613     my $onsite_checkout              = $params->{onsite_checkout};
 614     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 615     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 616     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 617     my $circulation_rule             = $params->{circulation_rule};
 618     my $onsite_circulation_rule      = $params->{onsite_circulation_rule};
 619
 620     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 621         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 622         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 623             return {
 624                 reason           => 'TOO_MANY_ONSITE_CHECKOUTS',
 625                 count            => $onsite_checkout_count,
 626                 max_allowed      => $max_onsite_checkouts_allowed,
 627                 circulation_rule => $onsite_circulation_rule,
 628             };
 629         }
 630     }
 631     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 632         if ( $max_checkouts_allowed eq '' ) { return; }
 633         my $delta = $switch_onsite_checkout ? 1 : 0;
 634         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 635             return {
 636                 reason           => 'TOO_MANY_CHECKOUTS',
 637                 count            => $checkout_count,
 638                 max_allowed      => $max_checkouts_allowed,
 639                 circulation_rule => $circulation_rule,
 640             };
 641         }
 642     }
 643     elsif ( not $onsite_checkout ) {
 644         if ( $max_checkouts_allowed eq '' ) { return; }
 645         if (
 646             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 647         {
 648             return {
 649                 reason           => 'TOO_MANY_CHECKOUTS',
 650                 count            => $checkout_count - $onsite_checkout_count,
 651                 max_allowed      => $max_checkouts_allowed,
 652                 circulation_rule => $circulation_rule,
 653             };
 654         }
 655     }
 656
 657     return;
 658 }
 659
 660 =head2 CanBookBeIssued
 661
 662   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 663                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 664
 665 Check if a book can be issued.
 666
 667 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 668
 669 IMPORTANT: The assumption by users of this routine is that causes blocking
 670 the issue are keyed by uppercase labels and other returned
 671 data is keyed in lower case!
 672
 673 =over 4
 674
 675 =item C<$patron> is a Koha::Patron
 676
 677 =item C<$barcode> is the bar code of the book being issued.
 678
 679 =item C<$duedates> is a DateTime object.
 680
 681 =item C<$inprocess> boolean switch
 682
 683 =item C<$ignore_reserves> boolean switch
 684
 685 =item C<$params> Hashref of additional parameters
 686
 687 Available keys:
 688     override_high_holds - Ignore high holds
 689     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 690     item                - Optionally pass the object for the item we are checking out to save a lookup
 691
 692 =back
 693
 694 Returns :
 695
 696 =over 4
 697
 698 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 699 Possible values are :
 700
 701 =back
 702
 703 =head3 INVALID_DATE
 704
 705 sticky due date is invalid
 706
 707 =head3 GNA
 708
 709 borrower gone with no address
 710
 711 =head3 CARD_LOST
 712
 713 borrower declared it's card lost
 714
 715 =head3 DEBARRED
 716
 717 borrower debarred
 718
 719 =head3 UNKNOWN_BARCODE
 720
 721 barcode unknown
 722
 723 =head3 NOT_FOR_LOAN
 724
 725 item is not for loan
 726
 727 =head3 WTHDRAWN
 728
 729 item withdrawn.
 730
 731 =head3 RESTRICTED
 732
 733 item is restricted (set by ??)
 734
 735 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 736 could be prevented, but ones that can be overriden by the operator.
 737
 738 Possible values are :
 739
 740 =head3 DEBT
 741
 742 borrower has debts.
 743
 744 =head3 RENEW_ISSUE
 745
 746 renewing, not issuing
 747
 748 =head3 ISSUED_TO_ANOTHER
 749
 750 issued to someone else.
 751
 752 =head3 RESERVED
 753
 754 reserved for someone else.
 755
 756 =head3 TRANSFERRED
 757
 758 reserved and being transferred for someone else.
 759
 760 =head3 INVALID_DATE
 761
 762 sticky due date is invalid or due date in the past
 763
 764 =head3 TOO_MANY
 765
 766 if the borrower borrows to much things
 767
 768 =head3 RECALLED
 769
 770 recalled by someone else
 771
 772 =cut
 773
 774 sub CanBookBeIssued {
 775     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 776     my %needsconfirmation;    # filled with problems that needs confirmations
 777     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 778     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 779     my %messages;             # filled with information messages that should be displayed.
 780
 781     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 782     my $override_high_holds = $params->{override_high_holds} || 0;
 783
 784     my $item_object = $params->{item}
 785       // Koha::Items->find( { barcode => $barcode } );
 786
 787     # MANDATORY CHECKS - unless item exists, nothing else matters
 788     unless ( $item_object ) {
 789         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 790     }
 791     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 792
 793     my $item_unblessed = $item_object->unblessed; # Transition...
 794     my $issue = $item_object->checkout;
 795     my $biblio = $item_object->biblio;
 796
 797     my $biblioitem = $biblio->biblioitem;
 798     my $effective_itemtype = $item_object->effective_itemtype;
 799     my $dbh             = C4::Context->dbh;
 800     my $patron_unblessed = $patron->unblessed;
 801
 802     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_object, $patron) );
 803
 804     my $now = dt_from_string();
 805     $duedate ||= CalcDateDue( $now, $effective_itemtype, $circ_library->branchcode, $patron );
 806     if (DateTime->compare($duedate,$now) == -1 ) { # duedate cannot be before now
 807          $needsconfirmation{INVALID_DATE} = $duedate;
 808     }
 809
 810     my $fees = Koha::Charges::Fees->new(
 811         {
 812             patron    => $patron,
 813             library   => $circ_library,
 814             item      => $item_object,
 815             to_date   => $duedate,
 816         }
 817     );
 818
 819     #
 820     # BORROWER STATUS
 821     #
 822     if ( $patron->category->category_type eq 'X' && ( $item_object->barcode ) ) {
 823
 824         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 825         C4::Stats::UpdateStats(
 826             {
 827                 branch         => C4::Context->userenv->{'branch'},
 828                 type           => 'localuse',
 829                 itemnumber     => $item_object->itemnumber,
 830                 itemtype       => $effective_itemtype,
 831                 borrowernumber => $patron->borrowernumber,
 832                 ccode          => $item_object->ccode,
 833                 categorycode   => $patron->categorycode,
 834                 location       => $item_object->location,
 835                 interface      => C4::Context->interface,
 836             }
 837         );
 838         my $block_lost_return = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
 839         my ( $stats_return, $stats_messages, $stats_iteminformation, $stats_borrower );
 840         ( $stats_return, $stats_messages, $stats_iteminformation, $stats_borrower ) =
 841             AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'}, undef, undef, 1 )
 842             if $item_object->onloan;
 843         ModDateLastSeen( $item_object->itemnumber, $block_lost_return );    # FIXME Move to Koha::Item
 844         return (
 845             {
 846                 STATS     => 1,
 847                 CHECKEDIN => $stats_return,
 848                 MESSAGES  => $stats_messages,
 849                 ITEM      => $stats_iteminformation,
 850                 BORROWER  => $stats_borrower,
 851             },
 852             {}
 853         );
 854     }
 855
 856     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 857         $issuingimpossible{GNA} = 1;
 858     }
 859
 860     if ( $patron->lost && $patron->lost == 1 ) {
 861         $issuingimpossible{CARD_LOST} = 1;
 862     }
 863     if ( $patron->is_debarred ) {
 864         $issuingimpossible{DEBARRED} = 1;
 865     }
 866
 867     if ( $patron->is_expired ) {
 868         $issuingimpossible{EXPIRED} = 1;
 869     }
 870
 871     #
 872     # BORROWER STATUS
 873     #
 874
 875     # DEBTS
 876     my $account = $patron->account;
 877     my $balance = $account->balance;
 878     my $non_issues_charges = $account->non_issues_charges;
 879     my $other_charges = $balance - $non_issues_charges;
 880
 881     my $amountlimit = C4::Context->preference("noissuescharge");
 882     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 883     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 884
 885     # Check the debt of this patrons guarantees
 886     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 887     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 888     if ( defined $no_issues_charge_guarantees ) {
 889         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 890         my $guarantees_non_issues_charges = 0;
 891         foreach my $g ( @guarantees ) {
 892             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 893         }
 894
 895         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 896             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 897         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 898             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 899         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 900             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 901         }
 902     }
 903
 904     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 905     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 906     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 907     if ( defined $no_issues_charge_guarantors ) {
 908         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 909
 910         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 911             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 912         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 913             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 914         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 915             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 916         }
 917     }
 918
 919     if ( C4::Context->preference("IssuingInProcess") ) {
 920         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 921             $issuingimpossible{DEBT} = $non_issues_charges;
 922         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 923             $needsconfirmation{DEBT} = $non_issues_charges;
 924         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 925             $needsconfirmation{DEBT} = $non_issues_charges;
 926         }
 927     }
 928     else {
 929         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 930             $needsconfirmation{DEBT} = $non_issues_charges;
 931         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 932             $issuingimpossible{DEBT} = $non_issues_charges;
 933         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 934             $needsconfirmation{DEBT} = $non_issues_charges;
 935         }
 936     }
 937
 938     if ($balance > 0 && $other_charges > 0) {
 939         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 940     }
 941
 942     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 943     $patron_unblessed = $patron->unblessed;
 944
 945     if ( my $debarred_date = $patron->is_debarred ) {
 946          # patron has accrued fine days or has a restriction. $count is a date
 947         if ($debarred_date eq '9999-12-31') {
 948             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 949         }
 950         else {
 951             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 952         }
 953     } elsif ( my $num_overdues = $patron->has_overdues ) {
 954         ## patron has outstanding overdue loans
 955         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 956             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 957         }
 958         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 959             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 960         }
 961     }
 962
 963     # Additional Materials Check
 964     if ( C4::Context->preference("CircConfirmItemParts")
 965         && $item_object->materials )
 966     {
 967         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 968     }
 969
 970     #
 971     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 972     #
 973     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 974
 975         # Already issued to current borrower.
 976         # If it is an on-site checkout if it can be switched to a normal checkout
 977         # or ask whether the loan should be renewed
 978
 979         if ( $issue->onsite_checkout
 980                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 981             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 982         } else {
 983             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed($patron, $issue);
 984             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 985                 if ( $renewerror eq 'onsite_checkout' ) {
 986                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 987                 }
 988                 else {
 989                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 990                 }
 991             }
 992             else {
 993                 $needsconfirmation{RENEW_ISSUE} = 1;
 994             }
 995         }
 996     }
 997     elsif ( $issue ) {
 998
 999         # issued to someone else
1000
1001         my $patron = Koha::Patrons->find( $issue->borrowernumber );
1002
1003         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1004
1005         if ( !$can_be_returned ) {
1006             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
1007             $issuingimpossible{branch_to_return} = $message;
1008         } else {
1009             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
1010                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
1011             }
1012             else {
1013                 $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
1014                 $needsconfirmation{issued_firstname} = $patron->firstname;
1015                 $needsconfirmation{issued_surname} = $patron->surname;
1016                 $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
1017                 $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
1018             }
1019         }
1020     }
1021
1022     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1023     #
1024     my $switch_onsite_checkout = (
1025           C4::Context->preference('SwitchOnSiteCheckouts')
1026       and $issue
1027       and $issue->onsite_checkout
1028       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1029     my $toomany = TooMany( $patron, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1030     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1031     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1032         if ( $toomany->{max_allowed} == 0 ) {
1033             $needsconfirmation{PATRON_CANT}                  = 1;
1034             $needsconfirmation{circulation_rule_PATRON_CANT} = $toomany->{circulation_rule};
1035         }
1036         if ( C4::Context->preference("AllowTooManyOverride") ) {
1037             $needsconfirmation{TOO_MANY}                  = $toomany->{reason};
1038             $needsconfirmation{current_loan_count}        = $toomany->{count};
1039             $needsconfirmation{max_loans_allowed}         = $toomany->{max_allowed};
1040             $needsconfirmation{circulation_rule_TOO_MANY} = $toomany->{circulation_rule};
1041         } else {
1042             $issuingimpossible{TOO_MANY}                  = $toomany->{reason};
1043             $issuingimpossible{current_loan_count}        = $toomany->{count};
1044             $issuingimpossible{max_loans_allowed}         = $toomany->{max_allowed};
1045             $needsconfirmation{circulation_rule_TOO_MANY} = $toomany->{circulation_rule};
1046         }
1047     }
1048
1049     #
1050     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1051     #
1052     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1053     if ( $patron->wants_check_for_previous_checkout && $patron->do_check_for_previous_checkout($item_unblessed) ) {
1054         $needsconfirmation{PREVISSUE} = 1;
1055     }
1056
1057     #
1058     # ITEM CHECKING
1059     #
1060     if ( $item_object->notforloan )
1061     {
1062         if(!C4::Context->preference("AllowNotForLoanOverride")){
1063             $issuingimpossible{NOT_FOR_LOAN} = 1;
1064             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1065         }else{
1066             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1067             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1068         }
1069     }
1070     else {
1071         # we have to check itemtypes.notforloan also
1072         if (C4::Context->preference('item-level_itypes')){
1073             # this should probably be a subroutine
1074             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1075             $sth->execute($effective_itemtype);
1076             my $notforloan=$sth->fetchrow_hashref();
1077             if ($notforloan->{'notforloan'}) {
1078                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1079                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1080                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1081                 } else {
1082                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1083                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1084                 }
1085             }
1086         }
1087         else {
1088             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1089             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1090                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1091                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1092                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1093                 } else {
1094                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1095                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1096                 }
1097             }
1098         }
1099     }
1100     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1101     {
1102         $issuingimpossible{WTHDRAWN} = 1;
1103     }
1104     if (   $item_object->restricted
1105         && $item_object->restricted == 1 )
1106     {
1107         $issuingimpossible{RESTRICTED} = 1;
1108     }
1109     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1110         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1111         my $code = $av->count ? $av->next->lib : '';
1112         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1113         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1114     }
1115     if ( C4::Context->preference("IndependentBranches") ) {
1116         my $userenv = C4::Context->userenv;
1117         unless ( C4::Context->IsSuperLibrarian() ) {
1118             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1119             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1120                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1121                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1122             }
1123             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1124               if ( $patron->branchcode ne $userenv->{branch} );
1125         }
1126     }
1127
1128     #
1129     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1130     #
1131     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1132     if ($rentalConfirmation) {
1133         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1134
1135         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1136         if ($itemtype_object) {
1137             my $accumulate_charge = $fees->accumulate_rentalcharge();
1138             if ( $accumulate_charge > 0 ) {
1139                 $rentalCharge += $accumulate_charge;
1140             }
1141         }
1142
1143         if ( $rentalCharge > 0 ) {
1144             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1145         }
1146     }
1147
1148     my $recall;
1149     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1150     # Only bother doing this if UseRecalls is enabled and the item is recallable
1151     # Don't look at recalls that are in transit
1152     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1153         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1154
1155         foreach my $r ( @recalls ) {
1156             if ( $r->item_id and
1157                 $r->item_id == $item_object->itemnumber and
1158                 $r->patron_id == $patron->borrowernumber and
1159                 ( $r->waiting or $r->requested ) ) {
1160                 $messages{RECALLED} = $r->id;
1161                 $recall = $r;
1162                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1163                 last;
1164             }
1165             elsif ( $r->item_id and
1166                 $r->item_id == $item_object->itemnumber and
1167                 $r->in_transit ) {
1168                 # recalled item is in transit
1169                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1170             }
1171             elsif ( $r->item_level and
1172                 $r->item_id == $item_object->itemnumber and
1173                 $r->patron_id != $patron->borrowernumber and
1174                 !$r->in_transit ) {
1175                 # this specific item has been recalled by a different patron
1176                 $needsconfirmation{RECALLED} = $r;
1177                 $recall = $r;
1178                 last;
1179             }
1180             elsif ( !$r->item_level and
1181                 $r->patron_id != $patron->borrowernumber and
1182                 !$r->in_transit ) {
1183                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1184                 $needsconfirmation{RECALLED} = $r;
1185                 $recall = $r;
1186                 last;
1187             }
1188         }
1189     }
1190
1191     unless ( $ignore_reserves || $recall ) {
1192         # See if the item is on reserve.
1193         my ( $restype, $res ) = CheckReserves( $item_object );
1194         if ($restype) {
1195             my $resbor = $res->{'borrowernumber'};
1196             if ( $resbor ne $patron->borrowernumber ) {
1197                 my $patron = Koha::Patrons->find( $resbor );
1198                 if ( $restype eq "Waiting" )
1199                 {
1200                     # The item is on reserve and waiting, but has been
1201                     # reserved by some other patron.
1202                     $needsconfirmation{RESERVE_WAITING} = 1;
1203                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1204                     $needsconfirmation{'ressurname'} = $patron->surname;
1205                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1206                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1207                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1208                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1209                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1210                 }
1211                 elsif ( $restype eq "Reserved" ) {
1212                     # The item is on reserve for someone else.
1213                     $needsconfirmation{RESERVED} = 1;
1214                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1215                     $needsconfirmation{'ressurname'} = $patron->surname;
1216                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1217                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1218                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1219                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1220                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1221                 }
1222                 elsif ( $restype eq "Transferred" ) {
1223                     # The item is determined hold being transferred for someone else.
1224                     $needsconfirmation{TRANSFERRED} = 1;
1225                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1226                     $needsconfirmation{'ressurname'} = $patron->surname;
1227                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1228                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1229                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1230                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1231                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1232                 }
1233                 elsif ( $restype eq "Processing" ) {
1234                     # The item is determined hold being processed for someone else.
1235                     $needsconfirmation{PROCESSING} = 1;
1236                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1237                     $needsconfirmation{'ressurname'} = $patron->surname;
1238                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1239                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1240                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1241                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1242                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1243                 }
1244             }
1245         }
1246     }
1247
1248     ## CHECK FOR BOOKINGS
1249     if (
1250         my $booking = $item_object->find_booking(
1251             {
1252                 checkout_date => $now,
1253                 due_date      => $duedate,
1254                 patron_id     => $patron->borrowernumber
1255             }
1256         )
1257         )
1258     {
1259         # Booked to this patron :)
1260         if ( $booking->patron_id == $patron->borrowernumber ) {
1261             if ( $now < dt_from_string( $booking->start_date ) ) {
1262                 $needsconfirmation{'BOOKED_EARLY'} = $booking;
1263             } else {
1264                 $alerts{'BOOKED'} = $booking;
1265             }
1266         }
1267
1268         # Booking starts before due date, reduce loan?
1269         elsif ( $duedate > dt_from_string( $booking->start_date ) ) {
1270             $needsconfirmation{'BOOKED_TO_ANOTHER'} = $booking;
1271         }
1272
1273         # Loan falls inside booking
1274         else {
1275             $issuingimpossible{'BOOKED_TO_ANOTHER'} = $booking;
1276         }
1277     }
1278
1279     ## CHECK AGE RESTRICTION
1280     my $agerestriction  = $biblioitem->agerestriction;
1281     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1282     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1283         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1284             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1285         }
1286         else {
1287             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1288         }
1289     }
1290
1291     ## check for high holds decreasing loan period
1292     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1293         my $check = checkHighHolds( $item_object, $patron );
1294
1295         if ( $check->{exceeded} ) {
1296             my $highholds = {
1297                 num_holds  => $check->{outstanding},
1298                 duration   => $check->{duration},
1299                 returndate => $check->{due_date},
1300             };
1301             if ($override_high_holds) {
1302                 $alerts{HIGHHOLDS} = $highholds;
1303             }
1304             else {
1305                 $needsconfirmation{HIGHHOLDS} = $highholds;
1306             }
1307         }
1308     }
1309
1310     if (
1311         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1312         # don't do the multiple loans per bib check if we've
1313         # already determined that we've got a loan on the same item
1314         !$issuingimpossible{NO_MORE_RENEWALS} &&
1315         !$needsconfirmation{RENEW_ISSUE}
1316     ) {
1317         # Check if borrower has already issued an item from the same biblio
1318         # Only if it's not a subscription
1319         my $biblionumber = $item_object->biblionumber;
1320         require C4::Serials;
1321         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1322         unless ($is_a_subscription) {
1323             # FIXME Should be $patron->checkouts($args);
1324             my $checkouts = Koha::Checkouts->search(
1325                 {
1326                     borrowernumber => $patron->borrowernumber,
1327                     biblionumber   => $biblionumber,
1328                 },
1329                 {
1330                     join => 'item',
1331                 }
1332             );
1333             # if we get here, we don't already have a loan on this item,
1334             # so if there are any loans on this bib, ask for confirmation
1335             if ( $checkouts->count ) {
1336                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1337             }
1338         }
1339     }
1340
1341     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1342 }
1343
1344 =head2 CanBookBeReturned
1345
1346   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1347
1348 Check whether the item can be returned to the provided branch
1349
1350 =over 4
1351
1352 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1353
1354 =item C<$branch> is the branchcode where the return is taking place
1355
1356 =back
1357
1358 Returns:
1359
1360 =over 4
1361
1362 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1363
1364 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1365
1366 =back
1367
1368 =cut
1369
1370 sub CanBookBeReturned {
1371   my ($item, $branch) = @_;
1372   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1373
1374   # assume return is allowed to start
1375   my $allowed = 1;
1376   my $message;
1377
1378   # identify all cases where return is forbidden
1379   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1380      $allowed = 0;
1381      $message = $item->{'homebranch'};
1382   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1383      $allowed = 0;
1384      $message = $item->{'holdingbranch'};
1385   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1386      $allowed = 0;
1387      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1388   }
1389
1390   return ($allowed, $message);
1391 }
1392
1393 =head2 CheckHighHolds
1394
1395     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1396     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1397     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1398
1399 =cut
1400
1401 sub checkHighHolds {
1402     my ( $item, $patron ) = @_;
1403     my $branchcode = _GetCircControlBranch( $item, $patron );
1404
1405     my $return_data = {
1406         exceeded    => 0,
1407         outstanding => 0,
1408         duration    => 0,
1409         due_date    => undef,
1410     };
1411
1412
1413     # Count holds on this record, ignoring the borrowers own holds as they would be filled by the checkout
1414     my $holds = Koha::Holds->search({
1415         biblionumber => $item->biblionumber,
1416         borrowernumber => { '!=' => $patron->borrowernumber }
1417     });
1418
1419     if ( $holds->count() ) {
1420         $return_data->{outstanding} = $holds->count();
1421
1422         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1423         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1424         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1425
1426         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1427
1428         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1429
1430             # static means just more than a given number of holds on the record
1431
1432             # If the number of holds is not above the threshold, we can stop here
1433             if ( $holds->count() <= $decreaseLoanHighHoldsValue ) {
1434                 return $return_data;
1435             }
1436         }
1437         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1438
1439             # dynamic means X more than the number of holdable items on the record
1440
1441             # let's get the items
1442             my @items = $holds->next()->biblio()->items()->as_list;
1443
1444             # Remove any items with status defined to be ignored even if the would not make item unholdable
1445             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1446                 @items = grep { !$_->$status } @items;
1447             }
1448
1449             # Remove any items that are not holdable for this patron
1450             # We need to ignore hold counts as the borrower's own hold that will be filled by the checkout
1451             # could prevent them from placing further holds
1452             @items = grep { CanItemBeReserved( $patron, $_, undef, { ignore_hold_counts => 1 } )->{status} eq 'OK' } @items;
1453
1454             my $items_count = scalar @items;
1455
1456             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1457
1458             # If the number of holds is less than the count of items we have
1459             # plus the number of holds allowed above that count, we can stop here
1460             if ( $holds->count() <= $threshold ) {
1461                 return $return_data;
1462             }
1463         }
1464
1465         my $issuedate = dt_from_string();
1466
1467         my $itype = $item->effective_itemtype;
1468         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1469             {
1470                 categorycode => $patron->categorycode,
1471                 itemtype     => $itype,
1472                 branchcode   => $branchcode,
1473             }
1474         );
1475         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1476
1477         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron );
1478
1479         my $rule = Koha::CirculationRules->get_effective_rule_value(
1480             {
1481                 categorycode => $patron->categorycode,
1482                 itemtype     => $item->effective_itemtype,
1483                 branchcode   => $branchcode,
1484                 rule_name    => 'decreaseloanholds',
1485             }
1486         );
1487
1488         my $duration;
1489         if ( defined($rule) && $rule ne '' ){
1490             # overrides decreaseLoanHighHoldsDuration syspref
1491             $duration = $rule;
1492         } else {
1493             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1494         }
1495         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1496         $reduced_datedue->set_hour($orig_due->hour);
1497         $reduced_datedue->set_minute($orig_due->minute);
1498         $reduced_datedue->truncate( to => 'minute' );
1499
1500         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1501             $return_data->{exceeded} = 1;
1502             $return_data->{duration} = $duration;
1503             $return_data->{due_date} = $reduced_datedue;
1504         }
1505     }
1506
1507     return $return_data;
1508 }
1509
1510 =head2 AddIssue
1511
1512   &AddIssue($patron, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1513
1514 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1515
1516 =over 4
1517
1518 =item C<$patron> is a patron object.
1519
1520 =item C<$barcode> is the barcode of the item being issued.
1521
1522 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1523 Calculated if empty.
1524
1525 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1526
1527 =item C<$issuedate> is a DateTime object for the date to issue the item (optional).
1528 Defaults to today.
1529
1530 AddIssue does the following things :
1531
1532   - step 01: check that there is a borrowernumber & a barcode provided
1533   - check for RENEWAL (book issued & being issued to the same patron)
1534       - renewal YES = Calculate Charge & renew
1535       - renewal NO  =
1536           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1537           * RESERVE PLACED ?
1538               - fill reserve if reserve to this patron
1539               - cancel reserve or not, otherwise
1540           * RECALL PLACED ?
1541               - fill recall if recall to this patron
1542               - cancel recall or not
1543               - revert recall's waiting status or not
1544           * TRANSFERT PENDING ?
1545               - complete the transfert
1546           * ISSUE THE BOOK
1547
1548 =back
1549
1550 =cut
1551
1552 sub AddIssue {
1553     my ( $patron, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1554
1555     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1556     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1557     my $auto_renew = $params && $params->{auto_renew};
1558     my $cancel_recall = $params && $params->{cancel_recall};
1559     my $recall_id = $params && $params->{recall_id};
1560     my $dbh          = C4::Context->dbh;
1561     my $barcodecheck = CheckValidBarcode($barcode);
1562
1563     my $issue;
1564
1565     if ( $datedue && ref $datedue ne 'DateTime' ) {
1566         $datedue = dt_from_string($datedue);
1567     }
1568
1569     # $issuedate defaults to today.
1570     if ( !defined $issuedate ) {
1571         $issuedate = dt_from_string();
1572     }
1573     else {
1574         if ( ref $issuedate ne 'DateTime' ) {
1575             $issuedate = dt_from_string($issuedate);
1576
1577         }
1578     }
1579
1580     # Stop here if the patron or barcode doesn't exist
1581     if ( $patron && $barcode && $barcodecheck ) {
1582         # find which item we issue
1583         my $item_object = Koha::Items->find({ barcode => $barcode })
1584           or return;    # if we don't get an Item, abort.
1585         my $item_unblessed = $item_object->unblessed;
1586
1587         my $branchcode = _GetCircControlBranch( $item_object, $patron );
1588
1589         # get actual issuing if there is one
1590         my $actualissue = $item_object->checkout;
1591
1592         # check if we just renew the issue.
1593         if ( $actualissue and $actualissue->borrowernumber eq $patron->borrowernumber
1594                 and not $switch_onsite_checkout ) {
1595             $datedue = AddRenewal(
1596                 {
1597                     borrowernumber => $patron->borrowernumber,
1598                     itemnumber     => $item_object->itemnumber,
1599                     branch         => $branchcode,
1600                     datedue        => $datedue,
1601                     lastreneweddate =>
1602                       $issuedate,    # here interpreted as the renewal date
1603                 }
1604             );
1605             $issue = $item_object->checkout;
1606         }
1607         else {
1608
1609             unless ($datedue) {
1610                 my $itype = $item_object->effective_itemtype;
1611                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $patron );
1612
1613             }
1614
1615             # Check if we need to use an exact due date set by the ILL module
1616             if ( C4::Context->preference('ILLModule') ) {
1617                 # Check if there is an ILL connected with the biblio of the item we are issuing
1618                 my $ill_request = Koha::Illrequests->search({
1619                     biblio_id => $item_object->biblionumber,
1620                     borrowernumber => $patron->borrowernumber,
1621                     completed => undef,
1622                     due_date => { '!=', undef },
1623                 })->next;
1624
1625                 if ( $ill_request and length( $ill_request->due_date ) > 0 ) {
1626                     my $ill_dt = dt_from_string( $ill_request->due_date );
1627                     $ill_dt->set_hour(23);
1628                     $ill_dt->set_minute(59);
1629                     $datedue = $ill_dt;
1630                 }
1631             }
1632
1633             $datedue->truncate( to => 'minute' );
1634
1635             my $library = Koha::Libraries->find( $branchcode );
1636             my $fees = Koha::Charges::Fees->new(
1637                 {
1638                     patron    => $patron,
1639                     library   => $library,
1640                     item      => $item_object,
1641                     to_date   => $datedue,
1642                 }
1643             );
1644
1645             # it's NOT a renewal
1646             if ( $actualissue and not $switch_onsite_checkout ) {
1647                 # This book is currently on loan, but not to the person
1648                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1649                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1650                 return unless $allowed;
1651                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1652                 # AddReturn certainly has side-effects, like onloan => undef
1653                 $item_object->discard_changes;
1654             }
1655
1656             if ( C4::Context->preference('UseRecalls') ) {
1657                 Koha::Recalls->move_recall(
1658                     {
1659                         action         => $cancel_recall,
1660                         recall_id      => $recall_id,
1661                         item           => $item_object,
1662                         borrowernumber => $patron->borrowernumber,
1663                     }
1664                 );
1665             }
1666
1667             C4::Reserves::MoveReserve( $item_object->itemnumber, $patron->borrowernumber, $cancelreserve );
1668
1669             # Starting process for transfer job (checking transfert and validate it if we have one)
1670             if ( my $transfer = $item_object->get_transfer ) {
1671                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1672                 $transfer->set(
1673                     {
1674                         datearrived => dt_from_string,
1675                         tobranch    => C4::Context->userenv->{branch},
1676                         comments    => 'Forced branchtransfer'
1677                     }
1678                 )->store;
1679                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1680                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1681                     if ( $hold ) { # Is this really needed?
1682                         $hold->set( { found => undef } )->store;
1683                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1684                     }
1685                 }
1686             }
1687
1688             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1689             unless ($auto_renew) {
1690                 my $rule = Koha::CirculationRules->get_effective_rule_value(
1691                     {
1692                         categorycode => $patron->categorycode,
1693                         itemtype     => $item_object->effective_itemtype,
1694                         branchcode   => $branchcode,
1695                         rule_name    => 'auto_renew'
1696                     }
1697                 );
1698
1699                 $auto_renew = $rule if defined $rule && $rule ne '';
1700             }
1701
1702             my $issue_attributes = {
1703                 borrowernumber  => $patron->borrowernumber,
1704                 issuedate       => $issuedate,
1705                 date_due        => $datedue,
1706                 branchcode      => C4::Context->userenv->{'branch'},
1707                 onsite_checkout => $onsite_checkout,
1708                 auto_renew      => $auto_renew ? 1 : 0,
1709             };
1710
1711             # Get ID of logged in user.  if called from a batch job,
1712             # no user session exists and C4::Context->userenv() returns
1713             # the scalar '0'. Only do this if the syspref says so
1714             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1715                 my $userenv = C4::Context->userenv();
1716                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1717                 if ($usernumber) {
1718                     $issue_attributes->{issuer_id} = $usernumber;
1719                 }
1720             }
1721
1722             # In the case that the borrower has an on-site checkout
1723             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1724             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1725             if ($issue) {
1726                 $issue->set($issue_attributes)->store;
1727             }
1728             else {
1729                 $issue = Koha::Checkout->new(
1730                     {
1731                         itemnumber => $item_object->itemnumber,
1732                         %$issue_attributes,
1733                     }
1734                 )->store;
1735
1736                 # Ensure item is no longer listed in the holds queue
1737                 $dbh->do(
1738                     q{DELETE tmp_holdsqueue, hold_fill_targets FROM tmp_holdsqueue LEFT JOIN hold_fill_targets USING ( itemnumber ) WHERE itemnumber = ?},
1739                     undef, $item_object->id
1740                 );
1741             }
1742             $issue->discard_changes;
1743             $patron->update_lastseen('check_out');
1744             if ( $item_object->location && $item_object->location eq 'CART'
1745                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1746             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1747                 CartToShelf( $item_object->itemnumber );
1748             }
1749
1750             # Update item location
1751             $item_object->location_update_trigger( 'checkout' );
1752
1753             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1754                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1755             }
1756
1757             # Record if item was lost
1758             my $was_lost = $item_object->itemlost;
1759
1760             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1761             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1762             $item_object->itemlost(0);
1763             $item_object->onloan($datedue->ymd());
1764             $item_object->datelastborrowed( dt_from_string()->ymd() );
1765             $item_object->datelastseen( dt_from_string() );
1766             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1767
1768             # If the item was lost, it has now been found, charge the overdue if necessary
1769             if ($was_lost) {
1770                 if ( $item_object->{_charge} ) {
1771                     $actualissue //= Koha::Old::Checkouts->search(
1772                         { itemnumber => $item_object->itemnumber },
1773                         {
1774                             order_by => { '-desc' => 'returndate' },
1775                             rows     => 1
1776                         }
1777                     )->single;
1778                     unless ( $patron->branchcode ) {
1779                         $patron = $actualissue->patron;
1780                     }
1781                     _CalculateAndUpdateFine(
1782                         {
1783                             issue       => $actualissue,
1784                             item        => $item_unblessed,
1785                             borrower    => $patron->unblessed,
1786                             return_date => $issuedate
1787                         }
1788                     );
1789                     _FixOverduesOnReturn( $patron->borrowernumber,
1790                         $item_object->itemnumber, undef, 'RENEWED' );
1791                 }
1792             }
1793
1794             # If it costs to borrow this book, charge it to the patron's account.
1795             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1796             if ( $charge && $charge > 0 ) {
1797                 AddIssuingCharge( $issue, $charge, 'RENT' );
1798             }
1799
1800             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1801             if ( $itemtype_object ) {
1802                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1803                 if ( $accumulate_charge > 0 ) {
1804                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1805                     $charge += $accumulate_charge;
1806                     $item_unblessed->{charge} = $charge;
1807                 }
1808             }
1809
1810             my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckout');
1811             if ($yaml) {
1812                 $yaml = "$yaml\n\n";
1813
1814                 my $rules;
1815                 eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
1816                 if ($@) {
1817                     warn "Unable to parse UpdateNotForLoanStatusOnCheckout syspref : $@";
1818                 }
1819                 else {
1820                     foreach my $key ( keys %$rules ) {
1821                         if ( $item_object->notforloan eq $key ) {
1822                             $item_object->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
1823                             last;
1824                         }
1825                     }
1826                 }
1827             }
1828
1829             # Record the fact that this book was issued.
1830             C4::Stats::UpdateStats(
1831                 {
1832                     branch => C4::Context->userenv->{'branch'},
1833                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1834                     amount         => $charge,
1835                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1836                     itemnumber     => $item_object->itemnumber,
1837                     itemtype       => $item_object->effective_itemtype,
1838                     location       => $item_object->location,
1839                     borrowernumber => $patron->borrowernumber,
1840                     ccode          => $item_object->ccode,
1841                     categorycode   => $patron->categorycode
1842                 }
1843             );
1844
1845             # Send a checkout slip.
1846             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1847             my %conditions        = (
1848                 branchcode   => $branchcode,
1849                 categorycode => $patron->categorycode,
1850                 item_type    => $item_object->effective_itemtype,
1851                 notification => 'CHECKOUT',
1852             );
1853             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1854                 SendCirculationAlert(
1855                     {
1856                         type     => 'CHECKOUT',
1857                         item     => $item_object->unblessed,
1858                         borrower => $patron->unblessed,
1859                         branch   => $branchcode,
1860                     }
1861                 );
1862             }
1863             logaction(
1864                 "CIRCULATION", "ISSUE",
1865                 $patron->borrowernumber,
1866                 $item_object->itemnumber,
1867             ) if C4::Context->preference("IssueLog");
1868
1869             Koha::Plugins->call('after_circ_action', {
1870                 action  => 'checkout',
1871                 payload => {
1872                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1873                     checkout => $issue->get_from_storage
1874                 }
1875             });
1876
1877             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1878                 {
1879                     biblio_ids => [ $item_object->biblionumber ]
1880                 }
1881             ) if C4::Context->preference('RealTimeHoldsQueue');
1882         }
1883     }
1884     return $issue;
1885 }
1886
1887 =head2 GetLoanLength
1888
1889   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1890
1891 Get loan length for an itemtype, a borrower type and a branch
1892
1893 =cut
1894
1895 sub GetLoanLength {
1896     my ( $categorycode, $itemtype, $branchcode ) = @_;
1897
1898     # Initialize default values
1899     my $rules = {
1900         issuelength   => 0,
1901         renewalperiod => 0,
1902         lengthunit    => 'days',
1903     };
1904
1905     my $found = Koha::CirculationRules->get_effective_rules( {
1906         branchcode => $branchcode,
1907         categorycode => $categorycode,
1908         itemtype => $itemtype,
1909         rules => [
1910             'issuelength',
1911             'renewalperiod',
1912             'lengthunit'
1913         ],
1914     } );
1915
1916     # Search for rules!
1917     foreach my $rule_name (keys %$found) {
1918         $rules->{$rule_name} = $found->{$rule_name};
1919     }
1920
1921     return $rules;
1922 }
1923
1924
1925 =head2 GetHardDueDate
1926
1927   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1928
1929 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1930
1931 =cut
1932
1933 sub GetHardDueDate {
1934     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1935
1936     my $rules = Koha::CirculationRules->get_effective_rules(
1937         {
1938             categorycode => $borrowertype,
1939             itemtype     => $itemtype,
1940             branchcode   => $branchcode,
1941             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1942         }
1943     );
1944
1945     if ( defined( $rules->{hardduedate} ) ) {
1946         if ( $rules->{hardduedate} ) {
1947             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1948         }
1949         else {
1950             return ( undef, undef );
1951         }
1952     }
1953 }
1954
1955 =head2 GetBranchBorrowerCircRule
1956
1957   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1958
1959 Retrieves circulation rule attributes that apply to the given
1960 branch and patron category, regardless of item type.
1961 The return value is a hashref containing the following key:
1962
1963 patron_maxissueqty - maximum number of loans that a
1964 patron of the given category can have at the given
1965 branch.  If the value is undef, no limit.
1966
1967 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1968 patron of the given category can have at the given
1969 branch.  If the value is undef, no limit.
1970
1971 This will check for different branch/category combinations in the following order:
1972 branch and category
1973 branch only
1974 category only
1975 default branch and category
1976
1977 If no rule has been found in the database, it will default to
1978 the buillt in rule:
1979
1980 patron_maxissueqty - undef
1981 patron_maxonsiteissueqty - undef
1982
1983 C<$branchcode> and C<$categorycode> should contain the
1984 literal branch code and patron category code, respectively - no
1985 wildcards.
1986
1987 =cut
1988
1989 sub GetBranchBorrowerCircRule {
1990     my ( $branchcode, $categorycode ) = @_;
1991
1992     # Initialize default values
1993     my $rules = {
1994         patron_maxissueqty       => undef,
1995         patron_maxonsiteissueqty => undef,
1996     };
1997
1998     # Search for rules!
1999     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
2000         my $rule = Koha::CirculationRules->get_effective_rule(
2001             {
2002                 categorycode => $categorycode,
2003                 itemtype     => undef,
2004                 branchcode   => $branchcode,
2005                 rule_name    => $rule_name,
2006             }
2007         );
2008
2009         $rules->{$rule_name} = $rule->rule_value if defined $rule;
2010     }
2011
2012     return $rules;
2013 }
2014
2015 =head2 GetBranchItemRule
2016
2017   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
2018
2019 Retrieves circulation rule attributes that apply to the given
2020 branch and item type, regardless of patron category.
2021
2022 The return value is a hashref containing the following keys:
2023
2024 holdallowed => Hold policy for this branch and itemtype. Possible values:
2025   not_allowed:           No holds allowed.
2026   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
2027   from_any_library:      Holds allowed from any patron.
2028   from_local_hold_group: Holds allowed from libraries in hold group
2029
2030 This searches branchitemrules in the following order:
2031
2032   * Same branchcode and itemtype
2033   * Same branchcode, itemtype '*'
2034   * branchcode '*', same itemtype
2035   * branchcode and itemtype '*'
2036
2037 Neither C<$branchcode> nor C<$itemtype> should be '*'.
2038
2039 =cut
2040
2041 sub GetBranchItemRule {
2042     my ( $branchcode, $itemtype ) = @_;
2043
2044     # Search for rules!
2045     my $rules = Koha::CirculationRules->get_effective_rules({
2046         branchcode => $branchcode,
2047         itemtype => $itemtype,
2048         rules => ['holdallowed', 'hold_fulfillment_policy']
2049     });
2050
2051     # built-in default circulation rule
2052     $rules->{holdallowed} //= 'from_any_library';
2053     $rules->{hold_fulfillment_policy} //= 'any';
2054
2055     return $rules;
2056 }
2057
2058 =head2 AddReturn
2059
2060   ($doreturn, $messages, $iteminformation, $borrower) =
2061       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] [,$skip_localuse ] );
2062
2063 Returns a book.
2064
2065 =over 4
2066
2067 =item C<$barcode> is the bar code of the book being returned.
2068
2069 =item C<$branch> is the code of the branch where the book is being returned.
2070
2071 =item C<$exemptfine> indicates that overdue charges for the item will be
2072 removed. Optional.
2073
2074 =item C<$return_date> allows the default return date to be overridden
2075 by the given return date. Optional.
2076
2077 =item C<$skip_localuse> indicated that localuse should not be recorded. Optional.
2078
2079 =back
2080
2081 C<&AddReturn> returns a list of four items:
2082
2083 C<$doreturn> is true iff the return succeeded.
2084
2085 C<$messages> is a reference-to-hash giving feedback on the operation.
2086 The keys of the hash are:
2087
2088 =over 4
2089
2090 =item C<BadBarcode>
2091
2092 No item with this barcode exists. The value is C<$barcode>.
2093
2094 =item C<NotIssued>
2095
2096 The book is not currently on loan. The value is C<$barcode>.
2097
2098 =item C<withdrawn>
2099
2100 This book has been withdrawn/cancelled. The value should be ignored.
2101
2102 =item C<Wrongbranch>
2103
2104 This book has was returned to the wrong branch.  The value is a hashref
2105 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2106 contain the branchcode of the incorrect and correct return library, respectively.
2107
2108 =item C<ResFound>
2109
2110 The item was reserved. The value is a reference-to-hash whose keys are
2111 fields from the reserves table of the Koha database, and
2112 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2113 either C<Waiting>, C<Reserved>, or 0.
2114
2115 =item C<WasReturned>
2116
2117 Value 1 if return is successful.
2118
2119 =item C<NeedsTransfer>
2120
2121 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2122
2123 =item C<RecallFound>
2124
2125 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2126 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2127 branchcode.
2128
2129 =item C<TransferredRecall>
2130
2131 This item has been transferred to this branch to fill a recall. The recall object is returned.
2132
2133 =back
2134
2135 C<$iteminformation> is a reference-to-hash, giving information about the
2136 returned item from the issues table.
2137
2138 C<$borrower> is a reference-to-hash, giving information about the
2139 patron who last borrowed the book.
2140
2141 =cut
2142
2143 sub AddReturn {
2144     my ( $barcode, $branch, $exemptfine, $return_date, $skip_localuse ) = @_;
2145
2146     if ($branch and not Koha::Libraries->find($branch)) {
2147         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2148         undef $branch;
2149     }
2150     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2151     my $return_date_specified = !!$return_date;
2152     $return_date //= dt_from_string();
2153     my $messages;
2154     my $patron;
2155     my $doreturn       = 1;
2156     my $validTransfer = 1;
2157     my $stat_type = 'return';
2158
2159     # get information on item
2160     my $item = Koha::Items->find({ barcode => $barcode });
2161     unless ($item) {
2162         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2163     }
2164
2165     my $itemnumber = $item->itemnumber;
2166     my $itemtype = $item->effective_itemtype;
2167
2168     my $issue  = $item->checkout;
2169     if ( $issue ) {
2170         $patron = $issue->patron
2171             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2172                 . Dumper($issue->unblessed) . "\n";
2173     } else {
2174         $messages->{'NotIssued'} = $barcode;
2175         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2176
2177         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2178         $doreturn = 0;
2179         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2180         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2181         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2182            $messages->{'LocalUse'} = 1;
2183            $stat_type = 'localuse';
2184         }
2185     }
2186
2187     if ( $item->withdrawn ) { # book has been cancelled
2188         $messages->{'withdrawn'} = 1;
2189
2190         # In the case where we block return of withdrawn, we should completely block the return
2191         # without updating item statuses, so we exit early
2192         return ( 0, $messages, $issue, ( $patron ? $patron->unblessed : {} ))
2193             if C4::Context->preference("BlockReturnOfWithdrawnItems");
2194     }
2195
2196
2197     # full item data, but no borrowernumber or checkout info (no issue)
2198     my $hbr = Koha::CirculationRules->get_return_branch_policy($item);
2199
2200     # check if returnbranch and homebranch belong to the same float group
2201     my $validate_float =
2202         Koha::Libraries->find( $item->homebranch )->validate_float_sibling( { branchcode => $branch } );
2203
2204     # get the proper branch to which to return the item
2205     my $returnbranch;
2206     if ( $hbr eq 'noreturn' ) {
2207         $returnbranch = $branch;
2208     } elsif ( $hbr eq 'returnbylibrarygroup' ) {
2209
2210         # if library isn't in same the float group, transfer item to homebranch
2211         $hbr          = 'homebranch';
2212         $returnbranch = $validate_float ? $branch : $item->$hbr;
2213     } else {
2214         $returnbranch = $item->$hbr;
2215     }
2216
2217     # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2218     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2219
2220     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2221     my $patron_unblessed = $patron ? $patron->unblessed : {};
2222
2223     # Update item location
2224     my $loc_messages = $item->location_update_trigger( 'checkin' );
2225     foreach my $loc_msg_key ( keys %$loc_messages ) {
2226         $messages->{ $loc_msg_key } = $loc_messages->{ $loc_msg_key };
2227     }
2228
2229     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2230     if ($yaml) {
2231         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2232         my $rules;
2233         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2234         if ($@) {
2235             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2236         }
2237         else {
2238             if ( defined $rules->{$item->itype} ) {
2239                 foreach my $notloan_rule_key (keys %{ $rules->{$item->itype}} ) {
2240                     if ( $item->notforloan eq $notloan_rule_key ) {
2241                         $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$item->itype}->{$notloan_rule_key} };
2242                         $item->notforloan( $rules->{ $item->itype }->{$notloan_rule_key} )
2243                             ->store( { log_action => 0, skip_record_index => 1, skip_holds_queue => 1 } )
2244                             unless $rules->{ $item->itype }->{$notloan_rule_key} eq 'ONLYMESSAGE';
2245                         last;
2246                     }
2247                 }
2248             } elsif ( defined $rules->{'_ALL_'} ) {
2249                 foreach my $notloan_rule_key (keys %{ $rules->{'_ALL_'}} ) {
2250                     if ( $item->notforloan eq $notloan_rule_key ) {
2251                         $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{'_ALL_'}->{$notloan_rule_key} };
2252                         $item->notforloan( $rules->{'_ALL_'}->{$notloan_rule_key} )
2253                             ->store( { log_action => 0, skip_record_index => 1, skip_holds_queue => 1 } )
2254                             unless $rules->{ '_ALL_' }->{$notloan_rule_key} eq 'ONLYMESSAGE';
2255                         last;
2256                     }
2257                 }
2258             }
2259         }
2260     }
2261
2262     # check if the return is allowed at this branch
2263     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2264     unless ($returnallowed){
2265         $messages->{'Wrongbranch'} = {
2266             Wrongbranch => $branch,
2267             Rightbranch => $message
2268         };
2269         $doreturn = 0;
2270         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2271         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2272         return ( $doreturn, $messages, $issue, $patron_unblessed);
2273     }
2274
2275     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2276         $doreturn = 0;
2277     }
2278
2279     # case of a return of document (deal with issues and holdingbranch)
2280     if ($doreturn) {
2281         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2282         $patron or warn "AddReturn without current borrower";
2283
2284         if ($patron) {
2285             eval {
2286                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2287             };
2288             unless ( $@ ) {
2289                 if (
2290                     (
2291                         C4::Context->preference('CalculateFinesOnReturn')
2292                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2293                     )
2294                     && !$item->itemlost
2295                   )
2296                 {
2297                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2298                 }
2299             } else {
2300                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2301
2302                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2303                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2304
2305                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2306             }
2307
2308             # FIXME is the "= 1" right?  This could be the borrower hash.
2309             $messages->{'WasReturned'} = 1;
2310
2311         } else {
2312             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2313         }
2314     }
2315
2316     # the holdingbranch is updated if the document is returned to another location.
2317     # this is always done regardless of whether the item was on loan or not
2318     if ($item->holdingbranch ne $branch) {
2319         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2320     }
2321
2322     my $item_was_lost = $item->itemlost;
2323     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2324     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2325
2326     # fix up the accounts.....
2327     if ($item_was_lost) {
2328         $messages->{'WasLost'} = 1;
2329         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2330             my @object_messages = @{ $updated_item->object_messages };
2331             for my $message (@object_messages) {
2332                 $messages->{'LostItemFeeRefunded'} = 1
2333                   if $message->message eq 'lost_refunded';
2334                 $messages->{'ProcessingFeeRefunded'} = 1
2335                   if $message->message eq 'processing_refunded';
2336                 $messages->{'LostItemFeeRestored'} = 1
2337                   if $message->message eq 'lost_restored';
2338
2339                 if ( $message->message eq 'lost_charge' ) {
2340                     $issue //= Koha::Old::Checkouts->search(
2341                         { itemnumber => $item->itemnumber },
2342                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2343                     )->single;
2344                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2345                         my $patron = $issue->patron;
2346                         $patron_unblessed = $patron->unblessed;
2347                     }
2348                     _CalculateAndUpdateFine(
2349                         {
2350                             issue       => $issue,
2351                             item        => $item->unblessed,
2352                             borrower    => $patron_unblessed,
2353                             return_date => $return_date
2354                         }
2355                     );
2356                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2357                         $item->itemnumber, undef, 'RETURNED' );
2358                     $messages->{'LostItemFeeCharged'} = 1;
2359                 }
2360             }
2361         }
2362     }
2363
2364     # check if we have a transfer for this document
2365     my $transfer = $item->get_transfer;
2366
2367     # if we have a transfer to complete, we update the line of transfers with the datearrived
2368     if ($transfer) {
2369         $validTransfer = 0;
2370         if ( $transfer->in_transit ) {
2371             if ( $transfer->tobranch eq $branch ) {
2372                 $transfer->receive;
2373                 $messages->{'TransferArrived'} = $transfer->frombranch;
2374                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2375                 $validTransfer = 1
2376                   if defined $transfer->reason && $transfer->reason eq 'Reserve';
2377             }
2378             else {
2379                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2380                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2381                 $messages->{'TransferTrigger'}   = $transfer->reason;
2382             }
2383         }
2384         else {
2385             if ( $transfer->tobranch eq $branch ) {
2386                 $transfer->receive;
2387                 $messages->{'TransferArrived'} = $transfer->frombranch;
2388                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2389                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2390             }
2391             else {
2392                 $messages->{'TransferTrigger'} = $transfer->reason;
2393                 if ( $transfer->frombranch eq $branch ) {
2394                     $transfer->transit;
2395                     $messages->{'WasTransfered'}   = $transfer->tobranch;
2396                 }
2397                 else {
2398                     $messages->{'WrongTransfer'}     = $transfer->tobranch;
2399                     $messages->{'WrongTransferItem'} = $item->itemnumber;
2400                 }
2401             }
2402         }
2403     }
2404
2405     # fix up the overdues in accounts...
2406     if ($borrowernumber) {
2407         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2408         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2409
2410         if ( $issue and $issue->is_overdue($return_date) ) {
2411         # fix fine days
2412             my ($debardate,$reminder) = _debar_user_on_return( $patron, $item, dt_from_string($issue->date_due), $return_date );
2413             if ($debardate and $debardate ne "9999-12-31") {
2414                 if ($reminder){
2415                     $messages->{'PrevDebarred'} = $debardate;
2416                 } else {
2417                     $messages->{'Debarred'} = $debardate;
2418                 }
2419             } elsif ($patron->debarred) {
2420                 if ( $patron->debarred eq "9999-12-31") {
2421                     $messages->{'ForeverDebarred'} = $patron->debarred;
2422                 } else {
2423                     my $borrower_debar_dt = dt_from_string( $patron->debarred );
2424                     $borrower_debar_dt->truncate(to => 'day');
2425                     my $today_dt = $return_date->clone()->truncate(to => 'day');
2426                     if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2427                         $messages->{'PrevDebarred'} = $patron->debarred;
2428                     }
2429                 }
2430             }
2431         # there's no overdue on the item but borrower had been previously debarred
2432         } elsif ( $issue->date_due and $patron->debarred ) {
2433              if ( $patron->debarred eq "9999-12-31") {
2434                 $messages->{'ForeverDebarred'} = $patron->debarred;
2435              } else {
2436                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2437                   $borrower_debar_dt->truncate(to => 'day');
2438                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2439                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2440                       $messages->{'PrevDebarred'} = $patron->debarred;
2441                   }
2442              }
2443         }
2444     }
2445
2446     # find recalls...
2447     if ( C4::Context->preference('UseRecalls') ) {
2448         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2449         my $recall = undef;
2450         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2451         if ( defined $recall ) {
2452             $messages->{RecallFound} = $recall;
2453             if ( $recall->pickup_library_id ne $branch ) {
2454                 $messages->{RecallNeedsTransfer} = $branch;
2455             }
2456         }
2457     }
2458
2459     # find reserves.....
2460     # launch the Checkreserves routine to find any holds
2461     my ($resfound, $resrec);
2462     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2463     ($resfound, $resrec, undef) = CheckReserves( $item, $lookahead ) unless ( $item->withdrawn );
2464     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2465     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2466         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2467         $resfound = 'Reserved';
2468         $resrec = $hold->unblessed;
2469     }
2470     if ($resfound) {
2471           $resrec->{'ResFound'} = $resfound;
2472         $messages->{'ResFound'} = $resrec;
2473     }
2474
2475     # Record the fact that this book was returned.
2476     my $categorycode = $patron_unblessed ? $patron_unblessed->{categorycode} : undef;
2477     C4::Stats::UpdateStats({
2478         branch         => $branch,
2479         type           => $stat_type,
2480         itemnumber     => $itemnumber,
2481         itemtype       => $itemtype,
2482         location       => $item->location,
2483         borrowernumber => $borrowernumber,
2484         ccode          => $item->ccode,
2485         categorycode   => $categorycode,
2486         interface      => C4::Context->interface,
2487     }) unless ( $skip_localuse && $stat_type eq 'localuse' );
2488
2489     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2490     if ( $patron ) {
2491         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2492         my %conditions = (
2493             branchcode   => $branch,
2494             categorycode => $patron->categorycode,
2495             item_type    => $itemtype,
2496             notification => 'CHECKIN',
2497         );
2498         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2499             SendCirculationAlert({
2500                 type     => 'CHECKIN',
2501                 item     => $item->unblessed,
2502                 borrower => $patron->unblessed,
2503                 branch   => $branch,
2504                 issue    => $issue
2505             });
2506         }
2507
2508         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2509             if C4::Context->preference("ReturnLog");
2510
2511         #Update borrowers.lastseen
2512         $patron->update_lastseen('check_in');
2513     }
2514
2515     # Check if this item belongs to a biblio record that is attached to an
2516     # ILL request, if it is we need to update the ILL request's status
2517     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2518         my $request = Koha::Illrequests->find(
2519             { biblio_id => $item->biblio->biblionumber }
2520         );
2521         $request->status('RET') if $request;
2522     }
2523
2524     if ( C4::Context->preference('UseRecalls') ) {
2525         # all recalls that have triggered a transfer will have an allocated itemnumber
2526         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2527         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2528             $messages->{TransferredRecall} = $transfer_recall;
2529         }
2530     }
2531
2532     if ( $messages->{WasLost} and C4::Context->preference('BlockReturnOfLostItems') ) {
2533         $validTransfer = 0;
2534     }
2535
2536     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2537     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2538         && ( $doreturn or $messages->{'NotIssued'} )
2539         and !$resfound
2540         and ( $branch ne $returnbranch )
2541         and not $messages->{'WrongTransfer'}
2542         and not $messages->{'WasTransfered'}
2543         and not $messages->{TransferredRecall}
2544         and not $messages->{RecallNeedsTransfer} )
2545     {
2546         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2547         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2548             (C4::Context->preference("UseBranchTransferLimits") and
2549              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2550            )) {
2551             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2552             $messages->{'WasTransfered'} = $returnbranch;
2553             $messages->{'TransferTrigger'} = $transfer_trigger;
2554         } else {
2555             $messages->{'NeedsTransfer'} = $returnbranch;
2556             $messages->{'TransferTrigger'} = $transfer_trigger;
2557         }
2558     }
2559
2560     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2561         my $claims = Koha::Checkouts::ReturnClaims->search(
2562            {
2563                itemnumber => $item->id,
2564                resolution => undef,
2565            }
2566         );
2567
2568         if ( $claims->count ) {
2569             $messages->{ReturnClaims} = $claims;
2570         }
2571     }
2572
2573     # Check for bundle status
2574     if ( $item->in_bundle ) {
2575         my $host = $item->bundle_host;
2576         $messages->{InBundle} = $host;
2577     }
2578
2579     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2580     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2581
2582     if ( $doreturn and $issue ) {
2583         my $checkin = Koha::Old::Checkouts->find($issue->id);
2584
2585         Koha::Plugins->call('after_circ_action', {
2586             action  => 'checkin',
2587             payload => {
2588                 checkout=> $checkin
2589             }
2590         });
2591
2592         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2593             {
2594                 biblio_ids => [ $item->biblionumber ]
2595             }
2596         ) if C4::Context->preference('RealTimeHoldsQueue');
2597     }
2598
2599     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2600 }
2601
2602 =head2 MarkIssueReturned
2603
2604   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2605
2606 Unconditionally marks an issue as being returned by
2607 moving the C<issues> row to C<old_issues> and
2608 setting C<returndate> to the current date.
2609
2610 if C<$returndate> is specified (in iso format), it is used as the date
2611 of the return.
2612
2613 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2614 the old_issue is immediately anonymised
2615
2616 Ideally, this function would be internal to C<C4::Circulation>,
2617 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2618 and offline_circ/process_koc.pl.
2619
2620 The last optional parameter allos passing skip_record_index to the item store call.
2621
2622 =cut
2623
2624 sub MarkIssueReturned {
2625     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2626
2627     # Retrieve the issue
2628     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2629     my $issue_branchcode = $issue->branchcode;
2630
2631     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2632
2633     my $issue_id = $issue->issue_id;
2634
2635     my $schema = Koha::Database->schema;
2636
2637     # FIXME Improve the return value and handle it from callers
2638     $schema->txn_do(sub {
2639
2640         my $patron = Koha::Patrons->find( $borrowernumber );
2641
2642         # Update the returndate value
2643         if ( $returndate ) {
2644             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2645         }
2646         else {
2647             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2648         }
2649
2650         # Create the old_issues entry
2651         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2652
2653         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2654         if ( $privacy && $privacy == 2) {
2655             $old_checkout->anonymize;
2656         }
2657
2658         # And finally delete the issue
2659         $issue->delete;
2660
2661         $issue->item->onloan(undef)->store(
2662             {   log_action        => 0,
2663                 skip_record_index => $params->{skip_record_index},
2664                 skip_holds_queue  => $params->{skip_holds_queue}
2665             }
2666         );
2667
2668         if ( C4::Context->preference('StoreLastBorrower') ) {
2669             my $item = Koha::Items->find( $itemnumber );
2670             $item->last_returned_by( $patron->borrowernumber )->store;
2671         }
2672
2673         # Possibly remove any OVERDUES related debarment
2674         my $overdue_restrictions = $patron->restrictions->search( { type => 'OVERDUES' } );
2675         if ( C4::Context->preference('AutoRemoveOverduesRestrictions') ne 'no' && $patron->is_debarred ) {
2676             my $remove_restrictions =
2677                 C4::Context->preference('AutoRemoveOverduesRestrictions') eq 'when_no_overdue_causing_debarment'
2678                 ? !$patron->has_restricting_overdues( { issue_branchcode => $issue_branchcode } )
2679                 : !$patron->has_overdues;
2680             if ( $remove_restrictions && $overdue_restrictions->count ) {
2681                 DelUniqueDebarment( { borrowernumber => $borrowernumber, type => 'OVERDUES' } );
2682             }
2683         }
2684
2685     });
2686
2687     return $issue_id;
2688 }
2689
2690 =head2 _debar_user_on_return
2691
2692     _debar_user_on_return($patron, $item, $datedue, $returndate);
2693
2694 C<$patron> patron object
2695
2696 C<$item> item object
2697
2698 C<$datedue> date due DateTime object
2699
2700 C<$returndate> DateTime object representing the return time
2701
2702 Internal function, called only by AddReturn that calculates and updates
2703  the user fine days, and debars them if necessary.
2704
2705 Should only be called for overdue returns
2706
2707 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2708 to ease testing.
2709
2710 =cut
2711
2712 sub _calculate_new_debar_dt {
2713     my ( $patron, $item, $dt_due, $return_date ) = @_;
2714
2715     my $branchcode = _GetCircControlBranch( $item, $patron );
2716     my $circcontrol = C4::Context->preference('CircControl');
2717     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2718         {   categorycode => $patron->categorycode,
2719             itemtype     => $item->effective_itemtype,
2720             branchcode   => $branchcode,
2721             rules => [
2722                 'finedays',
2723                 'lengthunit',
2724                 'firstremind',
2725                 'maxsuspensiondays',
2726                 'suspension_chargeperiod',
2727             ]
2728         }
2729     );
2730     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2731     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2732     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2733
2734     return unless $finedays;
2735
2736     # finedays is in days, so hourly loans must multiply by 24
2737     # thus 1 hour late equals 1 day suspension * finedays rate
2738     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2739
2740     # grace period is measured in the same units as the loan
2741     my $grace =
2742       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2743
2744     my $deltadays = DateTime::Duration->new(
2745         days => $chargeable_units
2746     );
2747
2748     if ( $deltadays->subtract($grace)->is_positive() ) {
2749         my $suspension_days = $deltadays * $finedays;
2750
2751         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2752             # No need to / 1 and do not consider / 0
2753             $suspension_days = DateTime::Duration->new(
2754                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2755             );
2756         }
2757
2758         # If the max suspension days is < than the suspension days
2759         # the suspension days is limited to this maximum period.
2760         my $max_sd = $issuing_rule->{maxsuspensiondays};
2761         if ( defined $max_sd && $max_sd ne '' ) {
2762             $max_sd = DateTime::Duration->new( days => $max_sd );
2763             $suspension_days = $max_sd
2764               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2765         }
2766
2767         my ( $has_been_extended );
2768         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $patron->is_debarred ) {
2769             my $debarment = $patron->restrictions->search({type => 'SUSPENSION' },{rows => 1})->single;
2770             if ( $debarment ) {
2771                 $return_date = dt_from_string( $debarment->expiration, 'sql' );
2772                 $has_been_extended = 1;
2773             }
2774         }
2775
2776         my $new_debar_dt;
2777         # Use the calendar or not to calculate the debarment date
2778         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2779             my $calendar = Koha::Calendar->new(
2780                 branchcode => $branchcode,
2781                 days_mode  => 'Calendar'
2782             );
2783             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2784         }
2785         else {
2786             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2787         }
2788         return $new_debar_dt;
2789     }
2790     return;
2791 }
2792
2793 sub _debar_user_on_return {
2794     my ( $patron, $item, $dt_due, $return_date ) = @_;
2795
2796     $return_date //= dt_from_string();
2797
2798     my $new_debar_dt = _calculate_new_debar_dt($patron, $item, $dt_due, $return_date);
2799
2800     return unless $new_debar_dt;
2801
2802     Koha::Patron::Debarments::AddUniqueDebarment({
2803         borrowernumber => $patron->borrowernumber,
2804         expiration     => $new_debar_dt->ymd(),
2805         type           => 'SUSPENSION',
2806     });
2807     # if borrower was already debarred but does not get an extra debarment
2808     my ($new_debarment_str, $is_a_reminder);
2809     if ( $patron->is_debarred ) {
2810         $is_a_reminder = 1;
2811         $new_debarment_str = $patron->debarred;
2812     } else {
2813         $new_debarment_str = $new_debar_dt->ymd();
2814     }
2815     # FIXME Should return a DateTime object
2816     return $new_debarment_str, $is_a_reminder;
2817 }
2818
2819 =head2 _FixOverduesOnReturn
2820
2821    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2822
2823 C<$borrowernumber> borrowernumber
2824
2825 C<$itemnumber> itemnumber
2826
2827 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2828
2829 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2830
2831 Internal function
2832
2833 =cut
2834
2835 sub _FixOverduesOnReturn {
2836     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2837     unless( $borrowernumber ) {
2838         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2839         return;
2840     }
2841     unless( $item ) {
2842         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2843         return;
2844     }
2845     unless( $status ) {
2846         warn "_FixOverduesOnReturn() not supplied valid status";
2847         return;
2848     }
2849
2850     my $schema = Koha::Database->schema;
2851
2852     my $result = $schema->txn_do(
2853         sub {
2854             # check for overdue fine
2855             my $accountlines = Koha::Account::Lines->search(
2856                 {
2857                     borrowernumber  => $borrowernumber,
2858                     itemnumber      => $item,
2859                     debit_type_code => 'OVERDUE',
2860                     status          => 'UNRETURNED'
2861                 }
2862             );
2863             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2864
2865             my $accountline = $accountlines->next;
2866             my $payments = $accountline->credits;
2867
2868             my $amountoutstanding = $accountline->amountoutstanding;
2869             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2870                 $accountline->delete;
2871                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2872             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2873                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2874                 my $credit = $account->add_credit(
2875                     {
2876                         amount     => $amountoutstanding,
2877                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2878                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2879                         interface  => C4::Context->interface,
2880                         type       => 'FORGIVEN',
2881                         item_id    => $item
2882                     }
2883                 );
2884
2885                 $credit->apply({ debits => [ $accountline ] });
2886
2887                 if (C4::Context->preference("FinesLog")) {
2888                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2889                 }
2890             }
2891
2892             $accountline->status($status);
2893             return $accountline->store();
2894         }
2895     );
2896
2897     return $result;
2898 }
2899
2900 =head2 _GetCircControlBranch
2901
2902    my $circ_control_branch = _GetCircControlBranch($item, $patron);
2903
2904 Internal function :
2905
2906 Return the library code to be used to determine which circulation
2907 policy applies to a transaction.  Looks up the CircControl and
2908 HomeOrHoldingBranch system preferences.
2909
2910 C<$item> is an item object.
2911
2912 C<$patron> is a patron object.
2913
2914 =cut
2915
2916 sub _GetCircControlBranch {
2917     my ($item, $patron) = @_;
2918     my $circcontrol = C4::Context->preference('CircControl');
2919     my $branch;
2920
2921     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2922         $branch = C4::Context->userenv->{'branch'};
2923     } elsif ($circcontrol eq 'PatronLibrary') {
2924         $branch = $patron->branchcode;
2925     } else {
2926         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2927         $branch = $item->get_column($branchfield);
2928         # default to item home branch if holdingbranch is used
2929         # and is not defined
2930         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2931             $branch = $item->homebranch;
2932         }
2933     }
2934     return $branch;
2935 }
2936
2937 =head2 GetUpcomingDueIssues
2938
2939   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2940
2941 =cut
2942
2943 sub GetUpcomingDueIssues {
2944     my $params = shift;
2945
2946     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2947     my $dbh = C4::Context->dbh;
2948     my $statement;
2949     $statement = q{
2950         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2951         FROM issues
2952         LEFT JOIN items USING (itemnumber)
2953         LEFT JOIN branches ON branches.branchcode =
2954     };
2955     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2956     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2957     my @bind_parameters = ( $params->{'days_in_advance'} );
2958
2959     my $sth = $dbh->prepare( $statement );
2960     $sth->execute( @bind_parameters );
2961     my $upcoming_dues = $sth->fetchall_arrayref({});
2962
2963     return $upcoming_dues;
2964 }
2965
2966 =head2 CanBookBeRenewed
2967
2968   ($ok,$error,$info) = &CanBookBeRenewed($patron, $issue, $override_limit, $cron);
2969
2970 Find out whether a borrowed item may be renewed.
2971
2972 C<$patron> is the patron who currently has the issue.
2973
2974 C<$issue> is the checkout to renew.
2975
2976 C<$cron> true or false, specifies if this check is being made
2977 by the automatic_renewals.pl cronscript
2978
2979 C<$override_limit>, if supplied with a true value, causes
2980 the limit on the number of times that the loan can be renewed
2981 (as controlled by the item type) to be ignored. Overriding also allows
2982 to renew sooner than "No renewal before" and to manually renew loans
2983 that are automatically renewed.
2984
2985 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2986 item must currently be on loan to the specified borrower; renewals
2987 must be allowed for the item's type; and the borrower must not have
2988 already renewed the loan.
2989     $error will contain the reason the renewal can not proceed
2990     $info will contain a hash of additional info
2991       currently 'soonest_renew_date' if error is 'too soon'
2992
2993 =cut
2994
2995 sub CanBookBeRenewed {
2996     my ( $patron, $issue, $override_limit, $cron ) = @_;
2997
2998     my $auto_renew = "no";
2999     my $soonest;
3000     my $item = $issue->item;
3001
3002     return ( 0, 'no_item' ) unless $item;
3003     return ( 0, 'no_checkout' ) unless $issue;
3004     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
3005     return ( 0, 'item_issued_to_other_patron') if $issue->borrowernumber != $patron->borrowernumber;
3006     return ( 0, 'item_denied_renewal') if $item->is_denied_renewal;
3007
3008     my $final_renewal        = 0;
3009     my $final_unseen_renewal = 0;
3010
3011     # override_limit will override anything else except on_reserve
3012     unless ( $override_limit ){
3013         my $branchcode = _GetCircControlBranch( $item, $patron );
3014
3015         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
3016             patron     => $patron,
3017             item       => $item,
3018             branchcode => $branchcode,
3019             issue      => $issue
3020         });
3021         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
3022         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
3023         # extra notices being sent. Cron also implies no override
3024         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
3025         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
3026         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
3027
3028         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3029             {
3030                 categorycode => $patron->categorycode,
3031                 itemtype     => $item->effective_itemtype,
3032                 branchcode   => $branchcode,
3033                 rules => [
3034                     'renewalsallowed',
3035                     'lengthunit',
3036                     'unseen_renewals_allowed'
3037                 ]
3038             }
3039         );
3040
3041         return ( 0, "too_many" )
3042           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals_count;
3043
3044         return ( 0, "too_unseen" )
3045           if C4::Context->preference('UnseenRenewals') &&
3046             looks_like_number($issuing_rule->{unseen_renewals_allowed}) &&
3047             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
3048
3049         $final_renewal        = $issuing_rule->{renewalsallowed} == ( $issue->renewals_count + 1 ) ? 1 : 0;
3050         $final_unseen_renewal = ( C4::Context->preference('UnseenRenewals')
3051                 && $issuing_rule->{unseen_renewals_allowed} == ( $issue->unseen_renewals + 1 ) ) ? 1 : 0;
3052
3053         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
3054         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
3055         my $restricted  = $patron->is_debarred;
3056         my $hasoverdues = $patron->has_overdues;
3057
3058         if ( $restricted and $restrictionblockrenewing ) {
3059             return ( 0, 'restriction');
3060         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
3061             return ( 0, 'overdue');
3062         }
3063
3064     }
3065
3066     if ( C4::Context->preference('UseRecalls') ) {
3067         my $recall = undef;
3068         $recall = $item->check_recalls if $item->can_be_waiting_recall;
3069         if ( defined $recall ) {
3070             if ( $recall->item_level ) {
3071                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
3072                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
3073             } else {
3074                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
3075                 return ( 0, 'recalled' ) unless ( $recall->waiting );
3076             }
3077         }
3078     }
3079
3080     # There is an item level hold on this item, no other item can fill the hold
3081     return ( 0, "on_reserve" )
3082       if ( $item->current_holds->search( { non_priority => 0 } )->count );
3083
3084     my $fillable_holds = Koha::Holds->search(
3085         {
3086             biblionumber => $item->biblionumber,
3087             non_priority => 0,
3088             found        => undef,
3089             reservedate  => { '<=' => \'NOW()' },
3090             suspend      => 0
3091         }
3092     );
3093     if ( $fillable_holds->count ) {
3094         if ( C4::Context->preference('AllowRenewalIfOtherItemsAvailable') ) {
3095             my @possible_holds = $fillable_holds->as_list;
3096
3097             # Get all other items that could possibly fill reserves
3098             # FIXME We could join reserves (or more tables) here to eliminate some checks later
3099             my @other_items = Koha::Items->search({
3100                 biblionumber => $item->biblionumber,
3101                 onloan       => undef,
3102                 notforloan   => 0,
3103                 -not         => { itemnumber => $item->itemnumber } })->as_list;
3104
3105             return ( 0, "on_reserve" ) if @possible_holds && (scalar @other_items < scalar @possible_holds);
3106
3107             my %matched_items;
3108             foreach my $possible_hold (@possible_holds) {
3109                 my $fillable = 0;
3110                 my $patron_with_reserve = Koha::Patrons->find($possible_hold->borrowernumber);
3111
3112                 # FIXME: We are not checking whether the item we are renewing can fill the hold
3113
3114                 foreach my $other_item (@other_items) {
3115                   next if defined $matched_items{$other_item->itemnumber};
3116                   next if IsItemOnHoldAndFound( $other_item->itemnumber );
3117                   next unless IsAvailableForItemLevelRequest($other_item, $patron_with_reserve, undef);
3118                   next unless CanItemBeReserved($patron_with_reserve,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
3119                   # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
3120                   # CanItemBeReserved checks 'rules' and 'policies' which means
3121                   # items will fill holds at checkin that are rejected here
3122                   $fillable = 1;
3123                   $matched_items{$other_item->itemnumber} = 1;
3124                   last;
3125                 }
3126                 return ( 0, "on_reserve" ) unless $fillable;
3127             }
3128         }
3129         else {
3130             my ($status, $matched_reserve, $possible_reserves) = CheckReserves($item);
3131             return ( 0, "on_reserve" ) if $status;
3132         }
3133     }
3134
3135     if ( $auto_renew eq 'auto_too_soon' ) {
3136
3137         # If its cron, tell it it's too soon for a an auto renewal
3138         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $cron;
3139
3140         # Check if it's too soon for a manual renewal
3141         my $soonestManual = GetSoonestRenewDate( $patron, $issue );
3142         if ( $soonestManual > dt_from_string() ) {
3143             return ( 0, "too_soon", { soonest_renew_date => $soonestManual } ) unless $override_limit;
3144         }
3145     }
3146
3147     $soonest = GetSoonestRenewDate($patron, $issue);
3148     if ( $soonest > dt_from_string() ){
3149         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
3150     }
3151
3152     my $auto_renew_code = $final_renewal ? 'auto_renew_final' : $final_unseen_renewal ? 'auto_unseen_final' : 'auto_renew';
3153     return ( 1, $auto_renew_code ) if $auto_renew eq "ok" || $auto_renew eq "auto_too_soon" && !$override_limit;
3154
3155     return ( 1, undef );
3156 }
3157
3158 =head2 AddRenewal
3159
3160   $new_date_due = AddRenewal({
3161       borrowernumber   => $borrowernumber,
3162       itemnumber       => $itemnumber,
3163       branch           => $branch,
3164       [datedue         => $datedue],
3165       [lastreneweddate => $lastreneweddate],
3166       [skipfinecalc    => $skipfinecalc],
3167       [seen            => $seen],
3168       [automatic       => $automatic],
3169       [skip_record_index => $skip_record_index]
3170   });
3171
3172 Renews a loan, returns the updated due date upon success.
3173
3174 C<$borrowernumber> is the borrower number of the patron who currently
3175 has the item.
3176
3177 C<$itemnumber> is the number of the item to renew.
3178
3179 C<$branch> is the library where the renewal took place (if any).
3180            The library that controls the circ policies for the renewal is retrieved from the issues record.
3181
3182 C<$datedue> can be a DateTime object used to set the due date.
3183
3184 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3185 this parameter is not supplied, lastreneweddate is set to the current date.
3186
3187 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3188 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3189 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3190 syspref)
3191
3192 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3193 from the book's item type.
3194
3195 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3196 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3197 fallback to a true value
3198
3199 C<$automatic> is a boolean flag indicating the renewal was triggered automatically and not by a person ( librarian or patron )
3200
3201 C<$skip_record_index> is an optional boolean flag to indicate whether queuing the search indexing
3202 should be skipped for this renewal.
3203
3204 =cut
3205
3206 sub AddRenewal {
3207     my $params = shift;
3208
3209     my $borrowernumber  = $params->{borrowernumber};
3210     my $itemnumber      = $params->{itemnumber};
3211     return unless $itemnumber;
3212
3213     my $branch            = $params->{branch};
3214     my $datedue           = $params->{datedue};
3215     my $lastreneweddate   = $params->{lastreneweddate} // dt_from_string();
3216     my $skipfinecalc      = $params->{skipfinecalc};
3217     my $seen              = $params->{seen};
3218     my $automatic         = $params->{automatic};
3219     my $skip_record_index = $params->{skip_record_index};
3220
3221     # Fallback on a 'seen' renewal
3222     $seen = defined $seen && $seen == 0 ? 0 : 1;
3223
3224     my $item_object   = Koha::Items->find($itemnumber) or return;
3225     my $biblio = $item_object->biblio;
3226     my $issue  = $item_object->checkout;
3227     my $item_unblessed = $item_object->unblessed;
3228
3229     my $renewal_type = $automatic ? "Automatic" : "Manual";
3230
3231     my $dbh = C4::Context->dbh;
3232
3233     return unless $issue;
3234
3235     $borrowernumber ||= $issue->borrowernumber;
3236
3237     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3238         $datedue = dt_from_string($datedue, 'sql');
3239     }
3240
3241     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3242     my $patron_unblessed = $patron->unblessed;
3243
3244     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_object, $patron) );
3245
3246     my $schema = Koha::Database->schema;
3247     $schema->txn_do(sub{
3248
3249         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3250             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3251         }
3252         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3253
3254         # If the due date wasn't specified, calculate it by adding the
3255         # book's loan length to today's date or the current due date
3256         # based on the value of the RenewalPeriodBase syspref.
3257         my $itemtype = $item_object->effective_itemtype;
3258         unless ($datedue) {
3259
3260             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3261                                             dt_from_string( $issue->date_due, 'sql' ) :
3262                                             dt_from_string();
3263             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron, 'is a renewal');
3264         }
3265
3266         my $fees = Koha::Charges::Fees->new(
3267             {
3268                 patron    => $patron,
3269                 library   => $circ_library,
3270                 item      => $item_object,
3271                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3272                 to_date   => dt_from_string($datedue),
3273             }
3274         );
3275
3276         # Increment the unseen renewals, if appropriate
3277         # We only do so if the syspref is enabled and
3278         # a maximum value has been set in the circ rules
3279         my $unseen_renewals = $issue->unseen_renewals;
3280         if (C4::Context->preference('UnseenRenewals')) {
3281             my $rule = Koha::CirculationRules->get_effective_rule(
3282                 {   categorycode => $patron->categorycode,
3283                     itemtype     => $item_object->effective_itemtype,
3284                     branchcode   => $circ_library->branchcode,
3285                     rule_name    => 'unseen_renewals_allowed'
3286                 }
3287             );
3288             if (!$seen && $rule && looks_like_number($rule->rule_value)) {
3289                 $unseen_renewals++;
3290             } else {
3291                 # If the renewal is seen, unseen should revert to 0
3292                 $unseen_renewals = 0;
3293             }
3294         }
3295
3296         # Update the issues record to have the new due date, and a new count
3297         # of how many times it has been renewed.
3298         my $renews = ( $issue->renewals_count || 0 ) + 1;
3299         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals_count = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3300
3301         eval{
3302             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3303         };
3304         if( $sth->err ){
3305             Koha::Exceptions::Checkout::FailedRenewal->throw(
3306                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3307             );
3308         }
3309
3310         # Update the renewal count on the item, and tell zebra to reindex
3311         $renews = ( $item_object->renewals || 0 ) + 1;
3312         $item_object->renewals($renews);
3313         $item_object->onloan($datedue);
3314         # Don't index as we are in a transaction, skip hardcoded here
3315         $item_object->store({ log_action => 0, skip_record_index => 1 });
3316
3317         # Charge a new rental fee, if applicable
3318         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3319         if ( $charge > 0 ) {
3320             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3321         }
3322
3323         # Charge a new accumulate rental fee, if applicable
3324         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3325         if ( $itemtype_object ) {
3326             my $accumulate_charge = $fees->accumulate_rentalcharge();
3327             if ( $accumulate_charge > 0 ) {
3328                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3329             }
3330             $charge += $accumulate_charge;
3331         }
3332
3333         # Send a renewal slip according to checkout alert preferencei
3334         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3335             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3336             my %conditions        = (
3337                 branchcode   => $branch,
3338                 categorycode => $patron->categorycode,
3339                 item_type    => $itemtype,
3340                 notification => 'CHECKOUT',
3341             );
3342             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3343                 SendCirculationAlert(
3344                     {
3345                         type     => 'RENEWAL',
3346                         item     => $item_unblessed,
3347                         borrower => $patron->unblessed,
3348                         branch   => $branch,
3349                     }
3350                 );
3351             }
3352         }
3353
3354         # Remove any OVERDUES related debarment if the borrower has no overdues
3355         my $overdue_restrictions = $patron->restrictions->search({ type => 'OVERDUES' });
3356         if ( $patron
3357           && $patron->is_debarred
3358           && ! $patron->has_overdues
3359           && $overdue_restrictions->count
3360         ) {
3361             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3362         }
3363
3364         # Add renewal record
3365         my $renewal = Koha::Checkouts::Renewal->new(
3366             {
3367                 checkout_id  => $issue->issue_id,
3368                 interface    => C4::Context->interface,
3369                 renewal_type => $renewal_type,
3370                 renewer_id   => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3371                 seen         => $seen,
3372             }
3373         )->store();
3374
3375         # Add the renewal to stats
3376         C4::Stats::UpdateStats(
3377             {
3378                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3379                 type           => 'renew',
3380                 amount         => $charge,
3381                 itemnumber     => $itemnumber,
3382                 itemtype       => $itemtype,
3383                 location       => $item_object->location,
3384                 borrowernumber => $borrowernumber,
3385                 ccode          => $item_object->ccode,
3386                 categorycode   => $patron->categorycode,
3387                 interface      => C4::Context->interface,
3388             }
3389         );
3390         #Update borrowers.lastseen
3391         $patron->update_lastseen('renewal');
3392
3393         #Log the renewal
3394         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3395
3396         Koha::Plugins->call('after_circ_action', {
3397             action  => 'renewal',
3398             payload => {
3399                 checkout  => $issue->get_from_storage
3400             }
3401         });
3402     });
3403
3404     unless( $skip_record_index ){
3405         # We index now, after the transaction is committed
3406         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
3407         $indexer->index_records( $item_object->biblionumber, "specialUpdate", "biblioserver" );
3408     }
3409
3410     return $datedue;
3411 }
3412
3413 sub GetRenewCount {
3414     # check renewal status
3415     my ( $borrowernumber_or_patron, $itemnumber_or_item ) = @_;
3416
3417     my $dbh           = C4::Context->dbh;
3418     my $renewcount    = 0;
3419     my $unseencount    = 0;
3420     my $renewsallowed = 0;
3421     my $unseenallowed = 0;
3422     my $renewsleft    = 0;
3423     my $unseenleft    = 0;
3424     my $patron = blessed $borrowernumber_or_patron ?
3425         $borrowernumber_or_patron : Koha::Patrons->find($borrowernumber_or_patron);
3426     my $item = blessed $itemnumber_or_item ?
3427         $itemnumber_or_item : Koha::Items->find($itemnumber_or_item);
3428
3429     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3430
3431     # Look in the issues table for this item, lent to this borrower,
3432     # and not yet returned.
3433
3434     # FIXME - I think this function could be redone to use only one SQL call.
3435     my $sth = $dbh->prepare(q{
3436         SELECT * FROM issues
3437         WHERE  (borrowernumber = ?) AND (itemnumber = ?)
3438     });
3439     $sth->execute( $patron->borrowernumber, $item->itemnumber );
3440     my $data = $sth->fetchrow_hashref;
3441     $renewcount = $data->{'renewals_count'} if $data->{'renewals_count'};
3442     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3443     # $item and $borrower should be calculated
3444     my $branchcode = _GetCircControlBranch($item, $patron);
3445
3446     my $rules = Koha::CirculationRules->get_effective_rules(
3447         {
3448             categorycode => $patron->categorycode,
3449             itemtype     => $item->effective_itemtype,
3450             branchcode   => $branchcode,
3451             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3452         }
3453     );
3454     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3455     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3456         $rules->{unseen_renewals_allowed} :
3457         0;
3458     $renewsleft    = $renewsallowed - $renewcount;
3459     $unseenleft    = $unseenallowed - $unseencount;
3460     if($renewsleft < 0){ $renewsleft = 0; }
3461     if($unseenleft < 0){ $unseenleft = 0; }
3462     return (
3463         $renewcount,
3464         $renewsallowed,
3465         $renewsleft,
3466         $unseencount,
3467         $unseenallowed,
3468         $unseenleft
3469     );
3470 }
3471
3472 =head2 GetSoonestRenewDate
3473
3474   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($patron, $issue);
3475
3476 Find out the soonest possible renew date of a borrowed item.
3477
3478 C<$patron> is the patron who currently has the item on loan.
3479
3480 C<$issue> is the the item issue.
3481
3482 C<$is_auto> is this soonest renew date for an auto renewal?
3483
3484 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3485 renew date, based on the value "No renewal before" of the applicable
3486 issuing rule. Returns the current date if the item can already be
3487 renewed, and returns undefined if the patron, item, or checkout
3488 cannot be found.
3489
3490 =cut
3491
3492 sub GetSoonestRenewDate {
3493     my ( $patron, $issue, $is_auto ) = @_;
3494     return unless $issue;
3495     return unless $patron;
3496
3497     my $item = $issue->item;
3498     return unless $item;
3499
3500     my $circ_rule = $is_auto ? 'noautorenewalbefore' : 'norenewalbefore';
3501
3502     my $dbh = C4::Context->dbh;
3503
3504     my $branchcode = _GetCircControlBranch( $item, $patron );
3505     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3506         {   categorycode => $patron->categorycode,
3507             itemtype     => $item->effective_itemtype,
3508             branchcode   => $branchcode,
3509             rules => [
3510                 $circ_rule,
3511                 'lengthunit',
3512             ]
3513         }
3514     );
3515
3516     my $now = dt_from_string;
3517
3518     if ( defined $issuing_rule->{$circ_rule}
3519         and $issuing_rule->{$circ_rule} ne "" )
3520     {
3521         my $soonestrenewal =
3522           dt_from_string( $issue->date_due )->subtract(
3523             $issuing_rule->{lengthunit} => $issuing_rule->{$circ_rule} );
3524
3525         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3526             and $issuing_rule->{lengthunit} eq 'days' )
3527         {
3528             $soonestrenewal->truncate( to => 'day' );
3529         }
3530         return $soonestrenewal;
3531     } elsif ( $is_auto && $issue->auto_renew && $patron->autorenew_checkouts ) {
3532         # Checkouts with auto-renewing fall back to due date if noautorenewalbefore is undef
3533         my $soonestrenewal = dt_from_string( $issue->date_due );
3534         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3535             and $issuing_rule->{lengthunit} eq 'days' )
3536         {
3537             $soonestrenewal->truncate( to => 'day' );
3538         }
3539         return $soonestrenewal;
3540     }
3541     return $now;
3542 }
3543
3544 =head2 GetLatestAutoRenewDate
3545
3546   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($patron, $issue);
3547
3548 Find out the latest possible auto renew date of a borrowed item.
3549
3550 C<$patron> is the patron who currently has the item on loan.
3551
3552 C<$issue> is the item issue.
3553
3554 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3555 auto renew date, based on the value "No auto renewal after" and the "No auto
3556 renewal after (hard limit) of the applicable issuing rule.
3557 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3558 or item cannot be found.
3559
3560 =cut
3561
3562 sub GetLatestAutoRenewDate {
3563     my ( $patron, $issue ) = @_;
3564     return unless $issue;
3565     return unless $patron;
3566
3567     my $item = $issue->item;
3568     return unless $item;
3569
3570     my $dbh = C4::Context->dbh;
3571     my $branchcode = _GetCircControlBranch( $item, $patron );
3572
3573     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3574         {
3575             categorycode => $patron->categorycode,
3576             itemtype     => $item->effective_itemtype,
3577             branchcode   => $branchcode,
3578             rules => [
3579                 'no_auto_renewal_after',
3580                 'no_auto_renewal_after_hard_limit',
3581                 'lengthunit',
3582             ]
3583         }
3584     );
3585
3586     return unless $circulation_rules;
3587     return
3588       if ( not $circulation_rules->{no_auto_renewal_after}
3589             or $circulation_rules->{no_auto_renewal_after} eq '' )
3590       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3591              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3592
3593     my $maximum_renewal_date;
3594     if ( $circulation_rules->{no_auto_renewal_after} ) {
3595         $maximum_renewal_date = dt_from_string($issue->issuedate);
3596         $maximum_renewal_date->add(
3597             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3598         );
3599     }
3600
3601     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3602         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3603         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3604     }
3605     return $maximum_renewal_date;
3606 }
3607
3608
3609 =head2 GetIssuingCharges
3610
3611   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3612
3613 Calculate how much it would cost for a given patron to borrow a given
3614 item, including any applicable discounts.
3615
3616 C<$itemnumber> is the item number of item the patron wishes to borrow.
3617
3618 C<$borrowernumber> is the patron's borrower number.
3619
3620 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3621 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3622 if it's a video).
3623
3624 =cut
3625
3626 sub GetIssuingCharges {
3627
3628     # calculate charges due
3629     my ( $itemnumber, $borrowernumber ) = @_;
3630     my $charge = 0;
3631     my $dbh    = C4::Context->dbh;
3632     my $item_type;
3633
3634     # Get the book's item type and rental charge (via its biblioitem).
3635     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3636         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3637     $charge_query .= (C4::Context->preference('item-level_itypes'))
3638         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3639         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3640
3641     $charge_query .= ' WHERE items.itemnumber =?';
3642
3643     my $sth = $dbh->prepare($charge_query);
3644     $sth->execute($itemnumber);
3645     my $patron;
3646     if ( my $item_data = $sth->fetchrow_hashref ) {
3647         $item_type = $item_data->{itemtype};
3648         $charge    = $item_data->{rentalcharge};
3649         if ($charge) {
3650             # FIXME This should follow CircControl
3651             my $branch = C4::Context::mybranch();
3652             $patron //= Koha::Patrons->find( $borrowernumber );
3653             my $discount = Koha::CirculationRules->get_effective_rule({
3654                 categorycode => $patron->categorycode,
3655                 branchcode   => $branch,
3656                 itemtype     => $item_type,
3657                 rule_name    => 'rentaldiscount'
3658             });
3659             if ($discount) {
3660                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3661             }
3662             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3663         }
3664     }
3665
3666     return ( $charge, $item_type );
3667 }
3668
3669 =head2 AddIssuingCharge
3670
3671   &AddIssuingCharge( $checkout, $charge, $type )
3672
3673 =cut
3674
3675 sub AddIssuingCharge {
3676     my ( $checkout, $charge, $type ) = @_;
3677
3678     # FIXME What if checkout does not exist?
3679
3680     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3681     my $accountline = $account->add_debit(
3682         {
3683             amount      => $charge,
3684             note        => undef,
3685             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3686             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3687             interface   => C4::Context->interface,
3688             type        => $type,
3689             item_id     => $checkout->itemnumber,
3690             issue_id    => $checkout->issue_id,
3691         }
3692     );
3693 }
3694
3695 =head2 GetTransfersFromTo
3696
3697   @results = GetTransfersFromTo($frombranch,$tobranch);
3698
3699 Returns the list of pending transfers between $from and $to branch
3700
3701 =cut
3702
3703 sub GetTransfersFromTo {
3704     my ( $frombranch, $tobranch ) = @_;
3705     return unless ( $frombranch && $tobranch );
3706     my $dbh   = C4::Context->dbh;
3707     my $query = "
3708         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3709         FROM   branchtransfers
3710         WHERE  frombranch=?
3711           AND  tobranch=?
3712           AND datecancelled IS NULL
3713           AND datesent IS NOT NULL
3714           AND datearrived IS NULL
3715     ";
3716     my $sth = $dbh->prepare($query);
3717     $sth->execute( $frombranch, $tobranch );
3718     my @gettransfers;
3719
3720     while ( my $data = $sth->fetchrow_hashref ) {
3721         push @gettransfers, $data;
3722     }
3723     return (@gettransfers);
3724 }
3725
3726 =head2 SendCirculationAlert
3727
3728 Send out a C<check-in> or C<checkout> alert using the messaging system.
3729
3730 B<Parameters>:
3731
3732 =over 4
3733
3734 =item type
3735
3736 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3737
3738 =item item
3739
3740 Hashref of information about the item being checked in or out.
3741
3742 =item borrower
3743
3744 Hashref of information about the borrower of the item.
3745
3746 =item branch
3747
3748 The branchcode from where the checkout or check-in took place.
3749
3750 =back
3751
3752 B<Example>:
3753
3754     SendCirculationAlert({
3755         type     => 'CHECKOUT',
3756         item     => $item,
3757         borrower => $borrower,
3758         branch   => $branch,
3759     });
3760
3761 =cut
3762
3763 sub SendCirculationAlert {
3764     my ($opts) = @_;
3765     my ($type, $item, $borrower, $branch, $issue) =
3766         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3767     my %message_name = (
3768         CHECKIN  => 'Item_Check_in',
3769         CHECKOUT => 'Item_Checkout',
3770         RENEWAL  => 'Item_Checkout',
3771     );
3772     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3773         borrowernumber => $borrower->{borrowernumber},
3774         message_name   => $message_name{$type},
3775     });
3776
3777
3778     my $tables = {
3779         items => $item->{itemnumber},
3780         biblio      => $item->{biblionumber},
3781         biblioitems => $item->{biblionumber},
3782         borrowers   => $borrower,
3783         branches    => $branch,
3784     };
3785
3786     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3787     # See C4::Letters:: _parseletter_sth
3788     if( $type eq 'CHECKIN' ){
3789         $tables->{old_issues} = $issue->issue_id;
3790     } else {
3791         $tables->{issues} = $item->{itemnumber};
3792     }
3793
3794     my $schema = Koha::Database->new->schema;
3795     my @transports = keys %{ $borrower_preferences->{transports} };
3796
3797     # From the MySQL doc:
3798     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3799     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3800     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3801     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3802
3803     for my $mtt (@transports) {
3804         my $letter =  C4::Letters::GetPreparedLetter (
3805             module => 'circulation',
3806             letter_code => $type,
3807             branchcode => $branch,
3808             message_transport_type => $mtt,
3809             lang => $borrower->{lang},
3810             tables => $tables,
3811         ) or next;
3812
3813         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3814         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3815         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3816         unless ( $message ) {
3817             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3818             my $patron = Koha::Patrons->find($borrower->{borrowernumber});
3819             C4::Message->enqueue($letter, $patron, $mtt);
3820         } else {
3821             $message->append($letter);
3822             $message->update;
3823         }
3824         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3825     }
3826
3827     return;
3828 }
3829
3830 =head2 updateWrongTransfer
3831
3832   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3833
3834 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3835
3836 =cut
3837
3838 sub updateWrongTransfer {
3839         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3840
3841     # first step: cancel the original transfer
3842     my $item = Koha::Items->find($itemNumber);
3843     my $transfer = $item->get_transfer;
3844     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3845
3846     # second step: create a new transfer to the right location
3847     my $new_transfer = $item->request_transfer(
3848         {
3849             to            => $transfer->to_library,
3850             reason        => $transfer->reason,
3851             comment       => $transfer->comments,
3852             ignore_limits => 1,
3853             enqueue       => 1
3854         }
3855     );
3856
3857     return $new_transfer;
3858 }
3859
3860 =head2 CalcDateDue
3861
3862 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3863
3864 this function calculates the due date given the start date and configured circulation rules,
3865 checking against the holidays calendar as per the daysmode circulation rule.
3866 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3867 C<$itemtype>  = itemtype code of item in question
3868 C<$branch>  = location whose calendar to use
3869 C<$patron> = Patron object
3870 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3871
3872 =cut
3873
3874 sub CalcDateDue {
3875     my ( $startdate, $itemtype, $branch, $patron, $isrenewal ) = @_;
3876
3877     $isrenewal ||= 0;
3878
3879     # loanlength now a href
3880     my $loanlength =
3881             GetLoanLength( $patron->categorycode, $itemtype, $branch );
3882
3883     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3884             ? qq{renewalperiod}
3885             : qq{issuelength};
3886
3887     my $datedue;
3888     if ( $startdate ) {
3889         if (ref $startdate ne 'DateTime' ) {
3890             $datedue = dt_from_string($datedue);
3891         } else {
3892             $datedue = $startdate->clone;
3893         }
3894     } else {
3895         $datedue = dt_from_string()->truncate( to => 'minute' );
3896     }
3897
3898
3899     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3900         {
3901             categorycode => $patron->categorycode,
3902             itemtype     => $itemtype,
3903             branchcode   => $branch,
3904         }
3905     );
3906
3907     # calculate the datedue as normal
3908     if ( $daysmode eq 'Days' )
3909     {    # ignoring calendar
3910         if ( $loanlength->{lengthunit} eq 'hours' ) {
3911             $datedue->add( hours => $loanlength->{$length_key} );
3912         } else {    # days
3913             $datedue->add( days => $loanlength->{$length_key} );
3914             $datedue->set_hour(23);
3915             $datedue->set_minute(59);
3916         }
3917     } else {
3918         my $dur;
3919         if ($loanlength->{lengthunit} eq 'hours') {
3920             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3921         }
3922         else { # days
3923             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3924         }
3925         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3926         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3927         if ($loanlength->{lengthunit} eq 'days') {
3928             $datedue->set_hour(23);
3929             $datedue->set_minute(59);
3930         }
3931     }
3932
3933     # if Hard Due Dates are used, retrieve them and apply as necessary
3934     my ( $hardduedate, $hardduedatecompare ) =
3935       GetHardDueDate( $patron->categorycode, $itemtype, $branch );
3936     if ($hardduedate) {    # hardduedates are currently dates
3937         $hardduedate->truncate( to => 'minute' );
3938         $hardduedate->set_hour(23);
3939         $hardduedate->set_minute(59);
3940         my $cmp = DateTime->compare( $hardduedate, $datedue );
3941
3942 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3943 # if the calculated date is before the 'after' Hard Due Date (floor), override
3944 # if the hard due date is set to 'exactly', overrride
3945         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3946             $datedue = $hardduedate->clone;
3947         }
3948
3949         # in all other cases, keep the date due as it is
3950
3951     }
3952
3953     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3954     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3955         my $expiry_dt = dt_from_string( $patron->dateexpiry, 'iso', 'floating');
3956         if( $expiry_dt ) { #skip empty expiry date..
3957             $expiry_dt->set( hour => 23, minute => 59);
3958             my $d1= $datedue->clone->set_time_zone('floating');
3959             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3960                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3961             }
3962         }
3963         if ( $daysmode ne 'Days' ) {
3964           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3965           if ( $calendar->is_holiday($datedue) ) {
3966               # Don't return on a closed day
3967               $datedue = $calendar->prev_open_days( $datedue, 1 );
3968           }
3969         }
3970     }
3971
3972     return $datedue;
3973 }
3974
3975
3976 sub CheckValidBarcode{
3977 my ($barcode) = @_;
3978 my $dbh = C4::Context->dbh;
3979 my $query=qq|SELECT count(*)
3980              FROM items
3981              WHERE barcode=?
3982             |;
3983 my $sth = $dbh->prepare($query);
3984 $sth->execute($barcode);
3985 my $exist=$sth->fetchrow ;
3986 return $exist;
3987 }
3988
3989 =head2 IsBranchTransferAllowed
3990
3991   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3992
3993 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3994
3995 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3996 Koha::Item->can_be_transferred.
3997
3998 =cut
3999
4000 sub IsBranchTransferAllowed {
4001         my ( $toBranch, $fromBranch, $code ) = @_;
4002
4003         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
4004
4005         my $limitType = C4::Context->preference("BranchTransferLimitsType");
4006         my $dbh = C4::Context->dbh;
4007
4008         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
4009         $sth->execute( $toBranch, $fromBranch, $code );
4010         my $limit = $sth->fetchrow_hashref();
4011
4012         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
4013         if ( $limit->{'limitId'} ) {
4014                 return 0;
4015         } else {
4016                 return 1;
4017         }
4018 }
4019
4020 =head2 CreateBranchTransferLimit
4021
4022   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
4023
4024 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
4025
4026 Deprecated in favor of Koha::Item::Transfer::Limit->new.
4027
4028 =cut
4029
4030 sub CreateBranchTransferLimit {
4031    my ( $toBranch, $fromBranch, $code ) = @_;
4032    return unless defined($toBranch) && defined($fromBranch);
4033    my $limitType = C4::Context->preference("BranchTransferLimitsType");
4034
4035    my $dbh = C4::Context->dbh;
4036
4037    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
4038    return $sth->execute( $code, $toBranch, $fromBranch );
4039 }
4040
4041 =head2 DeleteBranchTransferLimits
4042
4043     my $result = DeleteBranchTransferLimits($frombranch);
4044
4045 Deletes all the library transfer limits for one library.  Returns the
4046 number of limits deleted, 0e0 if no limits were deleted, or undef if
4047 no arguments are supplied.
4048
4049 Deprecated in favor of Koha::Item::Transfer::Limits->search({
4050     fromBranch => $fromBranch
4051     })->delete.
4052
4053 =cut
4054
4055 sub DeleteBranchTransferLimits {
4056     my $branch = shift;
4057     return unless defined $branch;
4058     my $dbh    = C4::Context->dbh;
4059     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
4060     return $sth->execute($branch);
4061 }
4062
4063 sub ReturnLostItem{
4064     my ( $borrowernumber, $itemnum ) = @_;
4065     MarkIssueReturned( $borrowernumber, $itemnum );
4066 }
4067
4068 =head2 LostItem
4069
4070   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
4071
4072 The final optional parameter, C<$params>, expected to contain
4073 'skip_record_index' key, which relayed down to Koha::Item/store,
4074 there it prevents calling of ModZebra index_records,
4075 which takes most of the time in batch adds/deletes: index_records better
4076 to be called later in C<additem.pl> after the whole loop.
4077
4078 $params:
4079     skip_record_index => 1|0
4080
4081 =cut
4082
4083 sub LostItem{
4084     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
4085
4086     unless ( $mark_lost_from ) {
4087         # Temporary check to avoid regressions
4088         die q|LostItem called without $mark_lost_from, check the API.|;
4089     }
4090
4091     my $mark_returned;
4092     if ( $force_mark_returned ) {
4093         $mark_returned = 1;
4094     } else {
4095         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
4096         $mark_returned = ( $pref =~ m|$mark_lost_from| );
4097     }
4098
4099     my $dbh = C4::Context->dbh();
4100     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
4101                            FROM issues
4102                            JOIN items USING (itemnumber)
4103                            JOIN biblio USING (biblionumber)
4104                            WHERE issues.itemnumber=?");
4105     $sth->execute($itemnumber);
4106     my $issues=$sth->fetchrow_hashref();
4107
4108     # If a borrower lost the item, add a replacement cost to the their record
4109     if ( my $borrowernumber = $issues->{borrowernumber} ){
4110         my $patron = Koha::Patrons->find( $borrowernumber );
4111
4112         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
4113         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
4114
4115         if (C4::Context->preference('WhenLostChargeReplacementFee')){
4116             C4::Accounts::chargelostitem(
4117                 $borrowernumber,
4118                 $itemnumber,
4119                 $issues->{'replacementprice'},
4120                 sprintf( "%s %s %s",
4121                     $issues->{'title'}          || q{},
4122                     $issues->{'barcode'}        || q{},
4123                     $issues->{'itemcallnumber'} || q{},
4124                 ),
4125             );
4126             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
4127             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
4128         }
4129
4130         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
4131     }
4132
4133     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
4134     my $item = Koha::Items->find($itemnumber);
4135     my $transfers = $item->get_transfers;
4136     while (my $transfer = $transfers->next) {
4137         $transfer->cancel({ reason => 'ItemLost', force => 1 });
4138     }
4139 }
4140
4141 sub GetOfflineOperations {
4142     my $dbh = C4::Context->dbh;
4143     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
4144     $sth->execute(C4::Context->userenv->{'branch'});
4145     my $results = $sth->fetchall_arrayref({});
4146     return $results;
4147 }
4148
4149 sub GetOfflineOperation {
4150     my $operationid = shift;
4151     return unless $operationid;
4152     my $dbh = C4::Context->dbh;
4153     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
4154     $sth->execute( $operationid );
4155     return $sth->fetchrow_hashref;
4156 }
4157
4158 sub AddOfflineOperation {
4159     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
4160     my $dbh = C4::Context->dbh;
4161     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
4162     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
4163     return "Added.";
4164 }
4165
4166 sub DeleteOfflineOperation {
4167     my $dbh = C4::Context->dbh;
4168     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
4169     $sth->execute( shift );
4170     return "Deleted.";
4171 }
4172
4173 sub ProcessOfflineOperation {
4174     my $operation = shift;
4175
4176     my $report;
4177     if ( $operation->{action} eq 'return' ) {
4178         $report = ProcessOfflineReturn( $operation );
4179     } elsif ( $operation->{action} eq 'issue' ) {
4180         $report = ProcessOfflineIssue( $operation );
4181     } elsif ( $operation->{action} eq 'payment' ) {
4182         $report = ProcessOfflinePayment( $operation );
4183     }
4184
4185     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4186
4187     return $report;
4188 }
4189
4190 sub ProcessOfflineReturn {
4191     my $operation = shift;
4192
4193     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4194
4195     if ( $item ) {
4196         my $itemnumber = $item->itemnumber;
4197         my $issue = $item->checkout;
4198         if ( $issue ) {
4199             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4200             ModDateLastSeen( $itemnumber, $leave_item_lost );
4201             MarkIssueReturned(
4202                 $issue->borrowernumber,
4203                 $itemnumber,
4204                 $operation->{timestamp},
4205             );
4206             $item->onloan(undef);
4207             $item->store({ log_action => 0 });
4208             return "Success.";
4209         } else {
4210             return "Item not issued.";
4211         }
4212     } else {
4213         return "Item not found.";
4214     }
4215 }
4216
4217 sub ProcessOfflineIssue {
4218     my $operation = shift;
4219
4220     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4221     $patron ||= Koha::Patrons->find( { userid => $operation->{cardnumber} } );
4222
4223     if ( $patron ) {
4224         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4225         unless ($item) {
4226             return "Barcode not found.";
4227         }
4228         my $itemnumber = $item->itemnumber;
4229         my $issue = $item->checkout;
4230
4231         if ( $issue and ( $issue->borrowernumber ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4232             MarkIssueReturned(
4233                 $issue->borrowernumber,
4234                 $itemnumber,
4235                 $operation->{timestamp},
4236             );
4237         }
4238         AddIssue(
4239             $patron,
4240             $operation->{'barcode'},
4241             undef,
4242             undef,
4243             $operation->{timestamp},
4244             undef,
4245         );
4246         return "Success.";
4247     } else {
4248         return "Borrower not found.";
4249     }
4250 }
4251
4252 sub ProcessOfflinePayment {
4253     my $operation = shift;
4254
4255     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4256     $patron ||= Koha::Patrons->find( { userid => $operation->{cardnumber} } );
4257
4258     $patron->account->pay(
4259         {
4260             amount     => $operation->{amount},
4261             library_id => $operation->{branchcode},
4262             interface  => 'koc'
4263         }
4264     );
4265
4266     return "Success.";
4267 }
4268
4269 =head2 TransferSlip
4270
4271   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4272
4273   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4274
4275 =cut
4276
4277 sub TransferSlip {
4278     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4279
4280     my $item =
4281       $itemnumber
4282       ? Koha::Items->find($itemnumber)
4283       : Koha::Items->find( { barcode => $barcode } );
4284
4285     $item or return;
4286
4287     return C4::Letters::GetPreparedLetter (
4288         module => 'circulation',
4289         letter_code => 'TRANSFERSLIP',
4290         branchcode => $branch,
4291         tables => {
4292             'branches'    => $to_branch,
4293             'biblio'      => $item->biblionumber,
4294             'items'       => $item->unblessed,
4295         },
4296     );
4297 }
4298
4299 =head2 CheckIfIssuedToPatron
4300
4301   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4302
4303   Return 1 if any record item is issued to patron, otherwise return 0
4304
4305 =cut
4306
4307 sub CheckIfIssuedToPatron {
4308     my ($borrowernumber, $biblionumber) = @_;
4309
4310     my $dbh = C4::Context->dbh;
4311     my $query = q|
4312         SELECT COUNT(*) FROM issues
4313         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4314         WHERE items.biblionumber = ?
4315         AND issues.borrowernumber = ?
4316     |;
4317     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4318     return 1 if $is_issued;
4319     return;
4320 }
4321
4322 =head2 IsItemIssued
4323
4324   IsItemIssued( $itemnumber )
4325
4326   Return 1 if the item is on loan, otherwise return 0
4327
4328 =cut
4329
4330 sub IsItemIssued {
4331     my $itemnumber = shift;
4332     my $dbh = C4::Context->dbh;
4333     my $sth = $dbh->prepare(q{
4334         SELECT COUNT(*)
4335         FROM issues
4336         WHERE itemnumber = ?
4337     });
4338     $sth->execute($itemnumber);
4339     return $sth->fetchrow;
4340 }
4341
4342 =head2 GetAgeRestriction
4343
4344   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4345   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4346
4347   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4348   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4349
4350 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4351 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4352 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4353          Negative days mean the borrower has gone past the age restriction age.
4354
4355 =cut
4356
4357 sub GetAgeRestriction {
4358     my ($record_restrictions, $borrower) = @_;
4359     my $markers = C4::Context->preference('AgeRestrictionMarker');
4360
4361     return unless $record_restrictions;
4362     # Split $record_restrictions to something like FSK 16 or PEGI 6
4363     my @values = split ' ', uc($record_restrictions);
4364     return unless @values;
4365
4366     # Search first occurrence of one of the markers
4367     my @markers = split /\|/, uc($markers);
4368     return unless @markers;
4369
4370     my $index            = 0;
4371     my $restriction_year = 0;
4372     for my $value (@values) {
4373         $index++;
4374         for my $marker (@markers) {
4375             $marker =~ s/^\s+//;    #remove leading spaces
4376             $marker =~ s/\s+$//;    #remove trailing spaces
4377             if ( $marker eq $value ) {
4378                 if ( $index <= $#values ) {
4379                     $restriction_year += $values[$index];
4380                 }
4381                 last;
4382             }
4383             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4384
4385                 # Perhaps it is something like "K16" (as in Finland)
4386                 $restriction_year += $1;
4387                 last;
4388             }
4389         }
4390         last if ( $restriction_year > 0 );
4391     }
4392
4393     #Check if the borrower is age restricted for this material and for how long.
4394     if ($restriction_year && $borrower) {
4395         if ( $borrower->{'dateofbirth'} ) {
4396             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4397             $alloweddate[0] += $restriction_year;
4398
4399             #Prevent runime eror on leap year (invalid date)
4400             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4401                 $alloweddate[2] = 28;
4402             }
4403
4404             #Get how many days the borrower has to reach the age restriction
4405             my @Today = split /-/, dt_from_string()->ymd();
4406             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4407             #Negative days means the borrower went past the age restriction age
4408             return ($restriction_year, $daysToAgeRestriction);
4409         }
4410     }
4411
4412     return ($restriction_year);
4413 }
4414
4415
4416 =head2 GetPendingOnSiteCheckouts
4417
4418 =cut
4419
4420 sub GetPendingOnSiteCheckouts {
4421     my $dbh = C4::Context->dbh;
4422     return $dbh->selectall_arrayref(q|
4423         SELECT
4424           items.barcode,
4425           items.biblionumber,
4426           items.itemnumber,
4427           items.itemnotes,
4428           items.itemcallnumber,
4429           items.location,
4430           issues.date_due,
4431           issues.branchcode,
4432           issues.date_due < NOW() AS is_overdue,
4433           biblio.author,
4434           biblio.title,
4435           borrowers.firstname,
4436           borrowers.surname,
4437           borrowers.cardnumber,
4438           borrowers.borrowernumber
4439         FROM items
4440         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4441         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4442         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4443         WHERE issues.onsite_checkout = 1
4444     |, { Slice => {} } );
4445 }
4446
4447 sub GetTopIssues {
4448     my ($params) = @_;
4449
4450     my ($count, $branch, $itemtype, $ccode, $newness)
4451         = @$params{qw(count branch itemtype ccode newness)};
4452
4453     my $dbh = C4::Context->dbh;
4454     my $query = q{
4455         SELECT * FROM (
4456         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4457           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4458           i.ccode, SUM(i.issues) AS count
4459         FROM biblio b
4460         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4461         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4462     };
4463
4464     my (@where_strs, @where_args);
4465
4466     if ($branch) {
4467         push @where_strs, 'i.homebranch = ?';
4468         push @where_args, $branch;
4469     }
4470     if ($itemtype) {
4471         if (C4::Context->preference('item-level_itypes')){
4472             push @where_strs, 'i.itype = ?';
4473             push @where_args, $itemtype;
4474         } else {
4475             push @where_strs, 'bi.itemtype = ?';
4476             push @where_args, $itemtype;
4477         }
4478     }
4479     if ($ccode) {
4480         push @where_strs, 'i.ccode = ?';
4481         push @where_args, $ccode;
4482     }
4483     if ($newness) {
4484         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4485         push @where_args, $newness;
4486     }
4487
4488     if (@where_strs) {
4489         $query .= 'WHERE ' . join(' AND ', @where_strs);
4490     }
4491
4492     $query .= q{
4493         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4494           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4495           i.ccode
4496         ORDER BY count DESC
4497     };
4498
4499     $query .= q{ ) xxx WHERE count > 0 };
4500     $count = int($count);
4501     if ($count > 0) {
4502         $query .= "LIMIT $count";
4503     }
4504
4505     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4506
4507     return @$rows;
4508 }
4509
4510 =head2 Internal methods
4511
4512 =cut
4513
4514 sub _CalculateAndUpdateFine {
4515     my ($params) = @_;
4516
4517     my $borrower    = $params->{borrower};
4518     my $item        = $params->{item};
4519     my $issue       = $params->{issue};
4520     my $return_date = $params->{return_date};
4521
4522     unless ($borrower) { carp "No borrower passed in!" && return; }
4523     unless ($item)     { carp "No item passed in!"     && return; }
4524     unless ($issue)    { carp "No issue passed in!"    && return; }
4525
4526     my $datedue = dt_from_string( $issue->date_due );
4527
4528     # we only need to calculate and change the fines if we want to do that on return
4529     # Should be on for hourly loans
4530     my $control = C4::Context->preference('CircControl');
4531     my $branch_type = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
4532     my $control_branchcode =
4533         ( $control eq 'ItemHomeLibrary' ) ? $item->{$branch_type}
4534       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4535       :                                     $issue->branchcode;
4536
4537     my $date_returned = $return_date ? $return_date : dt_from_string();
4538
4539     my ( $amount, $unitcounttotal, $unitcount  ) =
4540       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4541
4542     if ( C4::Context->preference('finesMode') eq 'production' ) {
4543         if ( $amount > 0 ) {
4544             C4::Overdues::UpdateFine({
4545                 issue_id       => $issue->issue_id,
4546                 itemnumber     => $issue->itemnumber,
4547                 borrowernumber => $issue->borrowernumber,
4548                 amount         => $amount,
4549                 due            => $datedue,
4550             });
4551         }
4552         elsif ($return_date) {
4553
4554             # Backdated returns may have fines that shouldn't exist,
4555             # so in this case, we need to drop those fines to 0
4556
4557             C4::Overdues::UpdateFine({
4558                 issue_id       => $issue->issue_id,
4559                 itemnumber     => $issue->itemnumber,
4560                 borrowernumber => $issue->borrowernumber,
4561                 amount         => 0,
4562                 due            => $datedue,
4563             });
4564         }
4565     }
4566 }
4567
4568 sub _CanBookBeAutoRenewed {
4569     my ( $params ) = @_;
4570     my $patron = $params->{patron};
4571     my $item = $params->{item};
4572     my $branchcode = $params->{branchcode};
4573     my $issue = $params->{issue};
4574
4575     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4576
4577     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4578         {
4579             categorycode => $patron->categorycode,
4580             itemtype     => $item->effective_itemtype,
4581             branchcode   => $branchcode,
4582             rules => [
4583                 'no_auto_renewal_after',
4584                 'no_auto_renewal_after_hard_limit',
4585                 'lengthunit',
4586                 'noautorenewalbefore',
4587             ]
4588         }
4589     );
4590
4591     if ( $patron->is_expired && $patron->category->effective_BlockExpiredPatronOpacActions ) {
4592         return 'auto_account_expired';
4593     }
4594
4595     if ( defined $issuing_rule->{no_auto_renewal_after}
4596             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4597         # Get issue_date and add no_auto_renewal_after
4598         # If this is greater than today, it's too late for renewal.
4599         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4600         $maximum_renewal_date->add(
4601             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4602         );
4603         my $now = dt_from_string;
4604         if ( $now >= $maximum_renewal_date ) {
4605             return "auto_too_late";
4606         }
4607     }
4608     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4609                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4610         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4611         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4612             return "auto_too_late";
4613         }
4614     }
4615
4616     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4617         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4618         my $amountoutstanding =
4619           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4620           ? $patron->account->balance
4621           : $patron->account->outstanding_debits->total_outstanding;
4622         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4623             return "auto_too_much_oweing";
4624         }
4625     }
4626
4627     my $soonest = GetSoonestRenewDate( $patron, $issue, 1 );
4628     if ( $soonest > dt_from_string() )
4629     {
4630         return ( "auto_too_soon", $soonest );
4631     }
4632
4633     return "ok";
4634 }
4635
4636
4637 1;
4638
4639 __END__
4640
4641 =head1 AUTHOR
4642
4643 Koha Development Team <http://koha-community.org/>
4644
4645 =cut