C4/Acquisition.pm

   1 package C4::Acquisition;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20
  21 use strict;
  22 use warnings;
  23 use Carp;
  24 use C4::Context;
  25 use C4::Debug;
  26 use C4::Dates qw(format_date format_date_in_iso);
  27 use MARC::Record;
  28 use C4::Suggestions;
  29 use C4::Biblio;
  30 use C4::Debug;
  31 use C4::SQLHelper qw(InsertInTable);
  32 use C4::Bookseller qw(GetBookSellerFromId);
  33 use C4::Templates qw(gettemplate);
  34
  35 use Time::localtime;
  36 use HTML::Entities;
  37
  38 use vars qw($VERSION @ISA @EXPORT);
  39
  40 BEGIN {
  41     # set the version for version checking
  42     $VERSION = 3.07.00.049;
  43     require Exporter;
  44     @ISA    = qw(Exporter);
  45     @EXPORT = qw(
  46         &GetBasket &NewBasket &CloseBasket &DelBasket &ModBasket
  47         &GetBasketAsCSV &GetBasketGroupAsCSV
  48         &GetBasketsByBookseller &GetBasketsByBasketgroup
  49         &GetBasketsInfosByBookseller
  50
  51         &ModBasketHeader
  52
  53         &ModBasketgroup &NewBasketgroup &DelBasketgroup &GetBasketgroup &CloseBasketgroup
  54         &GetBasketgroups &ReOpenBasketgroup
  55
  56         &NewOrder &DelOrder &ModOrder &GetPendingOrders &GetOrder &GetOrders &GetOrdersByBiblionumber
  57         &GetOrderNumber &GetLateOrders &GetOrderFromItemnumber
  58         &SearchOrder &GetHistory &GetRecentAcqui
  59         &ModReceiveOrder &CancelReceipt &ModOrderBiblioitemNumber
  60         &GetCancelledOrders
  61         &GetLastOrderNotReceivedFromSubscriptionid &GetLastOrderReceivedFromSubscriptionid
  62         &NewOrderItem &ModItemOrder
  63
  64         &GetParcels &GetParcel
  65         &GetContracts &GetContract
  66
  67         &GetInvoices
  68         &GetInvoice
  69         &GetInvoiceDetails
  70         &AddInvoice
  71         &ModInvoice
  72         &CloseInvoice
  73         &ReopenInvoice
  74
  75         &GetItemnumbersFromOrder
  76
  77         &AddClaim
  78     );
  79 }
  80
  81
  82
  83
  84
  85 sub GetOrderFromItemnumber {
  86     my ($itemnumber) = @_;
  87     my $dbh          = C4::Context->dbh;
  88     my $query        = qq|
  89
  90     SELECT  * from aqorders    LEFT JOIN aqorders_items
  91     ON (     aqorders.ordernumber = aqorders_items.ordernumber   )
  92     WHERE itemnumber = ?  |;
  93
  94     my $sth = $dbh->prepare($query);
  95
  96 #    $sth->trace(3);
  97
  98     $sth->execute($itemnumber);
  99
 100     my $order = $sth->fetchrow_hashref;
 101     return ( $order  );
 102
 103 }
 104
 105 # Returns the itemnumber(s) associated with the ordernumber given in parameter
 106 sub GetItemnumbersFromOrder {
 107     my ($ordernumber) = @_;
 108     my $dbh          = C4::Context->dbh;
 109     my $query        = "SELECT itemnumber FROM aqorders_items WHERE ordernumber=?";
 110     my $sth = $dbh->prepare($query);
 111     $sth->execute($ordernumber);
 112     my @tab;
 113
 114     while (my $order = $sth->fetchrow_hashref) {
 115     push @tab, $order->{'itemnumber'};
 116     }
 117
 118     return @tab;
 119
 120 }
 121
 122
 123
 124
 125
 126
 127 =head1 NAME
 128
 129 C4::Acquisition - Koha functions for dealing with orders and acquisitions
 130
 131 =head1 SYNOPSIS
 132
 133 use C4::Acquisition;
 134
 135 =head1 DESCRIPTION
 136
 137 The functions in this module deal with acquisitions, managing book
 138 orders, basket and parcels.
 139
 140 =head1 FUNCTIONS
 141
 142 =head2 FUNCTIONS ABOUT BASKETS
 143
 144 =head3 GetBasket
 145
 146   $aqbasket = &GetBasket($basketnumber);
 147
 148 get all basket informations in aqbasket for a given basket
 149
 150 B<returns:> informations for a given basket returned as a hashref.
 151
 152 =cut
 153
 154 sub GetBasket {
 155     my ($basketno) = @_;
 156     my $dbh        = C4::Context->dbh;
 157     my $query = "
 158         SELECT  aqbasket.*,
 159                 concat( b.firstname,' ',b.surname) AS authorisedbyname,
 160                 b.branchcode AS branch
 161         FROM    aqbasket
 162         LEFT JOIN borrowers b ON aqbasket.authorisedby=b.borrowernumber
 163         WHERE basketno=?
 164     ";
 165     my $sth=$dbh->prepare($query);
 166     $sth->execute($basketno);
 167     my $basket = $sth->fetchrow_hashref;
 168     return ( $basket );
 169 }
 170
 171 #------------------------------------------------------------#
 172
 173 =head3 NewBasket
 174
 175   $basket = &NewBasket( $booksellerid, $authorizedby, $basketname,
 176       $basketnote, $basketbooksellernote, $basketcontractnumber, $deliveryplace, $billingplace );
 177
 178 Create a new basket in aqbasket table
 179
 180 =over
 181
 182 =item C<$booksellerid> is a foreign key in the aqbasket table
 183
 184 =item C<$authorizedby> is the username of who created the basket
 185
 186 =back
 187
 188 The other parameters are optional, see ModBasketHeader for more info on them.
 189
 190 =cut
 191
 192 sub NewBasket {
 193     my ( $booksellerid, $authorisedby, $basketname, $basketnote,
 194         $basketbooksellernote, $basketcontractnumber, $deliveryplace,
 195         $billingplace ) = @_;
 196     my $dbh = C4::Context->dbh;
 197     my $query =
 198         'INSERT INTO aqbasket (creationdate,booksellerid,authorisedby) '
 199       . 'VALUES  (now(),?,?)';
 200     $dbh->do( $query, {}, $booksellerid, $authorisedby );
 201
 202     my $basket = $dbh->{mysql_insertid};
 203     $basketname           ||= q{}; # default to empty strings
 204     $basketnote           ||= q{};
 205     $basketbooksellernote ||= q{};
 206     ModBasketHeader( $basket, $basketname, $basketnote, $basketbooksellernote,
 207         $basketcontractnumber, $booksellerid, $deliveryplace, $billingplace );
 208     return $basket;
 209 }
 210
 211 #------------------------------------------------------------#
 212
 213 =head3 CloseBasket
 214
 215   &CloseBasket($basketno);
 216
 217 close a basket (becomes unmodifiable,except for recieves)
 218
 219 =cut
 220
 221 sub CloseBasket {
 222     my ($basketno) = @_;
 223     my $dbh        = C4::Context->dbh;
 224     my $query = "
 225         UPDATE aqbasket
 226         SET    closedate=now()
 227         WHERE  basketno=?
 228     ";
 229     my $sth = $dbh->prepare($query);
 230     $sth->execute($basketno);
 231 }
 232
 233 #------------------------------------------------------------#
 234
 235 =head3 GetBasketAsCSV
 236
 237   &GetBasketAsCSV($basketno);
 238
 239 Export a basket as CSV
 240
 241 $cgi parameter is needed for column name translation
 242
 243 =cut
 244
 245 sub GetBasketAsCSV {
 246     my ($basketno, $cgi) = @_;
 247     my $basket = GetBasket($basketno);
 248     my @orders = GetOrders($basketno);
 249     my $contract = GetContract($basket->{'contractnumber'});
 250
 251     my $template = C4::Templates::gettemplate("acqui/csv/basket.tmpl", "intranet", $cgi);
 252
 253     my @rows;
 254     foreach my $order (@orders) {
 255         my $bd = GetBiblioData( $order->{'biblionumber'} );
 256         my $row = {
 257             contractname => $contract->{'contractname'},
 258             ordernumber => $order->{'ordernumber'},
 259             entrydate => $order->{'entrydate'},
 260             isbn => $order->{'isbn'},
 261             author => $bd->{'author'},
 262             title => $bd->{'title'},
 263             publicationyear => $bd->{'publicationyear'},
 264             publishercode => $bd->{'publishercode'},
 265             collectiontitle => $bd->{'collectiontitle'},
 266             notes => $order->{'notes'},
 267             quantity => $order->{'quantity'},
 268             rrp => $order->{'rrp'},
 269             deliveryplace => C4::Branch::GetBranchName( $basket->{'deliveryplace'} ),
 270             billingplace => C4::Branch::GetBranchName( $basket->{'billingplace'} ),
 271         };
 272         foreach(qw(
 273             contractname author title publishercode collectiontitle notes
 274             deliveryplace billingplace
 275         ) ) {
 276             # Double the quotes to not be interpreted as a field end
 277             $row->{$_} =~ s/"/""/g if $row->{$_};
 278         }
 279         push @rows, $row;
 280     }
 281
 282     @rows = sort {
 283         if(defined $a->{publishercode} and defined $b->{publishercode}) {
 284             $a->{publishercode} cmp $b->{publishercode};
 285         }
 286     } @rows;
 287
 288     $template->param(rows => \@rows);
 289
 290     return $template->output;
 291 }
 292
 293
 294 =head3 GetBasketGroupAsCSV
 295
 296 =over 4
 297
 298 &GetBasketGroupAsCSV($basketgroupid);
 299
 300 Export a basket group as CSV
 301
 302 $cgi parameter is needed for column name translation
 303
 304 =back
 305
 306 =cut
 307
 308 sub GetBasketGroupAsCSV {
 309     my ($basketgroupid, $cgi) = @_;
 310     my $baskets = GetBasketsByBasketgroup($basketgroupid);
 311
 312     my $template = C4::Templates::gettemplate('acqui/csv/basketgroup.tmpl', 'intranet', $cgi);
 313
 314     my @rows;
 315     for my $basket (@$baskets) {
 316         my @orders     = GetOrders( $$basket{basketno} );
 317         my $contract   = GetContract( $$basket{contractnumber} );
 318         my $bookseller = GetBookSellerFromId( $$basket{booksellerid} );
 319         my $basketgroup = GetBasketgroup( $$basket{basketgroupid} );
 320
 321         foreach my $order (@orders) {
 322             my $bd = GetBiblioData( $order->{'biblionumber'} );
 323             my $row = {
 324                 clientnumber => $bookseller->{accountnumber},
 325                 basketname => $basket->{basketname},
 326                 ordernumber => $order->{ordernumber},
 327                 author => $bd->{author},
 328                 title => $bd->{title},
 329                 publishercode => $bd->{publishercode},
 330                 publicationyear => $bd->{publicationyear},
 331                 collectiontitle => $bd->{collectiontitle},
 332                 isbn => $order->{isbn},
 333                 quantity => $order->{quantity},
 334                 rrp => $order->{rrp},
 335                 discount => $bookseller->{discount},
 336                 ecost => $order->{ecost},
 337                 notes => $order->{notes},
 338                 entrydate => $order->{entrydate},
 339                 booksellername => $bookseller->{name},
 340                 bookselleraddress => $bookseller->{address1},
 341                 booksellerpostal => $bookseller->{postal},
 342                 contractnumber => $contract->{contractnumber},
 343                 contractname => $contract->{contractname},
 344                 basketgroupdeliveryplace => C4::Branch::GetBranchName( $basketgroup->{deliveryplace} ),
 345                 basketgroupbillingplace => C4::Branch::GetBranchName( $basketgroup->{billingplace} ),
 346                 basketdeliveryplace => C4::Branch::GetBranchName( $basket->{deliveryplace} ),
 347                 basketbillingplace => C4::Branch::GetBranchName( $basket->{billingplace} ),
 348             };
 349             foreach(qw(
 350                 basketname author title publishercode collectiontitle notes
 351                 booksellername bookselleraddress booksellerpostal contractname
 352                 basketgroupdeliveryplace basketgroupbillingplace
 353                 basketdeliveryplace basketbillingplace
 354             ) ) {
 355                 # Double the quotes to not be interpreted as a field end
 356                 $row->{$_} =~ s/"/""/g if $row->{$_};
 357             }
 358             push @rows, $row;
 359          }
 360      }
 361     $template->param(rows => \@rows);
 362
 363     return $template->output;
 364
 365 }
 366
 367 =head3 CloseBasketgroup
 368
 369   &CloseBasketgroup($basketgroupno);
 370
 371 close a basketgroup
 372
 373 =cut
 374
 375 sub CloseBasketgroup {
 376     my ($basketgroupno) = @_;
 377     my $dbh        = C4::Context->dbh;
 378     my $sth = $dbh->prepare("
 379         UPDATE aqbasketgroups
 380         SET    closed=1
 381         WHERE  id=?
 382     ");
 383     $sth->execute($basketgroupno);
 384 }
 385
 386 #------------------------------------------------------------#
 387
 388 =head3 ReOpenBaskergroup($basketgroupno)
 389
 390   &ReOpenBaskergroup($basketgroupno);
 391
 392 reopen a basketgroup
 393
 394 =cut
 395
 396 sub ReOpenBasketgroup {
 397     my ($basketgroupno) = @_;
 398     my $dbh        = C4::Context->dbh;
 399     my $sth = $dbh->prepare("
 400         UPDATE aqbasketgroups
 401         SET    closed=0
 402         WHERE  id=?
 403     ");
 404     $sth->execute($basketgroupno);
 405 }
 406
 407 #------------------------------------------------------------#
 408
 409
 410 =head3 DelBasket
 411
 412   &DelBasket($basketno);
 413
 414 Deletes the basket that has basketno field $basketno in the aqbasket table.
 415
 416 =over
 417
 418 =item C<$basketno> is the primary key of the basket in the aqbasket table.
 419
 420 =back
 421
 422 =cut
 423
 424 sub DelBasket {
 425     my ( $basketno ) = @_;
 426     my $query = "DELETE FROM aqbasket WHERE basketno=?";
 427     my $dbh = C4::Context->dbh;
 428     my $sth = $dbh->prepare($query);
 429     $sth->execute($basketno);
 430     $sth->finish;
 431 }
 432
 433 #------------------------------------------------------------#
 434
 435 =head3 ModBasket
 436
 437   &ModBasket($basketinfo);
 438
 439 Modifies a basket, using a hashref $basketinfo for the relevant information, only $basketinfo->{'basketno'} is required.
 440
 441 =over
 442
 443 =item C<$basketno> is the primary key of the basket in the aqbasket table.
 444
 445 =back
 446
 447 =cut
 448
 449 sub ModBasket {
 450     my $basketinfo = shift;
 451     my $query = "UPDATE aqbasket SET ";
 452     my @params;
 453     foreach my $key (keys %$basketinfo){
 454         if ($key ne 'basketno'){
 455             $query .= "$key=?, ";
 456             push(@params, $basketinfo->{$key} || undef );
 457         }
 458     }
 459 # get rid of the "," at the end of $query
 460     if (substr($query, length($query)-2) eq ', '){
 461         chop($query);
 462         chop($query);
 463         $query .= ' ';
 464     }
 465     $query .= "WHERE basketno=?";
 466     push(@params, $basketinfo->{'basketno'});
 467     my $dbh = C4::Context->dbh;
 468     my $sth = $dbh->prepare($query);
 469     $sth->execute(@params);
 470     $sth->finish;
 471 }
 472
 473 #------------------------------------------------------------#
 474
 475 =head3 ModBasketHeader
 476
 477   &ModBasketHeader($basketno, $basketname, $note, $booksellernote, $contractnumber, $booksellerid);
 478
 479 Modifies a basket's header.
 480
 481 =over
 482
 483 =item C<$basketno> is the "basketno" field in the "aqbasket" table;
 484
 485 =item C<$basketname> is the "basketname" field in the "aqbasket" table;
 486
 487 =item C<$note> is the "note" field in the "aqbasket" table;
 488
 489 =item C<$booksellernote> is the "booksellernote" field in the "aqbasket" table;
 490
 491 =item C<$contractnumber> is the "contractnumber" (foreign) key in the "aqbasket" table.
 492
 493 =item C<$booksellerid> is the id (foreign) key in the "aqbooksellers" table for the vendor.
 494
 495 =item C<$deliveryplace> is the "deliveryplace" field in the aqbasket table.
 496
 497 =item C<$billingplace> is the "billingplace" field in the aqbasket table.
 498
 499 =back
 500
 501 =cut
 502
 503 sub ModBasketHeader {
 504     my ($basketno, $basketname, $note, $booksellernote, $contractnumber, $booksellerid, $deliveryplace, $billingplace) = @_;
 505     my $query = qq{
 506         UPDATE aqbasket
 507         SET basketname=?, note=?, booksellernote=?, booksellerid=?, deliveryplace=?, billingplace=?
 508         WHERE basketno=?
 509     };
 510
 511     my $dbh = C4::Context->dbh;
 512     my $sth = $dbh->prepare($query);
 513     $sth->execute($basketname, $note, $booksellernote, $booksellerid, $deliveryplace, $billingplace, $basketno);
 514
 515     if ( $contractnumber ) {
 516         my $query2 ="UPDATE aqbasket SET contractnumber=? WHERE basketno=?";
 517         my $sth2 = $dbh->prepare($query2);
 518         $sth2->execute($contractnumber,$basketno);
 519         $sth2->finish;
 520     }
 521     $sth->finish;
 522 }
 523
 524 #------------------------------------------------------------#
 525
 526 =head3 GetBasketsByBookseller
 527
 528   @results = &GetBasketsByBookseller($booksellerid, $extra);
 529
 530 Returns a list of hashes of all the baskets that belong to bookseller 'booksellerid'.
 531
 532 =over
 533
 534 =item C<$booksellerid> is the 'id' field of the bookseller in the aqbooksellers table
 535
 536 =item C<$extra> is the extra sql parameters, can be
 537
 538  $extra->{groupby}: group baskets by column
 539     ex. $extra->{groupby} = aqbasket.basketgroupid
 540  $extra->{orderby}: order baskets by column
 541  $extra->{limit}: limit number of results (can be helpful for pagination)
 542
 543 =back
 544
 545 =cut
 546
 547 sub GetBasketsByBookseller {
 548     my ($booksellerid, $extra) = @_;
 549     my $query = "SELECT * FROM aqbasket WHERE booksellerid=?";
 550     if ($extra){
 551         if ($extra->{groupby}) {
 552             $query .= " GROUP by $extra->{groupby}";
 553         }
 554         if ($extra->{orderby}){
 555             $query .= " ORDER by $extra->{orderby}";
 556         }
 557         if ($extra->{limit}){
 558             $query .= " LIMIT $extra->{limit}";
 559         }
 560     }
 561     my $dbh = C4::Context->dbh;
 562     my $sth = $dbh->prepare($query);
 563     $sth->execute($booksellerid);
 564     my $results = $sth->fetchall_arrayref({});
 565     $sth->finish;
 566     return $results
 567 }
 568
 569 =head3 GetBasketsInfosByBookseller
 570
 571     my $baskets = GetBasketsInfosByBookseller($supplierid, $allbaskets);
 572
 573 The optional second parameter allbaskets is a boolean allowing you to
 574 select all baskets from the supplier; by default only active baskets (open or
 575 closed but still something to receive) are returned.
 576
 577 Returns in a arrayref of hashref all about booksellers baskets, plus:
 578     total_biblios: Number of distinct biblios in basket
 579     total_items: Number of items in basket
 580     expected_items: Number of non-received items in basket
 581
 582 =cut
 583
 584 sub GetBasketsInfosByBookseller {
 585     my ($supplierid, $allbaskets) = @_;
 586
 587     return unless $supplierid;
 588
 589     my $dbh = C4::Context->dbh;
 590     my $query = qq{
 591         SELECT aqbasket.*,
 592           SUM(aqorders.quantity) AS total_items,
 593           COUNT(DISTINCT aqorders.biblionumber) AS total_biblios,
 594           SUM(
 595             IF(aqorders.datereceived IS NULL
 596               AND aqorders.datecancellationprinted IS NULL
 597             , aqorders.quantity
 598             , 0)
 599           ) AS expected_items
 600         FROM aqbasket
 601           LEFT JOIN aqorders ON aqorders.basketno = aqbasket.basketno
 602         WHERE booksellerid = ?};
 603     if(!$allbaskets) {
 604         $query.=" AND (closedate IS NULL OR (aqorders.quantity > aqorders.quantityreceived AND datecancellationprinted IS NULL))";
 605     }
 606     $query.=" GROUP BY aqbasket.basketno";
 607
 608     my $sth = $dbh->prepare($query);
 609     $sth->execute($supplierid);
 610     return $sth->fetchall_arrayref({});
 611 }
 612
 613
 614 #------------------------------------------------------------#
 615
 616 =head3 GetBasketsByBasketgroup
 617
 618   $baskets = &GetBasketsByBasketgroup($basketgroupid);
 619
 620 Returns a reference to all baskets that belong to basketgroup $basketgroupid.
 621
 622 =cut
 623
 624 sub GetBasketsByBasketgroup {
 625     my $basketgroupid = shift;
 626     my $query = qq{
 627         SELECT *, aqbasket.booksellerid as booksellerid
 628         FROM aqbasket
 629         LEFT JOIN aqcontract USING(contractnumber) WHERE basketgroupid=?
 630     };
 631     my $dbh = C4::Context->dbh;
 632     my $sth = $dbh->prepare($query);
 633     $sth->execute($basketgroupid);
 634     my $results = $sth->fetchall_arrayref({});
 635     $sth->finish;
 636     return $results
 637 }
 638
 639 #------------------------------------------------------------#
 640
 641 =head3 NewBasketgroup
 642
 643   $basketgroupid = NewBasketgroup(\%hashref);
 644
 645 Adds a basketgroup to the aqbasketgroups table, and add the initial baskets to it.
 646
 647 $hashref->{'booksellerid'} is the 'id' field of the bookseller in the aqbooksellers table,
 648
 649 $hashref->{'name'} is the 'name' field of the basketgroup in the aqbasketgroups table,
 650
 651 $hashref->{'basketlist'} is a list reference of the 'id's of the baskets that belong to this group,
 652
 653 $hashref->{'billingplace'} is the 'billingplace' field of the basketgroup in the aqbasketgroups table,
 654
 655 $hashref->{'deliveryplace'} is the 'deliveryplace' field of the basketgroup in the aqbasketgroups table,
 656
 657 $hashref->{'freedeliveryplace'} is the 'freedeliveryplace' field of the basketgroup in the aqbasketgroups table,
 658
 659 $hashref->{'deliverycomment'} is the 'deliverycomment' field of the basketgroup in the aqbasketgroups table,
 660
 661 $hashref->{'closed'} is the 'closed' field of the aqbasketgroups table, it is false if 0, true otherwise.
 662
 663 =cut
 664
 665 sub NewBasketgroup {
 666     my $basketgroupinfo = shift;
 667     die "booksellerid is required to create a basketgroup" unless $basketgroupinfo->{'booksellerid'};
 668     my $query = "INSERT INTO aqbasketgroups (";
 669     my @params;
 670     foreach my $field (qw(name billingplace deliveryplace freedeliveryplace deliverycomment closed)) {
 671         if ( defined $basketgroupinfo->{$field} ) {
 672             $query .= "$field, ";
 673             push(@params, $basketgroupinfo->{$field});
 674         }
 675     }
 676     $query .= "booksellerid) VALUES (";
 677     foreach (@params) {
 678         $query .= "?, ";
 679     }
 680     $query .= "?)";
 681     push(@params, $basketgroupinfo->{'booksellerid'});
 682     my $dbh = C4::Context->dbh;
 683     my $sth = $dbh->prepare($query);
 684     $sth->execute(@params);
 685     my $basketgroupid = $dbh->{'mysql_insertid'};
 686     if( $basketgroupinfo->{'basketlist'} ) {
 687         foreach my $basketno (@{$basketgroupinfo->{'basketlist'}}) {
 688             my $query2 = "UPDATE aqbasket SET basketgroupid=? WHERE basketno=?";
 689             my $sth2 = $dbh->prepare($query2);
 690             $sth2->execute($basketgroupid, $basketno);
 691         }
 692     }
 693     return $basketgroupid;
 694 }
 695
 696 #------------------------------------------------------------#
 697
 698 =head3 ModBasketgroup
 699
 700   ModBasketgroup(\%hashref);
 701
 702 Modifies a basketgroup in the aqbasketgroups table, and add the baskets to it.
 703
 704 $hashref->{'id'} is the 'id' field of the basketgroup in the aqbasketgroup table, this parameter is mandatory,
 705
 706 $hashref->{'name'} is the 'name' field of the basketgroup in the aqbasketgroups table,
 707
 708 $hashref->{'basketlist'} is a list reference of the 'id's of the baskets that belong to this group,
 709
 710 $hashref->{'billingplace'} is the 'billingplace' field of the basketgroup in the aqbasketgroups table,
 711
 712 $hashref->{'deliveryplace'} is the 'deliveryplace' field of the basketgroup in the aqbasketgroups table,
 713
 714 $hashref->{'freedeliveryplace'} is the 'freedeliveryplace' field of the basketgroup in the aqbasketgroups table,
 715
 716 $hashref->{'deliverycomment'} is the 'deliverycomment' field of the basketgroup in the aqbasketgroups table,
 717
 718 $hashref->{'closed'} is the 'closed' field of the aqbasketgroups table, it is false if 0, true otherwise.
 719
 720 =cut
 721
 722 sub ModBasketgroup {
 723     my $basketgroupinfo = shift;
 724     die "basketgroup id is required to edit a basketgroup" unless $basketgroupinfo->{'id'};
 725     my $dbh = C4::Context->dbh;
 726     my $query = "UPDATE aqbasketgroups SET ";
 727     my @params;
 728     foreach my $field (qw(name billingplace deliveryplace freedeliveryplace deliverycomment closed)) {
 729         if ( defined $basketgroupinfo->{$field} ) {
 730             $query .= "$field=?, ";
 731             push(@params, $basketgroupinfo->{$field});
 732         }
 733     }
 734     chop($query);
 735     chop($query);
 736     $query .= " WHERE id=?";
 737     push(@params, $basketgroupinfo->{'id'});
 738     my $sth = $dbh->prepare($query);
 739     $sth->execute(@params);
 740
 741     $sth = $dbh->prepare('UPDATE aqbasket SET basketgroupid = NULL WHERE basketgroupid = ?');
 742     $sth->execute($basketgroupinfo->{'id'});
 743
 744     if($basketgroupinfo->{'basketlist'} && @{$basketgroupinfo->{'basketlist'}}){
 745         $sth = $dbh->prepare("UPDATE aqbasket SET basketgroupid=? WHERE basketno=?");
 746         foreach my $basketno (@{$basketgroupinfo->{'basketlist'}}) {
 747             $sth->execute($basketgroupinfo->{'id'}, $basketno);
 748             $sth->finish;
 749         }
 750     }
 751     $sth->finish;
 752 }
 753
 754 #------------------------------------------------------------#
 755
 756 =head3 DelBasketgroup
 757
 758   DelBasketgroup($basketgroupid);
 759
 760 Deletes a basketgroup in the aqbasketgroups table, and removes the reference to it from the baskets,
 761
 762 =over
 763
 764 =item C<$basketgroupid> is the 'id' field of the basket in the aqbasketgroup table
 765
 766 =back
 767
 768 =cut
 769
 770 sub DelBasketgroup {
 771     my $basketgroupid = shift;
 772     die "basketgroup id is required to edit a basketgroup" unless $basketgroupid;
 773     my $query = "DELETE FROM aqbasketgroups WHERE id=?";
 774     my $dbh = C4::Context->dbh;
 775     my $sth = $dbh->prepare($query);
 776     $sth->execute($basketgroupid);
 777     $sth->finish;
 778 }
 779
 780 #------------------------------------------------------------#
 781
 782
 783 =head2 FUNCTIONS ABOUT ORDERS
 784
 785 =head3 GetBasketgroup
 786
 787   $basketgroup = &GetBasketgroup($basketgroupid);
 788
 789 Returns a reference to the hash containing all information about the basketgroup.
 790
 791 =cut
 792
 793 sub GetBasketgroup {
 794     my $basketgroupid = shift;
 795     die "basketgroup id is required to edit a basketgroup" unless $basketgroupid;
 796     my $query = "SELECT * FROM aqbasketgroups WHERE id=?";
 797     my $dbh = C4::Context->dbh;
 798     my $sth = $dbh->prepare($query);
 799     $sth->execute($basketgroupid);
 800     my $result = $sth->fetchrow_hashref;
 801     $sth->finish;
 802     return $result
 803 }
 804
 805 #------------------------------------------------------------#
 806
 807 =head3 GetBasketgroups
 808
 809   $basketgroups = &GetBasketgroups($booksellerid);
 810
 811 Returns a reference to the array of all the basketgroups of bookseller $booksellerid.
 812
 813 =cut
 814
 815 sub GetBasketgroups {
 816     my $booksellerid = shift;
 817     die 'bookseller id is required to edit a basketgroup' unless $booksellerid;
 818     my $query = 'SELECT * FROM aqbasketgroups WHERE booksellerid=? ORDER BY id DESC';
 819     my $dbh = C4::Context->dbh;
 820     my $sth = $dbh->prepare($query);
 821     $sth->execute($booksellerid);
 822     return $sth->fetchall_arrayref({});
 823 }
 824
 825 #------------------------------------------------------------#
 826
 827 =head2 FUNCTIONS ABOUT ORDERS
 828
 829 =cut
 830
 831 #------------------------------------------------------------#
 832
 833 =head3 GetPendingOrders
 834
 835 $orders = &GetPendingOrders($supplierid,$grouped,$owner,$basketno,$ordernumber,$search,$ean);
 836
 837 Finds pending orders from the bookseller with the given ID. Ignores
 838 completed and cancelled orders.
 839
 840 C<$booksellerid> contains the bookseller identifier
 841 C<$owner> contains 0 or 1. 0 means any owner. 1 means only the list of orders entered by the user itself.
 842 C<$grouped> is a boolean that, if set to 1 will group all order lines of the same basket
 843 in a single result line
 844 C<$orders> is a reference-to-array; each element is a reference-to-hash.
 845
 846 Used also by the filter in parcel.pl
 847 I have added:
 848
 849 C<$ordernumber>
 850 C<$search>
 851 C<$ean>
 852
 853 These give the value of the corresponding field in the aqorders table
 854 of the Koha database.
 855
 856 Results are ordered from most to least recent.
 857
 858 =cut
 859
 860 sub GetPendingOrders {
 861     my ($supplierid,$grouped,$owner,$basketno,$ordernumber,$search,$ean) = @_;
 862     my $dbh = C4::Context->dbh;
 863     my $strsth = "
 864         SELECT ".($grouped?"count(*),":"")."aqbasket.basketno,
 865                surname,firstname,biblio.*,biblioitems.isbn,
 866                aqbasket.closedate, aqbasket.creationdate, aqbasket.basketname,
 867                aqorders.*
 868         FROM aqorders
 869         LEFT JOIN aqbasket ON aqbasket.basketno=aqorders.basketno
 870         LEFT JOIN borrowers ON aqbasket.authorisedby=borrowers.borrowernumber
 871         LEFT JOIN biblio ON biblio.biblionumber=aqorders.biblionumber
 872         LEFT JOIN biblioitems ON biblioitems.biblionumber=biblio.biblionumber
 873         WHERE (quantity > quantityreceived OR quantityreceived is NULL)
 874         AND datecancellationprinted IS NULL";
 875     my @query_params;
 876     my $userenv = C4::Context->userenv;
 877     if ( C4::Context->preference("IndependantBranches") ) {
 878         if ( ($userenv) && ( $userenv->{flags} != 1 ) ) {
 879             $strsth .= " AND (borrowers.branchcode = ?
 880                         or borrowers.branchcode  = '')";
 881             push @query_params, $userenv->{branch};
 882         }
 883     }
 884     if ($supplierid) {
 885         $strsth .= " AND aqbasket.booksellerid = ?";
 886         push @query_params, $supplierid;
 887     }
 888     if($ordernumber){
 889         $strsth .= " AND (aqorders.ordernumber=?)";
 890         push @query_params, $ordernumber;
 891     }
 892     if($search){
 893         $strsth .= " AND (biblio.title like ? OR biblio.author LIKE ? OR biblioitems.isbn like ?)";
 894         push @query_params, ("%$search%","%$search%","%$search%");
 895     }
 896     if ($ean) {
 897         $strsth .= " AND biblioitems.ean = ?";
 898         push @query_params, $ean;
 899     }
 900     if ($basketno) {
 901         $strsth .= " AND aqbasket.basketno=? ";
 902         push @query_params, $basketno;
 903     }
 904     if ($owner) {
 905         $strsth .= " AND aqbasket.authorisedby=? ";
 906         push @query_params, $userenv->{'number'};
 907     }
 908     $strsth .= " group by aqbasket.basketno" if $grouped;
 909     $strsth .= " order by aqbasket.basketno";
 910     my $sth = $dbh->prepare($strsth);
 911     $sth->execute( @query_params );
 912     my $results = $sth->fetchall_arrayref({});
 913     $sth->finish;
 914     return $results;
 915 }
 916
 917 #------------------------------------------------------------#
 918
 919 =head3 GetOrders
 920
 921   @orders = &GetOrders($basketnumber, $orderby);
 922
 923 Looks up the pending (non-cancelled) orders with the given basket
 924 number. If C<$booksellerID> is non-empty, only orders from that seller
 925 are returned.
 926
 927 return :
 928 C<&basket> returns a two-element array. C<@orders> is an array of
 929 references-to-hash, whose keys are the fields from the aqorders,
 930 biblio, and biblioitems tables in the Koha database.
 931
 932 =cut
 933
 934 sub GetOrders {
 935     my ( $basketno, $orderby ) = @_;
 936     my $dbh   = C4::Context->dbh;
 937     my $query  ="
 938         SELECT biblio.*,biblioitems.*,
 939                 aqorders.*,
 940                 aqbudgets.*,
 941                 biblio.title
 942         FROM    aqorders
 943             LEFT JOIN aqbudgets        ON aqbudgets.budget_id = aqorders.budget_id
 944             LEFT JOIN biblio           ON biblio.biblionumber = aqorders.biblionumber
 945             LEFT JOIN biblioitems      ON biblioitems.biblionumber =biblio.biblionumber
 946         WHERE   basketno=?
 947             AND (datecancellationprinted IS NULL OR datecancellationprinted='0000-00-00')
 948     ";
 949
 950     $orderby = "biblioitems.publishercode,biblio.title" unless $orderby;
 951     $query .= " ORDER BY $orderby";
 952     my $sth = $dbh->prepare($query);
 953     $sth->execute($basketno);
 954     my $results = $sth->fetchall_arrayref({});
 955     $sth->finish;
 956     return @$results;
 957 }
 958
 959 #------------------------------------------------------------#
 960 =head3 GetOrdersByBiblionumber
 961
 962   @orders = &GetOrdersByBiblionumber($biblionumber);
 963
 964 Looks up the orders with linked to a specific $biblionumber, including
 965 cancelled orders and received orders.
 966
 967 return :
 968 C<@orders> is an array of references-to-hash, whose keys are the
 969 fields from the aqorders, biblio, and biblioitems tables in the Koha database.
 970
 971 =cut
 972
 973 sub GetOrdersByBiblionumber {
 974     my $biblionumber = shift;
 975     return unless $biblionumber;
 976     my $dbh   = C4::Context->dbh;
 977     my $query  ="
 978         SELECT biblio.*,biblioitems.*,
 979                 aqorders.*,
 980                 aqbudgets.*
 981         FROM    aqorders
 982             LEFT JOIN aqbudgets        ON aqbudgets.budget_id = aqorders.budget_id
 983             LEFT JOIN biblio           ON biblio.biblionumber = aqorders.biblionumber
 984             LEFT JOIN biblioitems      ON biblioitems.biblionumber =biblio.biblionumber
 985         WHERE   aqorders.biblionumber=?
 986     ";
 987     my $sth = $dbh->prepare($query);
 988     $sth->execute($biblionumber);
 989     my $results = $sth->fetchall_arrayref({});
 990     $sth->finish;
 991     return @$results;
 992 }
 993
 994 #------------------------------------------------------------#
 995
 996 =head3 GetOrderNumber
 997
 998   $ordernumber = &GetOrderNumber($biblioitemnumber, $biblionumber);
 999
1000 Looks up the ordernumber with the given biblionumber and biblioitemnumber.
1001
1002 Returns the number of this order.
1003
1004 =over
1005
1006 =item C<$ordernumber> is the order number.
1007
1008 =back
1009
1010 =cut
1011
1012 sub GetOrderNumber {
1013     my ( $biblionumber,$biblioitemnumber ) = @_;
1014     my $dbh = C4::Context->dbh;
1015     my $query = "
1016         SELECT ordernumber
1017         FROM   aqorders
1018         WHERE  biblionumber=?
1019         AND    biblioitemnumber=?
1020     ";
1021     my $sth = $dbh->prepare($query);
1022     $sth->execute( $biblionumber, $biblioitemnumber );
1023
1024     return $sth->fetchrow;
1025 }
1026
1027 #------------------------------------------------------------#
1028
1029 =head3 GetOrder
1030
1031   $order = &GetOrder($ordernumber);
1032
1033 Looks up an order by order number.
1034
1035 Returns a reference-to-hash describing the order. The keys of
1036 C<$order> are fields from the biblio, biblioitems, aqorders tables of the Koha database.
1037
1038 =cut
1039
1040 sub GetOrder {
1041     my ($ordernumber) = @_;
1042     my $dbh      = C4::Context->dbh;
1043     my $query = "
1044         SELECT biblioitems.*, biblio.*, aqorders.*
1045         FROM   aqorders
1046         LEFT JOIN biblio on           biblio.biblionumber=aqorders.biblionumber
1047         LEFT JOIN biblioitems on       biblioitems.biblionumber=aqorders.biblionumber
1048         WHERE aqorders.ordernumber=?
1049
1050     ";
1051     my $sth= $dbh->prepare($query);
1052     $sth->execute($ordernumber);
1053     my $data = $sth->fetchrow_hashref;
1054     $sth->finish;
1055     return $data;
1056 }
1057
1058 =head3 GetLastOrderNotReceivedFromSubscriptionid
1059
1060   $order = &GetLastOrderNotReceivedFromSubscriptionid($subscriptionid);
1061
1062 Returns a reference-to-hash describing the last order not received for a subscription.
1063
1064 =cut
1065
1066 sub GetLastOrderNotReceivedFromSubscriptionid {
1067     my ( $subscriptionid ) = @_;
1068     my $dbh                = C4::Context->dbh;
1069     my $query              = qq|
1070         SELECT * FROM aqorders
1071         LEFT JOIN subscription
1072             ON ( aqorders.subscriptionid = subscription.subscriptionid )
1073         WHERE aqorders.subscriptionid = ?
1074             AND aqorders.datereceived IS NULL
1075         LIMIT 1
1076     |;
1077     my $sth = $dbh->prepare( $query );
1078     $sth->execute( $subscriptionid );
1079     my $order = $sth->fetchrow_hashref;
1080     return $order;
1081 }
1082
1083 =head3 GetLastOrderReceivedFromSubscriptionid
1084
1085   $order = &GetLastOrderReceivedFromSubscriptionid($subscriptionid);
1086
1087 Returns a reference-to-hash describing the last order received for a subscription.
1088
1089 =cut
1090
1091 sub GetLastOrderReceivedFromSubscriptionid {
1092     my ( $subscriptionid ) = @_;
1093     my $dbh                = C4::Context->dbh;
1094     my $query              = qq|
1095         SELECT * FROM aqorders
1096         LEFT JOIN subscription
1097             ON ( aqorders.subscriptionid = subscription.subscriptionid )
1098         WHERE aqorders.subscriptionid = ?
1099             AND aqorders.datereceived =
1100                 (
1101                     SELECT MAX( aqorders.datereceived )
1102                     FROM aqorders
1103                     LEFT JOIN subscription
1104                         ON ( aqorders.subscriptionid = subscription.subscriptionid )
1105                         WHERE aqorders.subscriptionid = ?
1106                             AND aqorders.datereceived IS NOT NULL
1107                 )
1108         ORDER BY ordernumber DESC
1109         LIMIT 1
1110     |;
1111     my $sth = $dbh->prepare( $query );
1112     $sth->execute( $subscriptionid, $subscriptionid );
1113     my $order = $sth->fetchrow_hashref;
1114     return $order;
1115
1116 }
1117
1118
1119 #------------------------------------------------------------#
1120
1121 =head3 NewOrder
1122
1123   &NewOrder(\%hashref);
1124
1125 Adds a new order to the database. Any argument that isn't described
1126 below is the new value of the field with the same name in the aqorders
1127 table of the Koha database.
1128
1129 =over
1130
1131 =item $hashref->{'basketno'} is the basketno foreign key in aqorders, it is mandatory
1132
1133 =item $hashref->{'ordernumber'} is a "minimum order number."
1134
1135 =item $hashref->{'budgetdate'} is effectively ignored.
1136 If it's undef (anything false) or the string 'now', the current day is used.
1137 Else, the upcoming July 1st is used.
1138
1139 =item $hashref->{'subscription'} may be either "yes", or anything else for "no".
1140
1141 =item $hashref->{'uncertainprice'} may be 0 for "the price is known" or 1 for "the price is uncertain"
1142
1143 =item defaults entrydate to Now
1144
1145 The following keys are used: "biblionumber", "title", "basketno", "quantity", "notes", "biblioitemnumber", "rrp", "ecost", "gstrate", "unitprice", "subscription", "sort1", "sort2", "booksellerinvoicenumber", "listprice", "budgetdate", "purchaseordernumber", "branchcode", "booksellerinvoicenumber", "budget_id".
1146
1147 =back
1148
1149 =cut
1150
1151 sub NewOrder {
1152     my $orderinfo = shift;
1153 #### ------------------------------
1154     my $dbh = C4::Context->dbh;
1155     my @params;
1156
1157
1158     # if these parameters are missing, we can't continue
1159     for my $key (qw/basketno quantity biblionumber budget_id/) {
1160         croak "Mandatory parameter $key missing" unless $orderinfo->{$key};
1161     }
1162
1163     if ( defined $orderinfo->{subscription} && $orderinfo->{'subscription'} eq 'yes' ) {
1164         $orderinfo->{'subscription'} = 1;
1165     } else {
1166         $orderinfo->{'subscription'} = 0;
1167     }
1168     $orderinfo->{'entrydate'} ||= C4::Dates->new()->output("iso");
1169     if (!$orderinfo->{quantityreceived}) {
1170         $orderinfo->{quantityreceived} = 0;
1171     }
1172
1173     my $ordernumber=InsertInTable("aqorders",$orderinfo);
1174     if (not $orderinfo->{parent_ordernumber}) {
1175         my $sth = $dbh->prepare("
1176             UPDATE aqorders
1177             SET parent_ordernumber = ordernumber
1178             WHERE ordernumber = ?
1179         ");
1180         $sth->execute($ordernumber);
1181     }
1182     return ( $orderinfo->{'basketno'}, $ordernumber );
1183 }
1184
1185
1186
1187 #------------------------------------------------------------#
1188
1189 =head3 NewOrderItem
1190
1191   &NewOrderItem();
1192
1193 =cut
1194
1195 sub NewOrderItem {
1196     my ($itemnumber, $ordernumber)  = @_;
1197     my $dbh = C4::Context->dbh;
1198     my $query = qq|
1199             INSERT INTO aqorders_items
1200                 (itemnumber, ordernumber)
1201             VALUES (?,?)    |;
1202
1203     my $sth = $dbh->prepare($query);
1204     $sth->execute( $itemnumber, $ordernumber);
1205 }
1206
1207 #------------------------------------------------------------#
1208
1209 =head3 ModOrder
1210
1211   &ModOrder(\%hashref);
1212
1213 Modifies an existing order. Updates the order with order number
1214 $hashref->{'ordernumber'} and biblionumber $hashref->{'biblionumber'}. All
1215 other keys of the hash update the fields with the same name in the aqorders
1216 table of the Koha database.
1217
1218 =cut
1219
1220 sub ModOrder {
1221     my $orderinfo = shift;
1222
1223     die "Ordernumber is required"     if $orderinfo->{'ordernumber'} eq  '' ;
1224     die "Biblionumber is required"  if  $orderinfo->{'biblionumber'} eq '';
1225
1226     my $dbh = C4::Context->dbh;
1227     my @params;
1228
1229     # update uncertainprice to an integer, just in case (under FF, checked boxes have the value "ON" by default)
1230     $orderinfo->{uncertainprice}=1 if $orderinfo->{uncertainprice};
1231
1232 #    delete($orderinfo->{'branchcode'});
1233     # the hash contains a lot of entries not in aqorders, so get the columns ...
1234     my $sth = $dbh->prepare("SELECT * FROM aqorders LIMIT 1;");
1235     $sth->execute;
1236     my $colnames = $sth->{NAME};
1237         #FIXME Be careful. If aqorders would have columns with diacritics,
1238         #you should need to decode what you get back from NAME.
1239         #See report 10110 and guided_reports.pl
1240     my $query = "UPDATE aqorders SET ";
1241
1242     foreach my $orderinfokey (grep(!/ordernumber/, keys %$orderinfo)){
1243         # ... and skip hash entries that are not in the aqorders table
1244         # FIXME : probably not the best way to do it (would be better to have a correct hash)
1245         next unless grep(/^$orderinfokey$/, @$colnames);
1246             $query .= "$orderinfokey=?, ";
1247             push(@params, $orderinfo->{$orderinfokey});
1248     }
1249
1250     $query .= "timestamp=NOW()  WHERE  ordernumber=?";
1251 #   push(@params, $specorderinfo{'ordernumber'});
1252     push(@params, $orderinfo->{'ordernumber'} );
1253     $sth = $dbh->prepare($query);
1254     $sth->execute(@params);
1255     $sth->finish;
1256 }
1257
1258 #------------------------------------------------------------#
1259
1260 =head3 ModItemOrder
1261
1262     ModItemOrder($itemnumber, $ordernumber);
1263
1264 Modifies the ordernumber of an item in aqorders_items.
1265
1266 =cut
1267
1268 sub ModItemOrder {
1269     my ($itemnumber, $ordernumber) = @_;
1270
1271     return unless ($itemnumber and $ordernumber);
1272
1273     my $dbh = C4::Context->dbh;
1274     my $query = qq{
1275         UPDATE aqorders_items
1276         SET ordernumber = ?
1277         WHERE itemnumber = ?
1278     };
1279     my $sth = $dbh->prepare($query);
1280     return $sth->execute($ordernumber, $itemnumber);
1281 }
1282
1283 #------------------------------------------------------------#
1284
1285
1286 =head3 ModOrderBibliotemNumber
1287
1288   &ModOrderBiblioitemNumber($biblioitemnumber,$ordernumber, $biblionumber);
1289
1290 Modifies the biblioitemnumber for an existing order.
1291 Updates the order with order number C<$ordernum> and biblionumber C<$biblionumber>.
1292
1293 =cut
1294
1295 #FIXME: is this used at all?
1296 sub ModOrderBiblioitemNumber {
1297     my ($biblioitemnumber,$ordernumber, $biblionumber) = @_;
1298     my $dbh = C4::Context->dbh;
1299     my $query = "
1300     UPDATE aqorders
1301     SET    biblioitemnumber = ?
1302     WHERE  ordernumber = ?
1303     AND biblionumber =  ?";
1304     my $sth = $dbh->prepare($query);
1305     $sth->execute( $biblioitemnumber, $ordernumber, $biblionumber );
1306 }
1307
1308 =head3 GetCancelledOrders
1309
1310   my @orders = GetCancelledOrders($basketno, $orderby);
1311
1312 Returns cancelled orders for a basket
1313
1314 =cut
1315
1316 sub GetCancelledOrders {
1317     my ( $basketno, $orderby ) = @_;
1318
1319     return () unless $basketno;
1320
1321     my $dbh   = C4::Context->dbh;
1322     my $query = "
1323         SELECT biblio.*, biblioitems.*, aqorders.*, aqbudgets.*
1324         FROM aqorders
1325           LEFT JOIN aqbudgets   ON aqbudgets.budget_id = aqorders.budget_id
1326           LEFT JOIN biblio      ON biblio.biblionumber = aqorders.biblionumber
1327           LEFT JOIN biblioitems ON biblioitems.biblionumber = biblio.biblionumber
1328         WHERE basketno = ?
1329           AND (datecancellationprinted IS NOT NULL
1330                AND datecancellationprinted <> '0000-00-00')
1331     ";
1332
1333     $orderby = "aqorders.datecancellationprinted desc, aqorders.timestamp desc"
1334         unless $orderby;
1335     $query .= " ORDER BY $orderby";
1336     my $sth = $dbh->prepare($query);
1337     $sth->execute($basketno);
1338     my $results = $sth->fetchall_arrayref( {} );
1339
1340     return @$results;
1341 }
1342
1343
1344 #------------------------------------------------------------#
1345
1346 =head3 ModReceiveOrder
1347
1348   &ModReceiveOrder($biblionumber, $ordernumber, $quantityreceived, $user,
1349     $unitprice, $invoiceid, $biblioitemnumber,
1350     $bookfund, $rrp, \@received_itemnumbers);
1351
1352 Updates an order, to reflect the fact that it was received, at least
1353 in part. All arguments not mentioned below update the fields with the
1354 same name in the aqorders table of the Koha database.
1355
1356 If a partial order is received, splits the order into two.
1357
1358 Updates the order with bibilionumber C<$biblionumber> and ordernumber
1359 C<$ordernumber>.
1360
1361 =cut
1362
1363
1364 sub ModReceiveOrder {
1365     my (
1366         $biblionumber,    $ordernumber,  $quantrec, $user, $cost, $ecost,
1367         $invoiceid, $rrp, $budget_id, $datereceived, $received_items
1368     )
1369     = @_;
1370
1371     my $dbh = C4::Context->dbh;
1372     $datereceived = C4::Dates->output('iso') unless $datereceived;
1373     my $suggestionid = GetSuggestionFromBiblionumber( $biblionumber );
1374     if ($suggestionid) {
1375         ModSuggestion( {suggestionid=>$suggestionid,
1376                         STATUS=>'AVAILABLE',
1377                         biblionumber=> $biblionumber}
1378                         );
1379     }
1380
1381     my $sth=$dbh->prepare("
1382         SELECT * FROM   aqorders
1383         WHERE           biblionumber=? AND aqorders.ordernumber=?");
1384
1385     $sth->execute($biblionumber,$ordernumber);
1386     my $order = $sth->fetchrow_hashref();
1387     $sth->finish();
1388
1389     my $new_ordernumber = $ordernumber;
1390     if ( $order->{quantity} > $quantrec ) {
1391         # Split order line in two parts: the first is the original order line
1392         # without received items (the quantity is decreased),
1393         # the second part is a new order line with quantity=quantityrec
1394         # (entirely received)
1395         $sth=$dbh->prepare("
1396             UPDATE aqorders
1397             SET quantity = ?
1398             WHERE ordernumber = ?
1399         ");
1400
1401         $sth->execute($order->{quantity} - $quantrec, $ordernumber);
1402
1403         $sth->finish;
1404
1405         delete $order->{'ordernumber'};
1406         $order->{'quantity'} = $quantrec;
1407         $order->{'quantityreceived'} = $quantrec;
1408         $order->{'datereceived'} = $datereceived;
1409         $order->{'invoiceid'} = $invoiceid;
1410         $order->{'unitprice'} = $cost;
1411         $order->{'rrp'} = $rrp;
1412         $order->{ecost} = $ecost;
1413         $order->{'orderstatus'} = 3;    # totally received
1414         my $basketno;
1415         ( $basketno, $new_ordernumber ) = NewOrder($order);
1416
1417         if ($received_items) {
1418             foreach my $itemnumber (@$received_items) {
1419                 ModItemOrder($itemnumber, $new_ordernumber);
1420             }
1421         }
1422     } else {
1423         $sth=$dbh->prepare("update aqorders
1424                             set quantityreceived=?,datereceived=?,invoiceid=?,
1425                                 unitprice=?,rrp=?,ecost=?
1426                             where biblionumber=? and ordernumber=?");
1427         $sth->execute($quantrec,$datereceived,$invoiceid,$cost,$rrp,$ecost,$biblionumber,$ordernumber);
1428         $sth->finish;
1429     }
1430     return ($datereceived, $new_ordernumber);
1431 }
1432
1433 =head3 CancelReceipt
1434
1435     my $parent_ordernumber = CancelReceipt($ordernumber);
1436
1437     Cancel an order line receipt and update the parent order line, as if no
1438     receipt was made.
1439     If items are created at receipt (AcqCreateItem = receiving) then delete
1440     these items.
1441
1442 =cut
1443
1444 sub CancelReceipt {
1445     my $ordernumber = shift;
1446
1447     return unless $ordernumber;
1448
1449     my $dbh = C4::Context->dbh;
1450     my $query = qq{
1451         SELECT datereceived, parent_ordernumber, quantity
1452         FROM aqorders
1453         WHERE ordernumber = ?
1454     };
1455     my $sth = $dbh->prepare($query);
1456     $sth->execute($ordernumber);
1457     my $order = $sth->fetchrow_hashref;
1458     unless($order) {
1459         warn "CancelReceipt: order $ordernumber does not exist";
1460         return;
1461     }
1462     unless($order->{'datereceived'}) {
1463         warn "CancelReceipt: order $ordernumber is not received";
1464         return;
1465     }
1466
1467     my $parent_ordernumber = $order->{'parent_ordernumber'};
1468
1469     if($parent_ordernumber == $ordernumber || not $parent_ordernumber) {
1470         # The order line has no parent, just mark it as not received
1471         $query = qq{
1472             UPDATE aqorders
1473             SET quantityreceived = ?,
1474                 datereceived = ?,
1475                 invoiceid = ?
1476             WHERE ordernumber = ?
1477         };
1478         $sth = $dbh->prepare($query);
1479         $sth->execute(0, undef, undef, $ordernumber);
1480     } else {
1481         # The order line has a parent, increase parent quantity and delete
1482         # the order line.
1483         $query = qq{
1484             SELECT quantity, datereceived
1485             FROM aqorders
1486             WHERE ordernumber = ?
1487         };
1488         $sth = $dbh->prepare($query);
1489         $sth->execute($parent_ordernumber);
1490         my $parent_order = $sth->fetchrow_hashref;
1491         unless($parent_order) {
1492             warn "Parent order $parent_ordernumber does not exist.";
1493             return;
1494         }
1495         if($parent_order->{'datereceived'}) {
1496             warn "CancelReceipt: parent order is received.".
1497                 " Can't cancel receipt.";
1498             return;
1499         }
1500         $query = qq{
1501             UPDATE aqorders
1502             SET quantity = ?
1503             WHERE ordernumber = ?
1504         };
1505         $sth = $dbh->prepare($query);
1506         my $rv = $sth->execute(
1507             $order->{'quantity'} + $parent_order->{'quantity'},
1508             $parent_ordernumber
1509         );
1510         unless($rv) {
1511             warn "Cannot update parent order line, so do not cancel".
1512                 " receipt";
1513             return;
1514         }
1515         if(C4::Context->preference('AcqCreateItem') eq 'receiving') {
1516             # Remove items that were created at receipt
1517             $query = qq{
1518                 DELETE FROM items, aqorders_items
1519                 USING items, aqorders_items
1520                 WHERE items.itemnumber = ? AND aqorders_items.itemnumber = ?
1521             };
1522             $sth = $dbh->prepare($query);
1523             my @itemnumbers = GetItemnumbersFromOrder($ordernumber);
1524             foreach my $itemnumber (@itemnumbers) {
1525                 $sth->execute($itemnumber, $itemnumber);
1526             }
1527         } else {
1528             # Update items
1529             my @itemnumbers = GetItemnumbersFromOrder($ordernumber);
1530             foreach my $itemnumber (@itemnumbers) {
1531                 ModItemOrder($itemnumber, $parent_ordernumber);
1532             }
1533         }
1534         # Delete order line
1535         $query = qq{
1536             DELETE FROM aqorders
1537             WHERE ordernumber = ?
1538         };
1539         $sth = $dbh->prepare($query);
1540         $sth->execute($ordernumber);
1541
1542     }
1543
1544     return $parent_ordernumber;
1545 }
1546
1547 #------------------------------------------------------------#
1548
1549 =head3 SearchOrder
1550
1551 @results = &SearchOrder($search, $biblionumber, $complete);
1552
1553 Searches for orders.
1554
1555 C<$search> may take one of several forms: if it is an ISBN,
1556 C<&ordersearch> returns orders with that ISBN. If C<$search> is an
1557 order number, C<&ordersearch> returns orders with that order number
1558 and biblionumber C<$biblionumber>. Otherwise, C<$search> is considered
1559 to be a space-separated list of search terms; in this case, all of the
1560 terms must appear in the title (matching the beginning of title
1561 words).
1562
1563 If C<$complete> is C<yes>, the results will include only completed
1564 orders. In any case, C<&ordersearch> ignores cancelled orders.
1565
1566 C<&ordersearch> returns an array.
1567 C<@results> is an array of references-to-hash with the following keys:
1568
1569 =over 4
1570
1571 =item C<author>
1572
1573 =item C<seriestitle>
1574
1575 =item C<branchcode>
1576
1577 =item C<budget_id>
1578
1579 =back
1580
1581 =cut
1582
1583 sub SearchOrder {
1584 #### -------- SearchOrder-------------------------------
1585     my ( $ordernumber, $search, $ean, $supplierid, $basket ) = @_;
1586
1587     my $dbh = C4::Context->dbh;
1588     my @args = ();
1589     my $query =
1590             "SELECT *
1591             FROM aqorders
1592             LEFT JOIN biblio ON aqorders.biblionumber=biblio.biblionumber
1593             LEFT JOIN biblioitems ON biblioitems.biblionumber=biblio.biblionumber
1594             LEFT JOIN aqbasket ON aqorders.basketno = aqbasket.basketno
1595                 WHERE  (datecancellationprinted is NULL)";
1596
1597     if($ordernumber){
1598         $query .= " AND (aqorders.ordernumber=?)";
1599         push @args, $ordernumber;
1600     }
1601     if($search){
1602         $query .= " AND (biblio.title like ? OR biblio.author LIKE ? OR biblioitems.isbn like ?)";
1603         push @args, ("%$search%","%$search%","%$search%");
1604     }
1605     if ($ean) {
1606         $query .= " AND biblioitems.ean = ?";
1607         push @args, $ean;
1608     }
1609     if ($supplierid) {
1610         $query .= "AND aqbasket.booksellerid = ?";
1611         push @args, $supplierid;
1612     }
1613     if($basket){
1614         $query .= "AND aqorders.basketno = ?";
1615         push @args, $basket;
1616     }
1617
1618     my $sth = $dbh->prepare($query);
1619     $sth->execute(@args);
1620     my $results = $sth->fetchall_arrayref({});
1621     $sth->finish;
1622     return $results;
1623 }
1624
1625 #------------------------------------------------------------#
1626
1627 =head3 DelOrder
1628
1629   &DelOrder($biblionumber, $ordernumber);
1630
1631 Cancel the order with the given order and biblio numbers. It does not
1632 delete any entries in the aqorders table, it merely marks them as
1633 cancelled.
1634
1635 =cut
1636
1637 sub DelOrder {
1638     my ( $bibnum, $ordernumber ) = @_;
1639     my $dbh = C4::Context->dbh;
1640     my $query = "
1641         UPDATE aqorders
1642         SET    datecancellationprinted=now()
1643         WHERE  biblionumber=? AND ordernumber=?
1644     ";
1645     my $sth = $dbh->prepare($query);
1646     $sth->execute( $bibnum, $ordernumber );
1647     $sth->finish;
1648     my @itemnumbers = GetItemnumbersFromOrder( $ordernumber );
1649     foreach my $itemnumber (@itemnumbers){
1650         C4::Items::DelItem( $dbh, $bibnum, $itemnumber );
1651     }
1652
1653 }
1654
1655 =head2 FUNCTIONS ABOUT PARCELS
1656
1657 =cut
1658
1659 #------------------------------------------------------------#
1660
1661 =head3 GetParcel
1662
1663   @results = &GetParcel($booksellerid, $code, $date);
1664
1665 Looks up all of the received items from the supplier with the given
1666 bookseller ID at the given date, for the given code (bookseller Invoice number). Ignores cancelled and completed orders.
1667
1668 C<@results> is an array of references-to-hash. The keys of each element are fields from
1669 the aqorders, biblio, and biblioitems tables of the Koha database.
1670
1671 C<@results> is sorted alphabetically by book title.
1672
1673 =cut
1674
1675 sub GetParcel {
1676     #gets all orders from a certain supplier, orders them alphabetically
1677     my ( $supplierid, $code, $datereceived ) = @_;
1678     my $dbh     = C4::Context->dbh;
1679     my @results = ();
1680     $code .= '%'
1681     if $code;  # add % if we search on a given code (otherwise, let him empty)
1682     my $strsth ="
1683         SELECT  authorisedby,
1684                 creationdate,
1685                 aqbasket.basketno,
1686                 closedate,surname,
1687                 firstname,
1688                 aqorders.biblionumber,
1689                 aqorders.ordernumber,
1690                 aqorders.parent_ordernumber,
1691                 aqorders.quantity,
1692                 aqorders.quantityreceived,
1693                 aqorders.unitprice,
1694                 aqorders.listprice,
1695                 aqorders.rrp,
1696                 aqorders.ecost,
1697                 aqorders.gstrate,
1698                 biblio.title
1699         FROM aqorders
1700         LEFT JOIN aqbasket ON aqbasket.basketno=aqorders.basketno
1701         LEFT JOIN borrowers ON aqbasket.authorisedby=borrowers.borrowernumber
1702         LEFT JOIN biblio ON aqorders.biblionumber=biblio.biblionumber
1703         LEFT JOIN aqinvoices ON aqorders.invoiceid = aqinvoices.invoiceid
1704         WHERE
1705             aqbasket.booksellerid = ?
1706             AND aqinvoices.invoicenumber LIKE ?
1707             AND aqorders.datereceived = ? ";
1708
1709     my @query_params = ( $supplierid, $code, $datereceived );
1710     if ( C4::Context->preference("IndependantBranches") ) {
1711         my $userenv = C4::Context->userenv;
1712         if ( ($userenv) && ( $userenv->{flags} != 1 ) ) {
1713             $strsth .= " and (borrowers.branchcode = ?
1714                         or borrowers.branchcode  = '')";
1715             push @query_params, $userenv->{branch};
1716         }
1717     }
1718     $strsth .= " ORDER BY aqbasket.basketno";
1719     # ## parcelinformation : $strsth
1720     my $sth = $dbh->prepare($strsth);
1721     $sth->execute( @query_params );
1722     while ( my $data = $sth->fetchrow_hashref ) {
1723         push( @results, $data );
1724     }
1725     # ## countparcelbiblio: scalar(@results)
1726     $sth->finish;
1727
1728     return @results;
1729 }
1730
1731 #------------------------------------------------------------#
1732
1733 =head3 GetParcels
1734
1735   $results = &GetParcels($bookseller, $order, $code, $datefrom, $dateto);
1736
1737 get a lists of parcels.
1738
1739 * Input arg :
1740
1741 =over
1742
1743 =item $bookseller
1744 is the bookseller this function has to get parcels.
1745
1746 =item $order
1747 To know on what criteria the results list has to be ordered.
1748
1749 =item $code
1750 is the booksellerinvoicenumber.
1751
1752 =item $datefrom & $dateto
1753 to know on what date this function has to filter its search.
1754
1755 =back
1756
1757 * return:
1758 a pointer on a hash list containing parcel informations as such :
1759
1760 =over
1761
1762 =item Creation date
1763
1764 =item Last operation
1765
1766 =item Number of biblio
1767
1768 =item Number of items
1769
1770 =back
1771
1772 =cut
1773
1774 sub GetParcels {
1775     my ($bookseller,$order, $code, $datefrom, $dateto) = @_;
1776     my $dbh    = C4::Context->dbh;
1777     my @query_params = ();
1778     my $strsth ="
1779         SELECT  aqinvoices.invoicenumber,
1780                 datereceived,purchaseordernumber,
1781                 count(DISTINCT biblionumber) AS biblio,
1782                 sum(quantity) AS itemsexpected,
1783                 sum(quantityreceived) AS itemsreceived
1784         FROM   aqorders LEFT JOIN aqbasket ON aqbasket.basketno = aqorders.basketno
1785         LEFT JOIN aqinvoices ON aqorders.invoiceid = aqinvoices.invoiceid
1786         WHERE aqbasket.booksellerid = ? and datereceived IS NOT NULL
1787     ";
1788     push @query_params, $bookseller;
1789
1790     if ( defined $code ) {
1791         $strsth .= ' and aqinvoices.invoicenumber like ? ';
1792         # add a % to the end of the code to allow stemming.
1793         push @query_params, "$code%";
1794     }
1795
1796     if ( defined $datefrom ) {
1797         $strsth .= ' and datereceived >= ? ';
1798         push @query_params, $datefrom;
1799     }
1800
1801     if ( defined $dateto ) {
1802         $strsth .=  'and datereceived <= ? ';
1803         push @query_params, $dateto;
1804     }
1805
1806     $strsth .= "group by aqinvoices.invoicenumber,datereceived ";
1807
1808     # can't use a placeholder to place this column name.
1809     # but, we could probably be checking to make sure it is a column that will be fetched.
1810     $strsth .= "order by $order " if ($order);
1811
1812     my $sth = $dbh->prepare($strsth);
1813
1814     $sth->execute( @query_params );
1815     my $results = $sth->fetchall_arrayref({});
1816     $sth->finish;
1817     return @$results;
1818 }
1819
1820 #------------------------------------------------------------#
1821
1822 =head3 GetLateOrders
1823
1824   @results = &GetLateOrders;
1825
1826 Searches for bookseller with late orders.
1827
1828 return:
1829 the table of supplier with late issues. This table is full of hashref.
1830
1831 =cut
1832
1833 sub GetLateOrders {
1834     my $delay      = shift;
1835     my $supplierid = shift;
1836     my $branch     = shift;
1837     my $estimateddeliverydatefrom = shift;
1838     my $estimateddeliverydateto = shift;
1839
1840     my $dbh = C4::Context->dbh;
1841
1842     #BEWARE, order of parenthesis and LEFT JOIN is important for speed
1843     my $dbdriver = C4::Context->config("db_scheme") || "mysql";
1844
1845     my @query_params = ();
1846     my $select = "
1847     SELECT aqbasket.basketno,
1848         aqorders.ordernumber,
1849         DATE(aqbasket.closedate)  AS orderdate,
1850         aqorders.rrp              AS unitpricesupplier,
1851         aqorders.ecost            AS unitpricelib,
1852         aqorders.claims_count     AS claims_count,
1853         aqorders.claimed_date     AS claimed_date,
1854         aqbudgets.budget_name     AS budget,
1855         borrowers.branchcode      AS branch,
1856         aqbooksellers.name        AS supplier,
1857         aqbooksellers.id          AS supplierid,
1858         biblio.author, biblio.title,
1859         biblioitems.publishercode AS publisher,
1860         biblioitems.publicationyear,
1861         ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) AS estimateddeliverydate,
1862     ";
1863     my $from = "
1864     FROM
1865         aqorders LEFT JOIN biblio     ON biblio.biblionumber         = aqorders.biblionumber
1866         LEFT JOIN biblioitems         ON biblioitems.biblionumber    = biblio.biblionumber
1867         LEFT JOIN aqbudgets           ON aqorders.budget_id          = aqbudgets.budget_id,
1868         aqbasket LEFT JOIN borrowers  ON aqbasket.authorisedby       = borrowers.borrowernumber
1869         LEFT JOIN aqbooksellers       ON aqbasket.booksellerid       = aqbooksellers.id
1870         WHERE aqorders.basketno = aqbasket.basketno
1871         AND ( datereceived = ''
1872             OR datereceived IS NULL
1873             OR aqorders.quantityreceived < aqorders.quantity
1874         )
1875         AND aqbasket.closedate IS NOT NULL
1876         AND (aqorders.datecancellationprinted IS NULL OR aqorders.datecancellationprinted='0000-00-00')
1877     ";
1878     my $having = "";
1879     if ($dbdriver eq "mysql") {
1880         $select .= "
1881         aqorders.quantity - COALESCE(aqorders.quantityreceived,0)                 AS quantity,
1882         (aqorders.quantity - COALESCE(aqorders.quantityreceived,0)) * aqorders.rrp AS subtotal,
1883         DATEDIFF(CAST(now() AS date),closedate) AS latesince
1884         ";
1885         if ( defined $delay ) {
1886             $from .= " AND (closedate <= DATE_SUB(CAST(now() AS date),INTERVAL ? DAY)) " ;
1887             push @query_params, $delay;
1888         }
1889         $having = "
1890         HAVING quantity          <> 0
1891             AND unitpricesupplier <> 0
1892             AND unitpricelib      <> 0
1893         ";
1894     } else {
1895         # FIXME: account for IFNULL as above
1896         $select .= "
1897                 aqorders.quantity                AS quantity,
1898                 aqorders.quantity * aqorders.rrp AS subtotal,
1899                 (CAST(now() AS date) - closedate)            AS latesince
1900         ";
1901         if ( defined $delay ) {
1902             $from .= " AND (closedate <= (CAST(now() AS date) -(INTERVAL ? DAY)) ";
1903             push @query_params, $delay;
1904         }
1905     }
1906     if (defined $supplierid) {
1907         $from .= ' AND aqbasket.booksellerid = ? ';
1908         push @query_params, $supplierid;
1909     }
1910     if (defined $branch) {
1911         $from .= ' AND borrowers.branchcode LIKE ? ';
1912         push @query_params, $branch;
1913     }
1914
1915     if ( defined $estimateddeliverydatefrom or defined $estimateddeliverydateto ) {
1916         $from .= ' AND aqbooksellers.deliverytime IS NOT NULL ';
1917     }
1918     if ( defined $estimateddeliverydatefrom ) {
1919         $from .= ' AND ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) >= ?';
1920         push @query_params, $estimateddeliverydatefrom;
1921     }
1922     if ( defined $estimateddeliverydateto ) {
1923         $from .= ' AND ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) <= ?';
1924         push @query_params, $estimateddeliverydateto;
1925     }
1926     if ( defined $estimateddeliverydatefrom and not defined $estimateddeliverydateto ) {
1927         $from .= ' AND ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) <= CAST(now() AS date)';
1928     }
1929     if (C4::Context->preference("IndependantBranches")
1930             && C4::Context->userenv
1931             && C4::Context->userenv->{flags} != 1 ) {
1932         $from .= ' AND borrowers.branchcode LIKE ? ';
1933         push @query_params, C4::Context->userenv->{branch};
1934     }
1935     my $query = "$select $from $having\nORDER BY latesince, basketno, borrowers.branchcode, supplier";
1936     $debug and print STDERR "GetLateOrders query: $query\nGetLateOrders args: " . join(" ",@query_params);
1937     my $sth = $dbh->prepare($query);
1938     $sth->execute(@query_params);
1939     my @results;
1940     while (my $data = $sth->fetchrow_hashref) {
1941         $data->{orderdate} = format_date($data->{orderdate});
1942         $data->{claimed_date} = format_date($data->{claimed_date});
1943         push @results, $data;
1944     }
1945     return @results;
1946 }
1947
1948 #------------------------------------------------------------#
1949
1950 =head3 GetHistory
1951
1952   (\@order_loop, $total_qty, $total_price, $total_qtyreceived) = GetHistory( %params );
1953
1954 Retreives some acquisition history information
1955
1956 params:
1957   title
1958   author
1959   name
1960   from_placed_on
1961   to_placed_on
1962   basket                  - search both basket name and number
1963   booksellerinvoicenumber
1964
1965 returns:
1966     $order_loop is a list of hashrefs that each look like this:
1967             {
1968                 'author'           => 'Twain, Mark',
1969                 'basketno'         => '1',
1970                 'biblionumber'     => '215',
1971                 'count'            => 1,
1972                 'creationdate'     => 'MM/DD/YYYY',
1973                 'datereceived'     => undef,
1974                 'ecost'            => '1.00',
1975                 'id'               => '1',
1976                 'invoicenumber'    => undef,
1977                 'name'             => '',
1978                 'ordernumber'      => '1',
1979                 'quantity'         => 1,
1980                 'quantityreceived' => undef,
1981                 'title'            => 'The Adventures of Huckleberry Finn'
1982             }
1983     $total_qty is the sum of all of the quantities in $order_loop
1984     $total_price is the cost of each in $order_loop times the quantity
1985     $total_qtyreceived is the sum of all of the quantityreceived entries in $order_loop
1986
1987 =cut
1988
1989 sub GetHistory {
1990 # don't run the query if there are no parameters (list would be too long for sure !)
1991     croak "No search params" unless @_;
1992     my %params = @_;
1993     my $title = $params{title};
1994     my $author = $params{author};
1995     my $isbn   = $params{isbn};
1996     my $ean    = $params{ean};
1997     my $name = $params{name};
1998     my $from_placed_on = $params{from_placed_on};
1999     my $to_placed_on = $params{to_placed_on};
2000     my $basket = $params{basket};
2001     my $booksellerinvoicenumber = $params{booksellerinvoicenumber};
2002     my $basketgroupname = $params{basketgroupname};
2003     my @order_loop;
2004     my $total_qty         = 0;
2005     my $total_qtyreceived = 0;
2006     my $total_price       = 0;
2007
2008     my $dbh   = C4::Context->dbh;
2009     my $query ="
2010         SELECT
2011             biblio.title,
2012             biblio.author,
2013             biblioitems.isbn,
2014         biblioitems.ean,
2015             aqorders.basketno,
2016             aqbasket.basketname,
2017             aqbasket.basketgroupid,
2018             aqbasketgroups.name as groupname,
2019             aqbooksellers.name,
2020             aqbasket.creationdate,
2021             aqorders.datereceived,
2022             aqorders.quantity,
2023             aqorders.quantityreceived,
2024             aqorders.ecost,
2025             aqorders.ordernumber,
2026             aqorders.invoiceid,
2027             aqinvoices.invoicenumber,
2028             aqbooksellers.id as id,
2029             aqorders.biblionumber
2030         FROM aqorders
2031         LEFT JOIN aqbasket ON aqorders.basketno=aqbasket.basketno
2032         LEFT JOIN aqbasketgroups ON aqbasket.basketgroupid=aqbasketgroups.id
2033         LEFT JOIN aqbooksellers ON aqbasket.booksellerid=aqbooksellers.id
2034         LEFT JOIN biblioitems ON biblioitems.biblionumber=aqorders.biblionumber
2035         LEFT JOIN biblio ON biblio.biblionumber=aqorders.biblionumber
2036     LEFT JOIN aqinvoices ON aqorders.invoiceid = aqinvoices.invoiceid";
2037
2038     $query .= " LEFT JOIN borrowers ON aqbasket.authorisedby=borrowers.borrowernumber"
2039     if ( C4::Context->preference("IndependantBranches") );
2040
2041     $query .= " WHERE (datecancellationprinted is NULL or datecancellationprinted='0000-00-00') ";
2042
2043     my @query_params  = ();
2044
2045     if ( $title ) {
2046         $query .= " AND biblio.title LIKE ? ";
2047         $title =~ s/\s+/%/g;
2048         push @query_params, "%$title%";
2049     }
2050
2051     if ( $author ) {
2052         $query .= " AND biblio.author LIKE ? ";
2053         push @query_params, "%$author%";
2054     }
2055
2056     if ( $isbn ) {
2057         $query .= " AND biblioitems.isbn LIKE ? ";
2058         push @query_params, "%$isbn%";
2059     }
2060     if ( defined $ean and $ean ) {
2061         $query .= " AND biblioitems.ean = ? ";
2062         push @query_params, "$ean";
2063     }
2064     if ( $name ) {
2065         $query .= " AND aqbooksellers.name LIKE ? ";
2066         push @query_params, "%$name%";
2067     }
2068
2069     if ( $from_placed_on ) {
2070         $query .= " AND creationdate >= ? ";
2071         push @query_params, $from_placed_on;
2072     }
2073
2074     if ( $to_placed_on ) {
2075         $query .= " AND creationdate <= ? ";
2076         push @query_params, $to_placed_on;
2077     }
2078
2079     if ($basket) {
2080         if ($basket =~ m/^\d+$/) {
2081             $query .= " AND aqorders.basketno = ? ";
2082             push @query_params, $basket;
2083         } else {
2084             $query .= " AND aqbasket.basketname LIKE ? ";
2085             push @query_params, "%$basket%";
2086         }
2087     }
2088
2089     if ($booksellerinvoicenumber) {
2090         $query .= " AND aqinvoices.invoicenumber LIKE ? ";
2091         push @query_params, "%$booksellerinvoicenumber%";
2092     }
2093
2094     if ($basketgroupname) {
2095         $query .= " AND aqbasketgroups.name LIKE ? ";
2096         push @query_params, "%$basketgroupname%";
2097     }
2098
2099     if ( C4::Context->preference("IndependantBranches") ) {
2100         my $userenv = C4::Context->userenv;
2101         if ( $userenv && ($userenv->{flags} || 0) != 1 ) {
2102             $query .= " AND (borrowers.branchcode = ? OR borrowers.branchcode ='' ) ";
2103             push @query_params, $userenv->{branch};
2104         }
2105     }
2106     $query .= " ORDER BY id";
2107     my $sth = $dbh->prepare($query);
2108     $sth->execute( @query_params );
2109     my $cnt = 1;
2110     while ( my $line = $sth->fetchrow_hashref ) {
2111         $line->{count} = $cnt++;
2112         $line->{toggle} = 1 if $cnt % 2;
2113         push @order_loop, $line;
2114         $total_qty         += $line->{'quantity'};
2115         $total_qtyreceived += $line->{'quantityreceived'};
2116         $total_price       += $line->{'quantity'} * $line->{'ecost'};
2117     }
2118     return \@order_loop, $total_qty, $total_price, $total_qtyreceived;
2119 }
2120
2121 =head2 GetRecentAcqui
2122
2123   $results = GetRecentAcqui($days);
2124
2125 C<$results> is a ref to a table which containts hashref
2126
2127 =cut
2128
2129 sub GetRecentAcqui {
2130     my $limit  = shift;
2131     my $dbh    = C4::Context->dbh;
2132     my $query = "
2133         SELECT *
2134         FROM   biblio
2135         ORDER BY timestamp DESC
2136         LIMIT  0,".$limit;
2137
2138     my $sth = $dbh->prepare($query);
2139     $sth->execute;
2140     my $results = $sth->fetchall_arrayref({});
2141     return $results;
2142 }
2143
2144 =head3 GetContracts
2145
2146   $contractlist = &GetContracts($booksellerid, $activeonly);
2147
2148 Looks up the contracts that belong to a bookseller
2149
2150 Returns a list of contracts
2151
2152 =over
2153
2154 =item C<$booksellerid> is the "id" field in the "aqbooksellers" table.
2155
2156 =item C<$activeonly> if exists get only contracts that are still active.
2157
2158 =back
2159
2160 =cut
2161
2162 sub GetContracts {
2163     my ( $booksellerid, $activeonly ) = @_;
2164     my $dbh = C4::Context->dbh;
2165     my $query;
2166     if (! $activeonly) {
2167         $query = "
2168             SELECT *
2169             FROM   aqcontract
2170             WHERE  booksellerid=?
2171         ";
2172     } else {
2173         $query = "SELECT *
2174             FROM aqcontract
2175             WHERE booksellerid=?
2176                 AND contractenddate >= CURDATE( )";
2177     }
2178     my $sth = $dbh->prepare($query);
2179     $sth->execute( $booksellerid );
2180     my @results;
2181     while (my $data = $sth->fetchrow_hashref ) {
2182         push(@results, $data);
2183     }
2184     $sth->finish;
2185     return @results;
2186 }
2187
2188 #------------------------------------------------------------#
2189
2190 =head3 GetContract
2191
2192   $contract = &GetContract($contractID);
2193
2194 Looks up the contract that has PRIMKEY (contractnumber) value $contractID
2195
2196 Returns a contract
2197
2198 =cut
2199
2200 sub GetContract {
2201     my ( $contractno ) = @_;
2202     my $dbh = C4::Context->dbh;
2203     my $query = "
2204         SELECT *
2205         FROM   aqcontract
2206         WHERE  contractnumber=?
2207         ";
2208
2209     my $sth = $dbh->prepare($query);
2210     $sth->execute( $contractno );
2211     my $result = $sth->fetchrow_hashref;
2212     return $result;
2213 }
2214
2215 =head3 AddClaim
2216
2217 =over 4
2218
2219 &AddClaim($ordernumber);
2220
2221 Add a claim for an order
2222
2223 =back
2224
2225 =cut
2226 sub AddClaim {
2227     my ($ordernumber) = @_;
2228     my $dbh          = C4::Context->dbh;
2229     my $query        = "
2230         UPDATE aqorders SET
2231             claims_count = claims_count + 1,
2232             claimed_date = CURDATE()
2233         WHERE ordernumber = ?
2234         ";
2235     my $sth = $dbh->prepare($query);
2236     $sth->execute($ordernumber);
2237 }
2238
2239 =head3 GetInvoices
2240
2241     my @invoices = GetInvoices(
2242         invoicenumber => $invoicenumber,
2243         suppliername => $suppliername,
2244         shipmentdatefrom => $shipmentdatefrom, # ISO format
2245         shipmentdateto => $shipmentdateto, # ISO format
2246         billingdatefrom => $billingdatefrom, # ISO format
2247         billingdateto => $billingdateto, # ISO format
2248         isbneanissn => $isbn_or_ean_or_issn,
2249         title => $title,
2250         author => $author,
2251         publisher => $publisher,
2252         publicationyear => $publicationyear,
2253         branchcode => $branchcode,
2254         order_by => $order_by
2255     );
2256
2257 Return a list of invoices that match all given criteria.
2258
2259 $order_by is "column_name (asc|desc)", where column_name is any of
2260 'invoicenumber', 'booksellerid', 'shipmentdate', 'billingdate', 'closedate',
2261 'shipmentcost', 'shipmentcost_budgetid'.
2262
2263 asc is the default if omitted
2264
2265 =cut
2266
2267 sub GetInvoices {
2268     my %args = @_;
2269
2270     my @columns = qw(invoicenumber booksellerid shipmentdate billingdate
2271         closedate shipmentcost shipmentcost_budgetid);
2272
2273     my $dbh = C4::Context->dbh;
2274     my $query = qq{
2275         SELECT aqinvoices.*, aqbooksellers.name AS suppliername,
2276           COUNT(
2277             DISTINCT IF(
2278               aqorders.datereceived IS NOT NULL,
2279               aqorders.biblionumber,
2280               NULL
2281             )
2282           ) AS receivedbiblios,
2283           SUM(aqorders.quantityreceived) AS receiveditems
2284         FROM aqinvoices
2285           LEFT JOIN aqbooksellers ON aqbooksellers.id = aqinvoices.booksellerid
2286           LEFT JOIN aqorders ON aqorders.invoiceid = aqinvoices.invoiceid
2287           LEFT JOIN biblio ON aqorders.biblionumber = biblio.biblionumber
2288           LEFT JOIN biblioitems ON biblio.biblionumber = biblioitems.biblionumber
2289           LEFT JOIN subscription ON biblio.biblionumber = subscription.biblionumber
2290     };
2291
2292     my @bind_args;
2293     my @bind_strs;
2294     if($args{supplierid}) {
2295         push @bind_strs, " aqinvoices.booksellerid = ? ";
2296         push @bind_args, $args{supplierid};
2297     }
2298     if($args{invoicenumber}) {
2299         push @bind_strs, " aqinvoices.invoicenumber LIKE ? ";
2300         push @bind_args, "%$args{invoicenumber}%";
2301     }
2302     if($args{suppliername}) {
2303         push @bind_strs, " aqbooksellers.name LIKE ? ";
2304         push @bind_args, "%$args{suppliername}%";
2305     }
2306     if($args{shipmentdatefrom}) {
2307         push @bind_strs, " aqinvoices.shipementdate >= ? ";
2308         push @bind_args, $args{shipmentdatefrom};
2309     }
2310     if($args{shipmentdateto}) {
2311         push @bind_strs, " aqinvoices.shipementdate <= ? ";
2312         push @bind_args, $args{shipmentdateto};
2313     }
2314     if($args{billingdatefrom}) {
2315         push @bind_strs, " aqinvoices.billingdate >= ? ";
2316         push @bind_args, $args{billingdatefrom};
2317     }
2318     if($args{billingdateto}) {
2319         push @bind_strs, " aqinvoices.billingdate <= ? ";
2320         push @bind_args, $args{billingdateto};
2321     }
2322     if($args{isbneanissn}) {
2323         push @bind_strs, " (biblioitems.isbn LIKE ? OR biblioitems.ean LIKE ? OR biblioitems.issn LIKE ? ) ";
2324         push @bind_args, $args{isbneanissn}, $args{isbneanissn}, $args{isbneanissn};
2325     }
2326     if($args{title}) {
2327         push @bind_strs, " biblio.title LIKE ? ";
2328         push @bind_args, $args{title};
2329     }
2330     if($args{author}) {
2331         push @bind_strs, " biblio.author LIKE ? ";
2332         push @bind_args, $args{author};
2333     }
2334     if($args{publisher}) {
2335         push @bind_strs, " biblioitems.publishercode LIKE ? ";
2336         push @bind_args, $args{publisher};
2337     }
2338     if($args{publicationyear}) {
2339         push @bind_strs, " biblioitems.publicationyear = ? ";
2340         push @bind_args, $args{publicationyear};
2341     }
2342     if($args{branchcode}) {
2343         push @bind_strs, " aqorders.branchcode = ? ";
2344         push @bind_args, $args{branchcode};
2345     }
2346
2347     $query .= " WHERE " . join(" AND ", @bind_strs) if @bind_strs;
2348     $query .= " GROUP BY aqinvoices.invoiceid ";
2349
2350     if($args{order_by}) {
2351         my ($column, $direction) = split / /, $args{order_by};
2352         if(grep /^$column$/, @columns) {
2353             $direction ||= 'ASC';
2354             $query .= " ORDER BY $column $direction";
2355         }
2356     }
2357
2358     my $sth = $dbh->prepare($query);
2359     $sth->execute(@bind_args);
2360
2361     my $results = $sth->fetchall_arrayref({});
2362     return @$results;
2363 }
2364
2365 =head3 GetInvoice
2366
2367     my $invoice = GetInvoice($invoiceid);
2368
2369 Get informations about invoice with given $invoiceid
2370
2371 Return a hash filled with aqinvoices.* fields
2372
2373 =cut
2374
2375 sub GetInvoice {
2376     my ($invoiceid) = @_;
2377     my $invoice;
2378
2379     return unless $invoiceid;
2380
2381     my $dbh = C4::Context->dbh;
2382     my $query = qq{
2383         SELECT *
2384         FROM aqinvoices
2385         WHERE invoiceid = ?
2386     };
2387     my $sth = $dbh->prepare($query);
2388     $sth->execute($invoiceid);
2389
2390     $invoice = $sth->fetchrow_hashref;
2391     return $invoice;
2392 }
2393
2394 =head3 GetInvoiceDetails
2395
2396     my $invoice = GetInvoiceDetails($invoiceid)
2397
2398 Return informations about an invoice + the list of related order lines
2399
2400 Orders informations are in $invoice->{orders} (array ref)
2401
2402 =cut
2403
2404 sub GetInvoiceDetails {
2405     my ($invoiceid) = @_;
2406
2407     if ( !defined $invoiceid ) {
2408         carp 'GetInvoiceDetails called without an invoiceid';
2409         return;
2410     }
2411
2412     my $dbh = C4::Context->dbh;
2413     my $query = qq{
2414         SELECT aqinvoices.*, aqbooksellers.name AS suppliername
2415         FROM aqinvoices
2416           LEFT JOIN aqbooksellers ON aqinvoices.booksellerid = aqbooksellers.id
2417         WHERE invoiceid = ?
2418     };
2419     my $sth = $dbh->prepare($query);
2420     $sth->execute($invoiceid);
2421
2422     my $invoice = $sth->fetchrow_hashref;
2423
2424     $query = qq{
2425         SELECT aqorders.*, biblio.*
2426         FROM aqorders
2427           LEFT JOIN biblio ON aqorders.biblionumber = biblio.biblionumber
2428         WHERE invoiceid = ?
2429     };
2430     $sth = $dbh->prepare($query);
2431     $sth->execute($invoiceid);
2432     $invoice->{orders} = $sth->fetchall_arrayref({});
2433     $invoice->{orders} ||= []; # force an empty arrayref if fetchall_arrayref fails
2434
2435     return $invoice;
2436 }
2437
2438 =head3 AddInvoice
2439
2440     my $invoiceid = AddInvoice(
2441         invoicenumber => $invoicenumber,
2442         booksellerid => $booksellerid,
2443         shipmentdate => $shipmentdate,
2444         billingdate => $billingdate,
2445         closedate => $closedate,
2446         shipmentcost => $shipmentcost,
2447         shipmentcost_budgetid => $shipmentcost_budgetid
2448     );
2449
2450 Create a new invoice and return its id or undef if it fails.
2451
2452 =cut
2453
2454 sub AddInvoice {
2455     my %invoice = @_;
2456
2457     return unless(%invoice and $invoice{invoicenumber});
2458
2459     my @columns = qw(invoicenumber booksellerid shipmentdate billingdate
2460         closedate shipmentcost shipmentcost_budgetid);
2461
2462     my @set_strs;
2463     my @set_args;
2464     foreach my $key (keys %invoice) {
2465         if(0 < grep(/^$key$/, @columns)) {
2466             push @set_strs, "$key = ?";
2467             push @set_args, ($invoice{$key} || undef);
2468         }
2469     }
2470
2471     my $rv;
2472     if(@set_args > 0) {
2473         my $dbh = C4::Context->dbh;
2474         my $query = "INSERT INTO aqinvoices SET ";
2475         $query .= join (",", @set_strs);
2476         my $sth = $dbh->prepare($query);
2477         $rv = $sth->execute(@set_args);
2478         if($rv) {
2479             $rv = $dbh->last_insert_id(undef, undef, 'aqinvoices', undef);
2480         }
2481     }
2482     return $rv;
2483 }
2484
2485 =head3 ModInvoice
2486
2487     ModInvoice(
2488         invoiceid => $invoiceid,    # Mandatory
2489         invoicenumber => $invoicenumber,
2490         booksellerid => $booksellerid,
2491         shipmentdate => $shipmentdate,
2492         billingdate => $billingdate,
2493         closedate => $closedate,
2494         shipmentcost => $shipmentcost,
2495         shipmentcost_budgetid => $shipmentcost_budgetid
2496     );
2497
2498 Modify an invoice, invoiceid is mandatory.
2499
2500 Return undef if it fails.
2501
2502 =cut
2503
2504 sub ModInvoice {
2505     my %invoice = @_;
2506
2507     return unless(%invoice and $invoice{invoiceid});
2508
2509     my @columns = qw(invoicenumber booksellerid shipmentdate billingdate
2510         closedate shipmentcost shipmentcost_budgetid);
2511
2512     my @set_strs;
2513     my @set_args;
2514     foreach my $key (keys %invoice) {
2515         if(0 < grep(/^$key$/, @columns)) {
2516             push @set_strs, "$key = ?";
2517             push @set_args, ($invoice{$key} || undef);
2518         }
2519     }
2520
2521     my $dbh = C4::Context->dbh;
2522     my $query = "UPDATE aqinvoices SET ";
2523     $query .= join(",", @set_strs);
2524     $query .= " WHERE invoiceid = ?";
2525
2526     my $sth = $dbh->prepare($query);
2527     $sth->execute(@set_args, $invoice{invoiceid});
2528 }
2529
2530 =head3 CloseInvoice
2531
2532     CloseInvoice($invoiceid);
2533
2534 Close an invoice.
2535
2536 Equivalent to ModInvoice(invoiceid => $invoiceid, closedate => undef);
2537
2538 =cut
2539
2540 sub CloseInvoice {
2541     my ($invoiceid) = @_;
2542
2543     return unless $invoiceid;
2544
2545     my $dbh = C4::Context->dbh;
2546     my $query = qq{
2547         UPDATE aqinvoices
2548         SET closedate = CAST(NOW() AS DATE)
2549         WHERE invoiceid = ?
2550     };
2551     my $sth = $dbh->prepare($query);
2552     $sth->execute($invoiceid);
2553 }
2554
2555 =head3 ReopenInvoice
2556
2557     ReopenInvoice($invoiceid);
2558
2559 Reopen an invoice
2560
2561 Equivalent to ModInvoice(invoiceid => $invoiceid, closedate => C4::Dates->new()->output('iso'))
2562
2563 =cut
2564
2565 sub ReopenInvoice {
2566     my ($invoiceid) = @_;
2567
2568     return unless $invoiceid;
2569
2570     my $dbh = C4::Context->dbh;
2571     my $query = qq{
2572         UPDATE aqinvoices
2573         SET closedate = NULL
2574         WHERE invoiceid = ?
2575     };
2576     my $sth = $dbh->prepare($query);
2577     $sth->execute($invoiceid);
2578 }
2579
2580 1;
2581 __END__
2582
2583 =head1 AUTHOR
2584
2585 Koha Development Team <http://koha-community.org/>
2586
2587 =cut