C4/Auth.pm

   1 package C4::Auth;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22 use Carp qw( croak );
  23
  24 use Digest::MD5 qw( md5_base64 );
  25 use CGI::Session;
  26 use CGI::Session::ErrorHandler;
  27 use URI;
  28 use URI::QueryParam;
  29
  30 use C4::Context;
  31 use C4::Templates;    # to get the template
  32 use C4::Languages;
  33 use C4::Search::History;
  34 use Koha;
  35 use Koha::Logger;
  36 use Koha::Caches;
  37 use Koha::AuthUtils qw( get_script_name hash_password );
  38 use Koha::Auth::TwoFactorAuth;
  39 use Koha::Checkouts;
  40 use Koha::DateUtils qw( dt_from_string );
  41 use Koha::Library::Groups;
  42 use Koha::Libraries;
  43 use Koha::Cash::Registers;
  44 use Koha::Desks;
  45 use Koha::Patrons;
  46 use Koha::Patron::Consents;
  47 use List::MoreUtils qw( any );
  48 use Encode;
  49 use C4::Auth_with_shibboleth qw( shib_ok get_login_shib login_shib_url logout_shib checkpw_shib );
  50 use Net::CIDR;
  51 use C4::Log qw( logaction );
  52 use Koha::CookieManager;
  53
  54 # use utf8;
  55
  56 use vars qw($ldap $cas $caslogout);
  57 our (@ISA, @EXPORT_OK);
  58 BEGIN {
  59     sub psgi_env { any { /^psgi\./ } keys %ENV }
  60
  61     sub safe_exit {
  62         if   (psgi_env) { die 'psgi:exit' }
  63         else            { exit }
  64     }
  65
  66     C4::Context->set_remote_address;
  67
  68     require Exporter;
  69     @ISA = qw(Exporter);
  70
  71     @EXPORT_OK = qw(
  72       checkauth check_api_auth get_session check_cookie_auth checkpw checkpw_internal checkpw_hash
  73       get_all_subpermissions get_user_subpermissions track_login_daily in_iprange
  74       get_template_and_user haspermission
  75     );
  76
  77     $ldap      = C4::Context->config('useldapserver') || 0;
  78     $cas       = C4::Context->preference('casAuthentication');
  79     $caslogout = C4::Context->preference('casLogout');
  80
  81     if ($ldap) {
  82         require C4::Auth_with_ldap;
  83         import C4::Auth_with_ldap qw(checkpw_ldap);
  84     }
  85     if ($cas) {
  86         require C4::Auth_with_cas;    # no import
  87         import C4::Auth_with_cas qw(check_api_auth_cas checkpw_cas login_cas logout_cas login_cas_url logout_if_required multipleAuth getMultipleAuth);
  88     }
  89
  90 }
  91
  92 =head1 NAME
  93
  94 C4::Auth - Authenticates Koha users
  95
  96 =head1 SYNOPSIS
  97
  98   use CGI qw ( -utf8 );
  99   use C4::Auth;
 100   use C4::Output;
 101
 102   my $query = CGI->new;
 103
 104   my ($template, $borrowernumber, $cookie)
 105     = get_template_and_user(
 106         {
 107             template_name   => "opac-main.tt",
 108             query           => $query,
 109       type            => "opac",
 110       authnotrequired => 0,
 111       flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 112   }
 113     );
 114
 115   output_html_with_http_headers $query, $cookie, $template->output;
 116
 117 =head1 DESCRIPTION
 118
 119 The main function of this module is to provide
 120 authentification. However the get_template_and_user function has
 121 been provided so that a users login information is passed along
 122 automatically. This gets loaded into the template.
 123
 124 =head1 FUNCTIONS
 125
 126 =head2 get_template_and_user
 127
 128  my ($template, $borrowernumber, $cookie)
 129      = get_template_and_user(
 130        {
 131          template_name   => "opac-main.tt",
 132          query           => $query,
 133          type            => "opac",
 134          authnotrequired => 0,
 135          flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 136        }
 137      );
 138
 139 This call passes the C<query>, C<flagsrequired> and C<authnotrequired>
 140 to C<&checkauth> (in this module) to perform authentification.
 141 See C<&checkauth> for an explanation of these parameters.
 142
 143 The C<template_name> is then used to find the correct template for
 144 the page. The authenticated users details are loaded onto the
 145 template in the logged_in_user variable (which is a Koha::Patron object). Also the
 146 C<sessionID> is passed to the template. This can be used in templates
 147 if cookies are disabled. It needs to be put as and input to every
 148 authenticated page.
 149
 150 More information on the C<gettemplate> sub can be found in the
 151 Output.pm module.
 152
 153 =cut
 154
 155 sub get_template_and_user {
 156
 157     my $in = shift;
 158     my ( $user, $cookie, $sessionID, $flags );
 159     $cookie = [];
 160
 161     my $cookie_mgr = Koha::CookieManager->new;
 162
 163     # Get shibboleth login attribute
 164     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 165     my $shib_login = $shib ? get_login_shib() : undef;
 166
 167     C4::Context->interface( $in->{type} );
 168
 169     $in->{'authnotrequired'} ||= 0;
 170
 171     # the following call includes a bad template check; might croak
 172     my $template = C4::Templates::gettemplate(
 173         $in->{'template_name'},
 174         $in->{'type'},
 175         $in->{'query'},
 176     );
 177
 178     if ( $in->{'template_name'} !~ m/maintenance/ ) {
 179         ( $user, $cookie, $sessionID, $flags ) = checkauth(
 180             $in->{'query'},
 181             $in->{'authnotrequired'},
 182             $in->{'flagsrequired'},
 183             $in->{'type'},
 184             undef,
 185             $in->{template_name},
 186         );
 187     }
 188
 189     # If we enforce GDPR and the user did not consent, redirect
 190     # Exceptions for consent page itself and SCI/SCO system
 191     if( $in->{type} eq 'opac' && $user &&
 192         $in->{'template_name'} !~ /^(opac-patron-consent|sc[io]\/)/ &&
 193         C4::Context->preference('GDPR_Policy') eq 'Enforced' )
 194     {
 195         my $consent = Koha::Patron::Consents->search({
 196             borrowernumber => getborrowernumber($user),
 197             type => 'GDPR_PROCESSING',
 198             given_on => { '!=', undef },
 199         })->next;
 200         if( !$consent ) {
 201             print $in->{query}->redirect(-uri => '/cgi-bin/koha/opac-patron-consent.pl', -cookie => $cookie);
 202             safe_exit;
 203         }
 204     }
 205
 206     if ( $in->{type} eq 'opac' && $user ) {
 207         my $is_sco_user;
 208         if ($sessionID){
 209             my $session = get_session($sessionID);
 210             if ($session){
 211                 $is_sco_user = $session->param('sco_user');
 212             }
 213         }
 214         my $kick_out;
 215
 216         if (
 217 # If the user logged in is the SCO user and they try to go out of the SCO module,
 218 # log the user out removing the CGISESSID cookie
 219             $in->{template_name} !~ m|sco/| && $in->{template_name} !~ m|errors/errorpage.tt|
 220             && (
 221                 $is_sco_user ||
 222                 (
 223                     C4::Context->preference('AutoSelfCheckID')
 224                     && $user eq C4::Context->preference('AutoSelfCheckID')
 225                 )
 226             )
 227           )
 228         {
 229             $kick_out = 1;
 230         }
 231         elsif (
 232 # If the user logged in is the SCI user and they try to go out of the SCI module,
 233 # kick them out unless it is SCO with a valid permission
 234 # or they are a superlibrarian
 235                $in->{template_name} !~ m|sci/|
 236             && haspermission( $user, { self_check => 'self_checkin_module' } )
 237             && !(
 238                 $in->{template_name} =~ m|sco/| && haspermission(
 239                     $user, { self_check => 'self_checkout_module' }
 240                 )
 241             )
 242             && $flags && $flags->{superlibrarian} != 1
 243           )
 244         {
 245             $kick_out = 1;
 246         }
 247
 248         if ($kick_out) {
 249             $template = C4::Templates::gettemplate( 'opac-auth.tt', 'opac',
 250                 $in->{query} );
 251             $cookie = $cookie_mgr->replace_in_list( $cookie, $in->{query}->cookie(
 252                 -name     => 'CGISESSID',
 253                 -value    => '',
 254                 -HttpOnly => 1,
 255                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 256                 -sameSite => 'Lax',
 257             ));
 258
 259             $template->param(
 260                 loginprompt => 1,
 261                 script_name => get_script_name(),
 262             );
 263
 264             print $in->{query}->header(
 265                 {
 266                     type              => 'text/html',
 267                     charset           => 'utf-8',
 268                     cookie            => $cookie,
 269                     'X-Frame-Options' => 'SAMEORIGIN'
 270                 }
 271               ),
 272               $template->output;
 273             safe_exit;
 274         }
 275     }
 276
 277     my $borrowernumber;
 278     if ($user) {
 279
 280         # It's possible for $user to be the borrowernumber if they don't have a
 281         # userid defined (and are logging in through some other method, such
 282         # as SSL certs against an email address)
 283         my $patron;
 284         $borrowernumber = getborrowernumber($user) if defined($user);
 285         if ( !defined($borrowernumber) && defined($user) ) {
 286             $patron = Koha::Patrons->find( $user );
 287             if ($patron) {
 288                 $borrowernumber = $user;
 289
 290                 # A bit of a hack, but I don't know there's a nicer way
 291                 # to do it.
 292                 $user = $patron->firstname . ' ' . $patron->surname;
 293             }
 294         } else {
 295             $patron = Koha::Patrons->find( $borrowernumber );
 296             # FIXME What to do if $patron does not exist?
 297         }
 298
 299         # user info
 300         $template->param( loggedinusername   => $user ); # OBSOLETE - Do not reuse this in template, use logged_in_user.userid instead
 301         $template->param( loggedinusernumber => $borrowernumber ); # FIXME Should be replaced with logged_in_user.borrowernumber
 302         $template->param( logged_in_user     => $patron );
 303         $template->param( sessionID          => $sessionID );
 304
 305         if ( $in->{'type'} eq 'opac' ) {
 306             require Koha::Virtualshelves;
 307             my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 308                 {
 309                     borrowernumber => $borrowernumber,
 310                     public         => 0,
 311                 }
 312             );
 313             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 314                 {
 315                     public => 1,
 316                 }
 317             );
 318             $template->param(
 319                 some_private_shelves => $some_private_shelves,
 320                 some_public_shelves  => $some_public_shelves,
 321             );
 322         }
 323
 324         my $all_perms = get_all_subpermissions();
 325
 326         my @flagroots = qw(circulate catalogue parameters borrowers permissions reserveforothers borrow
 327           editcatalogue updatecharges tools editauthorities serials reports acquisition clubs problem_reports);
 328
 329         # We are going to use the $flags returned by checkauth
 330         # to create the template's parameters that will indicate
 331         # which menus the user can access.
 332         if ( $flags && $flags->{superlibrarian} == 1 ) {
 333             $template->param( CAN_user_circulate        => 1 );
 334             $template->param( CAN_user_catalogue        => 1 );
 335             $template->param( CAN_user_parameters       => 1 );
 336             $template->param( CAN_user_borrowers        => 1 );
 337             $template->param( CAN_user_permissions      => 1 );
 338             $template->param( CAN_user_reserveforothers => 1 );
 339             $template->param( CAN_user_editcatalogue    => 1 );
 340             $template->param( CAN_user_updatecharges    => 1 );
 341             $template->param( CAN_user_acquisition      => 1 );
 342             $template->param( CAN_user_suggestions      => 1 );
 343             $template->param( CAN_user_tools            => 1 );
 344             $template->param( CAN_user_editauthorities  => 1 );
 345             $template->param( CAN_user_serials          => 1 );
 346             $template->param( CAN_user_reports          => 1 );
 347             $template->param( CAN_user_staffaccess      => 1 );
 348             $template->param( CAN_user_coursereserves   => 1 );
 349             $template->param( CAN_user_plugins          => 1 );
 350             $template->param( CAN_user_lists            => 1 );
 351             $template->param( CAN_user_clubs            => 1 );
 352             $template->param( CAN_user_ill              => 1 );
 353             $template->param( CAN_user_stockrotation    => 1 );
 354             $template->param( CAN_user_cash_management  => 1 );
 355             $template->param( CAN_user_problem_reports  => 1 );
 356             $template->param( CAN_user_recalls          => 1 );
 357
 358             foreach my $module ( keys %$all_perms ) {
 359                 foreach my $subperm ( keys %{ $all_perms->{$module} } ) {
 360                     $template->param( "CAN_user_${module}_${subperm}" => 1 );
 361                 }
 362             }
 363         }
 364
 365         if ($flags) {
 366             foreach my $module ( keys %$all_perms ) {
 367                 if ( defined($flags->{$module}) && $flags->{$module} == 1 ) {
 368                     foreach my $subperm ( keys %{ $all_perms->{$module} } ) {
 369                         $template->param( "CAN_user_${module}_${subperm}" => 1 );
 370                     }
 371                 } elsif ( ref( $flags->{$module} ) ) {
 372                     foreach my $subperm ( keys %{ $flags->{$module} } ) {
 373                         $template->param( "CAN_user_${module}_${subperm}" => 1 );
 374                     }
 375                 }
 376             }
 377         }
 378
 379         if ($flags) {
 380             foreach my $module ( keys %$flags ) {
 381                 if ( $flags->{$module} == 1 or ref( $flags->{$module} ) ) {
 382                     $template->param( "CAN_user_$module" => 1 );
 383                 }
 384             }
 385         }
 386
 387         # Logged-in opac search history
 388         # If the requested template is an opac one and opac search history is enabled
 389         if ( $in->{type} eq 'opac' && C4::Context->preference('EnableOpacSearchHistory') ) {
 390             my $dbh   = C4::Context->dbh;
 391             my $query = "SELECT COUNT(*) FROM search_history WHERE userid=?";
 392             my $sth   = $dbh->prepare($query);
 393             $sth->execute($borrowernumber);
 394
 395             # If at least one search has already been performed
 396             if ( $sth->fetchrow_array > 0 ) {
 397
 398                 # We show the link in opac
 399                 $template->param( EnableOpacSearchHistory => 1 );
 400             }
 401             if (C4::Context->preference('LoadSearchHistoryToTheFirstLoggedUser'))
 402             {
 403                 # And if there are searches performed when the user was not logged in,
 404                 # we add them to the logged-in search history
 405                 my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 406                 if (@recentSearches) {
 407                     my $dbh   = C4::Context->dbh;
 408                     my $query = q{
 409                         INSERT INTO search_history(userid, sessionid, query_desc, query_cgi, type,  total, time )
 410                         VALUES (?, ?, ?, ?, ?, ?, ?)
 411                     };
 412                     my $sth = $dbh->prepare($query);
 413                     $sth->execute( $borrowernumber,
 414                         $in->{query}->cookie("CGISESSID"),
 415                         $_->{query_desc},
 416                         $_->{query_cgi},
 417                         $_->{type} || 'biblio',
 418                         $_->{total},
 419                         $_->{time},
 420                     ) foreach @recentSearches;
 421
 422                     # clear out the search history from the session now that
 423                     # we've saved it to the database
 424                  }
 425               }
 426               C4::Search::History::set_to_session( { cgi => $in->{'query'}, search_history => [] } );
 427
 428         } elsif ( $in->{type} eq 'intranet' and C4::Context->preference('EnableSearchHistory') ) {
 429             $template->param( EnableSearchHistory => 1 );
 430         }
 431     }
 432     else {    # if this is an anonymous session, setup to display public lists...
 433
 434         # If shibboleth is enabled, and we're in an anonymous session, we should allow
 435         # the user to attempt login via shibboleth.
 436         if ($shib) {
 437             $template->param( shibbolethAuthentication => $shib,
 438                 shibbolethLoginUrl => login_shib_url( $in->{'query'} ),
 439             );
 440
 441             # If shibboleth is enabled and we have a shibboleth login attribute,
 442             # but we are in an anonymous session, then we clearly have an invalid
 443             # shibboleth koha account.
 444             if ($shib_login) {
 445                 $template->param( invalidShibLogin => '1' );
 446             }
 447         }
 448
 449         $template->param( sessionID => $sessionID );
 450
 451         if ( $in->{'type'} eq 'opac' ){
 452             require Koha::Virtualshelves;
 453             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 454                 {
 455                     public => 1,
 456                 }
 457             );
 458             $template->param(
 459                 some_public_shelves  => $some_public_shelves,
 460             );
 461
 462             # Set default branch if one has been passed by the environment.
 463             $template->param( default_branch => $ENV{OPAC_BRANCH_DEFAULT} ) if $ENV{OPAC_BRANCH_DEFAULT};
 464         }
 465     }
 466
 467     # Sysprefs disabled via URL param
 468     # Note that value must be defined in order to override via ENV
 469     foreach my $syspref (
 470         qw(
 471             OPACUserCSS
 472             OPACUserJS
 473             IntranetUserCSS
 474             IntranetUserJS
 475             OpacAdditionalStylesheet
 476             opaclayoutstylesheet
 477             intranetcolorstylesheet
 478             intranetstylesheet
 479         )
 480       )
 481     {
 482         $ENV{"OVERRIDE_SYSPREF_$syspref"} = q{}
 483           if $in->{'query'}->param("DISABLE_SYSPREF_$syspref");
 484     }
 485
 486     # Anonymous opac search history
 487     # If opac search history is enabled and at least one search has already been performed
 488     if ( C4::Context->preference('EnableOpacSearchHistory') ) {
 489         my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 490         if (@recentSearches) {
 491             $template->param( EnableOpacSearchHistory => 1 );
 492         }
 493     }
 494
 495     if ( C4::Context->preference('dateformat') ) {
 496         $template->param( dateformat => C4::Context->preference('dateformat') );
 497     }
 498
 499     $template->param(auth_forwarded_hash => scalar $in->{'query'}->param('auth_forwarded_hash'));
 500
 501     # these template parameters are set the same regardless of $in->{'type'}
 502
 503     my $minPasswordLength = C4::Context->preference('minPasswordLength');
 504     $minPasswordLength = 3 if not $minPasswordLength or $minPasswordLength < 3;
 505     $template->param(
 506         EnhancedMessagingPreferences                                       => C4::Context->preference('EnhancedMessagingPreferences'),
 507         GoogleJackets                                                      => C4::Context->preference("GoogleJackets"),
 508         OpenLibraryCovers                                                  => C4::Context->preference("OpenLibraryCovers"),
 509         KohaAdminEmailAddress                                              => "" . C4::Context->preference("KohaAdminEmailAddress"),
 510         LoginFirstname  => ( C4::Context->userenv ? C4::Context->userenv->{"firstname"} : "Bel" ),
 511         LoginSurname    => C4::Context->userenv ? C4::Context->userenv->{"surname"}      : "Inconnu",
 512         emailaddress    => C4::Context->userenv ? C4::Context->userenv->{"emailaddress"} : undef,
 513         TagsEnabled     => C4::Context->preference("TagsEnabled"),
 514         hide_marc       => C4::Context->preference("hide_marc"),
 515         item_level_itypes  => C4::Context->preference('item-level_itypes'),
 516         patronimages       => C4::Context->preference("patronimages"),
 517         singleBranchMode   => ( Koha::Libraries->search->count == 1 ),
 518         noItemTypeImages   => C4::Context->preference("noItemTypeImages"),
 519         marcflavour        => C4::Context->preference("marcflavour"),
 520         OPACBaseURL        => C4::Context->preference('OPACBaseURL'),
 521         minPasswordLength  => $minPasswordLength,
 522     );
 523     if ( $in->{'type'} eq "intranet" ) {
 524         $template->param(
 525             AmazonCoverImages                                                          => C4::Context->preference("AmazonCoverImages"),
 526             AutoLocation                                                               => C4::Context->preference("AutoLocation"),
 527             PatronAutoComplete                                                       => C4::Context->preference("PatronAutoComplete"),
 528             FRBRizeEditions                                                            => C4::Context->preference("FRBRizeEditions"),
 529             IndependentBranches                                                        => C4::Context->preference("IndependentBranches"),
 530             IntranetNav                                                                => C4::Context->preference("IntranetNav"),
 531             IntranetmainUserblock                                                      => C4::Context->preference("IntranetmainUserblock"),
 532             LibraryName                                                                => C4::Context->preference("LibraryName"),
 533             advancedMARCEditor                                                         => C4::Context->preference("advancedMARCEditor"),
 534             canreservefromotherbranches                                                => C4::Context->preference('canreservefromotherbranches'),
 535             intranetcolorstylesheet                                                    => C4::Context->preference("intranetcolorstylesheet"),
 536             IntranetFavicon                                                            => C4::Context->preference("IntranetFavicon"),
 537             intranetreadinghistory                                                     => C4::Context->preference("intranetreadinghistory"),
 538             intranetstylesheet                                                         => C4::Context->preference("intranetstylesheet"),
 539             IntranetUserCSS                                                            => C4::Context->preference("IntranetUserCSS"),
 540             IntranetUserJS                                                             => C4::Context->preference("IntranetUserJS"),
 541             suggestion                                                                 => C4::Context->preference("suggestion"),
 542             virtualshelves                                                             => C4::Context->preference("virtualshelves"),
 543             StaffSerialIssueDisplayCount                                               => C4::Context->preference("StaffSerialIssueDisplayCount"),
 544             EasyAnalyticalRecords                                                      => C4::Context->preference('EasyAnalyticalRecords'),
 545             LocalCoverImages                                                           => C4::Context->preference('LocalCoverImages'),
 546             OPACLocalCoverImages                                                       => C4::Context->preference('OPACLocalCoverImages'),
 547             AllowMultipleCovers                                                        => C4::Context->preference('AllowMultipleCovers'),
 548             EnableBorrowerFiles                                                        => C4::Context->preference('EnableBorrowerFiles'),
 549             UseCourseReserves                                                          => C4::Context->preference("UseCourseReserves"),
 550             useDischarge                                                               => C4::Context->preference('useDischarge'),
 551             pending_checkout_notes                                                     => Koha::Checkouts->search({ noteseen => 0 }),
 552         );
 553     }
 554     else {
 555         warn "template type should be OPAC, here it is=[" . $in->{'type'} . "]" unless ( $in->{'type'} eq 'opac' );
 556
 557         #TODO : replace LibraryName syspref with 'system name', and remove this html processing
 558         my $LibraryNameTitle = C4::Context->preference("LibraryName");
 559         $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
 560         $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
 561
 562         # clean up the busc param in the session
 563         # if the page is not opac-detail and not the "add to list" page
 564         # and not the "edit comments" page
 565         if ( C4::Context->preference("OpacBrowseResults")
 566             && $in->{'template_name'} =~ /opac-(.+)\.(?:tt|tmpl)$/ ) {
 567             my $pagename = $1;
 568             unless ( $pagename =~ /^(?:MARC|ISBD)?detail$/
 569                 or $pagename =~ /^showmarc$/
 570                 or $pagename =~ /^addbybiblionumber$/
 571                 or $pagename =~ /^review$/ )
 572             {
 573                 my $sessionSearch = get_session( $sessionID );
 574                 $sessionSearch->clear( ["busc"] ) if $sessionSearch;
 575             }
 576         }
 577
 578         # variables passed from CGI: opac_css_override and opac_search_limits.
 579         my $opac_search_limit   = $ENV{'OPAC_SEARCH_LIMIT'};
 580         my $opac_limit_override = $ENV{'OPAC_LIMIT_OVERRIDE'};
 581         my $opac_name           = '';
 582         if (
 583             ( $opac_limit_override && $opac_search_limit && $opac_search_limit =~ /branch:([\w-]+)/ ) ||
 584             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /branch:([\w-]+)/ ) ||
 585             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /multibranchlimit:(\w+)/ )
 586           ) {
 587             $opac_name = $1;    # opac_search_limit is a branch, so we use it.
 588         } elsif ( $in->{'query'}->param('multibranchlimit') ) {
 589             $opac_name = $in->{'query'}->param('multibranchlimit');
 590         } elsif ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv && C4::Context->userenv->{'branch'} ) {
 591             $opac_name = C4::Context->userenv->{'branch'};
 592         }
 593
 594         my @search_groups = Koha::Library::Groups->get_search_groups({ interface => 'opac' })->as_list;
 595         $template->param(
 596             AnonSuggestions                       => "" . C4::Context->preference("AnonSuggestions"),
 597             LibrarySearchGroups                   => \@search_groups,
 598             opac_name                             => $opac_name,
 599             LibraryName                           => "" . C4::Context->preference("LibraryName"),
 600             LibraryNameTitle                      => "" . $LibraryNameTitle,
 601             OPACAmazonCoverImages                 => C4::Context->preference("OPACAmazonCoverImages"),
 602             OPACFRBRizeEditions                   => C4::Context->preference("OPACFRBRizeEditions"),
 603             OpacHighlightedWords                  => C4::Context->preference("OpacHighlightedWords"),
 604             OPACShelfBrowser                      => "" . C4::Context->preference("OPACShelfBrowser"),
 605             OPACURLOpenInNewWindow                => "" . C4::Context->preference("OPACURLOpenInNewWindow"),
 606             OPACUserCSS                           => "" . C4::Context->preference("OPACUserCSS"),
 607             OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
 608             opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
 609             opac_search_limit                     => $opac_search_limit,
 610             opac_limit_override                   => $opac_limit_override,
 611             OpacBrowser                           => C4::Context->preference("OpacBrowser"),
 612             OpacCloud                             => C4::Context->preference("OpacCloud"),
 613             OpacKohaUrl                           => C4::Context->preference("OpacKohaUrl"),
 614             OpacPasswordChange                    => C4::Context->preference("OpacPasswordChange"),
 615             OPACPatronDetails                     => C4::Context->preference("OPACPatronDetails"),
 616             OPACPrivacy                           => C4::Context->preference("OPACPrivacy"),
 617             OPACFinesTab                          => C4::Context->preference("OPACFinesTab"),
 618             OpacTopissue                          => C4::Context->preference("OpacTopissue"),
 619             'Version'                             => C4::Context->preference('Version'),
 620             hidelostitems                         => C4::Context->preference("hidelostitems"),
 621             mylibraryfirst                        => ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv ) ? C4::Context->userenv->{'branch'} : '',
 622             opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
 623             OpacFavicon                           => C4::Context->preference("OpacFavicon"),
 624             opaclanguagesdisplay                  => "" . C4::Context->preference("opaclanguagesdisplay"),
 625             opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
 626             OPACUserJS                            => C4::Context->preference("OPACUserJS"),
 627             opacuserlogin                         => "" . C4::Context->preference("opacuserlogin"),
 628             OpenLibrarySearch                     => C4::Context->preference("OpenLibrarySearch"),
 629             ShowReviewer                          => C4::Context->preference("ShowReviewer"),
 630             ShowReviewerPhoto                     => C4::Context->preference("ShowReviewerPhoto"),
 631             suggestion                            => "" . C4::Context->preference("suggestion"),
 632             virtualshelves                        => "" . C4::Context->preference("virtualshelves"),
 633             OPACSerialIssueDisplayCount           => C4::Context->preference("OPACSerialIssueDisplayCount"),
 634             SyndeticsClientCode                   => C4::Context->preference("SyndeticsClientCode"),
 635             SyndeticsEnabled                      => C4::Context->preference("SyndeticsEnabled"),
 636             SyndeticsCoverImages                  => C4::Context->preference("SyndeticsCoverImages"),
 637             SyndeticsTOC                          => C4::Context->preference("SyndeticsTOC"),
 638             SyndeticsSummary                      => C4::Context->preference("SyndeticsSummary"),
 639             SyndeticsEditions                     => C4::Context->preference("SyndeticsEditions"),
 640             SyndeticsExcerpt                      => C4::Context->preference("SyndeticsExcerpt"),
 641             SyndeticsReviews                      => C4::Context->preference("SyndeticsReviews"),
 642             SyndeticsAuthorNotes                  => C4::Context->preference("SyndeticsAuthorNotes"),
 643             SyndeticsAwards                       => C4::Context->preference("SyndeticsAwards"),
 644             SyndeticsSeries                       => C4::Context->preference("SyndeticsSeries"),
 645             SyndeticsCoverImageSize               => C4::Context->preference("SyndeticsCoverImageSize"),
 646             OPACLocalCoverImages                  => C4::Context->preference("OPACLocalCoverImages"),
 647             PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
 648             PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
 649             useDischarge                 => C4::Context->preference('useDischarge'),
 650         );
 651
 652         $template->param( OpacPublic => '1' ) if ( $user || C4::Context->preference("OpacPublic") );
 653     }
 654
 655     # Check if we were asked using parameters to force a specific language
 656     if ( defined $in->{'query'}->param('language') ) {
 657
 658         # Extract the language, let C4::Languages::getlanguage choose
 659         # what to do
 660         my $language = C4::Languages::getlanguage( $in->{'query'} );
 661         my $languagecookie = C4::Templates::getlanguagecookie( $in->{'query'}, $language );
 662         $cookie = $cookie_mgr->replace_in_list( $cookie, $languagecookie );
 663     }
 664
 665     return ( $template, $borrowernumber, $cookie, $flags );
 666 }
 667
 668 =head2 checkauth
 669
 670   ($userid, $cookie, $sessionID) = &checkauth($query, $noauth, $flagsrequired, $type);
 671
 672 Verifies that the user is authorized to run this script.  If
 673 the user is authorized, a (userid, cookie, session-id, flags)
 674 quadruple is returned.  If the user is not authorized but does
 675 not have the required privilege (see $flagsrequired below), it
 676 displays an error page and exits.  Otherwise, it displays the
 677 login page and exits.
 678
 679 Note that C<&checkauth> will return if and only if the user
 680 is authorized, so it should be called early on, before any
 681 unfinished operations (e.g., if you've opened a file, then
 682 C<&checkauth> won't close it for you).
 683
 684 C<$query> is the CGI object for the script calling C<&checkauth>.
 685
 686 The C<$noauth> argument is optional. If it is set, then no
 687 authorization is required for the script.
 688
 689 C<&checkauth> fetches user and session information from C<$query> and
 690 ensures that the user is authorized to run scripts that require
 691 authorization.
 692
 693 The C<$flagsrequired> argument specifies the required privileges
 694 the user must have if the username and password are correct.
 695 It should be specified as a reference-to-hash; keys in the hash
 696 should be the "flags" for the user, as specified in the Members
 697 intranet module. Any key specified must correspond to a "flag"
 698 in the userflags table. E.g., { circulate => 1 } would specify
 699 that the user must have the "circulate" privilege in order to
 700 proceed. To make sure that access control is correct, the
 701 C<$flagsrequired> parameter must be specified correctly.
 702
 703 Koha also has a concept of sub-permissions, also known as
 704 granular permissions.  This makes the value of each key
 705 in the C<flagsrequired> hash take on an additional
 706 meaning, i.e.,
 707
 708  1
 709
 710 The user must have access to all subfunctions of the module
 711 specified by the hash key.
 712
 713  *
 714
 715 The user must have access to at least one subfunction of the module
 716 specified by the hash key.
 717
 718  specific permission, e.g., 'export_catalog'
 719
 720 The user must have access to the specific subfunction list, which
 721 must correspond to a row in the permissions table.
 722
 723 The C<$type> argument specifies whether the template should be
 724 retrieved from the opac or intranet directory tree.  "opac" is
 725 assumed if it is not specified; however, if C<$type> is specified,
 726 "intranet" is assumed if it is not "opac".
 727
 728 If C<$query> does not have a valid session ID associated with it
 729 (i.e., the user has not logged in) or if the session has expired,
 730 C<&checkauth> presents the user with a login page (from the point of
 731 view of the original script, C<&checkauth> does not return). Once the
 732 user has authenticated, C<&checkauth> restarts the original script
 733 (this time, C<&checkauth> returns).
 734
 735 The login page is provided using a HTML::Template, which is set in the
 736 systempreferences table or at the top of this file. The variable C<$type>
 737 selects which template to use, either the opac or the intranet
 738 authentification template.
 739
 740 C<&checkauth> returns a user ID, a cookie, and a session ID. The
 741 cookie should be sent back to the browser; it verifies that the user
 742 has authenticated.
 743
 744 =cut
 745
 746 sub _version_check {
 747     my $type  = shift;
 748     my $query = shift;
 749     my $version;
 750
 751     # If version syspref is unavailable, it means Koha is being installed,
 752     # and so we must redirect to OPAC maintenance page or to the WebInstaller
 753     # also, if OpacMaintenance is ON, OPAC should redirect to maintenance
 754     if ( C4::Context->preference('OpacMaintenance') && $type eq 'opac' ) {
 755         warn "OPAC Install required, redirecting to maintenance";
 756         print $query->redirect("/cgi-bin/koha/maintenance.pl");
 757         safe_exit;
 758     }
 759     unless ( $version = C4::Context->preference('Version') ) {    # assignment, not comparison
 760         if ( $type ne 'opac' ) {
 761             warn "Install required, redirecting to Installer";
 762             print $query->redirect("/cgi-bin/koha/installer/install.pl");
 763         } else {
 764             warn "OPAC Install required, redirecting to maintenance";
 765             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 766         }
 767         safe_exit;
 768     }
 769
 770     # check that database and koha version are the same
 771     # there is no DB version, it's a fresh install,
 772     # go to web installer
 773     # there is a DB version, compare it to the code version
 774     my $kohaversion = Koha::version();
 775
 776     # remove the 3 last . to have a Perl number
 777     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
 778     Koha::Logger->get->debug("kohaversion : $kohaversion");
 779     if ( $version < $kohaversion ) {
 780         my $warning = "Database update needed, redirecting to %s. Database is $version and Koha is $kohaversion";
 781         if ( $type ne 'opac' ) {
 782             warn sprintf( $warning, 'Installer' );
 783             print $query->redirect("/cgi-bin/koha/installer/install.pl?step=1&op=updatestructure");
 784         } else {
 785             warn sprintf( "OPAC: " . $warning, 'maintenance' );
 786             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 787         }
 788         safe_exit;
 789     }
 790 }
 791
 792 sub _timeout_syspref {
 793     my $default_timeout = 600;
 794     my $timeout = C4::Context->preference('timeout') || $default_timeout;
 795
 796     # value in days, convert in seconds
 797     if ( $timeout =~ /^(\d+)[dD]$/ ) {
 798         $timeout = $1 * 86400;
 799     }
 800     # value in hours, convert in seconds
 801     elsif ( $timeout =~ /^(\d+)[hH]$/ ) {
 802         $timeout = $1 * 3600;
 803     }
 804     elsif ( $timeout !~ m/^\d+$/ ) {
 805         warn "The value of the system preference 'timeout' is not correct, defaulting to $default_timeout";
 806         $timeout = $default_timeout;
 807     }
 808
 809     return $timeout;
 810 }
 811
 812 sub checkauth {
 813     my $query = shift;
 814
 815     # Get shibboleth login attribute
 816     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 817     my $shib_login = $shib ? get_login_shib() : undef;
 818
 819     # $authnotrequired will be set for scripts which will run without authentication
 820     my $authnotrequired = shift;
 821     my $flagsrequired   = shift;
 822     my $type            = shift;
 823     my $emailaddress    = shift;
 824     my $template_name   = shift;
 825     $type = 'opac' unless $type;
 826
 827     if ( $type eq 'opac' && !C4::Context->preference("OpacPublic") ) {
 828         my @allowed_scripts_for_private_opac = qw(
 829           opac-memberentry.tt
 830           opac-registration-email-sent.tt
 831           opac-registration-confirmation.tt
 832           opac-memberentry-update-submitted.tt
 833           opac-password-recovery.tt
 834           opac-reset-password.tt
 835         );
 836         $authnotrequired = 0 unless grep { $_ eq $template_name }
 837           @allowed_scripts_for_private_opac;
 838     }
 839
 840     my $dbh     = C4::Context->dbh;
 841     my $timeout = _timeout_syspref();
 842
 843     my $cookie_mgr = Koha::CookieManager->new;
 844
 845     _version_check( $type, $query );
 846
 847     # state variables
 848     my $loggedin = 0;
 849     my $auth_state = 'failed';
 850     my %info;
 851     my ( $userid, $cookie, $sessionID, $flags );
 852     $cookie = [];
 853     my $logout = $query->param('logout.x');
 854
 855     my $anon_search_history;
 856     my $cas_ticket = '';
 857     # This parameter is the name of the CAS server we want to authenticate against,
 858     # when using authentication against multiple CAS servers, as configured in Auth_cas_servers.yaml
 859     my $casparam = $query->param('cas');
 860     my $q_userid = $query->param('userid') // '';
 861
 862     my $session;
 863     my $invalid_otp_token;
 864     my $require_2FA = ( C4::Context->preference('TwoFactorAuthentication') && $type ne "opac" ) ? 1 : 0;
 865
 866     # Basic authentication is incompatible with the use of Shibboleth,
 867     # as Shibboleth may return REMOTE_USER as a Shibboleth attribute,
 868     # and it may not be the attribute we want to use to match the koha login.
 869     #
 870     # Also, do not consider an empty REMOTE_USER.
 871     #
 872     # Finally, after those tests, we can assume (although if it would be better with
 873     # a syspref) that if we get a REMOTE_USER, that's from basic authentication,
 874     # and we can affect it to $userid.
 875     if ( !$shib and defined( $ENV{'REMOTE_USER'} ) and $ENV{'REMOTE_USER'} ne '' and $userid = $ENV{'REMOTE_USER'} ) {
 876
 877         # Using Basic Authentication, no cookies required
 878         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 879             -name     => 'CGISESSID',
 880             -value    => '',
 881             -HttpOnly => 1,
 882             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 883             -sameSite => 'Lax',
 884         ));
 885         $loggedin = 1;
 886     }
 887     elsif ( $emailaddress) {
 888         # the Google OpenID Connect passes an email address
 889     }
 890     elsif ( $sessionID = $query->cookie("CGISESSID") ) {    # assignment, not comparison
 891         my ( $return, $more_info );
 892         # NOTE: $flags in the following call is still undefined !
 893         ( $return, $session, $more_info ) = check_cookie_auth( $sessionID, $flags,
 894             { remote_addr => $ENV{REMOTE_ADDR}, skip_version_check => 1 }
 895         );
 896
 897         if ( $return eq 'ok' || $return eq 'additional-auth-needed' ) {
 898             $userid = $session->param('id');
 899         }
 900
 901         $auth_state =
 902             $return eq 'ok'                     ? 'completed'
 903           : $return eq 'additional-auth-needed' ? 'additional-auth-needed'
 904           :                                       'failed';
 905
 906         # We are at the second screen if the waiting-for-2FA is set in session
 907         # and otp_token param has been passed
 908         if (   $require_2FA
 909             && $auth_state eq 'additional-auth-needed'
 910             && ( my $otp_token = $query->param('otp_token') ) )
 911         {
 912             my $patron    = Koha::Patrons->find( { userid => $userid } );
 913             my $auth      = Koha::Auth::TwoFactorAuth->new( { patron => $patron } );
 914             my $verified = $auth->verify($otp_token, 1);
 915             $auth->clear;
 916             if ( $verified ) {
 917                 # The token is correct, the user is fully logged in!
 918                 $auth_state = 'completed';
 919                 $session->param( 'waiting-for-2FA', 0 );
 920
 921                # This is an ugly trick to pass the test
 922                # $query->param('koha_login_context') && ( $q_userid ne $userid )
 923                # few lines later
 924                 $q_userid = $userid;
 925             }
 926             else {
 927                 $invalid_otp_token = 1;
 928             }
 929         }
 930
 931         if ( $auth_state eq 'completed' ) {
 932             Koha::Logger->get->debug(sprintf "AUTH_SESSION: (%s)\t%s %s - %s", map { $session->param($_) || q{} } qw(cardnumber firstname surname branch));
 933
 934             if ( ( $query->param('koha_login_context') && ( $q_userid ne $userid ) )
 935                 || ( $cas && $query->param('ticket') && !C4::Context->userenv->{'id'} )
 936                 || ( $shib && $shib_login && !$logout && !C4::Context->userenv->{'id'} )
 937             ) {
 938
 939                 #if a user enters an id ne to the id in the current session, we need to log them in...
 940                 #first we need to clear the anonymous session...
 941                 $anon_search_history = $session->param('search_history');
 942                 $session->delete();
 943                 $session->flush;
 944                 $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 945                 C4::Context::_unset_userenv($sessionID);
 946                 $sessionID = undef;
 947             } elsif (!$logout) {
 948
 949                 $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
 950                     -name     => 'CGISESSID',
 951                     -value    => $session->id,
 952                     -HttpOnly => 1,
 953                     -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 954                     -sameSite => 'Lax',
 955                 ));
 956
 957                 $flags = haspermission( $userid, $flagsrequired );
 958                 unless ( $flags ) {
 959                     $auth_state = 'failed';
 960                     $info{'nopermission'} = 1;
 961                 }
 962             }
 963         } elsif ( !$logout ) {
 964             if ( $return eq 'expired' ) {
 965                 $info{timed_out} = 1;
 966             } elsif ( $return eq 'restricted' ) {
 967                 $info{oldip}        = $more_info->{old_ip};
 968                 $info{newip}        = $more_info->{new_ip};
 969                 $info{different_ip} = 1;
 970             } elsif ( $return eq 'password_expired' ) {
 971                 $info{password_has_expired} = 1;
 972             }
 973         }
 974     }
 975
 976     if ( $auth_state eq 'failed' || $logout ) {
 977         $sessionID = undef;
 978         $userid    = undef;
 979     }
 980
 981     if ($logout) {
 982
 983         # voluntary logout the user
 984         # check wether the user was using their shibboleth session or a local one
 985         my $shibSuccess = C4::Context->userenv ? C4::Context->userenv->{'shibboleth'} : undef;
 986         if ( $session ) {
 987             $session->delete();
 988             $session->flush;
 989         }
 990         C4::Context::_unset_userenv($sessionID);
 991         $cookie = $cookie_mgr->clear_unless( $query->cookie, @$cookie );
 992
 993         if ($cas and $caslogout) {
 994             logout_cas($query, $type);
 995         }
 996
 997         # If we are in a shibboleth session (shibboleth is enabled, a shibboleth match attribute is set and matches koha matchpoint)
 998         if ( $shib and $shib_login and $shibSuccess) {
 999             logout_shib($query);
1000         }
1001
1002         $session   = undef;
1003         $auth_state = 'logout';
1004     }
1005
1006     unless ( $userid ) {
1007         #we initiate a session prior to checking for a username to allow for anonymous sessions...
1008         if( !$session or !$sessionID ) { # if we cleared sessionID, we need a new session
1009             $session = get_session() or die "Auth ERROR: Cannot get_session()";
1010         }
1011
1012         # Save anonymous search history in new session so it can be retrieved
1013         # by get_template_and_user to store it in user's search history after
1014         # a successful login.
1015         if ($anon_search_history) {
1016             $session->param( 'search_history', $anon_search_history );
1017         }
1018
1019         $sessionID = $session->id;
1020         C4::Context->_new_userenv($sessionID);
1021         $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1022             -name     => 'CGISESSID',
1023             -value    => $sessionID,
1024             -HttpOnly => 1,
1025             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1026             -sameSite => 'Lax',
1027         ));
1028         my $pki_field = C4::Context->preference('AllowPKIAuth');
1029         if ( !defined($pki_field) ) {
1030             print STDERR "ERROR: Missing system preference AllowPKIAuth.\n";
1031             $pki_field = 'None';
1032         }
1033         if ( ( $cas && $query->param('ticket') )
1034             || $q_userid
1035             || ( $shib && $shib_login )
1036             || $pki_field ne 'None'
1037             || $emailaddress )
1038         {
1039             my $password    = $query->param('password');
1040             my $shibSuccess = 0;
1041             my ( $return, $cardnumber );
1042
1043             # If shib is enabled and we have a shib login, does the login match a valid koha user
1044             if ( $shib && $shib_login ) {
1045                 my $retuserid;
1046
1047                 # Do not pass password here, else shib will not be checked in checkpw.
1048                 ( $return, $cardnumber, $retuserid ) = checkpw( $dbh, $q_userid, undef, $query );
1049                 $userid      = $retuserid;
1050                 $shibSuccess = $return;
1051                 $info{'invalidShibLogin'} = 1 unless ($return);
1052             }
1053
1054             # If shib login and match were successful, skip further login methods
1055             unless ($shibSuccess) {
1056                 if ( $cas && $query->param('ticket') ) {
1057                     my $retuserid;
1058                     ( $return, $cardnumber, $retuserid, $cas_ticket ) =
1059                       checkpw( $dbh, $userid, $password, $query, $type );
1060                     $userid = $retuserid;
1061                     $info{'invalidCasLogin'} = 1 unless ($return);
1062                 }
1063
1064                 elsif ( $emailaddress ) {
1065                     my $value = $emailaddress;
1066
1067                     # If we're looking up the email, there's a chance that the person
1068                     # doesn't have a userid. So if there is none, we pass along the
1069                     # borrower number, and the bits of code that need to know the user
1070                     # ID will have to be smart enough to handle that.
1071                     my $patrons = Koha::Patrons->search({ email => $value });
1072                     if ($patrons->count) {
1073
1074                         # First the userid, then the borrowernum
1075                         my $patron = $patrons->next;
1076                         $value = $patron->userid || $patron->borrowernumber;
1077                     } else {
1078                         undef $value;
1079                     }
1080                     $return = $value ? 1 : 0;
1081                     $userid = $value;
1082                 }
1083
1084                 elsif (
1085                     ( $pki_field eq 'Common Name' && $ENV{'SSL_CLIENT_S_DN_CN'} )
1086                     || ( $pki_field eq 'emailAddress'
1087                         && $ENV{'SSL_CLIENT_S_DN_Email'} )
1088                   )
1089                 {
1090                     my $value;
1091                     if ( $pki_field eq 'Common Name' ) {
1092                         $value = $ENV{'SSL_CLIENT_S_DN_CN'};
1093                     }
1094                     elsif ( $pki_field eq 'emailAddress' ) {
1095                         $value = $ENV{'SSL_CLIENT_S_DN_Email'};
1096
1097                         # If we're looking up the email, there's a chance that the person
1098                         # doesn't have a userid. So if there is none, we pass along the
1099                         # borrower number, and the bits of code that need to know the user
1100                         # ID will have to be smart enough to handle that.
1101                         my $patrons = Koha::Patrons->search({ email => $value });
1102                         if ($patrons->count) {
1103
1104                             # First the userid, then the borrowernum
1105                             my $patron = $patrons->next;
1106                             $value = $patron->userid || $patron->borrowernumber;
1107                         } else {
1108                             undef $value;
1109                         }
1110                     }
1111
1112                     $return = $value ? 1 : 0;
1113                     $userid = $value;
1114
1115                 }
1116                 else {
1117                     my $retuserid;
1118                     my $request_method = $query->request_method();
1119
1120                     if (
1121                         $request_method eq 'POST'
1122                         || ( C4::Context->preference('AutoSelfCheckID')
1123                             && $q_userid eq C4::Context->preference('AutoSelfCheckID') )
1124                       )
1125                     {
1126
1127                         ( $return, $cardnumber, $retuserid, $cas_ticket ) =
1128                           checkpw( $dbh, $q_userid, $password, $query, $type );
1129                         $userid = $retuserid if ($retuserid);
1130                         $info{'invalid_username_or_password'} = 1 unless ($return);
1131                     }
1132                 }
1133             }
1134
1135             # If shib configured and shibOnly enabled, we should ignore anything other than a shibboleth type login.
1136             if (
1137                    $shib
1138                 && !$shibSuccess
1139                 && (
1140                     (
1141                         ( $type eq 'opac' )
1142                         && C4::Context->preference('OPACShibOnly')
1143                     )
1144                     || ( ( $type ne 'opac' )
1145                         && C4::Context->preference('staffShibOnly') )
1146                 )
1147               )
1148             {
1149                 $return = 0;
1150             }
1151
1152             # $return: 1 = valid user
1153             if ($return > 0) {
1154
1155                 if ( $flags = haspermission( $userid, $flagsrequired ) ) {
1156                     $auth_state = "logged_in";
1157                 }
1158                 else {
1159                     $info{'nopermission'} = 1;
1160                     C4::Context::_unset_userenv($sessionID);
1161                 }
1162                 my ( $borrowernumber, $firstname, $surname, $userflags,
1163                     $branchcode, $branchname, $emailaddress, $desk_id,
1164                     $desk_name, $register_id, $register_name );
1165
1166                 if ( $return == 1 ) {
1167                     my $select = "
1168                     SELECT borrowernumber, firstname, surname, flags, borrowers.branchcode,
1169                     branches.branchname    as branchname, email
1170                     FROM borrowers
1171                     LEFT JOIN branches on borrowers.branchcode=branches.branchcode
1172                     ";
1173                     my $sth = $dbh->prepare("$select where userid=?");
1174                     $sth->execute($userid);
1175                     unless ( $sth->rows ) {
1176                         $sth = $dbh->prepare("$select where cardnumber=?");
1177                         $sth->execute($cardnumber);
1178
1179                         unless ( $sth->rows ) {
1180                             $sth->execute($userid);
1181                         }
1182                     }
1183                     if ( $sth->rows ) {
1184                         ( $borrowernumber, $firstname, $surname, $userflags,
1185                             $branchcode, $branchname, $emailaddress ) = $sth->fetchrow;
1186                     }
1187
1188                     # launch a sequence to check if we have a ip for the branch, i
1189                     # if we have one we replace the branchcode of the userenv by the branch bound in the ip.
1190
1191                     my $ip = $ENV{'REMOTE_ADDR'};
1192
1193                     # if they specify at login, use that
1194                     if ( $query->param('branch') ) {
1195                         $branchcode = $query->param('branch');
1196                         my $library = Koha::Libraries->find($branchcode);
1197                         $branchname = $library? $library->branchname: '';
1198                     }
1199                     if ( $query->param('desk_id') ) {
1200                         $desk_id = $query->param('desk_id');
1201                         my $desk = Koha::Desks->find($desk_id);
1202                         $desk_name = $desk ? $desk->desk_name : '';
1203                     }
1204                     if ( C4::Context->preference('UseCashRegisters') ) {
1205                         my $register =
1206                           $query->param('register_id')
1207                           ? Koha::Cash::Registers->find($query->param('register_id'))
1208                           : Koha::Cash::Registers->search(
1209                             { branch => $branchcode, branch_default => 1 },
1210                             { rows   => 1 } )->single;
1211                         $register_id   = $register->id   if ($register);
1212                         $register_name = $register->name if ($register);
1213                     }
1214                     my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1215                     if ( $type ne 'opac' and C4::Context->preference('AutoLocation') ) {
1216
1217                         # we have to check they are coming from the right ip range
1218                         my $domain = $branches->{$branchcode}->{'branchip'};
1219                         $domain =~ s|\.\*||g;
1220                         if ( $ip !~ /^$domain/ ) {
1221                             $loggedin = 0;
1222                             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1223                                 -name     => 'CGISESSID',
1224                                 -value    => '',
1225                                 -HttpOnly => 1,
1226                                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1227                                 -sameSite => 'Lax',
1228                             ));
1229                             $info{'wrongip'} = 1;
1230                         }
1231                     }
1232
1233                     foreach my $br ( keys %$branches ) {
1234
1235                         #     now we work with the treatment of ip
1236                         my $domain = $branches->{$br}->{'branchip'};
1237                         if ( $domain && $ip =~ /^$domain/ ) {
1238                             $branchcode = $branches->{$br}->{'branchcode'};
1239
1240                             # new op dev : add the branchname to the cookie
1241                             $branchname    = $branches->{$br}->{'branchname'};
1242                         }
1243                     }
1244
1245                     my $is_sco_user = 0;
1246                     if ( $query->param('sco_user_login') && ( $query->param('sco_user_login') eq '1' ) ){
1247                         $is_sco_user = 1;
1248                     }
1249
1250                     $session->param( 'number',       $borrowernumber );
1251                     $session->param( 'id',           $userid );
1252                     $session->param( 'cardnumber',   $cardnumber );
1253                     $session->param( 'firstname',    $firstname );
1254                     $session->param( 'surname',      $surname );
1255                     $session->param( 'branch',       $branchcode );
1256                     $session->param( 'branchname',   $branchname );
1257                     $session->param( 'desk_id',      $desk_id);
1258                     $session->param( 'desk_name',     $desk_name);
1259                     $session->param( 'flags',        $userflags );
1260                     $session->param( 'emailaddress', $emailaddress );
1261                     $session->param( 'ip',           $session->remote_addr() );
1262                     $session->param( 'lasttime',     time() );
1263                     $session->param( 'interface',    $type);
1264                     $session->param( 'shibboleth',   $shibSuccess );
1265                     $session->param( 'register_id',  $register_id );
1266                     $session->param( 'register_name',  $register_name );
1267                     $session->param( 'sco_user', $is_sco_user );
1268                 }
1269                 $session->param('cas_ticket', $cas_ticket) if $cas_ticket;
1270                 C4::Context->set_userenv(
1271                     $session->param('number'),       $session->param('id'),
1272                     $session->param('cardnumber'),   $session->param('firstname'),
1273                     $session->param('surname'),      $session->param('branch'),
1274                     $session->param('branchname'),   $session->param('flags'),
1275                     $session->param('emailaddress'), $session->param('shibboleth'),
1276                     $session->param('desk_id'),      $session->param('desk_name'),
1277                     $session->param('register_id'),  $session->param('register_name')
1278                 );
1279
1280             }
1281             # $return: 0 = invalid user
1282             # reset to anonymous session
1283             else {
1284                 if ($userid) {
1285                     $info{'invalid_username_or_password'} = 1;
1286                     C4::Context::_unset_userenv($sessionID);
1287                 }
1288                 $session->param( 'lasttime', time() );
1289                 $session->param( 'ip',       $session->remote_addr() );
1290                 $session->param( 'sessiontype', 'anon' );
1291                 $session->param( 'interface', $type);
1292             }
1293         }    # END if ( $q_userid
1294         elsif ( $type eq "opac" ) {
1295
1296             # anonymous sessions are created only for the OPAC
1297
1298             # setting a couple of other session vars...
1299             $session->param( 'ip',          $session->remote_addr() );
1300             $session->param( 'lasttime',    time() );
1301             $session->param( 'sessiontype', 'anon' );
1302             $session->param( 'interface', $type);
1303         }
1304         $session->flush;
1305     }    # END unless ($userid)
1306
1307
1308     if ( $auth_state eq 'logged_in' ) {
1309         $auth_state = 'completed';
1310
1311         # Auth is completed unless an additional auth is needed
1312         if ( $require_2FA ) {
1313             my $patron = Koha::Patrons->find({userid => $userid});
1314             if ( $patron->auth_method eq 'two-factor' ) {
1315                 # Ask for the OTP token
1316                 $auth_state = 'additional-auth-needed';
1317                 $session->param('waiting-for-2FA', 1);
1318                 %info = ();# We remove the warnings/errors we may have set incorrectly before
1319             }
1320         }
1321     }
1322
1323     # finished authentification, now respond
1324     if ( $auth_state eq 'completed' || $authnotrequired ) {
1325         # successful login
1326         unless (@$cookie) {
1327             $cookie = $cookie_mgr->replace_in_list( $cookie, $query->cookie(
1328                 -name     => 'CGISESSID',
1329                 -value    => '',
1330                 -HttpOnly => 1,
1331                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1332                 -sameSite => 'Lax',
1333             ));
1334         }
1335
1336         track_login_daily( $userid );
1337
1338         # In case, that this request was a login attempt, we want to prevent that users can repost the opac login
1339         # request. We therefore redirect the user to the requested page again without the login parameters.
1340         # See Post/Redirect/Get (PRG) design pattern: https://en.wikipedia.org/wiki/Post/Redirect/Get
1341         if ( $type eq "opac" && $query->param('koha_login_context') && $query->param('koha_login_context') ne 'sco' && $query->param('password') && $query->param('userid') ) {
1342             my $uri = URI->new($query->url(-relative=>1, -query_string=>1));
1343             $uri->query_param_delete('userid');
1344             $uri->query_param_delete('password');
1345             $uri->query_param_delete('koha_login_context');
1346             print $query->redirect(-uri => $uri->as_string, -cookie => $cookie, -status=>'303 See other');
1347             exit;
1348         }
1349
1350         return ( $userid, $cookie, $sessionID, $flags );
1351     }
1352
1353     #
1354     #
1355     # AUTH rejected, show the login/password template, after checking the DB.
1356     #
1357     #
1358
1359     my $patron = Koha::Patrons->find({ userid => $q_userid }); # Not necessary logged in!
1360
1361     # get the inputs from the incoming query
1362     my @inputs = ();
1363     my @inputs_to_clean = qw( userid password ticket logout.x otp_token );
1364     foreach my $name ( param $query) {
1365         next if grep { $name eq $_ } @inputs_to_clean;
1366         my @value = $query->multi_param($name);
1367         push @inputs, { name => $name, value => $_ } for @value;
1368     }
1369
1370     my $LibraryNameTitle = C4::Context->preference("LibraryName");
1371     $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
1372     $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
1373
1374     my $auth_template_name = ( $type eq 'opac' ) ? 'opac-auth.tt' : 'auth.tt';
1375     my $template = C4::Templates::gettemplate( $auth_template_name, $type, $query );
1376     $template->param(
1377         login                                 => 1,
1378         INPUTS                                => \@inputs,
1379         script_name                           => get_script_name(),
1380         casAuthentication                     => C4::Context->preference("casAuthentication"),
1381         shibbolethAuthentication              => $shib,
1382         suggestion                            => C4::Context->preference("suggestion"),
1383         virtualshelves                        => C4::Context->preference("virtualshelves"),
1384         LibraryName                           => "" . C4::Context->preference("LibraryName"),
1385         LibraryNameTitle                      => "" . $LibraryNameTitle,
1386         opacuserlogin                         => C4::Context->preference("opacuserlogin"),
1387         OpacFavicon                           => C4::Context->preference("OpacFavicon"),
1388         opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
1389         opaclanguagesdisplay                  => C4::Context->preference("opaclanguagesdisplay"),
1390         OPACUserJS                            => C4::Context->preference("OPACUserJS"),
1391         opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
1392         OpacCloud                             => C4::Context->preference("OpacCloud"),
1393         OpacTopissue                          => C4::Context->preference("OpacTopissue"),
1394         OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
1395         OpacBrowser                           => C4::Context->preference("OpacBrowser"),
1396         TagsEnabled                           => C4::Context->preference("TagsEnabled"),
1397         OPACUserCSS                           => C4::Context->preference("OPACUserCSS"),
1398         intranetcolorstylesheet               => C4::Context->preference("intranetcolorstylesheet"),
1399         intranetstylesheet                    => C4::Context->preference("intranetstylesheet"),
1400         IntranetNav                           => C4::Context->preference("IntranetNav"),
1401         IntranetFavicon                       => C4::Context->preference("IntranetFavicon"),
1402         IntranetUserCSS                       => C4::Context->preference("IntranetUserCSS"),
1403         IntranetUserJS                        => C4::Context->preference("IntranetUserJS"),
1404         IndependentBranches                   => C4::Context->preference("IndependentBranches"),
1405         AutoLocation                          => C4::Context->preference("AutoLocation"),
1406         wrongip                               => $info{'wrongip'},
1407         PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
1408         PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
1409         opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
1410         too_many_login_attempts               => ( $patron and $patron->account_locked ),
1411     );
1412
1413     $template->param( SCO_login => 1 ) if ( $query->param('sco_user_login') );
1414     $template->param( SCI_login => 1 ) if ( $query->param('sci_user_login') );
1415     $template->param( OpacPublic => C4::Context->preference("OpacPublic") );
1416     $template->param( loginprompt => 1 ) unless $info{'nopermission'};
1417     if ( $auth_state eq 'additional-auth-needed' ) {
1418         my $patron = Koha::Patrons->find( { userid => $userid } );
1419         $template->param(
1420             TwoFA_prompt => 1,
1421             invalid_otp_token => $invalid_otp_token,
1422             notice_email_address => $patron->notice_email_address, # We could also pass logged_in_user if necessary
1423         );
1424     }
1425
1426     if ( $type eq 'opac' ) {
1427         require Koha::Virtualshelves;
1428         my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
1429             {
1430                 public => 1,
1431             }
1432         );
1433         $template->param(
1434             some_public_shelves  => $some_public_shelves,
1435         );
1436     }
1437
1438     if ($cas) {
1439
1440         # Is authentication against multiple CAS servers enabled?
1441         require C4::Auth_with_cas;
1442         if ( multipleAuth() && !$casparam ) {
1443             my $casservers = getMultipleAuth();
1444             my @tmplservers;
1445             foreach my $key ( keys %$casservers ) {
1446                 push @tmplservers, { name => $key, value => login_cas_url( $query, $key, $type ) . "?cas=$key" };
1447             }
1448             $template->param(
1449                 casServersLoop => \@tmplservers
1450             );
1451         } else {
1452             $template->param(
1453                 casServerUrl => login_cas_url($query, undef, $type),
1454             );
1455         }
1456
1457         $template->param(
1458             invalidCasLogin => $info{'invalidCasLogin'}
1459         );
1460     }
1461
1462     if ($shib) {
1463         #If shibOnly is enabled just go ahead and redirect directly
1464         if ( (($type eq 'opac') && C4::Context->preference('OPACShibOnly')) || (($type ne 'opac') && C4::Context->preference('staffShibOnly')) ) {
1465             my $redirect_url = login_shib_url( $query );
1466             print $query->redirect( -uri => "$redirect_url", -status => 303 );
1467             safe_exit;
1468         }
1469
1470         $template->param(
1471             shibbolethAuthentication => $shib,
1472             shibbolethLoginUrl       => login_shib_url($query),
1473         );
1474     }
1475
1476     if (C4::Context->preference('GoogleOpenIDConnect')) {
1477         if ($query->param("OpenIDConnectFailed")) {
1478             my $reason = $query->param('OpenIDConnectFailed');
1479             $template->param(invalidGoogleOpenIDConnectLogin => $reason);
1480         }
1481     }
1482
1483     $template->param(
1484         LibraryName => C4::Context->preference("LibraryName"),
1485     );
1486     $template->param(%info);
1487
1488     #    $cookie = $query->cookie(CGISESSID => $session->id
1489     #   );
1490     print $query->header(
1491         {   type              => 'text/html',
1492             charset           => 'utf-8',
1493             cookie            => $cookie,
1494             'X-Frame-Options' => 'SAMEORIGIN',
1495             -sameSite => 'Lax'
1496         }
1497       ),
1498       $template->output;
1499     safe_exit;
1500 }
1501
1502 =head2 check_api_auth
1503
1504   ($status, $cookie, $sessionId) = check_api_auth($query, $userflags);
1505
1506 Given a CGI query containing the parameters 'userid' and 'password' and/or a session
1507 cookie, determine if the user has the privileges specified by C<$userflags>.
1508
1509 C<check_api_auth> is is meant for authenticating users of web services, and
1510 consequently will always return and will not attempt to redirect the user
1511 agent.
1512
1513 If a valid session cookie is already present, check_api_auth will return a status
1514 of "ok", the cookie, and the Koha session ID.
1515
1516 If no session cookie is present, check_api_auth will check the 'userid' and 'password
1517 parameters and create a session cookie and Koha session if the supplied credentials
1518 are OK.
1519
1520 Possible return values in C<$status> are:
1521
1522 =over
1523
1524 =item "ok" -- user authenticated; C<$cookie> and C<$sessionid> have valid values.
1525
1526 =item "failed" -- credentials are not correct; C<$cookie> and C<$sessionid> are undef
1527
1528 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1529
1530 =item "expired -- session cookie has expired; API user should resubmit userid and password
1531
1532 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1533
1534 =item "additional-auth-needed -- User is in an authentication process that is not finished
1535
1536 =back
1537
1538 =cut
1539
1540 sub check_api_auth {
1541
1542     my $query         = shift;
1543     my $flagsrequired = shift;
1544     my $dbh     = C4::Context->dbh;
1545     my $timeout = _timeout_syspref();
1546
1547     unless ( C4::Context->preference('Version') ) {
1548
1549         # database has not been installed yet
1550         return ( "maintenance", undef, undef );
1551     }
1552     my $kohaversion = Koha::version();
1553     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1554     if ( C4::Context->preference('Version') < $kohaversion ) {
1555
1556         # database in need of version update; assume that
1557         # no API should be called while databsae is in
1558         # this condition.
1559         return ( "maintenance", undef, undef );
1560     }
1561
1562     my ( $sessionID, $session );
1563     unless ( $query->param('userid') ) {
1564         $sessionID = $query->cookie("CGISESSID");
1565     }
1566     if ( $sessionID && not( $cas && $query->param('PT') ) ) {
1567
1568         my $return;
1569         ( $return, $session, undef ) = check_cookie_auth(
1570             $sessionID, $flagsrequired, { remote_addr => $ENV{REMOTE_ADDR} } );
1571
1572         return ( $return, undef, undef ) # Cookie auth failed
1573             if $return ne "ok";
1574
1575         my $cookie = $query->cookie(
1576             -name     => 'CGISESSID',
1577             -value    => $session->id,
1578             -HttpOnly => 1,
1579             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1580             -sameSite => 'Lax'
1581         );
1582         return ( $return, $cookie, $session ); # return == 'ok' here
1583
1584     } else {
1585
1586         # new login
1587         my $userid   = $query->param('userid');
1588         my $password = $query->param('password');
1589         my ( $return, $cardnumber, $cas_ticket );
1590
1591         # Proxy CAS auth
1592         if ( $cas && $query->param('PT') ) {
1593             my $retuserid;
1594
1595             # In case of a CAS authentication, we use the ticket instead of the password
1596             my $PT = $query->param('PT');
1597             ( $return, $cardnumber, $userid, $cas_ticket ) = check_api_auth_cas( $dbh, $PT, $query );    # EXTERNAL AUTH
1598         } else {
1599
1600             # User / password auth
1601             unless ( $userid and $password ) {
1602
1603                 # caller did something wrong, fail the authenticateion
1604                 return ( "failed", undef, undef );
1605             }
1606             my $newuserid;
1607             ( $return, $cardnumber, $newuserid, $cas_ticket ) = checkpw( $dbh, $userid, $password, $query );
1608         }
1609
1610         if ( $return and haspermission( $userid, $flagsrequired ) ) {
1611             my $session = get_session("");
1612             return ( "failed", undef, undef ) unless $session;
1613
1614             my $sessionID = $session->id;
1615             C4::Context->_new_userenv($sessionID);
1616             my $cookie = $query->cookie(
1617                 -name     => 'CGISESSID',
1618                 -value    => $sessionID,
1619                 -HttpOnly => 1,
1620                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1621                 -sameSite => 'Lax'
1622             );
1623             if ( $return == 1 ) {
1624                 my (
1625                     $borrowernumber, $firstname,  $surname,
1626                     $userflags,      $branchcode, $branchname,
1627                     $emailaddress
1628                 );
1629                 my $sth =
1630                   $dbh->prepare(
1631 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where userid=?"
1632                   );
1633                 $sth->execute($userid);
1634                 (
1635                     $borrowernumber, $firstname,  $surname,
1636                     $userflags,      $branchcode, $branchname,
1637                     $emailaddress
1638                 ) = $sth->fetchrow if ( $sth->rows );
1639
1640                 unless ( $sth->rows ) {
1641                     my $sth = $dbh->prepare(
1642 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
1643                     );
1644                     $sth->execute($cardnumber);
1645                     (
1646                         $borrowernumber, $firstname,  $surname,
1647                         $userflags,      $branchcode, $branchname,
1648                         $emailaddress
1649                     ) = $sth->fetchrow if ( $sth->rows );
1650
1651                     unless ( $sth->rows ) {
1652                         $sth->execute($userid);
1653                         (
1654                             $borrowernumber, $firstname,  $surname,       $userflags,
1655                             $branchcode,     $branchname, $emailaddress
1656                         ) = $sth->fetchrow if ( $sth->rows );
1657                     }
1658                 }
1659
1660                 my $ip = $ENV{'REMOTE_ADDR'};
1661
1662                 # if they specify at login, use that
1663                 if ( $query->param('branch') ) {
1664                     $branchcode = $query->param('branch');
1665                     my $library = Koha::Libraries->find($branchcode);
1666                     $branchname = $library? $library->branchname: '';
1667                 }
1668                 my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search->as_list };
1669                 foreach my $br ( keys %$branches ) {
1670
1671                     #     now we work with the treatment of ip
1672                     my $domain = $branches->{$br}->{'branchip'};
1673                     if ( $domain && $ip =~ /^$domain/ ) {
1674                         $branchcode = $branches->{$br}->{'branchcode'};
1675
1676                         # new op dev : add the branchname to the cookie
1677                         $branchname    = $branches->{$br}->{'branchname'};
1678                     }
1679                 }
1680                 $session->param( 'number',       $borrowernumber );
1681                 $session->param( 'id',           $userid );
1682                 $session->param( 'cardnumber',   $cardnumber );
1683                 $session->param( 'firstname',    $firstname );
1684                 $session->param( 'surname',      $surname );
1685                 $session->param( 'branch',       $branchcode );
1686                 $session->param( 'branchname',   $branchname );
1687                 $session->param( 'flags',        $userflags );
1688                 $session->param( 'emailaddress', $emailaddress );
1689                 $session->param( 'ip',           $session->remote_addr() );
1690                 $session->param( 'lasttime',     time() );
1691                 $session->param( 'interface',    'api'  );
1692             }
1693             $session->param( 'cas_ticket', $cas_ticket);
1694             C4::Context->set_userenv(
1695                 $session->param('number'),       $session->param('id'),
1696                 $session->param('cardnumber'),   $session->param('firstname'),
1697                 $session->param('surname'),      $session->param('branch'),
1698                 $session->param('branchname'),   $session->param('flags'),
1699                 $session->param('emailaddress'), $session->param('shibboleth'),
1700                 $session->param('desk_id'),      $session->param('desk_name'),
1701                 $session->param('register_id'),  $session->param('register_name')
1702             );
1703             return ( "ok", $cookie, $sessionID );
1704         } else {
1705             return ( "failed", undef, undef );
1706         }
1707     }
1708 }
1709
1710 =head2 check_cookie_auth
1711
1712   ($status, $sessionId) = check_cookie_auth($cookie, $userflags);
1713
1714 Given a CGISESSID cookie set during a previous login to Koha, determine
1715 if the user has the privileges specified by C<$userflags>. C<$userflags>
1716 is passed unaltered into C<haspermission> and as such accepts all options
1717 avaiable to that routine with the one caveat that C<check_api_auth> will
1718 also allow 'undef' to be passed and in such a case the permissions check
1719 will be skipped altogether.
1720
1721 C<check_cookie_auth> is meant for authenticating special services
1722 such as tools/upload-file.pl that are invoked by other pages that
1723 have been authenticated in the usual way.
1724
1725 Possible return values in C<$status> are:
1726
1727 =over
1728
1729 =item "ok" -- user authenticated; C<$sessionID> have valid values.
1730
1731 =item "anon" -- user not authenticated but valid for anonymous session.
1732
1733 =item "failed" -- credentials are not correct; C<$sessionid> are undef
1734
1735 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1736
1737 =item "expired -- session cookie has expired; API user should resubmit userid and password
1738
1739 =item "restricted" -- The IP has changed (if SessionRestrictionByIP)
1740
1741 =back
1742
1743 =cut
1744
1745 sub check_cookie_auth {
1746     my $sessionID     = shift;
1747     my $flagsrequired = shift;
1748     my $params        = shift;
1749
1750     my $remote_addr = $params->{remote_addr} || $ENV{REMOTE_ADDR};
1751
1752     my $skip_version_check = $params->{skip_version_check}; # Only for checkauth
1753
1754     unless ( $skip_version_check ) {
1755         unless ( C4::Context->preference('Version') ) {
1756
1757             # database has not been installed yet
1758             return ( "maintenance", undef );
1759         }
1760         my $kohaversion = Koha::version();
1761         $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1762         if ( C4::Context->preference('Version') < $kohaversion ) {
1763
1764             # database in need of version update; assume that
1765             # no API should be called while databsae is in
1766             # this condition.
1767             return ( "maintenance", undef );
1768         }
1769     }
1770
1771     # see if we have a valid session cookie already
1772     # however, if a userid parameter is present (i.e., from
1773     # a form submission, assume that any current cookie
1774     # is to be ignored
1775     unless ( $sessionID ) {
1776         return ( "failed", undef );
1777     }
1778     C4::Context::_unset_userenv($sessionID); # remove old userenv first
1779     my $session   = get_session($sessionID);
1780     if ($session) {
1781         my $userid   = $session->param('id');
1782         my $ip       = $session->param('ip');
1783         my $lasttime = $session->param('lasttime');
1784         my $timeout = _timeout_syspref();
1785
1786         if ( !$lasttime || ( $lasttime < time() - $timeout ) ) {
1787             # time out
1788             $session->delete();
1789             $session->flush;
1790             return ("expired", undef);
1791
1792         } elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $remote_addr ) {
1793             # IP address changed
1794             $session->delete();
1795             $session->flush;
1796             return ( "restricted", undef, { old_ip => $ip, new_ip => $remote_addr});
1797
1798         } elsif ( $userid ) {
1799             $session->param( 'lasttime', time() );
1800             my $patron = Koha::Patrons->find({ userid => $userid });
1801             $patron = Koha::Patron->find({ cardnumber => $userid }) unless $patron;
1802             return ("password_expired", undef ) if $patron->password_expired;
1803             my $flags = defined($flagsrequired) ? haspermission( $userid, $flagsrequired ) : 1;
1804             if ($flags) {
1805                 C4::Context->_new_userenv($sessionID);
1806                 C4::Context->interface($session->param('interface'));
1807                 C4::Context->set_userenv(
1808                     $session->param('number'),       $session->param('id') // '',
1809                     $session->param('cardnumber'),   $session->param('firstname'),
1810                     $session->param('surname'),      $session->param('branch'),
1811                     $session->param('branchname'),   $session->param('flags'),
1812                     $session->param('emailaddress'), $session->param('shibboleth'),
1813                     $session->param('desk_id'),      $session->param('desk_name'),
1814                     $session->param('register_id'),  $session->param('register_name')
1815                 );
1816                 return ( "additional-auth-needed", $session )
1817                     if $session->param('waiting-for-2FA');
1818
1819                 return ( "ok", $session );
1820             } else {
1821                 $session->delete();
1822                 $session->flush;
1823                 return ( "failed", undef );
1824             }
1825
1826         } else {
1827             C4::Context->_new_userenv($sessionID);
1828             C4::Context->interface($session->param('interface'));
1829             C4::Context->set_userenv( undef, q{} );
1830             return ( "anon", $session );
1831         }
1832     } else {
1833         return ( "expired", undef );
1834     }
1835 }
1836
1837 =head2 get_session
1838
1839   use CGI::Session;
1840   my $session = get_session($sessionID);
1841
1842 Given a session ID, retrieve the CGI::Session object used to store
1843 the session's state.  The session object can be used to store
1844 data that needs to be accessed by different scripts during a
1845 user's session.
1846
1847 If the C<$sessionID> parameter is an empty string, a new session
1848 will be created.
1849
1850 =cut
1851
1852 sub _get_session_params {
1853     my $storage_method = C4::Context->preference('SessionStorage');
1854     if ( $storage_method eq 'mysql' ) {
1855         my $dbh = C4::Context->dbh;
1856         return { dsn => "serializer:yamlxs;driver:MySQL;id:md5", dsn_args => { Handle => $dbh } };
1857     }
1858     elsif ( $storage_method eq 'Pg' ) {
1859         my $dbh = C4::Context->dbh;
1860         return { dsn => "serializer:yamlxs;driver:PostgreSQL;id:md5", dsn_args => { Handle => $dbh } };
1861     }
1862     elsif ( $storage_method eq 'memcached' && Koha::Caches->get_instance->memcached_cache ) {
1863         my $memcached = Koha::Caches->get_instance()->memcached_cache;
1864         return { dsn => "serializer:yamlxs;driver:memcached;id:md5", dsn_args => { Memcached => $memcached } };
1865     }
1866     else {
1867         # catch all defaults to tmp should work on all systems
1868         my $dir = C4::Context::temporary_directory;
1869         my $instance = C4::Context->config( 'database' ); #actually for packages not exactly the instance name, but generally safer to leave it as it is
1870         return { dsn => "serializer:yamlxs;driver:File;id:md5", dsn_args => { Directory => "$dir/cgisess_$instance" } };
1871     }
1872 }
1873
1874 sub get_session {
1875     my $sessionID      = shift;
1876     my $params = _get_session_params();
1877     my $session;
1878     if( $sessionID ) { # find existing
1879         CGI::Session::ErrorHandler->set_error( q{} ); # clear error, cpan issue #111463
1880         $session = CGI::Session->load( $params->{dsn}, $sessionID, $params->{dsn_args} );
1881     } else {
1882         $session = CGI::Session->new( $params->{dsn}, $sessionID, $params->{dsn_args} );
1883         # no need to flush here
1884     }
1885     return $session;
1886 }
1887
1888
1889 # FIXME no_set_userenv may be replaced with force_branchcode_for_userenv
1890 # (or something similar)
1891 # Currently it's only passed from C4::SIP::ILS::Patron::check_password, but
1892 # not having a userenv defined could cause a crash.
1893 sub checkpw {
1894     my ( $dbh, $userid, $password, $query, $type, $no_set_userenv ) = @_;
1895     $type = 'opac' unless $type;
1896
1897     # Get shibboleth login attribute
1898     my $shib = C4::Context->config('useshibboleth') && shib_ok();
1899     my $shib_login = $shib ? get_login_shib() : undef;
1900
1901     my @return;
1902     my $patron;
1903     if ( defined $userid ){
1904         $patron = Koha::Patrons->find({ userid => $userid });
1905         $patron = Koha::Patrons->find({ cardnumber => $userid }) unless $patron;
1906     }
1907     my $check_internal_as_fallback = 0;
1908     my $passwd_ok = 0;
1909     # Note: checkpw_* routines returns:
1910     # 1 if auth is ok
1911     # 0 if auth is nok
1912     # -1 if user bind failed (LDAP only)
1913
1914     if ( $patron and ( $patron->account_locked )  ) {
1915         # Nothing to check, account is locked
1916     } elsif ($ldap && defined($password)) {
1917         my ( $retval, $retcard, $retuserid ) = checkpw_ldap(@_);    # EXTERNAL AUTH
1918         if ( $retval == 1 ) {
1919             @return = ( $retval, $retcard, $retuserid );
1920             $passwd_ok = 1;
1921         }
1922         $check_internal_as_fallback = 1 if $retval == 0;
1923
1924     } elsif ( $cas && $query && $query->param('ticket') ) {
1925
1926         # In case of a CAS authentication, we use the ticket instead of the password
1927         my $ticket = $query->param('ticket');
1928         $query->delete('ticket');                                   # remove ticket to come back to original URL
1929         my ( $retval, $retcard, $retuserid, $cas_ticket ) = checkpw_cas( $dbh, $ticket, $query, $type );    # EXTERNAL AUTH
1930         if ( $retval ) {
1931             @return = ( $retval, $retcard, $retuserid, $cas_ticket );
1932         } else {
1933             @return = (0);
1934         }
1935         $passwd_ok = $retval;
1936     }
1937
1938     # If we are in a shibboleth session (shibboleth is enabled, and a shibboleth match attribute is present)
1939     # Check for password to asertain whether we want to be testing against shibboleth or another method this
1940     # time around.
1941     elsif ( $shib && $shib_login && !$password ) {
1942
1943         # In case of a Shibboleth authentication, we expect a shibboleth user attribute
1944         # (defined under shibboleth mapping in koha-conf.xml) to contain the login of the
1945         # shibboleth-authenticated user
1946
1947         # Then, we check if it matches a valid koha user
1948         if ($shib_login) {
1949             my ( $retval, $retcard, $retuserid ) = C4::Auth_with_shibboleth::checkpw_shib($shib_login);    # EXTERNAL AUTH
1950             if ( $retval ) {
1951                 @return = ( $retval, $retcard, $retuserid );
1952             }
1953             $passwd_ok = $retval;
1954         }
1955     } else {
1956         $check_internal_as_fallback = 1;
1957     }
1958
1959     # INTERNAL AUTH
1960     if ( $check_internal_as_fallback ) {
1961         @return = checkpw_internal( $dbh, $userid, $password, $no_set_userenv);
1962         $passwd_ok = 1 if $return[0] > 0; # 1 or 2
1963     }
1964
1965     if( $patron ) {
1966         if ( $passwd_ok ) {
1967             $patron->update({ login_attempts => 0 });
1968             if( $patron->password_expired ){
1969                 @return = (-2);
1970             }
1971         } elsif( !$patron->account_locked ) {
1972             $patron->update({ login_attempts => $patron->login_attempts + 1 });
1973         }
1974     }
1975
1976     # Optionally log success or failure
1977     if( $patron && $passwd_ok && C4::Context->preference('AuthSuccessLog') ) {
1978         logaction( 'AUTH', 'SUCCESS', $patron->id, "Valid password for $userid", $type );
1979     } elsif( !$passwd_ok && C4::Context->preference('AuthFailureLog') ) {
1980         logaction( 'AUTH', 'FAILURE', $patron ? $patron->id : 0, "Wrong password for $userid", $type );
1981     }
1982
1983     return @return;
1984 }
1985
1986 sub checkpw_internal {
1987     my ( $dbh, $userid, $password, $no_set_userenv ) = @_;
1988
1989     $password = Encode::encode( 'UTF-8', $password )
1990       if Encode::is_utf8($password);
1991
1992     my $sth =
1993       $dbh->prepare(
1994         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where userid=?"
1995       );
1996     $sth->execute($userid);
1997     if ( $sth->rows ) {
1998         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
1999             $surname, $branchcode, $branchname, $flags )
2000           = $sth->fetchrow;
2001
2002         if ( checkpw_hash( $password, $stored_hash ) ) {
2003
2004             C4::Context->set_userenv( "$borrowernumber", $userid, $cardnumber,
2005                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2006             return 1, $cardnumber, $userid;
2007         }
2008     }
2009     $sth =
2010       $dbh->prepare(
2011         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
2012       );
2013     $sth->execute($userid);
2014     if ( $sth->rows ) {
2015         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2016             $surname, $branchcode, $branchname, $flags )
2017           = $sth->fetchrow;
2018
2019         if ( checkpw_hash( $password, $stored_hash ) ) {
2020
2021             C4::Context->set_userenv( $borrowernumber, $userid, $cardnumber,
2022                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2023             return 1, $cardnumber, $userid;
2024         }
2025     }
2026     return 0;
2027 }
2028
2029 sub checkpw_hash {
2030     my ( $password, $stored_hash ) = @_;
2031
2032     return if $stored_hash eq '!';
2033
2034     # check what encryption algorithm was implemented: Bcrypt - if the hash starts with '$2' it is Bcrypt else md5
2035     my $hash;
2036     if ( substr( $stored_hash, 0, 2 ) eq '$2' ) {
2037         $hash = hash_password( $password, $stored_hash );
2038     } else {
2039         $hash = md5_base64($password);
2040     }
2041     return $hash eq $stored_hash;
2042 }
2043
2044 =head2 getuserflags
2045
2046     my $authflags = getuserflags($flags, $userid, [$dbh]);
2047
2048 Translates integer flags into permissions strings hash.
2049
2050 C<$flags> is the integer userflags value ( borrowers.userflags )
2051 C<$userid> is the members.userid, used for building subpermissions
2052 C<$authflags> is a hashref of permissions
2053
2054 =cut
2055
2056 sub getuserflags {
2057     my $flags  = shift;
2058     my $userid = shift;
2059     my $dbh    = @_ ? shift : C4::Context->dbh;
2060     my $userflags;
2061     {
2062         # I don't want to do this, but if someone logs in as the database
2063         # user, it would be preferable not to spam them to death with
2064         # numeric warnings. So, we make $flags numeric.
2065         no warnings 'numeric';
2066         $flags += 0;
2067     }
2068     my $sth = $dbh->prepare("SELECT bit, flag, defaulton FROM userflags");
2069     $sth->execute;
2070
2071     while ( my ( $bit, $flag, $defaulton ) = $sth->fetchrow ) {
2072         if ( ( $flags & ( 2**$bit ) ) || $defaulton ) {
2073             $userflags->{$flag} = 1;
2074         }
2075         else {
2076             $userflags->{$flag} = 0;
2077         }
2078     }
2079
2080     # get subpermissions and merge with top-level permissions
2081     my $user_subperms = get_user_subpermissions($userid);
2082     foreach my $module ( keys %$user_subperms ) {
2083         next if $userflags->{$module} == 1;    # user already has permission for everything in this module
2084         $userflags->{$module} = $user_subperms->{$module};
2085     }
2086
2087     return $userflags;
2088 }
2089
2090 =head2 get_user_subpermissions
2091
2092   $user_perm_hashref = get_user_subpermissions($userid);
2093
2094 Given the userid (note, not the borrowernumber) of a staff user,
2095 return a hashref of hashrefs of the specific subpermissions
2096 accorded to the user.  An example return is
2097
2098  {
2099     tools => {
2100         export_catalog => 1,
2101         import_patrons => 1,
2102     }
2103  }
2104
2105 The top-level hash-key is a module or function code from
2106 userflags.flag, while the second-level key is a code
2107 from permissions.
2108
2109 The results of this function do not give a complete picture
2110 of the functions that a staff user can access; it is also
2111 necessary to check borrowers.flags.
2112
2113 =cut
2114
2115 sub get_user_subpermissions {
2116     my $userid = shift;
2117
2118     my $dbh = C4::Context->dbh;
2119     my $sth = $dbh->prepare( "SELECT flag, user_permissions.code
2120                              FROM user_permissions
2121                              JOIN permissions USING (module_bit, code)
2122                              JOIN userflags ON (module_bit = bit)
2123                              JOIN borrowers USING (borrowernumber)
2124                              WHERE userid = ?" );
2125     $sth->execute($userid);
2126
2127     my $user_perms = {};
2128     while ( my $perm = $sth->fetchrow_hashref ) {
2129         $user_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2130     }
2131     return $user_perms;
2132 }
2133
2134 =head2 get_all_subpermissions
2135
2136   my $perm_hashref = get_all_subpermissions();
2137
2138 Returns a hashref of hashrefs defining all specific
2139 permissions currently defined.  The return value
2140 has the same structure as that of C<get_user_subpermissions>,
2141 except that the innermost hash value is the description
2142 of the subpermission.
2143
2144 =cut
2145
2146 sub get_all_subpermissions {
2147     my $dbh = C4::Context->dbh;
2148     my $sth = $dbh->prepare( "SELECT flag, code
2149                              FROM permissions
2150                              JOIN userflags ON (module_bit = bit)" );
2151     $sth->execute();
2152
2153     my $all_perms = {};
2154     while ( my $perm = $sth->fetchrow_hashref ) {
2155         $all_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2156     }
2157     return $all_perms;
2158 }
2159
2160 =head2 haspermission
2161
2162   $flagsrequired = '*';                                 # Any permission at all
2163   $flagsrequired = 'a_flag';                            # a_flag must be satisfied (all subpermissions)
2164   $flagsrequired = [ 'a_flag', 'b_flag' ];              # a_flag OR b_flag must be satisfied
2165   $flagsrequired = { 'a_flag => 1, 'b_flag' => 1 };     # a_flag AND b_flag must be satisfied
2166   $flagsrequired = { 'a_flag' => 'sub_a' };             # sub_a of a_flag must be satisfied
2167   $flagsrequired = { 'a_flag' => [ 'sub_a, 'sub_b' ] }; # sub_a OR sub_b of a_flag must be satisfied
2168
2169   $flags = ($userid, $flagsrequired);
2170
2171 C<$userid> the userid of the member
2172 C<$flags> is a query structure similar to that used by SQL::Abstract that
2173 denotes the combination of flags required. It is a required parameter.
2174
2175 The main logic of this method is that things in arrays are OR'ed, and things
2176 in hashes are AND'ed. The `*` character can be used, at any depth, to denote `ANY`
2177
2178 Returns member's flags or 0 if a permission is not met.
2179
2180 =cut
2181
2182 sub _dispatch {
2183     my ($required, $flags) = @_;
2184
2185     my $ref = ref($required);
2186     if ($ref eq '') {
2187         if ($required eq '*') {
2188             return 0 unless ( $flags or ref( $flags ) );
2189         } else {
2190             return 0 unless ( $flags and (!ref( $flags ) || $flags->{$required} ));
2191         }
2192     } elsif ($ref eq 'HASH') {
2193         foreach my $key (keys %{$required}) {
2194             next if $flags == 1;
2195             my $require = $required->{$key};
2196             my $rflags  = $flags->{$key};
2197             return 0 unless _dispatch($require, $rflags);
2198         }
2199     } elsif ($ref eq 'ARRAY') {
2200         my $satisfied = 0;
2201         foreach my $require ( @{$required} ) {
2202             my $rflags =
2203               ( ref($flags) && !ref($require) && ( $require ne '*' ) )
2204               ? $flags->{$require}
2205               : $flags;
2206             $satisfied++ if _dispatch( $require, $rflags );
2207         }
2208         return 0 unless $satisfied;
2209     } else {
2210         croak "Unexpected structure found: $ref";
2211     }
2212
2213     return $flags;
2214 };
2215
2216 sub haspermission {
2217     my ( $userid, $flagsrequired ) = @_;
2218
2219     #Koha::Exceptions::WrongParameter->throw('$flagsrequired should not be undef')
2220     #  unless defined($flagsrequired);
2221
2222     my $sth = C4::Context->dbh->prepare("SELECT flags FROM borrowers WHERE userid=?");
2223     $sth->execute($userid);
2224     my $row = $sth->fetchrow();
2225     my $flags = getuserflags( $row, $userid );
2226
2227     return $flags unless defined($flagsrequired);
2228     return $flags if $flags->{superlibrarian};
2229     return _dispatch($flagsrequired, $flags);
2230
2231     #FIXME - This fcn should return the failed permission so a suitable error msg can be delivered.
2232 }
2233
2234 =head2 in_iprange
2235
2236   $flags = ($iprange);
2237
2238 C<$iprange> A space separated string describing an IP range. Can include single IPs or ranges
2239
2240 Returns 1 if the remote address is in the provided iprange, or 0 otherwise.
2241
2242 =cut
2243
2244 sub in_iprange {
2245     my ($iprange) = @_;
2246     my $result = 1;
2247     my @allowedipranges = $iprange ? split(' ', $iprange) : ();
2248     if (scalar @allowedipranges > 0) {
2249         my @rangelist;
2250         eval { @rangelist = Net::CIDR::range2cidr(@allowedipranges); }; return 0 if $@;
2251         eval { $result = Net::CIDR::cidrlookup($ENV{'REMOTE_ADDR'}, @rangelist) } || Koha::Logger->get->warn('cidrlookup failed for ' . join(' ',@rangelist) );
2252      }
2253      return $result ? 1 : 0;
2254 }
2255
2256 sub getborrowernumber {
2257     my ($userid) = @_;
2258     my $userenv = C4::Context->userenv;
2259     if ( defined($userenv) && ref($userenv) eq 'HASH' && $userenv->{number} ) {
2260         return $userenv->{number};
2261     }
2262     my $dbh = C4::Context->dbh;
2263     for my $field ( 'userid', 'cardnumber' ) {
2264         my $sth =
2265           $dbh->prepare("select borrowernumber from borrowers where $field=?");
2266         $sth->execute($userid);
2267         if ( $sth->rows ) {
2268             my ($bnumber) = $sth->fetchrow;
2269             return $bnumber;
2270         }
2271     }
2272     return 0;
2273 }
2274
2275 =head2 track_login_daily
2276
2277     track_login_daily( $userid );
2278
2279 Wraps the call to $patron->track_login, the method used to update borrowers.lastseen. We only call track_login once a day.
2280
2281 =cut
2282
2283 sub track_login_daily {
2284     my $userid = shift;
2285     return if !$userid || !C4::Context->preference('TrackLastPatronActivity');
2286
2287     my $cache     = Koha::Caches->get_instance();
2288     my $cache_key = "track_login_" . $userid;
2289     my $cached    = $cache->get_from_cache($cache_key);
2290     my $today = dt_from_string()->ymd;
2291     return if $cached && $cached eq $today;
2292
2293     my $patron = Koha::Patrons->find({ userid => $userid });
2294     return unless $patron;
2295     $patron->track_login;
2296     $cache->set_in_cache( $cache_key, $today );
2297 }
2298
2299 END { }    # module clean-up code here (global destructor)
2300 1;
2301 __END__
2302
2303 =head1 SEE ALSO
2304
2305 CGI(3)
2306
2307 C4::Output(3)
2308
2309 Crypt::Eksblowfish::Bcrypt(3)
2310
2311 Digest::MD5(3)
2312
2313 =cut