C4/Auth.pm

   1 package C4::Auth;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22 use Digest::MD5 qw(md5_base64);
  23 use JSON qw/encode_json/;
  24 use URI::Escape;
  25 use CGI::Session;
  26
  27 require Exporter;
  28 use C4::Context;
  29 use C4::Templates;    # to get the template
  30 use C4::Languages;
  31 use C4::Branch;       # GetBranches
  32 use C4::Search::History;
  33 use Koha;
  34 use Koha::AuthUtils qw(hash_password);
  35 use POSIX qw/strftime/;
  36 use List::MoreUtils qw/ any /;
  37 use Encode qw( encode is_utf8);
  38
  39 # use utf8;
  40 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug $ldap $cas $caslogout $shib $shib_login);
  41
  42 BEGIN {
  43     sub psgi_env { any { /^psgi\./ } keys %ENV }
  44
  45     sub safe_exit {
  46         if   (psgi_env) { die 'psgi:exit' }
  47         else            { exit }
  48     }
  49     $VERSION = 3.07.00.049;    # set version for version checking
  50
  51     $debug     = $ENV{DEBUG};
  52     @ISA       = qw(Exporter);
  53     @EXPORT    = qw(&checkauth &get_template_and_user &haspermission &get_user_subpermissions);
  54     @EXPORT_OK = qw(&check_api_auth &get_session &check_cookie_auth &checkpw &checkpw_internal &checkpw_hash
  55       &get_all_subpermissions &get_user_subpermissions
  56     );
  57     %EXPORT_TAGS = ( EditPermissions => [qw(get_all_subpermissions get_user_subpermissions)] );
  58     $ldap      = C4::Context->config('useldapserver') || 0;
  59     $cas       = C4::Context->preference('casAuthentication');
  60     $shib      = C4::Context->config('useshibboleth') || 0;
  61     $caslogout = C4::Context->preference('casLogout');
  62     require C4::Auth_with_cas;    # no import
  63
  64     if ($ldap) {
  65         require C4::Auth_with_ldap;
  66         import C4::Auth_with_ldap qw(checkpw_ldap);
  67     }
  68     if ($shib) {
  69         require C4::Auth_with_shibboleth;
  70         import C4::Auth_with_shibboleth
  71           qw(shib_ok checkpw_shib logout_shib login_shib_url get_login_shib);
  72
  73         # Check for good config
  74         if ( shib_ok() ) {
  75
  76             # Get shibboleth login attribute
  77             $shib_login = get_login_shib();
  78         }
  79
  80         # Bad config, disable shibboleth
  81         else {
  82             $shib = 0;
  83         }
  84     }
  85     if ($cas) {
  86         import C4::Auth_with_cas qw(check_api_auth_cas checkpw_cas login_cas logout_cas login_cas_url);
  87     }
  88
  89 }
  90
  91 =head1 NAME
  92
  93 C4::Auth - Authenticates Koha users
  94
  95 =head1 SYNOPSIS
  96
  97   use CGI qw ( -utf8 );
  98   use C4::Auth;
  99   use C4::Output;
 100
 101   my $query = new CGI;
 102
 103   my ($template, $borrowernumber, $cookie)
 104     = get_template_and_user(
 105         {
 106             template_name   => "opac-main.tt",
 107             query           => $query,
 108       type            => "opac",
 109       authnotrequired => 0,
 110       flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 111   }
 112     );
 113
 114   output_html_with_http_headers $query, $cookie, $template->output;
 115
 116 =head1 DESCRIPTION
 117
 118 The main function of this module is to provide
 119 authentification. However the get_template_and_user function has
 120 been provided so that a users login information is passed along
 121 automatically. This gets loaded into the template.
 122
 123 =head1 FUNCTIONS
 124
 125 =head2 get_template_and_user
 126
 127  my ($template, $borrowernumber, $cookie)
 128      = get_template_and_user(
 129        {
 130          template_name   => "opac-main.tt",
 131          query           => $query,
 132          type            => "opac",
 133          authnotrequired => 0,
 134          flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 135        }
 136      );
 137
 138 This call passes the C<query>, C<flagsrequired> and C<authnotrequired>
 139 to C<&checkauth> (in this module) to perform authentification.
 140 See C<&checkauth> for an explanation of these parameters.
 141
 142 The C<template_name> is then used to find the correct template for
 143 the page. The authenticated users details are loaded onto the
 144 template in the HTML::Template LOOP variable C<USER_INFO>. Also the
 145 C<sessionID> is passed to the template. This can be used in templates
 146 if cookies are disabled. It needs to be put as and input to every
 147 authenticated page.
 148
 149 More information on the C<gettemplate> sub can be found in the
 150 Output.pm module.
 151
 152 =cut
 153
 154 sub get_template_and_user {
 155
 156     my $in = shift;
 157     my ( $user, $cookie, $sessionID, $flags );
 158
 159     C4::Context->interface( $in->{type} );
 160
 161     my $safe_chars = 'a-zA-Z0-9_\-\/';
 162     die "bad template path" unless $in->{'template_name'} =~ m/^[$safe_chars]+\.tt$/ig; #sanitize input
 163
 164     $in->{'authnotrequired'} ||= 0;
 165     my $template = C4::Templates::gettemplate(
 166         $in->{'template_name'},
 167         $in->{'type'},
 168         $in->{'query'},
 169         $in->{'is_plugin'}
 170     );
 171
 172     if ( $in->{'template_name'} !~ m/maintenance/ ) {
 173         ( $user, $cookie, $sessionID, $flags ) = checkauth(
 174             $in->{'query'},
 175             $in->{'authnotrequired'},
 176             $in->{'flagsrequired'},
 177             $in->{'type'}
 178         );
 179     }
 180
 181
 182     # If the user logged in is the SCO user and he tries to go out the SCO module, log the user out removing the CGISESSID cookie
 183     if ( $in->{type} eq 'opac' and $in->{template_name} !~ m|sco/| ) {
 184         if (  C4::Context->preference('AutoSelfCheckID') && $user eq C4::Context->preference('AutoSelfCheckID') ) {
 185             $template = C4::Templates::gettemplate( 'opac-auth.tt', 'opac', $in->{query} );
 186             my $cookie = $in->{query}->cookie(
 187                 -name     => 'CGISESSID',
 188                 -value    => '',
 189                 -expires  => '',
 190                 -HttpOnly => 1,
 191             );
 192
 193             $template->param( loginprompt => 1 );
 194             print $in->{query}->header(
 195                 -type    => 'text/html',
 196                 -charset => 'utf-8',
 197                 -cookie  => $cookie,
 198               ),
 199             $template->output;
 200             safe_exit;
 201         }
 202     }
 203
 204     my $borrowernumber;
 205     if ($user) {
 206         require C4::Members;
 207
 208         # It's possible for $user to be the borrowernumber if they don't have a
 209         # userid defined (and are logging in through some other method, such
 210         # as SSL certs against an email address)
 211         $borrowernumber = getborrowernumber($user) if defined($user);
 212         if ( !defined($borrowernumber) && defined($user) ) {
 213             my $borrower = C4::Members::GetMember( borrowernumber => $user );
 214             if ($borrower) {
 215                 $borrowernumber = $user;
 216
 217                 # A bit of a hack, but I don't know there's a nicer way
 218                 # to do it.
 219                 $user = $borrower->{firstname} . ' ' . $borrower->{surname};
 220             }
 221         }
 222
 223         # user info
 224         $template->param( loggedinusername   => $user );
 225         $template->param( loggedinusernumber => $borrowernumber );
 226         $template->param( sessionID          => $sessionID );
 227
 228         if ( $in->{'type'} eq 'opac' ) {
 229             require Koha::Virtualshelves;
 230             my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 231                 {
 232                     borrowernumber => $borrowernumber,
 233                     category       => 1,
 234                 }
 235             );
 236             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 237                 {
 238                     category       => 2,
 239                 }
 240             );
 241             $template->param(
 242                 some_private_shelves => $some_private_shelves,
 243                 some_public_shelves  => $some_public_shelves,
 244             );
 245         }
 246
 247         my ($borr) = C4::Members::GetMemberDetails($borrowernumber);
 248         my @bordat;
 249         $bordat[0] = $borr;
 250         $template->param( "USER_INFO" => \@bordat );
 251
 252         my $all_perms = get_all_subpermissions();
 253
 254         my @flagroots = qw(circulate catalogue parameters borrowers permissions reserveforothers borrow
 255           editcatalogue updatecharges management tools editauthorities serials reports acquisition);
 256
 257         # We are going to use the $flags returned by checkauth
 258         # to create the template's parameters that will indicate
 259         # which menus the user can access.
 260         if ( $flags && $flags->{superlibrarian} == 1 ) {
 261             $template->param( CAN_user_circulate        => 1 );
 262             $template->param( CAN_user_catalogue        => 1 );
 263             $template->param( CAN_user_parameters       => 1 );
 264             $template->param( CAN_user_borrowers        => 1 );
 265             $template->param( CAN_user_permissions      => 1 );
 266             $template->param( CAN_user_reserveforothers => 1 );
 267             $template->param( CAN_user_editcatalogue    => 1 );
 268             $template->param( CAN_user_updatecharges    => 1 );
 269             $template->param( CAN_user_acquisition      => 1 );
 270             $template->param( CAN_user_management       => 1 );
 271             $template->param( CAN_user_tools            => 1 );
 272             $template->param( CAN_user_editauthorities  => 1 );
 273             $template->param( CAN_user_serials          => 1 );
 274             $template->param( CAN_user_reports          => 1 );
 275             $template->param( CAN_user_staffaccess      => 1 );
 276             $template->param( CAN_user_plugins          => 1 );
 277             $template->param( CAN_user_coursereserves   => 1 );
 278             foreach my $module ( keys %$all_perms ) {
 279
 280                 foreach my $subperm ( keys %{ $all_perms->{$module} } ) {
 281                     $template->param( "CAN_user_${module}_${subperm}" => 1 );
 282                 }
 283             }
 284         }
 285
 286         if ($flags) {
 287             foreach my $module ( keys %$all_perms ) {
 288                 if ( defined($flags->{$module}) && $flags->{$module} == 1 ) {
 289                     foreach my $subperm ( keys %{ $all_perms->{$module} } ) {
 290                         $template->param( "CAN_user_${module}_${subperm}" => 1 );
 291                     }
 292                 } elsif ( ref( $flags->{$module} ) ) {
 293                     foreach my $subperm ( keys %{ $flags->{$module} } ) {
 294                         $template->param( "CAN_user_${module}_${subperm}" => 1 );
 295                     }
 296                 }
 297             }
 298         }
 299
 300         if ($flags) {
 301             foreach my $module ( keys %$flags ) {
 302                 if ( $flags->{$module} == 1 or ref( $flags->{$module} ) ) {
 303                     $template->param( "CAN_user_$module" => 1 );
 304                     if ( $module eq "parameters" ) {
 305                         $template->param( CAN_user_management => 1 );
 306                     }
 307                 }
 308             }
 309         }
 310
 311         # Logged-in opac search history
 312         # If the requested template is an opac one and opac search history is enabled
 313         if ( $in->{type} eq 'opac' && C4::Context->preference('EnableOpacSearchHistory') ) {
 314             my $dbh   = C4::Context->dbh;
 315             my $query = "SELECT COUNT(*) FROM search_history WHERE userid=?";
 316             my $sth   = $dbh->prepare($query);
 317             $sth->execute($borrowernumber);
 318
 319             # If at least one search has already been performed
 320             if ( $sth->fetchrow_array > 0 ) {
 321
 322                 # We show the link in opac
 323                 $template->param( EnableOpacSearchHistory => 1 );
 324             }
 325
 326             # And if there are searches performed when the user was not logged in,
 327             # we add them to the logged-in search history
 328             my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 329             if (@recentSearches) {
 330                 my $dbh   = C4::Context->dbh;
 331                 my $query = q{
 332                     INSERT INTO search_history(userid, sessionid, query_desc, query_cgi, type,  total, time )
 333                     VALUES (?, ?, ?, ?, ?, ?, ?)
 334                 };
 335
 336                 my $sth = $dbh->prepare($query);
 337                 $sth->execute( $borrowernumber,
 338                     $in->{query}->cookie("CGISESSID"),
 339                     $_->{query_desc},
 340                     $_->{query_cgi},
 341                     $_->{type} || 'biblio',
 342                     $_->{total},
 343                     $_->{time},
 344                 ) foreach @recentSearches;
 345
 346                 # clear out the search history from the session now that
 347                 # we've saved it to the database
 348                 C4::Search::History::set_to_session( { cgi => $in->{'query'}, search_history => [] } );
 349             }
 350         } elsif ( $in->{type} eq 'intranet' and C4::Context->preference('EnableSearchHistory') ) {
 351             $template->param( EnableSearchHistory => 1 );
 352         }
 353     }
 354     else {    # if this is an anonymous session, setup to display public lists...
 355
 356         # If shibboleth is enabled, and we're in an anonymous session, we should allow
 357         # the user to attempt login via shibboleth.
 358         if ($shib) {
 359             $template->param( shibbolethAuthentication => $shib,
 360                 shibbolethLoginUrl => login_shib_url( $in->{'query'} ),
 361             );
 362
 363             # If shibboleth is enabled and we have a shibboleth login attribute,
 364             # but we are in an anonymous session, then we clearly have an invalid
 365             # shibboleth koha account.
 366             if ($shib_login) {
 367                 $template->param( invalidShibLogin => '1' );
 368             }
 369         }
 370
 371         $template->param( sessionID => $sessionID );
 372
 373         if ( $in->{'type'} eq 'opac' ){
 374             require Koha::Virtualshelves;
 375             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 376                 {
 377                     category       => 2,
 378                 }
 379             );
 380             $template->param(
 381                 some_public_shelves  => $some_public_shelves,
 382             );
 383         }
 384     }
 385
 386     # Anonymous opac search history
 387     # If opac search history is enabled and at least one search has already been performed
 388     if ( C4::Context->preference('EnableOpacSearchHistory') ) {
 389         my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 390         if (@recentSearches) {
 391             $template->param( EnableOpacSearchHistory => 1 );
 392         }
 393     }
 394
 395     if ( C4::Context->preference('dateformat') ) {
 396         $template->param( dateformat => C4::Context->preference('dateformat') );
 397     }
 398
 399     $template->param(auth_forwarded_hash => $in->{'query'}->param('auth_forwarded_hash'));
 400
 401     # these template parameters are set the same regardless of $in->{'type'}
 402
 403     # Set the using_https variable for templates
 404     # FIXME Under Plack the CGI->https method always returns 'OFF'
 405     my $https = $in->{query}->https();
 406     my $using_https = ( defined $https and $https ne 'OFF' ) ? 1 : 0;
 407
 408     $template->param(
 409         "BiblioDefaultView" . C4::Context->preference("BiblioDefaultView") => 1,
 410         EnhancedMessagingPreferences                                       => C4::Context->preference('EnhancedMessagingPreferences'),
 411         GoogleJackets                                                      => C4::Context->preference("GoogleJackets"),
 412         OpenLibraryCovers                                                  => C4::Context->preference("OpenLibraryCovers"),
 413         KohaAdminEmailAddress                                              => "" . C4::Context->preference("KohaAdminEmailAddress"),
 414         LoginBranchcode => ( C4::Context->userenv ? C4::Context->userenv->{"branch"}    : undef ),
 415         LoginFirstname  => ( C4::Context->userenv ? C4::Context->userenv->{"firstname"} : "Bel" ),
 416         LoginSurname    => C4::Context->userenv ? C4::Context->userenv->{"surname"}      : "Inconnu",
 417         emailaddress    => C4::Context->userenv ? C4::Context->userenv->{"emailaddress"} : undef,
 418         loggedinpersona => C4::Context->userenv ? C4::Context->userenv->{"persona"}      : undef,
 419         TagsEnabled     => C4::Context->preference("TagsEnabled"),
 420         hide_marc       => C4::Context->preference("hide_marc"),
 421         item_level_itypes  => C4::Context->preference('item-level_itypes'),
 422         patronimages       => C4::Context->preference("patronimages"),
 423         singleBranchMode   => C4::Context->preference("singleBranchMode"),
 424         XSLTDetailsDisplay => C4::Context->preference("XSLTDetailsDisplay"),
 425         XSLTResultsDisplay => C4::Context->preference("XSLTResultsDisplay"),
 426         using_https        => $using_https,
 427         noItemTypeImages   => C4::Context->preference("noItemTypeImages"),
 428         marcflavour        => C4::Context->preference("marcflavour"),
 429         persona            => C4::Context->preference("persona"),
 430         OPACBaseURL        => C4::Context->preference('OPACBaseURL'),
 431     );
 432     if ( $in->{'type'} eq "intranet" ) {
 433         $template->param(
 434             AmazonCoverImages                                                          => C4::Context->preference("AmazonCoverImages"),
 435             AutoLocation                                                               => C4::Context->preference("AutoLocation"),
 436             "BiblioDefaultView" . C4::Context->preference("IntranetBiblioDefaultView") => 1,
 437             CircAutocompl                                                              => C4::Context->preference("CircAutocompl"),
 438             FRBRizeEditions                                                            => C4::Context->preference("FRBRizeEditions"),
 439             IndependentBranches                                                        => C4::Context->preference("IndependentBranches"),
 440             IntranetNav                                                                => C4::Context->preference("IntranetNav"),
 441             IntranetmainUserblock                                                      => C4::Context->preference("IntranetmainUserblock"),
 442             LibraryName                                                                => C4::Context->preference("LibraryName"),
 443             LoginBranchname                                                            => ( C4::Context->userenv ? C4::Context->userenv->{"branchname"} : undef ),
 444             advancedMARCEditor                                                         => C4::Context->preference("advancedMARCEditor"),
 445             canreservefromotherbranches                                                => C4::Context->preference('canreservefromotherbranches'),
 446             intranetcolorstylesheet                                                    => C4::Context->preference("intranetcolorstylesheet"),
 447             IntranetFavicon                                                            => C4::Context->preference("IntranetFavicon"),
 448             intranetreadinghistory                                                     => C4::Context->preference("intranetreadinghistory"),
 449             intranetstylesheet                                                         => C4::Context->preference("intranetstylesheet"),
 450             IntranetUserCSS                                                            => C4::Context->preference("IntranetUserCSS"),
 451             IntranetUserJS                                                             => C4::Context->preference("IntranetUserJS"),
 452             intranetbookbag                                                            => C4::Context->preference("intranetbookbag"),
 453             suggestion                                                                 => C4::Context->preference("suggestion"),
 454             virtualshelves                                                             => C4::Context->preference("virtualshelves"),
 455             StaffSerialIssueDisplayCount                                               => C4::Context->preference("StaffSerialIssueDisplayCount"),
 456             EasyAnalyticalRecords                                                      => C4::Context->preference('EasyAnalyticalRecords'),
 457             LocalCoverImages                                                           => C4::Context->preference('LocalCoverImages'),
 458             OPACLocalCoverImages                                                       => C4::Context->preference('OPACLocalCoverImages'),
 459             AllowMultipleCovers                                                        => C4::Context->preference('AllowMultipleCovers'),
 460             EnableBorrowerFiles                                                        => C4::Context->preference('EnableBorrowerFiles'),
 461             UseKohaPlugins                                                             => C4::Context->preference('UseKohaPlugins'),
 462             UseCourseReserves                                                          => C4::Context->preference("UseCourseReserves"),
 463             useDischarge                                                               => C4::Context->preference('useDischarge'),
 464         );
 465     }
 466     else {
 467         warn "template type should be OPAC, here it is=[" . $in->{'type'} . "]" unless ( $in->{'type'} eq 'opac' );
 468
 469         #TODO : replace LibraryName syspref with 'system name', and remove this html processing
 470         my $LibraryNameTitle = C4::Context->preference("LibraryName");
 471         $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
 472         $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
 473
 474         # clean up the busc param in the session
 475         # if the page is not opac-detail and not the "add to list" page
 476         # and not the "edit comments" page
 477         if ( C4::Context->preference("OpacBrowseResults")
 478             && $in->{'template_name'} =~ /opac-(.+)\.(?:tt|tmpl)$/ ) {
 479             my $pagename = $1;
 480             unless ( $pagename =~ /^(?:MARC|ISBD)?detail$/
 481                 or $pagename =~ /^addbybiblionumber$/
 482                 or $pagename =~ /^review$/ ) {
 483                 my $sessionSearch = get_session( $sessionID || $in->{'query'}->cookie("CGISESSID") );
 484                 $sessionSearch->clear( ["busc"] ) if ( $sessionSearch->param("busc") );
 485             }
 486         }
 487
 488         # variables passed from CGI: opac_css_override and opac_search_limits.
 489         my $opac_search_limit   = $ENV{'OPAC_SEARCH_LIMIT'};
 490         my $opac_limit_override = $ENV{'OPAC_LIMIT_OVERRIDE'};
 491         my $opac_name           = '';
 492         if (
 493             ( $opac_limit_override && $opac_search_limit && $opac_search_limit =~ /branch:(\w+)/ ) ||
 494             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /branch:(\w+)/ ) ||
 495             ( $in->{'query'}->param('multibranchlimit') && $in->{'query'}->param('multibranchlimit') =~ /multibranchlimit-(\w+)/ )
 496           ) {
 497             $opac_name = $1;    # opac_search_limit is a branch, so we use it.
 498         } elsif ( $in->{'query'}->param('multibranchlimit') ) {
 499             $opac_name = $in->{'query'}->param('multibranchlimit');
 500         } elsif ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv && C4::Context->userenv->{'branch'} ) {
 501             $opac_name = C4::Context->userenv->{'branch'};
 502         }
 503
 504         $template->param(
 505             OpacAdditionalStylesheet                   => C4::Context->preference("OpacAdditionalStylesheet"),
 506             AnonSuggestions                       => "" . C4::Context->preference("AnonSuggestions"),
 507             AuthorisedValueImages                 => C4::Context->preference("AuthorisedValueImages"),
 508             BranchesLoop                          => GetBranchesLoop($opac_name),
 509             BranchCategoriesLoop                  => GetBranchCategories( 'searchdomain', 1, $opac_name ),
 510             LibraryName                           => "" . C4::Context->preference("LibraryName"),
 511             LibraryNameTitle                      => "" . $LibraryNameTitle,
 512             LoginBranchname                       => C4::Context->userenv ? C4::Context->userenv->{"branchname"} : "",
 513             OPACAmazonCoverImages                 => C4::Context->preference("OPACAmazonCoverImages"),
 514             OPACFRBRizeEditions                   => C4::Context->preference("OPACFRBRizeEditions"),
 515             OpacHighlightedWords                  => C4::Context->preference("OpacHighlightedWords"),
 516             OPACShelfBrowser                      => "" . C4::Context->preference("OPACShelfBrowser"),
 517             OPACURLOpenInNewWindow                => "" . C4::Context->preference("OPACURLOpenInNewWindow"),
 518             OPACUserCSS                           => "" . C4::Context->preference("OPACUserCSS"),
 519             OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
 520             opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
 521             opac_search_limit                     => $opac_search_limit,
 522             opac_limit_override                   => $opac_limit_override,
 523             OpacBrowser                           => C4::Context->preference("OpacBrowser"),
 524             OpacCloud                             => C4::Context->preference("OpacCloud"),
 525             OpacKohaUrl                           => C4::Context->preference("OpacKohaUrl"),
 526             OpacMainUserBlock                     => "" . C4::Context->preference("OpacMainUserBlock"),
 527             OpacNav                               => "" . C4::Context->preference("OpacNav"),
 528             OpacNavRight                          => "" . C4::Context->preference("OpacNavRight"),
 529             OpacNavBottom                         => "" . C4::Context->preference("OpacNavBottom"),
 530             OpacPasswordChange                    => C4::Context->preference("OpacPasswordChange"),
 531             OPACPatronDetails                     => C4::Context->preference("OPACPatronDetails"),
 532             OPACPrivacy                           => C4::Context->preference("OPACPrivacy"),
 533             OPACFinesTab                          => C4::Context->preference("OPACFinesTab"),
 534             OpacTopissue                          => C4::Context->preference("OpacTopissue"),
 535             RequestOnOpac                         => C4::Context->preference("RequestOnOpac"),
 536             'Version'                             => C4::Context->preference('Version'),
 537             hidelostitems                         => C4::Context->preference("hidelostitems"),
 538             mylibraryfirst                        => ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv ) ? C4::Context->userenv->{'branch'} : '',
 539             opaclayoutstylesheet                  => "" . C4::Context->preference("opaclayoutstylesheet"),
 540             opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
 541             opaccredits                           => "" . C4::Context->preference("opaccredits"),
 542             OpacFavicon                           => C4::Context->preference("OpacFavicon"),
 543             opacheader                            => "" . C4::Context->preference("opacheader"),
 544             opaclanguagesdisplay                  => "" . C4::Context->preference("opaclanguagesdisplay"),
 545             opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
 546             OPACUserJS                            => C4::Context->preference("OPACUserJS"),
 547             opacuserlogin                         => "" . C4::Context->preference("opacuserlogin"),
 548             ShowReviewer                          => C4::Context->preference("ShowReviewer"),
 549             ShowReviewerPhoto                     => C4::Context->preference("ShowReviewerPhoto"),
 550             suggestion                            => "" . C4::Context->preference("suggestion"),
 551             virtualshelves                        => "" . C4::Context->preference("virtualshelves"),
 552             OPACSerialIssueDisplayCount           => C4::Context->preference("OPACSerialIssueDisplayCount"),
 553             OPACXSLTDetailsDisplay                => C4::Context->preference("OPACXSLTDetailsDisplay"),
 554             OPACXSLTResultsDisplay                => C4::Context->preference("OPACXSLTResultsDisplay"),
 555             SyndeticsClientCode                   => C4::Context->preference("SyndeticsClientCode"),
 556             SyndeticsEnabled                      => C4::Context->preference("SyndeticsEnabled"),
 557             SyndeticsCoverImages                  => C4::Context->preference("SyndeticsCoverImages"),
 558             SyndeticsTOC                          => C4::Context->preference("SyndeticsTOC"),
 559             SyndeticsSummary                      => C4::Context->preference("SyndeticsSummary"),
 560             SyndeticsEditions                     => C4::Context->preference("SyndeticsEditions"),
 561             SyndeticsExcerpt                      => C4::Context->preference("SyndeticsExcerpt"),
 562             SyndeticsReviews                      => C4::Context->preference("SyndeticsReviews"),
 563             SyndeticsAuthorNotes                  => C4::Context->preference("SyndeticsAuthorNotes"),
 564             SyndeticsAwards                       => C4::Context->preference("SyndeticsAwards"),
 565             SyndeticsSeries                       => C4::Context->preference("SyndeticsSeries"),
 566             SyndeticsCoverImageSize               => C4::Context->preference("SyndeticsCoverImageSize"),
 567             OPACLocalCoverImages                  => C4::Context->preference("OPACLocalCoverImages"),
 568             PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
 569             PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
 570             useDischarge                 => C4::Context->preference('useDischarge'),
 571         );
 572
 573         $template->param( OpacPublic => '1' ) if ( $user || C4::Context->preference("OpacPublic") );
 574     }
 575
 576     # Check if we were asked using parameters to force a specific language
 577     if ( defined $in->{'query'}->param('language') ) {
 578
 579         # Extract the language, let C4::Languages::getlanguage choose
 580         # what to do
 581         my $language = C4::Languages::getlanguage( $in->{'query'} );
 582         my $languagecookie = C4::Templates::getlanguagecookie( $in->{'query'}, $language );
 583         if ( ref $cookie eq 'ARRAY' ) {
 584             push @{$cookie}, $languagecookie;
 585         } else {
 586             $cookie = [ $cookie, $languagecookie ];
 587         }
 588     }
 589
 590     return ( $template, $borrowernumber, $cookie, $flags );
 591 }
 592
 593 =head2 checkauth
 594
 595   ($userid, $cookie, $sessionID) = &checkauth($query, $noauth, $flagsrequired, $type);
 596
 597 Verifies that the user is authorized to run this script.  If
 598 the user is authorized, a (userid, cookie, session-id, flags)
 599 quadruple is returned.  If the user is not authorized but does
 600 not have the required privilege (see $flagsrequired below), it
 601 displays an error page and exits.  Otherwise, it displays the
 602 login page and exits.
 603
 604 Note that C<&checkauth> will return if and only if the user
 605 is authorized, so it should be called early on, before any
 606 unfinished operations (e.g., if you've opened a file, then
 607 C<&checkauth> won't close it for you).
 608
 609 C<$query> is the CGI object for the script calling C<&checkauth>.
 610
 611 The C<$noauth> argument is optional. If it is set, then no
 612 authorization is required for the script.
 613
 614 C<&checkauth> fetches user and session information from C<$query> and
 615 ensures that the user is authorized to run scripts that require
 616 authorization.
 617
 618 The C<$flagsrequired> argument specifies the required privileges
 619 the user must have if the username and password are correct.
 620 It should be specified as a reference-to-hash; keys in the hash
 621 should be the "flags" for the user, as specified in the Members
 622 intranet module. Any key specified must correspond to a "flag"
 623 in the userflags table. E.g., { circulate => 1 } would specify
 624 that the user must have the "circulate" privilege in order to
 625 proceed. To make sure that access control is correct, the
 626 C<$flagsrequired> parameter must be specified correctly.
 627
 628 Koha also has a concept of sub-permissions, also known as
 629 granular permissions.  This makes the value of each key
 630 in the C<flagsrequired> hash take on an additional
 631 meaning, i.e.,
 632
 633  1
 634
 635 The user must have access to all subfunctions of the module
 636 specified by the hash key.
 637
 638  *
 639
 640 The user must have access to at least one subfunction of the module
 641 specified by the hash key.
 642
 643  specific permission, e.g., 'export_catalog'
 644
 645 The user must have access to the specific subfunction list, which
 646 must correspond to a row in the permissions table.
 647
 648 The C<$type> argument specifies whether the template should be
 649 retrieved from the opac or intranet directory tree.  "opac" is
 650 assumed if it is not specified; however, if C<$type> is specified,
 651 "intranet" is assumed if it is not "opac".
 652
 653 If C<$query> does not have a valid session ID associated with it
 654 (i.e., the user has not logged in) or if the session has expired,
 655 C<&checkauth> presents the user with a login page (from the point of
 656 view of the original script, C<&checkauth> does not return). Once the
 657 user has authenticated, C<&checkauth> restarts the original script
 658 (this time, C<&checkauth> returns).
 659
 660 The login page is provided using a HTML::Template, which is set in the
 661 systempreferences table or at the top of this file. The variable C<$type>
 662 selects which template to use, either the opac or the intranet
 663 authentification template.
 664
 665 C<&checkauth> returns a user ID, a cookie, and a session ID. The
 666 cookie should be sent back to the browser; it verifies that the user
 667 has authenticated.
 668
 669 =cut
 670
 671 sub _version_check {
 672     my $type  = shift;
 673     my $query = shift;
 674     my $version;
 675
 676     # If version syspref is unavailable, it means Koha is being installed,
 677     # and so we must redirect to OPAC maintenance page or to the WebInstaller
 678     # also, if OpacMaintenance is ON, OPAC should redirect to maintenance
 679     if ( C4::Context->preference('OpacMaintenance') && $type eq 'opac' ) {
 680         warn "OPAC Install required, redirecting to maintenance";
 681         print $query->redirect("/cgi-bin/koha/maintenance.pl");
 682         safe_exit;
 683     }
 684     unless ( $version = C4::Context->preference('Version') ) {    # assignment, not comparison
 685         if ( $type ne 'opac' ) {
 686             warn "Install required, redirecting to Installer";
 687             print $query->redirect("/cgi-bin/koha/installer/install.pl");
 688         } else {
 689             warn "OPAC Install required, redirecting to maintenance";
 690             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 691         }
 692         safe_exit;
 693     }
 694
 695     # check that database and koha version are the same
 696     # there is no DB version, it's a fresh install,
 697     # go to web installer
 698     # there is a DB version, compare it to the code version
 699     my $kohaversion = Koha::version();
 700
 701     # remove the 3 last . to have a Perl number
 702     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
 703     $debug and print STDERR "kohaversion : $kohaversion\n";
 704     if ( $version < $kohaversion ) {
 705         my $warning = "Database update needed, redirecting to %s. Database is $version and Koha is $kohaversion";
 706         if ( $type ne 'opac' ) {
 707             warn sprintf( $warning, 'Installer' );
 708             print $query->redirect("/cgi-bin/koha/installer/install.pl?step=1&op=updatestructure");
 709         } else {
 710             warn sprintf( "OPAC: " . $warning, 'maintenance' );
 711             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 712         }
 713         safe_exit;
 714     }
 715 }
 716
 717 sub _session_log {
 718     (@_) or return 0;
 719     open my $fh, '>>', "/tmp/sessionlog" or warn "ERROR: Cannot append to /tmp/sessionlog";
 720     printf $fh join( "\n", @_ );
 721     close $fh;
 722 }
 723
 724 sub _timeout_syspref {
 725     my $timeout = C4::Context->preference('timeout') || 600;
 726
 727     # value in days, convert in seconds
 728     if ( $timeout =~ /(\d+)[dD]/ ) {
 729         $timeout = $1 * 86400;
 730     }
 731     return $timeout;
 732 }
 733
 734 sub checkauth {
 735     my $query = shift;
 736     $debug and warn "Checking Auth";
 737
 738     # $authnotrequired will be set for scripts which will run without authentication
 739     my $authnotrequired = shift;
 740     my $flagsrequired   = shift;
 741     my $type            = shift;
 742     my $persona         = shift;
 743     $type = 'opac' unless $type;
 744
 745     my $dbh     = C4::Context->dbh;
 746     my $timeout = _timeout_syspref();
 747
 748     _version_check( $type, $query );
 749
 750     # state variables
 751     my $loggedin = 0;
 752     my %info;
 753     my ( $userid, $cookie, $sessionID, $flags );
 754     my $logout = $query->param('logout.x');
 755
 756     my $anon_search_history;
 757
 758     # This parameter is the name of the CAS server we want to authenticate against,
 759     # when using authentication against multiple CAS servers, as configured in Auth_cas_servers.yaml
 760     my $casparam = $query->param('cas');
 761     my $q_userid = $query->param('userid') // '';
 762
 763     # Basic authentication is incompatible with the use of Shibboleth,
 764     # as Shibboleth may return REMOTE_USER as a Shibboleth attribute,
 765     # and it may not be the attribute we want to use to match the koha login.
 766     #
 767     # Also, do not consider an empty REMOTE_USER.
 768     #
 769     # Finally, after those tests, we can assume (although if it would be better with
 770     # a syspref) that if we get a REMOTE_USER, that's from basic authentication,
 771     # and we can affect it to $userid.
 772     if ( !$shib and defined( $ENV{'REMOTE_USER'} ) and $ENV{'REMOTE_USER'} ne '' and $userid = $ENV{'REMOTE_USER'} ) {
 773
 774         # Using Basic Authentication, no cookies required
 775         $cookie = $query->cookie(
 776             -name     => 'CGISESSID',
 777             -value    => '',
 778             -expires  => '',
 779             -HttpOnly => 1,
 780         );
 781         $loggedin = 1;
 782     }
 783     elsif ($persona) {
 784
 785         # we don't want to set a session because we are being called by a persona callback
 786     }
 787     elsif ( $sessionID = $query->cookie("CGISESSID") )
 788     {    # assignment, not comparison
 789         my $session = get_session($sessionID);
 790         C4::Context->_new_userenv($sessionID);
 791         my ( $ip, $lasttime, $sessiontype );
 792         my $s_userid = '';
 793         if ($session) {
 794             $s_userid = $session->param('id') // '';
 795             C4::Context->set_userenv(
 796                 $session->param('number'),       $s_userid,
 797                 $session->param('cardnumber'),   $session->param('firstname'),
 798                 $session->param('surname'),      $session->param('branch'),
 799                 $session->param('branchname'),   $session->param('flags'),
 800                 $session->param('emailaddress'), $session->param('branchprinter'),
 801                 $session->param('persona'),      $session->param('shibboleth')
 802             );
 803             C4::Context::set_shelves_userenv( 'bar', $session->param('barshelves') );
 804             C4::Context::set_shelves_userenv( 'pub', $session->param('pubshelves') );
 805             C4::Context::set_shelves_userenv( 'tot', $session->param('totshelves') );
 806             $debug and printf STDERR "AUTH_SESSION: (%s)\t%s %s - %s\n", map { $session->param($_) } qw(cardnumber firstname surname branch);
 807             $ip          = $session->param('ip');
 808             $lasttime    = $session->param('lasttime');
 809             $userid      = $s_userid;
 810             $sessiontype = $session->param('sessiontype') || '';
 811         }
 812         if ( ( $query->param('koha_login_context') && ( $q_userid ne $s_userid ) )
 813             || ( $cas && $query->param('ticket') && !C4::Context->userenv->{'id'} ) || ( $shib && $shib_login && !$logout ) ) {
 814
 815             #if a user enters an id ne to the id in the current session, we need to log them in...
 816             #first we need to clear the anonymous session...
 817             $debug and warn "query id = $q_userid but session id = $s_userid";
 818             $anon_search_history = $session->param('search_history');
 819             $session->delete();
 820             $session->flush;
 821             C4::Context->_unset_userenv($sessionID);
 822             $sessionID = undef;
 823             $userid    = undef;
 824         }
 825         elsif ($logout) {
 826
 827             # voluntary logout the user
 828             # check wether the user was using their shibboleth session or a local one
 829             my $shibSuccess = C4::Context->userenv->{'shibboleth'};
 830             $session->delete();
 831             $session->flush;
 832             C4::Context->_unset_userenv($sessionID);
 833
 834             #_session_log(sprintf "%20s from %16s logged out at %30s (manually).\n", $userid,$ip,(strftime "%c",localtime));
 835             $sessionID = undef;
 836             $userid    = undef;
 837
 838             if ($cas and $caslogout) {
 839                 logout_cas($query, $type);
 840             }
 841
 842             # If we are in a shibboleth session (shibboleth is enabled, a shibboleth match attribute is set and matches koha matchpoint)
 843             if ( $shib and $shib_login and $shibSuccess and $type eq 'opac' ) {
 844
 845                 # (Note: $type eq 'opac' condition should be removed when shibboleth authentication for intranet will be implemented)
 846                 logout_shib($query);
 847             }
 848         }
 849         elsif ( !$lasttime || ( $lasttime < time() - $timeout ) ) {
 850
 851             # timed logout
 852             $info{'timed_out'} = 1;
 853             if ($session) {
 854                 $session->delete();
 855                 $session->flush;
 856             }
 857             C4::Context->_unset_userenv($sessionID);
 858
 859             #_session_log(sprintf "%20s from %16s logged out at %30s (inactivity).\n", $userid,$ip,(strftime "%c",localtime));
 860             $userid    = undef;
 861             $sessionID = undef;
 862         }
 863         elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $ENV{'REMOTE_ADDR'} ) {
 864
 865             # Different ip than originally logged in from
 866             $info{'oldip'}        = $ip;
 867             $info{'newip'}        = $ENV{'REMOTE_ADDR'};
 868             $info{'different_ip'} = 1;
 869             $session->delete();
 870             $session->flush;
 871             C4::Context->_unset_userenv($sessionID);
 872
 873             #_session_log(sprintf "%20s from %16s logged out at %30s (ip changed to %16s).\n", $userid,$ip,(strftime "%c",localtime), $info{'newip'});
 874             $sessionID = undef;
 875             $userid    = undef;
 876         }
 877         else {
 878             $cookie = $query->cookie(
 879                 -name     => 'CGISESSID',
 880                 -value    => $session->id,
 881                 -HttpOnly => 1
 882             );
 883             $session->param( 'lasttime', time() );
 884             unless ( $sessiontype && $sessiontype eq 'anon' ) {    #if this is an anonymous session, we want to update the session, but not behave as if they are logged in...
 885                 $flags = haspermission( $userid, $flagsrequired );
 886                 if ($flags) {
 887                     $loggedin = 1;
 888                 } else {
 889                     $info{'nopermission'} = 1;
 890                 }
 891             }
 892         }
 893     }
 894     unless ( $userid || $sessionID ) {
 895
 896         #we initiate a session prior to checking for a username to allow for anonymous sessions...
 897         my $session = get_session("") or die "Auth ERROR: Cannot get_session()";
 898
 899         # Save anonymous search history in new session so it can be retrieved
 900         # by get_template_and_user to store it in user's search history after
 901         # a successful login.
 902         if ($anon_search_history) {
 903             $session->param( 'search_history', $anon_search_history );
 904         }
 905
 906         my $sessionID = $session->id;
 907         C4::Context->_new_userenv($sessionID);
 908         $cookie = $query->cookie(
 909             -name     => 'CGISESSID',
 910             -value    => $session->id,
 911             -HttpOnly => 1
 912         );
 913         $userid = $q_userid;
 914         my $pki_field = C4::Context->preference('AllowPKIAuth');
 915         if ( !defined($pki_field) ) {
 916             print STDERR "ERROR: Missing system preference AllowPKIAuth.\n";
 917             $pki_field = 'None';
 918         }
 919         if ( ( $cas && $query->param('ticket') )
 920             || $userid
 921             || ( $shib && $shib_login )
 922             || $pki_field ne 'None'
 923             || $persona )
 924         {
 925             my $password    = $query->param('password');
 926             my $shibSuccess = 0;
 927
 928             my ( $return, $cardnumber );
 929
 930             # If shib is enabled and we have a shib login, does the login match a valid koha user
 931             if ( $shib && $shib_login && $type eq 'opac' ) {
 932                 my $retuserid;
 933
 934                 # Do not pass password here, else shib will not be checked in checkpw.
 935                 ( $return, $cardnumber, $retuserid ) = checkpw( $dbh, $userid, undef, $query );
 936                 $userid      = $retuserid;
 937                 $shibSuccess = $return;
 938                 $info{'invalidShibLogin'} = 1 unless ($return);
 939             }
 940
 941             # If shib login and match were successful, skip further login methods
 942             unless ($shibSuccess) {
 943                 if ( $cas && $query->param('ticket') ) {
 944                     my $retuserid;
 945                     ( $return, $cardnumber, $retuserid ) =
 946                       checkpw( $dbh, $userid, $password, $query, $type );
 947                     $userid = $retuserid;
 948                     $info{'invalidCasLogin'} = 1 unless ($return);
 949                 }
 950
 951                 elsif ($persona) {
 952                     my $value = $persona;
 953
 954                     # If we're looking up the email, there's a chance that the person
 955                     # doesn't have a userid. So if there is none, we pass along the
 956                     # borrower number, and the bits of code that need to know the user
 957                     # ID will have to be smart enough to handle that.
 958                     require C4::Members;
 959                     my @users_info = C4::Members::GetBorrowersWithEmail($value);
 960                     if (@users_info) {
 961
 962                         # First the userid, then the borrowernum
 963                         $value = $users_info[0][1] || $users_info[0][0];
 964                     }
 965                     else {
 966                         undef $value;
 967                     }
 968                     $return = $value ? 1 : 0;
 969                     $userid = $value;
 970                 }
 971
 972                 elsif (
 973                     ( $pki_field eq 'Common Name' && $ENV{'SSL_CLIENT_S_DN_CN'} )
 974                     || ( $pki_field eq 'emailAddress'
 975                         && $ENV{'SSL_CLIENT_S_DN_Email'} )
 976                   )
 977                 {
 978                     my $value;
 979                     if ( $pki_field eq 'Common Name' ) {
 980                         $value = $ENV{'SSL_CLIENT_S_DN_CN'};
 981                     }
 982                     elsif ( $pki_field eq 'emailAddress' ) {
 983                         $value = $ENV{'SSL_CLIENT_S_DN_Email'};
 984
 985                         # If we're looking up the email, there's a chance that the person
 986                         # doesn't have a userid. So if there is none, we pass along the
 987                         # borrower number, and the bits of code that need to know the user
 988                         # ID will have to be smart enough to handle that.
 989                         require C4::Members;
 990                         my @users_info = C4::Members::GetBorrowersWithEmail($value);
 991                         if (@users_info) {
 992
 993                             # First the userid, then the borrowernum
 994                             $value = $users_info[0][1] || $users_info[0][0];
 995                         } else {
 996                             undef $value;
 997                         }
 998                     }
 999
1000                     $return = $value ? 1 : 0;
1001                     $userid = $value;
1002
1003                 }
1004                 else {
1005                     my $retuserid;
1006                     ( $return, $cardnumber, $retuserid ) =
1007                       checkpw( $dbh, $userid, $password, $query, $type );
1008                     $userid = $retuserid if ($retuserid);
1009                     $info{'invalid_username_or_password'} = 1 unless ($return);
1010                 }
1011             }
1012
1013             # $return: 1 = valid user, 2 = superlibrarian
1014             if ($return) {
1015
1016                 #_session_log(sprintf "%20s from %16s logged in  at %30s.\n", $userid,$ENV{'REMOTE_ADDR'},(strftime '%c', localtime));
1017                 if ( $flags = haspermission( $userid, $flagsrequired ) ) {
1018                     $loggedin = 1;
1019                 }
1020                 else {
1021                     $info{'nopermission'} = 1;
1022                     C4::Context->_unset_userenv($sessionID);
1023                 }
1024                 my ( $borrowernumber, $firstname, $surname, $userflags,
1025                     $branchcode, $branchname, $branchprinter, $emailaddress );
1026
1027                 if ( $return == 1 ) {
1028                     my $select = "
1029                     SELECT borrowernumber, firstname, surname, flags, borrowers.branchcode,
1030                     branches.branchname    as branchname,
1031                     branches.branchprinter as branchprinter,
1032                     email
1033                     FROM borrowers
1034                     LEFT JOIN branches on borrowers.branchcode=branches.branchcode
1035                     ";
1036                     my $sth = $dbh->prepare("$select where userid=?");
1037                     $sth->execute($userid);
1038                     unless ( $sth->rows ) {
1039                         $debug and print STDERR "AUTH_1: no rows for userid='$userid'\n";
1040                         $sth = $dbh->prepare("$select where cardnumber=?");
1041                         $sth->execute($cardnumber);
1042
1043                         unless ( $sth->rows ) {
1044                             $debug and print STDERR "AUTH_2a: no rows for cardnumber='$cardnumber'\n";
1045                             $sth->execute($userid);
1046                             unless ( $sth->rows ) {
1047                                 $debug and print STDERR "AUTH_2b: no rows for userid='$userid' AS cardnumber\n";
1048                             }
1049                         }
1050                     }
1051                     if ( $sth->rows ) {
1052                         ( $borrowernumber, $firstname, $surname, $userflags,
1053                             $branchcode, $branchname, $branchprinter, $emailaddress ) = $sth->fetchrow;
1054                         $debug and print STDERR "AUTH_3 results: " .
1055                           "$cardnumber,$borrowernumber,$userid,$firstname,$surname,$userflags,$branchcode,$emailaddress\n";
1056                     } else {
1057                         print STDERR "AUTH_3: no results for userid='$userid', cardnumber='$cardnumber'.\n";
1058                     }
1059
1060                     # launch a sequence to check if we have a ip for the branch, i
1061                     # if we have one we replace the branchcode of the userenv by the branch bound in the ip.
1062
1063                     my $ip = $ENV{'REMOTE_ADDR'};
1064
1065                     # if they specify at login, use that
1066                     if ( $query->param('branch') ) {
1067                         $branchcode = $query->param('branch');
1068                         $branchname = GetBranchName($branchcode);
1069                     }
1070                     my $branches = GetBranches();
1071                     if ( C4::Context->boolean_preference('IndependentBranches') && C4::Context->boolean_preference('Autolocation') ) {
1072
1073                         # we have to check they are coming from the right ip range
1074                         my $domain = $branches->{$branchcode}->{'branchip'};
1075                         if ( $ip !~ /^$domain/ ) {
1076                             $loggedin = 0;
1077                             $info{'wrongip'} = 1;
1078                         }
1079                     }
1080
1081                     my @branchesloop;
1082                     foreach my $br ( keys %$branches ) {
1083
1084                         #     now we work with the treatment of ip
1085                         my $domain = $branches->{$br}->{'branchip'};
1086                         if ( $domain && $ip =~ /^$domain/ ) {
1087                             $branchcode = $branches->{$br}->{'branchcode'};
1088
1089                             # new op dev : add the branchprinter and branchname in the cookie
1090                             $branchprinter = $branches->{$br}->{'branchprinter'};
1091                             $branchname    = $branches->{$br}->{'branchname'};
1092                         }
1093                     }
1094                     $session->param( 'number',       $borrowernumber );
1095                     $session->param( 'id',           $userid );
1096                     $session->param( 'cardnumber',   $cardnumber );
1097                     $session->param( 'firstname',    $firstname );
1098                     $session->param( 'surname',      $surname );
1099                     $session->param( 'branch',       $branchcode );
1100                     $session->param( 'branchname',   $branchname );
1101                     $session->param( 'flags',        $userflags );
1102                     $session->param( 'emailaddress', $emailaddress );
1103                     $session->param( 'ip',           $session->remote_addr() );
1104                     $session->param( 'lasttime',     time() );
1105                     $session->param( 'shibboleth',   $shibSuccess );
1106                     $debug and printf STDERR "AUTH_4: (%s)\t%s %s - %s\n", map { $session->param($_) } qw(cardnumber firstname surname branch);
1107                 }
1108                 elsif ( $return == 2 ) {
1109
1110                     #We suppose the user is the superlibrarian
1111                     $borrowernumber = 0;
1112                     $session->param( 'number',       0 );
1113                     $session->param( 'id',           C4::Context->config('user') );
1114                     $session->param( 'cardnumber',   C4::Context->config('user') );
1115                     $session->param( 'firstname',    C4::Context->config('user') );
1116                     $session->param( 'surname',      C4::Context->config('user') );
1117                     $session->param( 'branch',       'NO_LIBRARY_SET' );
1118                     $session->param( 'branchname',   'NO_LIBRARY_SET' );
1119                     $session->param( 'flags',        1 );
1120                     $session->param( 'emailaddress', C4::Context->preference('KohaAdminEmailAddress') );
1121                     $session->param( 'ip',           $session->remote_addr() );
1122                     $session->param( 'lasttime',     time() );
1123                 }
1124                 if ($persona) {
1125                     $session->param( 'persona', 1 );
1126                 }
1127                 C4::Context->set_userenv(
1128                     $session->param('number'),       $session->param('id'),
1129                     $session->param('cardnumber'),   $session->param('firstname'),
1130                     $session->param('surname'),      $session->param('branch'),
1131                     $session->param('branchname'),   $session->param('flags'),
1132                     $session->param('emailaddress'), $session->param('branchprinter'),
1133                     $session->param('persona'),      $session->param('shibboleth')
1134                 );
1135
1136             }
1137             # $return: 0 = invalid user
1138             # reset to anonymous session
1139             else {
1140                 $debug and warn "Login failed, resetting anonymous session...";
1141                 if ($userid) {
1142                     $info{'invalid_username_or_password'} = 1;
1143                     C4::Context->_unset_userenv($sessionID);
1144                 }
1145                 $session->param( 'lasttime', time() );
1146                 $session->param( 'ip',       $session->remote_addr() );
1147                 $session->param( 'sessiontype', 'anon' );
1148             }
1149         }    # END if ( $userid    = $query->param('userid') )
1150         elsif ( $type eq "opac" ) {
1151
1152             # if we are here this is an anonymous session; add public lists to it and a few other items...
1153             # anonymous sessions are created only for the OPAC
1154             $debug and warn "Initiating an anonymous session...";
1155
1156             # setting a couple of other session vars...
1157             $session->param( 'ip',          $session->remote_addr() );
1158             $session->param( 'lasttime',    time() );
1159             $session->param( 'sessiontype', 'anon' );
1160         }
1161     }    # END unless ($userid)
1162
1163     # finished authentification, now respond
1164     if ( $loggedin || $authnotrequired )
1165     {
1166         # successful login
1167         unless ($cookie) {
1168             $cookie = $query->cookie(
1169                 -name     => 'CGISESSID',
1170                 -value    => '',
1171                 -HttpOnly => 1
1172             );
1173         }
1174         return ( $userid, $cookie, $sessionID, $flags );
1175     }
1176
1177     #
1178     #
1179     # AUTH rejected, show the login/password template, after checking the DB.
1180     #
1181     #
1182
1183     # get the inputs from the incoming query
1184     my @inputs = ();
1185     foreach my $name ( param $query) {
1186         (next) if ( $name eq 'userid' || $name eq 'password' || $name eq 'ticket' );
1187         my $value = $query->param($name);
1188         push @inputs, { name => $name, value => $value };
1189     }
1190
1191     my $LibraryNameTitle = C4::Context->preference("LibraryName");
1192     $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
1193     $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
1194
1195     my $template_name = ( $type eq 'opac' ) ? 'opac-auth.tt' : 'auth.tt';
1196     my $template = C4::Templates::gettemplate( $template_name, $type, $query );
1197     $template->param(
1198         branchloop                            => GetBranchesLoop(),
1199         OpacAdditionalStylesheet                   => C4::Context->preference("OpacAdditionalStylesheet"),
1200         opaclayoutstylesheet                  => C4::Context->preference("opaclayoutstylesheet"),
1201         login                                 => 1,
1202         INPUTS                                => \@inputs,
1203         casAuthentication                     => C4::Context->preference("casAuthentication"),
1204         shibbolethAuthentication              => $shib,
1205         SessionRestrictionByIP                => C4::Context->preference("SessionRestrictionByIP"),
1206         suggestion                            => C4::Context->preference("suggestion"),
1207         virtualshelves                        => C4::Context->preference("virtualshelves"),
1208         LibraryName                           => "" . C4::Context->preference("LibraryName"),
1209         LibraryNameTitle                      => "" . $LibraryNameTitle,
1210         opacuserlogin                         => C4::Context->preference("opacuserlogin"),
1211         OpacNav                               => C4::Context->preference("OpacNav"),
1212         OpacNavRight                          => C4::Context->preference("OpacNavRight"),
1213         OpacNavBottom                         => C4::Context->preference("OpacNavBottom"),
1214         opaccredits                           => C4::Context->preference("opaccredits"),
1215         OpacFavicon                           => C4::Context->preference("OpacFavicon"),
1216         opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
1217         opaclanguagesdisplay                  => C4::Context->preference("opaclanguagesdisplay"),
1218         OPACUserJS                            => C4::Context->preference("OPACUserJS"),
1219         opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
1220         OpacCloud                             => C4::Context->preference("OpacCloud"),
1221         OpacTopissue                          => C4::Context->preference("OpacTopissue"),
1222         OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
1223         OpacBrowser                           => C4::Context->preference("OpacBrowser"),
1224         opacheader                            => C4::Context->preference("opacheader"),
1225         TagsEnabled                           => C4::Context->preference("TagsEnabled"),
1226         OPACUserCSS                           => C4::Context->preference("OPACUserCSS"),
1227         intranetcolorstylesheet               => C4::Context->preference("intranetcolorstylesheet"),
1228         intranetstylesheet                    => C4::Context->preference("intranetstylesheet"),
1229         intranetbookbag                       => C4::Context->preference("intranetbookbag"),
1230         IntranetNav                           => C4::Context->preference("IntranetNav"),
1231         IntranetFavicon                       => C4::Context->preference("IntranetFavicon"),
1232         IntranetUserJS                        => C4::Context->preference("IntranetUserJS"),
1233         IndependentBranches                   => C4::Context->preference("IndependentBranches"),
1234         AutoLocation                          => C4::Context->preference("AutoLocation"),
1235         wrongip                               => $info{'wrongip'},
1236         PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
1237         PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
1238         persona                               => C4::Context->preference("Persona"),
1239         opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
1240     );
1241
1242     $template->param( OpacPublic => C4::Context->preference("OpacPublic") );
1243     $template->param( loginprompt => 1 ) unless $info{'nopermission'};
1244
1245     if ( $type eq 'opac' ) {
1246         require Koha::Virtualshelves;
1247         my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
1248             {
1249                 category       => 2,
1250             }
1251         );
1252         $template->param(
1253             some_public_shelves  => $some_public_shelves,
1254         );
1255     }
1256
1257     if ($cas) {
1258
1259         # Is authentication against multiple CAS servers enabled?
1260         if ( C4::Auth_with_cas::multipleAuth && !$casparam ) {
1261             my $casservers = C4::Auth_with_cas::getMultipleAuth();
1262             my @tmplservers;
1263             foreach my $key ( keys %$casservers ) {
1264                 push @tmplservers, { name => $key, value => login_cas_url( $query, $key, $type ) . "?cas=$key" };
1265             }
1266             $template->param(
1267                 casServersLoop => \@tmplservers
1268             );
1269         } else {
1270             $template->param(
1271                 casServerUrl => login_cas_url($query, undef, $type),
1272             );
1273         }
1274
1275         $template->param(
1276             invalidCasLogin => $info{'invalidCasLogin'}
1277         );
1278     }
1279
1280     if ($shib) {
1281         $template->param(
1282             shibbolethAuthentication => $shib,
1283             shibbolethLoginUrl       => login_shib_url($query),
1284         );
1285     }
1286
1287     $template->param(
1288         LibraryName => C4::Context->preference("LibraryName"),
1289     );
1290     $template->param(%info);
1291
1292     #    $cookie = $query->cookie(CGISESSID => $session->id
1293     #   );
1294     print $query->header(
1295         -type    => 'text/html',
1296         -charset => 'utf-8',
1297         -cookie  => $cookie
1298       ),
1299       $template->output;
1300     safe_exit;
1301 }
1302
1303 =head2 check_api_auth
1304
1305   ($status, $cookie, $sessionId) = check_api_auth($query, $userflags);
1306
1307 Given a CGI query containing the parameters 'userid' and 'password' and/or a session
1308 cookie, determine if the user has the privileges specified by C<$userflags>.
1309
1310 C<check_api_auth> is is meant for authenticating users of web services, and
1311 consequently will always return and will not attempt to redirect the user
1312 agent.
1313
1314 If a valid session cookie is already present, check_api_auth will return a status
1315 of "ok", the cookie, and the Koha session ID.
1316
1317 If no session cookie is present, check_api_auth will check the 'userid' and 'password
1318 parameters and create a session cookie and Koha session if the supplied credentials
1319 are OK.
1320
1321 Possible return values in C<$status> are:
1322
1323 =over
1324
1325 =item "ok" -- user authenticated; C<$cookie> and C<$sessionid> have valid values.
1326
1327 =item "failed" -- credentials are not correct; C<$cookie> and C<$sessionid> are undef
1328
1329 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1330
1331 =item "expired -- session cookie has expired; API user should resubmit userid and password
1332
1333 =back
1334
1335 =cut
1336
1337 sub check_api_auth {
1338     my $query         = shift;
1339     my $flagsrequired = shift;
1340
1341     my $dbh     = C4::Context->dbh;
1342     my $timeout = _timeout_syspref();
1343
1344     unless ( C4::Context->preference('Version') ) {
1345
1346         # database has not been installed yet
1347         return ( "maintenance", undef, undef );
1348     }
1349     my $kohaversion = Koha::version();
1350     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1351     if ( C4::Context->preference('Version') < $kohaversion ) {
1352
1353         # database in need of version update; assume that
1354         # no API should be called while databsae is in
1355         # this condition.
1356         return ( "maintenance", undef, undef );
1357     }
1358
1359     # FIXME -- most of what follows is a copy-and-paste
1360     # of code from checkauth.  There is an obvious need
1361     # for refactoring to separate the various parts of
1362     # the authentication code, but as of 2007-11-19 this
1363     # is deferred so as to not introduce bugs into the
1364     # regular authentication code for Koha 3.0.
1365
1366     # see if we have a valid session cookie already
1367     # however, if a userid parameter is present (i.e., from
1368     # a form submission, assume that any current cookie
1369     # is to be ignored
1370     my $sessionID = undef;
1371     unless ( $query->param('userid') ) {
1372         $sessionID = $query->cookie("CGISESSID");
1373     }
1374     if ( $sessionID && not( $cas && $query->param('PT') ) ) {
1375         my $session = get_session($sessionID);
1376         C4::Context->_new_userenv($sessionID);
1377         if ($session) {
1378             C4::Context->set_userenv(
1379                 $session->param('number'),       $session->param('id'),
1380                 $session->param('cardnumber'),   $session->param('firstname'),
1381                 $session->param('surname'),      $session->param('branch'),
1382                 $session->param('branchname'),   $session->param('flags'),
1383                 $session->param('emailaddress'), $session->param('branchprinter')
1384             );
1385
1386             my $ip       = $session->param('ip');
1387             my $lasttime = $session->param('lasttime');
1388             my $userid   = $session->param('id');
1389             if ( $lasttime < time() - $timeout ) {
1390
1391                 # time out
1392                 $session->delete();
1393                 $session->flush;
1394                 C4::Context->_unset_userenv($sessionID);
1395                 $userid    = undef;
1396                 $sessionID = undef;
1397                 return ( "expired", undef, undef );
1398             } elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $ENV{'REMOTE_ADDR'} ) {
1399
1400                 # IP address changed
1401                 $session->delete();
1402                 $session->flush;
1403                 C4::Context->_unset_userenv($sessionID);
1404                 $userid    = undef;
1405                 $sessionID = undef;
1406                 return ( "expired", undef, undef );
1407             } else {
1408                 my $cookie = $query->cookie(
1409                     -name     => 'CGISESSID',
1410                     -value    => $session->id,
1411                     -HttpOnly => 1,
1412                 );
1413                 $session->param( 'lasttime', time() );
1414                 my $flags = haspermission( $userid, $flagsrequired );
1415                 if ($flags) {
1416                     return ( "ok", $cookie, $sessionID );
1417                 } else {
1418                     $session->delete();
1419                     $session->flush;
1420                     C4::Context->_unset_userenv($sessionID);
1421                     $userid    = undef;
1422                     $sessionID = undef;
1423                     return ( "failed", undef, undef );
1424                 }
1425             }
1426         } else {
1427             return ( "expired", undef, undef );
1428         }
1429     } else {
1430
1431         # new login
1432         my $userid   = $query->param('userid');
1433         my $password = $query->param('password');
1434         my ( $return, $cardnumber );
1435
1436         # Proxy CAS auth
1437         if ( $cas && $query->param('PT') ) {
1438             my $retuserid;
1439             $debug and print STDERR "## check_api_auth - checking CAS\n";
1440
1441             # In case of a CAS authentication, we use the ticket instead of the password
1442             my $PT = $query->param('PT');
1443             ( $return, $cardnumber, $userid ) = check_api_auth_cas( $dbh, $PT, $query );    # EXTERNAL AUTH
1444         } else {
1445
1446             # User / password auth
1447             unless ( $userid and $password ) {
1448
1449                 # caller did something wrong, fail the authenticateion
1450                 return ( "failed", undef, undef );
1451             }
1452             ( $return, $cardnumber ) = checkpw( $dbh, $userid, $password, $query );
1453         }
1454
1455         if ( $return and haspermission( $userid, $flagsrequired ) ) {
1456             my $session = get_session("");
1457             return ( "failed", undef, undef ) unless $session;
1458
1459             my $sessionID = $session->id;
1460             C4::Context->_new_userenv($sessionID);
1461             my $cookie = $query->cookie(
1462                 -name     => 'CGISESSID',
1463                 -value    => $sessionID,
1464                 -HttpOnly => 1,
1465             );
1466             if ( $return == 1 ) {
1467                 my (
1468                     $borrowernumber, $firstname,  $surname,
1469                     $userflags,      $branchcode, $branchname,
1470                     $branchprinter,  $emailaddress
1471                 );
1472                 my $sth =
1473                   $dbh->prepare(
1474 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname,branches.branchprinter as branchprinter, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where userid=?"
1475                   );
1476                 $sth->execute($userid);
1477                 (
1478                     $borrowernumber, $firstname,  $surname,
1479                     $userflags,      $branchcode, $branchname,
1480                     $branchprinter,  $emailaddress
1481                 ) = $sth->fetchrow if ( $sth->rows );
1482
1483                 unless ( $sth->rows ) {
1484                     my $sth = $dbh->prepare(
1485 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, branches.branchprinter as branchprinter, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
1486                     );
1487                     $sth->execute($cardnumber);
1488                     (
1489                         $borrowernumber, $firstname,  $surname,
1490                         $userflags,      $branchcode, $branchname,
1491                         $branchprinter,  $emailaddress
1492                     ) = $sth->fetchrow if ( $sth->rows );
1493
1494                     unless ( $sth->rows ) {
1495                         $sth->execute($userid);
1496                         (
1497                             $borrowernumber, $firstname,  $surname,       $userflags,
1498                             $branchcode,     $branchname, $branchprinter, $emailaddress
1499                         ) = $sth->fetchrow if ( $sth->rows );
1500                     }
1501                 }
1502
1503                 my $ip = $ENV{'REMOTE_ADDR'};
1504
1505                 # if they specify at login, use that
1506                 if ( $query->param('branch') ) {
1507                     $branchcode = $query->param('branch');
1508                     $branchname = GetBranchName($branchcode);
1509                 }
1510                 my $branches = GetBranches();
1511                 my @branchesloop;
1512                 foreach my $br ( keys %$branches ) {
1513
1514                     #     now we work with the treatment of ip
1515                     my $domain = $branches->{$br}->{'branchip'};
1516                     if ( $domain && $ip =~ /^$domain/ ) {
1517                         $branchcode = $branches->{$br}->{'branchcode'};
1518
1519                         # new op dev : add the branchprinter and branchname in the cookie
1520                         $branchprinter = $branches->{$br}->{'branchprinter'};
1521                         $branchname    = $branches->{$br}->{'branchname'};
1522                     }
1523                 }
1524                 $session->param( 'number',       $borrowernumber );
1525                 $session->param( 'id',           $userid );
1526                 $session->param( 'cardnumber',   $cardnumber );
1527                 $session->param( 'firstname',    $firstname );
1528                 $session->param( 'surname',      $surname );
1529                 $session->param( 'branch',       $branchcode );
1530                 $session->param( 'branchname',   $branchname );
1531                 $session->param( 'flags',        $userflags );
1532                 $session->param( 'emailaddress', $emailaddress );
1533                 $session->param( 'ip',           $session->remote_addr() );
1534                 $session->param( 'lasttime',     time() );
1535             } elsif ( $return == 2 ) {
1536
1537                 #We suppose the user is the superlibrarian
1538                 $session->param( 'number',       0 );
1539                 $session->param( 'id',           C4::Context->config('user') );
1540                 $session->param( 'cardnumber',   C4::Context->config('user') );
1541                 $session->param( 'firstname',    C4::Context->config('user') );
1542                 $session->param( 'surname',      C4::Context->config('user') );
1543                 $session->param( 'branch',       'NO_LIBRARY_SET' );
1544                 $session->param( 'branchname',   'NO_LIBRARY_SET' );
1545                 $session->param( 'flags',        1 );
1546                 $session->param( 'emailaddress', C4::Context->preference('KohaAdminEmailAddress') );
1547                 $session->param( 'ip',           $session->remote_addr() );
1548                 $session->param( 'lasttime',     time() );
1549             }
1550             C4::Context->set_userenv(
1551                 $session->param('number'),       $session->param('id'),
1552                 $session->param('cardnumber'),   $session->param('firstname'),
1553                 $session->param('surname'),      $session->param('branch'),
1554                 $session->param('branchname'),   $session->param('flags'),
1555                 $session->param('emailaddress'), $session->param('branchprinter')
1556             );
1557             return ( "ok", $cookie, $sessionID );
1558         } else {
1559             return ( "failed", undef, undef );
1560         }
1561     }
1562 }
1563
1564 =head2 check_cookie_auth
1565
1566   ($status, $sessionId) = check_api_auth($cookie, $userflags);
1567
1568 Given a CGISESSID cookie set during a previous login to Koha, determine
1569 if the user has the privileges specified by C<$userflags>.
1570
1571 C<check_cookie_auth> is meant for authenticating special services
1572 such as tools/upload-file.pl that are invoked by other pages that
1573 have been authenticated in the usual way.
1574
1575 Possible return values in C<$status> are:
1576
1577 =over
1578
1579 =item "ok" -- user authenticated; C<$sessionID> have valid values.
1580
1581 =item "failed" -- credentials are not correct; C<$sessionid> are undef
1582
1583 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1584
1585 =item "expired -- session cookie has expired; API user should resubmit userid and password
1586
1587 =back
1588
1589 =cut
1590
1591 sub check_cookie_auth {
1592     my $cookie        = shift;
1593     my $flagsrequired = shift;
1594
1595     my $dbh     = C4::Context->dbh;
1596     my $timeout = _timeout_syspref();
1597
1598     unless ( C4::Context->preference('Version') ) {
1599
1600         # database has not been installed yet
1601         return ( "maintenance", undef );
1602     }
1603     my $kohaversion = Koha::version();
1604     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1605     if ( C4::Context->preference('Version') < $kohaversion ) {
1606
1607         # database in need of version update; assume that
1608         # no API should be called while databsae is in
1609         # this condition.
1610         return ( "maintenance", undef );
1611     }
1612
1613     # FIXME -- most of what follows is a copy-and-paste
1614     # of code from checkauth.  There is an obvious need
1615     # for refactoring to separate the various parts of
1616     # the authentication code, but as of 2007-11-23 this
1617     # is deferred so as to not introduce bugs into the
1618     # regular authentication code for Koha 3.0.
1619
1620     # see if we have a valid session cookie already
1621     # however, if a userid parameter is present (i.e., from
1622     # a form submission, assume that any current cookie
1623     # is to be ignored
1624     unless ( defined $cookie and $cookie ) {
1625         return ( "failed", undef );
1626     }
1627     my $sessionID = $cookie;
1628     my $session   = get_session($sessionID);
1629     C4::Context->_new_userenv($sessionID);
1630     if ($session) {
1631         C4::Context->set_userenv(
1632             $session->param('number'),       $session->param('id'),
1633             $session->param('cardnumber'),   $session->param('firstname'),
1634             $session->param('surname'),      $session->param('branch'),
1635             $session->param('branchname'),   $session->param('flags'),
1636             $session->param('emailaddress'), $session->param('branchprinter')
1637         );
1638
1639         my $ip       = $session->param('ip');
1640         my $lasttime = $session->param('lasttime');
1641         my $userid   = $session->param('id');
1642         if ( $lasttime < time() - $timeout ) {
1643
1644             # time out
1645             $session->delete();
1646             $session->flush;
1647             C4::Context->_unset_userenv($sessionID);
1648             $userid    = undef;
1649             $sessionID = undef;
1650             return ("expired", undef);
1651         } elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $ENV{'REMOTE_ADDR'} ) {
1652
1653             # IP address changed
1654             $session->delete();
1655             $session->flush;
1656             C4::Context->_unset_userenv($sessionID);
1657             $userid    = undef;
1658             $sessionID = undef;
1659             return ( "expired", undef );
1660         } else {
1661             $session->param( 'lasttime', time() );
1662             my $flags = haspermission( $userid, $flagsrequired );
1663             if ($flags) {
1664                 return ( "ok", $sessionID );
1665             } else {
1666                 $session->delete();
1667                 $session->flush;
1668                 C4::Context->_unset_userenv($sessionID);
1669                 $userid    = undef;
1670                 $sessionID = undef;
1671                 return ( "failed", undef );
1672             }
1673         }
1674     } else {
1675         return ( "expired", undef );
1676     }
1677 }
1678
1679 =head2 get_session
1680
1681   use CGI::Session;
1682   my $session = get_session($sessionID);
1683
1684 Given a session ID, retrieve the CGI::Session object used to store
1685 the session's state.  The session object can be used to store
1686 data that needs to be accessed by different scripts during a
1687 user's session.
1688
1689 If the C<$sessionID> parameter is an empty string, a new session
1690 will be created.
1691
1692 =cut
1693
1694 sub get_session {
1695     my $sessionID      = shift;
1696     my $storage_method = C4::Context->preference('SessionStorage');
1697     my $dbh            = C4::Context->dbh;
1698     my $session;
1699     if ( $storage_method eq 'mysql' ) {
1700         $session = new CGI::Session( "driver:MySQL;serializer:yaml;id:md5", $sessionID, { Handle => $dbh } );
1701     }
1702     elsif ( $storage_method eq 'Pg' ) {
1703         $session = new CGI::Session( "driver:PostgreSQL;serializer:yaml;id:md5", $sessionID, { Handle => $dbh } );
1704     }
1705     elsif ( $storage_method eq 'memcached' && C4::Context->ismemcached ) {
1706         $session = new CGI::Session( "driver:memcached;serializer:yaml;id:md5", $sessionID, { Memcached => C4::Context->memcached } );
1707     }
1708     else {
1709         # catch all defaults to tmp should work on all systems
1710         $session = new CGI::Session( "driver:File;serializer:yaml;id:md5", $sessionID, { Directory => '/tmp' } );
1711     }
1712     return $session;
1713 }
1714
1715 sub checkpw {
1716     my ( $dbh, $userid, $password, $query, $type ) = @_;
1717     $type = 'opac' unless $type;
1718     if ($ldap) {
1719         $debug and print STDERR "## checkpw - checking LDAP\n";
1720         my ( $retval, $retcard, $retuserid ) = checkpw_ldap(@_);    # EXTERNAL AUTH
1721         return 0 if $retval == -1;                                  # Incorrect password for LDAP login attempt
1722         ($retval) and return ( $retval, $retcard, $retuserid );
1723     }
1724
1725     if ( $cas && $query && $query->param('ticket') ) {
1726         $debug and print STDERR "## checkpw - checking CAS\n";
1727
1728         # In case of a CAS authentication, we use the ticket instead of the password
1729         my $ticket = $query->param('ticket');
1730         $query->delete('ticket');                                   # remove ticket to come back to original URL
1731         my ( $retval, $retcard, $retuserid ) = checkpw_cas( $dbh, $ticket, $query, $type );    # EXTERNAL AUTH
1732         ($retval) and return ( $retval, $retcard, $retuserid );
1733         return 0;
1734     }
1735
1736     # If we are in a shibboleth session (shibboleth is enabled, and a shibboleth match attribute is present)
1737     # Check for password to asertain whether we want to be testing against shibboleth or another method this
1738     # time around.
1739     if ( $shib && $shib_login && !$password ) {
1740
1741         $debug and print STDERR "## checkpw - checking Shibboleth\n";
1742
1743         # In case of a Shibboleth authentication, we expect a shibboleth user attribute
1744         # (defined under shibboleth mapping in koha-conf.xml) to contain the login of the
1745         # shibboleth-authenticated user
1746
1747         # Then, we check if it matches a valid koha user
1748         if ($shib_login) {
1749             my ( $retval, $retcard, $retuserid ) = C4::Auth_with_shibboleth::checkpw_shib($shib_login);    # EXTERNAL AUTH
1750             ($retval) and return ( $retval, $retcard, $retuserid );
1751             return 0;
1752         }
1753     }
1754
1755     # INTERNAL AUTH
1756     return checkpw_internal(@_)
1757 }
1758
1759 sub checkpw_internal {
1760     my ( $dbh, $userid, $password ) = @_;
1761
1762     $password = Encode::encode( 'UTF-8', $password )
1763       if Encode::is_utf8($password);
1764
1765     if ( $userid && $userid eq C4::Context->config('user') ) {
1766         if ( $password && $password eq C4::Context->config('pass') ) {
1767
1768             # Koha superuser account
1769             #     C4::Context->set_userenv(0,0,C4::Context->config('user'),C4::Context->config('user'),C4::Context->config('user'),"",1);
1770             return 2;
1771         }
1772         else {
1773             return 0;
1774         }
1775     }
1776
1777     my $sth =
1778       $dbh->prepare(
1779         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where userid=?"
1780       );
1781     $sth->execute($userid);
1782     if ( $sth->rows ) {
1783         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
1784             $surname, $branchcode, $branchname, $flags )
1785           = $sth->fetchrow;
1786
1787         if ( checkpw_hash( $password, $stored_hash ) ) {
1788
1789             C4::Context->set_userenv( "$borrowernumber", $userid, $cardnumber,
1790                 $firstname, $surname, $branchcode, $branchname, $flags );
1791             return 1, $cardnumber, $userid;
1792         }
1793     }
1794     $sth =
1795       $dbh->prepare(
1796         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
1797       );
1798     $sth->execute($userid);
1799     if ( $sth->rows ) {
1800         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
1801             $surname, $branchcode, $branchname, $flags )
1802           = $sth->fetchrow;
1803
1804         if ( checkpw_hash( $password, $stored_hash ) ) {
1805
1806             C4::Context->set_userenv( $borrowernumber, $userid, $cardnumber,
1807                 $firstname, $surname, $branchcode, $branchname, $flags );
1808             return 1, $cardnumber, $userid;
1809         }
1810     }
1811     if ( $userid && $userid eq 'demo'
1812         && "$password" eq 'demo'
1813         && C4::Context->config('demo') )
1814     {
1815
1816         # DEMO => the demo user is allowed to do everything (if demo set to 1 in koha.conf
1817         # some features won't be effective : modify systempref, modify MARC structure,
1818         return 2;
1819     }
1820     return 0;
1821 }
1822
1823 sub checkpw_hash {
1824     my ( $password, $stored_hash ) = @_;
1825
1826     return if $stored_hash eq '!';
1827
1828     # check what encryption algorithm was implemented: Bcrypt - if the hash starts with '$2' it is Bcrypt else md5
1829     my $hash;
1830     if ( substr( $stored_hash, 0, 2 ) eq '$2' ) {
1831         $hash = hash_password( $password, $stored_hash );
1832     } else {
1833         $hash = md5_base64($password);
1834     }
1835     return $hash eq $stored_hash;
1836 }
1837
1838 =head2 getuserflags
1839
1840     my $authflags = getuserflags($flags, $userid, [$dbh]);
1841
1842 Translates integer flags into permissions strings hash.
1843
1844 C<$flags> is the integer userflags value ( borrowers.userflags )
1845 C<$userid> is the members.userid, used for building subpermissions
1846 C<$authflags> is a hashref of permissions
1847
1848 =cut
1849
1850 sub getuserflags {
1851     my $flags  = shift;
1852     my $userid = shift;
1853     my $dbh    = @_ ? shift : C4::Context->dbh;
1854     my $userflags;
1855     {
1856         # I don't want to do this, but if someone logs in as the database
1857         # user, it would be preferable not to spam them to death with
1858         # numeric warnings. So, we make $flags numeric.
1859         no warnings 'numeric';
1860         $flags += 0;
1861     }
1862     my $sth = $dbh->prepare("SELECT bit, flag, defaulton FROM userflags");
1863     $sth->execute;
1864
1865     while ( my ( $bit, $flag, $defaulton ) = $sth->fetchrow ) {
1866         if ( ( $flags & ( 2**$bit ) ) || $defaulton ) {
1867             $userflags->{$flag} = 1;
1868         }
1869         else {
1870             $userflags->{$flag} = 0;
1871         }
1872     }
1873
1874     # get subpermissions and merge with top-level permissions
1875     my $user_subperms = get_user_subpermissions($userid);
1876     foreach my $module ( keys %$user_subperms ) {
1877         next if $userflags->{$module} == 1;    # user already has permission for everything in this module
1878         $userflags->{$module} = $user_subperms->{$module};
1879     }
1880
1881     return $userflags;
1882 }
1883
1884 =head2 get_user_subpermissions
1885
1886   $user_perm_hashref = get_user_subpermissions($userid);
1887
1888 Given the userid (note, not the borrowernumber) of a staff user,
1889 return a hashref of hashrefs of the specific subpermissions
1890 accorded to the user.  An example return is
1891
1892  {
1893     tools => {
1894         export_catalog => 1,
1895         import_patrons => 1,
1896     }
1897  }
1898
1899 The top-level hash-key is a module or function code from
1900 userflags.flag, while the second-level key is a code
1901 from permissions.
1902
1903 The results of this function do not give a complete picture
1904 of the functions that a staff user can access; it is also
1905 necessary to check borrowers.flags.
1906
1907 =cut
1908
1909 sub get_user_subpermissions {
1910     my $userid = shift;
1911
1912     my $dbh = C4::Context->dbh;
1913     my $sth = $dbh->prepare( "SELECT flag, user_permissions.code
1914                              FROM user_permissions
1915                              JOIN permissions USING (module_bit, code)
1916                              JOIN userflags ON (module_bit = bit)
1917                              JOIN borrowers USING (borrowernumber)
1918                              WHERE userid = ?" );
1919     $sth->execute($userid);
1920
1921     my $user_perms = {};
1922     while ( my $perm = $sth->fetchrow_hashref ) {
1923         $user_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
1924     }
1925     return $user_perms;
1926 }
1927
1928 =head2 get_all_subpermissions
1929
1930   my $perm_hashref = get_all_subpermissions();
1931
1932 Returns a hashref of hashrefs defining all specific
1933 permissions currently defined.  The return value
1934 has the same structure as that of C<get_user_subpermissions>,
1935 except that the innermost hash value is the description
1936 of the subpermission.
1937
1938 =cut
1939
1940 sub get_all_subpermissions {
1941     my $dbh = C4::Context->dbh;
1942     my $sth = $dbh->prepare( "SELECT flag, code
1943                              FROM permissions
1944                              JOIN userflags ON (module_bit = bit)" );
1945     $sth->execute();
1946
1947     my $all_perms = {};
1948     while ( my $perm = $sth->fetchrow_hashref ) {
1949         $all_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
1950     }
1951     return $all_perms;
1952 }
1953
1954 =head2 haspermission
1955
1956   $flags = ($userid, $flagsrequired);
1957
1958 C<$userid> the userid of the member
1959 C<$flags> is a hashref of required flags like C<$borrower-&lt;{authflags}>
1960
1961 Returns member's flags or 0 if a permission is not met.
1962
1963 =cut
1964
1965 sub haspermission {
1966     my ( $userid, $flagsrequired ) = @_;
1967     my $sth = C4::Context->dbh->prepare("SELECT flags FROM borrowers WHERE userid=?");
1968     $sth->execute($userid);
1969     my $row = $sth->fetchrow();
1970     my $flags = getuserflags( $row, $userid );
1971     if ( $userid eq C4::Context->config('user') ) {
1972
1973         # Super User Account from /etc/koha.conf
1974         $flags->{'superlibrarian'} = 1;
1975     }
1976     elsif ( $userid eq 'demo' && C4::Context->config('demo') ) {
1977
1978         # Demo user that can do "anything" (demo=1 in /etc/koha.conf)
1979         $flags->{'superlibrarian'} = 1;
1980     }
1981
1982     return $flags if $flags->{superlibrarian};
1983
1984     foreach my $module ( keys %$flagsrequired ) {
1985         my $subperm = $flagsrequired->{$module};
1986         if ( $subperm eq '*' ) {
1987             return 0 unless ( $flags->{$module} == 1 or ref( $flags->{$module} ) );
1988         } else {
1989             return 0 unless (
1990                 ( defined $flags->{$module} and
1991                     $flags->{$module} == 1 )
1992                 or
1993                 ( ref( $flags->{$module} ) and
1994                     exists $flags->{$module}->{$subperm} and
1995                     $flags->{$module}->{$subperm} == 1 )
1996             );
1997         }
1998     }
1999     return $flags;
2000
2001     #FIXME - This fcn should return the failed permission so a suitable error msg can be delivered.
2002 }
2003
2004 sub getborrowernumber {
2005     my ($userid) = @_;
2006     my $userenv = C4::Context->userenv;
2007     if ( defined($userenv) && ref($userenv) eq 'HASH' && $userenv->{number} ) {
2008         return $userenv->{number};
2009     }
2010     my $dbh = C4::Context->dbh;
2011     for my $field ( 'userid', 'cardnumber' ) {
2012         my $sth =
2013           $dbh->prepare("select borrowernumber from borrowers where $field=?");
2014         $sth->execute($userid);
2015         if ( $sth->rows ) {
2016             my ($bnumber) = $sth->fetchrow;
2017             return $bnumber;
2018         }
2019     }
2020     return 0;
2021 }
2022
2023 END { }    # module clean-up code here (global destructor)
2024 1;
2025 __END__
2026
2027 =head1 SEE ALSO
2028
2029 CGI(3)
2030
2031 C4::Output(3)
2032
2033 Crypt::Eksblowfish::Bcrypt(3)
2034
2035 Digest::MD5(3)
2036
2037 =cut