C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Carp;
  22
  23 use C4::Debug;
  24 use C4::Context;
  25 use C4::Members::Messaging;
  26 use C4::Auth qw(checkpw_internal);
  27 use Koha::Patrons;
  28 use Koha::AuthUtils qw(hash_password);
  29 use List::MoreUtils qw( any );
  30 use Net::LDAP;
  31 use Net::LDAP::Filter;
  32
  33 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  34
  35 BEGIN {
  36         require Exporter;
  37         @ISA    = qw(Exporter);
  38         @EXPORT = qw( checkpw_ldap );
  39 }
  40
  41 # Redefine checkpw_ldap:
  42 # connect to LDAP (named or anonymous)
  43 # ~ retrieves $userid from KOHA_CONF mapping
  44 # ~ then compares $password with userPassword
  45 # ~ then gets the LDAP entry
  46 # ~ and calls the memberadd if necessary
  47
  48 sub ldapserver_error {
  49         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  50 }
  51
  52 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  53 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  54 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  55 my $base      = $ldap->{base}           or die ldapserver_error('base');
  56 $ldapname     = $ldap->{user}           ;
  57 $ldappassword = $ldap->{pass}           ;
  58 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  59 my @mapkeys = keys %mapping;
  60 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  61 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  62 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  63
  64 my %categorycode_conversions;
  65 my $default_categorycode;
  66 if(defined $ldap->{categorycode_mapping}) {
  67     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  68     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  69         $categorycode_conversions{$cat->{value}} = $cat->{content};
  70     }
  71 }
  72
  73 my %config = (
  74     anonymous => defined ($ldap->{anonymous_bind}) ? $ldap->{anonymous_bind} : 1,
  75     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  76        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  77 );
  78
  79 sub description {
  80         my $result = shift or return;
  81         return "LDAP error #" . $result->code
  82                         . ": " . $result->error_name . "\n"
  83                         . "# " . $result->error_text . "\n";
  84 }
  85
  86 sub search_method {
  87     my $db     = shift or return;
  88     my $userid = shift or return;
  89         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  90         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  91         my $search = $db->search(
  92                   base => $base,
  93                 filter => $filter,
  94                 # attrs => ['*'],
  95     );
  96     die "LDAP search failed to return object : " . $search->error if $search->code;
  97
  98         my $count = $search->count;
  99         if ($search->code > 0) {
 100                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 101                 return 0;
 102         }
 103     if ($count == 0) {
 104         warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
 105         return 0;
 106     }
 107     return $search;
 108 }
 109
 110 sub checkpw_ldap {
 111     my ($dbh, $userid, $password) = @_;
 112     my @hosts = split(',', $prefhost);
 113     my $db = Net::LDAP->new(\@hosts);
 114     unless ( $db ) {
 115         warn "LDAP connexion failed";
 116         return 0;
 117     }
 118
 119         #$debug and $db->debug(5);
 120     my $userldapentry;
 121
 122     # first, LDAP authentication
 123     if ( $ldap->{auth_by_bind} ) {
 124         my $principal_name;
 125         if ( $config{anonymous} ) {
 126
 127             # Perform an anonymous bind
 128             my $res = $db->bind;
 129             if ( $res->code ) {
 130                 warn "Anonymous LDAP bind failed: " . description($res);
 131                 return 0;
 132             }
 133
 134             # Perform a LDAP search for the given username
 135             my $search = search_method( $db, $userid )
 136               or return 0;    # warnings are in the sub
 137             $userldapentry = $search->shift_entry;
 138             $principal_name = $userldapentry->dn;
 139         }
 140         else {
 141             $principal_name = $ldap->{principal_name};
 142             if ( $principal_name and $principal_name =~ /\%/ ) {
 143                 $principal_name = sprintf( $principal_name, $userid );
 144             }
 145             else {
 146                 $principal_name = $userid;
 147             }
 148         }
 149
 150         # Perform a LDAP bind for the given username using the matched DN
 151         my $res = $db->bind( $principal_name, password => $password );
 152         if ( $res->code ) {
 153             if ( $config{anonymous} ) {
 154                 # With anonymous_bind approach we can be sure we have found the correct user
 155                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 156                 # or password changed). We should not fall back to local accounts in this case.
 157                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 158                 return -1;
 159             } else {
 160                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 161                 # at all, and thus we should fall back to local logins to restore previous behaviour
 162                 # see bug 12831
 163                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 164                 return 0;
 165             }
 166         }
 167         if ( !defined($userldapentry)
 168             && ( $config{update} or $config{replicate} ) )
 169         {
 170             my $search = search_method( $db, $userid ) or return 0;
 171             $userldapentry = $search->shift_entry;
 172         }
 173     } else {
 174         my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 175                 if ($res->code) {               # connection refused
 176                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 177                         return 0;
 178                 }
 179         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 180         # Handle multiple branches. Same login exists several times in different branches.
 181         my $bind_ok = 0;
 182         while (my $entry = $search->shift_entry) {
 183             my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
 184             unless ($user_ldap_bind_ret->code) {
 185                 $userldapentry = $entry;
 186                 $bind_ok = 1;
 187                 last;
 188             }
 189         }
 190
 191         unless ($bind_ok) {
 192             warn "LDAP Auth rejected : invalid password for user '$userid'.";
 193             return -1;
 194         }
 195
 196
 197     }
 198
 199     # To get here, LDAP has accepted our user's login attempt.
 200     # But we still have work to do.  See perldoc below for detailed breakdown.
 201
 202     my (%borrower);
 203         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 204
 205     if (( $borrowernumber and $config{update}   ) or
 206         (!$borrowernumber and $config{replicate})   ) {
 207         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 208         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 209     }
 210
 211     if ($borrowernumber) {
 212         if ($config{update}) { # A1, B1
 213             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 214             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 215         } else { # C1, D1
 216             # maybe update just the password?
 217                 return(1, $cardnumber, $local_userid);
 218         }
 219     } elsif ($config{replicate}) { # A2, C2
 220         my @columns = Koha::Patrons->columns;
 221         my $patron = Koha::Patron->new(
 222             {
 223                 map { exists( $borrower{$_} ) ? ( $_ => $borrower{$_} ) : () } @columns
 224             }
 225         )->store;
 226         die "Insert of new patron failed" unless $patron;
 227         $borrowernumber = $patron->borrowernumber;
 228         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 229    } else {
 230         return 0;   # B2, D2
 231     }
 232     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 233         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 234         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 235         while ( my $attribute_type = $attribute_types->next ) {
 236             my $code = $attribute_type->code;
 237             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 238                 next;
 239             }
 240             my $patron = Koha::Patrons->find($borrowernumber);
 241             if ( $patron ) { # Should not be needed, but we are in C4::Auth LDAP...
 242                 eval {
 243                     my $attribute = Koha::Patron::Attribute->new({code => $code, attribute => $borrower{$code}});
 244                     $patron->extended_attributes([$attribute->unblessed]);
 245                 };
 246                 if ($@) { # FIXME Test if Koha::Exceptions::Patron::Attribute::NonRepeatable
 247                     warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 248                 }
 249             }
 250         }
 251     }
 252     return(1, $cardnumber, $userid);
 253 }
 254
 255 # Pass LDAP entry object and local cardnumber (userid).
 256 # Returns borrower hash.
 257 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 258 # Ensure that mandatory fields are correctly filled!
 259 #
 260 sub ldap_entry_2_hash {
 261         my $userldapentry = shift;
 262         my %borrower = ( cardnumber => shift );
 263         my %memberhash;
 264         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 265         if ($debug) {
 266                 foreach (keys %$userldapentry) {
 267                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 268                 }
 269         }
 270         my $x = $userldapentry->{attrs} or return;
 271         foreach (keys %$x) {
 272                 $memberhash{$_} = join ' ', @{$x->{$_}};
 273                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 274         }
 275         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 276                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 277         foreach my $key (keys %mapping) {
 278                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 279                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 280                 unless (defined $data) {
 281             $data = $mapping{$key}->{content} || undef;
 282                 }
 283         $borrower{$key} = $data;
 284         }
 285         $borrower{initials} = $memberhash{initials} ||
 286                 ( substr($borrower{'firstname'},0,1)
 287                 . substr($borrower{ 'surname' },0,1)
 288                 . " ");
 289
 290     # categorycode conversions
 291     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 292         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 293     }
 294     elsif($default_categorycode) {
 295         $borrower{categorycode} = $default_categorycode;
 296     }
 297
 298         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 299         my $dbh = C4::Context->dbh;
 300         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 301         $sth->execute( uc($borrower{'categorycode'}) );
 302         unless ( my $row = $sth->fetchrow_hashref ) {
 303                 my $default = $mapping{'categorycode'}->{content};
 304                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 305                 $borrower{'categorycode'} = $default
 306         }
 307
 308         return %borrower;
 309 }
 310
 311 sub exists_local {
 312         my $arg = shift;
 313         my $dbh = C4::Context->dbh;
 314         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 315
 316         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 317         $sth->execute($arg);
 318         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 319         ($sth->rows == 1) and return $sth->fetchrow;
 320
 321         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 322         $sth->execute($arg);
 323         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 324         ($sth->rows == 1) and return $sth->fetchrow;
 325         return 0;
 326 }
 327
 328 # This function performs a password update, given the userid, borrowerid,
 329 # and digested password. It will verify that things are correct and return the
 330 # borrowers cardnumber. The idea is that it is used to keep the local
 331 # passwords in sync with the LDAP passwords.
 332 #
 333 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 334 #
 335 # Note: if the LDAP config has the update_password tag set to a false value,
 336 # then this will not update the password, it will simply return the cardnumber.
 337 sub _do_changepassword {
 338     my ($userid, $borrowerid, $password) = @_;
 339
 340     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 341
 342         # We don't store the password in the database
 343         my $sth = C4::Context->dbh->prepare(
 344             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 345         $sth->execute($borrowerid);
 346         die "Unable to access borrowernumber "
 347             . "with userid=$userid, "
 348             . "borrowernumber=$borrowerid"
 349           if !$sth->rows;
 350         my ($cardnum) = $sth->fetchrow;
 351         $sth = C4::Context->dbh->prepare(
 352             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 353         $sth->execute($borrowerid);
 354         return $cardnum;
 355     }
 356
 357     my $digest = hash_password($password);
 358     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 359     Koha::Patrons->find($borrowerid)->set_password({ password => $password, skip_validation => 1 });
 360
 361     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 362     return $cardnum if $ok;
 363
 364     warn "Password mismatch after update to borrowernumber=$borrowerid";
 365     return;
 366 }
 367
 368 sub update_local {
 369     my $userid     = shift or croak "No userid";
 370     my $password   = shift or croak "No password";
 371     my $borrowerid = shift or croak "No borrowerid";
 372     my $borrower   = shift or croak "No borrower record";
 373
 374     # skip extended patron attributes in 'borrowers' attribute update
 375     my @keys = keys %$borrower;
 376     if (C4::Context->preference('ExtendedPatronAttributes')) {
 377         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 378         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 379         while ( my $attribute_type = $attribute_types->next ) {
 380            my $code = $attribute_type->code;
 381            @keys = grep { $_ ne $code } @keys;
 382            $debug and printf STDERR "ignoring extended patron attribute '%s' in update_local()\n", $code;
 383         }
 384     }
 385
 386     my $dbh = C4::Context->dbh;
 387     my $query = "UPDATE  borrowers\nSET     " .
 388         join(',', map {"$_=?"} @keys) .
 389         "\nWHERE   borrowernumber=? ";
 390     my $sth = $dbh->prepare($query);
 391     if ($debug) {
 392         print STDERR $query, "\n",
 393             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 394         print STDERR "\nuserid = $userid\n";
 395     }
 396     $sth->execute(
 397         ((map {$borrower->{$_}} @keys), $borrowerid)
 398     );
 399
 400     # MODIFY PASSWORD/LOGIN if password was mapped
 401     _do_changepassword($userid, $borrowerid, $password) if exists( $borrower->{'password'} );
 402 }
 403
 404 1;
 405 __END__
 406
 407 =head1 NAME
 408
 409 C4::Auth - Authenticates Koha users
 410
 411 =head1 SYNOPSIS
 412
 413   use C4::Auth_with_ldap;
 414
 415 =head1 LDAP Configuration
 416
 417     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 418         working LDAP servers.
 419         To use it :
 420            * Modify ldapserver element in KOHA_CONF
 421            * Establish field mapping in <mapping> element.
 422
 423         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 424         the username would match the "uid" field, and the password should match the "userpassword" field.
 425
 426         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 427         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 428
 429         mysql> show COLUMNS from borrowers;
 430                 +---------------------+--------------+------+-----+---------+----------------+
 431                 | Field               | Type         | Null | Key | Default | Extra          |
 432                 +---------------------+--------------+------+-----+---------+----------------+
 433                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 434                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 435                 | surname             | mediumtext   | NO   |     | NULL    |                |
 436                 | firstname           | text         | YES  |     | NULL    |                |
 437                 | title               | mediumtext   | YES  |     | NULL    |                |
 438                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 439                 | initials            | text         | YES  |     | NULL    |                |
 440                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 441                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 442                 | address             | mediumtext   | NO   |     | NULL    |                |
 443                 | address2            | text         | YES  |     | NULL    |                |
 444                 | city                | mediumtext   | NO   |     | NULL    |                |
 445                 | state               | mediumtext   | YES  |     | NULL    |                |
 446                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 447                 | country             | text         | YES  |     | NULL    |                |
 448                 | email               | mediumtext   | YES  |     | NULL    |                |
 449                 | phone               | text         | YES  |     | NULL    |                |
 450                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 451                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 452                 | emailpro            | text         | YES  |     | NULL    |                |
 453                 | phonepro            | text         | YES  |     | NULL    |                |
 454                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 455                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 456                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 457                 | B_address2          | text         | YES  |     | NULL    |                |
 458                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 459                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 460                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 461                 | B_country           | text         | YES  |     | NULL    |                |
 462                 | B_email             | text         | YES  |     | NULL    |                |
 463                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 464                 | dateofbirth         | date         | YES  |     | NULL    |                |
 465                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 466                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 467                 | dateenrolled        | date         | YES  |     | NULL    |                |
 468                 | dateexpiry          | date         | YES  |     | NULL    |                |
 469                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 470                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 471                 | debarred            | date         | YES  |     | NULL    |                |
 472                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 473                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 474                 | contactfirstname    | text         | YES  |     | NULL    |                |
 475                 | contacttitle        | text         | YES  |     | NULL    |                |
 476                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 477                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 478                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 479                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 480                 | password            | varchar(30)  | YES  |     | NULL    |                |
 481                 | flags               | int(11)      | YES  |     | NULL    |                |
 482                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 483                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 484                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 485                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 486                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 487                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 488                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 489                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 490                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 491                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 492                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 493                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 494                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 495                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 496                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 497                 | privacy             | int(11)      | NO   |     | 1       |                |
 498                 +---------------------+--------------+------+-----+---------+----------------+
 499                 66 rows in set (0.00 sec)
 500                 Where Null="NO", the field is required.
 501
 502 =head1 KOHA_CONF and field mapping
 503
 504 Example XML stanza for LDAP configuration in KOHA_CONF.
 505
 506  <config>
 507   ...
 508   <useldapserver>1</useldapserver>
 509   <!-- LDAP SERVER (optional) -->
 510   <ldapserver id="ldapserver">
 511     <hostname>localhost</hostname>
 512     <base>dc=metavore,dc=com</base>
 513     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 514     <pass>metavore</pass>          <!-- password, if not anonymous -->
 515     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 516     <update>1</update>             <!-- update existing users in Koha database -->
 517     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 518                                         password comparison, e.g., to use Active Directory -->
 519     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 520                                             an anonymous bind, even when auth_by_bind is on -->
 521     <principal_name>%s@my_domain.com</principal_name>
 522                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 523                                         Not used with anonymous_bind. -->
 524     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 525                                               synced to the local database -->
 526     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 527       <firstname    is="givenname"      ></firstname>
 528       <surname      is="sn"             ></surname>
 529       <address      is="postaladdress"  ></address>
 530       <city         is="l"              >Athens, OH</city>
 531       <zipcode      is="postalcode"     ></zipcode>
 532       <branchcode   is="branch"         >MAIN</branchcode>
 533       <userid       is="uid"            ></userid>
 534       <password     is="userpassword"   ></password>
 535       <email        is="mail"           ></email>
 536       <categorycode is="employeetype"   >PT</categorycode>
 537       <phone        is="telephonenumber"></phone>
 538     </mapping>
 539   </ldapserver>
 540  </config>
 541
 542 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 543 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 544 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 545 patron).
 546
 547 =head1 CONFIGURATION
 548
 549 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 550 your configuration and the presence of a matching Koha user in your local DB:
 551
 552                          LOCAL_USER
 553  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 554    A1      1       1        1      OK : We're updating them anyway.
 555    A2      1       1        0      OK : We're adding them anyway.
 556    B1      1       0        1      OK : We update them.
 557    B2      1       0        0     FAIL: We cannot add new user.
 558    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 559    C2      0       1        0      OK : We add the new user.
 560    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 561    D2      0       0        0     FAIL: We cannot add new user.
 562
 563 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 564 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 565 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 566
 567 If you choose NOT to update local users, the borrowers table will not be affected at all.
 568 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 569 the local table never contained the LDAP values.
 570
 571 =head2 auth_by_bind
 572
 573 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 574
 575 =head2 principal_name
 576
 577 Provides an optional sprintf-style format for manipulating the userid before the bind.
 578 Even though the userPrincipalName is one intended target, any uniquely identifying
 579 attribute that the server allows to be used for binding could be used.
 580
 581 Currently, principal_name only operates when auth_by_bind is enabled.
 582
 583 =head2 update_password
 584
 585 If this tag is left out or set to a true value, then the user's LDAP password
 586 will be stored (hashed) in the local Koha database. If you don't want this
 587 to happen, then set the value of this to '0'. Note that if passwords are not
 588 stored locally, and the connection to the LDAP system fails, then the users
 589 will not be able to log in at all.
 590
 591 =head2 Active Directory
 592
 593 The auth_by_bind and principal_name settings are recommended for Active Directory.
 594
 595 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 596 we would typically under openldap.  Instead of:
 597
 598     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 599
 600 We might get:
 601
 602     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 603
 604 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 605 in Koha userids.  But the userPrincipalName should be consistent, something like:
 606
 607     userPrincipalName: barnes.7@my_company.com
 608
 609 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 610 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 611 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 612 like this:
 613     <principal_name>%s@core.my_company.com</principal_name>
 614
 615 The user of the previous example, barnes.7, would then attempt to bind as:
 616     barnes.7@core.my_company.com
 617
 618 =head1 SEE ALSO
 619
 620 CGI(3)
 621
 622 Net::LDAP()
 623
 624 XML::Simple()
 625
 626 Digest::MD5(3)
 627
 628 sprintf()
 629
 630 =cut
 631
 632 # For reference, here's an important difference in the data structure we rely on.
 633 # ========================================
 634 # Using attrs instead of {asn}->attributes
 635 # ========================================
 636 #
 637 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 638 #       LDAP key: ->{             cn}->{           sss} = sss
 639 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 640 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 641 #
 642 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 643 #       LDAP key: ->{      givenname}->{Steve} = Steve
 644 #