C4/Barcodes/hbyymmincr.pm

   1 package C4::Barcodes::hbyymmincr;
   2
   3 # Copyright 2008 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use Carp;
  24
  25 use C4::Context;
  26 use C4::Debug;
  27
  28 use Koha::DateUtils qw( dt_from_string output_pref );
  29
  30 use vars qw(@ISA);
  31 use vars qw($debug $cgi_debug); # from C4::Debug, of course
  32 our $branch = '';
  33 our $width = 4; # FIXME: 4 is too small for sizeable or multi-branch libraries.
  34
  35 BEGIN {
  36     @ISA = qw(C4::Barcodes);
  37 }
  38
  39 # Generates barcode where hb = home branch Code, yymm = year/month catalogued, incr = incremental number,
  40 #       increment resets yearly -fbcit
  41
  42 sub db_max {
  43         my $self = shift;
  44     my $query = "SELECT SUBSTRING(barcode,-$width) AS chunk, barcode FROM items WHERE barcode REGEXP ?  ORDER BY chunk DESC LIMIT 1";
  45         $debug and print STDERR "(hbyymmincr) db_max query: $query\n";
  46         my $sth = C4::Context->dbh->prepare($query);
  47         my ($iso);
  48         if (@_) {
  49                 my $input = shift;
  50                 $iso = output_pref({ dt => dt_from_string( $input, 'iso' ), dateformat => 'iso', dateonly => 1 }); # try to set the date w/ 2nd arg
  51                 unless ($iso) {
  52                         warn "Failed to create 'iso' Dates object with input '$input'.  Reverting to today's date.";
  53                         $iso = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 });      # failover back to today
  54                 }
  55         } else {
  56                 $iso = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 });
  57         }
  58         my $year = substr($iso,2,2);    # i.e. "08" for 2008
  59         my $andtwo = $width+2;
  60         $sth->execute("^[a-zA-Z]{1,}" . $year . "[0-9]{$andtwo}");      # the extra two digits are the month.  we don't care what they are, just that they are there.
  61         unless ($sth->rows) {
  62                 warn "No existing hbyymmincr barcodes found.  Reverting to initial value.";
  63                 return $self->initial;
  64         }
  65         my ($row) = $sth->fetchrow_hashref;
  66         my $max = $row->{barcode};
  67         warn "barcode max (hbyymmincr format): $max" if $debug;
  68         return ($max || 0);
  69 }
  70
  71 sub initial {
  72         my $self = shift;
  73         # FIXME: populated branch?
  74     my $iso = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 }); # like "2008-07-02"
  75     warn "HBYYMM Barcode was not passed a branch, default is blank" if ( $self->branch eq '' );
  76         return $self->branch . substr($iso,2,2) . substr($iso,5,2) . sprintf('%' . "$width.$width" . 'd',1);
  77 }
  78
  79 sub parse {   # return 3 parts of barcode: non-incrementing, incrementing, non-incrementing
  80         my $self = shift;
  81         my $barcode = (@_) ? shift : $self->value;
  82         my $branch = $self->branch;
  83         unless ($barcode =~ /($branch\d{4})(\d+)$/) {
  84                 carp "Barcode '$barcode' has no incrementing part!";
  85                 return ($barcode,undef,undef);
  86         }
  87         $debug and warn "Barcode '$barcode' parses into: '$1', '$2', ''";
  88         return ($1,$2,'');  # the third part is in anticipation of barcodes that include checkdigits
  89 }
  90
  91 sub branch {
  92         my $self = shift;
  93         (@_) and $self->{branch} = shift;
  94         return $self->{branch};
  95 }
  96 sub width {
  97         my $self = shift;
  98         (@_) and $width = shift;        # hitting the class variable.
  99         return $width;
 100 }
 101 sub process_head {      # (self,head,whole,specific)
 102         my ($self,$head,$whole,$specific) = @_;
 103         $specific and return $head;     # if this is built off an existing barcode, just return the head unchanged.
 104         $head =~ s/\d{4}$//;            # else strip the old yymm
 105     my $iso = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 }); # like "2008-07-02"
 106         return $head . substr($iso,2,2) . substr($iso,5,2);
 107 }
 108
 109 sub new_object {
 110     $debug and warn "hbyymmincr: new_object called";
 111     my $class_or_object = shift;
 112
 113     my $type = ref($class_or_object) || $class_or_object;
 114
 115     my $from_obj =
 116       ref($class_or_object)
 117       ? 1
 118       : 0;    # are we building off another Barcodes object?
 119
 120       my $self = $class_or_object->default_self('hbyymmincr');
 121     bless $self, $type;
 122
 123     $self->branch( @_ ? shift : $from_obj ? $class_or_object->branch : $branch );
 124     warn "HBYYMM Barcode created with no branchcode, default is blank" if ( $self->branch() eq '' );
 125
 126     # take the branch from argument, or existing object, or default
 127     use Data::Dumper;
 128     $debug and print STDERR "(hbyymmincr) new_object: ", Dumper($self), "\n";
 129
 130     return $self;
 131 }
 132
 133 1;
 134 __END__
 135
 136 =head1 NOTICE
 137
 138 This format is deprecated and SHOULD NOT BE USED.
 139
 140 It is fairly clear the originator of the format did not intend to accommodate
 141 multiple branch libraries, given that the format caps the available namespace to
 142 10,000 barcodes per year TOTAL.
 143
 144 Also, the question of what to do with an item that changes branch is unsettled.
 145 Nothing prevents the barcode from working fine, but it will look out of place
 146 with the old branchcode in it.  Rebarcoding a single item is trivial, but if you
 147 consider the scenario of branches being consolidated, it is an unnecessary
 148 burden to force the rebarcoding of thousands of items, especially when the format
 149 will limit you to under 10,000 on the year!
 150
 151 The main purpose of the format seems to be to get the branch code into the barcode.
 152 This is wholly unnecessary, since the barcodes can be printed with the branchcode
 153 directly on it, without it being part of the barcode itself.
 154
 155 The API for this module should exist almost exclusively through C4::Barcodes.
 156 One novel aspect of this format is the fact that the barcode is tied to a branch.
 157
 158 =cut