C4/Branch.pm

   1 package C4::Branch;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along with
  15 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  16 # Suite 330, Boston, MA  02111-1307 USA
  17
  18
  19 use strict;
  20 #use warnings; FIXME - Bug 2505
  21 require Exporter;
  22 use C4::Context;
  23
  24 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  25
  26 BEGIN {
  27         # set the version for version checking
  28     $VERSION = 3.07.00.049;
  29         @ISA    = qw(Exporter);
  30         @EXPORT = qw(
  31                 &GetBranchCategory
  32                 &GetBranchName
  33                 &GetBranch
  34                 &GetBranches
  35                 &GetBranchesLoop
  36                 &GetBranchDetail
  37                 &get_branchinfos_of
  38                 &ModBranch
  39                 &CheckBranchCategorycode
  40                 &GetBranchInfo
  41                 &GetCategoryTypes
  42                 &GetBranchCategories
  43                 &GetBranchesInCategory
  44                 &ModBranchCategoryInfo
  45                 &DelBranch
  46                 &DelBranchCategory
  47                 &CheckCategoryUnique
  48                 &mybranch
  49                 &GetBranchesCount
  50         );
  51     @EXPORT_OK = qw( &onlymine &mybranch );
  52 }
  53
  54 =head1 NAME
  55
  56 C4::Branch - Koha branch module
  57
  58 =head1 SYNOPSIS
  59
  60 use C4::Branch;
  61
  62 =head1 DESCRIPTION
  63
  64 The functions in this module deal with branches.
  65
  66 =head1 FUNCTIONS
  67
  68 =head2 GetBranches
  69
  70   $branches = &GetBranches();
  71
  72 Returns informations about ALL branches, IndependentBranches Insensitive.
  73 GetBranchInfo() returns the same information without the problems of this function
  74 (namespace collision, mainly).
  75
  76 Create a branch selector with the following code.
  77
  78 =head3 in PERL SCRIPT
  79
  80     my $branches = GetBranches;
  81     my @branchloop;
  82     foreach my $thisbranch (sort keys %$branches) {
  83         my $selected = 1 if $thisbranch eq $branch;
  84         my %row =(value => $thisbranch,
  85                     selected => $selected,
  86                     branchname => $branches->{$thisbranch}->{branchname},
  87                 );
  88         push @branchloop, \%row;
  89     }
  90
  91 =head3 in TEMPLATE
  92
  93     <select name="branch">
  94         <option value="">Default</option>
  95         <!-- TMPL_LOOP name="branchloop" -->
  96         <option value="<!-- TMPL_VAR name="value" -->" <!-- TMPL_IF name="selected" -->selected<!-- /TMPL_IF -->><!-- TMPL_VAR name="branchname" --></option>
  97         <!-- /TMPL_LOOP -->
  98     </select>
  99
 100 =head4 Note that you often will want to just use GetBranchesLoop, for exactly the example above.
 101
 102 =cut
 103
 104 sub GetBranches {
 105     my ($onlymine)=@_;
 106     # returns a reference to a hash of references to ALL branches...
 107     my %branches;
 108     my $dbh = C4::Context->dbh;
 109     my $sth;
 110     my $query="SELECT * FROM branches";
 111     my @bind_parameters;
 112     if ($onlymine && C4::Context->userenv && C4::Context->userenv->{branch}){
 113       $query .= ' WHERE branchcode = ? ';
 114       push @bind_parameters, C4::Context->userenv->{branch};
 115     }
 116         $query.=" ORDER BY branchname";
 117     $sth = $dbh->prepare($query);
 118     $sth->execute( @bind_parameters );
 119
 120     my $nsth = $dbh->prepare(
 121         "SELECT categorycode FROM branchrelations WHERE branchcode = ?"
 122     );  # prepare once, outside while loop
 123
 124     while ( my $branch = $sth->fetchrow_hashref ) {
 125         $nsth->execute( $branch->{'branchcode'} );
 126         while ( my ($cat) = $nsth->fetchrow_array ) {
 127             # FIXME - This seems wrong. It ought to be
 128             # $branch->{categorycodes}{$cat} = 1;
 129             # otherwise, there's a namespace collision if there's a
 130             # category with the same name as a field in the 'branches'
 131             # table (i.e., don't create a category called "issuing").
 132             # In addition, the current structure doesn't really allow
 133             # you to list the categories that a branch belongs to:
 134             # you'd have to list keys %$branch, and remove those keys
 135             # that aren't fields in the "branches" table.
 136          #   $branch->{$cat} = 1;
 137             $branch->{category}{$cat} = 1;
 138         }
 139         $branches{ $branch->{'branchcode'} } = $branch;
 140     }
 141     return ( \%branches );
 142 }
 143
 144 sub onlymine {
 145     return
 146     C4::Context->preference('IndependentBranches') &&
 147     C4::Context->userenv                           &&
 148     C4::Context->userenv->{flags} %2 != 1          &&
 149     C4::Context->userenv->{branch}                 ;
 150 }
 151
 152 # always returns a string for OK comparison via "eq" or "ne"
 153 sub mybranch {
 154     C4::Context->userenv           or return '';
 155     return C4::Context->userenv->{branch} || '';
 156 }
 157
 158 sub GetBranchesLoop {  # since this is what most pages want anyway
 159     my $branch   = @_ ? shift : mybranch();     # optional first argument is branchcode of "my branch", if preselection is wanted.
 160     my $onlymine = @_ ? shift : onlymine();
 161     my $branches = GetBranches($onlymine);
 162     my @loop;
 163     foreach my $branchcode ( sort { uc($branches->{$a}->{branchname}) cmp uc($branches->{$b}->{branchname}) } keys %$branches ) {
 164         push @loop, {
 165             value      => $branchcode,
 166             branchcode => $branchcode,
 167             selected   => ($branchcode eq $branch) ? 1 : 0,
 168             branchname => $branches->{$branchcode}->{branchname},
 169         };
 170     }
 171     return \@loop;
 172 }
 173
 174 =head2 GetBranchName
 175
 176 =cut
 177
 178 sub GetBranchName {
 179     my ($branchcode) = @_;
 180     my $dbh = C4::Context->dbh;
 181     my $sth;
 182     $sth = $dbh->prepare("Select branchname from branches where branchcode=?");
 183     $sth->execute($branchcode);
 184     my $branchname = $sth->fetchrow_array;
 185     $sth->finish;
 186     return ($branchname);
 187 }
 188
 189 =head2 ModBranch
 190
 191 $error = &ModBranch($newvalue);
 192
 193 This function modify an existing branch
 194
 195 C<$newvalue> is a ref to an array wich is containt all the column from branches table.
 196
 197 =cut
 198
 199 sub ModBranch {
 200     my ($data) = @_;
 201
 202     my $dbh    = C4::Context->dbh;
 203     if ($data->{add}) {
 204         my $query  = "
 205             INSERT INTO branches
 206             (branchcode,branchname,branchaddress1,
 207             branchaddress2,branchaddress3,branchzip,branchcity,branchstate,
 208             branchcountry,branchphone,branchfax,branchemail,
 209             branchurl,branchip,branchprinter,branchnotes,opac_info)
 210             VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 211         ";
 212         my $sth    = $dbh->prepare($query);
 213         $sth->execute(
 214             $data->{'branchcode'},       $data->{'branchname'},
 215             $data->{'branchaddress1'},   $data->{'branchaddress2'},
 216             $data->{'branchaddress3'},   $data->{'branchzip'},
 217             $data->{'branchcity'},       $data->{'branchstate'},
 218             $data->{'branchcountry'},
 219             $data->{'branchphone'},      $data->{'branchfax'},
 220             $data->{'branchemail'},      $data->{'branchurl'},
 221             $data->{'branchip'},         $data->{'branchprinter'},
 222             $data->{'branchnotes'},      $data->{opac_info},
 223         );
 224         return 1 if $dbh->err;
 225     } else {
 226         my $query  = "
 227             UPDATE branches
 228             SET branchname=?,branchaddress1=?,
 229                 branchaddress2=?,branchaddress3=?,branchzip=?,
 230                 branchcity=?,branchstate=?,branchcountry=?,branchphone=?,
 231                 branchfax=?,branchemail=?,branchurl=?,branchip=?,
 232                 branchprinter=?,branchnotes=?,opac_info=?
 233             WHERE branchcode=?
 234         ";
 235         my $sth    = $dbh->prepare($query);
 236         $sth->execute(
 237             $data->{'branchname'},
 238             $data->{'branchaddress1'},   $data->{'branchaddress2'},
 239             $data->{'branchaddress3'},   $data->{'branchzip'},
 240             $data->{'branchcity'},       $data->{'branchstate'},
 241             $data->{'branchcountry'},
 242             $data->{'branchphone'},      $data->{'branchfax'},
 243             $data->{'branchemail'},      $data->{'branchurl'},
 244             $data->{'branchip'},         $data->{'branchprinter'},
 245             $data->{'branchnotes'},      $data->{opac_info},
 246             $data->{'branchcode'},
 247         );
 248     }
 249     # sort out the categories....
 250     my @checkedcats;
 251     my $cats = GetBranchCategories();
 252     foreach my $cat (@$cats) {
 253         my $code = $cat->{'categorycode'};
 254         if ( $data->{$code} ) {
 255             push( @checkedcats, $code );
 256         }
 257     }
 258     my $branchcode = uc( $data->{'branchcode'} );
 259     my $branch     = GetBranchInfo($branchcode);
 260     $branch = $branch->[0];
 261     my $branchcats = $branch->{'categories'};
 262     my @addcats;
 263     my @removecats;
 264     foreach my $bcat (@$branchcats) {
 265
 266         unless ( grep { /^$bcat$/ } @checkedcats ) {
 267             push( @removecats, $bcat );
 268         }
 269     }
 270     foreach my $ccat (@checkedcats) {
 271         unless ( grep { /^$ccat$/ } @$branchcats ) {
 272             push( @addcats, $ccat );
 273         }
 274     }
 275     foreach my $cat (@addcats) {
 276         my $sth =
 277           $dbh->prepare(
 278 "insert into branchrelations (branchcode, categorycode) values(?, ?)"
 279           );
 280         $sth->execute( $branchcode, $cat );
 281         $sth->finish;
 282     }
 283     foreach my $cat (@removecats) {
 284         my $sth =
 285           $dbh->prepare(
 286             "delete from branchrelations where branchcode=? and categorycode=?"
 287           );
 288         $sth->execute( $branchcode, $cat );
 289         $sth->finish;
 290     }
 291 }
 292
 293 =head2 GetBranchCategory
 294
 295 $results = GetBranchCategory($categorycode);
 296
 297 C<$results> is an hashref
 298
 299 =cut
 300
 301 sub GetBranchCategory {
 302     my ($catcode) = @_;
 303     return unless $catcode;
 304
 305     my $dbh = C4::Context->dbh;
 306     my $sth;
 307
 308     $sth = $dbh->prepare(q{
 309         SELECT *
 310         FROM branchcategories
 311         WHERE categorycode = ?
 312     });
 313     $sth->execute( $catcode );
 314     return $sth->fetchrow_hashref;
 315 }
 316
 317 =head2 GetBranchCategories
 318
 319   my $categories = GetBranchCategories($categorytype,$show_in_pulldown,$selected_in_pulldown);
 320
 321 Returns a list ref of anon hashrefs with keys eq columns of branchcategories table,
 322 i.e. categorydescription, categorytype, categoryname.
 323
 324 =cut
 325
 326 sub GetBranchCategories {
 327     my ( $categorytype, $show_in_pulldown, $selected_in_pulldown ) = @_;
 328     my $dbh = C4::Context->dbh();
 329
 330     my $query = "SELECT * FROM branchcategories ";
 331
 332     my ( @where, @bind );
 333     if ( $categorytype ) {
 334         push @where, " categorytype = ? ";
 335         push @bind, $categorytype;
 336     }
 337
 338     if ( defined( $show_in_pulldown ) ) {
 339         push( @where, " show_in_pulldown = ? " );
 340         push( @bind, $show_in_pulldown );
 341     }
 342
 343     $query .= " WHERE " . join(" AND ", @where) if(@where);
 344     $query .= " ORDER BY categorytype, categorycode";
 345     my $sth=$dbh->prepare( $query);
 346     $sth->execute(@bind);
 347
 348     my $branchcats = $sth->fetchall_arrayref({});
 349
 350     if ( $selected_in_pulldown ) {
 351         foreach my $bc ( @$branchcats ) {
 352             $bc->{selected} = 1 if $bc->{categorycode} eq $selected_in_pulldown;
 353         }
 354     }
 355
 356     return $branchcats;
 357 }
 358
 359 =head2 GetCategoryTypes
 360
 361 $categorytypes = GetCategoryTypes;
 362 returns a list of category types.
 363 Currently these types are HARDCODED.
 364 type: 'searchdomain' defines a group of agencies that the calling library may search in.
 365 Other usage of agency categories falls under type: 'properties'.
 366         to allow for other uses of categories.
 367 The searchdomain bit may be better implemented as a separate module, but
 368 the categories were already here, and minimally used.
 369 =cut
 370
 371         #TODO  manage category types.  rename possibly to 'agency domains' ? as borrowergroups are called categories.
 372 sub GetCategoryTypes {
 373         return ( 'searchdomain','properties');
 374 }
 375
 376 =head2 GetBranch
 377
 378 $branch = GetBranch( $query, $branches );
 379
 380 =cut
 381
 382 sub GetBranch {
 383     my ( $query, $branches ) = @_;    # get branch for this query from branches
 384     my $branch = $query->param('branch');
 385     my %cookie = $query->cookie('userenv');
 386     ($branch)                || ($branch = $cookie{'branchname'});
 387     ( $branches->{$branch} ) || ( $branch = ( keys %$branches )[0] );
 388     return $branch;
 389 }
 390
 391 =head2 GetBranchDetail
 392
 393     $branch = &GetBranchDetail($branchcode);
 394
 395 Given the branch code, the function returns a
 396 hashref for the corresponding row in the branches table.
 397
 398 =cut
 399
 400 sub GetBranchDetail {
 401     my ($branchcode) = shift or return;
 402     my $sth = C4::Context->dbh->prepare("SELECT * FROM branches WHERE branchcode = ?");
 403     $sth->execute($branchcode);
 404     return $sth->fetchrow_hashref();
 405 }
 406
 407 =head2 GetBranchesInCategory
 408
 409   my $branches = GetBranchesInCategory($categorycode);
 410
 411 Returns a href:  keys %$branches eq (branchcode,branchname) .
 412
 413 =cut
 414
 415 sub GetBranchesInCategory {
 416     my ($categorycode) = @_;
 417         my @branches;
 418         my $dbh = C4::Context->dbh();
 419         my $sth=$dbh->prepare( "SELECT b.branchcode FROM branchrelations r, branches b
 420                                                         where r.branchcode=b.branchcode and r.categorycode=?");
 421     $sth->execute($categorycode);
 422         while (my $branch = $sth->fetchrow) {
 423                 push @branches, $branch;
 424         }
 425         $sth->finish();
 426         return( \@branches );
 427 }
 428
 429 =head2 GetBranchInfo
 430
 431 $results = GetBranchInfo($branchcode);
 432
 433 returns C<$results>, a reference to an array of hashes containing branches.
 434 if $branchcode, just this branch, with associated categories.
 435 if ! $branchcode && $categorytype, all branches in the category.
 436 =cut
 437
 438 sub GetBranchInfo {
 439     my ($branchcode,$categorytype) = @_;
 440     my $dbh = C4::Context->dbh;
 441     my $sth;
 442
 443
 444         if ($branchcode) {
 445         $sth =
 446           $dbh->prepare(
 447             "Select * from branches where branchcode = ? order by branchcode");
 448         $sth->execute($branchcode);
 449     }
 450     else {
 451         $sth = $dbh->prepare("Select * from branches order by branchcode");
 452         $sth->execute();
 453     }
 454     my @results;
 455     while ( my $data = $sth->fetchrow_hashref ) {
 456                 my @bind = ($data->{'branchcode'});
 457         my $query= "select r.categorycode from branchrelations r";
 458                 $query .= ", branchcategories c " if($categorytype);
 459                 $query .= " where  branchcode=? ";
 460                 if($categorytype) {
 461                         $query .= " and c.categorytype=? and r.categorycode=c.categorycode";
 462                         push @bind, $categorytype;
 463                 }
 464         my $nsth=$dbh->prepare($query);
 465                 $nsth->execute( @bind );
 466         my @cats = ();
 467         while ( my ($cat) = $nsth->fetchrow_array ) {
 468             push( @cats, $cat );
 469         }
 470         $nsth->finish;
 471         $data->{'categories'} = \@cats;
 472         push( @results, $data );
 473     }
 474     $sth->finish;
 475     return \@results;
 476 }
 477
 478 =head2 DelBranch
 479
 480 &DelBranch($branchcode);
 481
 482 =cut
 483
 484 sub DelBranch {
 485     my ($branchcode) = @_;
 486     my $dbh = C4::Context->dbh;
 487     my $sth = $dbh->prepare("delete from branches where branchcode = ?");
 488     $sth->execute($branchcode);
 489     $sth->finish;
 490 }
 491
 492 =head2 ModBranchCategoryInfo
 493
 494 &ModBranchCategoryInfo($data);
 495 sets the data from the editbranch form, and writes to the database...
 496
 497 =cut
 498
 499 sub ModBranchCategoryInfo {
 500     my ($data) = @_;
 501     my $dbh    = C4::Context->dbh;
 502     if ($data->{'add'}){
 503         # we are doing an insert
 504   my $sth   = $dbh->prepare("INSERT INTO branchcategories (categorycode,categoryname,codedescription,categorytype,show_in_pulldown) VALUES (?,?,?,?,?)");
 505         $sth->execute(uc( $data->{'categorycode'} ),$data->{'categoryname'}, $data->{'codedescription'},$data->{'categorytype'},$data->{'show_in_pulldown'} );
 506         $sth->finish();
 507     }
 508     else {
 509         # modifying
 510         my $sth = $dbh->prepare("UPDATE branchcategories SET categoryname=?,codedescription=?,categorytype=?,show_in_pulldown=? WHERE categorycode=?");
 511         $sth->execute($data->{'categoryname'}, $data->{'codedescription'},$data->{'categorytype'},$data->{'show_in_pulldown'},uc( $data->{'categorycode'} ) );
 512         $sth->finish();
 513     }
 514 }
 515
 516 =head2 CheckCategoryUnique
 517
 518 if (CheckCategoryUnique($categorycode)){
 519   # do something
 520 }
 521
 522 =cut
 523
 524 sub CheckCategoryUnique {
 525     my $categorycode = shift;
 526     my $dbh    = C4::Context->dbh;
 527     my $sth = $dbh->prepare("SELECT categorycode FROM branchcategories WHERE categorycode = ?");
 528     $sth->execute(uc( $categorycode) );
 529     if (my $data = $sth->fetchrow_hashref){
 530         return 0;
 531     }
 532     else {
 533         return 1;
 534     }
 535 }
 536
 537
 538 =head2 DeleteBranchCategory
 539
 540 DeleteBranchCategory($categorycode);
 541
 542 =cut
 543
 544 sub DelBranchCategory {
 545     my ($categorycode) = @_;
 546     my $dbh = C4::Context->dbh;
 547     my $sth = $dbh->prepare("delete from branchcategories where categorycode = ?");
 548     $sth->execute($categorycode);
 549     $sth->finish;
 550 }
 551
 552 =head2 CheckBranchCategorycode
 553
 554 $number_rows_affected = CheckBranchCategorycode($categorycode);
 555
 556 =cut
 557
 558 sub CheckBranchCategorycode {
 559
 560     # check to see if the branchcode is being used in the database somewhere....
 561     my ($categorycode) = @_;
 562     my $dbh            = C4::Context->dbh;
 563     my $sth            =
 564       $dbh->prepare(
 565         "select count(*) from branchrelations where categorycode=?");
 566     $sth->execute($categorycode);
 567     my ($total) = $sth->fetchrow_array;
 568     return $total;
 569 }
 570
 571 sub GetBranchesCount {
 572     my $dbh = C4::Context->dbh();
 573     my $query = "SELECT COUNT(*) AS branches_count FROM branches";
 574     my $sth = $dbh->prepare( $query );
 575     $sth->execute();
 576     my $row = $sth->fetchrow_hashref();
 577     return $row->{'branches_count'};
 578 }
 579
 580 1;
 581 __END__
 582
 583 =head1 AUTHOR
 584
 585 Koha Development Team <http://koha-community.org/>
 586
 587 =cut