C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use C4::Context;
  28 use C4::Stats qw( UpdateStats );
  29 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest ItemsAnyAvailableAndNotRestricted );
  30 use C4::Biblio qw( UpdateTotalIssues );
  31 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Log qw( logaction ); # logaction
  36 use C4::Overdues;
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits qw( CheckDigits );
  39
  40 use Data::Dumper qw( Dumper );
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment GetDebarments AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetUpcomingDueIssues
  99       CheckIfIssuedToPatron
 100       IsItemIssued
 101       GetAgeRestriction
 102       GetTopIssues
 103
 104       AddReturn
 105       MarkIssueReturned
 106
 107       transferbook
 108       TooMany
 109       GetTransfersFromTo
 110       updateWrongTransfer
 111       CalcDateDue
 112       CheckValidBarcode
 113       IsBranchTransferAllowed
 114       CreateBranchTransferLimit
 115       DeleteBranchTransferLimits
 116       TransferSlip
 117
 118       GetOfflineOperations
 119       GetOfflineOperation
 120       AddOfflineOperation
 121       DeleteOfflineOperation
 122       ProcessOfflineOperation
 123       ProcessOfflinePayment
 124       ProcessOfflineIssue
 125     );
 126     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 127 }
 128
 129 =head1 NAME
 130
 131 C4::Circulation - Koha circulation module
 132
 133 =head1 SYNOPSIS
 134
 135 use C4::Circulation;
 136
 137 =head1 DESCRIPTION
 138
 139 The functions in this module deal with circulation, issues, and
 140 returns, as well as general information about the library.
 141 Also deals with inventory.
 142
 143 =head1 FUNCTIONS
 144
 145 =head2 barcodedecode
 146
 147   $str = &barcodedecode($barcode, [$filter]);
 148
 149 Generic filter function for barcode string.
 150 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 151 Will do some manipulation of the barcode for systems that deliver a barcode
 152 to circulation.pl that differs from the barcode stored for the item.
 153 For proper functioning of this filter, calling the function on the
 154 correct barcode string (items.barcode) should return an unaltered barcode.
 155 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 156
 157 The optional $filter argument is to allow for testing or explicit
 158 behavior that ignores the System Pref.  Valid values are the same as the
 159 System Pref options.
 160
 161 =cut
 162
 163 # FIXME -- the &decode fcn below should be wrapped into this one.
 164 # FIXME -- these plugins should be moved out of Circulation.pm
 165 #
 166 sub barcodedecode {
 167     my ($barcode, $filter) = @_;
 168
 169     return unless defined $barcode;
 170
 171     my $branch = C4::Context::mybranch();
 172     $barcode =~ s/^\s+|\s+$//g;
 173     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 174     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 175     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 176         if ($filter eq 'whitespace') {
 177                 $barcode =~ s/\s//g;
 178         } elsif ($filter eq 'cuecat') {
 179                 chomp($barcode);
 180             my @fields = split( /\./, $barcode );
 181             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 182             ($#results == 2) and return $results[2];
 183         } elsif ($filter eq 'T-prefix') {
 184                 if ($barcode =~ /^[Tt](\d)/) {
 185                         (defined($1) and $1 eq '0') and return $barcode;
 186             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 187                 }
 188         return sprintf("T%07d", $barcode);
 189         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 190         # Why drop the nonzero digit after the T?
 191         # Why pass non-digits (or empty string) to "T%07d"?
 192         } elsif ($filter eq 'libsuite8') {
 193                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 194                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 195                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 196                         }else{
 197                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 198                         }
 199                 }
 200     } elsif ($filter eq 'EAN13') {
 201         my $ean = CheckDigits('ean');
 202         if ( $ean->is_valid($barcode) ) {
 203             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 204             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 205         } else {
 206             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 207         }
 208         }
 209     return $barcode;    # return barcode, modified or not
 210 }
 211
 212 =head2 _decode
 213
 214   $str = &_decode($chunk);
 215
 216 Decodes a segment of a string emitted by a CueCat barcode scanner and
 217 returns it.
 218
 219 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 220 or Javascript based decoding on the client side.
 221
 222 =cut
 223
 224 sub _decode {
 225     my ($encoded) = @_;
 226     my $seq =
 227       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 228     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 229     my $l = ( $#s + 1 ) % 4;
 230     if ($l) {
 231         if ( $l == 1 ) {
 232             # warn "Error: Cuecat decode parsing failed!";
 233             return;
 234         }
 235         $l = 4 - $l;
 236         $#s += $l;
 237     }
 238     my $r = '';
 239     while ( $#s >= 0 ) {
 240         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 241         $r .=
 242             chr( ( $n >> 16 ) ^ 67 )
 243          .chr( ( $n >> 8 & 255 ) ^ 67 )
 244          .chr( ( $n & 255 ) ^ 67 );
 245         @s = @s[ 4 .. $#s ];
 246     }
 247     $r = substr( $r, 0, length($r) - $l );
 248     return $r;
 249 }
 250
 251 =head2 transferbook
 252
 253   ($dotransfer, $messages, $iteminformation) = &transferbook({
 254                                                    from_branch => $frombranch
 255                                                    to_branch => $tobranch,
 256                                                    barcode => $barcode,
 257                                                    ignore_reserves => $ignore_reserves,
 258                                                    trigger => $trigger
 259                                                 });
 260
 261 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 262
 263 C<$fbr> is the code for the branch initiating the transfer.
 264 C<$tbr> is the code for the branch to which the item should be transferred.
 265
 266 C<$barcode> is the barcode of the item to be transferred.
 267
 268 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 269 Otherwise, if an item is reserved, the transfer fails.
 270
 271 C<$trigger> is the enum value for what triggered the transfer.
 272
 273 Returns three values:
 274
 275 =over
 276
 277 =item $dotransfer
 278
 279 is true if the transfer was successful.
 280
 281 =item $messages
 282
 283 is a reference-to-hash which may have any of the following keys:
 284
 285 =over
 286
 287 =item C<BadBarcode>
 288
 289 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 290
 291 =item C<DestinationEqualsHolding>
 292
 293 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 294
 295 =item C<WasReturned>
 296
 297 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 298
 299 =item C<ResFound>
 300
 301 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 302
 303 =item C<WasTransferred>
 304
 305 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 306
 307 =item C<RecallPlacedAtHoldingBranch>
 308
 309 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 310
 311 =item C<RecallFound>
 312
 313 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 314
 315 =back
 316
 317 =back
 318
 319 =cut
 320
 321 sub transferbook {
 322     my $params = shift;
 323     my $tbr      = $params->{to_branch};
 324     my $fbr      = $params->{from_branch};
 325     my $ignoreRs = $params->{ignore_reserves};
 326     my $barcode  = $params->{barcode};
 327     my $trigger  = $params->{trigger};
 328     my $messages;
 329     my $dotransfer      = 1;
 330     my $item = Koha::Items->find( { barcode => $barcode } );
 331
 332     Koha::Exceptions::MissingParameter->throw(
 333         "Missing mandatory parameter: from_branch")
 334       unless $fbr;
 335
 336     Koha::Exceptions::MissingParameter->throw(
 337         "Missing mandatory parameter: to_branch")
 338       unless $tbr;
 339
 340     # bad barcode..
 341     unless ( $item ) {
 342         $messages->{'BadBarcode'} = $barcode;
 343         $dotransfer = 0;
 344         return ( $dotransfer, $messages );
 345     }
 346
 347     my $itemnumber = $item->itemnumber;
 348     # get branches of book...
 349     my $hbr = $item->homebranch;
 350
 351     # if using Branch Transfer Limits
 352     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 353         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 354         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 355             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 356                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 357                 $dotransfer = 0;
 358             }
 359         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 360             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 361             $dotransfer = 0;
 362         }
 363     }
 364
 365     # can't transfer book if is already there....
 366     if ( $fbr eq $tbr ) {
 367         $messages->{'DestinationEqualsHolding'} = 1;
 368         $dotransfer = 0;
 369     }
 370
 371     # check if it is still issued to someone, return it...
 372     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 373     if ( $issue ) {
 374         AddReturn( $barcode, $fbr );
 375         $messages->{'WasReturned'} = $issue->borrowernumber;
 376     }
 377
 378     # find reserves.....
 379     # That'll save a database query.
 380     my ( $resfound, $resrec, undef ) =
 381       CheckReserves( $itemnumber );
 382     if ( $resfound ) {
 383         $resrec->{'ResFound'} = $resfound;
 384         $messages->{'ResFound'} = $resrec;
 385         $dotransfer = 0 unless $ignoreRs;
 386     }
 387
 388     # find recall
 389     if ( C4::Context->preference('UseRecalls') ) {
 390         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 391         if ( defined $recall ) {
 392             # do a transfer if the recall branch is different to the item holding branch
 393             if ( $recall->pickup_library_id eq $fbr ) {
 394                 $dotransfer = 0;
 395                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 396             } else {
 397                 $dotransfer = 1;
 398                 $messages->{'RecallFound'} = $recall;
 399             }
 400         }
 401     }
 402
 403     #actually do the transfer....
 404     if ($dotransfer) {
 405         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 406
 407         # don't need to update MARC anymore, we do it in batch now
 408         $messages->{'WasTransfered'} = $tbr;
 409
 410     }
 411     ModDateLastSeen( $itemnumber );
 412     return ( $dotransfer, $messages );
 413 }
 414
 415
 416 sub TooMany {
 417     my $borrower        = shift;
 418     my $item_object = shift;
 419     my $params = shift;
 420     my $onsite_checkout = $params->{onsite_checkout} || 0;
 421     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 422     my $cat_borrower    = $borrower->{'categorycode'};
 423     my $dbh             = C4::Context->dbh;
 424     # Get which branchcode we need
 425     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 426     my $type = $item_object->effective_itemtype;
 427
 428     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 429     $type_object = Koha::ItemTypes->find( $type );
 430     $parent_type = $type_object->parent_type if $type_object;
 431     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 432     # Find any children if we are a parent_type;
 433
 434     # given branch, patron category, and item type, determine
 435     # applicable issuing rule
 436
 437     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 438         {
 439             categorycode => $cat_borrower,
 440             itemtype     => $parent_type,
 441             branchcode   => $branch,
 442             rule_name    => 'maxissueqty',
 443         }
 444     ) if $parent_type;
 445     # If the parent rule is for default type we discount it
 446     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 447
 448     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 449         {
 450             categorycode => $cat_borrower,
 451             itemtype     => $type,
 452             branchcode   => $branch,
 453             rule_name    => 'maxissueqty',
 454         }
 455     );
 456
 457     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 458         {
 459             categorycode => $cat_borrower,
 460             itemtype     => $type,
 461             branchcode   => $branch,
 462             rule_name    => 'maxonsiteissueqty',
 463         }
 464     );
 465
 466
 467     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 468     # if a rule is found and has a loan limit set, count
 469     # how many loans the patron already has that meet that
 470     # rule
 471     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 472
 473         my $checkouts;
 474         if ( $maxissueqty_rule->branchcode ) {
 475             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 476                 $checkouts = $patron->checkouts->search(
 477                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 478             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 479                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 480             } else {
 481                 $checkouts = $patron->checkouts->search(
 482                     { 'item.homebranch' => $maxissueqty_rule->branchcode } );
 483             }
 484         } else {
 485             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 486         }
 487         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 488
 489         my $sum_checkouts;
 490         my $rule_itemtype = $maxissueqty_rule->itemtype;
 491
 492         my @types;
 493         unless ( $rule_itemtype ) {
 494             # matching rule has the default item type, so count only
 495             # those existing loans that don't fall under a more
 496             # specific rule
 497             @types = Koha::CirculationRules->search(
 498                 {
 499                     branchcode => $maxissueqty_rule->branchcode,
 500                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 501                     itemtype  => { '!=' => undef },
 502                     rule_name => 'maxissueqty'
 503                 }
 504             )->get_column('itemtype');
 505         } else {
 506             if ( $parent_maxissueqty_rule ) {
 507                 # if we have a parent item type then we count loans of the
 508                 # specific item type or its siblings or parent
 509                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 510                 @types = $children->get_column('itemtype');
 511                 push @types, $parent_type;
 512             } elsif ( $child_types ) {
 513                 # If we are a parent type, we need to count all child types and our own type
 514                 @types = $child_types->get_column('itemtype');
 515                 push @types, $type; # And don't forget to count our own types
 516             } else {
 517                 # Otherwise only count the specific itemtype
 518                 push @types, $type;
 519             }
 520         }
 521
 522         while ( my $c = $checkouts->next ) {
 523             my $itemtype = $c->item->effective_itemtype;
 524
 525             unless ( $rule_itemtype ) {
 526                 next if grep {$_ eq $itemtype} @types;
 527             } else {
 528                 next unless grep {$_ eq $itemtype} @types;
 529             }
 530
 531             $sum_checkouts->{total}++;
 532             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 533             $sum_checkouts->{itemtype}->{$itemtype}++;
 534         }
 535
 536         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 537         my $checkout_count = $sum_checkouts->{total} || 0;
 538         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 539
 540         my $checkout_rules = {
 541             checkout_count               => $checkout_count,
 542             onsite_checkout_count        => $onsite_checkout_count,
 543             onsite_checkout              => $onsite_checkout,
 544             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 545             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 546             switch_onsite_checkout       => $switch_onsite_checkout,
 547         };
 548         # If parent rules exists
 549         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 550             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 551             my $qty_over = _check_max_qty($checkout_rules);
 552             return $qty_over if defined $qty_over;
 553
 554             # If the parent rule is less than or equal to the child, we only need check the parent
 555             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 556                 $checkout_rules->{checkout_count} = $checkout_count_type;
 557                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 558                 my $qty_over = _check_max_qty($checkout_rules);
 559                 return $qty_over if defined $qty_over;
 560             }
 561         } else {
 562             my $qty_over = _check_max_qty($checkout_rules);
 563             return $qty_over if defined $qty_over;
 564         }
 565     }
 566
 567     # Now count total loans against the limit for the branch
 568     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 569     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 570         my $checkouts;
 571         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 572             $checkouts = $patron->checkouts->search(
 573                 { 'me.branchcode' => $branch} );
 574         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 575             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 576         } else {
 577             $checkouts = $patron->checkouts->search(
 578                 { 'item.homebranch' => $branch},
 579                 { prefetch          => 'item' } );
 580         }
 581
 582         my $checkout_count = $checkouts->count;
 583         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 584         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 585         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 586
 587         my $qty_over = _check_max_qty(
 588             {
 589                 checkout_count               => $checkout_count,
 590                 onsite_checkout_count        => $onsite_checkout_count,
 591                 onsite_checkout              => $onsite_checkout,
 592                 max_checkouts_allowed        => $max_checkouts_allowed,
 593                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 594                 switch_onsite_checkout       => $switch_onsite_checkout
 595             }
 596         );
 597         return $qty_over if defined $qty_over;
 598     }
 599
 600     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 601         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 602     }
 603
 604     # OK, the patron can issue !!!
 605     return;
 606 }
 607
 608 sub _check_max_qty {
 609     my $params                       = shift;
 610     my $checkout_count               = $params->{checkout_count};
 611     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 612     my $onsite_checkout              = $params->{onsite_checkout};
 613     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 614     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 615     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 616
 617     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 618         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 619         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 620             return {
 621                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 622                 count       => $onsite_checkout_count,
 623                 max_allowed => $max_onsite_checkouts_allowed,
 624             };
 625         }
 626     }
 627     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 628         if ( $max_checkouts_allowed eq '' ) { return; }
 629         my $delta = $switch_onsite_checkout ? 1 : 0;
 630         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 631             return {
 632                 reason      => 'TOO_MANY_CHECKOUTS',
 633                 count       => $checkout_count,
 634                 max_allowed => $max_checkouts_allowed,
 635             };
 636         }
 637     }
 638     elsif ( not $onsite_checkout ) {
 639         if ( $max_checkouts_allowed eq '' ) { return; }
 640         if (
 641             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 642         {
 643             return {
 644                 reason      => 'TOO_MANY_CHECKOUTS',
 645                 count       => $checkout_count - $onsite_checkout_count,
 646                 max_allowed => $max_checkouts_allowed,
 647             };
 648         }
 649     }
 650
 651     return;
 652 }
 653
 654 =head2 CanBookBeIssued
 655
 656   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 657                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 658
 659 Check if a book can be issued.
 660
 661 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 662
 663 IMPORTANT: The assumption by users of this routine is that causes blocking
 664 the issue are keyed by uppercase labels and other returned
 665 data is keyed in lower case!
 666
 667 =over 4
 668
 669 =item C<$patron> is a Koha::Patron
 670
 671 =item C<$barcode> is the bar code of the book being issued.
 672
 673 =item C<$duedates> is a DateTime object.
 674
 675 =item C<$inprocess> boolean switch
 676
 677 =item C<$ignore_reserves> boolean switch
 678
 679 =item C<$params> Hashref of additional parameters
 680
 681 Available keys:
 682     override_high_holds - Ignore high holds
 683     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 684
 685 =back
 686
 687 Returns :
 688
 689 =over 4
 690
 691 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 692 Possible values are :
 693
 694 =back
 695
 696 =head3 INVALID_DATE
 697
 698 sticky due date is invalid
 699
 700 =head3 GNA
 701
 702 borrower gone with no address
 703
 704 =head3 CARD_LOST
 705
 706 borrower declared it's card lost
 707
 708 =head3 DEBARRED
 709
 710 borrower debarred
 711
 712 =head3 UNKNOWN_BARCODE
 713
 714 barcode unknown
 715
 716 =head3 NOT_FOR_LOAN
 717
 718 item is not for loan
 719
 720 =head3 WTHDRAWN
 721
 722 item withdrawn.
 723
 724 =head3 RESTRICTED
 725
 726 item is restricted (set by ??)
 727
 728 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 729 could be prevented, but ones that can be overriden by the operator.
 730
 731 Possible values are :
 732
 733 =head3 DEBT
 734
 735 borrower has debts.
 736
 737 =head3 RENEW_ISSUE
 738
 739 renewing, not issuing
 740
 741 =head3 ISSUED_TO_ANOTHER
 742
 743 issued to someone else.
 744
 745 =head3 RESERVED
 746
 747 reserved for someone else.
 748
 749 =head3 TRANSFERRED
 750
 751 reserved and being transferred for someone else.
 752
 753 =head3 INVALID_DATE
 754
 755 sticky due date is invalid or due date in the past
 756
 757 =head3 TOO_MANY
 758
 759 if the borrower borrows to much things
 760
 761 =head3 RECALLED
 762
 763 recalled by someone else
 764
 765 =cut
 766
 767 sub CanBookBeIssued {
 768     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 769     my %needsconfirmation;    # filled with problems that needs confirmations
 770     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 771     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 772     my %messages;             # filled with information messages that should be displayed.
 773
 774     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 775     my $override_high_holds = $params->{override_high_holds} || 0;
 776
 777     my $item_object = Koha::Items->find({barcode => $barcode });
 778
 779     # MANDATORY CHECKS - unless item exists, nothing else matters
 780     unless ( $item_object ) {
 781         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 782     }
 783     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 784
 785     my $item_unblessed = $item_object->unblessed; # Transition...
 786     my $issue = $item_object->checkout;
 787     my $biblio = $item_object->biblio;
 788
 789     my $biblioitem = $biblio->biblioitem;
 790     my $effective_itemtype = $item_object->effective_itemtype;
 791     my $dbh             = C4::Context->dbh;
 792     my $patron_unblessed = $patron->unblessed;
 793
 794     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 795
 796     my $now = dt_from_string();
 797     $duedate ||= CalcDateDue( $now, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 798     if (DateTime->compare($duedate,$now) == -1 ) { # duedate cannot be before now
 799          $needsconfirmation{INVALID_DATE} = $duedate;
 800     }
 801
 802     my $fees = Koha::Charges::Fees->new(
 803         {
 804             patron    => $patron,
 805             library   => $circ_library,
 806             item      => $item_object,
 807             to_date   => $duedate,
 808         }
 809     );
 810
 811     #
 812     # BORROWER STATUS
 813     #
 814     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 815         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 816         C4::Stats::UpdateStats(
 817             {
 818                 branch         => C4::Context->userenv->{'branch'},
 819                 type           => 'localuse',
 820                 itemnumber     => $item_object->itemnumber,
 821                 itemtype       => $effective_itemtype,
 822                 borrowernumber => $patron->borrowernumber,
 823                 ccode          => $item_object->ccode,
 824                 categorycode   => $patron->categorycode,
 825             }
 826         );
 827         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 828         return( { STATS => 1 }, {});
 829     }
 830
 831     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 832         $issuingimpossible{GNA} = 1;
 833     }
 834
 835     if ( $patron->lost && $patron->lost == 1 ) {
 836         $issuingimpossible{CARD_LOST} = 1;
 837     }
 838     if ( $patron->is_debarred ) {
 839         $issuingimpossible{DEBARRED} = 1;
 840     }
 841
 842     if ( $patron->is_expired ) {
 843         $issuingimpossible{EXPIRED} = 1;
 844     }
 845
 846     #
 847     # BORROWER STATUS
 848     #
 849
 850     # DEBTS
 851     my $account = $patron->account;
 852     my $balance = $account->balance;
 853     my $non_issues_charges = $account->non_issues_charges;
 854     my $other_charges = $balance - $non_issues_charges;
 855
 856     my $amountlimit = C4::Context->preference("noissuescharge");
 857     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 858     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 859
 860     # Check the debt of this patrons guarantees
 861     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 862     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 863     if ( defined $no_issues_charge_guarantees ) {
 864         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 865         my $guarantees_non_issues_charges = 0;
 866         foreach my $g ( @guarantees ) {
 867             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 868         }
 869
 870         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 871             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 872         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 873             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 874         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 875             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 876         }
 877     }
 878
 879     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 880     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 881     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 882     if ( defined $no_issues_charge_guarantors ) {
 883         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 884
 885         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 886             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 887         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 888             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 889         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 890             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 891         }
 892     }
 893
 894     if ( C4::Context->preference("IssuingInProcess") ) {
 895         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 896             $issuingimpossible{DEBT} = $non_issues_charges;
 897         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 898             $needsconfirmation{DEBT} = $non_issues_charges;
 899         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 900             $needsconfirmation{DEBT} = $non_issues_charges;
 901         }
 902     }
 903     else {
 904         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 905             $needsconfirmation{DEBT} = $non_issues_charges;
 906         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 907             $issuingimpossible{DEBT} = $non_issues_charges;
 908         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 909             $needsconfirmation{DEBT} = $non_issues_charges;
 910         }
 911     }
 912
 913     if ($balance > 0 && $other_charges > 0) {
 914         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 915     }
 916
 917     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 918     $patron_unblessed = $patron->unblessed;
 919
 920     if ( my $debarred_date = $patron->is_debarred ) {
 921          # patron has accrued fine days or has a restriction. $count is a date
 922         if ($debarred_date eq '9999-12-31') {
 923             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 924         }
 925         else {
 926             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 927         }
 928     } elsif ( my $num_overdues = $patron->has_overdues ) {
 929         ## patron has outstanding overdue loans
 930         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 931             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 932         }
 933         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 934             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 935         }
 936     }
 937
 938     # Additional Materials Check
 939     if ( C4::Context->preference("CircConfirmItemParts")
 940         && $item_object->materials )
 941     {
 942         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 943     }
 944
 945     #
 946     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 947     #
 948     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 949
 950         # Already issued to current borrower.
 951         # If it is an on-site checkout if it can be switched to a normal checkout
 952         # or ask whether the loan should be renewed
 953
 954         if ( $issue->onsite_checkout
 955                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 956             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 957         } else {
 958             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 959                 $patron->borrowernumber,
 960                 $item_object->itemnumber,
 961             );
 962             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 963                 if ( $renewerror eq 'onsite_checkout' ) {
 964                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 965                 }
 966                 else {
 967                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 968                 }
 969             }
 970             else {
 971                 $needsconfirmation{RENEW_ISSUE} = 1;
 972             }
 973         }
 974     }
 975     elsif ( $issue ) {
 976
 977         # issued to someone else
 978
 979         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 980
 981         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 982
 983         unless ( $can_be_returned ) {
 984             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 985             $issuingimpossible{branch_to_return} = $message;
 986         } else {
 987             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 988                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 989             } else {
 990             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 991             $needsconfirmation{issued_firstname} = $patron->firstname;
 992             $needsconfirmation{issued_surname} = $patron->surname;
 993             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 994             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 995             }
 996         }
 997     }
 998
 999     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1000     #
1001     my $switch_onsite_checkout = (
1002           C4::Context->preference('SwitchOnSiteCheckouts')
1003       and $issue
1004       and $issue->onsite_checkout
1005       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1006     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1007     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1008     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1009         if ( $toomany->{max_allowed} == 0 ) {
1010             $needsconfirmation{PATRON_CANT} = 1;
1011         }
1012         if ( C4::Context->preference("AllowTooManyOverride") ) {
1013             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1014             $needsconfirmation{current_loan_count} = $toomany->{count};
1015             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1016         } else {
1017             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1018             $issuingimpossible{current_loan_count} = $toomany->{count};
1019             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1020         }
1021     }
1022
1023     #
1024     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1025     #
1026     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1027     my $wants_check = $patron->wants_check_for_previous_checkout;
1028     $needsconfirmation{PREVISSUE} = 1
1029         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1030
1031     #
1032     # ITEM CHECKING
1033     #
1034     if ( $item_object->notforloan )
1035     {
1036         if(!C4::Context->preference("AllowNotForLoanOverride")){
1037             $issuingimpossible{NOT_FOR_LOAN} = 1;
1038             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1039         }else{
1040             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1041             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1042         }
1043     }
1044     else {
1045         # we have to check itemtypes.notforloan also
1046         if (C4::Context->preference('item-level_itypes')){
1047             # this should probably be a subroutine
1048             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1049             $sth->execute($effective_itemtype);
1050             my $notforloan=$sth->fetchrow_hashref();
1051             if ($notforloan->{'notforloan'}) {
1052                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1053                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1054                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1055                 } else {
1056                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1057                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1058                 }
1059             }
1060         }
1061         else {
1062             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1063             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1064                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1065                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1066                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1067                 } else {
1068                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1069                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1070                 }
1071             }
1072         }
1073     }
1074     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1075     {
1076         $issuingimpossible{WTHDRAWN} = 1;
1077     }
1078     if (   $item_object->restricted
1079         && $item_object->restricted == 1 )
1080     {
1081         $issuingimpossible{RESTRICTED} = 1;
1082     }
1083     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1084         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1085         my $code = $av->count ? $av->next->lib : '';
1086         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1087         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1088     }
1089     if ( C4::Context->preference("IndependentBranches") ) {
1090         my $userenv = C4::Context->userenv;
1091         unless ( C4::Context->IsSuperLibrarian() ) {
1092             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1093             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1094                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1095                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1096             }
1097             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1098               if ( $patron->branchcode ne $userenv->{branch} );
1099         }
1100     }
1101
1102     #
1103     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1104     #
1105     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1106     if ($rentalConfirmation) {
1107         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1108
1109         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1110         if ($itemtype_object) {
1111             my $accumulate_charge = $fees->accumulate_rentalcharge();
1112             if ( $accumulate_charge > 0 ) {
1113                 $rentalCharge += $accumulate_charge;
1114             }
1115         }
1116
1117         if ( $rentalCharge > 0 ) {
1118             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1119         }
1120     }
1121
1122     my $recall;
1123     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1124     # Only bother doing this if UseRecalls is enabled and the item is recallable
1125     # Don't look at recalls that are in transit
1126     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1127         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1128
1129         foreach my $r ( @recalls ) {
1130             if ( $r->item_id and
1131                 $r->item_id == $item_object->itemnumber and
1132                 $r->patron_id == $patron->borrowernumber and
1133                 ( $r->waiting or $r->requested ) ) {
1134                 $messages{RECALLED} = $r->id;
1135                 $recall = $r;
1136                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1137                 last;
1138             }
1139             elsif ( $r->item_id and
1140                 $r->item_id == $item_object->itemnumber and
1141                 $r->in_transit ) {
1142                 # recalled item is in transit
1143                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1144             }
1145             elsif ( $r->item_level and
1146                 $r->item_id == $item_object->itemnumber and
1147                 $r->patron_id != $patron->borrowernumber and
1148                 !$r->in_transit ) {
1149                 # this specific item has been recalled by a different patron
1150                 $needsconfirmation{RECALLED} = $r;
1151                 $recall = $r;
1152                 last;
1153             }
1154             elsif ( !$r->item_level and
1155                 $r->patron_id != $patron->borrowernumber and
1156                 !$r->in_transit ) {
1157                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1158                 $needsconfirmation{RECALLED} = $r;
1159                 $recall = $r;
1160                 last;
1161             }
1162         }
1163     }
1164
1165     unless ( $ignore_reserves and defined $recall ) {
1166         # See if the item is on reserve.
1167         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1168         if ($restype) {
1169             my $resbor = $res->{'borrowernumber'};
1170             if ( $resbor ne $patron->borrowernumber ) {
1171                 my $patron = Koha::Patrons->find( $resbor );
1172                 if ( $restype eq "Waiting" )
1173                 {
1174                     # The item is on reserve and waiting, but has been
1175                     # reserved by some other patron.
1176                     $needsconfirmation{RESERVE_WAITING} = 1;
1177                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1178                     $needsconfirmation{'ressurname'} = $patron->surname;
1179                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1180                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1181                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1182                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1183                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1184                 }
1185                 elsif ( $restype eq "Reserved" ) {
1186                     # The item is on reserve for someone else.
1187                     $needsconfirmation{RESERVED} = 1;
1188                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1189                     $needsconfirmation{'ressurname'} = $patron->surname;
1190                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1191                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1192                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1193                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1194                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1195                 }
1196                 elsif ( $restype eq "Transferred" ) {
1197                     # The item is determined hold being transferred for someone else.
1198                     $needsconfirmation{TRANSFERRED} = 1;
1199                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1200                     $needsconfirmation{'ressurname'} = $patron->surname;
1201                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1202                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1203                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1204                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1205                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1206                 }
1207                 elsif ( $restype eq "Processing" ) {
1208                     # The item is determined hold being processed for someone else.
1209                     $needsconfirmation{PROCESSING} = 1;
1210                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1211                     $needsconfirmation{'ressurname'} = $patron->surname;
1212                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1213                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1214                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1215                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1216                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1217                 }
1218             }
1219         }
1220     }
1221
1222     ## CHECK AGE RESTRICTION
1223     my $agerestriction  = $biblioitem->agerestriction;
1224     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1225     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1226         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1227             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1228         }
1229         else {
1230             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1231         }
1232     }
1233
1234     ## check for high holds decreasing loan period
1235     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1236         my $check = checkHighHolds( $item_object, $patron );
1237
1238         if ( $check->{exceeded} ) {
1239             my $highholds = {
1240                 num_holds  => $check->{outstanding},
1241                 duration   => $check->{duration},
1242                 returndate => $check->{due_date},
1243             };
1244             if ($override_high_holds) {
1245                 $alerts{HIGHHOLDS} = $highholds;
1246             }
1247             else {
1248                 $needsconfirmation{HIGHHOLDS} = $highholds;
1249             }
1250         }
1251     }
1252
1253     if (
1254         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1255         # don't do the multiple loans per bib check if we've
1256         # already determined that we've got a loan on the same item
1257         !$issuingimpossible{NO_MORE_RENEWALS} &&
1258         !$needsconfirmation{RENEW_ISSUE}
1259     ) {
1260         # Check if borrower has already issued an item from the same biblio
1261         # Only if it's not a subscription
1262         my $biblionumber = $item_object->biblionumber;
1263         require C4::Serials;
1264         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1265         unless ($is_a_subscription) {
1266             # FIXME Should be $patron->checkouts($args);
1267             my $checkouts = Koha::Checkouts->search(
1268                 {
1269                     borrowernumber => $patron->borrowernumber,
1270                     biblionumber   => $biblionumber,
1271                 },
1272                 {
1273                     join => 'item',
1274                 }
1275             );
1276             # if we get here, we don't already have a loan on this item,
1277             # so if there are any loans on this bib, ask for confirmation
1278             if ( $checkouts->count ) {
1279                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1280             }
1281         }
1282     }
1283
1284     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1285 }
1286
1287 =head2 CanBookBeReturned
1288
1289   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1290
1291 Check whether the item can be returned to the provided branch
1292
1293 =over 4
1294
1295 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1296
1297 =item C<$branch> is the branchcode where the return is taking place
1298
1299 =back
1300
1301 Returns:
1302
1303 =over 4
1304
1305 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1306
1307 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1308
1309 =back
1310
1311 =cut
1312
1313 sub CanBookBeReturned {
1314   my ($item, $branch) = @_;
1315   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1316
1317   # assume return is allowed to start
1318   my $allowed = 1;
1319   my $message;
1320
1321   # identify all cases where return is forbidden
1322   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1323      $allowed = 0;
1324      $message = $item->{'homebranch'};
1325   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1326      $allowed = 0;
1327      $message = $item->{'holdingbranch'};
1328   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1329      $allowed = 0;
1330      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1331   }
1332
1333   return ($allowed, $message);
1334 }
1335
1336 =head2 CheckHighHolds
1337
1338     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1339     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1340     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1341
1342 =cut
1343
1344 sub checkHighHolds {
1345     my ( $item, $patron ) = @_;
1346     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
1347
1348     my $return_data = {
1349         exceeded    => 0,
1350         outstanding => 0,
1351         duration    => 0,
1352         due_date    => undef,
1353     };
1354
1355     my $holds = Koha::Holds->search( { biblionumber => $item->biblionumber } );
1356
1357     if ( $holds->count() ) {
1358         $return_data->{outstanding} = $holds->count();
1359
1360         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1361         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1362         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1363
1364         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1365
1366         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1367
1368             # static means just more than a given number of holds on the record
1369
1370             # If the number of holds is less than the threshold, we can stop here
1371             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1372                 return $return_data;
1373             }
1374         }
1375         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1376
1377             # dynamic means X more than the number of holdable items on the record
1378
1379             # let's get the items
1380             my @items = $holds->next()->biblio()->items()->as_list;
1381
1382             # Remove any items with status defined to be ignored even if the would not make item unholdable
1383             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1384                 @items = grep { !$_->$status } @items;
1385             }
1386
1387             # Remove any items that are not holdable for this patron
1388             @items = grep { CanItemBeReserved( $patron , $_, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1389
1390             my $items_count = scalar @items;
1391
1392             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1393
1394             # If the number of holds is less than the count of items we have
1395             # plus the number of holds allowed above that count, we can stop here
1396             if ( $holds->count() <= $threshold ) {
1397                 return $return_data;
1398             }
1399         }
1400
1401         my $issuedate = dt_from_string();
1402
1403         my $itype = $item->effective_itemtype;
1404         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1405             {
1406                 categorycode => $patron->categorycode,
1407                 itemtype     => $itype,
1408                 branchcode   => $branchcode,
1409             }
1410         );
1411         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1412
1413         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron->unblessed );
1414
1415         my $rule = Koha::CirculationRules->get_effective_rule_value(
1416             {
1417                 categorycode => $patron->categorycode,
1418                 itemtype     => $item->effective_itemtype,
1419                 branchcode   => $branchcode,
1420                 rule_name    => 'decreaseloanholds',
1421             }
1422         );
1423
1424         my $duration;
1425         if ( defined($rule) && $rule ne '' ){
1426             # overrides decreaseLoanHighHoldsDuration syspref
1427             $duration = $rule;
1428         } else {
1429             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1430         }
1431         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1432         $reduced_datedue->set_hour($orig_due->hour);
1433         $reduced_datedue->set_minute($orig_due->minute);
1434         $reduced_datedue->truncate( to => 'minute' );
1435
1436         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1437             $return_data->{exceeded} = 1;
1438             $return_data->{duration} = $duration;
1439             $return_data->{due_date} = $reduced_datedue;
1440         }
1441     }
1442
1443     return $return_data;
1444 }
1445
1446 =head2 AddIssue
1447
1448   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1449
1450 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1451
1452 =over 4
1453
1454 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1455
1456 =item C<$barcode> is the barcode of the item being issued.
1457
1458 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1459 Calculated if empty.
1460
1461 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1462
1463 =item C<$issuedate> is a DateTime object for the date to issue the item (optional).
1464 Defaults to today.
1465
1466 AddIssue does the following things :
1467
1468   - step 01: check that there is a borrowernumber & a barcode provided
1469   - check for RENEWAL (book issued & being issued to the same patron)
1470       - renewal YES = Calculate Charge & renew
1471       - renewal NO  =
1472           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1473           * RESERVE PLACED ?
1474               - fill reserve if reserve to this patron
1475               - cancel reserve or not, otherwise
1476           * RECALL PLACED ?
1477               - fill recall if recall to this patron
1478               - cancel recall or not
1479               - revert recall's waiting status or not
1480           * TRANSFERT PENDING ?
1481               - complete the transfert
1482           * ISSUE THE BOOK
1483
1484 =back
1485
1486 =cut
1487
1488 sub AddIssue {
1489     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1490
1491     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1492     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1493     my $auto_renew = $params && $params->{auto_renew};
1494     my $cancel_recall = $params && $params->{cancel_recall};
1495     my $recall_id = $params && $params->{recall_id};
1496     my $dbh          = C4::Context->dbh;
1497     my $barcodecheck = CheckValidBarcode($barcode);
1498
1499     my $issue;
1500
1501     if ( $datedue && ref $datedue ne 'DateTime' ) {
1502         $datedue = dt_from_string($datedue);
1503     }
1504
1505     # $issuedate defaults to today.
1506     if ( !defined $issuedate ) {
1507         $issuedate = dt_from_string();
1508     }
1509     else {
1510         if ( ref $issuedate ne 'DateTime' ) {
1511             $issuedate = dt_from_string($issuedate);
1512
1513         }
1514     }
1515
1516     # Stop here if the patron or barcode doesn't exist
1517     if ( $borrower && $barcode && $barcodecheck ) {
1518         # find which item we issue
1519         my $item_object = Koha::Items->find({ barcode => $barcode })
1520           or return;    # if we don't get an Item, abort.
1521         my $item_unblessed = $item_object->unblessed;
1522
1523         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1524
1525         # get actual issuing if there is one
1526         my $actualissue = $item_object->checkout;
1527
1528         # check if we just renew the issue.
1529         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1530                 and not $switch_onsite_checkout ) {
1531             $datedue = AddRenewal(
1532                 $borrower->{'borrowernumber'},
1533                 $item_object->itemnumber,
1534                 $branchcode,
1535                 $datedue,
1536                 $issuedate,    # here interpreted as the renewal date
1537             );
1538         }
1539         else {
1540             unless ($datedue) {
1541                 my $itype = $item_object->effective_itemtype;
1542                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1543
1544             }
1545
1546             # Check if we need to use an exact due date set by the ILL module
1547             if ( C4::Context->preference('ILLModule') ) {
1548                 # Check if there is an ILL connected with the biblio of the item we are issuing
1549                 my $ill_request = Koha::Illrequests->search({
1550                     biblio_id => $item_object->biblionumber,
1551                     borrowernumber => $borrower->{'borrowernumber'},
1552                     completed => undef,
1553                     due_date => { '!=', undef },
1554                 })->next;
1555
1556                 if ( $ill_request and length( $ill_request->due_date ) > 0 ) {
1557                     my $ill_dt = dt_from_string( $ill_request->due_date );
1558                     $ill_dt->set_hour(23);
1559                     $ill_dt->set_minute(59);
1560                     $datedue = $ill_dt;
1561                 }
1562             }
1563
1564             $datedue->truncate( to => 'minute' );
1565
1566             my $patron = Koha::Patrons->find( $borrower );
1567             my $library = Koha::Libraries->find( $branchcode );
1568             my $fees = Koha::Charges::Fees->new(
1569                 {
1570                     patron    => $patron,
1571                     library   => $library,
1572                     item      => $item_object,
1573                     to_date   => $datedue,
1574                 }
1575             );
1576
1577             # it's NOT a renewal
1578             if ( $actualissue and not $switch_onsite_checkout ) {
1579                 # This book is currently on loan, but not to the person
1580                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1581                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1582                 return unless $allowed;
1583                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1584                 # AddReturn certainly has side-effects, like onloan => undef
1585                 $item_object->discard_changes;
1586             }
1587
1588             if ( C4::Context->preference('UseRecalls') ) {
1589                 Koha::Recalls->move_recall(
1590                     {
1591                         action         => $cancel_recall,
1592                         recall_id      => $recall_id,
1593                         item           => $item_object,
1594                         borrowernumber => $borrower->{borrowernumber},
1595                     }
1596                 );
1597             }
1598
1599             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1600
1601             # Starting process for transfer job (checking transfert and validate it if we have one)
1602             if ( my $transfer = $item_object->get_transfer ) {
1603                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1604                 $transfer->set(
1605                     {
1606                         datearrived => dt_from_string,
1607                         tobranch    => C4::Context->userenv->{branch},
1608                         comments    => 'Forced branchtransfer'
1609                     }
1610                 )->store;
1611                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1612                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1613                     if ( $hold ) { # Is this really needed?
1614                         $hold->set( { found => undef } )->store;
1615                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1616                     }
1617                 }
1618             }
1619
1620             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1621             unless ($auto_renew) {
1622                 my $rule = Koha::CirculationRules->get_effective_rule_value(
1623                     {
1624                         categorycode => $borrower->{categorycode},
1625                         itemtype     => $item_object->effective_itemtype,
1626                         branchcode   => $branchcode,
1627                         rule_name    => 'auto_renew'
1628                     }
1629                 );
1630
1631                 $auto_renew = $rule if defined $rule && $rule ne '';
1632             }
1633
1634             my $issue_attributes = {
1635                 borrowernumber  => $borrower->{'borrowernumber'},
1636                 issuedate       => $issuedate,
1637                 date_due        => $datedue,
1638                 branchcode      => C4::Context->userenv->{'branch'},
1639                 onsite_checkout => $onsite_checkout,
1640                 auto_renew      => $auto_renew ? 1 : 0,
1641             };
1642
1643             # Get ID of logged in user.  if called from a batch job,
1644             # no user session exists and C4::Context->userenv() returns
1645             # the scalar '0'. Only do this if the syspref says so
1646             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1647                 my $userenv = C4::Context->userenv();
1648                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1649                 if ($usernumber) {
1650                     $issue_attributes->{issuer_id} = $usernumber;
1651                 }
1652             }
1653
1654             # In the case that the borrower has an on-site checkout
1655             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1656             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1657             if ($issue) {
1658                 $issue->set($issue_attributes)->store;
1659             }
1660             else {
1661                 $issue = Koha::Checkout->new(
1662                     {
1663                         itemnumber => $item_object->itemnumber,
1664                         %$issue_attributes,
1665                     }
1666                 )->store;
1667             }
1668             $issue->discard_changes;
1669             C4::Auth::track_login_daily( $borrower->{userid} );
1670             if ( $item_object->location && $item_object->location eq 'CART'
1671                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1672             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1673                 CartToShelf( $item_object->itemnumber );
1674             }
1675
1676             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1677                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1678             }
1679
1680             # Record if item was lost
1681             my $was_lost = $item_object->itemlost;
1682
1683             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1684             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1685             $item_object->itemlost(0);
1686             $item_object->onloan($datedue->ymd());
1687             $item_object->datelastborrowed( dt_from_string()->ymd() );
1688             $item_object->datelastseen( dt_from_string()->ymd() );
1689             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1690
1691             # If the item was lost, it has now been found, charge the overdue if necessary
1692             if ($was_lost) {
1693                 if ( $item_object->{_charge} ) {
1694                     $actualissue //= Koha::Old::Checkouts->search(
1695                         { itemnumber => $item_unblessed->{itemnumber} },
1696                         {
1697                             order_by => { '-desc' => 'returndate' },
1698                             rows     => 1
1699                         }
1700                     )->single;
1701                     unless ( exists( $borrower->{branchcode} ) ) {
1702                         my $patron = $actualissue->patron;
1703                         $borrower = $patron->unblessed;
1704                     }
1705                     _CalculateAndUpdateFine(
1706                         {
1707                             issue       => $actualissue,
1708                             item        => $item_unblessed,
1709                             borrower    => $borrower,
1710                             return_date => $issuedate
1711                         }
1712                     );
1713                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1714                         $item_object->itemnumber, undef, 'RENEWED' );
1715                 }
1716             }
1717
1718             # If it costs to borrow this book, charge it to the patron's account.
1719             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1720             if ( $charge && $charge > 0 ) {
1721                 AddIssuingCharge( $issue, $charge, 'RENT' );
1722             }
1723
1724             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1725             if ( $itemtype_object ) {
1726                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1727                 if ( $accumulate_charge > 0 ) {
1728                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1729                     $charge += $accumulate_charge;
1730                     $item_unblessed->{charge} = $charge;
1731                 }
1732             }
1733
1734             # Record the fact that this book was issued.
1735             C4::Stats::UpdateStats(
1736                 {
1737                     branch => C4::Context->userenv->{'branch'},
1738                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1739                     amount         => $charge,
1740                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1741                     itemnumber     => $item_object->itemnumber,
1742                     itemtype       => $item_object->effective_itemtype,
1743                     location       => $item_object->location,
1744                     borrowernumber => $borrower->{'borrowernumber'},
1745                     ccode          => $item_object->ccode,
1746                     categorycode   => $borrower->{'categorycode'}
1747                 }
1748             );
1749
1750             # Send a checkout slip.
1751             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1752             my %conditions        = (
1753                 branchcode   => $branchcode,
1754                 categorycode => $borrower->{categorycode},
1755                 item_type    => $item_object->effective_itemtype,
1756                 notification => 'CHECKOUT',
1757             );
1758             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1759                 SendCirculationAlert(
1760                     {
1761                         type     => 'CHECKOUT',
1762                         item     => $item_object->unblessed,
1763                         borrower => $borrower,
1764                         branch   => $branchcode,
1765                     }
1766                 );
1767             }
1768             logaction(
1769                 "CIRCULATION", "ISSUE",
1770                 $borrower->{'borrowernumber'},
1771                 $item_object->itemnumber,
1772             ) if C4::Context->preference("IssueLog");
1773
1774             Koha::Plugins->call('after_circ_action', {
1775                 action  => 'checkout',
1776                 payload => {
1777                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1778                     checkout => $issue->get_from_storage
1779                 }
1780             });
1781
1782             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1783                 {
1784                     biblio_ids => [ $item_object->biblionumber ]
1785                 }
1786             ) if C4::Context->preference('RealTimeHoldsQueue');
1787         }
1788     }
1789     return $issue;
1790 }
1791
1792 =head2 GetLoanLength
1793
1794   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1795
1796 Get loan length for an itemtype, a borrower type and a branch
1797
1798 =cut
1799
1800 sub GetLoanLength {
1801     my ( $categorycode, $itemtype, $branchcode ) = @_;
1802
1803     # Initialize default values
1804     my $rules = {
1805         issuelength   => 0,
1806         renewalperiod => 0,
1807         lengthunit    => 'days',
1808     };
1809
1810     my $found = Koha::CirculationRules->get_effective_rules( {
1811         branchcode => $branchcode,
1812         categorycode => $categorycode,
1813         itemtype => $itemtype,
1814         rules => [
1815             'issuelength',
1816             'renewalperiod',
1817             'lengthunit'
1818         ],
1819     } );
1820
1821     # Search for rules!
1822     foreach my $rule_name (keys %$found) {
1823         $rules->{$rule_name} = $found->{$rule_name};
1824     }
1825
1826     return $rules;
1827 }
1828
1829
1830 =head2 GetHardDueDate
1831
1832   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1833
1834 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1835
1836 =cut
1837
1838 sub GetHardDueDate {
1839     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1840
1841     my $rules = Koha::CirculationRules->get_effective_rules(
1842         {
1843             categorycode => $borrowertype,
1844             itemtype     => $itemtype,
1845             branchcode   => $branchcode,
1846             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1847         }
1848     );
1849
1850     if ( defined( $rules->{hardduedate} ) ) {
1851         if ( $rules->{hardduedate} ) {
1852             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1853         }
1854         else {
1855             return ( undef, undef );
1856         }
1857     }
1858 }
1859
1860 =head2 GetBranchBorrowerCircRule
1861
1862   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1863
1864 Retrieves circulation rule attributes that apply to the given
1865 branch and patron category, regardless of item type.
1866 The return value is a hashref containing the following key:
1867
1868 patron_maxissueqty - maximum number of loans that a
1869 patron of the given category can have at the given
1870 branch.  If the value is undef, no limit.
1871
1872 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1873 patron of the given category can have at the given
1874 branch.  If the value is undef, no limit.
1875
1876 This will check for different branch/category combinations in the following order:
1877 branch and category
1878 branch only
1879 category only
1880 default branch and category
1881
1882 If no rule has been found in the database, it will default to
1883 the buillt in rule:
1884
1885 patron_maxissueqty - undef
1886 patron_maxonsiteissueqty - undef
1887
1888 C<$branchcode> and C<$categorycode> should contain the
1889 literal branch code and patron category code, respectively - no
1890 wildcards.
1891
1892 =cut
1893
1894 sub GetBranchBorrowerCircRule {
1895     my ( $branchcode, $categorycode ) = @_;
1896
1897     # Initialize default values
1898     my $rules = {
1899         patron_maxissueqty       => undef,
1900         patron_maxonsiteissueqty => undef,
1901     };
1902
1903     # Search for rules!
1904     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1905         my $rule = Koha::CirculationRules->get_effective_rule(
1906             {
1907                 categorycode => $categorycode,
1908                 itemtype     => undef,
1909                 branchcode   => $branchcode,
1910                 rule_name    => $rule_name,
1911             }
1912         );
1913
1914         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1915     }
1916
1917     return $rules;
1918 }
1919
1920 =head2 GetBranchItemRule
1921
1922   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1923
1924 Retrieves circulation rule attributes that apply to the given
1925 branch and item type, regardless of patron category.
1926
1927 The return value is a hashref containing the following keys:
1928
1929 holdallowed => Hold policy for this branch and itemtype. Possible values:
1930   not_allowed:           No holds allowed.
1931   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1932   from_any_library:      Holds allowed from any patron.
1933   from_local_hold_group: Holds allowed from libraries in hold group
1934
1935 This searches branchitemrules in the following order:
1936
1937   * Same branchcode and itemtype
1938   * Same branchcode, itemtype '*'
1939   * branchcode '*', same itemtype
1940   * branchcode and itemtype '*'
1941
1942 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1943
1944 =cut
1945
1946 sub GetBranchItemRule {
1947     my ( $branchcode, $itemtype ) = @_;
1948
1949     # Search for rules!
1950     my $rules = Koha::CirculationRules->get_effective_rules({
1951         branchcode => $branchcode,
1952         itemtype => $itemtype,
1953         rules => ['holdallowed', 'hold_fulfillment_policy']
1954     });
1955
1956     # built-in default circulation rule
1957     $rules->{holdallowed} //= 'from_any_library';
1958     $rules->{hold_fulfillment_policy} //= 'any';
1959
1960     return $rules;
1961 }
1962
1963 =head2 AddReturn
1964
1965   ($doreturn, $messages, $iteminformation, $borrower) =
1966       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1967
1968 Returns a book.
1969
1970 =over 4
1971
1972 =item C<$barcode> is the bar code of the book being returned.
1973
1974 =item C<$branch> is the code of the branch where the book is being returned.
1975
1976 =item C<$exemptfine> indicates that overdue charges for the item will be
1977 removed. Optional.
1978
1979 =item C<$return_date> allows the default return date to be overridden
1980 by the given return date. Optional.
1981
1982 =back
1983
1984 C<&AddReturn> returns a list of four items:
1985
1986 C<$doreturn> is true iff the return succeeded.
1987
1988 C<$messages> is a reference-to-hash giving feedback on the operation.
1989 The keys of the hash are:
1990
1991 =over 4
1992
1993 =item C<BadBarcode>
1994
1995 No item with this barcode exists. The value is C<$barcode>.
1996
1997 =item C<NotIssued>
1998
1999 The book is not currently on loan. The value is C<$barcode>.
2000
2001 =item C<withdrawn>
2002
2003 This book has been withdrawn/cancelled. The value should be ignored.
2004
2005 =item C<Wrongbranch>
2006
2007 This book has was returned to the wrong branch.  The value is a hashref
2008 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2009 contain the branchcode of the incorrect and correct return library, respectively.
2010
2011 =item C<ResFound>
2012
2013 The item was reserved. The value is a reference-to-hash whose keys are
2014 fields from the reserves table of the Koha database, and
2015 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2016 either C<Waiting>, C<Reserved>, or 0.
2017
2018 =item C<WasReturned>
2019
2020 Value 1 if return is successful.
2021
2022 =item C<NeedsTransfer>
2023
2024 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2025
2026 =item C<RecallFound>
2027
2028 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2029 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2030 branchcode.
2031
2032 =item C<TransferredRecall>
2033
2034 This item has been transferred to this branch to fill a recall. The recall object is returned.
2035
2036 =back
2037
2038 C<$iteminformation> is a reference-to-hash, giving information about the
2039 returned item from the issues table.
2040
2041 C<$borrower> is a reference-to-hash, giving information about the
2042 patron who last borrowed the book.
2043
2044 =cut
2045
2046 sub AddReturn {
2047     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2048
2049     if ($branch and not Koha::Libraries->find($branch)) {
2050         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2051         undef $branch;
2052     }
2053     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2054     my $return_date_specified = !!$return_date;
2055     $return_date //= dt_from_string();
2056     my $messages;
2057     my $patron;
2058     my $doreturn       = 1;
2059     my $validTransfer = 1;
2060     my $stat_type = 'return';
2061
2062     # get information on item
2063     my $item = Koha::Items->find({ barcode => $barcode });
2064     unless ($item) {
2065         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2066     }
2067
2068     my $itemnumber = $item->itemnumber;
2069     my $itemtype = $item->effective_itemtype;
2070
2071     my $issue  = $item->checkout;
2072     if ( $issue ) {
2073         $patron = $issue->patron
2074             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2075                 . Dumper($issue->unblessed) . "\n";
2076     } else {
2077         $messages->{'NotIssued'} = $barcode;
2078         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2079
2080         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2081         $doreturn = 0;
2082         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2083         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2084         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2085            $messages->{'LocalUse'} = 1;
2086            $stat_type = 'localuse';
2087         }
2088     }
2089
2090         # full item data, but no borrowernumber or checkout info (no issue)
2091     my $hbr = Koha::CirculationRules->get_return_branch_policy($item);
2092         # get the proper branch to which to return the item
2093     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2094         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2095     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2096
2097     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2098     my $patron_unblessed = $patron ? $patron->unblessed : {};
2099
2100     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2101     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2102     if ($update_loc_rules) {
2103         if (defined $update_loc_rules->{_ALL_}) {
2104             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2105             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2106             if (
2107                 ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) ||
2108                 (!defined $item->location && $update_loc_rules->{_ALL_} ne "")
2109                ) {
2110                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2111                 $item->location($update_loc_rules->{_ALL_})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2112             }
2113         }
2114         else {
2115             foreach my $key ( keys %$update_loc_rules ) {
2116                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2117                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2118                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2119                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2120                     $item->location($update_loc_rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2121                     last;
2122                 }
2123             }
2124         }
2125     }
2126
2127     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2128     if ($yaml) {
2129         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2130         my $rules;
2131         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2132         if ($@) {
2133             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2134         }
2135         else {
2136             foreach my $key ( keys %$rules ) {
2137                 if ( $item->notforloan eq $key ) {
2138                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2139                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2140                     last;
2141                 }
2142             }
2143         }
2144     }
2145
2146     # check if the return is allowed at this branch
2147     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2148     unless ($returnallowed){
2149         $messages->{'Wrongbranch'} = {
2150             Wrongbranch => $branch,
2151             Rightbranch => $message
2152         };
2153         $doreturn = 0;
2154         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2155         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2156         return ( $doreturn, $messages, $issue, $patron_unblessed);
2157     }
2158
2159     if ( $item->withdrawn ) { # book has been cancelled
2160         $messages->{'withdrawn'} = 1;
2161         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2162     }
2163
2164     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2165         $doreturn = 0;
2166     }
2167
2168     # case of a return of document (deal with issues and holdingbranch)
2169     if ($doreturn) {
2170         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2171         $patron or warn "AddReturn without current borrower";
2172
2173         if ($patron) {
2174             eval {
2175                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2176             };
2177             unless ( $@ ) {
2178                 if (
2179                     (
2180                         C4::Context->preference('CalculateFinesOnReturn')
2181                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2182                     )
2183                     && !$item->itemlost
2184                   )
2185                 {
2186                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2187                 }
2188             } else {
2189                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2190
2191                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2192                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2193
2194                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2195             }
2196
2197             # FIXME is the "= 1" right?  This could be the borrower hash.
2198             $messages->{'WasReturned'} = 1;
2199
2200         } else {
2201             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2202         }
2203     }
2204
2205     # the holdingbranch is updated if the document is returned to another location.
2206     # this is always done regardless of whether the item was on loan or not
2207     if ($item->holdingbranch ne $branch) {
2208         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2209     }
2210
2211     my $item_was_lost = $item->itemlost;
2212     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2213     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2214
2215     # fix up the accounts.....
2216     if ($item_was_lost) {
2217         $messages->{'WasLost'} = 1;
2218         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2219             my @object_messages = @{ $updated_item->object_messages };
2220             for my $message (@object_messages) {
2221                 $messages->{'LostItemFeeRefunded'} = 1
2222                   if $message->message eq 'lost_refunded';
2223                 $messages->{'ProcessingFeeRefunded'} = 1
2224                   if $message->message eq 'processing_refunded';
2225                 $messages->{'LostItemFeeRestored'} = 1
2226                   if $message->message eq 'lost_restored';
2227
2228                 if ( $message->message eq 'lost_charge' ) {
2229                     $issue //= Koha::Old::Checkouts->search(
2230                         { itemnumber => $item->itemnumber },
2231                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2232                     )->single;
2233                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2234                         my $patron = $issue->patron;
2235                         $patron_unblessed = $patron->unblessed;
2236                     }
2237                     _CalculateAndUpdateFine(
2238                         {
2239                             issue       => $issue,
2240                             item        => $item->unblessed,
2241                             borrower    => $patron_unblessed,
2242                             return_date => $return_date
2243                         }
2244                     );
2245                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2246                         $item->itemnumber, undef, 'RETURNED' );
2247                     $messages->{'LostItemFeeCharged'} = 1;
2248                 }
2249             }
2250         }
2251     }
2252
2253     # check if we have a transfer for this document
2254     my $transfer = $item->get_transfer;
2255
2256     # if we have a transfer to complete, we update the line of transfers with the datearrived
2257     if ($transfer) {
2258         $validTransfer = 0;
2259         if ( $transfer->in_transit ) {
2260             if ( $transfer->tobranch eq $branch ) {
2261                 $transfer->receive;
2262                 $messages->{'TransferArrived'} = $transfer->frombranch;
2263                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2264                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2265             }
2266             else {
2267                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2268                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2269                 $messages->{'TransferTrigger'}   = $transfer->reason;
2270             }
2271         }
2272         else {
2273             if ( $transfer->tobranch eq $branch ) {
2274                 $transfer->receive;
2275                 $messages->{'TransferArrived'} = $transfer->frombranch;
2276                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2277                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2278             }
2279             else {
2280                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2281                 $messages->{'TransferTrigger'} = $transfer->reason;
2282             }
2283         }
2284     }
2285
2286     # fix up the overdues in accounts...
2287     if ($borrowernumber) {
2288         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2289         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2290
2291         if ( $issue and $issue->is_overdue($return_date) ) {
2292         # fix fine days
2293             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2294             if ($reminder){
2295                 $messages->{'PrevDebarred'} = $debardate;
2296             } else {
2297                 $messages->{'Debarred'} = $debardate if $debardate;
2298             }
2299         # there's no overdue on the item but borrower had been previously debarred
2300         } elsif ( $issue->date_due and $patron->debarred ) {
2301              if ( $patron->debarred eq "9999-12-31") {
2302                 $messages->{'ForeverDebarred'} = $patron->debarred;
2303              } else {
2304                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2305                   $borrower_debar_dt->truncate(to => 'day');
2306                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2307                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2308                       $messages->{'PrevDebarred'} = $patron->debarred;
2309                   }
2310              }
2311         }
2312     }
2313
2314     # find recalls...
2315     if ( C4::Context->preference('UseRecalls') ) {
2316         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2317         my $recall = undef;
2318         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2319         if ( defined $recall ) {
2320             $messages->{RecallFound} = $recall;
2321             if ( $recall->pickup_library_id ne $branch ) {
2322                 $messages->{RecallNeedsTransfer} = $branch;
2323             }
2324         }
2325     }
2326
2327     # find reserves.....
2328     # launch the Checkreserves routine to find any holds
2329     my ($resfound, $resrec);
2330     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2331     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2332     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2333     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2334         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2335         $resfound = 'Reserved';
2336         $resrec = $hold->unblessed;
2337     }
2338     if ($resfound) {
2339           $resrec->{'ResFound'} = $resfound;
2340         $messages->{'ResFound'} = $resrec;
2341     }
2342
2343     # Record the fact that this book was returned.
2344     my $categorycode = $patron_unblessed ? $patron_unblessed->{categorycode} : undef;
2345     C4::Stats::UpdateStats({
2346         branch         => $branch,
2347         type           => $stat_type,
2348         itemnumber     => $itemnumber,
2349         itemtype       => $itemtype,
2350         location       => $item->location,
2351         borrowernumber => $borrowernumber,
2352         ccode          => $item->ccode,
2353         categorycode   => $categorycode,
2354     });
2355
2356     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2357     if ( $patron ) {
2358         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2359         my %conditions = (
2360             branchcode   => $branch,
2361             categorycode => $patron->categorycode,
2362             item_type    => $itemtype,
2363             notification => 'CHECKIN',
2364         );
2365         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2366             SendCirculationAlert({
2367                 type     => 'CHECKIN',
2368                 item     => $item->unblessed,
2369                 borrower => $patron->unblessed,
2370                 branch   => $branch,
2371                 issue    => $issue
2372             });
2373         }
2374
2375         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2376             if C4::Context->preference("ReturnLog");
2377         }
2378
2379     # Check if this item belongs to a biblio record that is attached to an
2380     # ILL request, if it is we need to update the ILL request's status
2381     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2382         my $request = Koha::Illrequests->find(
2383             { biblio_id => $item->biblio->biblionumber }
2384         );
2385         $request->status('RET') if $request;
2386     }
2387
2388     if ( C4::Context->preference('UseRecalls') ) {
2389         # all recalls that have triggered a transfer will have an allocated itemnumber
2390         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2391         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2392             $messages->{TransferredRecall} = $transfer_recall;
2393         }
2394     }
2395
2396     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2397     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2398         && ( $doreturn or $messages->{'NotIssued'} )
2399         and !$resfound
2400         and ( $branch ne $returnbranch )
2401         and not $messages->{'WrongTransfer'}
2402         and not $messages->{'WasTransfered'}
2403         and not $messages->{TransferredRecall}
2404         and not $messages->{RecallNeedsTransfer} )
2405     {
2406         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2407         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2408             (C4::Context->preference("UseBranchTransferLimits") and
2409              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2410            )) {
2411             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2412             $messages->{'WasTransfered'} = $returnbranch;
2413             $messages->{'TransferTrigger'} = $transfer_trigger;
2414         } else {
2415             $messages->{'NeedsTransfer'} = $returnbranch;
2416             $messages->{'TransferTrigger'} = $transfer_trigger;
2417         }
2418     }
2419
2420     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2421         my $claims = Koha::Checkouts::ReturnClaims->search(
2422            {
2423                itemnumber => $item->id,
2424                resolution => undef,
2425            }
2426         );
2427
2428         if ( $claims->count ) {
2429             $messages->{ReturnClaims} = $claims;
2430         }
2431     }
2432
2433     # Check for bundle status
2434     if ( $item->in_bundle ) {
2435         my $host = $item->bundle_host;
2436         $messages->{InBundle} = $host;
2437     }
2438
2439     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2440     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2441
2442     if ( $doreturn and $issue ) {
2443         my $checkin = Koha::Old::Checkouts->find($issue->id);
2444
2445         Koha::Plugins->call('after_circ_action', {
2446             action  => 'checkin',
2447             payload => {
2448                 checkout=> $checkin
2449             }
2450         });
2451
2452         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2453             {
2454                 biblio_ids => [ $item->biblionumber ]
2455             }
2456         ) if C4::Context->preference('RealTimeHoldsQueue');
2457     }
2458
2459     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2460 }
2461
2462 =head2 MarkIssueReturned
2463
2464   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2465
2466 Unconditionally marks an issue as being returned by
2467 moving the C<issues> row to C<old_issues> and
2468 setting C<returndate> to the current date.
2469
2470 if C<$returndate> is specified (in iso format), it is used as the date
2471 of the return.
2472
2473 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2474 the old_issue is immediately anonymised
2475
2476 Ideally, this function would be internal to C<C4::Circulation>,
2477 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2478 and offline_circ/process_koc.pl.
2479
2480 The last optional parameter allos passing skip_record_index to the item store call.
2481
2482 =cut
2483
2484 sub MarkIssueReturned {
2485     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2486
2487     # Retrieve the issue
2488     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2489
2490     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2491
2492     my $issue_id = $issue->issue_id;
2493
2494     my $schema = Koha::Database->schema;
2495
2496     # FIXME Improve the return value and handle it from callers
2497     $schema->txn_do(sub {
2498
2499         my $patron = Koha::Patrons->find( $borrowernumber );
2500
2501         # Update the returndate value
2502         if ( $returndate ) {
2503             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2504         }
2505         else {
2506             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2507         }
2508
2509         # Create the old_issues entry
2510         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2511
2512         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2513         if ( $privacy && $privacy == 2) {
2514             $old_checkout->anonymize;
2515         }
2516
2517         # And finally delete the issue
2518         $issue->delete;
2519
2520         $issue->item->onloan(undef)->store(
2521             {   log_action        => 0,
2522                 skip_record_index => $params->{skip_record_index},
2523                 skip_holds_queue  => $params->{skip_holds_queue}
2524             }
2525         );
2526
2527         if ( C4::Context->preference('StoreLastBorrower') ) {
2528             my $item = Koha::Items->find( $itemnumber );
2529             $item->last_returned_by( $patron );
2530         }
2531
2532         # Remove any OVERDUES related debarment if the borrower has no overdues
2533         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2534           && $patron->debarred
2535           && !$patron->has_overdues
2536           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2537         ) {
2538             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2539         }
2540
2541     });
2542
2543     return $issue_id;
2544 }
2545
2546 =head2 _debar_user_on_return
2547
2548     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2549
2550 C<$borrower> borrower hashref
2551
2552 C<$item> item hashref
2553
2554 C<$datedue> date due DateTime object
2555
2556 C<$returndate> DateTime object representing the return time
2557
2558 Internal function, called only by AddReturn that calculates and updates
2559  the user fine days, and debars them if necessary.
2560
2561 Should only be called for overdue returns
2562
2563 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2564 to ease testing.
2565
2566 =cut
2567
2568 sub _calculate_new_debar_dt {
2569     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2570
2571     my $branchcode = _GetCircControlBranch( $item, $borrower );
2572     my $circcontrol = C4::Context->preference('CircControl');
2573     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2574         {   categorycode => $borrower->{categorycode},
2575             itemtype     => $item->{itype},
2576             branchcode   => $branchcode,
2577             rules => [
2578                 'finedays',
2579                 'lengthunit',
2580                 'firstremind',
2581                 'maxsuspensiondays',
2582                 'suspension_chargeperiod',
2583             ]
2584         }
2585     );
2586     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2587     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2588     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2589
2590     return unless $finedays;
2591
2592     # finedays is in days, so hourly loans must multiply by 24
2593     # thus 1 hour late equals 1 day suspension * finedays rate
2594     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2595
2596     # grace period is measured in the same units as the loan
2597     my $grace =
2598       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2599
2600     my $deltadays = DateTime::Duration->new(
2601         days => $chargeable_units
2602     );
2603
2604     if ( $deltadays->subtract($grace)->is_positive() ) {
2605         my $suspension_days = $deltadays * $finedays;
2606
2607         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2608             # No need to / 1 and do not consider / 0
2609             $suspension_days = DateTime::Duration->new(
2610                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2611             );
2612         }
2613
2614         # If the max suspension days is < than the suspension days
2615         # the suspension days is limited to this maximum period.
2616         my $max_sd = $issuing_rule->{maxsuspensiondays};
2617         if ( defined $max_sd && $max_sd ne '' ) {
2618             $max_sd = DateTime::Duration->new( days => $max_sd );
2619             $suspension_days = $max_sd
2620               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2621         }
2622
2623         my ( $has_been_extended );
2624         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2625             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2626             if ( $debarment ) {
2627                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2628                 $has_been_extended = 1;
2629             }
2630         }
2631
2632         my $new_debar_dt;
2633         # Use the calendar or not to calculate the debarment date
2634         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2635             my $calendar = Koha::Calendar->new(
2636                 branchcode => $branchcode,
2637                 days_mode  => 'Calendar'
2638             );
2639             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2640         }
2641         else {
2642             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2643         }
2644         return $new_debar_dt;
2645     }
2646     return;
2647 }
2648
2649 sub _debar_user_on_return {
2650     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2651
2652     $return_date //= dt_from_string();
2653
2654     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2655
2656     return unless $new_debar_dt;
2657
2658     Koha::Patron::Debarments::AddUniqueDebarment({
2659         borrowernumber => $borrower->{borrowernumber},
2660         expiration     => $new_debar_dt->ymd(),
2661         type           => 'SUSPENSION',
2662     });
2663     # if borrower was already debarred but does not get an extra debarment
2664     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2665     my ($new_debarment_str, $is_a_reminder);
2666     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2667         $is_a_reminder = 1;
2668         $new_debarment_str = $borrower->{debarred};
2669     } else {
2670         $new_debarment_str = $new_debar_dt->ymd();
2671     }
2672     # FIXME Should return a DateTime object
2673     return $new_debarment_str, $is_a_reminder;
2674 }
2675
2676 =head2 _FixOverduesOnReturn
2677
2678    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2679
2680 C<$borrowernumber> borrowernumber
2681
2682 C<$itemnumber> itemnumber
2683
2684 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2685
2686 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2687
2688 Internal function
2689
2690 =cut
2691
2692 sub _FixOverduesOnReturn {
2693     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2694     unless( $borrowernumber ) {
2695         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2696         return;
2697     }
2698     unless( $item ) {
2699         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2700         return;
2701     }
2702     unless( $status ) {
2703         warn "_FixOverduesOnReturn() not supplied valid status";
2704         return;
2705     }
2706
2707     my $schema = Koha::Database->schema;
2708
2709     my $result = $schema->txn_do(
2710         sub {
2711             # check for overdue fine
2712             my $accountlines = Koha::Account::Lines->search(
2713                 {
2714                     borrowernumber  => $borrowernumber,
2715                     itemnumber      => $item,
2716                     debit_type_code => 'OVERDUE',
2717                     status          => 'UNRETURNED'
2718                 }
2719             );
2720             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2721
2722             my $accountline = $accountlines->next;
2723             my $payments = $accountline->credits;
2724
2725             my $amountoutstanding = $accountline->amountoutstanding;
2726             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2727                 $accountline->delete;
2728                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2729             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2730                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2731                 my $credit = $account->add_credit(
2732                     {
2733                         amount     => $amountoutstanding,
2734                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2735                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2736                         interface  => C4::Context->interface,
2737                         type       => 'FORGIVEN',
2738                         item_id    => $item
2739                     }
2740                 );
2741
2742                 $credit->apply({ debits => [ $accountline ] });
2743
2744                 if (C4::Context->preference("FinesLog")) {
2745                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2746                 }
2747             }
2748
2749             $accountline->status($status);
2750             return $accountline->store();
2751         }
2752     );
2753
2754     return $result;
2755 }
2756
2757 =head2 _GetCircControlBranch
2758
2759    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2760
2761 Internal function :
2762
2763 Return the library code to be used to determine which circulation
2764 policy applies to a transaction.  Looks up the CircControl and
2765 HomeOrHoldingBranch system preferences.
2766
2767 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2768
2769 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2770
2771 =cut
2772
2773 sub _GetCircControlBranch {
2774     my ($item, $borrower) = @_;
2775     my $circcontrol = C4::Context->preference('CircControl');
2776     my $branch;
2777
2778     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2779         $branch= C4::Context->userenv->{'branch'};
2780     } elsif ($circcontrol eq 'PatronLibrary') {
2781         $branch=$borrower->{branchcode};
2782     } else {
2783         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2784         $branch = $item->{$branchfield};
2785         # default to item home branch if holdingbranch is used
2786         # and is not defined
2787         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2788             $branch = $item->{homebranch};
2789         }
2790     }
2791     return $branch;
2792 }
2793
2794 =head2 GetUpcomingDueIssues
2795
2796   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2797
2798 =cut
2799
2800 sub GetUpcomingDueIssues {
2801     my $params = shift;
2802
2803     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2804     my $dbh = C4::Context->dbh;
2805     my $statement;
2806     $statement = q{
2807         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2808         FROM issues
2809         LEFT JOIN items USING (itemnumber)
2810         LEFT JOIN branches ON branches.branchcode =
2811     };
2812     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2813     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2814     my @bind_parameters = ( $params->{'days_in_advance'} );
2815
2816     my $sth = $dbh->prepare( $statement );
2817     $sth->execute( @bind_parameters );
2818     my $upcoming_dues = $sth->fetchall_arrayref({});
2819
2820     return $upcoming_dues;
2821 }
2822
2823 =head2 CanBookBeRenewed
2824
2825   ($ok,$error,$info) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2826
2827 Find out whether a borrowed item may be renewed.
2828
2829 C<$borrowernumber> is the borrower number of the patron who currently
2830 has the item on loan.
2831
2832 C<$itemnumber> is the number of the item to renew.
2833
2834 C<$override_limit>, if supplied with a true value, causes
2835 the limit on the number of times that the loan can be renewed
2836 (as controlled by the item type) to be ignored. Overriding also allows
2837 to renew sooner than "No renewal before" and to manually renew loans
2838 that are automatically renewed.
2839
2840 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2841 item must currently be on loan to the specified borrower; renewals
2842 must be allowed for the item's type; and the borrower must not have
2843 already renewed the loan.
2844     $error will contain the reason the renewal can not proceed
2845     $info will contain a hash of additional info
2846       currently 'soonest_renew_date' if error is 'too soon'
2847
2848 =cut
2849
2850 sub CanBookBeRenewed {
2851     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2852
2853     my $auto_renew = "no";
2854     my $soonest;
2855
2856     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2857     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2858     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2859     return ( 0, 'item_denied_renewal') if $item->is_denied_renewal;
2860
2861     my $patron = $issue->patron or return;
2862
2863     # override_limit will override anything else except on_reserve
2864     unless ( $override_limit ){
2865         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2866         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2867             {
2868                 categorycode => $patron->categorycode,
2869                 itemtype     => $item->effective_itemtype,
2870                 branchcode   => $branchcode,
2871                 rules => [
2872                     'renewalsallowed',
2873                     'lengthunit',
2874                     'unseen_renewals_allowed'
2875                 ]
2876             }
2877         );
2878
2879         return ( 0, "too_many" )
2880           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals_count;
2881
2882         return ( 0, "too_unseen" )
2883           if C4::Context->preference('UnseenRenewals') &&
2884             looks_like_number($issuing_rule->{unseen_renewals_allowed}) &&
2885             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2886
2887         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2888         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2889         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2890         my $restricted  = $patron->is_debarred;
2891         my $hasoverdues = $patron->has_overdues;
2892
2893         if ( $restricted and $restrictionblockrenewing ) {
2894             return ( 0, 'restriction');
2895         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2896             return ( 0, 'overdue');
2897         }
2898
2899         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
2900             patron     => $patron,
2901             item       => $item,
2902             branchcode => $branchcode,
2903             issue      => $issue
2904         });
2905         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
2906         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
2907         # extra notices being sent. Cron also implies no override
2908         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
2909         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
2910         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
2911     }
2912
2913     if ( C4::Context->preference('UseRecalls') ) {
2914         my $recall = undef;
2915         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2916         if ( defined $recall ) {
2917             if ( $recall->item_level ) {
2918                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
2919                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
2920             } else {
2921                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
2922                 return ( 0, 'recalled' ) unless ( $recall->waiting );
2923             }
2924         }
2925     }
2926
2927     my $fillable_holds = Koha::Holds->search(
2928         {
2929             biblionumber => $item->biblionumber,
2930             non_priority => 0,
2931             found        => undef,
2932             reservedate  => { '<=' => \'NOW()' },
2933             suspend      => 0,
2934         },
2935         { prefetch => 'patron' }
2936     );
2937     if ( $fillable_holds->count ) {
2938         if ( C4::Context->preference('AllowRenewalIfOtherItemsAvailable') ) {
2939             my @possible_holds = $fillable_holds->as_list;
2940
2941             # Get all other items that could possibly fill reserves
2942             # FIXME We could join reserves (or more tables) here to eliminate some checks later
2943             my @other_items = Koha::Items->search({
2944                 biblionumber => $item->biblionumber,
2945                 onloan       => undef,
2946                 notforloan   => 0,
2947                 -not         => { itemnumber => $itemnumber } })->as_list;
2948
2949             return ( 0, "on_reserve" ) if @possible_holds && (scalar @other_items < scalar @possible_holds);
2950
2951             my %matched_items;
2952             foreach my $possible_hold (@possible_holds) {
2953                 my $fillable = 0;
2954                 my $patron_with_reserve = Koha::Patrons->find($possible_hold->borrowernumber);
2955                 my $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron_with_reserve });
2956
2957                 # FIXME: We are not checking whether the item we are renewing can fill the hold
2958
2959                 foreach my $other_item (@other_items) {
2960                   next if defined $matched_items{$other_item->itemnumber};
2961                   next if IsItemOnHoldAndFound( $other_item->itemnumber );
2962                   next unless IsAvailableForItemLevelRequest($other_item, $patron_with_reserve, undef, $items_any_available);
2963                   next unless CanItemBeReserved($patron_with_reserve,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
2964                   # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
2965                   # CanItemBeReserved checks 'rules' and 'policies' which means
2966                   # items will fill holds at checkin that are rejected here
2967                   $fillable = 1;
2968                   $matched_items{$other_item->itemnumber} = 1;
2969                   last;
2970                 }
2971                 return ( 0, "on_reserve" ) unless $fillable;
2972             }
2973
2974         } else {
2975             my ($status, $matched_reserve, $possible_reserves) = CheckReserves($itemnumber);
2976             return ( 0, "on_reserve" ) if $status;
2977         }
2978     }
2979
2980     return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2981     $soonest = GetSoonestRenewDate($issue);
2982     if ( $soonest > dt_from_string() ){
2983         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
2984     }
2985
2986     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
2987
2988     return ( 1, undef );
2989 }
2990
2991 =head2 AddRenewal
2992
2993   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
2994
2995 Renews a loan.
2996
2997 C<$borrowernumber> is the borrower number of the patron who currently
2998 has the item.
2999
3000 C<$itemnumber> is the number of the item to renew.
3001
3002 C<$branch> is the library where the renewal took place (if any).
3003            The library that controls the circ policies for the renewal is retrieved from the issues record.
3004
3005 C<$datedue> can be a DateTime object used to set the due date.
3006
3007 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3008 this parameter is not supplied, lastreneweddate is set to the current date.
3009
3010 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3011 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3012 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3013 syspref)
3014
3015 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3016 from the book's item type.
3017
3018 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3019 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3020 fallback to a true value
3021
3022 =cut
3023
3024 sub AddRenewal {
3025     my $borrowernumber  = shift;
3026     my $itemnumber      = shift or return;
3027     my $branch          = shift;
3028     my $datedue         = shift;
3029     my $lastreneweddate = shift || dt_from_string();
3030     my $skipfinecalc    = shift;
3031     my $seen            = shift;
3032
3033     # Fallback on a 'seen' renewal
3034     $seen = defined $seen && $seen == 0 ? 0 : 1;
3035
3036     my $item_object   = Koha::Items->find($itemnumber) or return;
3037     my $biblio = $item_object->biblio;
3038     my $issue  = $item_object->checkout;
3039     my $item_unblessed = $item_object->unblessed;
3040
3041     my $dbh = C4::Context->dbh;
3042
3043     return unless $issue;
3044
3045     $borrowernumber ||= $issue->borrowernumber;
3046
3047     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3048         $datedue = dt_from_string($datedue, 'sql');
3049     }
3050
3051     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3052     my $patron_unblessed = $patron->unblessed;
3053
3054     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3055
3056     my $schema = Koha::Database->schema;
3057     $schema->txn_do(sub{
3058
3059         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3060             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3061         }
3062         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3063
3064         # If the due date wasn't specified, calculate it by adding the
3065         # book's loan length to today's date or the current due date
3066         # based on the value of the RenewalPeriodBase syspref.
3067         my $itemtype = $item_object->effective_itemtype;
3068         unless ($datedue) {
3069
3070             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3071                                             dt_from_string( $issue->date_due, 'sql' ) :
3072                                             dt_from_string();
3073             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3074         }
3075
3076         my $fees = Koha::Charges::Fees->new(
3077             {
3078                 patron    => $patron,
3079                 library   => $circ_library,
3080                 item      => $item_object,
3081                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3082                 to_date   => dt_from_string($datedue),
3083             }
3084         );
3085
3086         # Increment the unseen renewals, if appropriate
3087         # We only do so if the syspref is enabled and
3088         # a maximum value has been set in the circ rules
3089         my $unseen_renewals = $issue->unseen_renewals;
3090         if (C4::Context->preference('UnseenRenewals')) {
3091             my $rule = Koha::CirculationRules->get_effective_rule(
3092                 {   categorycode => $patron->categorycode,
3093                     itemtype     => $item_object->effective_itemtype,
3094                     branchcode   => $circ_library->branchcode,
3095                     rule_name    => 'unseen_renewals_allowed'
3096                 }
3097             );
3098             if (!$seen && $rule && looks_like_number($rule->rule_value)) {
3099                 $unseen_renewals++;
3100             } else {
3101                 # If the renewal is seen, unseen should revert to 0
3102                 $unseen_renewals = 0;
3103             }
3104         }
3105
3106         # Update the issues record to have the new due date, and a new count
3107         # of how many times it has been renewed.
3108         my $renews = ( $issue->renewals_count || 0 ) + 1;
3109         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals_count = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3110
3111         eval{
3112             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3113         };
3114         if( $sth->err ){
3115             Koha::Exceptions::Checkout::FailedRenewal->throw(
3116                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3117             );
3118         }
3119
3120         # Update the renewal count on the item, and tell zebra to reindex
3121         $renews = ( $item_object->renewals || 0 ) + 1;
3122         $item_object->renewals($renews);
3123         $item_object->onloan($datedue);
3124         $item_object->store({ log_action => 0 });
3125
3126         # Charge a new rental fee, if applicable
3127         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3128         if ( $charge > 0 ) {
3129             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3130         }
3131
3132         # Charge a new accumulate rental fee, if applicable
3133         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3134         if ( $itemtype_object ) {
3135             my $accumulate_charge = $fees->accumulate_rentalcharge();
3136             if ( $accumulate_charge > 0 ) {
3137                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3138             }
3139             $charge += $accumulate_charge;
3140         }
3141
3142         # Send a renewal slip according to checkout alert preferencei
3143         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3144             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3145             my %conditions        = (
3146                 branchcode   => $branch,
3147                 categorycode => $patron->categorycode,
3148                 item_type    => $itemtype,
3149                 notification => 'CHECKOUT',
3150             );
3151             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3152                 SendCirculationAlert(
3153                     {
3154                         type     => 'RENEWAL',
3155                         item     => $item_unblessed,
3156                         borrower => $patron->unblessed,
3157                         branch   => $branch,
3158                     }
3159                 );
3160             }
3161         }
3162
3163         # Remove any OVERDUES related debarment if the borrower has no overdues
3164         if ( $patron
3165           && $patron->is_debarred
3166           && ! $patron->has_overdues
3167           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3168         ) {
3169             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3170         }
3171
3172         # Add renewal record
3173         my $renewal = Koha::Checkouts::Renewal->new(
3174             {
3175                 checkout_id => $issue->issue_id,
3176                 renewer_id  => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3177                 seen        => $seen,
3178                 interface   => C4::Context->interface
3179             }
3180         )->store();
3181
3182         # Add the renewal to stats
3183         C4::Stats::UpdateStats(
3184             {
3185                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3186                 type           => 'renew',
3187                 amount         => $charge,
3188                 itemnumber     => $itemnumber,
3189                 itemtype       => $itemtype,
3190                 location       => $item_object->location,
3191                 borrowernumber => $borrowernumber,
3192                 ccode          => $item_object->ccode,
3193                 categorycode   => $patron->categorycode,
3194             }
3195         );
3196
3197         #Log the renewal
3198         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3199
3200         Koha::Plugins->call('after_circ_action', {
3201             action  => 'renewal',
3202             payload => {
3203                 checkout  => $issue->get_from_storage
3204             }
3205         });
3206     });
3207
3208     return $datedue;
3209 }
3210
3211 sub GetRenewCount {
3212     # check renewal status
3213     my ( $bornum, $itemno ) = @_;
3214     my $dbh           = C4::Context->dbh;
3215     my $renewcount    = 0;
3216     my $unseencount    = 0;
3217     my $renewsallowed = 0;
3218     my $unseenallowed = 0;
3219     my $renewsleft    = 0;
3220     my $unseenleft    = 0;
3221
3222     my $patron = Koha::Patrons->find( $bornum );
3223     my $item   = Koha::Items->find($itemno);
3224
3225     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3226
3227     # Look in the issues table for this item, lent to this borrower,
3228     # and not yet returned.
3229
3230     # FIXME - I think this function could be redone to use only one SQL call.
3231     my $sth = $dbh->prepare(
3232         "select * from issues
3233                                 where (borrowernumber = ?)
3234                                 and (itemnumber = ?)"
3235     );
3236     $sth->execute( $bornum, $itemno );
3237     my $data = $sth->fetchrow_hashref;
3238     $renewcount = $data->{'renewals_count'} if $data->{'renewals_count'};
3239     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3240     # $item and $borrower should be calculated
3241     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3242
3243     my $rules = Koha::CirculationRules->get_effective_rules(
3244         {
3245             categorycode => $patron->categorycode,
3246             itemtype     => $item->effective_itemtype,
3247             branchcode   => $branchcode,
3248             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3249         }
3250     );
3251     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3252     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3253         $rules->{unseen_renewals_allowed} :
3254         0;
3255     $renewsleft    = $renewsallowed - $renewcount;
3256     $unseenleft    = $unseenallowed - $unseencount;
3257     if($renewsleft < 0){ $renewsleft = 0; }
3258     if($unseenleft < 0){ $unseenleft = 0; }
3259     return (
3260         $renewcount,
3261         $renewsallowed,
3262         $renewsleft,
3263         $unseencount,
3264         $unseenallowed,
3265         $unseenleft
3266     );
3267 }
3268
3269 =head2 GetSoonestRenewDate
3270
3271   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($checkout);
3272
3273 Find out the soonest possible renew date of a borrowed item.
3274
3275 C<$checkout> is the checkout object to renew.
3276
3277 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3278 renew date, based on the value "No renewal before" of the applicable
3279 issuing rule. Returns the current date if the item can already be
3280 renewed, and returns undefined if the patron, item, or checkout
3281 cannot be found.
3282
3283 =cut
3284
3285 sub GetSoonestRenewDate {
3286     my ( $checkout ) = @_;
3287
3288     my $item   = $checkout->item or return;
3289     my $patron = $checkout->patron or return;
3290
3291     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3292     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3293         {   categorycode => $patron->categorycode,
3294             itemtype     => $item->effective_itemtype,
3295             branchcode   => $branchcode,
3296             rules => [
3297                 'norenewalbefore',
3298                 'lengthunit',
3299             ]
3300         }
3301     );
3302
3303     my $now = dt_from_string;
3304
3305     if ( defined $issuing_rule->{norenewalbefore}
3306         and $issuing_rule->{norenewalbefore} ne "" )
3307     {
3308         my $soonestrenewal =
3309           dt_from_string( $checkout->date_due )->subtract(
3310             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3311
3312         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3313             and $issuing_rule->{lengthunit} eq 'days' )
3314         {
3315             $soonestrenewal->truncate( to => 'day' );
3316         }
3317         return $soonestrenewal if $now < $soonestrenewal;
3318     } elsif ( $checkout->auto_renew && $patron->autorenew_checkouts ) {
3319         # Checkouts with auto-renewing fall back to due date
3320         my $soonestrenewal = dt_from_string( $checkout->date_due );
3321         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3322             and $issuing_rule->{lengthunit} eq 'days' )
3323         {
3324             $soonestrenewal->truncate( to => 'day' );
3325         }
3326         return $soonestrenewal;
3327     }
3328     return $now;
3329 }
3330
3331 =head2 GetLatestAutoRenewDate
3332
3333   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3334
3335 Find out the latest possible auto renew date of a borrowed item.
3336
3337 C<$borrowernumber> is the borrower number of the patron who currently
3338 has the item on loan.
3339
3340 C<$itemnumber> is the number of the item to renew.
3341
3342 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3343 auto renew date, based on the value "No auto renewal after" and the "No auto
3344 renewal after (hard limit) of the applicable issuing rule.
3345 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3346 or item cannot be found.
3347
3348 =cut
3349
3350 sub GetLatestAutoRenewDate {
3351     my ( $borrowernumber, $itemnumber ) = @_;
3352
3353     my $dbh = C4::Context->dbh;
3354
3355     my $item      = Koha::Items->find($itemnumber)  or return;
3356     my $itemissue = $item->checkout                 or return;
3357
3358     $borrowernumber ||= $itemissue->borrowernumber;
3359     my $patron = Koha::Patrons->find( $borrowernumber )
3360       or return;
3361
3362     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3363     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3364         {
3365             categorycode => $patron->categorycode,
3366             itemtype     => $item->effective_itemtype,
3367             branchcode   => $branchcode,
3368             rules => [
3369                 'no_auto_renewal_after',
3370                 'no_auto_renewal_after_hard_limit',
3371                 'lengthunit',
3372             ]
3373         }
3374     );
3375
3376     return unless $circulation_rules;
3377     return
3378       if ( not $circulation_rules->{no_auto_renewal_after}
3379             or $circulation_rules->{no_auto_renewal_after} eq '' )
3380       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3381              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3382
3383     my $maximum_renewal_date;
3384     if ( $circulation_rules->{no_auto_renewal_after} ) {
3385         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3386         $maximum_renewal_date->add(
3387             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3388         );
3389     }
3390
3391     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3392         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3393         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3394     }
3395     return $maximum_renewal_date;
3396 }
3397
3398
3399 =head2 GetIssuingCharges
3400
3401   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3402
3403 Calculate how much it would cost for a given patron to borrow a given
3404 item, including any applicable discounts.
3405
3406 C<$itemnumber> is the item number of item the patron wishes to borrow.
3407
3408 C<$borrowernumber> is the patron's borrower number.
3409
3410 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3411 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3412 if it's a video).
3413
3414 =cut
3415
3416 sub GetIssuingCharges {
3417
3418     # calculate charges due
3419     my ( $itemnumber, $borrowernumber ) = @_;
3420     my $charge = 0;
3421     my $dbh    = C4::Context->dbh;
3422     my $item_type;
3423
3424     # Get the book's item type and rental charge (via its biblioitem).
3425     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3426         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3427     $charge_query .= (C4::Context->preference('item-level_itypes'))
3428         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3429         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3430
3431     $charge_query .= ' WHERE items.itemnumber =?';
3432
3433     my $sth = $dbh->prepare($charge_query);
3434     $sth->execute($itemnumber);
3435     if ( my $item_data = $sth->fetchrow_hashref ) {
3436         $item_type = $item_data->{itemtype};
3437         $charge    = $item_data->{rentalcharge};
3438         if ($charge) {
3439             # FIXME This should follow CircControl
3440             my $branch = C4::Context::mybranch();
3441             my $patron = Koha::Patrons->find( $borrowernumber );
3442             my $discount = Koha::CirculationRules->get_effective_rule({
3443                 categorycode => $patron->categorycode,
3444                 branchcode   => $branch,
3445                 itemtype     => $item_type,
3446                 rule_name    => 'rentaldiscount'
3447             });
3448             if ($discount) {
3449                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3450             }
3451             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3452         }
3453     }
3454
3455     return ( $charge, $item_type );
3456 }
3457
3458 =head2 AddIssuingCharge
3459
3460   &AddIssuingCharge( $checkout, $charge, $type )
3461
3462 =cut
3463
3464 sub AddIssuingCharge {
3465     my ( $checkout, $charge, $type ) = @_;
3466
3467     # FIXME What if checkout does not exist?
3468
3469     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3470     my $accountline = $account->add_debit(
3471         {
3472             amount      => $charge,
3473             note        => undef,
3474             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3475             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3476             interface   => C4::Context->interface,
3477             type        => $type,
3478             item_id     => $checkout->itemnumber,
3479             issue_id    => $checkout->issue_id,
3480         }
3481     );
3482 }
3483
3484 =head2 GetTransfersFromTo
3485
3486   @results = GetTransfersFromTo($frombranch,$tobranch);
3487
3488 Returns the list of pending transfers between $from and $to branch
3489
3490 =cut
3491
3492 sub GetTransfersFromTo {
3493     my ( $frombranch, $tobranch ) = @_;
3494     return unless ( $frombranch && $tobranch );
3495     my $dbh   = C4::Context->dbh;
3496     my $query = "
3497         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3498         FROM   branchtransfers
3499         WHERE  frombranch=?
3500           AND  tobranch=?
3501           AND datecancelled IS NULL
3502           AND datesent IS NOT NULL
3503           AND datearrived IS NULL
3504     ";
3505     my $sth = $dbh->prepare($query);
3506     $sth->execute( $frombranch, $tobranch );
3507     my @gettransfers;
3508
3509     while ( my $data = $sth->fetchrow_hashref ) {
3510         push @gettransfers, $data;
3511     }
3512     return (@gettransfers);
3513 }
3514
3515 =head2 SendCirculationAlert
3516
3517 Send out a C<check-in> or C<checkout> alert using the messaging system.
3518
3519 B<Parameters>:
3520
3521 =over 4
3522
3523 =item type
3524
3525 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3526
3527 =item item
3528
3529 Hashref of information about the item being checked in or out.
3530
3531 =item borrower
3532
3533 Hashref of information about the borrower of the item.
3534
3535 =item branch
3536
3537 The branchcode from where the checkout or check-in took place.
3538
3539 =back
3540
3541 B<Example>:
3542
3543     SendCirculationAlert({
3544         type     => 'CHECKOUT',
3545         item     => $item,
3546         borrower => $borrower,
3547         branch   => $branch,
3548     });
3549
3550 =cut
3551
3552 sub SendCirculationAlert {
3553     my ($opts) = @_;
3554     my ($type, $item, $borrower, $branch, $issue) =
3555         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3556     my %message_name = (
3557         CHECKIN  => 'Item_Check_in',
3558         CHECKOUT => 'Item_Checkout',
3559         RENEWAL  => 'Item_Checkout',
3560     );
3561     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3562         borrowernumber => $borrower->{borrowernumber},
3563         message_name   => $message_name{$type},
3564     });
3565
3566
3567     my $tables = {
3568         items => $item->{itemnumber},
3569         biblio      => $item->{biblionumber},
3570         biblioitems => $item->{biblionumber},
3571         borrowers   => $borrower,
3572         branches    => $branch,
3573     };
3574
3575     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3576     # See C4::Letters:: _parseletter_sth
3577     if( $type eq 'CHECKIN' ){
3578         $tables->{old_issues} = $issue->issue_id;
3579     } else {
3580         $tables->{issues} = $item->{itemnumber};
3581     }
3582
3583     my $schema = Koha::Database->new->schema;
3584     my @transports = keys %{ $borrower_preferences->{transports} };
3585
3586     # From the MySQL doc:
3587     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3588     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3589     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3590     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3591
3592     for my $mtt (@transports) {
3593         my $letter =  C4::Letters::GetPreparedLetter (
3594             module => 'circulation',
3595             letter_code => $type,
3596             branchcode => $branch,
3597             message_transport_type => $mtt,
3598             lang => $borrower->{lang},
3599             tables => $tables,
3600         ) or next;
3601
3602         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3603         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3604         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3605         unless ( $message ) {
3606             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3607             C4::Message->enqueue($letter, $borrower, $mtt);
3608         } else {
3609             $message->append($letter);
3610             $message->update;
3611         }
3612         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3613     }
3614
3615     return;
3616 }
3617
3618 =head2 updateWrongTransfer
3619
3620   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3621
3622 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3623
3624 =cut
3625
3626 sub updateWrongTransfer {
3627         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3628
3629     # first step: cancel the original transfer
3630     my $item = Koha::Items->find($itemNumber);
3631     my $transfer = $item->get_transfer;
3632     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3633
3634     # second step: create a new transfer to the right location
3635     my $new_transfer = $item->request_transfer(
3636         {
3637             to            => $transfer->to_library,
3638             reason        => $transfer->reason,
3639             comment       => $transfer->comments,
3640             ignore_limits => 1,
3641             enqueue       => 1
3642         }
3643     );
3644
3645     return $new_transfer;
3646 }
3647
3648 =head2 CalcDateDue
3649
3650 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3651
3652 this function calculates the due date given the start date and configured circulation rules,
3653 checking against the holidays calendar as per the daysmode circulation rule.
3654 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3655 C<$itemtype>  = itemtype code of item in question
3656 C<$branch>  = location whose calendar to use
3657 C<$borrower> = Borrower object
3658 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3659
3660 =cut
3661
3662 sub CalcDateDue {
3663     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3664
3665     $isrenewal ||= 0;
3666
3667     # loanlength now a href
3668     my $loanlength =
3669             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3670
3671     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3672             ? qq{renewalperiod}
3673             : qq{issuelength};
3674
3675     my $datedue;
3676     if ( $startdate ) {
3677         if (ref $startdate ne 'DateTime' ) {
3678             $datedue = dt_from_string($datedue);
3679         } else {
3680             $datedue = $startdate->clone;
3681         }
3682     } else {
3683         $datedue = dt_from_string()->truncate( to => 'minute' );
3684     }
3685
3686
3687     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3688         {
3689             categorycode => $borrower->{categorycode},
3690             itemtype     => $itemtype,
3691             branchcode   => $branch,
3692         }
3693     );
3694
3695     # calculate the datedue as normal
3696     if ( $daysmode eq 'Days' )
3697     {    # ignoring calendar
3698         if ( $loanlength->{lengthunit} eq 'hours' ) {
3699             $datedue->add( hours => $loanlength->{$length_key} );
3700         } else {    # days
3701             $datedue->add( days => $loanlength->{$length_key} );
3702             $datedue->set_hour(23);
3703             $datedue->set_minute(59);
3704         }
3705     } else {
3706         my $dur;
3707         if ($loanlength->{lengthunit} eq 'hours') {
3708             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3709         }
3710         else { # days
3711             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3712         }
3713         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3714         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3715         if ($loanlength->{lengthunit} eq 'days') {
3716             $datedue->set_hour(23);
3717             $datedue->set_minute(59);
3718         }
3719     }
3720
3721     # if Hard Due Dates are used, retrieve them and apply as necessary
3722     my ( $hardduedate, $hardduedatecompare ) =
3723       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3724     if ($hardduedate) {    # hardduedates are currently dates
3725         $hardduedate->truncate( to => 'minute' );
3726         $hardduedate->set_hour(23);
3727         $hardduedate->set_minute(59);
3728         my $cmp = DateTime->compare( $hardduedate, $datedue );
3729
3730 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3731 # if the calculated date is before the 'after' Hard Due Date (floor), override
3732 # if the hard due date is set to 'exactly', overrride
3733         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3734             $datedue = $hardduedate->clone;
3735         }
3736
3737         # in all other cases, keep the date due as it is
3738
3739     }
3740
3741     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3742     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3743         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3744         if( $expiry_dt ) { #skip empty expiry date..
3745             $expiry_dt->set( hour => 23, minute => 59);
3746             my $d1= $datedue->clone->set_time_zone('floating');
3747             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3748                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3749             }
3750         }
3751         if ( $daysmode ne 'Days' ) {
3752           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3753           if ( $calendar->is_holiday($datedue) ) {
3754               # Don't return on a closed day
3755               $datedue = $calendar->prev_open_days( $datedue, 1 );
3756           }
3757         }
3758     }
3759
3760     return $datedue;
3761 }
3762
3763
3764 sub CheckValidBarcode{
3765 my ($barcode) = @_;
3766 my $dbh = C4::Context->dbh;
3767 my $query=qq|SELECT count(*)
3768              FROM items
3769              WHERE barcode=?
3770             |;
3771 my $sth = $dbh->prepare($query);
3772 $sth->execute($barcode);
3773 my $exist=$sth->fetchrow ;
3774 return $exist;
3775 }
3776
3777 =head2 IsBranchTransferAllowed
3778
3779   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3780
3781 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3782
3783 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3784 Koha::Item->can_be_transferred.
3785
3786 =cut
3787
3788 sub IsBranchTransferAllowed {
3789         my ( $toBranch, $fromBranch, $code ) = @_;
3790
3791         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3792
3793         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3794         my $dbh = C4::Context->dbh;
3795
3796         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3797         $sth->execute( $toBranch, $fromBranch, $code );
3798         my $limit = $sth->fetchrow_hashref();
3799
3800         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3801         if ( $limit->{'limitId'} ) {
3802                 return 0;
3803         } else {
3804                 return 1;
3805         }
3806 }
3807
3808 =head2 CreateBranchTransferLimit
3809
3810   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3811
3812 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3813
3814 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3815
3816 =cut
3817
3818 sub CreateBranchTransferLimit {
3819    my ( $toBranch, $fromBranch, $code ) = @_;
3820    return unless defined($toBranch) && defined($fromBranch);
3821    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3822
3823    my $dbh = C4::Context->dbh;
3824
3825    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3826    return $sth->execute( $code, $toBranch, $fromBranch );
3827 }
3828
3829 =head2 DeleteBranchTransferLimits
3830
3831     my $result = DeleteBranchTransferLimits($frombranch);
3832
3833 Deletes all the library transfer limits for one library.  Returns the
3834 number of limits deleted, 0e0 if no limits were deleted, or undef if
3835 no arguments are supplied.
3836
3837 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3838     fromBranch => $fromBranch
3839     })->delete.
3840
3841 =cut
3842
3843 sub DeleteBranchTransferLimits {
3844     my $branch = shift;
3845     return unless defined $branch;
3846     my $dbh    = C4::Context->dbh;
3847     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3848     return $sth->execute($branch);
3849 }
3850
3851 sub ReturnLostItem{
3852     my ( $borrowernumber, $itemnum ) = @_;
3853     MarkIssueReturned( $borrowernumber, $itemnum );
3854 }
3855
3856 =head2 LostItem
3857
3858   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3859
3860 The final optional parameter, C<$params>, expected to contain
3861 'skip_record_index' key, which relayed down to Koha::Item/store,
3862 there it prevents calling of ModZebra index_records,
3863 which takes most of the time in batch adds/deletes: index_records better
3864 to be called later in C<additem.pl> after the whole loop.
3865
3866 $params:
3867     skip_record_index => 1|0
3868
3869 =cut
3870
3871 sub LostItem{
3872     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3873
3874     unless ( $mark_lost_from ) {
3875         # Temporary check to avoid regressions
3876         die q|LostItem called without $mark_lost_from, check the API.|;
3877     }
3878
3879     my $mark_returned;
3880     if ( $force_mark_returned ) {
3881         $mark_returned = 1;
3882     } else {
3883         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3884         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3885     }
3886
3887     my $dbh = C4::Context->dbh();
3888     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3889                            FROM issues
3890                            JOIN items USING (itemnumber)
3891                            JOIN biblio USING (biblionumber)
3892                            WHERE issues.itemnumber=?");
3893     $sth->execute($itemnumber);
3894     my $issues=$sth->fetchrow_hashref();
3895
3896     # If a borrower lost the item, add a replacement cost to the their record
3897     if ( my $borrowernumber = $issues->{borrowernumber} ){
3898         my $patron = Koha::Patrons->find( $borrowernumber );
3899
3900         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3901         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3902
3903         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3904             C4::Accounts::chargelostitem(
3905                 $borrowernumber,
3906                 $itemnumber,
3907                 $issues->{'replacementprice'},
3908                 sprintf( "%s %s %s",
3909                     $issues->{'title'}          || q{},
3910                     $issues->{'barcode'}        || q{},
3911                     $issues->{'itemcallnumber'} || q{},
3912                 ),
3913             );
3914             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3915             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3916         }
3917
3918         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
3919     }
3920
3921     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
3922     my $item = Koha::Items->find($itemnumber);
3923     my $transfers = $item->get_transfers;
3924     while (my $transfer = $transfers->next) {
3925         $transfer->cancel({ reason => 'ItemLost', force => 1 });
3926     }
3927 }
3928
3929 sub GetOfflineOperations {
3930     my $dbh = C4::Context->dbh;
3931     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3932     $sth->execute(C4::Context->userenv->{'branch'});
3933     my $results = $sth->fetchall_arrayref({});
3934     return $results;
3935 }
3936
3937 sub GetOfflineOperation {
3938     my $operationid = shift;
3939     return unless $operationid;
3940     my $dbh = C4::Context->dbh;
3941     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3942     $sth->execute( $operationid );
3943     return $sth->fetchrow_hashref;
3944 }
3945
3946 sub AddOfflineOperation {
3947     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3948     my $dbh = C4::Context->dbh;
3949     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3950     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3951     return "Added.";
3952 }
3953
3954 sub DeleteOfflineOperation {
3955     my $dbh = C4::Context->dbh;
3956     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3957     $sth->execute( shift );
3958     return "Deleted.";
3959 }
3960
3961 sub ProcessOfflineOperation {
3962     my $operation = shift;
3963
3964     my $report;
3965     if ( $operation->{action} eq 'return' ) {
3966         $report = ProcessOfflineReturn( $operation );
3967     } elsif ( $operation->{action} eq 'issue' ) {
3968         $report = ProcessOfflineIssue( $operation );
3969     } elsif ( $operation->{action} eq 'payment' ) {
3970         $report = ProcessOfflinePayment( $operation );
3971     }
3972
3973     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3974
3975     return $report;
3976 }
3977
3978 sub ProcessOfflineReturn {
3979     my $operation = shift;
3980
3981     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3982
3983     if ( $item ) {
3984         my $itemnumber = $item->itemnumber;
3985         my $issue = $item->checkout;
3986         if ( $issue ) {
3987             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
3988             ModDateLastSeen( $itemnumber, $leave_item_lost );
3989             MarkIssueReturned(
3990                 $issue->borrowernumber,
3991                 $itemnumber,
3992                 $operation->{timestamp},
3993             );
3994             $item->renewals_count(0);
3995             $item->onloan(undef);
3996             $item->store({ log_action => 0 });
3997             return "Success.";
3998         } else {
3999             return "Item not issued.";
4000         }
4001     } else {
4002         return "Item not found.";
4003     }
4004 }
4005
4006 sub ProcessOfflineIssue {
4007     my $operation = shift;
4008
4009     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4010
4011     if ( $patron ) {
4012         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4013         unless ($item) {
4014             return "Barcode not found.";
4015         }
4016         my $itemnumber = $item->itemnumber;
4017         my $issue = $item->checkout;
4018
4019         if ( $issue and ( $issue->borrowernumber ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4020             MarkIssueReturned(
4021                 $issue->borrowernumber,
4022                 $itemnumber,
4023                 $operation->{timestamp},
4024             );
4025         }
4026         AddIssue(
4027             $patron->unblessed,
4028             $operation->{'barcode'},
4029             undef,
4030             undef,
4031             $operation->{timestamp},
4032             undef,
4033         );
4034         return "Success.";
4035     } else {
4036         return "Borrower not found.";
4037     }
4038 }
4039
4040 sub ProcessOfflinePayment {
4041     my $operation = shift;
4042
4043     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4044
4045     $patron->account->pay(
4046         {
4047             amount     => $operation->{amount},
4048             library_id => $operation->{branchcode},
4049             interface  => 'koc'
4050         }
4051     );
4052
4053     return "Success.";
4054 }
4055
4056 =head2 TransferSlip
4057
4058   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4059
4060   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4061
4062 =cut
4063
4064 sub TransferSlip {
4065     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4066
4067     my $item =
4068       $itemnumber
4069       ? Koha::Items->find($itemnumber)
4070       : Koha::Items->find( { barcode => $barcode } );
4071
4072     $item or return;
4073
4074     return C4::Letters::GetPreparedLetter (
4075         module => 'circulation',
4076         letter_code => 'TRANSFERSLIP',
4077         branchcode => $branch,
4078         tables => {
4079             'branches'    => $to_branch,
4080             'biblio'      => $item->biblionumber,
4081             'items'       => $item->unblessed,
4082         },
4083     );
4084 }
4085
4086 =head2 CheckIfIssuedToPatron
4087
4088   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4089
4090   Return 1 if any record item is issued to patron, otherwise return 0
4091
4092 =cut
4093
4094 sub CheckIfIssuedToPatron {
4095     my ($borrowernumber, $biblionumber) = @_;
4096
4097     my $dbh = C4::Context->dbh;
4098     my $query = q|
4099         SELECT COUNT(*) FROM issues
4100         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4101         WHERE items.biblionumber = ?
4102         AND issues.borrowernumber = ?
4103     |;
4104     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4105     return 1 if $is_issued;
4106     return;
4107 }
4108
4109 =head2 IsItemIssued
4110
4111   IsItemIssued( $itemnumber )
4112
4113   Return 1 if the item is on loan, otherwise return 0
4114
4115 =cut
4116
4117 sub IsItemIssued {
4118     my $itemnumber = shift;
4119     my $dbh = C4::Context->dbh;
4120     my $sth = $dbh->prepare(q{
4121         SELECT COUNT(*)
4122         FROM issues
4123         WHERE itemnumber = ?
4124     });
4125     $sth->execute($itemnumber);
4126     return $sth->fetchrow;
4127 }
4128
4129 =head2 GetAgeRestriction
4130
4131   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4132   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4133
4134   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4135   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4136
4137 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4138 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4139 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4140          Negative days mean the borrower has gone past the age restriction age.
4141
4142 =cut
4143
4144 sub GetAgeRestriction {
4145     my ($record_restrictions, $borrower) = @_;
4146     my $markers = C4::Context->preference('AgeRestrictionMarker');
4147
4148     return unless $record_restrictions;
4149     # Split $record_restrictions to something like FSK 16 or PEGI 6
4150     my @values = split ' ', uc($record_restrictions);
4151     return unless @values;
4152
4153     # Search first occurrence of one of the markers
4154     my @markers = split /\|/, uc($markers);
4155     return unless @markers;
4156
4157     my $index            = 0;
4158     my $restriction_year = 0;
4159     for my $value (@values) {
4160         $index++;
4161         for my $marker (@markers) {
4162             $marker =~ s/^\s+//;    #remove leading spaces
4163             $marker =~ s/\s+$//;    #remove trailing spaces
4164             if ( $marker eq $value ) {
4165                 if ( $index <= $#values ) {
4166                     $restriction_year += $values[$index];
4167                 }
4168                 last;
4169             }
4170             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4171
4172                 # Perhaps it is something like "K16" (as in Finland)
4173                 $restriction_year += $1;
4174                 last;
4175             }
4176         }
4177         last if ( $restriction_year > 0 );
4178     }
4179
4180     #Check if the borrower is age restricted for this material and for how long.
4181     if ($restriction_year && $borrower) {
4182         if ( $borrower->{'dateofbirth'} ) {
4183             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4184             $alloweddate[0] += $restriction_year;
4185
4186             #Prevent runime eror on leap year (invalid date)
4187             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4188                 $alloweddate[2] = 28;
4189             }
4190
4191             #Get how many days the borrower has to reach the age restriction
4192             my @Today = split /-/, dt_from_string()->ymd();
4193             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4194             #Negative days means the borrower went past the age restriction age
4195             return ($restriction_year, $daysToAgeRestriction);
4196         }
4197     }
4198
4199     return ($restriction_year);
4200 }
4201
4202
4203 =head2 GetPendingOnSiteCheckouts
4204
4205 =cut
4206
4207 sub GetPendingOnSiteCheckouts {
4208     my $dbh = C4::Context->dbh;
4209     return $dbh->selectall_arrayref(q|
4210         SELECT
4211           items.barcode,
4212           items.biblionumber,
4213           items.itemnumber,
4214           items.itemnotes,
4215           items.itemcallnumber,
4216           items.location,
4217           issues.date_due,
4218           issues.branchcode,
4219           issues.date_due < NOW() AS is_overdue,
4220           biblio.author,
4221           biblio.title,
4222           borrowers.firstname,
4223           borrowers.surname,
4224           borrowers.cardnumber,
4225           borrowers.borrowernumber
4226         FROM items
4227         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4228         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4229         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4230         WHERE issues.onsite_checkout = 1
4231     |, { Slice => {} } );
4232 }
4233
4234 sub GetTopIssues {
4235     my ($params) = @_;
4236
4237     my ($count, $branch, $itemtype, $ccode, $newness)
4238         = @$params{qw(count branch itemtype ccode newness)};
4239
4240     my $dbh = C4::Context->dbh;
4241     my $query = q{
4242         SELECT * FROM (
4243         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4244           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4245           i.ccode, SUM(i.issues) AS count
4246         FROM biblio b
4247         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4248         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4249     };
4250
4251     my (@where_strs, @where_args);
4252
4253     if ($branch) {
4254         push @where_strs, 'i.homebranch = ?';
4255         push @where_args, $branch;
4256     }
4257     if ($itemtype) {
4258         if (C4::Context->preference('item-level_itypes')){
4259             push @where_strs, 'i.itype = ?';
4260             push @where_args, $itemtype;
4261         } else {
4262             push @where_strs, 'bi.itemtype = ?';
4263             push @where_args, $itemtype;
4264         }
4265     }
4266     if ($ccode) {
4267         push @where_strs, 'i.ccode = ?';
4268         push @where_args, $ccode;
4269     }
4270     if ($newness) {
4271         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4272         push @where_args, $newness;
4273     }
4274
4275     if (@where_strs) {
4276         $query .= 'WHERE ' . join(' AND ', @where_strs);
4277     }
4278
4279     $query .= q{
4280         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4281           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4282           i.ccode
4283         ORDER BY count DESC
4284     };
4285
4286     $query .= q{ ) xxx WHERE count > 0 };
4287     $count = int($count);
4288     if ($count > 0) {
4289         $query .= "LIMIT $count";
4290     }
4291
4292     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4293
4294     return @$rows;
4295 }
4296
4297 =head2 Internal methods
4298
4299 =cut
4300
4301 sub _CalculateAndUpdateFine {
4302     my ($params) = @_;
4303
4304     my $borrower    = $params->{borrower};
4305     my $item        = $params->{item};
4306     my $issue       = $params->{issue};
4307     my $return_date = $params->{return_date};
4308
4309     unless ($borrower) { carp "No borrower passed in!" && return; }
4310     unless ($item)     { carp "No item passed in!"     && return; }
4311     unless ($issue)    { carp "No issue passed in!"    && return; }
4312
4313     my $datedue = dt_from_string( $issue->date_due );
4314
4315     # we only need to calculate and change the fines if we want to do that on return
4316     # Should be on for hourly loans
4317     my $control = C4::Context->preference('CircControl');
4318     my $control_branchcode =
4319         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4320       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4321       :                                     $issue->branchcode;
4322
4323     my $date_returned = $return_date ? $return_date : dt_from_string();
4324
4325     my ( $amount, $unitcounttotal, $unitcount  ) =
4326       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4327
4328     if ( C4::Context->preference('finesMode') eq 'production' ) {
4329         if ( $amount > 0 ) {
4330             C4::Overdues::UpdateFine({
4331                 issue_id       => $issue->issue_id,
4332                 itemnumber     => $issue->itemnumber,
4333                 borrowernumber => $issue->borrowernumber,
4334                 amount         => $amount,
4335                 due            => $datedue,
4336             });
4337         }
4338         elsif ($return_date) {
4339
4340             # Backdated returns may have fines that shouldn't exist,
4341             # so in this case, we need to drop those fines to 0
4342
4343             C4::Overdues::UpdateFine({
4344                 issue_id       => $issue->issue_id,
4345                 itemnumber     => $issue->itemnumber,
4346                 borrowernumber => $issue->borrowernumber,
4347                 amount         => 0,
4348                 due            => $datedue,
4349             });
4350         }
4351     }
4352 }
4353
4354 sub _CanBookBeAutoRenewed {
4355     my ( $params ) = @_;
4356     my $patron = $params->{patron};
4357     my $item = $params->{item};
4358     my $branchcode = $params->{branchcode};
4359     my $issue = $params->{issue};
4360
4361     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4362
4363     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4364         {
4365             categorycode => $patron->categorycode,
4366             itemtype     => $item->effective_itemtype,
4367             branchcode   => $branchcode,
4368             rules => [
4369                 'no_auto_renewal_after',
4370                 'no_auto_renewal_after_hard_limit',
4371                 'lengthunit',
4372                 'norenewalbefore',
4373             ]
4374         }
4375     );
4376
4377     if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
4378         return 'auto_account_expired';
4379     }
4380
4381     if ( defined $issuing_rule->{no_auto_renewal_after}
4382             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4383         # Get issue_date and add no_auto_renewal_after
4384         # If this is greater than today, it's too late for renewal.
4385         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4386         $maximum_renewal_date->add(
4387             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4388         );
4389         my $now = dt_from_string;
4390         if ( $now >= $maximum_renewal_date ) {
4391             return "auto_too_late";
4392         }
4393     }
4394     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4395                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4396         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4397         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4398             return "auto_too_late";
4399         }
4400     }
4401
4402     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4403         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4404         my $amountoutstanding =
4405           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4406           ? $patron->account->balance
4407           : $patron->account->outstanding_debits->total_outstanding;
4408         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4409             return "auto_too_much_oweing";
4410         }
4411     }
4412
4413     my $soonest = GetSoonestRenewDate($issue);
4414     if ( $soonest > dt_from_string() )
4415     {
4416         return ( "auto_too_soon", $soonest );
4417     }
4418
4419     return "ok";
4420 }
4421
4422
4423 1;
4424
4425 __END__
4426
4427 =head1 AUTHOR
4428
4429 Koha Development Team <http://koha-community.org/>
4430
4431 =cut