C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use Koha::DateUtils;
  25 use C4::Context;
  26 use C4::Stats;
  27 use C4::Reserves;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Members;
  31 use C4::Accounts;
  32 use C4::ItemCirculationAlertPreference;
  33 use C4::Message;
  34 use C4::Debug;
  35 use C4::Log; # logaction
  36 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits;
  39
  40 use Data::Dumper;
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::Biblioitems;
  44 use Koha::DateUtils;
  45 use Koha::Calendar;
  46 use Koha::Checkouts;
  47 use Koha::Illrequests;
  48 use Koha::Items;
  49 use Koha::Patrons;
  50 use Koha::Patron::Debarments;
  51 use Koha::Database;
  52 use Koha::Libraries;
  53 use Koha::Account::Lines;
  54 use Koha::Holds;
  55 use Koha::Account::Lines;
  56 use Koha::Account::Offsets;
  57 use Koha::Config::SysPrefs;
  58 use Koha::Charges::Fees;
  59 use Koha::Util::SystemPreferences;
  60 use Koha::Checkouts::ReturnClaims;
  61 use Koha::SearchEngine::Indexer;
  62 use Carp;
  63 use List::MoreUtils qw( uniq any );
  64 use Scalar::Util qw( looks_like_number );
  65 use Try::Tiny;
  66 use Date::Calc qw(
  67   Today
  68   Today_and_Now
  69   Add_Delta_YM
  70   Add_Delta_DHMS
  71   Date_to_Days
  72   Day_of_Week
  73   Add_Delta_Days
  74 );
  75 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  76
  77 BEGIN {
  78         require Exporter;
  79         @ISA    = qw(Exporter);
  80
  81         # FIXME subs that should probably be elsewhere
  82         push @EXPORT, qw(
  83                 &barcodedecode
  84         &LostItem
  85         &ReturnLostItem
  86         &GetPendingOnSiteCheckouts
  87         );
  88
  89         # subs to deal with issuing a book
  90         push @EXPORT, qw(
  91                 &CanBookBeIssued
  92                 &CanBookBeRenewed
  93                 &AddIssue
  94                 &AddRenewal
  95                 &GetRenewCount
  96         &GetSoonestRenewDate
  97         &GetLatestAutoRenewDate
  98                 &GetIssuingCharges
  99         &GetBranchBorrowerCircRule
 100         &GetBranchItemRule
 101                 &GetBiblioIssues
 102                 &GetOpenIssue
 103         &CheckIfIssuedToPatron
 104         &IsItemIssued
 105         GetTopIssues
 106         );
 107
 108         # subs to deal with returns
 109         push @EXPORT, qw(
 110                 &AddReturn
 111         &MarkIssueReturned
 112         );
 113
 114         # subs to deal with transfers
 115         push @EXPORT, qw(
 116                 &transferbook
 117                 &GetTransfers
 118                 &GetTransfersFromTo
 119                 &updateWrongTransfer
 120                 &DeleteTransfer
 121                 &IsBranchTransferAllowed
 122                 &CreateBranchTransferLimit
 123                 &DeleteBranchTransferLimits
 124         &TransferSlip
 125         );
 126
 127     # subs to deal with offline circulation
 128     push @EXPORT, qw(
 129       &GetOfflineOperations
 130       &GetOfflineOperation
 131       &AddOfflineOperation
 132       &DeleteOfflineOperation
 133       &ProcessOfflineOperation
 134     );
 135 }
 136
 137 =head1 NAME
 138
 139 C4::Circulation - Koha circulation module
 140
 141 =head1 SYNOPSIS
 142
 143 use C4::Circulation;
 144
 145 =head1 DESCRIPTION
 146
 147 The functions in this module deal with circulation, issues, and
 148 returns, as well as general information about the library.
 149 Also deals with inventory.
 150
 151 =head1 FUNCTIONS
 152
 153 =head2 barcodedecode
 154
 155   $str = &barcodedecode($barcode, [$filter]);
 156
 157 Generic filter function for barcode string.
 158 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 159 Will do some manipulation of the barcode for systems that deliver a barcode
 160 to circulation.pl that differs from the barcode stored for the item.
 161 For proper functioning of this filter, calling the function on the
 162 correct barcode string (items.barcode) should return an unaltered barcode.
 163
 164 The optional $filter argument is to allow for testing or explicit
 165 behavior that ignores the System Pref.  Valid values are the same as the
 166 System Pref options.
 167
 168 =cut
 169
 170 # FIXME -- the &decode fcn below should be wrapped into this one.
 171 # FIXME -- these plugins should be moved out of Circulation.pm
 172 #
 173 sub barcodedecode {
 174     my ($barcode, $filter) = @_;
 175     my $branch = C4::Context::mybranch();
 176     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 177     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 178         if ($filter eq 'whitespace') {
 179                 $barcode =~ s/\s//g;
 180         } elsif ($filter eq 'cuecat') {
 181                 chomp($barcode);
 182             my @fields = split( /\./, $barcode );
 183             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 184             ($#results == 2) and return $results[2];
 185         } elsif ($filter eq 'T-prefix') {
 186                 if ($barcode =~ /^[Tt](\d)/) {
 187                         (defined($1) and $1 eq '0') and return $barcode;
 188             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 189                 }
 190         return sprintf("T%07d", $barcode);
 191         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 192         # Why drop the nonzero digit after the T?
 193         # Why pass non-digits (or empty string) to "T%07d"?
 194         } elsif ($filter eq 'libsuite8') {
 195                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 196                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 197                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 198                         }else{
 199                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 200                         }
 201                 }
 202     } elsif ($filter eq 'EAN13') {
 203         my $ean = CheckDigits('ean');
 204         if ( $ean->is_valid($barcode) ) {
 205             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 206             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 207         } else {
 208             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 209         }
 210         }
 211     return $barcode;    # return barcode, modified or not
 212 }
 213
 214 =head2 decode
 215
 216   $str = &decode($chunk);
 217
 218 Decodes a segment of a string emitted by a CueCat barcode scanner and
 219 returns it.
 220
 221 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 222 or Javascript based decoding on the client side.
 223
 224 =cut
 225
 226 sub decode {
 227     my ($encoded) = @_;
 228     my $seq =
 229       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 230     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 231     my $l = ( $#s + 1 ) % 4;
 232     if ($l) {
 233         if ( $l == 1 ) {
 234             # warn "Error: Cuecat decode parsing failed!";
 235             return;
 236         }
 237         $l = 4 - $l;
 238         $#s += $l;
 239     }
 240     my $r = '';
 241     while ( $#s >= 0 ) {
 242         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 243         $r .=
 244             chr( ( $n >> 16 ) ^ 67 )
 245          .chr( ( $n >> 8 & 255 ) ^ 67 )
 246          .chr( ( $n & 255 ) ^ 67 );
 247         @s = @s[ 4 .. $#s ];
 248     }
 249     $r = substr( $r, 0, length($r) - $l );
 250     return $r;
 251 }
 252
 253 =head2 transferbook
 254
 255   ($dotransfer, $messages, $iteminformation) = &transferbook({
 256                                                    from_branch => $frombranch
 257                                                    to_branch => $tobranch,
 258                                                    barcode => $barcode,
 259                                                    ignore_reserves => $ignore_reserves,
 260                                                    trigger => $trigger
 261                                                 });
 262
 263 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 264
 265 C<$fbr> is the code for the branch initiating the transfer.
 266 C<$tbr> is the code for the branch to which the item should be transferred.
 267
 268 C<$barcode> is the barcode of the item to be transferred.
 269
 270 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 271 Otherwise, if an item is reserved, the transfer fails.
 272
 273 C<$trigger> is the enum value for what triggered the transfer.
 274
 275 Returns three values:
 276
 277 =over
 278
 279 =item $dotransfer
 280
 281 is true if the transfer was successful.
 282
 283 =item $messages
 284
 285 is a reference-to-hash which may have any of the following keys:
 286
 287 =over
 288
 289 =item C<BadBarcode>
 290
 291 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 292
 293 =item C<DestinationEqualsHolding>
 294
 295 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 296
 297 =item C<WasReturned>
 298
 299 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 300
 301 =item C<ResFound>
 302
 303 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 304
 305 =item C<WasTransferred>
 306
 307 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 308
 309 =back
 310
 311 =back
 312
 313 =cut
 314
 315 sub transferbook {
 316     my $params = shift;
 317     my $tbr      = $params->{to_branch};
 318     my $fbr      = $params->{from_branch};
 319     my $ignoreRs = $params->{ignore_reserves};
 320     my $barcode  = $params->{barcode};
 321     my $trigger  = $params->{trigger};
 322     my $messages;
 323     my $dotransfer      = 1;
 324     my $item = Koha::Items->find( { barcode => $barcode } );
 325
 326     Koha::Exceptions::MissingParameter->throw(
 327         "Missing mandatory parameter: from_branch")
 328       unless $fbr;
 329
 330     Koha::Exceptions::MissingParameter->throw(
 331         "Missing mandatory parameter: to_branch")
 332       unless $tbr;
 333
 334     # bad barcode..
 335     unless ( $item ) {
 336         $messages->{'BadBarcode'} = $barcode;
 337         $dotransfer = 0;
 338         return ( $dotransfer, $messages );
 339     }
 340
 341     my $itemnumber = $item->itemnumber;
 342     # get branches of book...
 343     my $hbr = $item->homebranch;
 344
 345     # if using Branch Transfer Limits
 346     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 347         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 348         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 349             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 350                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 351                 $dotransfer = 0;
 352             }
 353         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 354             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 355             $dotransfer = 0;
 356         }
 357     }
 358
 359     # can't transfer book if is already there....
 360     if ( $fbr eq $tbr ) {
 361         $messages->{'DestinationEqualsHolding'} = 1;
 362         $dotransfer = 0;
 363     }
 364
 365     # check if it is still issued to someone, return it...
 366     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 367     if ( $issue ) {
 368         AddReturn( $barcode, $fbr );
 369         $messages->{'WasReturned'} = $issue->borrowernumber;
 370     }
 371
 372     # find reserves.....
 373     # That'll save a database query.
 374     my ( $resfound, $resrec, undef ) =
 375       CheckReserves( $itemnumber );
 376     if ( $resfound and not $ignoreRs ) {
 377         $resrec->{'ResFound'} = $resfound;
 378         $messages->{'ResFound'} = $resrec;
 379         $dotransfer = 1;
 380     }
 381
 382     #actually do the transfer....
 383     if ($dotransfer) {
 384         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 385
 386         # don't need to update MARC anymore, we do it in batch now
 387         $messages->{'WasTransfered'} = 1;
 388
 389     }
 390     ModDateLastSeen( $itemnumber );
 391     return ( $dotransfer, $messages );
 392 }
 393
 394
 395 sub TooMany {
 396     my $borrower        = shift;
 397     my $item_object = shift;
 398     my $params = shift;
 399     my $onsite_checkout = $params->{onsite_checkout} || 0;
 400     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 401     my $cat_borrower    = $borrower->{'categorycode'};
 402     my $dbh             = C4::Context->dbh;
 403     # Get which branchcode we need
 404     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 405     my $type = $item_object->effective_itemtype;
 406
 407     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 408     $type_object = Koha::ItemTypes->find( $type );
 409     $parent_type = $type_object->parent_type if $type_object;
 410     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 411     # Find any children if we are a parent_type;
 412
 413     # given branch, patron category, and item type, determine
 414     # applicable issuing rule
 415
 416     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 417         {
 418             categorycode => $cat_borrower,
 419             itemtype     => $parent_type,
 420             branchcode   => $branch,
 421             rule_name    => 'maxissueqty',
 422         }
 423     ) if $parent_type;
 424     # If the parent rule is for default type we discount it
 425     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 426
 427     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 428         {
 429             categorycode => $cat_borrower,
 430             itemtype     => $type,
 431             branchcode   => $branch,
 432             rule_name    => 'maxissueqty',
 433         }
 434     );
 435
 436     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 437         {
 438             categorycode => $cat_borrower,
 439             itemtype     => $type,
 440             branchcode   => $branch,
 441             rule_name    => 'maxonsiteissueqty',
 442         }
 443     );
 444
 445
 446     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 447     # if a rule is found and has a loan limit set, count
 448     # how many loans the patron already has that meet that
 449     # rule
 450     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 451
 452         my $checkouts;
 453         if ( $maxissueqty_rule->branchcode ) {
 454             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 455                 $checkouts = $patron->checkouts->search(
 456                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 457             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 458                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 459             } else {
 460                 $checkouts = $patron->checkouts->search(
 461                     { 'item.homebranch' => $maxissueqty_rule->branchcode },
 462                     { prefetch          => 'item' } );
 463             }
 464         } else {
 465             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 466         }
 467         my $sum_checkouts;
 468         my $rule_itemtype = $maxissueqty_rule->itemtype;
 469         while ( my $c = $checkouts->next ) {
 470             my $itemtype = $c->item->effective_itemtype;
 471             my @types;
 472             unless ( $rule_itemtype ) {
 473                 # matching rule has the default item type, so count only
 474                 # those existing loans that don't fall under a more
 475                 # specific rule
 476                 @types = Koha::CirculationRules->search(
 477                     {
 478                         branchcode => $maxissueqty_rule->branchcode,
 479                         categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 480                         itemtype  => { '!=' => undef },
 481                         rule_name => 'maxissueqty'
 482                     }
 483                 )->get_column('itemtype');
 484
 485                 next if grep {$_ eq $itemtype} @types;
 486             } else {
 487                 my @types;
 488                 if ( $parent_maxissueqty_rule ) {
 489                 # if we have a parent item type then we count loans of the
 490                 # specific item type or its siblings or parent
 491                     my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 492                     @types = $children->get_column('itemtype');
 493                     push @types, $parent_type;
 494                 } elsif ( $child_types ) {
 495                 # If we are a parent type, we need to count all child types and our own type
 496                     @types = $child_types->get_column('itemtype');
 497                     push @types, $type; # And don't forget to count our own types
 498                 } else { push @types, $type; } # Otherwise only count the specific itemtype
 499
 500                 next unless grep {$_ eq $itemtype} @types;
 501             }
 502             $sum_checkouts->{total}++;
 503             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 504             $sum_checkouts->{itemtype}->{$itemtype}++;
 505         }
 506
 507         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 508         my $checkout_count = $sum_checkouts->{total} || 0;
 509         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 510
 511         my $checkout_rules = {
 512             checkout_count               => $checkout_count,
 513             onsite_checkout_count        => $onsite_checkout_count,
 514             onsite_checkout              => $onsite_checkout,
 515             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 516             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 517             switch_onsite_checkout       => $switch_onsite_checkout,
 518         };
 519         # If parent rules exists
 520         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 521             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 522             my $qty_over = _check_max_qty($checkout_rules);
 523             return $qty_over if defined $qty_over;
 524
 525             # If the parent rule is less than or equal to the child, we only need check the parent
 526             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 527                 $checkout_rules->{checkout_count} = $checkout_count_type;
 528                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 529                 my $qty_over = _check_max_qty($checkout_rules);
 530                 return $qty_over if defined $qty_over;
 531             }
 532         } else {
 533             my $qty_over = _check_max_qty($checkout_rules);
 534             return $qty_over if defined $qty_over;
 535         }
 536     }
 537
 538     # Now count total loans against the limit for the branch
 539     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 540     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 541         my $checkouts;
 542         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 543             $checkouts = $patron->checkouts->search(
 544                 { 'me.branchcode' => $branch} );
 545         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 546             ; # if branch is the patron's home branch, then count all loans by patron
 547         } else {
 548             $checkouts = $patron->checkouts->search(
 549                 { 'item.homebranch' => $branch} );
 550         }
 551
 552         my $checkout_count = $checkouts->count;
 553         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 554         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 555         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 556
 557         my $qty_over = _check_max_qty(
 558             {
 559                 checkout_count               => $checkout_count,
 560                 onsite_checkout_count        => $onsite_checkout_count,
 561                 onsite_checkout              => $onsite_checkout,
 562                 max_checkouts_allowed        => $max_checkouts_allowed,
 563                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 564                 switch_onsite_checkout       => $switch_onsite_checkout
 565             }
 566         );
 567         return $qty_over if defined $qty_over;
 568     }
 569
 570     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 571         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 572     }
 573
 574     # OK, the patron can issue !!!
 575     return;
 576 }
 577
 578 sub _check_max_qty {
 579     my $params                       = shift;
 580     my $checkout_count               = $params->{checkout_count};
 581     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 582     my $onsite_checkout              = $params->{onsite_checkout};
 583     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 584     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 585     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 586
 587     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 588         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 589         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 590             return {
 591                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 592                 count       => $onsite_checkout_count,
 593                 max_allowed => $max_onsite_checkouts_allowed,
 594             };
 595         }
 596     }
 597     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 598         if ( $max_checkouts_allowed eq '' ) { return; }
 599         my $delta = $switch_onsite_checkout ? 1 : 0;
 600         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 601             return {
 602                 reason      => 'TOO_MANY_CHECKOUTS',
 603                 count       => $checkout_count,
 604                 max_allowed => $max_checkouts_allowed,
 605             };
 606         }
 607     }
 608     elsif ( not $onsite_checkout ) {
 609         if ( $max_checkouts_allowed eq '' ) { return; }
 610         if (
 611             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 612         {
 613             return {
 614                 reason      => 'TOO_MANY_CHECKOUTS',
 615                 count       => $checkout_count - $onsite_checkout_count,
 616                 max_allowed => $max_checkouts_allowed,
 617             };
 618         }
 619     }
 620
 621     return;
 622 }
 623
 624 =head2 CanBookBeIssued
 625
 626   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 627                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 628
 629 Check if a book can be issued.
 630
 631 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 632
 633 IMPORTANT: The assumption by users of this routine is that causes blocking
 634 the issue are keyed by uppercase labels and other returned
 635 data is keyed in lower case!
 636
 637 =over 4
 638
 639 =item C<$patron> is a Koha::Patron
 640
 641 =item C<$barcode> is the bar code of the book being issued.
 642
 643 =item C<$duedates> is a DateTime object.
 644
 645 =item C<$inprocess> boolean switch
 646
 647 =item C<$ignore_reserves> boolean switch
 648
 649 =item C<$params> Hashref of additional parameters
 650
 651 Available keys:
 652     override_high_holds - Ignore high holds
 653     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 654
 655 =back
 656
 657 Returns :
 658
 659 =over 4
 660
 661 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 662 Possible values are :
 663
 664 =back
 665
 666 =head3 INVALID_DATE
 667
 668 sticky due date is invalid
 669
 670 =head3 GNA
 671
 672 borrower gone with no address
 673
 674 =head3 CARD_LOST
 675
 676 borrower declared it's card lost
 677
 678 =head3 DEBARRED
 679
 680 borrower debarred
 681
 682 =head3 UNKNOWN_BARCODE
 683
 684 barcode unknown
 685
 686 =head3 NOT_FOR_LOAN
 687
 688 item is not for loan
 689
 690 =head3 WTHDRAWN
 691
 692 item withdrawn.
 693
 694 =head3 RESTRICTED
 695
 696 item is restricted (set by ??)
 697
 698 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 699 could be prevented, but ones that can be overriden by the operator.
 700
 701 Possible values are :
 702
 703 =head3 DEBT
 704
 705 borrower has debts.
 706
 707 =head3 RENEW_ISSUE
 708
 709 renewing, not issuing
 710
 711 =head3 ISSUED_TO_ANOTHER
 712
 713 issued to someone else.
 714
 715 =head3 RESERVED
 716
 717 reserved for someone else.
 718
 719 =head3 INVALID_DATE
 720
 721 sticky due date is invalid or due date in the past
 722
 723 =head3 TOO_MANY
 724
 725 if the borrower borrows to much things
 726
 727 =cut
 728
 729 sub CanBookBeIssued {
 730     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 731     my %needsconfirmation;    # filled with problems that needs confirmations
 732     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 733     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 734     my %messages;             # filled with information messages that should be displayed.
 735
 736     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 737     my $override_high_holds = $params->{override_high_holds} || 0;
 738
 739     my $item_object = Koha::Items->find({barcode => $barcode });
 740
 741     # MANDATORY CHECKS - unless item exists, nothing else matters
 742     unless ( $item_object ) {
 743         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 744     }
 745     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 746
 747     my $item_unblessed = $item_object->unblessed; # Transition...
 748     my $issue = $item_object->checkout;
 749     my $biblio = $item_object->biblio;
 750
 751     my $biblioitem = $biblio->biblioitem;
 752     my $effective_itemtype = $item_object->effective_itemtype;
 753     my $dbh             = C4::Context->dbh;
 754     my $patron_unblessed = $patron->unblessed;
 755
 756     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 757     #
 758     # DUE DATE is OK ? -- should already have checked.
 759     #
 760     if ($duedate && ref $duedate ne 'DateTime') {
 761         $duedate = dt_from_string($duedate);
 762     }
 763     my $now = dt_from_string();
 764     unless ( $duedate ) {
 765         my $issuedate = $now->clone();
 766
 767         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 768
 769         # Offline circ calls AddIssue directly, doesn't run through here
 770         #  So issuingimpossible should be ok.
 771     }
 772
 773     my $fees = Koha::Charges::Fees->new(
 774         {
 775             patron    => $patron,
 776             library   => $circ_library,
 777             item      => $item_object,
 778             to_date   => $duedate,
 779         }
 780     );
 781
 782     if ($duedate) {
 783         my $today = $now->clone();
 784         $today->truncate( to => 'minute');
 785         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 786             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 787         }
 788     } else {
 789             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 790     }
 791
 792     #
 793     # BORROWER STATUS
 794     #
 795     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 796         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 797         &UpdateStats({
 798                      branch => C4::Context->userenv->{'branch'},
 799                      type => 'localuse',
 800                      itemnumber => $item_object->itemnumber,
 801                      itemtype => $effective_itemtype,
 802                      borrowernumber => $patron->borrowernumber,
 803                      ccode => $item_object->ccode}
 804                     );
 805         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 806         return( { STATS => 1 }, {});
 807     }
 808
 809     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 810         $issuingimpossible{GNA} = 1;
 811     }
 812
 813     if ( $patron->lost && $patron->lost == 1 ) {
 814         $issuingimpossible{CARD_LOST} = 1;
 815     }
 816     if ( $patron->is_debarred ) {
 817         $issuingimpossible{DEBARRED} = 1;
 818     }
 819
 820     if ( $patron->is_expired ) {
 821         $issuingimpossible{EXPIRED} = 1;
 822     }
 823
 824     #
 825     # BORROWER STATUS
 826     #
 827
 828     # DEBTS
 829     my $account = $patron->account;
 830     my $balance = $account->balance;
 831     my $non_issues_charges = $account->non_issues_charges;
 832     my $other_charges = $balance - $non_issues_charges;
 833
 834     my $amountlimit = C4::Context->preference("noissuescharge");
 835     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 836     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 837
 838     # Check the debt of this patrons guarantees
 839     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 840     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 841     if ( defined $no_issues_charge_guarantees ) {
 842         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 843         my $guarantees_non_issues_charges;
 844         foreach my $g ( @guarantees ) {
 845             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 846         }
 847
 848         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 849             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 850         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 851             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 852         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 853             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 854         }
 855     }
 856
 857     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 858     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 859     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 860     if ( defined $no_issues_charge_guarantors ) {
 861         my $guarantors_non_issues_charges += $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 862
 863         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 864             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 865         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 866             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 867         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 868             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 869         }
 870     }
 871
 872     if ( C4::Context->preference("IssuingInProcess") ) {
 873         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 874             $issuingimpossible{DEBT} = $non_issues_charges;
 875         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 876             $needsconfirmation{DEBT} = $non_issues_charges;
 877         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 878             $needsconfirmation{DEBT} = $non_issues_charges;
 879         }
 880     }
 881     else {
 882         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 883             $needsconfirmation{DEBT} = $non_issues_charges;
 884         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 885             $issuingimpossible{DEBT} = $non_issues_charges;
 886         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 887             $needsconfirmation{DEBT} = $non_issues_charges;
 888         }
 889     }
 890
 891     if ($balance > 0 && $other_charges > 0) {
 892         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 893     }
 894
 895     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 896     $patron_unblessed = $patron->unblessed;
 897
 898     if ( my $debarred_date = $patron->is_debarred ) {
 899          # patron has accrued fine days or has a restriction. $count is a date
 900         if ($debarred_date eq '9999-12-31') {
 901             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 902         }
 903         else {
 904             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 905         }
 906     } elsif ( my $num_overdues = $patron->has_overdues ) {
 907         ## patron has outstanding overdue loans
 908         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 909             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 910         }
 911         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 912             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 913         }
 914     }
 915
 916     # Additional Materials Check
 917     if ( C4::Context->preference("CircConfirmItemParts")
 918         && $item_object->materials )
 919     {
 920         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 921     }
 922
 923     #
 924     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 925     #
 926     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 927
 928         # Already issued to current borrower.
 929         # If it is an on-site checkout if it can be switched to a normal checkout
 930         # or ask whether the loan should be renewed
 931
 932         if ( $issue->onsite_checkout
 933                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 934             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 935         } else {
 936             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 937                 $patron->borrowernumber,
 938                 $item_object->itemnumber,
 939             );
 940             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 941                 if ( $renewerror eq 'onsite_checkout' ) {
 942                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 943                 }
 944                 else {
 945                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 946                 }
 947             }
 948             else {
 949                 $needsconfirmation{RENEW_ISSUE} = 1;
 950             }
 951         }
 952     }
 953     elsif ( $issue ) {
 954
 955         # issued to someone else
 956
 957         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 958
 959         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 960
 961         unless ( $can_be_returned ) {
 962             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 963             $issuingimpossible{branch_to_return} = $message;
 964         } else {
 965             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 966                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 967             } else {
 968             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 969             $needsconfirmation{issued_firstname} = $patron->firstname;
 970             $needsconfirmation{issued_surname} = $patron->surname;
 971             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 972             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 973             }
 974         }
 975     }
 976
 977     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 978     #
 979     my $switch_onsite_checkout = (
 980           C4::Context->preference('SwitchOnSiteCheckouts')
 981       and $issue
 982       and $issue->onsite_checkout
 983       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 984     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 985     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 986     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 987         if ( $toomany->{max_allowed} == 0 ) {
 988             $needsconfirmation{PATRON_CANT} = 1;
 989         }
 990         if ( C4::Context->preference("AllowTooManyOverride") ) {
 991             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 992             $needsconfirmation{current_loan_count} = $toomany->{count};
 993             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 994         } else {
 995             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 996             $issuingimpossible{current_loan_count} = $toomany->{count};
 997             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 998         }
 999     }
1000
1001     #
1002     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1003     #
1004     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1005     my $wants_check = $patron->wants_check_for_previous_checkout;
1006     $needsconfirmation{PREVISSUE} = 1
1007         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1008
1009     #
1010     # ITEM CHECKING
1011     #
1012     if ( $item_object->notforloan )
1013     {
1014         if(!C4::Context->preference("AllowNotForLoanOverride")){
1015             $issuingimpossible{NOT_FOR_LOAN} = 1;
1016             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1017         }else{
1018             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1019             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1020         }
1021     }
1022     else {
1023         # we have to check itemtypes.notforloan also
1024         if (C4::Context->preference('item-level_itypes')){
1025             # this should probably be a subroutine
1026             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1027             $sth->execute($effective_itemtype);
1028             my $notforloan=$sth->fetchrow_hashref();
1029             if ($notforloan->{'notforloan'}) {
1030                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1031                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1032                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1033                 } else {
1034                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1035                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1036                 }
1037             }
1038         }
1039         else {
1040             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1041             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1042                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1043                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1044                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1045                 } else {
1046                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1047                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1048                 }
1049             }
1050         }
1051     }
1052     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1053     {
1054         $issuingimpossible{WTHDRAWN} = 1;
1055     }
1056     if (   $item_object->restricted
1057         && $item_object->restricted == 1 )
1058     {
1059         $issuingimpossible{RESTRICTED} = 1;
1060     }
1061     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1062         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1063         my $code = $av->count ? $av->next->lib : '';
1064         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1065         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1066     }
1067     if ( C4::Context->preference("IndependentBranches") ) {
1068         my $userenv = C4::Context->userenv;
1069         unless ( C4::Context->IsSuperLibrarian() ) {
1070             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1071             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1072                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1073                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1074             }
1075             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1076               if ( $patron->branchcode ne $userenv->{branch} );
1077         }
1078     }
1079
1080     #
1081     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1082     #
1083     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1084     if ($rentalConfirmation) {
1085         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1086
1087         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1088         if ($itemtype_object) {
1089             my $accumulate_charge = $fees->accumulate_rentalcharge();
1090             if ( $accumulate_charge > 0 ) {
1091                 $rentalCharge += $accumulate_charge;
1092             }
1093         }
1094
1095         if ( $rentalCharge > 0 ) {
1096             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1097         }
1098     }
1099
1100     unless ( $ignore_reserves ) {
1101         # See if the item is on reserve.
1102         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1103         if ($restype) {
1104             my $resbor = $res->{'borrowernumber'};
1105             if ( $resbor ne $patron->borrowernumber ) {
1106                 my $patron = Koha::Patrons->find( $resbor );
1107                 if ( $restype eq "Waiting" )
1108                 {
1109                     # The item is on reserve and waiting, but has been
1110                     # reserved by some other patron.
1111                     $needsconfirmation{RESERVE_WAITING} = 1;
1112                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1113                     $needsconfirmation{'ressurname'} = $patron->surname;
1114                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1115                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1116                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1117                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1118                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1119                 }
1120                 elsif ( $restype eq "Reserved" ) {
1121                     # The item is on reserve for someone else.
1122                     $needsconfirmation{RESERVED} = 1;
1123                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1124                     $needsconfirmation{'ressurname'} = $patron->surname;
1125                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1126                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1127                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1128                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1129                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1130                 }
1131             }
1132         }
1133     }
1134
1135     ## CHECK AGE RESTRICTION
1136     my $agerestriction  = $biblioitem->agerestriction;
1137     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1138     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1139         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1140             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1141         }
1142         else {
1143             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1144         }
1145     }
1146
1147     ## check for high holds decreasing loan period
1148     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1149         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1150
1151         if ( $check->{exceeded} ) {
1152             if ($override_high_holds) {
1153                 $alerts{HIGHHOLDS} = {
1154                     num_holds  => $check->{outstanding},
1155                     duration   => $check->{duration},
1156                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1157                 };
1158             }
1159             else {
1160                 $needsconfirmation{HIGHHOLDS} = {
1161                     num_holds  => $check->{outstanding},
1162                     duration   => $check->{duration},
1163                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1164                 };
1165             }
1166         }
1167     }
1168
1169     if (
1170         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1171         # don't do the multiple loans per bib check if we've
1172         # already determined that we've got a loan on the same item
1173         !$issuingimpossible{NO_MORE_RENEWALS} &&
1174         !$needsconfirmation{RENEW_ISSUE}
1175     ) {
1176         # Check if borrower has already issued an item from the same biblio
1177         # Only if it's not a subscription
1178         my $biblionumber = $item_object->biblionumber;
1179         require C4::Serials;
1180         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1181         unless ($is_a_subscription) {
1182             # FIXME Should be $patron->checkouts($args);
1183             my $checkouts = Koha::Checkouts->search(
1184                 {
1185                     borrowernumber => $patron->borrowernumber,
1186                     biblionumber   => $biblionumber,
1187                 },
1188                 {
1189                     join => 'item',
1190                 }
1191             );
1192             # if we get here, we don't already have a loan on this item,
1193             # so if there are any loans on this bib, ask for confirmation
1194             if ( $checkouts->count ) {
1195                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1196             }
1197         }
1198     }
1199
1200     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1201 }
1202
1203 =head2 CanBookBeReturned
1204
1205   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1206
1207 Check whether the item can be returned to the provided branch
1208
1209 =over 4
1210
1211 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1212
1213 =item C<$branch> is the branchcode where the return is taking place
1214
1215 =back
1216
1217 Returns:
1218
1219 =over 4
1220
1221 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1222
1223 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1224
1225 =back
1226
1227 =cut
1228
1229 sub CanBookBeReturned {
1230   my ($item, $branch) = @_;
1231   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1232
1233   # assume return is allowed to start
1234   my $allowed = 1;
1235   my $message;
1236
1237   # identify all cases where return is forbidden
1238   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1239      $allowed = 0;
1240      $message = $item->{'homebranch'};
1241   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1242      $allowed = 0;
1243      $message = $item->{'holdingbranch'};
1244   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1245      $allowed = 0;
1246      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1247   }
1248
1249   return ($allowed, $message);
1250 }
1251
1252 =head2 CheckHighHolds
1253
1254     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1255     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1256     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1257
1258 =cut
1259
1260 sub checkHighHolds {
1261     my ( $item, $borrower ) = @_;
1262     my $branchcode = _GetCircControlBranch( $item, $borrower );
1263     my $item_object = Koha::Items->find( $item->{itemnumber} );
1264
1265     my $return_data = {
1266         exceeded    => 0,
1267         outstanding => 0,
1268         duration    => 0,
1269         due_date    => undef,
1270     };
1271
1272     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1273
1274     if ( $holds->count() ) {
1275         $return_data->{outstanding} = $holds->count();
1276
1277         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1278         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1279         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1280
1281         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1282
1283         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1284
1285             # static means just more than a given number of holds on the record
1286
1287             # If the number of holds is less than the threshold, we can stop here
1288             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1289                 return $return_data;
1290             }
1291         }
1292         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1293
1294             # dynamic means X more than the number of holdable items on the record
1295
1296             # let's get the items
1297             my @items = $holds->next()->biblio()->items()->as_list;
1298
1299             # Remove any items with status defined to be ignored even if the would not make item unholdable
1300             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1301                 @items = grep { !$_->$status } @items;
1302             }
1303
1304             # Remove any items that are not holdable for this patron
1305             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1306
1307             my $items_count = scalar @items;
1308
1309             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1310
1311             # If the number of holds is less than the count of items we have
1312             # plus the number of holds allowed above that count, we can stop here
1313             if ( $holds->count() <= $threshold ) {
1314                 return $return_data;
1315             }
1316         }
1317
1318         my $issuedate = dt_from_string();
1319
1320         my $itype = $item_object->effective_itemtype;
1321         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1322             {
1323                 categorycode => $borrower->{categorycode},
1324                 itemtype     => $itype,
1325                 branchcode   => $branchcode,
1326             }
1327         );
1328         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1329
1330         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1331
1332         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1333
1334         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1335         $reduced_datedue->set_hour($orig_due->hour);
1336         $reduced_datedue->set_minute($orig_due->minute);
1337         $reduced_datedue->truncate( to => 'minute' );
1338
1339         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1340             $return_data->{exceeded} = 1;
1341             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1342             $return_data->{due_date} = $reduced_datedue;
1343         }
1344     }
1345
1346     return $return_data;
1347 }
1348
1349 =head2 AddIssue
1350
1351   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1352
1353 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1354
1355 =over 4
1356
1357 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1358
1359 =item C<$barcode> is the barcode of the item being issued.
1360
1361 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1362 Calculated if empty.
1363
1364 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1365
1366 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1367 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1368
1369 AddIssue does the following things :
1370
1371   - step 01: check that there is a borrowernumber & a barcode provided
1372   - check for RENEWAL (book issued & being issued to the same patron)
1373       - renewal YES = Calculate Charge & renew
1374       - renewal NO  =
1375           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1376           * RESERVE PLACED ?
1377               - fill reserve if reserve to this patron
1378               - cancel reserve or not, otherwise
1379           * TRANSFERT PENDING ?
1380               - complete the transfert
1381           * ISSUE THE BOOK
1382
1383 =back
1384
1385 =cut
1386
1387 sub AddIssue {
1388     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1389
1390     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1391     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1392     my $auto_renew = $params && $params->{auto_renew};
1393     my $dbh          = C4::Context->dbh;
1394     my $barcodecheck = CheckValidBarcode($barcode);
1395
1396     my $issue;
1397
1398     if ( $datedue && ref $datedue ne 'DateTime' ) {
1399         $datedue = dt_from_string($datedue);
1400     }
1401
1402     # $issuedate defaults to today.
1403     if ( !defined $issuedate ) {
1404         $issuedate = dt_from_string();
1405     }
1406     else {
1407         if ( ref $issuedate ne 'DateTime' ) {
1408             $issuedate = dt_from_string($issuedate);
1409
1410         }
1411     }
1412
1413     # Stop here if the patron or barcode doesn't exist
1414     if ( $borrower && $barcode && $barcodecheck ) {
1415         # find which item we issue
1416         my $item_object = Koha::Items->find({ barcode => $barcode })
1417           or return;    # if we don't get an Item, abort.
1418         my $item_unblessed = $item_object->unblessed;
1419
1420         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1421
1422         # get actual issuing if there is one
1423         my $actualissue = $item_object->checkout;
1424
1425         # check if we just renew the issue.
1426         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1427                 and not $switch_onsite_checkout ) {
1428             $datedue = AddRenewal(
1429                 $borrower->{'borrowernumber'},
1430                 $item_object->itemnumber,
1431                 $branchcode,
1432                 $datedue,
1433                 $issuedate,    # here interpreted as the renewal date
1434             );
1435         }
1436         else {
1437             unless ($datedue) {
1438                 my $itype = $item_object->effective_itemtype;
1439                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1440
1441             }
1442             $datedue->truncate( to => 'minute' );
1443
1444             my $patron = Koha::Patrons->find( $borrower );
1445             my $library = Koha::Libraries->find( $branchcode );
1446             my $fees = Koha::Charges::Fees->new(
1447                 {
1448                     patron    => $patron,
1449                     library   => $library,
1450                     item      => $item_object,
1451                     to_date   => $datedue,
1452                 }
1453             );
1454
1455             # it's NOT a renewal
1456             if ( $actualissue and not $switch_onsite_checkout ) {
1457                 # This book is currently on loan, but not to the person
1458                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1459                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1460                 return unless $allowed;
1461                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1462             }
1463
1464             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1465
1466             # Starting process for transfer job (checking transfert and validate it if we have one)
1467             if ( my $transfer = $item_object->get_transfer ) {
1468                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1469                 $transfer->set(
1470                     {
1471                         datearrived => dt_from_string,
1472                         tobranch    => C4::Context->userenv->{branch},
1473                         comments    => 'Forced branchtransfer'
1474                     }
1475                 )->store;
1476                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1477                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1478                     if ( $hold ) { # Is this really needed?
1479                         $hold->set( { found => undef } )->store;
1480                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1481                     }
1482                 }
1483             }
1484
1485             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1486             unless ($auto_renew) {
1487                 my $rule = Koha::CirculationRules->get_effective_rule(
1488                     {
1489                         categorycode => $borrower->{categorycode},
1490                         itemtype     => $item_object->effective_itemtype,
1491                         branchcode   => $branchcode,
1492                         rule_name    => 'auto_renew'
1493                     }
1494                 );
1495
1496                 $auto_renew = $rule->rule_value if $rule;
1497             }
1498
1499             # Record in the database the fact that the book was issued.
1500             unless ($datedue) {
1501                 my $itype = $item_object->effective_itemtype;
1502                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1503
1504             }
1505             $datedue->truncate( to => 'minute' );
1506
1507             my $issue_attributes = {
1508                 borrowernumber  => $borrower->{'borrowernumber'},
1509                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1510                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1511                 branchcode      => C4::Context->userenv->{'branch'},
1512                 onsite_checkout => $onsite_checkout,
1513                 auto_renew      => $auto_renew ? 1 : 0,
1514             };
1515
1516             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1517             if ($issue) {
1518                 $issue->set($issue_attributes)->store;
1519             }
1520             else {
1521                 $issue = Koha::Checkout->new(
1522                     {
1523                         itemnumber => $item_object->itemnumber,
1524                         %$issue_attributes,
1525                     }
1526                 )->store;
1527             }
1528             if ( $item_object->location && $item_object->location eq 'CART'
1529                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1530             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1531                 CartToShelf( $item_object->itemnumber );
1532             }
1533
1534             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1535                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1536             }
1537
1538             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1539             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1540             $item_object->itemlost(0);
1541             $item_object->onloan($datedue->ymd());
1542             $item_object->datelastborrowed( dt_from_string()->ymd() );
1543             $item_object->store({log_action => 0});
1544             ModDateLastSeen( $item_object->itemnumber );
1545
1546             # If it costs to borrow this book, charge it to the patron's account.
1547             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1548             if ( $charge && $charge > 0 ) {
1549                 AddIssuingCharge( $issue, $charge, 'RENT' );
1550             }
1551
1552             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1553             if ( $itemtype_object ) {
1554                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1555                 if ( $accumulate_charge > 0 ) {
1556                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1557                     $charge += $accumulate_charge;
1558                     $item_unblessed->{charge} = $charge;
1559                 }
1560             }
1561
1562             # Record the fact that this book was issued.
1563             &UpdateStats(
1564                 {
1565                     branch => C4::Context->userenv->{'branch'},
1566                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1567                     amount         => $charge,
1568                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1569                     itemnumber     => $item_object->itemnumber,
1570                     itemtype       => $item_object->effective_itemtype,
1571                     location       => $item_object->location,
1572                     borrowernumber => $borrower->{'borrowernumber'},
1573                     ccode          => $item_object->ccode,
1574                 }
1575             );
1576
1577             # Send a checkout slip.
1578             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1579             my %conditions        = (
1580                 branchcode   => $branchcode,
1581                 categorycode => $borrower->{categorycode},
1582                 item_type    => $item_object->effective_itemtype,
1583                 notification => 'CHECKOUT',
1584             );
1585             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1586                 SendCirculationAlert(
1587                     {
1588                         type     => 'CHECKOUT',
1589                         item     => $item_object->unblessed,
1590                         borrower => $borrower,
1591                         branch   => $branchcode,
1592                     }
1593                 );
1594             }
1595             logaction(
1596                 "CIRCULATION", "ISSUE",
1597                 $borrower->{'borrowernumber'},
1598                 $item_object->itemnumber,
1599             ) if C4::Context->preference("IssueLog");
1600
1601             Koha::Plugins->call('after_circ_action', {
1602                 action  => 'checkout',
1603                 payload => {
1604                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1605                     checkout => $issue->get_from_storage
1606                 }
1607             });
1608         }
1609     }
1610     return $issue;
1611 }
1612
1613 =head2 GetLoanLength
1614
1615   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1616
1617 Get loan length for an itemtype, a borrower type and a branch
1618
1619 =cut
1620
1621 sub GetLoanLength {
1622     my ( $categorycode, $itemtype, $branchcode ) = @_;
1623
1624     # Initialize default values
1625     my $rules = {
1626         issuelength   => 0,
1627         renewalperiod => 0,
1628         lengthunit    => 'days',
1629     };
1630
1631     my $found = Koha::CirculationRules->get_effective_rules( {
1632         branchcode => $branchcode,
1633         categorycode => $categorycode,
1634         itemtype => $itemtype,
1635         rules => [
1636             'issuelength',
1637             'renewalperiod',
1638             'lengthunit'
1639         ],
1640     } );
1641
1642     # Search for rules!
1643     foreach my $rule_name (keys %$found) {
1644         $rules->{$rule_name} = $found->{$rule_name};
1645     }
1646
1647     return $rules;
1648 }
1649
1650
1651 =head2 GetHardDueDate
1652
1653   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1654
1655 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1656
1657 =cut
1658
1659 sub GetHardDueDate {
1660     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1661
1662     my $rules = Koha::CirculationRules->get_effective_rules(
1663         {
1664             categorycode => $borrowertype,
1665             itemtype     => $itemtype,
1666             branchcode   => $branchcode,
1667             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1668         }
1669     );
1670
1671     if ( defined( $rules->{hardduedate} ) ) {
1672         if ( $rules->{hardduedate} ) {
1673             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1674         }
1675         else {
1676             return ( undef, undef );
1677         }
1678     }
1679 }
1680
1681 =head2 GetBranchBorrowerCircRule
1682
1683   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1684
1685 Retrieves circulation rule attributes that apply to the given
1686 branch and patron category, regardless of item type.
1687 The return value is a hashref containing the following key:
1688
1689 patron_maxissueqty - maximum number of loans that a
1690 patron of the given category can have at the given
1691 branch.  If the value is undef, no limit.
1692
1693 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1694 patron of the given category can have at the given
1695 branch.  If the value is undef, no limit.
1696
1697 This will check for different branch/category combinations in the following order:
1698 branch and category
1699 branch only
1700 category only
1701 default branch and category
1702
1703 If no rule has been found in the database, it will default to
1704 the buillt in rule:
1705
1706 patron_maxissueqty - undef
1707 patron_maxonsiteissueqty - undef
1708
1709 C<$branchcode> and C<$categorycode> should contain the
1710 literal branch code and patron category code, respectively - no
1711 wildcards.
1712
1713 =cut
1714
1715 sub GetBranchBorrowerCircRule {
1716     my ( $branchcode, $categorycode ) = @_;
1717
1718     # Initialize default values
1719     my $rules = {
1720         patron_maxissueqty       => undef,
1721         patron_maxonsiteissueqty => undef,
1722     };
1723
1724     # Search for rules!
1725     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1726         my $rule = Koha::CirculationRules->get_effective_rule(
1727             {
1728                 categorycode => $categorycode,
1729                 itemtype     => undef,
1730                 branchcode   => $branchcode,
1731                 rule_name    => $rule_name,
1732             }
1733         );
1734
1735         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1736     }
1737
1738     return $rules;
1739 }
1740
1741 =head2 GetBranchItemRule
1742
1743   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1744
1745 Retrieves circulation rule attributes that apply to the given
1746 branch and item type, regardless of patron category.
1747
1748 The return value is a hashref containing the following keys:
1749
1750 holdallowed => Hold policy for this branch and itemtype. Possible values:
1751   0: No holds allowed.
1752   1: Holds allowed only by patrons that have the same homebranch as the item.
1753   2: Holds allowed from any patron.
1754
1755 returnbranch => branch to which to return item.  Possible values:
1756   noreturn: do not return, let item remain where checked in (floating collections)
1757   homebranch: return to item's home branch
1758   holdingbranch: return to issuer branch
1759
1760 This searches branchitemrules in the following order:
1761
1762   * Same branchcode and itemtype
1763   * Same branchcode, itemtype '*'
1764   * branchcode '*', same itemtype
1765   * branchcode and itemtype '*'
1766
1767 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1768
1769 =cut
1770
1771 sub GetBranchItemRule {
1772     my ( $branchcode, $itemtype ) = @_;
1773
1774     # Search for rules!
1775     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1776         {
1777             branchcode => $branchcode,
1778             itemtype => $itemtype,
1779             rule_name => 'holdallowed',
1780         }
1781     );
1782     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1783         {
1784             branchcode => $branchcode,
1785             itemtype => $itemtype,
1786             rule_name => 'hold_fulfillment_policy',
1787         }
1788     );
1789     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1790         {
1791             branchcode => $branchcode,
1792             itemtype => $itemtype,
1793             rule_name => 'returnbranch',
1794         }
1795     );
1796
1797     # built-in default circulation rule
1798     my $rules;
1799     $rules->{holdallowed} = defined $holdallowed_rule
1800         ? $holdallowed_rule->rule_value
1801         : 2;
1802     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1803         ? $hold_fulfillment_policy_rule->rule_value
1804         : 'any';
1805     $rules->{returnbranch} = defined $returnbranch_rule
1806         ? $returnbranch_rule->rule_value
1807         : 'homebranch';
1808
1809     return $rules;
1810 }
1811
1812 =head2 AddReturn
1813
1814   ($doreturn, $messages, $iteminformation, $borrower) =
1815       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1816
1817 Returns a book.
1818
1819 =over 4
1820
1821 =item C<$barcode> is the bar code of the book being returned.
1822
1823 =item C<$branch> is the code of the branch where the book is being returned.
1824
1825 =item C<$exemptfine> indicates that overdue charges for the item will be
1826 removed. Optional.
1827
1828 =item C<$return_date> allows the default return date to be overridden
1829 by the given return date. Optional.
1830
1831 =back
1832
1833 C<&AddReturn> returns a list of four items:
1834
1835 C<$doreturn> is true iff the return succeeded.
1836
1837 C<$messages> is a reference-to-hash giving feedback on the operation.
1838 The keys of the hash are:
1839
1840 =over 4
1841
1842 =item C<BadBarcode>
1843
1844 No item with this barcode exists. The value is C<$barcode>.
1845
1846 =item C<NotIssued>
1847
1848 The book is not currently on loan. The value is C<$barcode>.
1849
1850 =item C<withdrawn>
1851
1852 This book has been withdrawn/cancelled. The value should be ignored.
1853
1854 =item C<Wrongbranch>
1855
1856 This book has was returned to the wrong branch.  The value is a hashref
1857 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1858 contain the branchcode of the incorrect and correct return library, respectively.
1859
1860 =item C<ResFound>
1861
1862 The item was reserved. The value is a reference-to-hash whose keys are
1863 fields from the reserves table of the Koha database, and
1864 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1865 either C<Waiting>, C<Reserved>, or 0.
1866
1867 =item C<WasReturned>
1868
1869 Value 1 if return is successful.
1870
1871 =item C<NeedsTransfer>
1872
1873 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1874
1875 =back
1876
1877 C<$iteminformation> is a reference-to-hash, giving information about the
1878 returned item from the issues table.
1879
1880 C<$borrower> is a reference-to-hash, giving information about the
1881 patron who last borrowed the book.
1882
1883 =cut
1884
1885 sub AddReturn {
1886     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1887
1888     if ($branch and not Koha::Libraries->find($branch)) {
1889         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1890         undef $branch;
1891     }
1892     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1893     my $return_date_specified = !!$return_date;
1894     $return_date //= dt_from_string();
1895     my $messages;
1896     my $patron;
1897     my $doreturn       = 1;
1898     my $validTransfer = 1;
1899     my $stat_type = 'return';
1900
1901     # get information on item
1902     my $item = Koha::Items->find({ barcode => $barcode });
1903     unless ($item) {
1904         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1905     }
1906
1907     my $itemnumber = $item->itemnumber;
1908     my $itemtype = $item->effective_itemtype;
1909
1910     my $issue  = $item->checkout;
1911     if ( $issue ) {
1912         $patron = $issue->patron
1913             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1914                 . Dumper($issue->unblessed) . "\n";
1915     } else {
1916         $messages->{'NotIssued'} = $barcode;
1917         $item->onloan(undef)->store({skip_record_index=>1}) if defined $item->onloan;
1918
1919         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1920         $doreturn = 0;
1921         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1922         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1923         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1924            $messages->{'LocalUse'} = 1;
1925            $stat_type = 'localuse';
1926         }
1927     }
1928
1929         # full item data, but no borrowernumber or checkout info (no issue)
1930     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1931         # get the proper branch to which to return the item
1932     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
1933         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1934     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
1935
1936     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1937     my $patron_unblessed = $patron ? $patron->unblessed : {};
1938
1939     my $update_loc_rules = get_yaml_pref_hash('UpdateItemLocationOnCheckin');
1940     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
1941     if ($update_loc_rules) {
1942         if (defined $update_loc_rules->{_ALL_}) {
1943             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
1944             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
1945             if ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) {
1946                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
1947                 $item->location($update_loc_rules->{_ALL_})->store({skip_record_index=>1});
1948             }
1949         }
1950         else {
1951             foreach my $key ( keys %$update_loc_rules ) {
1952                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
1953                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
1954                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
1955                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
1956                     $item->location($update_loc_rules->{$key})->store({skip_record_index=>1});
1957                     last;
1958                 }
1959             }
1960         }
1961     }
1962
1963     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1964     if ($yaml) {
1965         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1966         my $rules;
1967         eval { $rules = YAML::Load($yaml); };
1968         if ($@) {
1969             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1970         }
1971         else {
1972             foreach my $key ( keys %$rules ) {
1973                 if ( $item->notforloan eq $key ) {
1974                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
1975                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
1976                     last;
1977                 }
1978             }
1979         }
1980     }
1981
1982     # check if the return is allowed at this branch
1983     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
1984     unless ($returnallowed){
1985         $messages->{'Wrongbranch'} = {
1986             Wrongbranch => $branch,
1987             Rightbranch => $message
1988         };
1989         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
1990         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
1991         return ( $doreturn, $messages, $issue, $patron_unblessed);
1992     }
1993
1994     if ( $item->withdrawn ) { # book has been cancelled
1995         $messages->{'withdrawn'} = 1;
1996         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1997     }
1998
1999     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2000         $doreturn = 0;
2001     }
2002
2003     # case of a return of document (deal with issues and holdingbranch)
2004     if ($doreturn) {
2005         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2006         $patron or warn "AddReturn without current borrower";
2007
2008         if ($patron) {
2009             eval {
2010                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1} );
2011             };
2012             unless ( $@ ) {
2013                 if (
2014                     (
2015                         C4::Context->preference('CalculateFinesOnReturn')
2016                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2017                     )
2018                     && !$item->itemlost
2019                   )
2020                 {
2021                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2022                 }
2023             } else {
2024                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
2025
2026                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2027                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2028
2029                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2030             }
2031
2032             # FIXME is the "= 1" right?  This could be the borrower hash.
2033             $messages->{'WasReturned'} = 1;
2034
2035         } else {
2036             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1 });
2037         }
2038     }
2039
2040     # the holdingbranch is updated if the document is returned to another location.
2041     # this is always done regardless of whether the item was on loan or not
2042     if ($item->holdingbranch ne $branch) {
2043         $item->holdingbranch($branch)->store({ skip_record_index => 1 });
2044     }
2045
2046     my $item_was_lost = $item->itemlost;
2047     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2048     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1 } ); # will unset itemlost if needed
2049
2050     # fix up the accounts.....
2051     if ( $item_was_lost ) {
2052         $messages->{'WasLost'} = 1;
2053         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2054             $messages->{'LostItemFeeRefunded'} = $updated_item->{_refunded};
2055         }
2056     }
2057
2058     # check if we have a transfer for this document
2059     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
2060
2061     # if we have a transfer to complete, we update the line of transfers with the datearrived
2062     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
2063     if ($datesent) {
2064         # At this point we will either fill the transfer or it is a wrong transfer
2065         # either way we should not now generate a new transfer
2066         $validTransfer = 0;
2067         if ( $tobranch eq $branch ) {
2068             my $sth = C4::Context->dbh->prepare(
2069                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
2070             );
2071             $sth->execute( $item->itemnumber );
2072             $messages->{'TransferArrived'} = $frombranch;
2073         } else {
2074             $messages->{'WrongTransfer'}     = $tobranch;
2075             $messages->{'WrongTransferItem'} = $item->itemnumber;
2076         }
2077     }
2078
2079     # fix up the overdues in accounts...
2080     if ($borrowernumber) {
2081         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2082         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2083
2084         if ( $issue and $issue->is_overdue($return_date) ) {
2085         # fix fine days
2086             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2087             if ($reminder){
2088                 $messages->{'PrevDebarred'} = $debardate;
2089             } else {
2090                 $messages->{'Debarred'} = $debardate if $debardate;
2091             }
2092         # there's no overdue on the item but borrower had been previously debarred
2093         } elsif ( $issue->date_due and $patron->debarred ) {
2094              if ( $patron->debarred eq "9999-12-31") {
2095                 $messages->{'ForeverDebarred'} = $patron->debarred;
2096              } else {
2097                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2098                   $borrower_debar_dt->truncate(to => 'day');
2099                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2100                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2101                       $messages->{'PrevDebarred'} = $patron->debarred;
2102                   }
2103              }
2104         }
2105     }
2106
2107     # find reserves.....
2108     # launch the Checkreserves routine to find any holds
2109     my ($resfound, $resrec);
2110     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2111     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2112     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2113     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2114         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2115         $resfound = 'Reserved';
2116         $resrec = $hold->unblessed;
2117     }
2118     if ($resfound) {
2119           $resrec->{'ResFound'} = $resfound;
2120         $messages->{'ResFound'} = $resrec;
2121     }
2122
2123     # Record the fact that this book was returned.
2124     UpdateStats({
2125         branch         => $branch,
2126         type           => $stat_type,
2127         itemnumber     => $itemnumber,
2128         itemtype       => $itemtype,
2129         location       => $item->location,
2130         borrowernumber => $borrowernumber,
2131         ccode          => $item->ccode,
2132     });
2133
2134     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2135     if ( $patron ) {
2136         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2137         my %conditions = (
2138             branchcode   => $branch,
2139             categorycode => $patron->categorycode,
2140             item_type    => $itemtype,
2141             notification => 'CHECKIN',
2142         );
2143         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2144             SendCirculationAlert({
2145                 type     => 'CHECKIN',
2146                 item     => $item->unblessed,
2147                 borrower => $patron->unblessed,
2148                 branch   => $branch,
2149             });
2150         }
2151
2152         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2153             if C4::Context->preference("ReturnLog");
2154         }
2155
2156     # Check if this item belongs to a biblio record that is attached to an
2157     # ILL request, if it is we need to update the ILL request's status
2158     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2159         my $request = Koha::Illrequests->find(
2160             { biblio_id => $item->biblio->biblionumber }
2161         );
2162         $request->status('RET') if $request;
2163     }
2164
2165     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2166     if ($validTransfer && !$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) ){
2167         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2168         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2169             (C4::Context->preference("UseBranchTransferLimits") and
2170              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2171            )) {
2172             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s, %s)", $item->itemnumber,$branch, $returnbranch, $transfer_trigger;
2173             $debug and warn "item: " . Dumper($item->unblessed);
2174             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2175             $messages->{'WasTransfered'} = 1;
2176         } else {
2177             $messages->{'NeedsTransfer'} = $returnbranch;
2178             $messages->{'TransferTrigger'} = $transfer_trigger;
2179         }
2180     }
2181
2182     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2183         my $claims = Koha::Checkouts::ReturnClaims->search(
2184            {
2185                itemnumber => $item->id,
2186                resolution => undef,
2187            }
2188         );
2189
2190         if ( $claims->count ) {
2191             $messages->{ReturnClaims} = $claims;
2192         }
2193     }
2194
2195     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2196     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2197
2198     if ( $doreturn and $issue ) {
2199         my $checkin = Koha::Old::Checkouts->find($issue->id);
2200
2201         Koha::Plugins->call('after_circ_action', {
2202             action  => 'checkin',
2203             payload => {
2204                 checkout=> $checkin
2205             }
2206         });
2207     }
2208
2209     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2210 }
2211
2212 =head2 MarkIssueReturned
2213
2214   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2215
2216 Unconditionally marks an issue as being returned by
2217 moving the C<issues> row to C<old_issues> and
2218 setting C<returndate> to the current date.
2219
2220 if C<$returndate> is specified (in iso format), it is used as the date
2221 of the return.
2222
2223 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2224 the old_issue is immediately anonymised
2225
2226 Ideally, this function would be internal to C<C4::Circulation>,
2227 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2228 and offline_circ/process_koc.pl.
2229
2230 The last optional parameter allos passing skip_record_index to the item store call.
2231
2232 =cut
2233
2234 sub MarkIssueReturned {
2235     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2236
2237     # Retrieve the issue
2238     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2239
2240     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2241
2242     my $issue_id = $issue->issue_id;
2243
2244     my $anonymouspatron;
2245     if ( $privacy && $privacy == 2 ) {
2246         # The default of 0 will not work due to foreign key constraints
2247         # The anonymisation will fail if AnonymousPatron is not a valid entry
2248         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2249         # Note that a warning should appear on the about page (System information tab).
2250         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2251         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2252             unless Koha::Patrons->find( $anonymouspatron );
2253     }
2254
2255     my $schema = Koha::Database->schema;
2256
2257     # FIXME Improve the return value and handle it from callers
2258     $schema->txn_do(sub {
2259
2260         my $patron = Koha::Patrons->find( $borrowernumber );
2261
2262         # Update the returndate value
2263         if ( $returndate ) {
2264             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2265         }
2266         else {
2267             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2268         }
2269
2270         # Create the old_issues entry
2271         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2272
2273         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2274         if ( $privacy && $privacy == 2) {
2275             $old_checkout->borrowernumber($anonymouspatron)->store;
2276         }
2277
2278         # And finally delete the issue
2279         $issue->delete;
2280
2281         $issue->item->onloan(undef)->store({ log_action => 0, skip_record_index => $params->{skip_record_index} });
2282
2283         if ( C4::Context->preference('StoreLastBorrower') ) {
2284             my $item = Koha::Items->find( $itemnumber );
2285             $item->last_returned_by( $patron );
2286         }
2287
2288         # Remove any OVERDUES related debarment if the borrower has no overdues
2289         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2290           && $patron->debarred
2291           && !$patron->has_overdues
2292           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2293         ) {
2294             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2295         }
2296
2297     });
2298
2299     return $issue_id;
2300 }
2301
2302 =head2 _debar_user_on_return
2303
2304     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2305
2306 C<$borrower> borrower hashref
2307
2308 C<$item> item hashref
2309
2310 C<$datedue> date due DateTime object
2311
2312 C<$returndate> DateTime object representing the return time
2313
2314 Internal function, called only by AddReturn that calculates and updates
2315  the user fine days, and debars them if necessary.
2316
2317 Should only be called for overdue returns
2318
2319 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2320 to ease testing.
2321
2322 =cut
2323
2324 sub _calculate_new_debar_dt {
2325     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2326
2327     my $branchcode = _GetCircControlBranch( $item, $borrower );
2328     my $circcontrol = C4::Context->preference('CircControl');
2329     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2330         {   categorycode => $borrower->{categorycode},
2331             itemtype     => $item->{itype},
2332             branchcode   => $branchcode,
2333             rules => [
2334                 'finedays',
2335                 'lengthunit',
2336                 'firstremind',
2337                 'maxsuspensiondays',
2338                 'suspension_chargeperiod',
2339             ]
2340         }
2341     );
2342     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2343     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2344     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2345
2346     return unless $finedays;
2347
2348     # finedays is in days, so hourly loans must multiply by 24
2349     # thus 1 hour late equals 1 day suspension * finedays rate
2350     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2351
2352     # grace period is measured in the same units as the loan
2353     my $grace =
2354       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} );
2355
2356     my $deltadays = DateTime::Duration->new(
2357         days => $chargeable_units
2358     );
2359
2360     if ( $deltadays->subtract($grace)->is_positive() ) {
2361         my $suspension_days = $deltadays * $finedays;
2362
2363         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2364             # No need to / 1 and do not consider / 0
2365             $suspension_days = DateTime::Duration->new(
2366                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2367             );
2368         }
2369
2370         # If the max suspension days is < than the suspension days
2371         # the suspension days is limited to this maximum period.
2372         my $max_sd = $issuing_rule->{maxsuspensiondays};
2373         if ( defined $max_sd && $max_sd ne '' ) {
2374             $max_sd = DateTime::Duration->new( days => $max_sd );
2375             $suspension_days = $max_sd
2376               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2377         }
2378
2379         my ( $has_been_extended );
2380         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2381             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2382             if ( $debarment ) {
2383                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2384                 $has_been_extended = 1;
2385             }
2386         }
2387
2388         my $new_debar_dt;
2389         # Use the calendar or not to calculate the debarment date
2390         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2391             my $calendar = Koha::Calendar->new(
2392                 branchcode => $branchcode,
2393                 days_mode  => 'Calendar'
2394             );
2395             $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2396         }
2397         else {
2398             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2399         }
2400         return $new_debar_dt;
2401     }
2402     return;
2403 }
2404
2405 sub _debar_user_on_return {
2406     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2407
2408     $return_date //= dt_from_string();
2409
2410     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2411
2412     return unless $new_debar_dt;
2413
2414     Koha::Patron::Debarments::AddUniqueDebarment({
2415         borrowernumber => $borrower->{borrowernumber},
2416         expiration     => $new_debar_dt->ymd(),
2417         type           => 'SUSPENSION',
2418     });
2419     # if borrower was already debarred but does not get an extra debarment
2420     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2421     my ($new_debarment_str, $is_a_reminder);
2422     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2423         $is_a_reminder = 1;
2424         $new_debarment_str = $borrower->{debarred};
2425     } else {
2426         $new_debarment_str = $new_debar_dt->ymd();
2427     }
2428     # FIXME Should return a DateTime object
2429     return $new_debarment_str, $is_a_reminder;
2430 }
2431
2432 =head2 _FixOverduesOnReturn
2433
2434    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2435
2436 C<$borrowernumber> borrowernumber
2437
2438 C<$itemnumber> itemnumber
2439
2440 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2441
2442 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2443
2444 Internal function
2445
2446 =cut
2447
2448 sub _FixOverduesOnReturn {
2449     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2450     unless( $borrowernumber ) {
2451         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2452         return;
2453     }
2454     unless( $item ) {
2455         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2456         return;
2457     }
2458     unless( $status ) {
2459         warn "_FixOverduesOnReturn() not supplied valid status";
2460         return;
2461     }
2462
2463     my $schema = Koha::Database->schema;
2464
2465     my $result = $schema->txn_do(
2466         sub {
2467             # check for overdue fine
2468             my $accountlines = Koha::Account::Lines->search(
2469                 {
2470                     borrowernumber  => $borrowernumber,
2471                     itemnumber      => $item,
2472                     debit_type_code => 'OVERDUE',
2473                     status          => 'UNRETURNED'
2474                 }
2475             );
2476             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2477
2478             my $accountline = $accountlines->next;
2479             my $payments = $accountline->credits;
2480
2481             my $amountoutstanding = $accountline->amountoutstanding;
2482             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2483                 $accountline->delete;
2484             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2485                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2486                 my $credit = $account->add_credit(
2487                     {
2488                         amount     => $amountoutstanding,
2489                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2490                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2491                         interface  => C4::Context->interface,
2492                         type       => 'FORGIVEN',
2493                         item_id    => $item
2494                     }
2495                 );
2496
2497                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2498
2499                 if (C4::Context->preference("FinesLog")) {
2500                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2501                 }
2502
2503                 $accountline->status('FORGIVEN');
2504                 $accountline->store();
2505             } else {
2506                 $accountline->status($status);
2507                 $accountline->store();
2508
2509             }
2510         }
2511     );
2512
2513     return $result;
2514 }
2515
2516 =head2 _GetCircControlBranch
2517
2518    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2519
2520 Internal function :
2521
2522 Return the library code to be used to determine which circulation
2523 policy applies to a transaction.  Looks up the CircControl and
2524 HomeOrHoldingBranch system preferences.
2525
2526 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2527
2528 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2529
2530 =cut
2531
2532 sub _GetCircControlBranch {
2533     my ($item, $borrower) = @_;
2534     my $circcontrol = C4::Context->preference('CircControl');
2535     my $branch;
2536
2537     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2538         $branch= C4::Context->userenv->{'branch'};
2539     } elsif ($circcontrol eq 'PatronLibrary') {
2540         $branch=$borrower->{branchcode};
2541     } else {
2542         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2543         $branch = $item->{$branchfield};
2544         # default to item home branch if holdingbranch is used
2545         # and is not defined
2546         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2547             $branch = $item->{homebranch};
2548         }
2549     }
2550     return $branch;
2551 }
2552
2553 =head2 GetOpenIssue
2554
2555   $issue = GetOpenIssue( $itemnumber );
2556
2557 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2558
2559 C<$itemnumber> is the item's itemnumber
2560
2561 Returns a hashref
2562
2563 =cut
2564
2565 sub GetOpenIssue {
2566   my ( $itemnumber ) = @_;
2567   return unless $itemnumber;
2568   my $dbh = C4::Context->dbh;
2569   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2570   $sth->execute( $itemnumber );
2571   return $sth->fetchrow_hashref();
2572
2573 }
2574
2575 =head2 GetBiblioIssues
2576
2577   $issues = GetBiblioIssues($biblionumber);
2578
2579 this function get all issues from a biblionumber.
2580
2581 Return:
2582 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2583 tables issues and the firstname,surname & cardnumber from borrowers.
2584
2585 =cut
2586
2587 sub GetBiblioIssues {
2588     my $biblionumber = shift;
2589     return unless $biblionumber;
2590     my $dbh   = C4::Context->dbh;
2591     my $query = "
2592         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2593         FROM issues
2594             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2595             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2596             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2597             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2598         WHERE biblio.biblionumber = ?
2599         UNION ALL
2600         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2601         FROM old_issues
2602             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2603             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2604             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2605             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2606         WHERE biblio.biblionumber = ?
2607         ORDER BY timestamp
2608     ";
2609     my $sth = $dbh->prepare($query);
2610     $sth->execute($biblionumber, $biblionumber);
2611
2612     my @issues;
2613     while ( my $data = $sth->fetchrow_hashref ) {
2614         push @issues, $data;
2615     }
2616     return \@issues;
2617 }
2618
2619 =head2 GetUpcomingDueIssues
2620
2621   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2622
2623 =cut
2624
2625 sub GetUpcomingDueIssues {
2626     my $params = shift;
2627
2628     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2629     my $dbh = C4::Context->dbh;
2630
2631     my $statement = <<END_SQL;
2632 SELECT *
2633 FROM (
2634     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2635     FROM issues
2636     LEFT JOIN items USING (itemnumber)
2637     LEFT OUTER JOIN branches USING (branchcode)
2638     WHERE returndate is NULL
2639 ) tmp
2640 WHERE days_until_due >= 0 AND days_until_due <= ?
2641 END_SQL
2642
2643     my @bind_parameters = ( $params->{'days_in_advance'} );
2644
2645     my $sth = $dbh->prepare( $statement );
2646     $sth->execute( @bind_parameters );
2647     my $upcoming_dues = $sth->fetchall_arrayref({});
2648
2649     return $upcoming_dues;
2650 }
2651
2652 =head2 CanBookBeRenewed
2653
2654   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2655
2656 Find out whether a borrowed item may be renewed.
2657
2658 C<$borrowernumber> is the borrower number of the patron who currently
2659 has the item on loan.
2660
2661 C<$itemnumber> is the number of the item to renew.
2662
2663 C<$override_limit>, if supplied with a true value, causes
2664 the limit on the number of times that the loan can be renewed
2665 (as controlled by the item type) to be ignored. Overriding also allows
2666 to renew sooner than "No renewal before" and to manually renew loans
2667 that are automatically renewed.
2668
2669 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2670 item must currently be on loan to the specified borrower; renewals
2671 must be allowed for the item's type; and the borrower must not have
2672 already renewed the loan. $error will contain the reason the renewal can not proceed
2673
2674 =cut
2675
2676 sub CanBookBeRenewed {
2677     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2678
2679     my $dbh    = C4::Context->dbh;
2680     my $renews = 1;
2681     my $auto_renew = "no";
2682
2683     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2684     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2685     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2686     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2687
2688     my $patron = $issue->patron or return;
2689
2690     # override_limit will override anything else except on_reserve
2691     unless ( $override_limit ){
2692         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2693         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2694             {
2695                 categorycode => $patron->categorycode,
2696                 itemtype     => $item->effective_itemtype,
2697                 branchcode   => $branchcode,
2698                 rules => [
2699                     'renewalsallowed',
2700                     'no_auto_renewal_after',
2701                     'no_auto_renewal_after_hard_limit',
2702                     'lengthunit',
2703                     'norenewalbefore',
2704                 ]
2705             }
2706         );
2707
2708         return ( 0, "too_many" )
2709           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2710
2711         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2712         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2713         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2714         my $restricted  = $patron->is_debarred;
2715         my $hasoverdues = $patron->has_overdues;
2716
2717         if ( $restricted and $restrictionblockrenewing ) {
2718             return ( 0, 'restriction');
2719         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2720             return ( 0, 'overdue');
2721         }
2722
2723         if ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2724
2725             if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2726                 return ( 0, 'auto_account_expired' );
2727             }
2728
2729             if ( defined $issuing_rule->{no_auto_renewal_after}
2730                     and $issuing_rule->{no_auto_renewal_after} ne "" ) {
2731                 # Get issue_date and add no_auto_renewal_after
2732                 # If this is greater than today, it's too late for renewal.
2733                 my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2734                 $maximum_renewal_date->add(
2735                     $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
2736                 );
2737                 my $now = dt_from_string;
2738                 if ( $now >= $maximum_renewal_date ) {
2739                     return ( 0, "auto_too_late" );
2740                 }
2741             }
2742             if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
2743                           and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
2744                 # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2745                 if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
2746                     return ( 0, "auto_too_late" );
2747                 }
2748             }
2749
2750             if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2751                 my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2752                 my $amountoutstanding =
2753                   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2754                   ? $patron->account->balance
2755                   : $patron->account->outstanding_debits->total_outstanding;
2756                 if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2757                     return ( 0, "auto_too_much_oweing" );
2758                 }
2759             }
2760         }
2761
2762         if ( defined $issuing_rule->{norenewalbefore}
2763             and $issuing_rule->{norenewalbefore} ne "" )
2764         {
2765
2766             # Calculate soonest renewal by subtracting 'No renewal before' from due date
2767             my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2768                 $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
2769
2770             # Depending on syspref reset the exact time, only check the date
2771             if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2772                 and $issuing_rule->{lengthunit} eq 'days' )
2773             {
2774                 $soonestrenewal->truncate( to => 'day' );
2775             }
2776
2777             if ( $soonestrenewal > dt_from_string() )
2778             {
2779                 $auto_renew = ($issue->auto_renew && $patron->autorenew_checkouts) ? "auto_too_soon" : "too_soon";
2780             }
2781             elsif ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2782                 $auto_renew = "ok";
2783             }
2784         }
2785
2786         # Fallback for automatic renewals:
2787         # If norenewalbefore is undef, don't renew before due date.
2788         if ( $issue->auto_renew && $auto_renew eq "no" && $patron->autorenew_checkouts ) {
2789             my $now = dt_from_string;
2790             if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
2791                 $auto_renew = "ok";
2792             } else {
2793                 $auto_renew = "auto_too_soon";
2794             }
2795         }
2796     }
2797
2798     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2799
2800     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2801     if ( $resfound && $resrec->{non_priority} ) {
2802         $resfound = Koha::Holds->search(
2803             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2804           ->count > 0;
2805     }
2806
2807
2808
2809     # This item can fill one or more unfilled reserve, can those unfilled reserves
2810     # all be filled by other available items?
2811     if ( $resfound
2812         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2813     {
2814         my $schema = Koha::Database->new()->schema();
2815
2816         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2817         if ($item_holds) {
2818             # There is an item level hold on this item, no other item can fill the hold
2819             $resfound = 1;
2820         }
2821         else {
2822
2823             # Get all other items that could possibly fill reserves
2824             my @itemnumbers = $schema->resultset('Item')->search(
2825                 {
2826                     biblionumber => $resrec->{biblionumber},
2827                     onloan       => undef,
2828                     notforloan   => 0,
2829                     -not         => { itemnumber => $itemnumber }
2830                 },
2831                 { columns => 'itemnumber' }
2832             )->get_column('itemnumber')->all();
2833
2834             # Get all other reserves that could have been filled by this item
2835             my @borrowernumbers;
2836             while (1) {
2837                 my ( $reserve_found, $reserve, undef ) =
2838                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2839
2840                 if ($reserve_found) {
2841                     push( @borrowernumbers, $reserve->{borrowernumber} );
2842                 }
2843                 else {
2844                     last;
2845                 }
2846             }
2847
2848             # If the count of the union of the lists of reservable items for each borrower
2849             # is equal or greater than the number of borrowers, we know that all reserves
2850             # can be filled with available items. We can get the union of the sets simply
2851             # by pushing all the elements onto an array and removing the duplicates.
2852             my @reservable;
2853             my %patrons;
2854             ITEM: foreach my $itemnumber (@itemnumbers) {
2855                 my $item = Koha::Items->find( $itemnumber );
2856                 next if IsItemOnHoldAndFound( $itemnumber );
2857                 for my $borrowernumber (@borrowernumbers) {
2858                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2859                     next unless IsAvailableForItemLevelRequest($item, $patron);
2860                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2861
2862                     push @reservable, $itemnumber;
2863                     if (@reservable >= @borrowernumbers) {
2864                         $resfound = 0;
2865                         last ITEM;
2866                     }
2867                     last;
2868                 }
2869             }
2870         }
2871     }
2872     if( $cron ) { #The cron wants to return 'too_soon' over 'on_reserve'
2873         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2874         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2875     } else { # For other purposes we want 'on_reserve' before 'too_soon'
2876         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2877         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2878     }
2879
2880     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
2881
2882     return ( 1, undef );
2883 }
2884
2885 =head2 AddRenewal
2886
2887   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2888
2889 Renews a loan.
2890
2891 C<$borrowernumber> is the borrower number of the patron who currently
2892 has the item.
2893
2894 C<$itemnumber> is the number of the item to renew.
2895
2896 C<$branch> is the library where the renewal took place (if any).
2897            The library that controls the circ policies for the renewal is retrieved from the issues record.
2898
2899 C<$datedue> can be a DateTime object used to set the due date.
2900
2901 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2902 this parameter is not supplied, lastreneweddate is set to the current date.
2903
2904 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
2905 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
2906 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
2907 syspref)
2908
2909 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2910 from the book's item type.
2911
2912 =cut
2913
2914 sub AddRenewal {
2915     my $borrowernumber  = shift;
2916     my $itemnumber      = shift or return;
2917     my $branch          = shift;
2918     my $datedue         = shift;
2919     my $lastreneweddate = shift || dt_from_string();
2920     my $skipfinecalc    = shift;
2921
2922     my $item_object   = Koha::Items->find($itemnumber) or return;
2923     my $biblio = $item_object->biblio;
2924     my $issue  = $item_object->checkout;
2925     my $item_unblessed = $item_object->unblessed;
2926
2927     my $dbh = C4::Context->dbh;
2928
2929     return unless $issue;
2930
2931     $borrowernumber ||= $issue->borrowernumber;
2932
2933     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2934         carp 'Invalid date passed to AddRenewal.';
2935         return;
2936     }
2937
2938     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2939     my $patron_unblessed = $patron->unblessed;
2940
2941     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
2942
2943     my $schema = Koha::Database->schema;
2944     $schema->txn_do(sub{
2945
2946         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
2947             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
2948         }
2949         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
2950
2951         # If the due date wasn't specified, calculate it by adding the
2952         # book's loan length to today's date or the current due date
2953         # based on the value of the RenewalPeriodBase syspref.
2954         my $itemtype = $item_object->effective_itemtype;
2955         unless ($datedue) {
2956
2957             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2958                                             dt_from_string( $issue->date_due, 'sql' ) :
2959                                             dt_from_string();
2960             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
2961         }
2962
2963         my $fees = Koha::Charges::Fees->new(
2964             {
2965                 patron    => $patron,
2966                 library   => $circ_library,
2967                 item      => $item_object,
2968                 from_date => dt_from_string( $issue->date_due, 'sql' ),
2969                 to_date   => dt_from_string($datedue),
2970             }
2971         );
2972
2973         # Update the issues record to have the new due date, and a new count
2974         # of how many times it has been renewed.
2975         my $renews = ( $issue->renewals || 0 ) + 1;
2976         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
2977                                 WHERE borrowernumber=?
2978                                 AND itemnumber=?"
2979         );
2980
2981         $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
2982
2983         # Update the renewal count on the item, and tell zebra to reindex
2984         $renews = ( $item_object->renewals || 0 ) + 1;
2985         $item_object->renewals($renews);
2986         $item_object->onloan($datedue);
2987         $item_object->store({ log_action => 0 });
2988
2989         # Charge a new rental fee, if applicable
2990         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
2991         if ( $charge > 0 ) {
2992             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
2993         }
2994
2995         # Charge a new accumulate rental fee, if applicable
2996         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
2997         if ( $itemtype_object ) {
2998             my $accumulate_charge = $fees->accumulate_rentalcharge();
2999             if ( $accumulate_charge > 0 ) {
3000                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3001             }
3002             $charge += $accumulate_charge;
3003         }
3004
3005         # Send a renewal slip according to checkout alert preferencei
3006         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3007             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3008             my %conditions        = (
3009                 branchcode   => $branch,
3010                 categorycode => $patron->categorycode,
3011                 item_type    => $itemtype,
3012                 notification => 'CHECKOUT',
3013             );
3014             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3015                 SendCirculationAlert(
3016                     {
3017                         type     => 'RENEWAL',
3018                         item     => $item_unblessed,
3019                         borrower => $patron->unblessed,
3020                         branch   => $branch,
3021                     }
3022                 );
3023             }
3024         }
3025
3026         # Remove any OVERDUES related debarment if the borrower has no overdues
3027         if ( $patron
3028           && $patron->is_debarred
3029           && ! $patron->has_overdues
3030           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3031         ) {
3032             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3033         }
3034
3035         # Add the renewal to stats
3036         UpdateStats(
3037             {
3038                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3039                 type           => 'renew',
3040                 amount         => $charge,
3041                 itemnumber     => $itemnumber,
3042                 itemtype       => $itemtype,
3043                 location       => $item_object->location,
3044                 borrowernumber => $borrowernumber,
3045                 ccode          => $item_object->ccode,
3046             }
3047         );
3048
3049         #Log the renewal
3050         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3051
3052         Koha::Plugins->call('after_circ_action', {
3053             action  => 'renewal',
3054             payload => {
3055                 checkout  => $issue->get_from_storage
3056             }
3057         });
3058     });
3059
3060     return $datedue;
3061 }
3062
3063 sub GetRenewCount {
3064     # check renewal status
3065     my ( $bornum, $itemno ) = @_;
3066     my $dbh           = C4::Context->dbh;
3067     my $renewcount    = 0;
3068     my $renewsallowed = 0;
3069     my $renewsleft    = 0;
3070
3071     my $patron = Koha::Patrons->find( $bornum );
3072     my $item   = Koha::Items->find($itemno);
3073
3074     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3075
3076     # Look in the issues table for this item, lent to this borrower,
3077     # and not yet returned.
3078
3079     # FIXME - I think this function could be redone to use only one SQL call.
3080     my $sth = $dbh->prepare(
3081         "select * from issues
3082                                 where (borrowernumber = ?)
3083                                 and (itemnumber = ?)"
3084     );
3085     $sth->execute( $bornum, $itemno );
3086     my $data = $sth->fetchrow_hashref;
3087     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3088     # $item and $borrower should be calculated
3089     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3090
3091     my $rule = Koha::CirculationRules->get_effective_rule(
3092         {
3093             categorycode => $patron->categorycode,
3094             itemtype     => $item->effective_itemtype,
3095             branchcode   => $branchcode,
3096             rule_name    => 'renewalsallowed',
3097         }
3098     );
3099
3100     $renewsallowed = $rule ? $rule->rule_value : 0;
3101     $renewsleft    = $renewsallowed - $renewcount;
3102     if($renewsleft < 0){ $renewsleft = 0; }
3103     return ( $renewcount, $renewsallowed, $renewsleft );
3104 }
3105
3106 =head2 GetSoonestRenewDate
3107
3108   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3109
3110 Find out the soonest possible renew date of a borrowed item.
3111
3112 C<$borrowernumber> is the borrower number of the patron who currently
3113 has the item on loan.
3114
3115 C<$itemnumber> is the number of the item to renew.
3116
3117 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3118 renew date, based on the value "No renewal before" of the applicable
3119 issuing rule. Returns the current date if the item can already be
3120 renewed, and returns undefined if the borrower, loan, or item
3121 cannot be found.
3122
3123 =cut
3124
3125 sub GetSoonestRenewDate {
3126     my ( $borrowernumber, $itemnumber ) = @_;
3127
3128     my $dbh = C4::Context->dbh;
3129
3130     my $item      = Koha::Items->find($itemnumber)      or return;
3131     my $itemissue = $item->checkout or return;
3132
3133     $borrowernumber ||= $itemissue->borrowernumber;
3134     my $patron = Koha::Patrons->find( $borrowernumber )
3135       or return;
3136
3137     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3138     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3139         {   categorycode => $patron->categorycode,
3140             itemtype     => $item->effective_itemtype,
3141             branchcode   => $branchcode,
3142             rules => [
3143                 'norenewalbefore',
3144                 'lengthunit',
3145             ]
3146         }
3147     );
3148
3149     my $now = dt_from_string;
3150     return $now unless $issuing_rule;
3151
3152     if ( defined $issuing_rule->{norenewalbefore}
3153         and $issuing_rule->{norenewalbefore} ne "" )
3154     {
3155         my $soonestrenewal =
3156           dt_from_string( $itemissue->date_due )->subtract(
3157             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3158
3159         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3160             and $issuing_rule->{lengthunit} eq 'days' )
3161         {
3162             $soonestrenewal->truncate( to => 'day' );
3163         }
3164         return $soonestrenewal if $now < $soonestrenewal;
3165     }
3166     return $now;
3167 }
3168
3169 =head2 GetLatestAutoRenewDate
3170
3171   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3172
3173 Find out the latest possible auto renew date of a borrowed item.
3174
3175 C<$borrowernumber> is the borrower number of the patron who currently
3176 has the item on loan.
3177
3178 C<$itemnumber> is the number of the item to renew.
3179
3180 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3181 auto renew date, based on the value "No auto renewal after" and the "No auto
3182 renewal after (hard limit) of the applicable issuing rule.
3183 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3184 or item cannot be found.
3185
3186 =cut
3187
3188 sub GetLatestAutoRenewDate {
3189     my ( $borrowernumber, $itemnumber ) = @_;
3190
3191     my $dbh = C4::Context->dbh;
3192
3193     my $item      = Koha::Items->find($itemnumber)  or return;
3194     my $itemissue = $item->checkout                 or return;
3195
3196     $borrowernumber ||= $itemissue->borrowernumber;
3197     my $patron = Koha::Patrons->find( $borrowernumber )
3198       or return;
3199
3200     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3201     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3202         {
3203             categorycode => $patron->categorycode,
3204             itemtype     => $item->effective_itemtype,
3205             branchcode   => $branchcode,
3206             rules => [
3207                 'no_auto_renewal_after',
3208                 'no_auto_renewal_after_hard_limit',
3209                 'lengthunit',
3210             ]
3211         }
3212     );
3213
3214     return unless $circulation_rules;
3215     return
3216       if ( not $circulation_rules->{no_auto_renewal_after}
3217             or $circulation_rules->{no_auto_renewal_after} eq '' )
3218       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3219              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3220
3221     my $maximum_renewal_date;
3222     if ( $circulation_rules->{no_auto_renewal_after} ) {
3223         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3224         $maximum_renewal_date->add(
3225             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3226         );
3227     }
3228
3229     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3230         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3231         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3232     }
3233     return $maximum_renewal_date;
3234 }
3235
3236
3237 =head2 GetIssuingCharges
3238
3239   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3240
3241 Calculate how much it would cost for a given patron to borrow a given
3242 item, including any applicable discounts.
3243
3244 C<$itemnumber> is the item number of item the patron wishes to borrow.
3245
3246 C<$borrowernumber> is the patron's borrower number.
3247
3248 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3249 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3250 if it's a video).
3251
3252 =cut
3253
3254 sub GetIssuingCharges {
3255
3256     # calculate charges due
3257     my ( $itemnumber, $borrowernumber ) = @_;
3258     my $charge = 0;
3259     my $dbh    = C4::Context->dbh;
3260     my $item_type;
3261
3262     # Get the book's item type and rental charge (via its biblioitem).
3263     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3264         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3265     $charge_query .= (C4::Context->preference('item-level_itypes'))
3266         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3267         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3268
3269     $charge_query .= ' WHERE items.itemnumber =?';
3270
3271     my $sth = $dbh->prepare($charge_query);
3272     $sth->execute($itemnumber);
3273     if ( my $item_data = $sth->fetchrow_hashref ) {
3274         $item_type = $item_data->{itemtype};
3275         $charge    = $item_data->{rentalcharge};
3276         my $branch = C4::Context::mybranch();
3277         my $patron = Koha::Patrons->find( $borrowernumber );
3278         my $discount = _get_discount_from_rule($patron->categorycode, $branch, $item_type);
3279         if ($discount) {
3280             # We may have multiple rules so get the most specific
3281             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3282         }
3283         if ($charge) {
3284             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3285         }
3286     }
3287
3288     return ( $charge, $item_type );
3289 }
3290
3291 # Select most appropriate discount rule from those returned
3292 sub _get_discount_from_rule {
3293     my ($categorycode, $branchcode, $itemtype) = @_;
3294
3295     # Set search precedences
3296     my @params = (
3297         {
3298             branchcode   => $branchcode,
3299             itemtype     => $itemtype,
3300             categorycode => $categorycode,
3301         },
3302         {
3303             branchcode   => undef,
3304             categorycode => $categorycode,
3305             itemtype     => $itemtype,
3306         },
3307         {
3308             branchcode   => $branchcode,
3309             categorycode => $categorycode,
3310             itemtype     => undef,
3311         },
3312         {
3313             branchcode   => undef,
3314             categorycode => $categorycode,
3315             itemtype     => undef,
3316         },
3317     );
3318
3319     foreach my $params (@params) {
3320         my $rule = Koha::CirculationRules->search(
3321             {
3322                 rule_name => 'rentaldiscount',
3323                 %$params,
3324             }
3325         )->next();
3326
3327         return $rule->rule_value if $rule;
3328     }
3329
3330     # none of the above
3331     return 0;
3332 }
3333
3334 =head2 AddIssuingCharge
3335
3336   &AddIssuingCharge( $checkout, $charge, $type )
3337
3338 =cut
3339
3340 sub AddIssuingCharge {
3341     my ( $checkout, $charge, $type ) = @_;
3342
3343     # FIXME What if checkout does not exist?
3344
3345     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3346     my $accountline = $account->add_debit(
3347         {
3348             amount      => $charge,
3349             note        => undef,
3350             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3351             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3352             interface   => C4::Context->interface,
3353             type        => $type,
3354             item_id     => $checkout->itemnumber,
3355             issue_id    => $checkout->issue_id,
3356         }
3357     );
3358 }
3359
3360 =head2 GetTransfers
3361
3362   GetTransfers($itemnumber);
3363
3364 =cut
3365
3366 sub GetTransfers {
3367     my ($itemnumber) = @_;
3368
3369     my $dbh = C4::Context->dbh;
3370
3371     my $query = '
3372         SELECT datesent,
3373                frombranch,
3374                tobranch,
3375                branchtransfer_id
3376         FROM branchtransfers
3377         WHERE itemnumber = ?
3378           AND datearrived IS NULL
3379         ';
3380     my $sth = $dbh->prepare($query);
3381     $sth->execute($itemnumber);
3382     my @row = $sth->fetchrow_array();
3383     return @row;
3384 }
3385
3386 =head2 GetTransfersFromTo
3387
3388   @results = GetTransfersFromTo($frombranch,$tobranch);
3389
3390 Returns the list of pending transfers between $from and $to branch
3391
3392 =cut
3393
3394 sub GetTransfersFromTo {
3395     my ( $frombranch, $tobranch ) = @_;
3396     return unless ( $frombranch && $tobranch );
3397     my $dbh   = C4::Context->dbh;
3398     my $query = "
3399         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3400         FROM   branchtransfers
3401         WHERE  frombranch=?
3402           AND  tobranch=?
3403           AND datearrived IS NULL
3404     ";
3405     my $sth = $dbh->prepare($query);
3406     $sth->execute( $frombranch, $tobranch );
3407     my @gettransfers;
3408
3409     while ( my $data = $sth->fetchrow_hashref ) {
3410         push @gettransfers, $data;
3411     }
3412     return (@gettransfers);
3413 }
3414
3415 =head2 DeleteTransfer
3416
3417   &DeleteTransfer($itemnumber);
3418
3419 =cut
3420
3421 sub DeleteTransfer {
3422     my ($itemnumber) = @_;
3423     return unless $itemnumber;
3424     my $dbh          = C4::Context->dbh;
3425     my $sth          = $dbh->prepare(
3426         "DELETE FROM branchtransfers
3427          WHERE itemnumber=?
3428          AND datearrived IS NULL "
3429     );
3430     return $sth->execute($itemnumber);
3431 }
3432
3433 =head2 SendCirculationAlert
3434
3435 Send out a C<check-in> or C<checkout> alert using the messaging system.
3436
3437 B<Parameters>:
3438
3439 =over 4
3440
3441 =item type
3442
3443 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3444
3445 =item item
3446
3447 Hashref of information about the item being checked in or out.
3448
3449 =item borrower
3450
3451 Hashref of information about the borrower of the item.
3452
3453 =item branch
3454
3455 The branchcode from where the checkout or check-in took place.
3456
3457 =back
3458
3459 B<Example>:
3460
3461     SendCirculationAlert({
3462         type     => 'CHECKOUT',
3463         item     => $item,
3464         borrower => $borrower,
3465         branch   => $branch,
3466     });
3467
3468 =cut
3469
3470 sub SendCirculationAlert {
3471     my ($opts) = @_;
3472     my ($type, $item, $borrower, $branch) =
3473         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3474     my %message_name = (
3475         CHECKIN  => 'Item_Check_in',
3476         CHECKOUT => 'Item_Checkout',
3477         RENEWAL  => 'Item_Checkout',
3478     );
3479     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3480         borrowernumber => $borrower->{borrowernumber},
3481         message_name   => $message_name{$type},
3482     });
3483     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3484
3485     my $schema = Koha::Database->new->schema;
3486     my @transports = keys %{ $borrower_preferences->{transports} };
3487
3488     # From the MySQL doc:
3489     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3490     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3491     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3492     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3493
3494     for my $mtt (@transports) {
3495         my $letter =  C4::Letters::GetPreparedLetter (
3496             module => 'circulation',
3497             letter_code => $type,
3498             branchcode => $branch,
3499             message_transport_type => $mtt,
3500             lang => $borrower->{lang},
3501             tables => {
3502                 $issues_table => $item->{itemnumber},
3503                 'items'       => $item->{itemnumber},
3504                 'biblio'      => $item->{biblionumber},
3505                 'biblioitems' => $item->{biblionumber},
3506                 'borrowers'   => $borrower,
3507                 'branches'    => $branch,
3508             }
3509         ) or next;
3510
3511         $schema->storage->txn_begin;
3512         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3513         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3514         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3515         unless ( $message ) {
3516             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3517             C4::Message->enqueue($letter, $borrower, $mtt);
3518         } else {
3519             $message->append($letter);
3520             $message->update;
3521         }
3522         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3523         $schema->storage->txn_commit;
3524     }
3525
3526     return;
3527 }
3528
3529 =head2 updateWrongTransfer
3530
3531   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3532
3533 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3534
3535 =cut
3536
3537 sub updateWrongTransfer {
3538         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3539         my $dbh = C4::Context->dbh;
3540 # first step validate the actual line of transfert .
3541         my $sth =
3542                 $dbh->prepare(
3543                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3544                 );
3545                 $sth->execute($FromLibrary,$itemNumber);
3546
3547 # second step create a new line of branchtransfer to the right location .
3548         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3549
3550 #third step changing holdingbranch of item
3551     my $item = Koha::Items->find($itemNumber)->holdingbranch($FromLibrary)->store;
3552 }
3553
3554 =head2 CalcDateDue
3555
3556 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3557
3558 this function calculates the due date given the start date and configured circulation rules,
3559 checking against the holidays calendar as per the daysmode circulation rule.
3560 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3561 C<$itemtype>  = itemtype code of item in question
3562 C<$branch>  = location whose calendar to use
3563 C<$borrower> = Borrower object
3564 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3565
3566 =cut
3567
3568 sub CalcDateDue {
3569     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3570
3571     $isrenewal ||= 0;
3572
3573     # loanlength now a href
3574     my $loanlength =
3575             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3576
3577     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3578             ? qq{renewalperiod}
3579             : qq{issuelength};
3580
3581     my $datedue;
3582     if ( $startdate ) {
3583         if (ref $startdate ne 'DateTime' ) {
3584             $datedue = dt_from_string($datedue);
3585         } else {
3586             $datedue = $startdate->clone;
3587         }
3588     } else {
3589         $datedue = dt_from_string()->truncate( to => 'minute' );
3590     }
3591
3592
3593     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3594         {
3595             categorycode => $borrower->{categorycode},
3596             itemtype     => $itemtype,
3597             branchcode   => $branch,
3598         }
3599     );
3600
3601     # calculate the datedue as normal
3602     if ( $daysmode eq 'Days' )
3603     {    # ignoring calendar
3604         if ( $loanlength->{lengthunit} eq 'hours' ) {
3605             $datedue->add( hours => $loanlength->{$length_key} );
3606         } else {    # days
3607             $datedue->add( days => $loanlength->{$length_key} );
3608             $datedue->set_hour(23);
3609             $datedue->set_minute(59);
3610         }
3611     } else {
3612         my $dur;
3613         if ($loanlength->{lengthunit} eq 'hours') {
3614             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3615         }
3616         else { # days
3617             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3618         }
3619         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3620         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3621         if ($loanlength->{lengthunit} eq 'days') {
3622             $datedue->set_hour(23);
3623             $datedue->set_minute(59);
3624         }
3625     }
3626
3627     # if Hard Due Dates are used, retrieve them and apply as necessary
3628     my ( $hardduedate, $hardduedatecompare ) =
3629       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3630     if ($hardduedate) {    # hardduedates are currently dates
3631         $hardduedate->truncate( to => 'minute' );
3632         $hardduedate->set_hour(23);
3633         $hardduedate->set_minute(59);
3634         my $cmp = DateTime->compare( $hardduedate, $datedue );
3635
3636 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3637 # if the calculated date is before the 'after' Hard Due Date (floor), override
3638 # if the hard due date is set to 'exactly', overrride
3639         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3640             $datedue = $hardduedate->clone;
3641         }
3642
3643         # in all other cases, keep the date due as it is
3644
3645     }
3646
3647     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3648     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3649         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3650         if( $expiry_dt ) { #skip empty expiry date..
3651             $expiry_dt->set( hour => 23, minute => 59);
3652             my $d1= $datedue->clone->set_time_zone('floating');
3653             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3654                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3655             }
3656         }
3657         if ( $daysmode ne 'Days' ) {
3658           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3659           if ( $calendar->is_holiday($datedue) ) {
3660               # Don't return on a closed day
3661               $datedue = $calendar->prev_open_days( $datedue, 1 );
3662           }
3663         }
3664     }
3665
3666     return $datedue;
3667 }
3668
3669
3670 sub CheckValidBarcode{
3671 my ($barcode) = @_;
3672 my $dbh = C4::Context->dbh;
3673 my $query=qq|SELECT count(*)
3674              FROM items
3675              WHERE barcode=?
3676             |;
3677 my $sth = $dbh->prepare($query);
3678 $sth->execute($barcode);
3679 my $exist=$sth->fetchrow ;
3680 return $exist;
3681 }
3682
3683 =head2 IsBranchTransferAllowed
3684
3685   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3686
3687 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3688
3689 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3690 Koha::Item->can_be_transferred.
3691
3692 =cut
3693
3694 sub IsBranchTransferAllowed {
3695         my ( $toBranch, $fromBranch, $code ) = @_;
3696
3697         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3698
3699         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3700         my $dbh = C4::Context->dbh;
3701
3702         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3703         $sth->execute( $toBranch, $fromBranch, $code );
3704         my $limit = $sth->fetchrow_hashref();
3705
3706         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3707         if ( $limit->{'limitId'} ) {
3708                 return 0;
3709         } else {
3710                 return 1;
3711         }
3712 }
3713
3714 =head2 CreateBranchTransferLimit
3715
3716   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3717
3718 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3719
3720 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3721
3722 =cut
3723
3724 sub CreateBranchTransferLimit {
3725    my ( $toBranch, $fromBranch, $code ) = @_;
3726    return unless defined($toBranch) && defined($fromBranch);
3727    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3728
3729    my $dbh = C4::Context->dbh;
3730
3731    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3732    return $sth->execute( $code, $toBranch, $fromBranch );
3733 }
3734
3735 =head2 DeleteBranchTransferLimits
3736
3737     my $result = DeleteBranchTransferLimits($frombranch);
3738
3739 Deletes all the library transfer limits for one library.  Returns the
3740 number of limits deleted, 0e0 if no limits were deleted, or undef if
3741 no arguments are supplied.
3742
3743 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3744     fromBranch => $fromBranch
3745     })->delete.
3746
3747 =cut
3748
3749 sub DeleteBranchTransferLimits {
3750     my $branch = shift;
3751     return unless defined $branch;
3752     my $dbh    = C4::Context->dbh;
3753     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3754     return $sth->execute($branch);
3755 }
3756
3757 sub ReturnLostItem{
3758     my ( $borrowernumber, $itemnum ) = @_;
3759     MarkIssueReturned( $borrowernumber, $itemnum );
3760 }
3761
3762 =head2 LostItem
3763
3764   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3765
3766 The final optional parameter, C<$params>, expected to contain
3767 'skip_record_index' key, which relayed down to Koha::Item/store,
3768 there it prevents calling of ModZebra index_records,
3769 which takes most of the time in batch adds/deletes: index_records better
3770 to be called later in C<additem.pl> after the whole loop.
3771
3772 $params:
3773     skip_record_index => 1|0
3774
3775 =cut
3776
3777 sub LostItem{
3778     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3779
3780     unless ( $mark_lost_from ) {
3781         # Temporary check to avoid regressions
3782         die q|LostItem called without $mark_lost_from, check the API.|;
3783     }
3784
3785     my $mark_returned;
3786     if ( $force_mark_returned ) {
3787         $mark_returned = 1;
3788     } else {
3789         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3790         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3791     }
3792
3793     my $dbh = C4::Context->dbh();
3794     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3795                            FROM issues
3796                            JOIN items USING (itemnumber)
3797                            JOIN biblio USING (biblionumber)
3798                            WHERE issues.itemnumber=?");
3799     $sth->execute($itemnumber);
3800     my $issues=$sth->fetchrow_hashref();
3801
3802     # If a borrower lost the item, add a replacement cost to the their record
3803     if ( my $borrowernumber = $issues->{borrowernumber} ){
3804         my $patron = Koha::Patrons->find( $borrowernumber );
3805
3806         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3807         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3808
3809         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3810             C4::Accounts::chargelostitem(
3811                 $borrowernumber,
3812                 $itemnumber,
3813                 $issues->{'replacementprice'},
3814                 sprintf( "%s %s %s",
3815                     $issues->{'title'}          || q{},
3816                     $issues->{'barcode'}        || q{},
3817                     $issues->{'itemcallnumber'} || q{},
3818                 ),
3819             );
3820             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3821             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3822         }
3823
3824         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3825     }
3826
3827     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3828     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3829         Koha::Items->find($itemnumber)->holdingbranch($frombranch)->store({ skip_record_index => $params->{skip_record_index} });
3830     }
3831     my $transferdeleted = DeleteTransfer($itemnumber);
3832 }
3833
3834 sub GetOfflineOperations {
3835     my $dbh = C4::Context->dbh;
3836     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3837     $sth->execute(C4::Context->userenv->{'branch'});
3838     my $results = $sth->fetchall_arrayref({});
3839     return $results;
3840 }
3841
3842 sub GetOfflineOperation {
3843     my $operationid = shift;
3844     return unless $operationid;
3845     my $dbh = C4::Context->dbh;
3846     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3847     $sth->execute( $operationid );
3848     return $sth->fetchrow_hashref;
3849 }
3850
3851 sub AddOfflineOperation {
3852     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3853     my $dbh = C4::Context->dbh;
3854     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3855     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3856     return "Added.";
3857 }
3858
3859 sub DeleteOfflineOperation {
3860     my $dbh = C4::Context->dbh;
3861     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3862     $sth->execute( shift );
3863     return "Deleted.";
3864 }
3865
3866 sub ProcessOfflineOperation {
3867     my $operation = shift;
3868
3869     my $report;
3870     if ( $operation->{action} eq 'return' ) {
3871         $report = ProcessOfflineReturn( $operation );
3872     } elsif ( $operation->{action} eq 'issue' ) {
3873         $report = ProcessOfflineIssue( $operation );
3874     } elsif ( $operation->{action} eq 'payment' ) {
3875         $report = ProcessOfflinePayment( $operation );
3876     }
3877
3878     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3879
3880     return $report;
3881 }
3882
3883 sub ProcessOfflineReturn {
3884     my $operation = shift;
3885
3886     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3887
3888     if ( $item ) {
3889         my $itemnumber = $item->itemnumber;
3890         my $issue = GetOpenIssue( $itemnumber );
3891         if ( $issue ) {
3892             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
3893             ModDateLastSeen( $itemnumber, $leave_item_lost );
3894             MarkIssueReturned(
3895                 $issue->{borrowernumber},
3896                 $itemnumber,
3897                 $operation->{timestamp},
3898             );
3899             $item->renewals(0);
3900             $item->onloan(undef);
3901             $item->store({ log_action => 0 });
3902             return "Success.";
3903         } else {
3904             return "Item not issued.";
3905         }
3906     } else {
3907         return "Item not found.";
3908     }
3909 }
3910
3911 sub ProcessOfflineIssue {
3912     my $operation = shift;
3913
3914     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3915
3916     if ( $patron ) {
3917         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3918         unless ($item) {
3919             return "Barcode not found.";
3920         }
3921         my $itemnumber = $item->itemnumber;
3922         my $issue = GetOpenIssue( $itemnumber );
3923
3924         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3925             MarkIssueReturned(
3926                 $issue->{borrowernumber},
3927                 $itemnumber,
3928                 $operation->{timestamp},
3929             );
3930         }
3931         AddIssue(
3932             $patron->unblessed,
3933             $operation->{'barcode'},
3934             undef,
3935             1,
3936             $operation->{timestamp},
3937             undef,
3938         );
3939         return "Success.";
3940     } else {
3941         return "Borrower not found.";
3942     }
3943 }
3944
3945 sub ProcessOfflinePayment {
3946     my $operation = shift;
3947
3948     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
3949
3950     $patron->account->pay(
3951         {
3952             amount     => $operation->{amount},
3953             library_id => $operation->{branchcode},
3954             interface  => 'koc'
3955         }
3956     );
3957
3958     return "Success.";
3959 }
3960
3961 =head2 TransferSlip
3962
3963   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3964
3965   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
3966
3967 =cut
3968
3969 sub TransferSlip {
3970     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
3971
3972     my $item =
3973       $itemnumber
3974       ? Koha::Items->find($itemnumber)
3975       : Koha::Items->find( { barcode => $barcode } );
3976
3977     $item or return;
3978
3979     return C4::Letters::GetPreparedLetter (
3980         module => 'circulation',
3981         letter_code => 'TRANSFERSLIP',
3982         branchcode => $branch,
3983         tables => {
3984             'branches'    => $to_branch,
3985             'biblio'      => $item->biblionumber,
3986             'items'       => $item->unblessed,
3987         },
3988     );
3989 }
3990
3991 =head2 CheckIfIssuedToPatron
3992
3993   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
3994
3995   Return 1 if any record item is issued to patron, otherwise return 0
3996
3997 =cut
3998
3999 sub CheckIfIssuedToPatron {
4000     my ($borrowernumber, $biblionumber) = @_;
4001
4002     my $dbh = C4::Context->dbh;
4003     my $query = q|
4004         SELECT COUNT(*) FROM issues
4005         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4006         WHERE items.biblionumber = ?
4007         AND issues.borrowernumber = ?
4008     |;
4009     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4010     return 1 if $is_issued;
4011     return;
4012 }
4013
4014 =head2 IsItemIssued
4015
4016   IsItemIssued( $itemnumber )
4017
4018   Return 1 if the item is on loan, otherwise return 0
4019
4020 =cut
4021
4022 sub IsItemIssued {
4023     my $itemnumber = shift;
4024     my $dbh = C4::Context->dbh;
4025     my $sth = $dbh->prepare(q{
4026         SELECT COUNT(*)
4027         FROM issues
4028         WHERE itemnumber = ?
4029     });
4030     $sth->execute($itemnumber);
4031     return $sth->fetchrow;
4032 }
4033
4034 =head2 GetAgeRestriction
4035
4036   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4037   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4038
4039   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4040   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4041
4042 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4043 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4044 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4045          Negative days mean the borrower has gone past the age restriction age.
4046
4047 =cut
4048
4049 sub GetAgeRestriction {
4050     my ($record_restrictions, $borrower) = @_;
4051     my $markers = C4::Context->preference('AgeRestrictionMarker');
4052
4053     return unless $record_restrictions;
4054     # Split $record_restrictions to something like FSK 16 or PEGI 6
4055     my @values = split ' ', uc($record_restrictions);
4056     return unless @values;
4057
4058     # Search first occurrence of one of the markers
4059     my @markers = split /\|/, uc($markers);
4060     return unless @markers;
4061
4062     my $index            = 0;
4063     my $restriction_year = 0;
4064     for my $value (@values) {
4065         $index++;
4066         for my $marker (@markers) {
4067             $marker =~ s/^\s+//;    #remove leading spaces
4068             $marker =~ s/\s+$//;    #remove trailing spaces
4069             if ( $marker eq $value ) {
4070                 if ( $index <= $#values ) {
4071                     $restriction_year += $values[$index];
4072                 }
4073                 last;
4074             }
4075             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4076
4077                 # Perhaps it is something like "K16" (as in Finland)
4078                 $restriction_year += $1;
4079                 last;
4080             }
4081         }
4082         last if ( $restriction_year > 0 );
4083     }
4084
4085     #Check if the borrower is age restricted for this material and for how long.
4086     if ($restriction_year && $borrower) {
4087         if ( $borrower->{'dateofbirth'} ) {
4088             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4089             $alloweddate[0] += $restriction_year;
4090
4091             #Prevent runime eror on leap year (invalid date)
4092             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4093                 $alloweddate[2] = 28;
4094             }
4095
4096             #Get how many days the borrower has to reach the age restriction
4097             my @Today = split /-/, dt_from_string()->ymd();
4098             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4099             #Negative days means the borrower went past the age restriction age
4100             return ($restriction_year, $daysToAgeRestriction);
4101         }
4102     }
4103
4104     return ($restriction_year);
4105 }
4106
4107
4108 =head2 GetPendingOnSiteCheckouts
4109
4110 =cut
4111
4112 sub GetPendingOnSiteCheckouts {
4113     my $dbh = C4::Context->dbh;
4114     return $dbh->selectall_arrayref(q|
4115         SELECT
4116           items.barcode,
4117           items.biblionumber,
4118           items.itemnumber,
4119           items.itemnotes,
4120           items.itemcallnumber,
4121           items.location,
4122           issues.date_due,
4123           issues.branchcode,
4124           issues.date_due < NOW() AS is_overdue,
4125           biblio.author,
4126           biblio.title,
4127           borrowers.firstname,
4128           borrowers.surname,
4129           borrowers.cardnumber,
4130           borrowers.borrowernumber
4131         FROM items
4132         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4133         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4134         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4135         WHERE issues.onsite_checkout = 1
4136     |, { Slice => {} } );
4137 }
4138
4139 sub GetTopIssues {
4140     my ($params) = @_;
4141
4142     my ($count, $branch, $itemtype, $ccode, $newness)
4143         = @$params{qw(count branch itemtype ccode newness)};
4144
4145     my $dbh = C4::Context->dbh;
4146     my $query = q{
4147         SELECT * FROM (
4148         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4149           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4150           i.ccode, SUM(i.issues) AS count
4151         FROM biblio b
4152         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4153         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4154     };
4155
4156     my (@where_strs, @where_args);
4157
4158     if ($branch) {
4159         push @where_strs, 'i.homebranch = ?';
4160         push @where_args, $branch;
4161     }
4162     if ($itemtype) {
4163         if (C4::Context->preference('item-level_itypes')){
4164             push @where_strs, 'i.itype = ?';
4165             push @where_args, $itemtype;
4166         } else {
4167             push @where_strs, 'bi.itemtype = ?';
4168             push @where_args, $itemtype;
4169         }
4170     }
4171     if ($ccode) {
4172         push @where_strs, 'i.ccode = ?';
4173         push @where_args, $ccode;
4174     }
4175     if ($newness) {
4176         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4177         push @where_args, $newness;
4178     }
4179
4180     if (@where_strs) {
4181         $query .= 'WHERE ' . join(' AND ', @where_strs);
4182     }
4183
4184     $query .= q{
4185         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4186           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4187           i.ccode
4188         ORDER BY count DESC
4189     };
4190
4191     $query .= q{ ) xxx WHERE count > 0 };
4192     $count = int($count);
4193     if ($count > 0) {
4194         $query .= "LIMIT $count";
4195     }
4196
4197     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4198
4199     return @$rows;
4200 }
4201
4202 =head2 Internal methods
4203
4204 =cut
4205
4206 sub _CalculateAndUpdateFine {
4207     my ($params) = @_;
4208
4209     my $borrower    = $params->{borrower};
4210     my $item        = $params->{item};
4211     my $issue       = $params->{issue};
4212     my $return_date = $params->{return_date};
4213
4214     unless ($borrower) { carp "No borrower passed in!" && return; }
4215     unless ($item)     { carp "No item passed in!"     && return; }
4216     unless ($issue)    { carp "No issue passed in!"    && return; }
4217
4218     my $datedue = dt_from_string( $issue->date_due );
4219
4220     # we only need to calculate and change the fines if we want to do that on return
4221     # Should be on for hourly loans
4222     my $control = C4::Context->preference('CircControl');
4223     my $control_branchcode =
4224         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4225       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4226       :                                     $issue->branchcode;
4227
4228     my $date_returned = $return_date ? $return_date : dt_from_string();
4229
4230     my ( $amount, $unitcounttotal, $unitcount  ) =
4231       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4232
4233     if ( C4::Context->preference('finesMode') eq 'production' ) {
4234         if ( $amount > 0 ) {
4235             C4::Overdues::UpdateFine({
4236                 issue_id       => $issue->issue_id,
4237                 itemnumber     => $issue->itemnumber,
4238                 borrowernumber => $issue->borrowernumber,
4239                 amount         => $amount,
4240                 due            => output_pref($datedue),
4241             });
4242         }
4243         elsif ($return_date) {
4244
4245             # Backdated returns may have fines that shouldn't exist,
4246             # so in this case, we need to drop those fines to 0
4247
4248             C4::Overdues::UpdateFine({
4249                 issue_id       => $issue->issue_id,
4250                 itemnumber     => $issue->itemnumber,
4251                 borrowernumber => $issue->borrowernumber,
4252                 amount         => 0,
4253                 due            => output_pref($datedue),
4254             });
4255         }
4256     }
4257 }
4258
4259 sub _item_denied_renewal {
4260     my ($params) = @_;
4261
4262     my $item = $params->{item};
4263     return unless $item;
4264
4265     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4266     return unless $denyingrules;
4267     foreach my $field (keys %$denyingrules) {
4268         my $val = $item->$field;
4269         if( !defined $val) {
4270             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4271                 return 1;
4272             }
4273         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4274            # If the results matches the values in the syspref
4275            # We return true if match found
4276             return 1;
4277         }
4278     }
4279     return 0;
4280 }
4281
4282 1;
4283
4284 __END__
4285
4286 =head1 AUTHOR
4287
4288 Koha Development Team <http://koha-community.org/>
4289
4290 =cut