C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along
  16 # with Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79     }   # else there is no browser to send fatals to!
  80
  81     # Check if there are memcached servers set
  82     $servers = $ENV{'MEMCACHED_SERVERS'};
  83     if ($servers) {
  84         # Load required libraries and create the memcached object
  85         require Cache::Memcached;
  86         $memcached = Cache::Memcached->new({
  87         servers => [ $servers ],
  88         debug   => 0,
  89         compress_threshold => 10_000,
  90         expire_time => 600,
  91         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  92     });
  93         # Verify memcached available (set a variable and test the output)
  94     $ismemcached = $memcached->set('ismemcached','1');
  95     }
  96
  97     $VERSION = '3.07.00.049';
  98 }
  99
 100 use DBI;
 101 use ZOOM;
 102 use XML::Simple;
 103 use C4::Boolean;
 104 use C4::Debug;
 105 use POSIX ();
 106 use DateTime::TimeZone;
 107 use Module::Load::Conditional qw(can_load);
 108
 109 =head1 NAME
 110
 111 C4::Context - Maintain and manipulate the context of a Koha script
 112
 113 =head1 SYNOPSIS
 114
 115   use C4::Context;
 116
 117   use C4::Context("/path/to/koha-conf.xml");
 118
 119   $config_value = C4::Context->config("config_variable");
 120
 121   $koha_preference = C4::Context->preference("preference");
 122
 123   $db_handle = C4::Context->dbh;
 124
 125   $Zconn = C4::Context->Zconn;
 126
 127   $stopwordhash = C4::Context->stopwords;
 128
 129 =head1 DESCRIPTION
 130
 131 When a Koha script runs, it makes use of a certain number of things:
 132 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 133 databases, and so forth. These things make up the I<context> in which
 134 the script runs.
 135
 136 This module takes care of setting up the context for a script:
 137 figuring out which configuration file to load, and loading it, opening
 138 a connection to the right database, and so forth.
 139
 140 Most scripts will only use one context. They can simply have
 141
 142   use C4::Context;
 143
 144 at the top.
 145
 146 Other scripts may need to use several contexts. For instance, if a
 147 library has two databases, one for a certain collection, and the other
 148 for everything else, it might be necessary for a script to use two
 149 different contexts to search both databases. Such scripts should use
 150 the C<&set_context> and C<&restore_context> functions, below.
 151
 152 By default, C4::Context reads the configuration from
 153 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 154 environment variable to the pathname of a configuration file to use.
 155
 156 =head1 METHODS
 157
 158 =cut
 159
 160 #'
 161 # In addition to what is said in the POD above, a Context object is a
 162 # reference-to-hash with the following fields:
 163 #
 164 # config
 165 #    A reference-to-hash whose keys and values are the
 166 #    configuration variables and values specified in the config
 167 #    file (/etc/koha/koha-conf.xml).
 168 # dbh
 169 #    A handle to the appropriate database for this context.
 170 # dbh_stack
 171 #    Used by &set_dbh and &restore_dbh to hold other database
 172 #    handles for this context.
 173 # Zconn
 174 #     A connection object for the Zebra server
 175
 176 # Koha's main configuration file koha-conf.xml
 177 # is searched for according to this priority list:
 178 #
 179 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 180 # 2. Path supplied in KOHA_CONF environment variable.
 181 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 182 #    as value has changed from its default of
 183 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 184 #    when Koha is installed in 'standard' or 'single'
 185 #    mode.
 186 # 4. Path supplied in CONFIG_FNAME.
 187 #
 188 # The first entry that refers to a readable file is used.
 189
 190 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 191                 # Default config file, if none is specified
 192
 193 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 194                 # path to config file set by installer
 195                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 196                 # when Koha is installed in 'standard' or 'single'
 197                 # mode.  If Koha was installed in 'dev' mode,
 198                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 199                 # developers should set the KOHA_CONF environment variable
 200
 201 $context = undef;        # Initially, no context is set
 202 @context_stack = ();        # Initially, no saved contexts
 203
 204
 205 =head2 KOHAVERSION
 206
 207 returns the kohaversion stored in kohaversion.pl file
 208
 209 =cut
 210
 211 sub KOHAVERSION {
 212     my $cgidir = C4::Context->intranetdir;
 213
 214     # Apparently the GIT code does not run out of a CGI-BIN subdirectory
 215     # but distribution code does?  (Stan, 1jan08)
 216     if(-d $cgidir . "/cgi-bin"){
 217         my $cgidir .= "/cgi-bin";
 218     }
 219
 220     do $cgidir."/kohaversion.pl" || die "NO $cgidir/kohaversion.pl";
 221     return kohaversion();
 222 }
 223
 224 =head2 final_linear_version
 225
 226 Returns the version number of the final update to run in updatedatabase.pl.
 227 This number is equal to the version in kohaversion.pl
 228
 229 =cut
 230
 231 sub final_linear_version {
 232     return KOHAVERSION;
 233 }
 234
 235 =head2 read_config_file
 236
 237 Reads the specified Koha config file.
 238
 239 Returns an object containing the configuration variables. The object's
 240 structure is a bit complex to the uninitiated ... take a look at the
 241 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 242 here are a few examples that may give you what you need:
 243
 244 The simple elements nested within the <config> element:
 245
 246     my $pass = $koha->{'config'}->{'pass'};
 247
 248 The <listen> elements:
 249
 250     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 251
 252 The elements nested within the <server> element:
 253
 254     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 255
 256 Returns undef in case of error.
 257
 258 =cut
 259
 260 sub read_config_file {          # Pass argument naming config file to read
 261     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 262
 263     if ($ismemcached) {
 264       $memcached->set('kohaconf',$koha);
 265     }
 266
 267     return $koha;                       # Return value: ref-to-hash holding the configuration
 268 }
 269
 270 =head2 ismemcached
 271
 272 Returns the value of the $ismemcached variable (0/1)
 273
 274 =cut
 275
 276 sub ismemcached {
 277     return $ismemcached;
 278 }
 279
 280 =head2 memcached
 281
 282 If $ismemcached is true, returns the $memcache variable.
 283 Returns undef otherwise
 284
 285 =cut
 286
 287 sub memcached {
 288     if ($ismemcached) {
 289       return $memcached;
 290     } else {
 291       return;
 292     }
 293 }
 294
 295 # db_scheme2dbi
 296 # Translates the full text name of a database into de appropiate dbi name
 297 #
 298 sub db_scheme2dbi {
 299     my $name = shift;
 300     # for instance, we support only mysql, so don't care checking
 301     return "mysql";
 302     for ($name) {
 303 # FIXME - Should have other databases.
 304         if (/mysql/) { return("mysql"); }
 305         if (/Postgres|Pg|PostgresSQL/) { return("Pg"); }
 306         if (/oracle/) { return("Oracle"); }
 307     }
 308     return;         # Just in case
 309 }
 310
 311 sub import {
 312     # Create the default context ($C4::Context::Context)
 313     # the first time the module is called
 314     # (a config file can be optionaly passed)
 315
 316     # default context allready exists?
 317     return if $context;
 318
 319     # no ? so load it!
 320     my ($pkg,$config_file) = @_ ;
 321     my $new_ctx = __PACKAGE__->new($config_file);
 322     return unless $new_ctx;
 323
 324     # if successfully loaded, use it by default
 325     $new_ctx->set_context;
 326     1;
 327 }
 328
 329 =head2 new
 330
 331   $context = new C4::Context;
 332   $context = new C4::Context("/path/to/koha-conf.xml");
 333
 334 Allocates a new context. Initializes the context from the specified
 335 file, which defaults to either the file given by the C<$KOHA_CONF>
 336 environment variable, or F</etc/koha/koha-conf.xml>.
 337
 338 It saves the koha-conf.xml values in the declared memcached server(s)
 339 if currently available and uses those values until them expire and
 340 re-reads them.
 341
 342 C<&new> does not set this context as the new default context; for
 343 that, use C<&set_context>.
 344
 345 =cut
 346
 347 #'
 348 # Revision History:
 349 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 350 sub new {
 351     my $class = shift;
 352     my $conf_fname = shift;        # Config file to load
 353     my $self = {};
 354
 355     # check that the specified config file exists and is not empty
 356     undef $conf_fname unless
 357         (defined $conf_fname && -s $conf_fname);
 358     # Figure out a good config file to load if none was specified.
 359     if (!defined($conf_fname))
 360     {
 361         # If the $KOHA_CONF environment variable is set, use
 362         # that. Otherwise, use the built-in default.
 363         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 364             $conf_fname = $ENV{"KOHA_CONF"};
 365         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 366             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 367             # regex to anything else -- don't want installer to rewrite it
 368             $conf_fname = $INSTALLED_CONFIG_FNAME;
 369         } elsif (-s CONFIG_FNAME) {
 370             $conf_fname = CONFIG_FNAME;
 371         } else {
 372             warn "unable to locate Koha configuration file koha-conf.xml";
 373             return;
 374         }
 375     }
 376
 377     if ($ismemcached) {
 378         # retreive from memcached
 379         $self = $memcached->get('kohaconf');
 380         if (not defined $self) {
 381             # not in memcached yet
 382             $self = read_config_file($conf_fname);
 383         }
 384     } else {
 385         # non-memcached env, read from file
 386         $self = read_config_file($conf_fname);
 387     }
 388
 389     $self->{"config_file"} = $conf_fname;
 390     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 391     return if !defined($self->{"config"});
 392
 393     $self->{"dbh"} = undef;        # Database handle
 394     $self->{"Zconn"} = undef;    # Zebra Connections
 395     $self->{"stopwords"} = undef; # stopwords list
 396     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 397     $self->{"userenv"} = undef;        # User env
 398     $self->{"activeuser"} = undef;        # current active user
 399     $self->{"shelves"} = undef;
 400     $self->{tz} = undef; # local timezone object
 401
 402     bless $self, $class;
 403     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 404     return $self;
 405 }
 406
 407 =head2 set_context
 408
 409   $context = new C4::Context;
 410   $context->set_context();
 411 or
 412   set_context C4::Context $context;
 413
 414   ...
 415   restore_context C4::Context;
 416
 417 In some cases, it might be necessary for a script to use multiple
 418 contexts. C<&set_context> saves the current context on a stack, then
 419 sets the context to C<$context>, which will be used in future
 420 operations. To restore the previous context, use C<&restore_context>.
 421
 422 =cut
 423
 424 #'
 425 sub set_context
 426 {
 427     my $self = shift;
 428     my $new_context;    # The context to set
 429
 430     # Figure out whether this is a class or instance method call.
 431     #
 432     # We're going to make the assumption that control got here
 433     # through valid means, i.e., that the caller used an instance
 434     # or class method call, and that control got here through the
 435     # usual inheritance mechanisms. The caller can, of course,
 436     # break this assumption by playing silly buggers, but that's
 437     # harder to do than doing it properly, and harder to check
 438     # for.
 439     if (ref($self) eq "")
 440     {
 441         # Class method. The new context is the next argument.
 442         $new_context = shift;
 443     } else {
 444         # Instance method. The new context is $self.
 445         $new_context = $self;
 446     }
 447
 448     # Save the old context, if any, on the stack
 449     push @context_stack, $context if defined($context);
 450
 451     # Set the new context
 452     $context = $new_context;
 453 }
 454
 455 =head2 restore_context
 456
 457   &restore_context;
 458
 459 Restores the context set by C<&set_context>.
 460
 461 =cut
 462
 463 #'
 464 sub restore_context
 465 {
 466     my $self = shift;
 467
 468     if ($#context_stack < 0)
 469     {
 470         # Stack underflow.
 471         die "Context stack underflow";
 472     }
 473
 474     # Pop the old context and set it.
 475     $context = pop @context_stack;
 476
 477     # FIXME - Should this return something, like maybe the context
 478     # that was current when this was called?
 479 }
 480
 481 =head2 config
 482
 483   $value = C4::Context->config("config_variable");
 484
 485   $value = C4::Context->config_variable;
 486
 487 Returns the value of a variable specified in the configuration file
 488 from which the current context was created.
 489
 490 The second form is more compact, but of course may conflict with
 491 method names. If there is a configuration variable called "new", then
 492 C<C4::Config-E<gt>new> will not return it.
 493
 494 =cut
 495
 496 sub _common_config {
 497         my $var = shift;
 498         my $term = shift;
 499     return if !defined($context->{$term});
 500        # Presumably $self->{$term} might be
 501        # undefined if the config file given to &new
 502        # didn't exist, and the caller didn't bother
 503        # to check the return value.
 504
 505     # Return the value of the requested config variable
 506     return $context->{$term}->{$var};
 507 }
 508
 509 sub config {
 510         return _common_config($_[1],'config');
 511 }
 512 sub zebraconfig {
 513         return _common_config($_[1],'server');
 514 }
 515 sub ModZebrations {
 516         return _common_config($_[1],'serverinfo');
 517 }
 518
 519 =head2 preference
 520
 521   $sys_preference = C4::Context->preference('some_variable');
 522
 523 Looks up the value of the given system preference in the
 524 systempreferences table of the Koha database, and returns it. If the
 525 variable is not set or does not exist, undef is returned.
 526
 527 In case of an error, this may return 0.
 528
 529 Note: It is impossible to tell the difference between system
 530 preferences which do not exist, and those whose values are set to NULL
 531 with this method.
 532
 533 =cut
 534
 535 # FIXME: running this under mod_perl will require a means of
 536 # flushing the caching mechanism.
 537
 538 my %sysprefs;
 539 my $use_syspref_cache = 1;
 540
 541 sub preference {
 542     my $self = shift;
 543     my $var  = shift;    # The system preference to return
 544
 545     if ($use_syspref_cache && exists $sysprefs{lc $var}) {
 546         return $sysprefs{lc $var};
 547     }
 548
 549     my $dbh  = C4::Context->dbh or return 0;
 550
 551     my $value;
 552     if ( defined $ENV{"OVERRIDE_SYSPREF_$var"} ) {
 553         $value = $ENV{"OVERRIDE_SYSPREF_$var"};
 554     } else {
 555         # Look up systempreferences.variable==$var
 556         my $sql = q{
 557             SELECT  value
 558             FROM    systempreferences
 559             WHERE   variable = ?
 560             LIMIT   1
 561         };
 562         $value = $dbh->selectrow_array( $sql, {}, lc $var );
 563     }
 564
 565     $sysprefs{lc $var} = $value;
 566     return $value;
 567 }
 568
 569 sub boolean_preference {
 570     my $self = shift;
 571     my $var = shift;        # The system preference to return
 572     my $it = preference($self, $var);
 573     return defined($it)? C4::Boolean::true_p($it): undef;
 574 }
 575
 576 =head2 enable_syspref_cache
 577
 578   C4::Context->enable_syspref_cache();
 579
 580 Enable the in-memory syspref cache used by C4::Context. This is the
 581 default behavior.
 582
 583 =cut
 584
 585 sub enable_syspref_cache {
 586     my ($self) = @_;
 587     $use_syspref_cache = 1;
 588 }
 589
 590 =head2 disable_syspref_cache
 591
 592   C4::Context->disable_syspref_cache();
 593
 594 Disable the in-memory syspref cache used by C4::Context. This should be
 595 used with Plack and other persistent environments.
 596
 597 =cut
 598
 599 sub disable_syspref_cache {
 600     my ($self) = @_;
 601     $use_syspref_cache = 0;
 602     $self->clear_syspref_cache();
 603 }
 604
 605 =head2 clear_syspref_cache
 606
 607   C4::Context->clear_syspref_cache();
 608
 609 cleans the internal cache of sysprefs. Please call this method if
 610 you update the systempreferences table. Otherwise, your new changes
 611 will not be seen by this process.
 612
 613 =cut
 614
 615 sub clear_syspref_cache {
 616     %sysprefs = ();
 617 }
 618
 619 =head2 set_preference
 620
 621   C4::Context->set_preference( $variable, $value );
 622
 623 This updates a preference's value both in the systempreferences table and in
 624 the sysprefs cache.
 625
 626 =cut
 627
 628 sub set_preference {
 629     my $self = shift;
 630     my $var = lc(shift);
 631     my $value = shift;
 632
 633     my $dbh = C4::Context->dbh or return 0;
 634
 635     my $type = $dbh->selectrow_array( "SELECT type FROM systempreferences WHERE variable = ?", {}, $var );
 636
 637     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 638
 639     my $sth = $dbh->prepare( "
 640       INSERT INTO systempreferences
 641         ( variable, value )
 642         VALUES( ?, ? )
 643         ON DUPLICATE KEY UPDATE value = VALUES(value)
 644     " );
 645
 646     if($sth->execute( $var, $value )) {
 647         $sysprefs{$var} = $value;
 648     }
 649     $sth->finish;
 650 }
 651
 652 # AUTOLOAD
 653 # This implements C4::Config->foo, and simply returns
 654 # C4::Context->config("foo"), as described in the documentation for
 655 # &config, above.
 656
 657 # FIXME - Perhaps this should be extended to check &config first, and
 658 # then &preference if that fails. OTOH, AUTOLOAD could lead to crappy
 659 # code, so it'd probably be best to delete it altogether so as not to
 660 # encourage people to use it.
 661 sub AUTOLOAD
 662 {
 663     my $self = shift;
 664
 665     $AUTOLOAD =~ s/.*:://;        # Chop off the package name,
 666                     # leaving only the function name.
 667     return $self->config($AUTOLOAD);
 668 }
 669
 670 =head2 Zconn
 671
 672   $Zconn = C4::Context->Zconn
 673
 674 Returns a connection to the Zebra database for the current
 675 context. If no connection has yet been made, this method
 676 creates one and connects.
 677
 678 C<$self>
 679
 680 C<$server> one of the servers defined in the koha-conf.xml file
 681
 682 C<$async> whether this is a asynchronous connection
 683
 684 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 685
 686
 687 =cut
 688
 689 sub Zconn {
 690     my $self=shift;
 691     my $server=shift;
 692     my $async=shift;
 693     my $auth=shift;
 694     my $piggyback=shift;
 695     my $syntax=shift;
 696     if ( defined($context->{"Zconn"}->{$server}) && (0 == $context->{"Zconn"}->{$server}->errcode()) ) {
 697         return $context->{"Zconn"}->{$server};
 698     # No connection object or it died. Create one.
 699     }else {
 700         # release resources if we're closing a connection and making a new one
 701         # FIXME: this needs to be smarter -- an error due to a malformed query or
 702         # a missing index does not necessarily require us to close the connection
 703         # and make a new one, particularly for a batch job.  However, at
 704         # first glance it does not look like there's a way to easily check
 705         # the basic health of a ZOOM::Connection
 706         $context->{"Zconn"}->{$server}->destroy() if defined($context->{"Zconn"}->{$server});
 707
 708         $context->{"Zconn"}->{$server} = &_new_Zconn($server,$async,$auth,$piggyback,$syntax);
 709         $context->{ Zconn }->{ $server }->option(
 710             preferredRecordSyntax => C4::Context->preference("marcflavour") );
 711         return $context->{"Zconn"}->{$server};
 712     }
 713 }
 714
 715 =head2 _new_Zconn
 716
 717 $context->{"Zconn"} = &_new_Zconn($server,$async);
 718
 719 Internal function. Creates a new database connection from the data given in the current context and returns it.
 720
 721 C<$server> one of the servers defined in the koha-conf.xml file
 722
 723 C<$async> whether this is a asynchronous connection
 724
 725 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 726
 727 =cut
 728
 729 sub _new_Zconn {
 730     my ($server,$async,$auth,$piggyback,$syntax) = @_;
 731
 732     my $tried=0; # first attempt
 733     my $Zconn; # connection object
 734     $server = "biblioserver" unless $server;
 735     $syntax = "usmarc" unless $syntax;
 736
 737     my $host = $context->{'listen'}->{$server}->{'content'};
 738     my $servername = $context->{"config"}->{$server};
 739     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 740     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 741  $auth = 1 if($user && $password);
 742     retry:
 743     eval {
 744         # set options
 745         my $o = new ZOOM::Options();
 746         $o->option(user=>$user) if $auth;
 747         $o->option(password=>$password) if $auth;
 748         $o->option(async => 1) if $async;
 749         $o->option(count => $piggyback) if $piggyback;
 750         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 751         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 752         $o->option(preferredRecordSyntax => $syntax);
 753         $o->option(elementSetName => "F"); # F for 'full' as opposed to B for 'brief'
 754         $o->option(databaseName => ($servername?$servername:"biblios"));
 755
 756         # create a new connection object
 757         $Zconn= create ZOOM::Connection($o);
 758
 759         # forge to server
 760         $Zconn->connect($host, 0);
 761
 762         # check for errors and warn
 763         if ($Zconn->errcode() !=0) {
 764             warn "something wrong with the connection: ". $Zconn->errmsg();
 765         }
 766
 767     };
 768 #     if ($@) {
 769 #         # Koha manages the Zebra server -- this doesn't work currently for me because of permissions issues
 770 #         # Also, I'm skeptical about whether it's the best approach
 771 #         warn "problem with Zebra";
 772 #         if ( C4::Context->preference("ManageZebra") ) {
 773 #             if ($@->code==10000 && $tried==0) { ##No connection try restarting Zebra
 774 #                 $tried=1;
 775 #                 warn "trying to restart Zebra";
 776 #                 my $res=system("zebrasrv -f $ENV{'KOHA_CONF'} >/koha/log/zebra-error.log");
 777 #                 goto "retry";
 778 #             } else {
 779 #                 warn "Error ", $@->code(), ": ", $@->message(), "\n";
 780 #                 $Zconn="error";
 781 #                 return $Zconn;
 782 #             }
 783 #         }
 784 #     }
 785     return $Zconn;
 786 }
 787
 788 # _new_dbh
 789 # Internal helper function (not a method!). This creates a new
 790 # database connection from the data given in the current context, and
 791 # returns it.
 792 sub _new_dbh
 793 {
 794
 795     ## $context
 796     ## correct name for db_scheme
 797     my $db_driver;
 798     if ($context->config("db_scheme")){
 799         $db_driver=$context->{db_driver};
 800     }else{
 801         $db_driver="mysql";
 802     }
 803
 804     my $db_name   = $context->config("database");
 805     my $db_host   = $context->config("hostname");
 806     my $db_port   = $context->config("port") || '';
 807     my $db_user   = $context->config("user");
 808     my $db_passwd = $context->config("pass");
 809     # MJR added or die here, as we can't work without dbh
 810     my $dbh = DBI->connect("DBI:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 811     $db_user, $db_passwd, {'RaiseError' => $ENV{DEBUG}?1:0 }) or die $DBI::errstr;
 812
 813     # Check for the existence of a systempreference table; if we don't have this, we don't
 814     # have a valid database and should not set RaiseError in order to allow the installer
 815     # to run; installer will not run otherwise since we raise all db errors
 816
 817     eval {
 818                 local $dbh->{PrintError} = 0;
 819                 local $dbh->{RaiseError} = 1;
 820                 $dbh->do(qq{SELECT * FROM systempreferences WHERE 1 = 0 });
 821     };
 822
 823     if ($@) {
 824         $dbh->{RaiseError} = 0;
 825     }
 826
 827     if ( $db_driver eq 'mysql' ) {
 828         $dbh->{mysql_auto_reconnect} = 1;
 829     }
 830
 831         my $tz = $ENV{TZ};
 832     if ( $db_driver eq 'mysql' ) {
 833         # Koha 3.0 is utf-8, so force utf8 communication between mySQL and koha, whatever the mysql default config.
 834         # this is better than modifying my.cnf (and forcing all communications to be in utf8)
 835         $dbh->{'mysql_enable_utf8'}=1; #enable
 836         $dbh->do("set NAMES 'utf8'");
 837         ($tz) and $dbh->do(qq(SET time_zone = "$tz"));
 838     }
 839     elsif ( $db_driver eq 'Pg' ) {
 840             $dbh->do( "set client_encoding = 'UTF8';" );
 841         ($tz) and $dbh->do(qq(SET TIME ZONE = "$tz"));
 842     }
 843     return $dbh;
 844 }
 845
 846 =head2 dbh
 847
 848   $dbh = C4::Context->dbh;
 849
 850 Returns a database handle connected to the Koha database for the
 851 current context. If no connection has yet been made, this method
 852 creates one, and connects to the database.
 853
 854 This database handle is cached for future use: if you call
 855 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 856 times. If you need a second database handle, use C<&new_dbh> and
 857 possibly C<&set_dbh>.
 858
 859 =cut
 860
 861 #'
 862 sub dbh
 863 {
 864     my $self = shift;
 865     my $params = shift;
 866     my $sth;
 867
 868     unless ( $params->{new} ) {
 869         if ( defined($context->{db_driver}) && $context->{db_driver} eq 'mysql' && $context->{"dbh"} ) {
 870             return $context->{"dbh"};
 871         } elsif ( defined($context->{"dbh"}) && $context->{"dbh"}->ping() ) {
 872             return $context->{"dbh"};
 873         }
 874     }
 875
 876     # No database handle or it died . Create one.
 877     $context->{"dbh"} = &_new_dbh();
 878
 879     return $context->{"dbh"};
 880 }
 881
 882 =head2 new_dbh
 883
 884   $dbh = C4::Context->new_dbh;
 885
 886 Creates a new connection to the Koha database for the current context,
 887 and returns the database handle (a C<DBI::db> object).
 888
 889 The handle is not saved anywhere: this method is strictly a
 890 convenience function; the point is that it knows which database to
 891 connect to so that the caller doesn't have to know.
 892
 893 =cut
 894
 895 #'
 896 sub new_dbh
 897 {
 898     my $self = shift;
 899
 900     return &_new_dbh();
 901 }
 902
 903 =head2 set_dbh
 904
 905   $my_dbh = C4::Connect->new_dbh;
 906   C4::Connect->set_dbh($my_dbh);
 907   ...
 908   C4::Connect->restore_dbh;
 909
 910 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 911 C<&set_context> and C<&restore_context>.
 912
 913 C<&set_dbh> saves the current database handle on a stack, then sets
 914 the current database handle to C<$my_dbh>.
 915
 916 C<$my_dbh> is assumed to be a good database handle.
 917
 918 =cut
 919
 920 #'
 921 sub set_dbh
 922 {
 923     my $self = shift;
 924     my $new_dbh = shift;
 925
 926     # Save the current database handle on the handle stack.
 927     # We assume that $new_dbh is all good: if the caller wants to
 928     # screw himself by passing an invalid handle, that's fine by
 929     # us.
 930     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 931     $context->{"dbh"} = $new_dbh;
 932 }
 933
 934 =head2 restore_dbh
 935
 936   C4::Context->restore_dbh;
 937
 938 Restores the database handle saved by an earlier call to
 939 C<C4::Context-E<gt>set_dbh>.
 940
 941 =cut
 942
 943 #'
 944 sub restore_dbh
 945 {
 946     my $self = shift;
 947
 948     if ($#{$context->{"dbh_stack"}} < 0)
 949     {
 950         # Stack underflow
 951         die "DBH stack underflow";
 952     }
 953
 954     # Pop the old database handle and set it.
 955     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 956
 957     # FIXME - If it is determined that restore_context should
 958     # return something, then this function should, too.
 959 }
 960
 961 =head2 queryparser
 962
 963   $queryparser = C4::Context->queryparser
 964
 965 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 966
 967 =cut
 968
 969 sub queryparser {
 970     my $self = shift;
 971     unless (defined $context->{"queryparser"}) {
 972         $context->{"queryparser"} = &_new_queryparser();
 973     }
 974
 975     return
 976       defined( $context->{"queryparser"} )
 977       ? $context->{"queryparser"}->new
 978       : undef;
 979 }
 980
 981 =head2 _new_queryparser
 982
 983 Internal helper function to create a new QueryParser object. QueryParser
 984 is loaded dynamically so as to keep the lack of the QueryParser library from
 985 getting in anyone's way.
 986
 987 =cut
 988
 989 sub _new_queryparser {
 990     my $qpmodules = {
 991         'OpenILS::QueryParser'           => undef,
 992         'Koha::QueryParser::Driver::PQF' => undef
 993     };
 994     if ( can_load( 'modules' => $qpmodules ) ) {
 995         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 996         my $config_file = $context->config('queryparser_config');
 997         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 998         if ( $QParser->load_config($config_file) ) {
 999             # TODO: allow indexes to be configured in the database
1000             return $QParser;
1001         }
1002     }
1003     return;
1004 }
1005
1006 =head2 marcfromkohafield
1007
1008   $dbh = C4::Context->marcfromkohafield;
1009
1010 Returns a hash with marcfromkohafield.
1011
1012 This hash is cached for future use: if you call
1013 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
1014
1015 =cut
1016
1017 #'
1018 sub marcfromkohafield
1019 {
1020     my $retval = {};
1021
1022     # If the hash already exists, return it.
1023     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
1024
1025     # No hash. Create one.
1026     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
1027
1028     return $context->{"marcfromkohafield"};
1029 }
1030
1031 # _new_marcfromkohafield
1032 # Internal helper function (not a method!). This creates a new
1033 # hash with stopwords
1034 sub _new_marcfromkohafield
1035 {
1036     my $dbh = C4::Context->dbh;
1037     my $marcfromkohafield;
1038     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
1039     $sth->execute;
1040     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
1041         my $retval = {};
1042         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
1043     }
1044     return $marcfromkohafield;
1045 }
1046
1047 =head2 stopwords
1048
1049   $dbh = C4::Context->stopwords;
1050
1051 Returns a hash with stopwords.
1052
1053 This hash is cached for future use: if you call
1054 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
1055
1056 =cut
1057
1058 #'
1059 sub stopwords
1060 {
1061     my $retval = {};
1062
1063     # If the hash already exists, return it.
1064     return $context->{"stopwords"} if defined($context->{"stopwords"});
1065
1066     # No hash. Create one.
1067     $context->{"stopwords"} = &_new_stopwords();
1068
1069     return $context->{"stopwords"};
1070 }
1071
1072 # _new_stopwords
1073 # Internal helper function (not a method!). This creates a new
1074 # hash with stopwords
1075 sub _new_stopwords
1076 {
1077     my $dbh = C4::Context->dbh;
1078     my $stopwordlist;
1079     my $sth = $dbh->prepare("select word from stopwords");
1080     $sth->execute;
1081     while (my $stopword = $sth->fetchrow_array) {
1082         $stopwordlist->{$stopword} = uc($stopword);
1083     }
1084     $stopwordlist->{A} = "A" unless $stopwordlist;
1085     return $stopwordlist;
1086 }
1087
1088 =head2 userenv
1089
1090   C4::Context->userenv;
1091
1092 Retrieves a hash for user environment variables.
1093
1094 This hash shall be cached for future use: if you call
1095 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1096
1097 =cut
1098
1099 #'
1100 sub userenv {
1101     my $var = $context->{"activeuser"};
1102     if (defined $var and defined $context->{"userenv"}->{$var}) {
1103         return $context->{"userenv"}->{$var};
1104     } else {
1105         return;
1106     }
1107 }
1108
1109 =head2 set_userenv
1110
1111   C4::Context->set_userenv($usernum, $userid, $usercnum, $userfirstname,
1112                   $usersurname, $userbranch, $userflags, $emailaddress, $branchprinter,
1113                   $persona);
1114
1115 Establish a hash of user environment variables.
1116
1117 set_userenv is called in Auth.pm
1118
1119 =cut
1120
1121 #'
1122 sub set_userenv {
1123     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona)= @_;
1124     my $var=$context->{"activeuser"} || '';
1125     my $cell = {
1126         "number"     => $usernum,
1127         "id"         => $userid,
1128         "cardnumber" => $usercnum,
1129         "firstname"  => $userfirstname,
1130         "surname"    => $usersurname,
1131         #possibly a law problem
1132         "branch"     => $userbranch,
1133         "branchname" => $branchname,
1134         "flags"      => $userflags,
1135         "emailaddress"     => $emailaddress,
1136         "branchprinter"    => $branchprinter,
1137         "persona"    => $persona,
1138     };
1139     $context->{userenv}->{$var} = $cell;
1140     return $cell;
1141 }
1142
1143 sub set_shelves_userenv {
1144         my ($type, $shelves) = @_ or return;
1145         my $activeuser = $context->{activeuser} or return;
1146         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1147         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1148         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1149 }
1150
1151 sub get_shelves_userenv {
1152         my $active;
1153         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1154                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1155                 return;
1156         }
1157         my $totshelves = $active->{totshelves} or undef;
1158         my $pubshelves = $active->{pubshelves} or undef;
1159         my $barshelves = $active->{barshelves} or undef;
1160         return ($totshelves, $pubshelves, $barshelves);
1161 }
1162
1163 =head2 _new_userenv
1164
1165   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1166
1167 Builds a hash for user environment variables.
1168
1169 This hash shall be cached for future use: if you call
1170 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1171
1172 _new_userenv is called in Auth.pm
1173
1174 =cut
1175
1176 #'
1177 sub _new_userenv
1178 {
1179     shift;  # Useless except it compensates for bad calling style
1180     my ($sessionID)= @_;
1181      $context->{"activeuser"}=$sessionID;
1182 }
1183
1184 =head2 _unset_userenv
1185
1186   C4::Context->_unset_userenv;
1187
1188 Destroys the hash for activeuser user environment variables.
1189
1190 =cut
1191
1192 #'
1193
1194 sub _unset_userenv
1195 {
1196     my ($sessionID)= @_;
1197     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1198 }
1199
1200
1201 =head2 get_versions
1202
1203   C4::Context->get_versions
1204
1205 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1206
1207 =cut
1208
1209 #'
1210
1211 # A little example sub to show more debugging info for CGI::Carp
1212 sub get_versions {
1213     my %versions;
1214     $versions{kohaVersion}  = KOHAVERSION();
1215     $versions{kohaDbVersion} = C4::Context->preference('version');
1216     $versions{osVersion} = join(" ", POSIX::uname());
1217     $versions{perlVersion} = $];
1218     {
1219         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1220         $versions{mysqlVersion}  = `mysql -V`;
1221         $versions{apacheVersion} = `httpd -v`;
1222         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1223         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1224         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1225     }
1226     return %versions;
1227 }
1228
1229
1230 =head2 tz
1231
1232   C4::Context->tz
1233
1234   Returns a DateTime::TimeZone object for the system timezone
1235
1236 =cut
1237
1238 sub tz {
1239     my $self = shift;
1240     if (!defined $context->{tz}) {
1241         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1242     }
1243     return $context->{tz};
1244 }
1245
1246
1247
1248 1;
1249 __END__
1250
1251 =head1 ENVIRONMENT
1252
1253 =head2 C<KOHA_CONF>
1254
1255 Specifies the configuration file to read.
1256
1257 =head1 SEE ALSO
1258
1259 XML::Simple
1260
1261 =head1 AUTHORS
1262
1263 Andrew Arensburger <arensb at ooblick dot com>
1264
1265 Joshua Ferraro <jmf at liblime dot com>
1266
1267 =cut