C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along
  16 # with Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22
  23 BEGIN {
  24         if ($ENV{'HTTP_USER_AGENT'})    {
  25                 require CGI::Carp;
  26         # FIXME for future reference, CGI::Carp doc says
  27         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  28                 import CGI::Carp qw(fatalsToBrowser);
  29                         sub handle_errors {
  30                             my $msg = shift;
  31                             my $debug_level;
  32                             eval {C4::Context->dbh();};
  33                             if ($@){
  34                                 $debug_level = 1;
  35                             }
  36                             else {
  37                                 $debug_level =  C4::Context->preference("DebugLevel");
  38                             }
  39
  40                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  41                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  42                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  43                        <head><title>Koha Error</title></head>
  44                        <body>
  45                 );
  46                                 if ($debug_level eq "2"){
  47                                         # debug 2 , print extra info too.
  48                                         my %versions = get_versions();
  49
  50                 # a little example table with various version info";
  51                                         print "
  52                                                 <h1>Koha error</h1>
  53                                                 <p>The following fatal error has occurred:</p>
  54                         <pre><code>$msg</code></pre>
  55                                                 <table>
  56                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  57                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  58                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  59                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  60                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  61                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  62                                                 </table>";
  63
  64                                 } elsif ($debug_level eq "1"){
  65                                         print "
  66                                                 <h1>Koha error</h1>
  67                                                 <p>The following fatal error has occurred:</p>
  68                         <pre><code>$msg</code></pre>";
  69                                 } else {
  70                                         print "<p>production mode - trapped fatal error</p>";
  71                                 }
  72                 print "</body></html>";
  73                         }
  74                 #CGI::Carp::set_message(\&handle_errors);
  75                 ## give a stack backtrace if KOHA_BACKTRACES is set
  76                 ## can't rely on DebugLevel for this, as we're not yet connected
  77                 if ($ENV{KOHA_BACKTRACES}) {
  78                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  79                 }
  80     }   # else there is no browser to send fatals to!
  81
  82     # Check if there are memcached servers set
  83     $servers = $ENV{'MEMCACHED_SERVERS'};
  84     if ($servers) {
  85         # Load required libraries and create the memcached object
  86         require Cache::Memcached;
  87         $memcached = Cache::Memcached->new({
  88         servers => [ $servers ],
  89         debug   => 0,
  90         compress_threshold => 10_000,
  91         expire_time => 600,
  92         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  93     });
  94         # Verify memcached available (set a variable and test the output)
  95     $ismemcached = $memcached->set('ismemcached','1');
  96     }
  97
  98     $VERSION = '3.08.01.002';
  99 }
 100
 101 use DBI;
 102 use ZOOM;
 103 use XML::Simple;
 104 use C4::Boolean;
 105 use C4::Debug;
 106 use POSIX ();
 107 use DateTime::TimeZone;
 108
 109 =head1 NAME
 110
 111 C4::Context - Maintain and manipulate the context of a Koha script
 112
 113 =head1 SYNOPSIS
 114
 115   use C4::Context;
 116
 117   use C4::Context("/path/to/koha-conf.xml");
 118
 119   $config_value = C4::Context->config("config_variable");
 120
 121   $koha_preference = C4::Context->preference("preference");
 122
 123   $db_handle = C4::Context->dbh;
 124
 125   $Zconn = C4::Context->Zconn;
 126
 127   $stopwordhash = C4::Context->stopwords;
 128
 129 =head1 DESCRIPTION
 130
 131 When a Koha script runs, it makes use of a certain number of things:
 132 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 133 databases, and so forth. These things make up the I<context> in which
 134 the script runs.
 135
 136 This module takes care of setting up the context for a script:
 137 figuring out which configuration file to load, and loading it, opening
 138 a connection to the right database, and so forth.
 139
 140 Most scripts will only use one context. They can simply have
 141
 142   use C4::Context;
 143
 144 at the top.
 145
 146 Other scripts may need to use several contexts. For instance, if a
 147 library has two databases, one for a certain collection, and the other
 148 for everything else, it might be necessary for a script to use two
 149 different contexts to search both databases. Such scripts should use
 150 the C<&set_context> and C<&restore_context> functions, below.
 151
 152 By default, C4::Context reads the configuration from
 153 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 154 environment variable to the pathname of a configuration file to use.
 155
 156 =head1 METHODS
 157
 158 =cut
 159
 160 #'
 161 # In addition to what is said in the POD above, a Context object is a
 162 # reference-to-hash with the following fields:
 163 #
 164 # config
 165 #    A reference-to-hash whose keys and values are the
 166 #    configuration variables and values specified in the config
 167 #    file (/etc/koha/koha-conf.xml).
 168 # dbh
 169 #    A handle to the appropriate database for this context.
 170 # dbh_stack
 171 #    Used by &set_dbh and &restore_dbh to hold other database
 172 #    handles for this context.
 173 # Zconn
 174 #     A connection object for the Zebra server
 175
 176 # Koha's main configuration file koha-conf.xml
 177 # is searched for according to this priority list:
 178 #
 179 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 180 # 2. Path supplied in KOHA_CONF environment variable.
 181 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 182 #    as value has changed from its default of
 183 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 184 #    when Koha is installed in 'standard' or 'single'
 185 #    mode.
 186 # 4. Path supplied in CONFIG_FNAME.
 187 #
 188 # The first entry that refers to a readable file is used.
 189
 190 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 191                 # Default config file, if none is specified
 192
 193 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 194                 # path to config file set by installer
 195                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 196                 # when Koha is installed in 'standard' or 'single'
 197                 # mode.  If Koha was installed in 'dev' mode,
 198                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 199                 # developers should set the KOHA_CONF environment variable
 200
 201 $context = undef;        # Initially, no context is set
 202 @context_stack = ();        # Initially, no saved contexts
 203
 204
 205 =head2 KOHAVERSION
 206
 207 returns the kohaversion stored in kohaversion.pl file
 208
 209 =cut
 210
 211 sub KOHAVERSION {
 212     my $cgidir = C4::Context->intranetdir;
 213
 214     # Apparently the GIT code does not run out of a CGI-BIN subdirectory
 215     # but distribution code does?  (Stan, 1jan08)
 216     if(-d $cgidir . "/cgi-bin"){
 217         my $cgidir .= "/cgi-bin";
 218     }
 219
 220     do $cgidir."/kohaversion.pl" || die "NO $cgidir/kohaversion.pl";
 221     return kohaversion();
 222 }
 223 =head2 read_config_file
 224
 225 Reads the specified Koha config file.
 226
 227 Returns an object containing the configuration variables. The object's
 228 structure is a bit complex to the uninitiated ... take a look at the
 229 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 230 here are a few examples that may give you what you need:
 231
 232 The simple elements nested within the <config> element:
 233
 234     my $pass = $koha->{'config'}->{'pass'};
 235
 236 The <listen> elements:
 237
 238     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 239
 240 The elements nested within the <server> element:
 241
 242     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 243
 244 Returns undef in case of error.
 245
 246 =cut
 247
 248 sub read_config_file {          # Pass argument naming config file to read
 249     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 250
 251     if ($ismemcached) {
 252       $memcached->set('kohaconf',$koha);
 253     }
 254
 255     return $koha;                       # Return value: ref-to-hash holding the configuration
 256 }
 257
 258 =head2 ismemcached
 259
 260 Returns the value of the $ismemcached variable (0/1)
 261
 262 =cut
 263
 264 sub ismemcached {
 265     return $ismemcached;
 266 }
 267
 268 =head2 memcached
 269
 270 If $ismemcached is true, returns the $memcache variable.
 271 Returns undef otherwise
 272
 273 =cut
 274
 275 sub memcached {
 276     if ($ismemcached) {
 277       return $memcached;
 278     } else {
 279       return undef;
 280     }
 281 }
 282
 283 # db_scheme2dbi
 284 # Translates the full text name of a database into de appropiate dbi name
 285 #
 286 sub db_scheme2dbi {
 287     my $name = shift;
 288     # for instance, we support only mysql, so don't care checking
 289     return "mysql";
 290     for ($name) {
 291 # FIXME - Should have other databases.
 292         if (/mysql/) { return("mysql"); }
 293         if (/Postgres|Pg|PostgresSQL/) { return("Pg"); }
 294         if (/oracle/) { return("Oracle"); }
 295     }
 296     return undef;         # Just in case
 297 }
 298
 299 sub import {
 300     # Create the default context ($C4::Context::Context)
 301     # the first time the module is called
 302     # (a config file can be optionaly passed)
 303
 304     # default context allready exists?
 305     return if $context;
 306
 307     # no ? so load it!
 308     my ($pkg,$config_file) = @_ ;
 309     my $new_ctx = __PACKAGE__->new($config_file);
 310     return unless $new_ctx;
 311
 312     # if successfully loaded, use it by default
 313     $new_ctx->set_context;
 314     1;
 315 }
 316
 317 =head2 new
 318
 319   $context = new C4::Context;
 320   $context = new C4::Context("/path/to/koha-conf.xml");
 321
 322 Allocates a new context. Initializes the context from the specified
 323 file, which defaults to either the file given by the C<$KOHA_CONF>
 324 environment variable, or F</etc/koha/koha-conf.xml>.
 325
 326 It saves the koha-conf.xml values in the declared memcached server(s)
 327 if currently available and uses those values until them expire and
 328 re-reads them.
 329
 330 C<&new> does not set this context as the new default context; for
 331 that, use C<&set_context>.
 332
 333 =cut
 334
 335 #'
 336 # Revision History:
 337 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 338 sub new {
 339     my $class = shift;
 340     my $conf_fname = shift;        # Config file to load
 341     my $self = {};
 342
 343     # check that the specified config file exists and is not empty
 344     undef $conf_fname unless
 345         (defined $conf_fname && -s $conf_fname);
 346     # Figure out a good config file to load if none was specified.
 347     if (!defined($conf_fname))
 348     {
 349         # If the $KOHA_CONF environment variable is set, use
 350         # that. Otherwise, use the built-in default.
 351         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 352             $conf_fname = $ENV{"KOHA_CONF"};
 353         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 354             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 355             # regex to anything else -- don't want installer to rewrite it
 356             $conf_fname = $INSTALLED_CONFIG_FNAME;
 357         } elsif (-s CONFIG_FNAME) {
 358             $conf_fname = CONFIG_FNAME;
 359         } else {
 360             warn "unable to locate Koha configuration file koha-conf.xml";
 361             return undef;
 362         }
 363     }
 364
 365     if ($ismemcached) {
 366         # retreive from memcached
 367         $self = $memcached->get('kohaconf');
 368         if (not defined $self) {
 369             # not in memcached yet
 370             $self = read_config_file($conf_fname);
 371         }
 372     } else {
 373         # non-memcached env, read from file
 374         $self = read_config_file($conf_fname);
 375     }
 376
 377     $self->{"config_file"} = $conf_fname;
 378     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 379     return undef if !defined($self->{"config"});
 380
 381     $self->{"dbh"} = undef;        # Database handle
 382     $self->{"Zconn"} = undef;    # Zebra Connections
 383     $self->{"stopwords"} = undef; # stopwords list
 384     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 385     $self->{"userenv"} = undef;        # User env
 386     $self->{"activeuser"} = undef;        # current active user
 387     $self->{"shelves"} = undef;
 388     $self->{tz} = undef; # local timezone object
 389
 390     bless $self, $class;
 391     return $self;
 392 }
 393
 394 =head2 set_context
 395
 396   $context = new C4::Context;
 397   $context->set_context();
 398 or
 399   set_context C4::Context $context;
 400
 401   ...
 402   restore_context C4::Context;
 403
 404 In some cases, it might be necessary for a script to use multiple
 405 contexts. C<&set_context> saves the current context on a stack, then
 406 sets the context to C<$context>, which will be used in future
 407 operations. To restore the previous context, use C<&restore_context>.
 408
 409 =cut
 410
 411 #'
 412 sub set_context
 413 {
 414     my $self = shift;
 415     my $new_context;    # The context to set
 416
 417     # Figure out whether this is a class or instance method call.
 418     #
 419     # We're going to make the assumption that control got here
 420     # through valid means, i.e., that the caller used an instance
 421     # or class method call, and that control got here through the
 422     # usual inheritance mechanisms. The caller can, of course,
 423     # break this assumption by playing silly buggers, but that's
 424     # harder to do than doing it properly, and harder to check
 425     # for.
 426     if (ref($self) eq "")
 427     {
 428         # Class method. The new context is the next argument.
 429         $new_context = shift;
 430     } else {
 431         # Instance method. The new context is $self.
 432         $new_context = $self;
 433     }
 434
 435     # Save the old context, if any, on the stack
 436     push @context_stack, $context if defined($context);
 437
 438     # Set the new context
 439     $context = $new_context;
 440 }
 441
 442 =head2 restore_context
 443
 444   &restore_context;
 445
 446 Restores the context set by C<&set_context>.
 447
 448 =cut
 449
 450 #'
 451 sub restore_context
 452 {
 453     my $self = shift;
 454
 455     if ($#context_stack < 0)
 456     {
 457         # Stack underflow.
 458         die "Context stack underflow";
 459     }
 460
 461     # Pop the old context and set it.
 462     $context = pop @context_stack;
 463
 464     # FIXME - Should this return something, like maybe the context
 465     # that was current when this was called?
 466 }
 467
 468 =head2 config
 469
 470   $value = C4::Context->config("config_variable");
 471
 472   $value = C4::Context->config_variable;
 473
 474 Returns the value of a variable specified in the configuration file
 475 from which the current context was created.
 476
 477 The second form is more compact, but of course may conflict with
 478 method names. If there is a configuration variable called "new", then
 479 C<C4::Config-E<gt>new> will not return it.
 480
 481 =cut
 482
 483 sub _common_config ($$) {
 484         my $var = shift;
 485         my $term = shift;
 486     return undef if !defined($context->{$term});
 487        # Presumably $self->{$term} might be
 488        # undefined if the config file given to &new
 489        # didn't exist, and the caller didn't bother
 490        # to check the return value.
 491
 492     # Return the value of the requested config variable
 493     return $context->{$term}->{$var};
 494 }
 495
 496 sub config {
 497         return _common_config($_[1],'config');
 498 }
 499 sub zebraconfig {
 500         return _common_config($_[1],'server');
 501 }
 502 sub ModZebrations {
 503         return _common_config($_[1],'serverinfo');
 504 }
 505
 506 =head2 preference
 507
 508   $sys_preference = C4::Context->preference('some_variable');
 509
 510 Looks up the value of the given system preference in the
 511 systempreferences table of the Koha database, and returns it. If the
 512 variable is not set or does not exist, undef is returned.
 513
 514 In case of an error, this may return 0.
 515
 516 Note: It is impossible to tell the difference between system
 517 preferences which do not exist, and those whose values are set to NULL
 518 with this method.
 519
 520 =cut
 521
 522 # FIXME: running this under mod_perl will require a means of
 523 # flushing the caching mechanism.
 524
 525 my %sysprefs;
 526
 527 sub preference {
 528     my $self = shift;
 529     my $var  = lc(shift);                          # The system preference to return
 530
 531     if (exists $sysprefs{$var}) {
 532         return $sysprefs{$var};
 533     }
 534
 535     my $dbh  = C4::Context->dbh or return 0;
 536
 537     # Look up systempreferences.variable==$var
 538     my $sql = <<'END_SQL';
 539         SELECT    value
 540         FROM    systempreferences
 541         WHERE    variable=?
 542         LIMIT    1
 543 END_SQL
 544     $sysprefs{$var} = $dbh->selectrow_array( $sql, {}, $var );
 545     return $sysprefs{$var};
 546 }
 547
 548 sub boolean_preference ($) {
 549     my $self = shift;
 550     my $var = shift;        # The system preference to return
 551     my $it = preference($self, $var);
 552     return defined($it)? C4::Boolean::true_p($it): undef;
 553 }
 554
 555 =head2 clear_syspref_cache
 556
 557   C4::Context->clear_syspref_cache();
 558
 559 cleans the internal cache of sysprefs. Please call this method if
 560 you update the systempreferences table. Otherwise, your new changes
 561 will not be seen by this process.
 562
 563 =cut
 564
 565 sub clear_syspref_cache {
 566     %sysprefs = ();
 567 }
 568
 569 =head2 set_preference
 570
 571   C4::Context->set_preference( $variable, $value );
 572
 573 This updates a preference's value both in the systempreferences table and in
 574 the sysprefs cache.
 575
 576 =cut
 577
 578 sub set_preference {
 579     my $self = shift;
 580     my $var = lc(shift);
 581     my $value = shift;
 582
 583     my $dbh = C4::Context->dbh or return 0;
 584
 585     my $type = $dbh->selectrow_array( "SELECT type FROM systempreferences WHERE variable = ?", {}, $var );
 586
 587     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 588
 589     my $sth = $dbh->prepare( "
 590       INSERT INTO systempreferences
 591         ( variable, value )
 592         VALUES( ?, ? )
 593         ON DUPLICATE KEY UPDATE value = VALUES(value)
 594     " );
 595
 596     if($sth->execute( $var, $value )) {
 597         $sysprefs{$var} = $value;
 598     }
 599     $sth->finish;
 600 }
 601
 602 # AUTOLOAD
 603 # This implements C4::Config->foo, and simply returns
 604 # C4::Context->config("foo"), as described in the documentation for
 605 # &config, above.
 606
 607 # FIXME - Perhaps this should be extended to check &config first, and
 608 # then &preference if that fails. OTOH, AUTOLOAD could lead to crappy
 609 # code, so it'd probably be best to delete it altogether so as not to
 610 # encourage people to use it.
 611 sub AUTOLOAD
 612 {
 613     my $self = shift;
 614
 615     $AUTOLOAD =~ s/.*:://;        # Chop off the package name,
 616                     # leaving only the function name.
 617     return $self->config($AUTOLOAD);
 618 }
 619
 620 =head2 Zconn
 621
 622   $Zconn = C4::Context->Zconn
 623
 624 Returns a connection to the Zebra database for the current
 625 context. If no connection has yet been made, this method
 626 creates one and connects.
 627
 628 C<$self>
 629
 630 C<$server> one of the servers defined in the koha-conf.xml file
 631
 632 C<$async> whether this is a asynchronous connection
 633
 634 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 635
 636
 637 =cut
 638
 639 sub Zconn {
 640     my $self=shift;
 641     my $server=shift;
 642     my $async=shift;
 643     my $auth=shift;
 644     my $piggyback=shift;
 645     my $syntax=shift;
 646     if ( defined($context->{"Zconn"}->{$server}) && (0 == $context->{"Zconn"}->{$server}->errcode()) ) {
 647         return $context->{"Zconn"}->{$server};
 648     # No connection object or it died. Create one.
 649     }else {
 650         # release resources if we're closing a connection and making a new one
 651         # FIXME: this needs to be smarter -- an error due to a malformed query or
 652         # a missing index does not necessarily require us to close the connection
 653         # and make a new one, particularly for a batch job.  However, at
 654         # first glance it does not look like there's a way to easily check
 655         # the basic health of a ZOOM::Connection
 656         $context->{"Zconn"}->{$server}->destroy() if defined($context->{"Zconn"}->{$server});
 657
 658         $context->{"Zconn"}->{$server} = &_new_Zconn($server,$async,$auth,$piggyback,$syntax);
 659         return $context->{"Zconn"}->{$server};
 660     }
 661 }
 662
 663 =head2 _new_Zconn
 664
 665 $context->{"Zconn"} = &_new_Zconn($server,$async);
 666
 667 Internal function. Creates a new database connection from the data given in the current context and returns it.
 668
 669 C<$server> one of the servers defined in the koha-conf.xml file
 670
 671 C<$async> whether this is a asynchronous connection
 672
 673 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 674
 675 =cut
 676
 677 sub _new_Zconn {
 678     my ($server,$async,$auth,$piggyback,$syntax) = @_;
 679
 680     my $tried=0; # first attempt
 681     my $Zconn; # connection object
 682     $server = "biblioserver" unless $server;
 683     $syntax = "usmarc" unless $syntax;
 684
 685     my $host = $context->{'listen'}->{$server}->{'content'};
 686     my $servername = $context->{"config"}->{$server};
 687     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 688     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 689  $auth = 1 if($user && $password);
 690     retry:
 691     eval {
 692         # set options
 693         my $o = new ZOOM::Options();
 694         $o->option(user=>$user) if $auth;
 695         $o->option(password=>$password) if $auth;
 696         $o->option(async => 1) if $async;
 697         $o->option(count => $piggyback) if $piggyback;
 698         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 699         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 700         $o->option(preferredRecordSyntax => $syntax);
 701         $o->option(elementSetName => "F"); # F for 'full' as opposed to B for 'brief'
 702         $o->option(databaseName => ($servername?$servername:"biblios"));
 703
 704         # create a new connection object
 705         $Zconn= create ZOOM::Connection($o);
 706
 707         # forge to server
 708         $Zconn->connect($host, 0);
 709
 710         # check for errors and warn
 711         if ($Zconn->errcode() !=0) {
 712             warn "something wrong with the connection: ". $Zconn->errmsg();
 713         }
 714
 715     };
 716 #     if ($@) {
 717 #         # Koha manages the Zebra server -- this doesn't work currently for me because of permissions issues
 718 #         # Also, I'm skeptical about whether it's the best approach
 719 #         warn "problem with Zebra";
 720 #         if ( C4::Context->preference("ManageZebra") ) {
 721 #             if ($@->code==10000 && $tried==0) { ##No connection try restarting Zebra
 722 #                 $tried=1;
 723 #                 warn "trying to restart Zebra";
 724 #                 my $res=system("zebrasrv -f $ENV{'KOHA_CONF'} >/koha/log/zebra-error.log");
 725 #                 goto "retry";
 726 #             } else {
 727 #                 warn "Error ", $@->code(), ": ", $@->message(), "\n";
 728 #                 $Zconn="error";
 729 #                 return $Zconn;
 730 #             }
 731 #         }
 732 #     }
 733     return $Zconn;
 734 }
 735
 736 # _new_dbh
 737 # Internal helper function (not a method!). This creates a new
 738 # database connection from the data given in the current context, and
 739 # returns it.
 740 sub _new_dbh
 741 {
 742
 743     ## $context
 744     ## correct name for db_schme
 745     my $db_driver;
 746     if ($context->config("db_scheme")){
 747         $db_driver=db_scheme2dbi($context->config("db_scheme"));
 748     }else{
 749         $db_driver="mysql";
 750     }
 751
 752     my $db_name   = $context->config("database");
 753     my $db_host   = $context->config("hostname");
 754     my $db_port   = $context->config("port") || '';
 755     my $db_user   = $context->config("user");
 756     my $db_passwd = $context->config("pass");
 757     # MJR added or die here, as we can't work without dbh
 758     my $dbh = DBI->connect("DBI:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 759     $db_user, $db_passwd, {'RaiseError' => $ENV{DEBUG}?1:0 }) or die $DBI::errstr;
 760
 761     # Check for the existence of a systempreference table; if we don't have this, we don't
 762     # have a valid database and should not set RaiseError in order to allow the installer
 763     # to run; installer will not run otherwise since we raise all db errors
 764
 765     eval {
 766                 local $dbh->{PrintError} = 0;
 767                 local $dbh->{RaiseError} = 1;
 768                 $dbh->do(qq{SELECT * FROM systempreferences WHERE 1 = 0 });
 769     };
 770
 771     if ($@) {
 772         $dbh->{RaiseError} = 0;
 773     }
 774
 775         my $tz = $ENV{TZ};
 776     if ( $db_driver eq 'mysql' ) {
 777         # Koha 3.0 is utf-8, so force utf8 communication between mySQL and koha, whatever the mysql default config.
 778         # this is better than modifying my.cnf (and forcing all communications to be in utf8)
 779         $dbh->{'mysql_enable_utf8'}=1; #enable
 780         $dbh->do("set NAMES 'utf8'");
 781         ($tz) and $dbh->do(qq(SET time_zone = "$tz"));
 782     }
 783     elsif ( $db_driver eq 'Pg' ) {
 784             $dbh->do( "set client_encoding = 'UTF8';" );
 785         ($tz) and $dbh->do(qq(SET TIME ZONE = "$tz"));
 786     }
 787     return $dbh;
 788 }
 789
 790 =head2 dbh
 791
 792   $dbh = C4::Context->dbh;
 793
 794 Returns a database handle connected to the Koha database for the
 795 current context. If no connection has yet been made, this method
 796 creates one, and connects to the database.
 797
 798 This database handle is cached for future use: if you call
 799 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 800 times. If you need a second database handle, use C<&new_dbh> and
 801 possibly C<&set_dbh>.
 802
 803 =cut
 804
 805 #'
 806 sub dbh
 807 {
 808     my $self = shift;
 809     my $sth;
 810
 811     if (defined($context->{"dbh"}) && $context->{"dbh"}->ping()) {
 812         return $context->{"dbh"};
 813     }
 814
 815     # No database handle or it died . Create one.
 816     $context->{"dbh"} = &_new_dbh();
 817
 818     return $context->{"dbh"};
 819 }
 820
 821 =head2 new_dbh
 822
 823   $dbh = C4::Context->new_dbh;
 824
 825 Creates a new connection to the Koha database for the current context,
 826 and returns the database handle (a C<DBI::db> object).
 827
 828 The handle is not saved anywhere: this method is strictly a
 829 convenience function; the point is that it knows which database to
 830 connect to so that the caller doesn't have to know.
 831
 832 =cut
 833
 834 #'
 835 sub new_dbh
 836 {
 837     my $self = shift;
 838
 839     return &_new_dbh();
 840 }
 841
 842 =head2 set_dbh
 843
 844   $my_dbh = C4::Connect->new_dbh;
 845   C4::Connect->set_dbh($my_dbh);
 846   ...
 847   C4::Connect->restore_dbh;
 848
 849 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 850 C<&set_context> and C<&restore_context>.
 851
 852 C<&set_dbh> saves the current database handle on a stack, then sets
 853 the current database handle to C<$my_dbh>.
 854
 855 C<$my_dbh> is assumed to be a good database handle.
 856
 857 =cut
 858
 859 #'
 860 sub set_dbh
 861 {
 862     my $self = shift;
 863     my $new_dbh = shift;
 864
 865     # Save the current database handle on the handle stack.
 866     # We assume that $new_dbh is all good: if the caller wants to
 867     # screw himself by passing an invalid handle, that's fine by
 868     # us.
 869     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 870     $context->{"dbh"} = $new_dbh;
 871 }
 872
 873 =head2 restore_dbh
 874
 875   C4::Context->restore_dbh;
 876
 877 Restores the database handle saved by an earlier call to
 878 C<C4::Context-E<gt>set_dbh>.
 879
 880 =cut
 881
 882 #'
 883 sub restore_dbh
 884 {
 885     my $self = shift;
 886
 887     if ($#{$context->{"dbh_stack"}} < 0)
 888     {
 889         # Stack underflow
 890         die "DBH stack underflow";
 891     }
 892
 893     # Pop the old database handle and set it.
 894     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 895
 896     # FIXME - If it is determined that restore_context should
 897     # return something, then this function should, too.
 898 }
 899
 900 =head2 marcfromkohafield
 901
 902   $dbh = C4::Context->marcfromkohafield;
 903
 904 Returns a hash with marcfromkohafield.
 905
 906 This hash is cached for future use: if you call
 907 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
 908
 909 =cut
 910
 911 #'
 912 sub marcfromkohafield
 913 {
 914     my $retval = {};
 915
 916     # If the hash already exists, return it.
 917     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
 918
 919     # No hash. Create one.
 920     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
 921
 922     return $context->{"marcfromkohafield"};
 923 }
 924
 925 # _new_marcfromkohafield
 926 # Internal helper function (not a method!). This creates a new
 927 # hash with stopwords
 928 sub _new_marcfromkohafield
 929 {
 930     my $dbh = C4::Context->dbh;
 931     my $marcfromkohafield;
 932     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
 933     $sth->execute;
 934     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
 935         my $retval = {};
 936         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
 937     }
 938     return $marcfromkohafield;
 939 }
 940
 941 =head2 stopwords
 942
 943   $dbh = C4::Context->stopwords;
 944
 945 Returns a hash with stopwords.
 946
 947 This hash is cached for future use: if you call
 948 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
 949
 950 =cut
 951
 952 #'
 953 sub stopwords
 954 {
 955     my $retval = {};
 956
 957     # If the hash already exists, return it.
 958     return $context->{"stopwords"} if defined($context->{"stopwords"});
 959
 960     # No hash. Create one.
 961     $context->{"stopwords"} = &_new_stopwords();
 962
 963     return $context->{"stopwords"};
 964 }
 965
 966 # _new_stopwords
 967 # Internal helper function (not a method!). This creates a new
 968 # hash with stopwords
 969 sub _new_stopwords
 970 {
 971     my $dbh = C4::Context->dbh;
 972     my $stopwordlist;
 973     my $sth = $dbh->prepare("select word from stopwords");
 974     $sth->execute;
 975     while (my $stopword = $sth->fetchrow_array) {
 976         $stopwordlist->{$stopword} = uc($stopword);
 977     }
 978     $stopwordlist->{A} = "A" unless $stopwordlist;
 979     return $stopwordlist;
 980 }
 981
 982 =head2 userenv
 983
 984   C4::Context->userenv;
 985
 986 Retrieves a hash for user environment variables.
 987
 988 This hash shall be cached for future use: if you call
 989 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
 990
 991 =cut
 992
 993 #'
 994 sub userenv {
 995     my $var = $context->{"activeuser"};
 996     return $context->{"userenv"}->{$var} if (defined $var and defined $context->{"userenv"}->{$var});
 997     # insecure=1 management
 998     if ($context->{"dbh"} && $context->preference('insecure') eq 'yes') {
 999         my %insecure;
1000         $insecure{flags} = '16382';
1001         $insecure{branchname} ='Insecure';
1002         $insecure{number} ='0';
1003         $insecure{cardnumber} ='0';
1004         $insecure{id} = 'insecure';
1005         $insecure{branch} = 'INS';
1006         $insecure{emailaddress} = 'test@mode.insecure.com';
1007         return \%insecure;
1008     } else {
1009         return;
1010     }
1011 }
1012
1013 =head2 set_userenv
1014
1015   C4::Context->set_userenv($usernum, $userid, $usercnum, $userfirstname,
1016                   $usersurname, $userbranch, $userflags, $emailaddress);
1017
1018 Establish a hash of user environment variables.
1019
1020 set_userenv is called in Auth.pm
1021
1022 =cut
1023
1024 #'
1025 sub set_userenv {
1026     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter)= @_;
1027     my $var=$context->{"activeuser"};
1028     my $cell = {
1029         "number"     => $usernum,
1030         "id"         => $userid,
1031         "cardnumber" => $usercnum,
1032         "firstname"  => $userfirstname,
1033         "surname"    => $usersurname,
1034         #possibly a law problem
1035         "branch"     => $userbranch,
1036         "branchname" => $branchname,
1037         "flags"      => $userflags,
1038         "emailaddress"     => $emailaddress,
1039         "branchprinter"    => $branchprinter
1040     };
1041     $context->{userenv}->{$var} = $cell;
1042     return $cell;
1043 }
1044
1045 sub set_shelves_userenv ($$) {
1046         my ($type, $shelves) = @_ or return undef;
1047         my $activeuser = $context->{activeuser} or return undef;
1048         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1049         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1050         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1051 }
1052
1053 sub get_shelves_userenv () {
1054         my $active;
1055         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1056                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1057                 return undef;
1058         }
1059         my $totshelves = $active->{totshelves} or undef;
1060         my $pubshelves = $active->{pubshelves} or undef;
1061         my $barshelves = $active->{barshelves} or undef;
1062         return ($totshelves, $pubshelves, $barshelves);
1063 }
1064
1065 =head2 _new_userenv
1066
1067   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1068
1069 Builds a hash for user environment variables.
1070
1071 This hash shall be cached for future use: if you call
1072 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1073
1074 _new_userenv is called in Auth.pm
1075
1076 =cut
1077
1078 #'
1079 sub _new_userenv
1080 {
1081     shift;  # Useless except it compensates for bad calling style
1082     my ($sessionID)= @_;
1083      $context->{"activeuser"}=$sessionID;
1084 }
1085
1086 =head2 _unset_userenv
1087
1088   C4::Context->_unset_userenv;
1089
1090 Destroys the hash for activeuser user environment variables.
1091
1092 =cut
1093
1094 #'
1095
1096 sub _unset_userenv
1097 {
1098     my ($sessionID)= @_;
1099     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1100 }
1101
1102
1103 =head2 get_versions
1104
1105   C4::Context->get_versions
1106
1107 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1108
1109 =cut
1110
1111 #'
1112
1113 # A little example sub to show more debugging info for CGI::Carp
1114 sub get_versions {
1115     my %versions;
1116     $versions{kohaVersion}  = KOHAVERSION();
1117     $versions{kohaDbVersion} = C4::Context->preference('version');
1118     $versions{osVersion} = join(" ", POSIX::uname());
1119     $versions{perlVersion} = $];
1120     {
1121         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1122         $versions{mysqlVersion}  = `mysql -V`;
1123         $versions{apacheVersion} = `httpd -v`;
1124         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1125         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1126         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1127     }
1128     return %versions;
1129 }
1130
1131
1132 =head2 tz
1133
1134   C4::Context->tz
1135
1136   Returns a DateTime::TimeZone object for the system timezone
1137
1138 =cut
1139
1140 sub tz {
1141     my $self = shift;
1142     if (!defined $context->{tz}) {
1143         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1144     }
1145     return $context->{tz};
1146 }
1147
1148
1149
1150 1;
1151 __END__
1152
1153 =head1 ENVIRONMENT
1154
1155 =head2 C<KOHA_CONF>
1156
1157 Specifies the configuration file to read.
1158
1159 =head1 SEE ALSO
1160
1161 XML::Simple
1162
1163 =head1 AUTHORS
1164
1165 Andrew Arensburger <arensb at ooblick dot com>
1166
1167 Joshua Ferraro <jmf at liblime dot com>
1168
1169 =cut