C4/Context.pm

   1 package C4::Context;
   2
   3 # Copyright 2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use vars qw($AUTOLOAD $context @context_stack);
  23 BEGIN {
  24     if ( $ENV{'HTTP_USER_AGENT'} ) { # Only hit when plack is not enabled
  25
  26         # Redefine multi_param if cgi version is < 4.08
  27         # Remove the "CGI::param called in list context" warning in this case
  28         require CGI;    # Can't check version without the require.
  29         if ( !defined($CGI::VERSION) || $CGI::VERSION < 4.08 ) {
  30             no warnings 'redefine';
  31             *CGI::multi_param = \&CGI::param;
  32             use warnings 'redefine';
  33             $CGI::LIST_CONTEXT_WARN = 0;
  34         }
  35     }
  36 };
  37
  38 use Carp qw( carp );
  39 use DateTime::TimeZone;
  40 use Encode;
  41 use File::Spec;
  42 use POSIX;
  43 use YAML::XS;
  44 use ZOOM;
  45 use List::MoreUtils qw(any);
  46
  47 use Koha::Caches;
  48 use Koha::Config::SysPref;
  49 use Koha::Config::SysPrefs;
  50 use Koha::Config;
  51 use Koha;
  52
  53 =head1 NAME
  54
  55 C4::Context - Maintain and manipulate the context of a Koha script
  56
  57 =head1 SYNOPSIS
  58
  59   use C4::Context;
  60
  61   use C4::Context("/path/to/koha-conf.xml");
  62
  63   $config_value = C4::Context->config("config_variable");
  64
  65   $koha_preference = C4::Context->preference("preference");
  66
  67   $db_handle = C4::Context->dbh;
  68
  69   $Zconn = C4::Context->Zconn;
  70
  71 =head1 DESCRIPTION
  72
  73 When a Koha script runs, it makes use of a certain number of things:
  74 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
  75 databases, and so forth. These things make up the I<context> in which
  76 the script runs.
  77
  78 This module takes care of setting up the context for a script:
  79 figuring out which configuration file to load, and loading it, opening
  80 a connection to the right database, and so forth.
  81
  82 Most scripts will only use one context. They can simply have
  83
  84   use C4::Context;
  85
  86 at the top.
  87
  88 Other scripts may need to use several contexts. For instance, if a
  89 library has two databases, one for a certain collection, and the other
  90 for everything else, it might be necessary for a script to use two
  91 different contexts to search both databases. Such scripts should use
  92 the C<&set_context> and C<&restore_context> functions, below.
  93
  94 By default, C4::Context reads the configuration from
  95 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
  96 environment variable to the pathname of a configuration file to use.
  97
  98 =head1 METHODS
  99
 100 =cut
 101
 102 #'
 103 # In addition to what is said in the POD above, a Context object is a
 104 # reference-to-hash with the following fields:
 105 #
 106 # config
 107 #    A reference-to-hash whose keys and values are the
 108 #    configuration variables and values specified in the config
 109 #    file (/etc/koha/koha-conf.xml).
 110 # dbh
 111 #    A handle to the appropriate database for this context.
 112 # dbh_stack
 113 #    Used by &set_dbh and &restore_dbh to hold other database
 114 #    handles for this context.
 115 # Zconn
 116 #     A connection object for the Zebra server
 117
 118 $context = undef;        # Initially, no context is set
 119 @context_stack = ();        # Initially, no saved contexts
 120
 121 sub import {
 122     # Create the default context ($C4::Context::Context)
 123     # the first time the module is called
 124     # (a config file can be optionaly passed)
 125
 126     # default context already exists?
 127     return if $context;
 128
 129     # no ? so load it!
 130     my ($pkg,$config_file) = @_ ;
 131     my $new_ctx = __PACKAGE__->new($config_file);
 132     return unless $new_ctx;
 133
 134     # if successfully loaded, use it by default
 135     $new_ctx->set_context;
 136     1;
 137 }
 138
 139 =head2 new
 140
 141   $context = C4::Context->new;
 142   $context = C4::Context->new("/path/to/koha-conf.xml");
 143
 144 Allocates a new context. Initializes the context from the specified
 145 file, which defaults to either the file given by the C<$KOHA_CONF>
 146 environment variable, or F</etc/koha/koha-conf.xml>.
 147
 148 It saves the koha-conf.xml values in the declared memcached server(s)
 149 if currently available and uses those values until them expire and
 150 re-reads them.
 151
 152 C<&new> does not set this context as the new default context; for
 153 that, use C<&set_context>.
 154
 155 =cut
 156
 157 #'
 158 # Revision History:
 159 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 160 sub new {
 161     my $class = shift;
 162     my $conf_fname = shift;        # Config file to load
 163
 164     # check that the specified config file exists and is not empty
 165     undef $conf_fname unless
 166         (defined $conf_fname && -s $conf_fname);
 167     # Figure out a good config file to load if none was specified.
 168     unless ( defined $conf_fname ) {
 169         $conf_fname = Koha::Config->guess_koha_conf;
 170         unless ( $conf_fname ) {
 171             warn "unable to locate Koha configuration file koha-conf.xml";
 172             return;
 173         }
 174     }
 175
 176     my $self = {};
 177     $self->{config} = Koha::Config->get_instance($conf_fname);
 178     unless ( defined $self->{config} ) {
 179         warn "The config file ($conf_fname) has not been parsed correctly";
 180         return;
 181     }
 182
 183     $self->{"Zconn"} = undef;    # Zebra Connections
 184     $self->{"userenv"} = undef;        # User env
 185     $self->{"activeuser"} = undef;        # current active user
 186     $self->{"shelves"} = undef;
 187     $self->{tz} = undef; # local timezone object
 188
 189     bless $self, $class;
 190     return $self;
 191 }
 192
 193 =head2 set_context
 194
 195   $context = new C4::Context;
 196   $context->set_context();
 197 or
 198   set_context C4::Context $context;
 199
 200   ...
 201   restore_context C4::Context;
 202
 203 In some cases, it might be necessary for a script to use multiple
 204 contexts. C<&set_context> saves the current context on a stack, then
 205 sets the context to C<$context>, which will be used in future
 206 operations. To restore the previous context, use C<&restore_context>.
 207
 208 =cut
 209
 210 #'
 211 sub set_context
 212 {
 213     my $self = shift;
 214     my $new_context;    # The context to set
 215
 216     # Figure out whether this is a class or instance method call.
 217     #
 218     # We're going to make the assumption that control got here
 219     # through valid means, i.e., that the caller used an instance
 220     # or class method call, and that control got here through the
 221     # usual inheritance mechanisms. The caller can, of course,
 222     # break this assumption by playing silly buggers, but that's
 223     # harder to do than doing it properly, and harder to check
 224     # for.
 225     if (ref($self) eq "")
 226     {
 227         # Class method. The new context is the next argument.
 228         $new_context = shift;
 229     } else {
 230         # Instance method. The new context is $self.
 231         $new_context = $self;
 232     }
 233
 234     # Save the old context, if any, on the stack
 235     push @context_stack, $context if defined($context);
 236
 237     # Set the new context
 238     $context = $new_context;
 239 }
 240
 241 =head2 restore_context
 242
 243   &restore_context;
 244
 245 Restores the context set by C<&set_context>.
 246
 247 =cut
 248
 249 #'
 250 sub restore_context
 251 {
 252     my $self = shift;
 253
 254     if ($#context_stack < 0)
 255     {
 256         # Stack underflow.
 257         die "Context stack underflow";
 258     }
 259
 260     # Pop the old context and set it.
 261     $context = pop @context_stack;
 262
 263     # FIXME - Should this return something, like maybe the context
 264     # that was current when this was called?
 265 }
 266
 267 =head2 config
 268
 269   $value = C4::Context->config("config_variable");
 270
 271 Returns the value of a variable specified in the configuration file
 272 from which the current context was created.
 273
 274 =cut
 275
 276 sub _common_config {
 277     my ($var, $term) = @_;
 278
 279     return unless defined $context and defined $context->{config};
 280
 281     return $context->{config}->get($var, $term);
 282 }
 283
 284 sub config {
 285         return _common_config($_[1],'config');
 286 }
 287 sub zebraconfig {
 288         return _common_config($_[1],'server');
 289 }
 290
 291 =head2 preference
 292
 293   $sys_preference = C4::Context->preference('some_variable');
 294
 295 Looks up the value of the given system preference in the
 296 systempreferences table of the Koha database, and returns it. If the
 297 variable is not set or does not exist, undef is returned.
 298
 299 In case of an error, this may return 0.
 300
 301 Note: It is impossible to tell the difference between system
 302 preferences which do not exist, and those whose values are set to NULL
 303 with this method.
 304
 305 =cut
 306
 307 my $use_syspref_cache = 1;
 308 sub preference {
 309     my $self = shift;
 310     my $var  = shift;    # The system preference to return
 311
 312     return Encode::decode_utf8($ENV{"OVERRIDE_SYSPREF_$var"})
 313         if defined $ENV{"OVERRIDE_SYSPREF_$var"};
 314
 315     $var = lc $var;
 316
 317     if ($use_syspref_cache) {
 318         my $syspref_cache = Koha::Caches->get_instance('syspref');
 319         my $cached_var = $syspref_cache->get_from_cache("syspref_$var");
 320         return $cached_var if defined $cached_var;
 321     }
 322
 323     my $syspref;
 324     eval { $syspref = Koha::Config::SysPrefs->find( lc $var ) };
 325     my $value = $syspref ? $syspref->value() : undef;
 326
 327     if ( $use_syspref_cache ) {
 328         my $syspref_cache = Koha::Caches->get_instance('syspref');
 329         $syspref_cache->set_in_cache("syspref_$var", $value);
 330     }
 331     return $value;
 332 }
 333
 334 =head2 yaml_preference
 335
 336 Retrieves the required system preference value, and converts it
 337 from YAML into a Perl data structure. It throws an exception if
 338 the value cannot be properly decoded as YAML.
 339
 340 =cut
 341
 342 sub yaml_preference {
 343     my ( $self, $preference ) = @_;
 344
 345     my $yaml = eval { YAML::XS::Load( Encode::encode_utf8( $self->preference( $preference ) ) ); };
 346     if ($@) {
 347         warn "Unable to parse $preference syspref : $@";
 348         return;
 349     }
 350
 351     # TODO Remove next line when enforced elsewhere
 352     if( $yaml && lc($preference) eq 'itemsdeniedrenewal' and ref($yaml) ne 'HASH' ) { warn "Hashref expected for $preference"; return; }
 353     return $yaml;
 354 }
 355
 356 =head2 enable_syspref_cache
 357
 358   C4::Context->enable_syspref_cache();
 359
 360 Enable the in-memory syspref cache used by C4::Context. This is the
 361 default behavior.
 362
 363 =cut
 364
 365 sub enable_syspref_cache {
 366     my ($self) = @_;
 367     $use_syspref_cache = 1;
 368     # We need to clear the cache to have it up-to-date
 369     $self->clear_syspref_cache();
 370 }
 371
 372 =head2 disable_syspref_cache
 373
 374   C4::Context->disable_syspref_cache();
 375
 376 Disable the in-memory syspref cache used by C4::Context. This should be
 377 used with Plack and other persistent environments.
 378
 379 =cut
 380
 381 sub disable_syspref_cache {
 382     my ($self) = @_;
 383     $use_syspref_cache = 0;
 384     $self->clear_syspref_cache();
 385 }
 386
 387 =head2 clear_syspref_cache
 388
 389   C4::Context->clear_syspref_cache();
 390
 391 cleans the internal cache of sysprefs. Please call this method if
 392 you update the systempreferences table. Otherwise, your new changes
 393 will not be seen by this process.
 394
 395 =cut
 396
 397 sub clear_syspref_cache {
 398     return unless $use_syspref_cache;
 399     my $syspref_cache = Koha::Caches->get_instance('syspref');
 400     $syspref_cache->flush_all;
 401 }
 402
 403 =head2 set_preference
 404
 405   C4::Context->set_preference( $variable, $value, [ $explanation, $type, $options ] );
 406
 407 This updates a preference's value both in the systempreferences table and in
 408 the sysprefs cache. If the optional parameters are provided, then the query
 409 becomes a create. It won't update the parameters (except value) for an existing
 410 preference.
 411
 412 =cut
 413
 414 sub set_preference {
 415     my ( $self, $variable, $value, $explanation, $type, $options ) = @_;
 416
 417     my $variable_case = $variable;
 418     $variable = lc $variable;
 419
 420     my $syspref = Koha::Config::SysPrefs->find($variable);
 421     $type =
 422         $type    ? $type
 423       : $syspref ? $syspref->type
 424       :            undef;
 425
 426     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 427
 428     # force explicit protocol on OPACBaseURL
 429     if ( $variable eq 'opacbaseurl' && $value && substr( $value, 0, 4 ) !~ /http/ ) {
 430         $value = 'http://' . $value;
 431     }
 432
 433     if ($syspref) {
 434         $syspref->set(
 435             {   ( defined $value ? ( value       => $value )       : () ),
 436                 ( $explanation   ? ( explanation => $explanation ) : () ),
 437                 ( $type          ? ( type        => $type )        : () ),
 438                 ( $options       ? ( options     => $options )     : () ),
 439             }
 440         )->store;
 441     } else {
 442         $syspref = Koha::Config::SysPref->new(
 443             {   variable    => $variable_case,
 444                 value       => $value,
 445                 explanation => $explanation || undef,
 446                 type        => $type,
 447                 options     => $options || undef,
 448             }
 449         )->store();
 450     }
 451
 452     if ( $use_syspref_cache ) {
 453         my $syspref_cache = Koha::Caches->get_instance('syspref');
 454         $syspref_cache->set_in_cache( "syspref_$variable", $value );
 455     }
 456
 457     return $syspref;
 458 }
 459
 460 =head2 delete_preference
 461
 462     C4::Context->delete_preference( $variable );
 463
 464 This deletes a system preference from the database. Returns a true value on
 465 success. Failure means there was an issue with the database, not that there
 466 was no syspref of the name.
 467
 468 =cut
 469
 470 sub delete_preference {
 471     my ( $self, $var ) = @_;
 472
 473     if ( Koha::Config::SysPrefs->find( $var )->delete ) {
 474         if ( $use_syspref_cache ) {
 475             my $syspref_cache = Koha::Caches->get_instance('syspref');
 476             $syspref_cache->clear_from_cache("syspref_$var");
 477         }
 478
 479         return 1;
 480     }
 481     return 0;
 482 }
 483
 484 =head2 csv_delimiter
 485
 486     $delimiter = C4::Context->csv_delimiter;
 487
 488     Returns preferred CSV delimiter, using system preference 'CSVDelimiter'.
 489     If this preference is missing or empty, comma will be returned.
 490     This method is needed because of special behavior for tabulation.
 491
 492     You can, optionally, pass a value parameter to this routine
 493     in the case of existing delimiter.
 494
 495 =cut
 496
 497 sub csv_delimiter {
 498     my ( $self, $value ) = @_;
 499     my $delimiter = $value || $self->preference('CSVDelimiter') || ',';
 500     $delimiter = "\t" if $delimiter eq 'tabulation';
 501     return $delimiter;
 502 }
 503
 504 =head2 default_catalog_sort_by
 505
 506     $delimiter = C4::Context->default_catalog_sort_by;
 507
 508     Returns default sort by for catalog search.
 509     For relevance no sort order is used.
 510
 511     For staff interface, depends on system preferences 'defaultSortField' and 'defaultSortOrder'.
 512     For OPAC interface, depends on system preferences 'OPACdefaultSortField' and 'OPACdefaultSortOrder'.
 513
 514 =cut
 515
 516 sub default_catalog_sort_by {
 517     my $self = shift;
 518     my ( $sort_by, $sort_field, $sort_order );
 519     if ( C4::Context->interface eq 'opac' ) {
 520         $sort_field = C4::Context->preference('OPACdefaultSortField');
 521         $sort_order = C4::Context->preference('OPACdefaultSortOrder');
 522     } else {
 523         $sort_field = C4::Context->preference('defaultSortField');
 524         $sort_order = C4::Context->preference('defaultSortOrder');
 525     }
 526     if ( $sort_field && $sort_order ) {
 527         if ( $sort_field eq 'relevance' ) {
 528             $sort_by = $sort_field;
 529         } else {
 530             $sort_by = $sort_field . '_' . $sort_order;
 531         }
 532     }
 533     return $sort_by;
 534 }
 535
 536 =head2 Zconn
 537
 538   $Zconn = C4::Context->Zconn
 539
 540 Returns a connection to the Zebra database
 541
 542 C<$self>
 543
 544 C<$server> one of the servers defined in the koha-conf.xml file
 545
 546 C<$async> whether this is a asynchronous connection
 547
 548 =cut
 549
 550 sub Zconn {
 551     my ($self, $server, $async ) = @_;
 552     my $cache_key = join ('::', (map { $_ // '' } ($server, $async )));
 553     if ( (!defined($ENV{GATEWAY_INTERFACE})) && defined($context->{"Zconn"}->{$cache_key}) && (0 == $context->{"Zconn"}->{$cache_key}->errcode()) ) {
 554         # if we are running the script from the commandline, lets try to use the caching
 555         return $context->{"Zconn"}->{$cache_key};
 556     }
 557     $context->{"Zconn"}->{$cache_key}->destroy() if defined($context->{"Zconn"}->{$cache_key}); #destroy old connection before making a new one
 558     $context->{"Zconn"}->{$cache_key} = &_new_Zconn( $server, $async );
 559     return $context->{"Zconn"}->{$cache_key};
 560 }
 561
 562 =head2 _new_Zconn
 563
 564 $context->{"Zconn"} = &_new_Zconn($server,$async);
 565
 566 Internal function. Creates a new database connection from the data given in the current context and returns it.
 567
 568 C<$server> one of the servers defined in the koha-conf.xml file
 569
 570 C<$async> whether this is a asynchronous connection
 571
 572 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 573
 574 =cut
 575
 576 sub _new_Zconn {
 577     my ( $server, $async ) = @_;
 578
 579     my $tried=0; # first attempt
 580     my $Zconn; # connection object
 581     my $elementSetName;
 582     my $syntax;
 583
 584     $server //= "biblioserver";
 585
 586     $syntax = 'xml';
 587     $elementSetName = 'marcxml';
 588
 589     my $host = _common_config($server, 'listen')->{content};
 590     my $serverinfo = _common_config($server, 'serverinfo');
 591     my $user = $serverinfo->{user};
 592     my $password = $serverinfo->{password};
 593     eval {
 594         # set options
 595         my $o = ZOOM::Options->new();
 596         $o->option(user => $user) if $user && $password;
 597         $o->option(password => $password) if $user && $password;
 598         $o->option(async => 1) if $async;
 599         $o->option(cqlfile=> _common_config($server, 'server')->{cql2rpn});
 600         $o->option(cclfile=> $serverinfo->{ccl2rpn});
 601         $o->option(preferredRecordSyntax => $syntax);
 602         $o->option(elementSetName => $elementSetName) if $elementSetName;
 603         $o->option(databaseName => _common_config($server, 'config') || 'biblios');
 604         my $timeout = C4::Context->config('zebra_connection_timeout') || 30;
 605         $o->option(timeout => $timeout);
 606
 607         # create a new connection object
 608         $Zconn= create ZOOM::Connection($o);
 609
 610         # forge to server
 611         $Zconn->connect($host, 0);
 612
 613         # check for errors and warn
 614         if ($Zconn->errcode() !=0) {
 615             warn "something wrong with the connection: ". $Zconn->errmsg();
 616         }
 617     };
 618     return $Zconn;
 619 }
 620
 621 # _new_dbh
 622 # Internal helper function (not a method!). This creates a new
 623 # database connection from the data given in the current context, and
 624 # returns it.
 625 sub _new_dbh
 626 {
 627
 628     Koha::Database->schema({ new => 1 })->storage->dbh;
 629 }
 630
 631 =head2 dbh
 632
 633   $dbh = C4::Context->dbh;
 634
 635 Returns a database handle connected to the Koha database for the
 636 current context. If no connection has yet been made, this method
 637 creates one, and connects to the database.
 638
 639 This database handle is cached for future use: if you call
 640 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 641 times. If you need a second database handle, use C<&new_dbh> and
 642 possibly C<&set_dbh>.
 643
 644 =cut
 645
 646 #'
 647 sub dbh
 648 {
 649     my $self = shift;
 650     my $params = shift;
 651
 652     unless ( $params->{new} ) {
 653         return Koha::Database->schema->storage->dbh;
 654     }
 655
 656     return Koha::Database->schema({ new => 1 })->storage->dbh;
 657 }
 658
 659 =head2 new_dbh
 660
 661   $dbh = C4::Context->new_dbh;
 662
 663 Creates a new connection to the Koha database for the current context,
 664 and returns the database handle (a C<DBI::db> object).
 665
 666 The handle is not saved anywhere: this method is strictly a
 667 convenience function; the point is that it knows which database to
 668 connect to so that the caller doesn't have to know.
 669
 670 =cut
 671
 672 #'
 673 sub new_dbh
 674 {
 675     my $self = shift;
 676
 677     return &dbh({ new => 1 });
 678 }
 679
 680 =head2 set_dbh
 681
 682   $my_dbh = C4::Connect->new_dbh;
 683   C4::Connect->set_dbh($my_dbh);
 684   ...
 685   C4::Connect->restore_dbh;
 686
 687 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 688 C<&set_context> and C<&restore_context>.
 689
 690 C<&set_dbh> saves the current database handle on a stack, then sets
 691 the current database handle to C<$my_dbh>.
 692
 693 C<$my_dbh> is assumed to be a good database handle.
 694
 695 =cut
 696
 697 #'
 698 sub set_dbh
 699 {
 700     my $self = shift;
 701     my $new_dbh = shift;
 702
 703     # Save the current database handle on the handle stack.
 704     # We assume that $new_dbh is all good: if the caller wants to
 705     # screw himself by passing an invalid handle, that's fine by
 706     # us.
 707     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 708     $context->{"dbh"} = $new_dbh;
 709 }
 710
 711 =head2 restore_dbh
 712
 713   C4::Context->restore_dbh;
 714
 715 Restores the database handle saved by an earlier call to
 716 C<C4::Context-E<gt>set_dbh>.
 717
 718 =cut
 719
 720 #'
 721 sub restore_dbh
 722 {
 723     my $self = shift;
 724
 725     if ($#{$context->{"dbh_stack"}} < 0)
 726     {
 727         # Stack underflow
 728         die "DBH stack underflow";
 729     }
 730
 731     # Pop the old database handle and set it.
 732     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 733
 734     # FIXME - If it is determined that restore_context should
 735     # return something, then this function should, too.
 736 }
 737
 738 =head2 userenv
 739
 740   C4::Context->userenv;
 741
 742 Retrieves a hash for user environment variables.
 743
 744 This hash shall be cached for future use: if you call
 745 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
 746
 747 =cut
 748
 749 #'
 750 sub userenv {
 751     my $var = $context->{"activeuser"};
 752     if (defined $var and defined $context->{"userenv"}->{$var}) {
 753         return $context->{"userenv"}->{$var};
 754     } else {
 755         return;
 756     }
 757 }
 758
 759 =head2 set_userenv
 760
 761   C4::Context->set_userenv($usernum, $userid, $usercnum,
 762                            $userfirstname, $usersurname,
 763                            $userbranch, $branchname, $userflags,
 764                            $emailaddress, $shibboleth
 765                            $desk_id, $desk_name,
 766                            $register_id, $register_name);
 767
 768 Establish a hash of user environment variables.
 769
 770 set_userenv is called in Auth.pm
 771
 772 =cut
 773
 774 #'
 775 sub set_userenv {
 776     shift @_;
 777     my (
 778         $usernum,      $userid,     $usercnum,   $userfirstname,
 779         $usersurname,  $userbranch, $branchname, $userflags,
 780         $emailaddress, $shibboleth, $desk_id,    $desk_name,
 781         $register_id,  $register_name
 782     ) = @_;
 783
 784     my $var=$context->{"activeuser"} || '';
 785     my $cell = {
 786         "number"     => $usernum,
 787         "id"         => $userid,
 788         "cardnumber" => $usercnum,
 789         "firstname"  => $userfirstname,
 790         "surname"    => $usersurname,
 791
 792         #possibly a law problem
 793         "branch"        => $userbranch,
 794         "branchname"    => $branchname,
 795         "flags"         => $userflags,
 796         "emailaddress"  => $emailaddress,
 797         "shibboleth"    => $shibboleth,
 798         "desk_id"       => $desk_id,
 799         "desk_name"     => $desk_name,
 800         "register_id"   => $register_id,
 801         "register_name" => $register_name
 802     };
 803     $context->{userenv}->{$var} = $cell;
 804     return $cell;
 805 }
 806
 807 =head2 _new_userenv
 808
 809   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
 810
 811 Builds a hash for user environment variables.
 812
 813 This hash shall be cached for future use: if you call
 814 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
 815
 816 _new_userenv is called in Auth.pm
 817
 818 =cut
 819
 820 #'
 821 sub _new_userenv
 822 {
 823     shift;  # Useless except it compensates for bad calling style
 824     my ($sessionID)= @_;
 825      $context->{"activeuser"}=$sessionID;
 826 }
 827
 828 =head2 _unset_userenv
 829
 830   C4::Context->_unset_userenv;
 831
 832 Destroys the hash for activeuser user environment variables.
 833
 834 =cut
 835
 836 #'
 837
 838 sub _unset_userenv
 839 {
 840     my ($sessionID)= @_;
 841     undef $context->{activeuser} if $sessionID && $context->{activeuser} && $context->{activeuser} eq $sessionID;
 842 }
 843
 844
 845 =head2 get_versions
 846
 847   C4::Context->get_versions
 848
 849 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
 850
 851 =cut
 852
 853 #'
 854
 855 # A little example sub to show more debugging info for CGI::Carp
 856 sub get_versions {
 857     my ( %versions, $mysqlVersion );
 858     $versions{kohaVersion}  = Koha::version();
 859     $versions{kohaDbVersion} = C4::Context->preference('version');
 860     $versions{osVersion} = join(" ", POSIX::uname());
 861     $versions{perlVersion} = $];
 862
 863     my $dbh = C4::Context->dbh;
 864     $mysqlVersion = $dbh->get_info(18) if $dbh; # SQL_DBMS_VER
 865
 866     {
 867         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
 868         $mysqlVersion          ||= `mysql -V`; # fallback to sql client version?
 869         $versions{apacheVersion} = (`apache2ctl -v`)[0];
 870         $versions{apacheVersion} = `httpd -v`             unless  $versions{apacheVersion} ;
 871         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
 872         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
 873         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
 874     }
 875     $versions{mysqlVersion} = $mysqlVersion;
 876     return %versions;
 877 }
 878
 879 =head2 tz
 880
 881   C4::Context->tz
 882
 883   Returns a DateTime::TimeZone object for the system timezone
 884
 885 =cut
 886
 887 sub tz {
 888     my $self = shift;
 889     if (!defined $context->{tz}) {
 890         my $timezone = $context->{config}->timezone;
 891         $context->{tz} = DateTime::TimeZone->new(name => $timezone);
 892     }
 893     return $context->{tz};
 894 }
 895
 896
 897 =head2 IsSuperLibrarian
 898
 899     C4::Context->IsSuperLibrarian();
 900
 901 =cut
 902
 903 sub IsSuperLibrarian {
 904     my $userenv = C4::Context->userenv;
 905
 906     unless ( $userenv and exists $userenv->{flags} ) {
 907         # If we reach this without a user environment,
 908         # assume that we're running from a command-line script,
 909         # and act as a superlibrarian.
 910         carp("C4::Context->userenv not defined!");
 911         return 1;
 912     }
 913
 914     return ($userenv->{flags}//0) % 2;
 915 }
 916
 917 =head2 interface
 918
 919 Sets the current interface for later retrieval in any Perl module
 920
 921     C4::Context->interface('opac');
 922     C4::Context->interface('intranet');
 923     my $interface = C4::Context->interface;
 924
 925 =cut
 926
 927 sub interface {
 928     my ($class, $interface) = @_;
 929
 930     if (defined $interface) {
 931         $interface = lc $interface;
 932         if (   $interface eq 'api'
 933             || $interface eq 'opac'
 934             || $interface eq 'intranet'
 935             || $interface eq 'sip'
 936             || $interface eq 'cron'
 937             || $interface eq 'commandline' )
 938         {
 939             $context->{interface} = $interface;
 940         } else {
 941             warn "invalid interface : '$interface'";
 942         }
 943     }
 944
 945     return $context->{interface} // 'opac';
 946 }
 947
 948 # always returns a string for OK comparison via "eq" or "ne"
 949 sub mybranch {
 950     C4::Context->userenv           or return '';
 951     return C4::Context->userenv->{branch} || '';
 952 }
 953
 954 =head2 only_my_library
 955
 956     my $test = C4::Context->only_my_library;
 957
 958     Returns true if you enabled IndependentBranches and the current user
 959     does not have superlibrarian permissions.
 960
 961 =cut
 962
 963 sub only_my_library {
 964     return
 965          C4::Context->preference('IndependentBranches')
 966       && C4::Context->userenv
 967       && !C4::Context->IsSuperLibrarian()
 968       && C4::Context->userenv->{branch};
 969 }
 970
 971 =head3 temporary_directory
 972
 973 Returns root directory for temporary storage
 974
 975 =cut
 976
 977 sub temporary_directory {
 978     my ( $class ) = @_;
 979     return C4::Context->config('tmp_path') || File::Spec->tmpdir;
 980 }
 981
 982 =head3 set_remote_address
 983
 984 set_remote_address should be called at the beginning of every script
 985 that is *not* running under plack in order to the REMOTE_ADDR environment
 986 variable to be set correctly.
 987
 988 =cut
 989
 990 sub set_remote_address {
 991     if ( C4::Context->config('koha_trusted_proxies') ) {
 992         require CGI;
 993         my $header = CGI->http('HTTP_X_FORWARDED_FOR');
 994
 995         if ($header) {
 996             require Koha::Middleware::RealIP;
 997             $ENV{REMOTE_ADDR} = Koha::Middleware::RealIP::get_real_ip( $ENV{REMOTE_ADDR}, $header );
 998         }
 999     }
1000 }
1001
1002 =head3 https_enabled
1003
1004 https_enabled should be called when checking if a HTTPS connection
1005 is used.
1006
1007 Note that this depends on a HTTPS environmental variable being defined
1008 by the web server. This function may not return the expected result,
1009 if your web server or reverse proxies are not setting the correct
1010 X-Forwarded-Proto headers and HTTPS environmental variable.
1011
1012 Note too that the HTTPS value can vary from web server to web server.
1013 We are relying on the convention of the value being "on" or "ON" here.
1014
1015 =cut
1016
1017 sub https_enabled {
1018     my $https_enabled = 0;
1019     my $env_https = $ENV{HTTPS};
1020     if ($env_https){
1021         if ($env_https =~ /^ON$/i){
1022             $https_enabled = 1;
1023         }
1024     }
1025     return $https_enabled;
1026 }
1027
1028 1;
1029
1030 =head3 needs_install
1031
1032     if ( $context->needs_install ) { ... }
1033
1034 This method returns a boolean representing the install status of the Koha instance.
1035
1036 =cut
1037
1038 sub needs_install {
1039     my ($self) = @_;
1040     return ($self->preference('Version')) ? 0 : 1;
1041 }
1042
1043 =head3 psgi_env
1044
1045 psgi_env returns true if there is an environmental variable
1046 prefixed with "psgi" or "plack". This is useful for detecting whether
1047 this is a PSGI app or a CGI app, and implementing code as appropriate.
1048
1049 =cut
1050
1051 sub psgi_env {
1052     my ( $self ) = @_;
1053     return any { /^(psgi\.|plack\.|PLACK_ENV$)/i } keys %ENV;
1054 }
1055
1056 =head3 is_internal_PSGI_request
1057
1058 is_internal_PSGI_request is used to detect if this request was made
1059 from within the individual PSGI app or externally from the mounted PSGI
1060 app
1061
1062 =cut
1063
1064 #NOTE: This is not a very robust method but it's the best we have so far
1065 sub is_internal_PSGI_request {
1066     my ( $self ) = @_;
1067     my $is_internal = 0;
1068     if( $self->psgi_env && ( $ENV{REQUEST_URI} !~ /^(\/intranet|\/opac)/ ) ) {
1069         $is_internal = 1;
1070     }
1071     return $is_internal;
1072 }
1073
1074 __END__
1075
1076 =head1 ENVIRONMENT
1077
1078 =head2 C<KOHA_CONF>
1079
1080 Specifies the configuration file to read.
1081
1082 =head1 AUTHORS
1083
1084 Andrew Arensburger <arensb at ooblick dot com>
1085
1086 Joshua Ferraro <jmf at liblime dot com>
1087