C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along
  16 # with Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22
  23 BEGIN {
  24         if ($ENV{'HTTP_USER_AGENT'})    {
  25                 require CGI::Carp;
  26         # FIXME for future reference, CGI::Carp doc says
  27         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  28                 import CGI::Carp qw(fatalsToBrowser);
  29                         sub handle_errors {
  30                             my $msg = shift;
  31                             my $debug_level;
  32                             eval {C4::Context->dbh();};
  33                             if ($@){
  34                                 $debug_level = 1;
  35                             }
  36                             else {
  37                                 $debug_level =  C4::Context->preference("DebugLevel");
  38                             }
  39
  40                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  41                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  42                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  43                        <head><title>Koha Error</title></head>
  44                        <body>
  45                 );
  46                                 if ($debug_level eq "2"){
  47                                         # debug 2 , print extra info too.
  48                                         my %versions = get_versions();
  49
  50                 # a little example table with various version info";
  51                                         print "
  52                                                 <h1>Koha error</h1>
  53                                                 <p>The following fatal error has occurred:</p>
  54                         <pre><code>$msg</code></pre>
  55                                                 <table>
  56                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  57                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  58                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  59                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  60                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  61                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  62                                                 </table>";
  63
  64                                 } elsif ($debug_level eq "1"){
  65                                         print "
  66                                                 <h1>Koha error</h1>
  67                                                 <p>The following fatal error has occurred:</p>
  68                         <pre><code>$msg</code></pre>";
  69                                 } else {
  70                                         print "<p>production mode - trapped fatal error</p>";
  71                                 }
  72                 print "</body></html>";
  73                         }
  74                 #CGI::Carp::set_message(\&handle_errors);
  75                 ## give a stack backtrace if KOHA_BACKTRACES is set
  76                 ## can't rely on DebugLevel for this, as we're not yet connected
  77                 if ($ENV{KOHA_BACKTRACES}) {
  78                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  79                 }
  80     }   # else there is no browser to send fatals to!
  81
  82     # Check if there are memcached servers set
  83     $servers = $ENV{'MEMCACHED_SERVERS'};
  84     if ($servers) {
  85         # Load required libraries and create the memcached object
  86         require Cache::Memcached;
  87         $memcached = Cache::Memcached->new({
  88         servers => [ $servers ],
  89         debug   => 0,
  90         compress_threshold => 10_000,
  91         expire_time => 600,
  92         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  93     });
  94         # Verify memcached available (set a variable and test the output)
  95     $ismemcached = $memcached->set('ismemcached','1');
  96     }
  97
  98     $VERSION = '3.07.00.049';
  99 }
 100
 101 use DBI;
 102 use ZOOM;
 103 use XML::Simple;
 104 use C4::Boolean;
 105 use C4::Debug;
 106 use POSIX ();
 107 use DateTime::TimeZone;
 108 use Module::Load::Conditional qw(can_load);
 109
 110 =head1 NAME
 111
 112 C4::Context - Maintain and manipulate the context of a Koha script
 113
 114 =head1 SYNOPSIS
 115
 116   use C4::Context;
 117
 118   use C4::Context("/path/to/koha-conf.xml");
 119
 120   $config_value = C4::Context->config("config_variable");
 121
 122   $koha_preference = C4::Context->preference("preference");
 123
 124   $db_handle = C4::Context->dbh;
 125
 126   $Zconn = C4::Context->Zconn;
 127
 128   $stopwordhash = C4::Context->stopwords;
 129
 130 =head1 DESCRIPTION
 131
 132 When a Koha script runs, it makes use of a certain number of things:
 133 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 134 databases, and so forth. These things make up the I<context> in which
 135 the script runs.
 136
 137 This module takes care of setting up the context for a script:
 138 figuring out which configuration file to load, and loading it, opening
 139 a connection to the right database, and so forth.
 140
 141 Most scripts will only use one context. They can simply have
 142
 143   use C4::Context;
 144
 145 at the top.
 146
 147 Other scripts may need to use several contexts. For instance, if a
 148 library has two databases, one for a certain collection, and the other
 149 for everything else, it might be necessary for a script to use two
 150 different contexts to search both databases. Such scripts should use
 151 the C<&set_context> and C<&restore_context> functions, below.
 152
 153 By default, C4::Context reads the configuration from
 154 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 155 environment variable to the pathname of a configuration file to use.
 156
 157 =head1 METHODS
 158
 159 =cut
 160
 161 #'
 162 # In addition to what is said in the POD above, a Context object is a
 163 # reference-to-hash with the following fields:
 164 #
 165 # config
 166 #    A reference-to-hash whose keys and values are the
 167 #    configuration variables and values specified in the config
 168 #    file (/etc/koha/koha-conf.xml).
 169 # dbh
 170 #    A handle to the appropriate database for this context.
 171 # dbh_stack
 172 #    Used by &set_dbh and &restore_dbh to hold other database
 173 #    handles for this context.
 174 # Zconn
 175 #     A connection object for the Zebra server
 176
 177 # Koha's main configuration file koha-conf.xml
 178 # is searched for according to this priority list:
 179 #
 180 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 181 # 2. Path supplied in KOHA_CONF environment variable.
 182 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 183 #    as value has changed from its default of
 184 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 185 #    when Koha is installed in 'standard' or 'single'
 186 #    mode.
 187 # 4. Path supplied in CONFIG_FNAME.
 188 #
 189 # The first entry that refers to a readable file is used.
 190
 191 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 192                 # Default config file, if none is specified
 193
 194 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 195                 # path to config file set by installer
 196                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 197                 # when Koha is installed in 'standard' or 'single'
 198                 # mode.  If Koha was installed in 'dev' mode,
 199                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 200                 # developers should set the KOHA_CONF environment variable
 201
 202 $context = undef;        # Initially, no context is set
 203 @context_stack = ();        # Initially, no saved contexts
 204
 205
 206 =head2 KOHAVERSION
 207
 208 returns the kohaversion stored in kohaversion.pl file
 209
 210 =cut
 211
 212 sub KOHAVERSION {
 213     my $cgidir = C4::Context->intranetdir;
 214
 215     # Apparently the GIT code does not run out of a CGI-BIN subdirectory
 216     # but distribution code does?  (Stan, 1jan08)
 217     if(-d $cgidir . "/cgi-bin"){
 218         my $cgidir .= "/cgi-bin";
 219     }
 220
 221     do $cgidir."/kohaversion.pl" || die "NO $cgidir/kohaversion.pl";
 222     return kohaversion();
 223 }
 224
 225 =head2 final_linear_version
 226
 227 Returns the version number of the final update to run in updatedatabase.pl.
 228 This number is equal to the version in kohaversion.pl
 229
 230 =cut
 231
 232 sub final_linear_version {
 233     return KOHAVERSION;
 234 }
 235
 236 =head2 read_config_file
 237
 238 Reads the specified Koha config file.
 239
 240 Returns an object containing the configuration variables. The object's
 241 structure is a bit complex to the uninitiated ... take a look at the
 242 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 243 here are a few examples that may give you what you need:
 244
 245 The simple elements nested within the <config> element:
 246
 247     my $pass = $koha->{'config'}->{'pass'};
 248
 249 The <listen> elements:
 250
 251     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 252
 253 The elements nested within the <server> element:
 254
 255     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 256
 257 Returns undef in case of error.
 258
 259 =cut
 260
 261 sub read_config_file {          # Pass argument naming config file to read
 262     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 263
 264     if ($ismemcached) {
 265       $memcached->set('kohaconf',$koha);
 266     }
 267
 268     return $koha;                       # Return value: ref-to-hash holding the configuration
 269 }
 270
 271 =head2 ismemcached
 272
 273 Returns the value of the $ismemcached variable (0/1)
 274
 275 =cut
 276
 277 sub ismemcached {
 278     return $ismemcached;
 279 }
 280
 281 =head2 memcached
 282
 283 If $ismemcached is true, returns the $memcache variable.
 284 Returns undef otherwise
 285
 286 =cut
 287
 288 sub memcached {
 289     if ($ismemcached) {
 290       return $memcached;
 291     } else {
 292       return;
 293     }
 294 }
 295
 296 # db_scheme2dbi
 297 # Translates the full text name of a database into de appropiate dbi name
 298 #
 299 sub db_scheme2dbi {
 300     my $name = shift;
 301     # for instance, we support only mysql, so don't care checking
 302     return "mysql";
 303     for ($name) {
 304 # FIXME - Should have other databases.
 305         if (/mysql/) { return("mysql"); }
 306         if (/Postgres|Pg|PostgresSQL/) { return("Pg"); }
 307         if (/oracle/) { return("Oracle"); }
 308     }
 309     return;         # Just in case
 310 }
 311
 312 sub import {
 313     # Create the default context ($C4::Context::Context)
 314     # the first time the module is called
 315     # (a config file can be optionaly passed)
 316
 317     # default context allready exists?
 318     return if $context;
 319
 320     # no ? so load it!
 321     my ($pkg,$config_file) = @_ ;
 322     my $new_ctx = __PACKAGE__->new($config_file);
 323     return unless $new_ctx;
 324
 325     # if successfully loaded, use it by default
 326     $new_ctx->set_context;
 327     1;
 328 }
 329
 330 =head2 new
 331
 332   $context = new C4::Context;
 333   $context = new C4::Context("/path/to/koha-conf.xml");
 334
 335 Allocates a new context. Initializes the context from the specified
 336 file, which defaults to either the file given by the C<$KOHA_CONF>
 337 environment variable, or F</etc/koha/koha-conf.xml>.
 338
 339 It saves the koha-conf.xml values in the declared memcached server(s)
 340 if currently available and uses those values until them expire and
 341 re-reads them.
 342
 343 C<&new> does not set this context as the new default context; for
 344 that, use C<&set_context>.
 345
 346 =cut
 347
 348 #'
 349 # Revision History:
 350 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 351 sub new {
 352     my $class = shift;
 353     my $conf_fname = shift;        # Config file to load
 354     my $self = {};
 355
 356     # check that the specified config file exists and is not empty
 357     undef $conf_fname unless
 358         (defined $conf_fname && -s $conf_fname);
 359     # Figure out a good config file to load if none was specified.
 360     if (!defined($conf_fname))
 361     {
 362         # If the $KOHA_CONF environment variable is set, use
 363         # that. Otherwise, use the built-in default.
 364         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 365             $conf_fname = $ENV{"KOHA_CONF"};
 366         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 367             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 368             # regex to anything else -- don't want installer to rewrite it
 369             $conf_fname = $INSTALLED_CONFIG_FNAME;
 370         } elsif (-s CONFIG_FNAME) {
 371             $conf_fname = CONFIG_FNAME;
 372         } else {
 373             warn "unable to locate Koha configuration file koha-conf.xml";
 374             return;
 375         }
 376     }
 377
 378     if ($ismemcached) {
 379         # retreive from memcached
 380         $self = $memcached->get('kohaconf');
 381         if (not defined $self) {
 382             # not in memcached yet
 383             $self = read_config_file($conf_fname);
 384         }
 385     } else {
 386         # non-memcached env, read from file
 387         $self = read_config_file($conf_fname);
 388     }
 389
 390     $self->{"config_file"} = $conf_fname;
 391     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 392     return if !defined($self->{"config"});
 393
 394     $self->{"dbh"} = undef;        # Database handle
 395     $self->{"Zconn"} = undef;    # Zebra Connections
 396     $self->{"stopwords"} = undef; # stopwords list
 397     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 398     $self->{"userenv"} = undef;        # User env
 399     $self->{"activeuser"} = undef;        # current active user
 400     $self->{"shelves"} = undef;
 401     $self->{tz} = undef; # local timezone object
 402
 403     bless $self, $class;
 404     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 405     return $self;
 406 }
 407
 408 =head2 set_context
 409
 410   $context = new C4::Context;
 411   $context->set_context();
 412 or
 413   set_context C4::Context $context;
 414
 415   ...
 416   restore_context C4::Context;
 417
 418 In some cases, it might be necessary for a script to use multiple
 419 contexts. C<&set_context> saves the current context on a stack, then
 420 sets the context to C<$context>, which will be used in future
 421 operations. To restore the previous context, use C<&restore_context>.
 422
 423 =cut
 424
 425 #'
 426 sub set_context
 427 {
 428     my $self = shift;
 429     my $new_context;    # The context to set
 430
 431     # Figure out whether this is a class or instance method call.
 432     #
 433     # We're going to make the assumption that control got here
 434     # through valid means, i.e., that the caller used an instance
 435     # or class method call, and that control got here through the
 436     # usual inheritance mechanisms. The caller can, of course,
 437     # break this assumption by playing silly buggers, but that's
 438     # harder to do than doing it properly, and harder to check
 439     # for.
 440     if (ref($self) eq "")
 441     {
 442         # Class method. The new context is the next argument.
 443         $new_context = shift;
 444     } else {
 445         # Instance method. The new context is $self.
 446         $new_context = $self;
 447     }
 448
 449     # Save the old context, if any, on the stack
 450     push @context_stack, $context if defined($context);
 451
 452     # Set the new context
 453     $context = $new_context;
 454 }
 455
 456 =head2 restore_context
 457
 458   &restore_context;
 459
 460 Restores the context set by C<&set_context>.
 461
 462 =cut
 463
 464 #'
 465 sub restore_context
 466 {
 467     my $self = shift;
 468
 469     if ($#context_stack < 0)
 470     {
 471         # Stack underflow.
 472         die "Context stack underflow";
 473     }
 474
 475     # Pop the old context and set it.
 476     $context = pop @context_stack;
 477
 478     # FIXME - Should this return something, like maybe the context
 479     # that was current when this was called?
 480 }
 481
 482 =head2 config
 483
 484   $value = C4::Context->config("config_variable");
 485
 486   $value = C4::Context->config_variable;
 487
 488 Returns the value of a variable specified in the configuration file
 489 from which the current context was created.
 490
 491 The second form is more compact, but of course may conflict with
 492 method names. If there is a configuration variable called "new", then
 493 C<C4::Config-E<gt>new> will not return it.
 494
 495 =cut
 496
 497 sub _common_config {
 498         my $var = shift;
 499         my $term = shift;
 500     return if !defined($context->{$term});
 501        # Presumably $self->{$term} might be
 502        # undefined if the config file given to &new
 503        # didn't exist, and the caller didn't bother
 504        # to check the return value.
 505
 506     # Return the value of the requested config variable
 507     return $context->{$term}->{$var};
 508 }
 509
 510 sub config {
 511         return _common_config($_[1],'config');
 512 }
 513 sub zebraconfig {
 514         return _common_config($_[1],'server');
 515 }
 516 sub ModZebrations {
 517         return _common_config($_[1],'serverinfo');
 518 }
 519
 520 =head2 preference
 521
 522   $sys_preference = C4::Context->preference('some_variable');
 523
 524 Looks up the value of the given system preference in the
 525 systempreferences table of the Koha database, and returns it. If the
 526 variable is not set or does not exist, undef is returned.
 527
 528 In case of an error, this may return 0.
 529
 530 Note: It is impossible to tell the difference between system
 531 preferences which do not exist, and those whose values are set to NULL
 532 with this method.
 533
 534 =cut
 535
 536 # FIXME: running this under mod_perl will require a means of
 537 # flushing the caching mechanism.
 538
 539 my %sysprefs;
 540 my $use_syspref_cache = 1;
 541
 542 sub preference {
 543     my $self = shift;
 544     my $var  = lc(shift);                          # The system preference to return
 545
 546     if ($use_syspref_cache && exists $sysprefs{$var}) {
 547         return $sysprefs{$var};
 548     }
 549
 550     my $dbh  = C4::Context->dbh or return 0;
 551
 552     # Look up systempreferences.variable==$var
 553     my $sql = <<'END_SQL';
 554         SELECT    value
 555         FROM    systempreferences
 556         WHERE    variable=?
 557         LIMIT    1
 558 END_SQL
 559     $sysprefs{$var} = $dbh->selectrow_array( $sql, {}, $var );
 560     return $sysprefs{$var};
 561 }
 562
 563 sub boolean_preference {
 564     my $self = shift;
 565     my $var = shift;        # The system preference to return
 566     my $it = preference($self, $var);
 567     return defined($it)? C4::Boolean::true_p($it): undef;
 568 }
 569
 570 =head2 enable_syspref_cache
 571
 572   C4::Context->enable_syspref_cache();
 573
 574 Enable the in-memory syspref cache used by C4::Context. This is the
 575 default behavior.
 576
 577 =cut
 578
 579 sub enable_syspref_cache {
 580     my ($self) = @_;
 581     $use_syspref_cache = 1;
 582 }
 583
 584 =head2 disable_syspref_cache
 585
 586   C4::Context->disable_syspref_cache();
 587
 588 Disable the in-memory syspref cache used by C4::Context. This should be
 589 used with Plack and other persistent environments.
 590
 591 =cut
 592
 593 sub disable_syspref_cache {
 594     my ($self) = @_;
 595     $use_syspref_cache = 0;
 596     $self->clear_syspref_cache();
 597 }
 598
 599 =head2 clear_syspref_cache
 600
 601   C4::Context->clear_syspref_cache();
 602
 603 cleans the internal cache of sysprefs. Please call this method if
 604 you update the systempreferences table. Otherwise, your new changes
 605 will not be seen by this process.
 606
 607 =cut
 608
 609 sub clear_syspref_cache {
 610     %sysprefs = ();
 611 }
 612
 613 =head2 set_preference
 614
 615   C4::Context->set_preference( $variable, $value );
 616
 617 This updates a preference's value both in the systempreferences table and in
 618 the sysprefs cache.
 619
 620 =cut
 621
 622 sub set_preference {
 623     my $self = shift;
 624     my $var = lc(shift);
 625     my $value = shift;
 626
 627     my $dbh = C4::Context->dbh or return 0;
 628
 629     my $type = $dbh->selectrow_array( "SELECT type FROM systempreferences WHERE variable = ?", {}, $var );
 630
 631     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 632
 633     my $sth = $dbh->prepare( "
 634       INSERT INTO systempreferences
 635         ( variable, value )
 636         VALUES( ?, ? )
 637         ON DUPLICATE KEY UPDATE value = VALUES(value)
 638     " );
 639
 640     if($sth->execute( $var, $value )) {
 641         $sysprefs{$var} = $value;
 642     }
 643     $sth->finish;
 644 }
 645
 646 # AUTOLOAD
 647 # This implements C4::Config->foo, and simply returns
 648 # C4::Context->config("foo"), as described in the documentation for
 649 # &config, above.
 650
 651 # FIXME - Perhaps this should be extended to check &config first, and
 652 # then &preference if that fails. OTOH, AUTOLOAD could lead to crappy
 653 # code, so it'd probably be best to delete it altogether so as not to
 654 # encourage people to use it.
 655 sub AUTOLOAD
 656 {
 657     my $self = shift;
 658
 659     $AUTOLOAD =~ s/.*:://;        # Chop off the package name,
 660                     # leaving only the function name.
 661     return $self->config($AUTOLOAD);
 662 }
 663
 664 =head2 Zconn
 665
 666   $Zconn = C4::Context->Zconn
 667
 668 Returns a connection to the Zebra database for the current
 669 context. If no connection has yet been made, this method
 670 creates one and connects.
 671
 672 C<$self>
 673
 674 C<$server> one of the servers defined in the koha-conf.xml file
 675
 676 C<$async> whether this is a asynchronous connection
 677
 678 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 679
 680
 681 =cut
 682
 683 sub Zconn {
 684     my $self=shift;
 685     my $server=shift;
 686     my $async=shift;
 687     my $auth=shift;
 688     my $piggyback=shift;
 689     my $syntax=shift;
 690     if ( defined($context->{"Zconn"}->{$server}) && (0 == $context->{"Zconn"}->{$server}->errcode()) ) {
 691         return $context->{"Zconn"}->{$server};
 692     # No connection object or it died. Create one.
 693     }else {
 694         # release resources if we're closing a connection and making a new one
 695         # FIXME: this needs to be smarter -- an error due to a malformed query or
 696         # a missing index does not necessarily require us to close the connection
 697         # and make a new one, particularly for a batch job.  However, at
 698         # first glance it does not look like there's a way to easily check
 699         # the basic health of a ZOOM::Connection
 700         $context->{"Zconn"}->{$server}->destroy() if defined($context->{"Zconn"}->{$server});
 701
 702         $context->{"Zconn"}->{$server} = &_new_Zconn($server,$async,$auth,$piggyback,$syntax);
 703         $context->{ Zconn }->{ $server }->option(
 704             preferredRecordSyntax => C4::Context->preference("marcflavour") );
 705         return $context->{"Zconn"}->{$server};
 706     }
 707 }
 708
 709 =head2 _new_Zconn
 710
 711 $context->{"Zconn"} = &_new_Zconn($server,$async);
 712
 713 Internal function. Creates a new database connection from the data given in the current context and returns it.
 714
 715 C<$server> one of the servers defined in the koha-conf.xml file
 716
 717 C<$async> whether this is a asynchronous connection
 718
 719 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 720
 721 =cut
 722
 723 sub _new_Zconn {
 724     my ($server,$async,$auth,$piggyback,$syntax) = @_;
 725
 726     my $tried=0; # first attempt
 727     my $Zconn; # connection object
 728     $server = "biblioserver" unless $server;
 729     $syntax = "usmarc" unless $syntax;
 730
 731     my $host = $context->{'listen'}->{$server}->{'content'};
 732     my $servername = $context->{"config"}->{$server};
 733     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 734     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 735  $auth = 1 if($user && $password);
 736     retry:
 737     eval {
 738         # set options
 739         my $o = new ZOOM::Options();
 740         $o->option(user=>$user) if $auth;
 741         $o->option(password=>$password) if $auth;
 742         $o->option(async => 1) if $async;
 743         $o->option(count => $piggyback) if $piggyback;
 744         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 745         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 746         $o->option(preferredRecordSyntax => $syntax);
 747         $o->option(elementSetName => "F"); # F for 'full' as opposed to B for 'brief'
 748         $o->option(databaseName => ($servername?$servername:"biblios"));
 749
 750         # create a new connection object
 751         $Zconn= create ZOOM::Connection($o);
 752
 753         # forge to server
 754         $Zconn->connect($host, 0);
 755
 756         # check for errors and warn
 757         if ($Zconn->errcode() !=0) {
 758             warn "something wrong with the connection: ". $Zconn->errmsg();
 759         }
 760
 761     };
 762 #     if ($@) {
 763 #         # Koha manages the Zebra server -- this doesn't work currently for me because of permissions issues
 764 #         # Also, I'm skeptical about whether it's the best approach
 765 #         warn "problem with Zebra";
 766 #         if ( C4::Context->preference("ManageZebra") ) {
 767 #             if ($@->code==10000 && $tried==0) { ##No connection try restarting Zebra
 768 #                 $tried=1;
 769 #                 warn "trying to restart Zebra";
 770 #                 my $res=system("zebrasrv -f $ENV{'KOHA_CONF'} >/koha/log/zebra-error.log");
 771 #                 goto "retry";
 772 #             } else {
 773 #                 warn "Error ", $@->code(), ": ", $@->message(), "\n";
 774 #                 $Zconn="error";
 775 #                 return $Zconn;
 776 #             }
 777 #         }
 778 #     }
 779     return $Zconn;
 780 }
 781
 782 # _new_dbh
 783 # Internal helper function (not a method!). This creates a new
 784 # database connection from the data given in the current context, and
 785 # returns it.
 786 sub _new_dbh
 787 {
 788
 789     ## $context
 790     ## correct name for db_scheme
 791     my $db_driver;
 792     if ($context->config("db_scheme")){
 793         $db_driver=$context->{db_driver};
 794     }else{
 795         $db_driver="mysql";
 796     }
 797
 798     my $db_name   = $context->config("database");
 799     my $db_host   = $context->config("hostname");
 800     my $db_port   = $context->config("port") || '';
 801     my $db_user   = $context->config("user");
 802     my $db_passwd = $context->config("pass");
 803     # MJR added or die here, as we can't work without dbh
 804     my $dbh = DBI->connect("DBI:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 805     $db_user, $db_passwd, {'RaiseError' => $ENV{DEBUG}?1:0 }) or die $DBI::errstr;
 806
 807     # Check for the existence of a systempreference table; if we don't have this, we don't
 808     # have a valid database and should not set RaiseError in order to allow the installer
 809     # to run; installer will not run otherwise since we raise all db errors
 810
 811     eval {
 812                 local $dbh->{PrintError} = 0;
 813                 local $dbh->{RaiseError} = 1;
 814                 $dbh->do(qq{SELECT * FROM systempreferences WHERE 1 = 0 });
 815     };
 816
 817     if ($@) {
 818         $dbh->{RaiseError} = 0;
 819     }
 820
 821     if ( $db_driver eq 'mysql' ) {
 822         $dbh->{mysql_auto_reconnect} = 1;
 823     }
 824
 825         my $tz = $ENV{TZ};
 826     if ( $db_driver eq 'mysql' ) {
 827         # Koha 3.0 is utf-8, so force utf8 communication between mySQL and koha, whatever the mysql default config.
 828         # this is better than modifying my.cnf (and forcing all communications to be in utf8)
 829         $dbh->{'mysql_enable_utf8'}=1; #enable
 830         $dbh->do("set NAMES 'utf8'");
 831         ($tz) and $dbh->do(qq(SET time_zone = "$tz"));
 832     }
 833     elsif ( $db_driver eq 'Pg' ) {
 834             $dbh->do( "set client_encoding = 'UTF8';" );
 835         ($tz) and $dbh->do(qq(SET TIME ZONE = "$tz"));
 836     }
 837     return $dbh;
 838 }
 839
 840 =head2 dbh
 841
 842   $dbh = C4::Context->dbh;
 843
 844 Returns a database handle connected to the Koha database for the
 845 current context. If no connection has yet been made, this method
 846 creates one, and connects to the database.
 847
 848 This database handle is cached for future use: if you call
 849 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 850 times. If you need a second database handle, use C<&new_dbh> and
 851 possibly C<&set_dbh>.
 852
 853 =cut
 854
 855 #'
 856 sub dbh
 857 {
 858     my $self = shift;
 859     my $params = shift;
 860     my $sth;
 861
 862     unless ( $params->{new} ) {
 863         if ( defined($context->{db_driver}) && $context->{db_driver} eq 'mysql' && $context->{"dbh"} ) {
 864             return $context->{"dbh"};
 865         } elsif ( defined($context->{"dbh"}) && $context->{"dbh"}->ping() ) {
 866             return $context->{"dbh"};
 867         }
 868     }
 869
 870     # No database handle or it died . Create one.
 871     $context->{"dbh"} = &_new_dbh();
 872
 873     return $context->{"dbh"};
 874 }
 875
 876 =head2 new_dbh
 877
 878   $dbh = C4::Context->new_dbh;
 879
 880 Creates a new connection to the Koha database for the current context,
 881 and returns the database handle (a C<DBI::db> object).
 882
 883 The handle is not saved anywhere: this method is strictly a
 884 convenience function; the point is that it knows which database to
 885 connect to so that the caller doesn't have to know.
 886
 887 =cut
 888
 889 #'
 890 sub new_dbh
 891 {
 892     my $self = shift;
 893
 894     return &_new_dbh();
 895 }
 896
 897 =head2 set_dbh
 898
 899   $my_dbh = C4::Connect->new_dbh;
 900   C4::Connect->set_dbh($my_dbh);
 901   ...
 902   C4::Connect->restore_dbh;
 903
 904 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 905 C<&set_context> and C<&restore_context>.
 906
 907 C<&set_dbh> saves the current database handle on a stack, then sets
 908 the current database handle to C<$my_dbh>.
 909
 910 C<$my_dbh> is assumed to be a good database handle.
 911
 912 =cut
 913
 914 #'
 915 sub set_dbh
 916 {
 917     my $self = shift;
 918     my $new_dbh = shift;
 919
 920     # Save the current database handle on the handle stack.
 921     # We assume that $new_dbh is all good: if the caller wants to
 922     # screw himself by passing an invalid handle, that's fine by
 923     # us.
 924     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 925     $context->{"dbh"} = $new_dbh;
 926 }
 927
 928 =head2 restore_dbh
 929
 930   C4::Context->restore_dbh;
 931
 932 Restores the database handle saved by an earlier call to
 933 C<C4::Context-E<gt>set_dbh>.
 934
 935 =cut
 936
 937 #'
 938 sub restore_dbh
 939 {
 940     my $self = shift;
 941
 942     if ($#{$context->{"dbh_stack"}} < 0)
 943     {
 944         # Stack underflow
 945         die "DBH stack underflow";
 946     }
 947
 948     # Pop the old database handle and set it.
 949     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 950
 951     # FIXME - If it is determined that restore_context should
 952     # return something, then this function should, too.
 953 }
 954
 955 =head2 queryparser
 956
 957   $queryparser = C4::Context->queryparser
 958
 959 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 960
 961 =cut
 962
 963 sub queryparser {
 964     my $self = shift;
 965     unless (defined $context->{"queryparser"}) {
 966         $context->{"queryparser"} = &_new_queryparser();
 967     }
 968
 969     return
 970       defined( $context->{"queryparser"} )
 971       ? $context->{"queryparser"}->new
 972       : undef;
 973 }
 974
 975 =head2 _new_queryparser
 976
 977 Internal helper function to create a new QueryParser object. QueryParser
 978 is loaded dynamically so as to keep the lack of the QueryParser library from
 979 getting in anyone's way.
 980
 981 =cut
 982
 983 sub _new_queryparser {
 984     my $qpmodules = {
 985         'OpenILS::QueryParser'           => undef,
 986         'Koha::QueryParser::Driver::PQF' => undef
 987     };
 988     if ( can_load( 'modules' => $qpmodules ) ) {
 989         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 990         my $config_file = $context->config('queryparser_config');
 991         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 992         if ( $QParser->load_config($config_file) ) {
 993             # TODO: allow indexes to be configured in the database
 994             return $QParser;
 995         }
 996     }
 997     return;
 998 }
 999
1000 =head2 marcfromkohafield
1001
1002   $dbh = C4::Context->marcfromkohafield;
1003
1004 Returns a hash with marcfromkohafield.
1005
1006 This hash is cached for future use: if you call
1007 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
1008
1009 =cut
1010
1011 #'
1012 sub marcfromkohafield
1013 {
1014     my $retval = {};
1015
1016     # If the hash already exists, return it.
1017     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
1018
1019     # No hash. Create one.
1020     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
1021
1022     return $context->{"marcfromkohafield"};
1023 }
1024
1025 # _new_marcfromkohafield
1026 # Internal helper function (not a method!). This creates a new
1027 # hash with stopwords
1028 sub _new_marcfromkohafield
1029 {
1030     my $dbh = C4::Context->dbh;
1031     my $marcfromkohafield;
1032     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
1033     $sth->execute;
1034     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
1035         my $retval = {};
1036         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
1037     }
1038     return $marcfromkohafield;
1039 }
1040
1041 =head2 stopwords
1042
1043   $dbh = C4::Context->stopwords;
1044
1045 Returns a hash with stopwords.
1046
1047 This hash is cached for future use: if you call
1048 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
1049
1050 =cut
1051
1052 #'
1053 sub stopwords
1054 {
1055     my $retval = {};
1056
1057     # If the hash already exists, return it.
1058     return $context->{"stopwords"} if defined($context->{"stopwords"});
1059
1060     # No hash. Create one.
1061     $context->{"stopwords"} = &_new_stopwords();
1062
1063     return $context->{"stopwords"};
1064 }
1065
1066 # _new_stopwords
1067 # Internal helper function (not a method!). This creates a new
1068 # hash with stopwords
1069 sub _new_stopwords
1070 {
1071     my $dbh = C4::Context->dbh;
1072     my $stopwordlist;
1073     my $sth = $dbh->prepare("select word from stopwords");
1074     $sth->execute;
1075     while (my $stopword = $sth->fetchrow_array) {
1076         $stopwordlist->{$stopword} = uc($stopword);
1077     }
1078     $stopwordlist->{A} = "A" unless $stopwordlist;
1079     return $stopwordlist;
1080 }
1081
1082 =head2 userenv
1083
1084   C4::Context->userenv;
1085
1086 Retrieves a hash for user environment variables.
1087
1088 This hash shall be cached for future use: if you call
1089 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1090
1091 =cut
1092
1093 #'
1094 sub userenv {
1095     my $var = $context->{"activeuser"};
1096     if (defined $var and defined $context->{"userenv"}->{$var}) {
1097         return $context->{"userenv"}->{$var};
1098     } else {
1099         return;
1100     }
1101 }
1102
1103 =head2 set_userenv
1104
1105   C4::Context->set_userenv($usernum, $userid, $usercnum, $userfirstname,
1106                   $usersurname, $userbranch, $userflags, $emailaddress, $branchprinter,
1107                   $persona);
1108
1109 Establish a hash of user environment variables.
1110
1111 set_userenv is called in Auth.pm
1112
1113 =cut
1114
1115 #'
1116 sub set_userenv {
1117     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona)= @_;
1118     my $var=$context->{"activeuser"} || '';
1119     my $cell = {
1120         "number"     => $usernum,
1121         "id"         => $userid,
1122         "cardnumber" => $usercnum,
1123         "firstname"  => $userfirstname,
1124         "surname"    => $usersurname,
1125         #possibly a law problem
1126         "branch"     => $userbranch,
1127         "branchname" => $branchname,
1128         "flags"      => $userflags,
1129         "emailaddress"     => $emailaddress,
1130         "branchprinter"    => $branchprinter,
1131         "persona"    => $persona,
1132     };
1133     $context->{userenv}->{$var} = $cell;
1134     return $cell;
1135 }
1136
1137 sub set_shelves_userenv {
1138         my ($type, $shelves) = @_ or return;
1139         my $activeuser = $context->{activeuser} or return;
1140         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1141         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1142         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1143 }
1144
1145 sub get_shelves_userenv {
1146         my $active;
1147         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1148                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1149                 return;
1150         }
1151         my $totshelves = $active->{totshelves} or undef;
1152         my $pubshelves = $active->{pubshelves} or undef;
1153         my $barshelves = $active->{barshelves} or undef;
1154         return ($totshelves, $pubshelves, $barshelves);
1155 }
1156
1157 =head2 _new_userenv
1158
1159   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1160
1161 Builds a hash for user environment variables.
1162
1163 This hash shall be cached for future use: if you call
1164 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1165
1166 _new_userenv is called in Auth.pm
1167
1168 =cut
1169
1170 #'
1171 sub _new_userenv
1172 {
1173     shift;  # Useless except it compensates for bad calling style
1174     my ($sessionID)= @_;
1175      $context->{"activeuser"}=$sessionID;
1176 }
1177
1178 =head2 _unset_userenv
1179
1180   C4::Context->_unset_userenv;
1181
1182 Destroys the hash for activeuser user environment variables.
1183
1184 =cut
1185
1186 #'
1187
1188 sub _unset_userenv
1189 {
1190     my ($sessionID)= @_;
1191     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1192 }
1193
1194
1195 =head2 get_versions
1196
1197   C4::Context->get_versions
1198
1199 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1200
1201 =cut
1202
1203 #'
1204
1205 # A little example sub to show more debugging info for CGI::Carp
1206 sub get_versions {
1207     my %versions;
1208     $versions{kohaVersion}  = KOHAVERSION();
1209     $versions{kohaDbVersion} = C4::Context->preference('version');
1210     $versions{osVersion} = join(" ", POSIX::uname());
1211     $versions{perlVersion} = $];
1212     {
1213         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1214         $versions{mysqlVersion}  = `mysql -V`;
1215         $versions{apacheVersion} = `httpd -v`;
1216         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1217         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1218         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1219     }
1220     return %versions;
1221 }
1222
1223
1224 =head2 tz
1225
1226   C4::Context->tz
1227
1228   Returns a DateTime::TimeZone object for the system timezone
1229
1230 =cut
1231
1232 sub tz {
1233     my $self = shift;
1234     if (!defined $context->{tz}) {
1235         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1236     }
1237     return $context->{tz};
1238 }
1239
1240
1241
1242 1;
1243 __END__
1244
1245 =head1 ENVIRONMENT
1246
1247 =head2 C<KOHA_CONF>
1248
1249 Specifies the configuration file to read.
1250
1251 =head1 SEE ALSO
1252
1253 XML::Simple
1254
1255 =head1 AUTHORS
1256
1257 Andrew Arensburger <arensb at ooblick dot com>
1258
1259 Joshua Ferraro <jmf at liblime dot com>
1260
1261 =cut