C4/Creators/Lib.pm

   1 package C4::Creators::Lib;
   2
   3 # Copyright 2009 Foundations Bible College.
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use autouse 'Data::Dumper' => qw(Dumper);
  24
  25 use C4::Context;
  26 use C4::Debug;
  27
  28 BEGIN {
  29     use version; our $VERSION = qv('3.07.00.049');
  30     use base qw(Exporter);
  31     our @EXPORT = qw(get_all_templates
  32                      get_all_layouts
  33                      get_all_profiles
  34                      get_all_image_names
  35                      get_batch_summary
  36                      get_label_summary
  37                      get_card_summary
  38                      get_barcode_types
  39                      get_label_types
  40                      get_font_types
  41                      get_text_justification_types
  42                      get_output_formats
  43                      get_column_names
  44                      get_table_names
  45                      get_unit_values
  46                      html_table
  47     );
  48 }
  49
  50 =head1 NAME
  51
  52 C4::Creators::Lib
  53
  54 =cut
  55
  56 =head1 FUNCTIONS
  57
  58 =cut
  59
  60 #=head2 C4::Creators::Lib::_SELECT()
  61 #
  62 #    This function returns a recordset upon success and 1 upon failure. Errors are logged to the Apache log.
  63 #
  64 #    examples:
  65 #
  66 #        my $field_value = _SELECT(field_name, table_name, condition);
  67 #
  68 #=cut
  69
  70 sub _SELECT {
  71     my @params = @_;
  72     my $query = "SELECT $params[0] FROM $params[1]";
  73     $params[2] ? $query .= " WHERE $params[2];" : $query .= ';';
  74     my $sth = C4::Context->dbh->prepare($query);
  75 #    $sth->{'TraceLevel'} = 3;
  76     $sth->execute();
  77     if ($sth->err) {
  78         warn sprintf('Database returned the following error: %s', $sth->errstr);
  79         return 1;
  80     }
  81     my $record_set = [];
  82     while (my $row = $sth->fetchrow_hashref()) {
  83         push(@$record_set, $row);
  84     }
  85     return $record_set;
  86 }
  87
  88 my $barcode_types = [
  89     {type => 'CODE39',          name => 'Code 39',              desc => 'Translates the characters 0-9, A-Z, \'-\', \'*\', \'+\', \'$\', \'%\', \'/\', \'.\' and \' \' to a barcode pattern.',                                  selected => 0},
  90     {type => 'CODE39MOD',       name => 'Code 39 + Modulo43',   desc => 'Translates the characters 0-9, A-Z, \'-\', \'*\', \'+\', \'$\', \'%\', \'/\', \'.\' and \' \' to a barcode pattern. Encodes Mod 43 checksum.',         selected => 0},
  91     {type => 'CODE39MOD10',     name => 'Code 39 + Modulo10',   desc => 'Translates the characters 0-9, A-Z, \'-\', \'*\', \'+\', \'$\', \'%\', \'/\', \'.\' and \' \' to a barcode pattern. Encodes Mod 10 checksum.',         selected => 0},
  92     {type => 'COOP2OF5',        name => 'COOP2of5',             desc => 'Creates COOP2of5 barcodes from a string consisting of the numeric characters 0-9',                                                                     selected => 0},
  93 #    {type => 'EAN13',           name => 'EAN13',                desc => 'Creates EAN13 barcodes from a string of 12 or 13 digits. The check number (the 13:th digit) is calculated if not supplied.',                           selected => 0},
  94 #    {type => 'EAN8',            name => 'EAN8',                 desc => 'Translates a string of 7 or 8 digits to EAN8 barcodes. The check number (the 8:th digit) is calculated if not supplied.',                              selected => 0},
  95 #    {type => 'IATA2of5',        name => 'IATA2of5',             desc => 'Creates IATA2of5 barcodes from a string consisting of the numeric characters 0-9',                                                                     selected => 0},
  96     {type => 'INDUSTRIAL2OF5',  name => 'Industrial2of5',       desc => 'Creates Industrial2of5 barcodes from a string consisting of the numeric characters 0-9',                                                               selected => 0},
  97 #    {type => 'ITF',             name => 'Interleaved2of5',      desc => 'Translates the characters 0-9 to a barcodes. These barcodes could also be called 'Interleaved2of5'.',                                                  selected => 0},
  98 #    {type => 'MATRIX2OF5',      name => 'Matrix2of5',           desc => 'Creates Matrix2of5 barcodes from a string consisting of the numeric characters 0-9',                                                                   selected => 0},
  99 #    {type => 'NW7',             name => 'NW7',                  desc => 'Creates a NW7 barcodes from a string consisting of the numeric characters 0-9',                                                                        selected => 0},
 100 #    {type => 'UPCA',            name => 'UPCA',                 desc => 'Translates a string of 11 or 12 digits to UPCA barcodes. The check number (the 12:th digit) is calculated if not supplied.',                           selected => 0},
 101 #    {type => 'UPCE',            name => 'UPCE',                 desc => 'Translates a string of 6, 7 or 8 digits to UPCE barcodes. If the string is 6 digits long, '0' is added first in the string. The check number (the 8:th digit) is calculated if not supplied.',                                 selected => 0},
 102 ];
 103
 104 my $label_types = [
 105     {type => 'BIB',     name => 'Biblio',               desc => 'Only the bibliographic data is printed.',                              selected => 0},
 106     {type => 'BARBIB',  name => 'Barcode/Biblio',       desc => 'Barcode proceeds bibliographic data.',                                 selected => 0},
 107     {type => 'BIBBAR',  name => 'Biblio/Barcode',       desc => 'Bibliographic data proceeds barcode.',                                 selected => 0},
 108     {type => 'ALT',     name => 'Alternating',          desc => 'Barcode and bibliographic data are printed on alternating labels.',    selected => 0},
 109     {type => 'BAR',     name => 'Barcode',              desc => 'Only the barcode is printed.',                                         selected => 0},
 110 ];
 111
 112 my $font_types = [
 113     {type => 'TR',      name => 'Times-Roman',                  selected => 0},
 114     {type => 'TB',      name => 'Times-Bold',                   selected => 0},
 115     {type => 'TI',      name => 'Times-Italic',                 selected => 0},
 116     {type => 'TBI',     name => 'Times-Bold-Italic',            selected => 0},
 117     {type => 'C',       name => 'Courier',                      selected => 0},
 118     {type => 'CB',      name => 'Courier-Bold',                 selected => 0},
 119     {type => 'CO',      name => 'Courier-Oblique',              selected => 0},
 120     {type => 'CBO',     name => 'Courier-Bold-Oblique',         selected => 0},
 121     {type => 'H',       name => 'Helvetica',                    selected => 0},
 122     {type => 'HB',      name => 'Helvetica-Bold',               selected => 0},
 123     {type => 'HBO',     name => 'Helvetica-Bold-Oblique',       selected => 0},
 124 ];
 125
 126 my $text_justification_types = [
 127     {type => 'L',       name => 'Left',                         selected => 0},
 128     {type => 'C',       name => 'Center',                       selected => 0},
 129     {type => 'R',       name => 'Right',                        selected => 0},
 130 #    {type => 'F',       name => 'Full',                         selected => 0},
 131 ];
 132
 133 my $unit_values = [
 134     {type       => 'POINT',      desc    => 'PostScript Points',  value   => 1,                 selected => 0},
 135     {type       => 'AGATE',      desc    => 'Adobe Agates',       value   => 5.1428571,         selected => 0},
 136     {type       => 'INCH',       desc    => 'US Inches',          value   => 72,                selected => 0},
 137     {type       => 'MM',         desc    => 'SI Millimeters',     value   => 2.83464567,        selected => 0},
 138     {type       => 'CM',         desc    => 'SI Centimeters',     value   => 28.3464567,        selected => 0},
 139 ];
 140
 141 my $output_formats = [
 142     {type       => 'pdf',       desc    => 'PDF File'},
 143     {type       => 'csv',       desc    => 'CSV File'},
 144 ];
 145
 146 =head2 C4::Creators::Lib::get_all_templates()
 147
 148   my $templates = get_all_templates();
 149
 150 This function returns a reference to a hash containing all templates upon success and 1 upon failure. Errors are logged to the Apache log.
 151
 152 =cut
 153
 154 sub get_all_templates {
 155     my %params = @_;
 156     my @templates = ();
 157     my $query = "SELECT " . ($params{'field_list'} ? $params{'field_list'} : '*') . " FROM creator_templates";
 158     $query .= ($params{'filter'} ? " WHERE $params{'filter'};" : ';');
 159     my $sth = C4::Context->dbh->prepare($query);
 160     $sth->execute();
 161     if ($sth->err) {
 162         warn sprintf('Database returned the following error: %s', $sth->errstr);
 163         return -1;
 164     }
 165     ADD_TEMPLATES:
 166     while (my $template = $sth->fetchrow_hashref) {
 167         push(@templates, $template);
 168     }
 169     return \@templates;
 170 }
 171
 172 =head2 C4::Creators::Lib::get_all_layouts()
 173
 174   my $layouts = get_all_layouts();
 175
 176 This function returns a reference to a hash containing all layouts upon success and 1 upon failure. Errors are logged to the Apache log.
 177
 178 =cut
 179
 180 sub get_all_layouts {
 181     my %params = @_;
 182     my @layouts = ();
 183     my $query = "SELECT " . ($params{'field_list'} ? $params{'field_list'} : '*') . " FROM creator_layouts";
 184     $query .= ($params{'filter'} ? " WHERE $params{'filter'};" : ';');
 185     my $sth = C4::Context->dbh->prepare($query);
 186     $sth->execute();
 187     if ($sth->err) {
 188         warn sprintf('Database returned the following error: %s', $sth->errstr);
 189         return -1;
 190     }
 191     ADD_LAYOUTS:
 192     while (my $layout = $sth->fetchrow_hashref) {
 193         push(@layouts, $layout);
 194     }
 195     return \@layouts;
 196 }
 197
 198 =head2 C4::Creators::Lib::get_all_profiles()
 199
 200   my $profiles = get_all_profiles();
 201
 202   my $profiles = get_all_profiles(field_list => field_list, filter => filter_string);
 203
 204 This function returns an arrayref whose elements are hashes containing all profiles upon success and 1 upon failure. Errors are logged
 205 to the Apache log. Two parameters are accepted. The first limits the field(s) returned. This parameter should be string of comma separted
 206 fields. ie. "field_1, field_2, ...field_n" The second limits the records returned based on a string containing a valud SQL 'WHERE' filter.
 207
 208 NOTE: Do not pass in the keyword 'WHERE.'
 209
 210 =cut
 211
 212 sub get_all_profiles {
 213     my %params = @_;
 214     my @profiles = ();
 215     my $query = "SELECT " . ($params{'field_list'} ? $params{'field_list'} : '*') . " FROM printers_profile";
 216     $query .= ($params{'filter'} ? " WHERE $params{'filter'};" : ';');
 217     my $sth = C4::Context->dbh->prepare($query);
 218 #    $sth->{'TraceLevel'} = 3 if $debug;
 219     $sth->execute();
 220     if ($sth->err) {
 221         warn sprintf('Database returned the following error: %s', $sth->errstr);
 222         return -1;
 223     }
 224     ADD_PROFILES:
 225     while (my $profile = $sth->fetchrow_hashref) {
 226         push(@profiles, $profile);
 227     }
 228     return \@profiles;
 229 }
 230
 231 =head2 C4::Creators::Lib::get_all_image_names()
 232
 233 =cut
 234
 235 sub get_all_image_names {
 236     my $image_names = [];
 237     my $query = "SELECT image_name FROM creator_images";
 238     my $sth = C4::Context->dbh->prepare($query);
 239 #    $sth->{'TraceLevel'} = 3 if $debug;
 240     $sth->execute();
 241     if ($sth->err) {
 242         warn sprintf('Database returned the following error: %s', $sth->errstr);
 243         return -1;
 244     }
 245     grep {push @$image_names, {type => $$_[0], name => $$_[0], selected => 0}} @{$sth->fetchall_arrayref([0])};
 246     return $image_names;
 247 }
 248
 249 =head2 C4::Creators::Lib::get_batch_summary()
 250
 251   my $batches = get_batch_summary();
 252
 253   my $batches = get_batch_summary(filter => filter_string);
 254
 255 This function returns an arrayref whose elements are hashes containing the batch_ids of current batches along with the item count
 256 for each batch upon success and 1 upon failure. Item counts are stored under the key '_item_count' Errors are logged to the Apache log.
 257 One parameter is accepted which limits the records returned based on a string containing a valud SQL 'WHERE' filter.
 258
 259 NOTE: Do not pass in the keyword 'WHERE.'
 260
 261 =cut
 262
 263 sub get_batch_summary {
 264     my %params = @_;
 265     my @batches = ();
 266     my $query = "SELECT batch_id,count(batch_id) as _item_count FROM creator_batches WHERE creator=?";
 267     $query .= ($params{'filter'} ? " AND $params{'filter'}" : '');
 268     $query .= " GROUP BY batch_id";
 269     my $sth = C4::Context->dbh->prepare($query);
 270 #    $sth->{'TraceLevel'} = 3;
 271     $sth->execute($params{'creator'});
 272     if ($sth->err) {
 273         warn sprintf('Database returned the following error on attempted SELECT: %s', $sth->errstr);
 274         return -1;
 275     }
 276     while (my $batch = $sth->fetchrow_hashref) {
 277         push(@batches, $batch);
 278     }
 279     return \@batches;
 280 }
 281
 282 =head2 C4::Creators::Lib::get_label_summary()
 283
 284   my $labels = get_label_summary();
 285
 286   my $labels = get_label_summary(items => @item_list);
 287
 288 This function returns an arrayref whose elements are hashes containing the label_ids of current labels along with the item count
 289 for each label upon success and 1 upon failure. Item counts are stored under the key '_item_count' Errors are logged to the Apache log.
 290 One parameter is accepted which limits the records returned based on a string containing a valud SQL 'WHERE' filter.
 291
 292 NOTE: Do not pass in the keyword 'WHERE.'
 293
 294 =cut
 295
 296 sub get_label_summary {
 297     my %params = @_;
 298     my $label_number = 0;
 299     my @label_summaries = ();
 300     my $query = "     SELECT b.title, b.author, bi.itemtype, i.barcode, i.biblionumber, i.itype
 301                       FROM creator_batches AS c LEFT JOIN items AS i ON (c.item_number=i.itemnumber)
 302                       LEFT JOIN biblioitems AS bi ON (i.biblioitemnumber=bi.biblioitemnumber)
 303                       LEFT JOIN biblio AS b ON (bi.biblionumber=b.biblionumber)
 304                       WHERE itemnumber=? AND batch_id=?;
 305                   ";
 306     my $sth = C4::Context->dbh->prepare($query);
 307     foreach my $item (@{$params{'items'}}) {
 308         $label_number++;
 309         $sth->execute($item->{'item_number'}, $params{'batch_id'});
 310         if ($sth->err) {
 311             warn sprintf('Database returned the following error on attempted SELECT: %s', $sth->errstr);
 312             return -1;
 313         }
 314         my $record = $sth->fetchrow_hashref;
 315         my $label_summary;
 316         $label_summary->{'_label_number'} = $label_number;
 317         $record->{'author'} =~ s/[^\.|\w]$// if $record->{'author'};  # strip off ugly trailing chars... but not periods or word chars
 318         $record->{'title'} =~ s/\W*$//;  # strip off ugly trailing chars
 319         # FIXME contructing staff interface URLs should be done *much* higher up the stack - for the most part, C4 module code
 320         # should not know that it's part of a web app
 321         $record->{'title'} = '<a href="/cgi-bin/koha/catalogue/detail.pl?biblionumber=' . $record->{'biblionumber'} . '"> ' . $record->{'title'} . '</a>';
 322         $label_summary->{'_summary'} = $record->{'title'} . " | " . ($record->{'author'} ? $record->{'author'} : 'N/A');
 323         $label_summary->{'_item_type'} = C4::Context->preference("item-level_itypes") ? $record->{'itype'} : $record->{'itemtype'};
 324         $label_summary->{'_barcode'} = $record->{'barcode'};
 325         $label_summary->{'_item_number'} = $item->{'item_number'};
 326         $label_summary->{'_label_id'} = $item->{'label_id'};
 327         push (@label_summaries, $label_summary);
 328     }
 329     return \@label_summaries;
 330 }
 331
 332 =head2 C4::Creators::Lib::get_card_summary()
 333
 334   my $cards = get_card_summary();
 335
 336   my $cards = get_card_summary(items => @item_list);
 337
 338 This function returns an arrayref whose elements are hashes containing the label_ids of current cards along with the item count
 339 for each card upon success and 1 upon failure. Item counts are stored under the key '_item_count' Errors are logged to the Apache log.
 340 One parameter is accepted which limits the records returned based on a string containing a valud SQL 'WHERE' filter.
 341
 342 NOTE: Do not pass in the keyword 'WHERE.'
 343
 344 =cut
 345
 346 sub get_card_summary {
 347     my %params = @_;
 348     my $card_number = 0;
 349     my @card_summaries = ();
 350     my $query = "SELECT CONCAT_WS(', ', surname, firstname) AS name, cardnumber FROM borrowers WHERE borrowernumber=?;";
 351     my $sth = C4::Context->dbh->prepare($query);
 352     foreach my $item (@{$params{'items'}}) {
 353         $card_number++;
 354         $sth->execute($item->{'borrower_number'});
 355         if ($sth->err) {
 356             warn sprintf('Database returned the following error on attempted SELECT: %s', $sth->errstr);
 357             return -1;
 358         }
 359         my $record = $sth->fetchrow_hashref;
 360         my $card_summary->{'_card_number'} = $card_number;
 361         $card_summary->{'_summary'} = $record->{'name'};
 362         $card_summary->{'borrowernumber'} = $item->{'borrower_number'};
 363         $card_summary->{'_label_id'} = $item->{'label_id'};
 364         push (@card_summaries, $card_summary);
 365     }
 366     return \@card_summaries;
 367 }
 368
 369 =head2 C4::Creators::Lib::get_barcode_types()
 370
 371   my $barcode_types = get_barcode_types();
 372
 373 This function returns a reference to an array of hashes containing all barcode types along with their name and description.
 374
 375 =cut
 376
 377 sub get_barcode_types {
 378     return $barcode_types;
 379 }
 380
 381 =head2 C4::Creators::Lib::get_label_types()
 382
 383   my $label_types = get_label_types();
 384
 385 This function returns a reference to an array of hashes containing all label types along with their name and description.
 386
 387 =cut
 388
 389 sub get_label_types {
 390     return $label_types;
 391 }
 392
 393 =head2 C4::Creators::Lib::get_font_types()
 394
 395   my $font_types = get_font_types();
 396
 397 This function returns a reference to an array of hashes containing all font types along with their name and description.
 398
 399 =cut
 400
 401 sub get_font_types {
 402     return $font_types;
 403 }
 404
 405 =head2 C4::Creators::Lib::get_text_justification_types()
 406
 407   my $text_justification_types = get_text_justification_types();
 408
 409 This function returns a reference to an array of hashes containing all text justification types along with their name and description.
 410
 411 =cut
 412
 413 sub get_text_justification_types {
 414     return $text_justification_types;
 415 }
 416
 417 =head2 C4::Creators::Lib::get_unit_values()
 418
 419   my $unit_values = get_unit_values();
 420
 421 This function returns a reference to an array of  hashes containing all unit types along with their description and multiplier.
 422 NOTE: All units are relative to a PostScript Point.
 423 There are 72 PS points to the inch.
 424
 425 =cut
 426
 427 sub get_unit_values {
 428     return $unit_values;
 429 }
 430
 431 =head2 C4::Creators::Lib::get_output_formats()
 432
 433   my $label_output_formats = get_output_formats();
 434
 435 This function returns a reference to an array of hashes containing all label output formats along with their description.
 436
 437 =cut
 438
 439 sub get_output_formats {
 440     return $output_formats;
 441 }
 442
 443 =head2 C4::Creators::Lib::get_column_names($table_name)
 444
 445 Return an arrayref of an array containing the column names of the supplied table.
 446
 447 =cut
 448
 449 sub get_column_names {
 450     my $table = shift;
 451     my $dbh = C4::Context->dbh();
 452     my $column_names = [];
 453     my $sth = $dbh->column_info(undef,undef,$table,'%');
 454     while (my $info = $sth->fetchrow_hashref()){
 455         $$column_names[$info->{'ORDINAL_POSITION'}] = $info->{'COLUMN_NAME'};
 456     }
 457     return $column_names;
 458 }
 459
 460 =head2 C4::Creators::Lib::get_table_names($search_term)
 461
 462 Return an arrayref of an array containing the table names which contain the supplied search term.
 463
 464 =cut
 465
 466 sub get_table_names {
 467     my $search_term = shift;
 468     my $dbh = C4::Context->dbh();
 469     my $table_names = [];
 470     my $sth = $dbh->table_info(undef,undef,"%$search_term%");
 471     while (my $info = $sth->fetchrow_hashref()){
 472         push (@$table_names, $info->{'TABLE_NAME'});
 473     }
 474     return $table_names;
 475 }
 476
 477 =head2 C4::Creators::Lib::html_table()
 478
 479 This function returns an arrayref of an array of hashes contianing the supplied data formatted suitably to
 480 be passed off as a T::P template parameter and used to build an html table.
 481
 482    my $table = html_table(header_fields, array_of_row_data);
 483    $template->param(
 484        TABLE => $table,
 485    );
 486
 487     html example:
 488
 489        <table>
 490             <!-- TMPL_LOOP NAME="TABLE" -->
 491             <!-- TMPL_IF NAME="header_fields" -->
 492             <tr>
 493             <!-- TMPL_LOOP NAME="header_fields" -->
 494                 <th><!-- TMPL_VAR NAME="field_label" --></th>
 495             <!-- /TMPL_LOOP -->
 496             </tr>
 497             <!-- TMPL_ELSE -->
 498             <tr>
 499             <!-- TMPL_LOOP NAME="text_fields" -->
 500             <!-- TMPL_IF NAME="select_field" -->
 501                 <td align="center"><input type="checkbox" name="action" value="<!-- TMPL_VAR NAME="field_value" -->" /></td>
 502             <!-- TMPL_ELSIF NAME="field_value" -->
 503                 <td><!-- TMPL_VAR NAME="field_value" --></td>
 504             <!-- TMPL_ELSE -->
 505                 <td>&nbsp;</td>
 506             <!-- /TMPL_IF -->
 507             <!-- /TMPL_LOOP -->
 508             </tr>
 509             <!-- /TMPL_IF -->
 510             <!-- /TMPL_LOOP -->
 511         </table>
 512
 513 =cut
 514
 515 sub html_table {
 516     my $headers = shift;
 517     my $data = shift;
 518     return undef if scalar(@$data) == 0;      # no need to generate a table if there is not data to display
 519     my $table = [];
 520     my $fields = [];
 521     my @table_columns = ();
 522     my ($row_index, $col_index) = (0,0);
 523     my $cols = 0;       # number of columns to wrap on
 524     my $field_count = 0;
 525     my $select_value = undef;
 526     my $link_field = undef;
 527     POPULATE_HEADER:
 528     foreach my $header (@$headers) {
 529         my @key = keys %$header;
 530         if ($key[0] eq 'select' ) {
 531             push (@table_columns, $key[0]);
 532             $$fields[$col_index] = {hidden => 0, select_field => 0, field_name => ($key[0]), field_label => $header->{$key[0]}{'label'}};
 533             # do special formatting stuff....
 534             $select_value = $header->{$key[0]}{'value'};
 535         }
 536         else {
 537             # do special formatting stuff....
 538             $link_field->{$key[0]} = ($header->{$key[0]}{'link_field'} == 1 ? 1 : 0);
 539             push (@table_columns, $key[0]);
 540             $$fields[$col_index] = {hidden => 0, select_field => 0, field_name => ($key[0]), field_label => $header->{$key[0]}{'label'}};
 541         }
 542         $field_count++;
 543         $col_index++;
 544     }
 545     $$table[$row_index] = {header_fields => $fields};
 546     $cols = $col_index;
 547     $field_count *= scalar(@$data);     # total fields to be displayed in the table
 548     $col_index = 0;
 549     $row_index++;
 550     $fields = [];
 551     POPULATE_TABLE:
 552     foreach my $db_row (@$data) {
 553         POPULATE_ROW:
 554         foreach my $table_column (@table_columns) {
 555             if (grep {$table_column eq $_} keys %$db_row) {
 556                 $$fields[$col_index] = {hidden => 0, link_field => $link_field->{$table_column}, select_field => 0, field_name => ($table_column . "_tbl"), field_value => $db_row->{$table_column}};
 557                 $col_index++;
 558                 next POPULATE_ROW;
 559             }
 560             elsif ($table_column =~ m/^_((.*)_(.*$))/) {   # this a special case
 561                 my $table_name = get_table_names($2);
 562                 my $record_set = _SELECT($1, @$table_name[0], $2 . "_id = " . $db_row->{$2 . "_id"});
 563                 $$fields[$col_index] = {hidden => 0, link_field => $link_field->{$table_column}, select_field => 0, field_name => ($table_column . "_tbl"), field_value => $$record_set[0]{$1}};
 564                 $col_index++;
 565                 next POPULATE_ROW;
 566             }
 567             elsif ($table_column eq 'select' ) {
 568                 $$fields[$col_index] = {hidden => 0, select_field => 1, field_name => 'select', field_value => $db_row->{$select_value}};
 569             }
 570         }
 571         $$table[$row_index] = {text_fields => $fields};
 572         $col_index = 0;
 573         $row_index++;
 574         $fields = [];
 575     }
 576     return $table;
 577 }
 578
 579 1;
 580 __END__
 581
 582 =head1 AUTHOR
 583
 584 Chris Nighswonger <cnighswonger AT foundations DOT edu>
 585
 586 =cut