C4/HoldsQueue.pm

   1 package C4::HoldsQueue;
   2
   3 # Copyright 2011 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 # FIXME: expand perldoc, explain intended logic
  21
  22 use strict;
  23 use warnings;
  24
  25 use C4::Context;
  26 use C4::Search;
  27 use C4::Items;
  28 use C4::Circulation;
  29 use C4::Members;
  30 use C4::Biblio;
  31 use Koha::DateUtils;
  32 use Koha::Items;
  33 use Koha::Patrons;
  34 use Koha::Libraries;
  35
  36 use List::Util qw(shuffle);
  37 use List::MoreUtils qw(any);
  38 use Data::Dumper;
  39
  40 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  41 BEGIN {
  42     require Exporter;
  43     @ISA = qw(Exporter);
  44     @EXPORT_OK = qw(
  45         &CreateQueue
  46         &GetHoldsQueueItems
  47
  48         &TransportCostMatrix
  49         &UpdateTransportCostMatrix
  50      );
  51 }
  52
  53
  54 =head1 FUNCTIONS
  55
  56 =head2 TransportCostMatrix
  57
  58   TransportCostMatrix();
  59
  60 Returns Transport Cost Matrix as a hashref <to branch code> => <from branch code> => cost
  61
  62 =cut
  63
  64 sub TransportCostMatrix {
  65     my ( $params ) = @_;
  66     my $ignore_holds_queue_skip_closed = $params->{ignore_holds_queue_skip_closed};
  67
  68     my $dbh   = C4::Context->dbh;
  69     my $transport_costs = $dbh->selectall_arrayref("SELECT * FROM transport_cost",{ Slice => {} });
  70
  71     my $today = dt_from_string();
  72     my $calendars;
  73     my %transport_cost_matrix;
  74     foreach (@$transport_costs) {
  75         my $from     = $_->{frombranch};
  76         my $to       = $_->{tobranch};
  77         my $cost     = $_->{cost};
  78         my $disabled = $_->{disable_transfer};
  79         $transport_cost_matrix{$to}{$from} = {
  80             cost             => $cost,
  81             disable_transfer => $disabled
  82         };
  83
  84         if ( !$ignore_holds_queue_skip_closed && C4::Context->preference("HoldsQueueSkipClosed") ) {
  85             $calendars->{$from} ||= Koha::Calendar->new( branchcode => $from );
  86             $transport_cost_matrix{$to}{$from}{disable_transfer} ||=
  87               $calendars->{$from}->is_holiday( $today );
  88         }
  89
  90     }
  91     return \%transport_cost_matrix;
  92 }
  93
  94 =head2 UpdateTransportCostMatrix
  95
  96   UpdateTransportCostMatrix($records);
  97
  98 Updates full Transport Cost Matrix table. $records is an arrayref of records.
  99 Records: { frombranch => <code>, tobranch => <code>, cost => <figure>, disable_transfer => <0,1> }
 100
 101 =cut
 102
 103 sub UpdateTransportCostMatrix {
 104     my ($records) = @_;
 105     my $dbh   = C4::Context->dbh;
 106
 107     my $sth = $dbh->prepare("INSERT INTO transport_cost (frombranch, tobranch, cost, disable_transfer) VALUES (?, ?, ?, ?)");
 108
 109     $dbh->do("DELETE FROM transport_cost");
 110     foreach (@$records) {
 111         my $cost = $_->{cost};
 112         my $from = $_->{frombranch};
 113         my $to = $_->{tobranch};
 114         if ($_->{disable_transfer}) {
 115             $cost ||= 0;
 116         }
 117         elsif ( !defined ($cost) || ($cost !~ m/(0|[1-9][0-9]*)(\.[0-9]*)?/o) ) {
 118             warn  "Invalid $from -> $to cost $cost - must be a number >= 0, disabling";
 119             $cost = 0;
 120             $_->{disable_transfer} = 1;
 121         }
 122         $sth->execute( $from, $to, $cost, $_->{disable_transfer} ? 1 : 0 );
 123     }
 124 }
 125
 126 =head2 GetHoldsQueueItems
 127
 128   GetHoldsQueueItems($branch);
 129
 130 Returns hold queue for a holding branch. If branch is omitted, then whole queue is returned
 131
 132 =cut
 133
 134 sub GetHoldsQueueItems {
 135     my ($branchlimit) = @_;
 136     my $dbh   = C4::Context->dbh;
 137
 138     my @bind_params = ();
 139     my $query = q/SELECT tmp_holdsqueue.*, biblio.author, items.ccode, items.itype, biblioitems.itemtype, items.location,
 140                          items.enumchron, items.cn_sort, biblioitems.publishercode,
 141                          biblio.copyrightdate, biblio.subtitle, biblio.medium,
 142                          biblio.part_number, biblio.part_name,
 143                          biblioitems.publicationyear, biblioitems.pages, biblioitems.size,
 144                          biblioitems.isbn, biblioitems.editionstatement, items.copynumber
 145                   FROM tmp_holdsqueue
 146                        JOIN biblio      USING (biblionumber)
 147                   LEFT JOIN biblioitems USING (biblionumber)
 148                   LEFT JOIN items       USING (  itemnumber)
 149                 /;
 150     if ($branchlimit) {
 151         $query .=" WHERE tmp_holdsqueue.holdingbranch = ?";
 152         push @bind_params, $branchlimit;
 153     }
 154     $query .= " ORDER BY ccode, location, cn_sort, author, title, pickbranch, reservedate";
 155     my $sth = $dbh->prepare($query);
 156     $sth->execute(@bind_params);
 157     my $items = [];
 158     while ( my $row = $sth->fetchrow_hashref ){
 159         # return the bib-level or item-level itype per syspref
 160         if (!C4::Context->preference('item-level_itypes')) {
 161             $row->{itype} = $row->{itemtype};
 162         }
 163         delete $row->{itemtype};
 164
 165         push @$items, $row;
 166     }
 167     return $items;
 168 }
 169
 170 =head2 CreateQueue
 171
 172   CreateQueue();
 173
 174 Top level function that turns reserves into tmp_holdsqueue and hold_fill_targets.
 175
 176 =cut
 177
 178 sub CreateQueue {
 179     my $dbh   = C4::Context->dbh;
 180
 181     $dbh->do("DELETE FROM tmp_holdsqueue");  # clear the old table for new info
 182     $dbh->do("DELETE FROM hold_fill_targets");
 183
 184     my $total_bibs            = 0;
 185     my $total_requests        = 0;
 186     my $total_available_items = 0;
 187     my $num_items_mapped      = 0;
 188
 189     my $branches_to_use;
 190     my $transport_cost_matrix;
 191     my $use_transport_cost_matrix = C4::Context->preference("UseTransportCostMatrix");
 192     if ($use_transport_cost_matrix) {
 193         $transport_cost_matrix = TransportCostMatrix();
 194         unless (keys %$transport_cost_matrix) {
 195             warn "UseTransportCostMatrix set to yes, but matrix not populated";
 196             undef $transport_cost_matrix;
 197         }
 198     }
 199     unless ($transport_cost_matrix) {
 200         $branches_to_use = load_branches_to_pull_from();
 201     }
 202
 203     my $bibs_with_pending_requests = GetBibsWithPendingHoldRequests();
 204
 205     foreach my $biblionumber (@$bibs_with_pending_requests) {
 206         $total_bibs++;
 207         my $hold_requests   = GetPendingHoldRequestsForBib($biblionumber);
 208         my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_to_use);
 209         $total_requests        += scalar(@$hold_requests);
 210         $total_available_items += scalar(@$available_items);
 211
 212         my $item_map = MapItemsToHoldRequests($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix);
 213         $item_map  or next;
 214         my $item_map_size = scalar(keys %$item_map)
 215           or next;
 216
 217         $num_items_mapped += $item_map_size;
 218         CreatePicklistFromItemMap($item_map);
 219         AddToHoldTargetMap($item_map);
 220         if (($item_map_size < scalar(@$hold_requests  )) and
 221             ($item_map_size < scalar(@$available_items))) {
 222             # DOUBLE CHECK, but this is probably OK - unfilled item-level requests
 223             # FIXME
 224             #warn "unfilled requests for $biblionumber";
 225             #warn Dumper($hold_requests), Dumper($available_items), Dumper($item_map);
 226         }
 227     }
 228 }
 229
 230 =head2 GetBibsWithPendingHoldRequests
 231
 232   my $biblionumber_aref = GetBibsWithPendingHoldRequests();
 233
 234 Return an arrayref of the biblionumbers of all bibs
 235 that have one or more unfilled hold requests.
 236
 237 =cut
 238
 239 sub GetBibsWithPendingHoldRequests {
 240     my $dbh = C4::Context->dbh;
 241
 242     my $bib_query = "SELECT DISTINCT biblionumber
 243                      FROM reserves
 244                      WHERE found IS NULL
 245                      AND priority > 0
 246                      AND reservedate <= CURRENT_DATE()
 247                      AND suspend = 0
 248                      ";
 249     my $sth = $dbh->prepare($bib_query);
 250
 251     $sth->execute();
 252     my $biblionumbers = $sth->fetchall_arrayref();
 253
 254     return [ map { $_->[0] } @$biblionumbers ];
 255 }
 256
 257 =head2 GetPendingHoldRequestsForBib
 258
 259   my $requests = GetPendingHoldRequestsForBib($biblionumber);
 260
 261 Returns an arrayref of hashrefs to pending, unfilled hold requests
 262 on the bib identified by $biblionumber.  The following keys
 263 are present in each hashref:
 264
 265     biblionumber
 266     borrowernumber
 267     itemnumber
 268     priority
 269     branchcode
 270     reservedate
 271     reservenotes
 272     borrowerbranch
 273
 274 The arrayref is sorted in order of increasing priority.
 275
 276 =cut
 277
 278 sub GetPendingHoldRequestsForBib {
 279     my $biblionumber = shift;
 280
 281     my $dbh = C4::Context->dbh;
 282
 283     my $request_query = "SELECT biblionumber, borrowernumber, itemnumber, priority, reserve_id, reserves.branchcode,
 284                                 reservedate, reservenotes, borrowers.branchcode AS borrowerbranch, itemtype, item_level_hold
 285                          FROM reserves
 286                          JOIN borrowers USING (borrowernumber)
 287                          WHERE biblionumber = ?
 288                          AND found IS NULL
 289                          AND priority > 0
 290                          AND reservedate <= CURRENT_DATE()
 291                          AND suspend = 0
 292                          ORDER BY priority";
 293     my $sth = $dbh->prepare($request_query);
 294     $sth->execute($biblionumber);
 295
 296     my $requests = $sth->fetchall_arrayref({});
 297     return $requests;
 298
 299 }
 300
 301 =head2 GetItemsAvailableToFillHoldRequestsForBib
 302
 303   my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_ar);
 304
 305 Returns an arrayref of items available to fill hold requests
 306 for the bib identified by C<$biblionumber>.  An item is available
 307 to fill a hold request if and only if:
 308
 309     * it is not on loan
 310     * it is not withdrawn
 311     * it is not marked notforloan
 312     * it is not currently in transit
 313     * it is not lost
 314     * it is not sitting on the hold shelf
 315     * it is not damaged (unless AllowHoldsOnDamagedItems is on)
 316
 317 =cut
 318
 319 sub GetItemsAvailableToFillHoldRequestsForBib {
 320     my ($biblionumber, $branches_to_use) = @_;
 321
 322     my $dbh = C4::Context->dbh;
 323     my $items_query = "SELECT itemnumber, homebranch, holdingbranch, itemtypes.itemtype AS itype
 324                        FROM items ";
 325
 326     if (C4::Context->preference('item-level_itypes')) {
 327         $items_query .=   "LEFT JOIN itemtypes ON (itemtypes.itemtype = items.itype) ";
 328     } else {
 329         $items_query .=   "JOIN biblioitems USING (biblioitemnumber)
 330                            LEFT JOIN itemtypes USING (itemtype) ";
 331     }
 332     $items_query .=   "WHERE items.notforloan = 0
 333                        AND holdingbranch IS NOT NULL
 334                        AND itemlost = 0
 335                        AND withdrawn = 0";
 336     $items_query .= "  AND damaged = 0" unless C4::Context->preference('AllowHoldsOnDamagedItems');
 337     $items_query .= "  AND items.onloan IS NULL
 338                        AND (itemtypes.notforloan IS NULL OR itemtypes.notforloan = 0)
 339                        AND itemnumber NOT IN (
 340                            SELECT itemnumber
 341                            FROM reserves
 342                            WHERE biblionumber = ?
 343                            AND itemnumber IS NOT NULL
 344                            AND (found IS NOT NULL OR priority = 0)
 345                         )
 346                        AND items.biblionumber = ?";
 347
 348     my @params = ($biblionumber, $biblionumber);
 349     if ($branches_to_use && @$branches_to_use) {
 350         $items_query .= " AND holdingbranch IN (" . join (",", map { "?" } @$branches_to_use) . ")";
 351         push @params, @$branches_to_use;
 352     }
 353     my $sth = $dbh->prepare($items_query);
 354     $sth->execute(@params);
 355
 356     my $itm = $sth->fetchall_arrayref({});
 357     my @items = grep { ! scalar GetTransfers($_->{itemnumber}) } @$itm;
 358     return [ grep {
 359         my $rule = GetBranchItemRule($_->{homebranch}, $_->{itype});
 360         $_->{holdallowed} = $rule->{holdallowed};
 361         $_->{hold_fulfillment_policy} = $rule->{hold_fulfillment_policy};
 362     } @items ];
 363 }
 364
 365 =head2 _checkHoldPolicy
 366
 367     _checkHoldPolicy($item, $request)
 368
 369     check if item agrees with hold policies
 370
 371 =cut
 372
 373 sub _checkHoldPolicy {
 374     my ( $item, $request ) = @_;
 375
 376     return 0 unless $item->{holdallowed};
 377
 378     return 0
 379       if $item->{holdallowed} == 1
 380       && $item->{homebranch} ne $request->{borrowerbranch};
 381
 382     return 0
 383       if $item->{'holdallowed'} == 3
 384       && !Koha::Libraries->find( $item->{homebranch} )
 385               ->validate_hold_sibling( { branchcode => $request->{borrowerbranch} } );
 386
 387     my $hold_fulfillment_policy = $item->{hold_fulfillment_policy};
 388
 389     return 0
 390       if $hold_fulfillment_policy eq 'holdgroup'
 391       && !Koha::Libraries->find( $item->{homebranch} )
 392             ->validate_hold_sibling( { branchcode => $request->{branchcode} } );
 393
 394     return 0
 395       if $hold_fulfillment_policy eq 'homebranch'
 396       && $request->{branchcode} ne $item->{$hold_fulfillment_policy};
 397
 398     return 0
 399       if $hold_fulfillment_policy eq 'holdingbranch'
 400       && $request->{branchcode} ne $item->{$hold_fulfillment_policy};
 401
 402     return 0
 403       if $hold_fulfillment_policy eq 'patrongroup'
 404       && !Koha::Libraries->find( $request->{borrowerbranch} )
 405               ->validate_hold_sibling( { branchcode => $request->{branchcode} } );
 406
 407     return 1;
 408
 409 }
 410
 411 =head2 MapItemsToHoldRequests
 412
 413   MapItemsToHoldRequests($hold_requests, $available_items, $branches, $transport_cost_matrix)
 414
 415 =cut
 416
 417 sub MapItemsToHoldRequests {
 418     my ($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix) = @_;
 419
 420     # handle trival cases
 421     return unless scalar(@$hold_requests) > 0;
 422     return unless scalar(@$available_items) > 0;
 423
 424     # identify item-level requests
 425     my %specific_items_requested = map { $_->{itemnumber} => 1 }
 426                                    grep { defined($_->{itemnumber}) }
 427                                    @$hold_requests;
 428
 429     map { $_->{_object} = Koha::Items->find( $_->{itemnumber} ) } @$available_items;
 430     my $libraries = {};
 431     map { $libraries->{$_->id} = $_ } Koha::Libraries->search();
 432
 433     # group available items by itemnumber
 434     my %items_by_itemnumber = map { $_->{itemnumber} => $_ } @$available_items;
 435
 436     # items already allocated
 437     my %allocated_items = ();
 438
 439     # map of items to hold requests
 440     my %item_map = ();
 441
 442     # figure out which item-level requests can be filled
 443     my $num_items_remaining = scalar(@$available_items);
 444
 445     # Look for Local Holds Priority matches first
 446     if ( C4::Context->preference('LocalHoldsPriority') ) {
 447         my $LocalHoldsPriorityPatronControl =
 448           C4::Context->preference('LocalHoldsPriorityPatronControl');
 449         my $LocalHoldsPriorityItemControl =
 450           C4::Context->preference('LocalHoldsPriorityItemControl');
 451
 452         foreach my $request (@$hold_requests) {
 453             last if $num_items_remaining == 0;
 454             my $patron = Koha::Patrons->find($request->{borrowernumber});
 455             next if $patron->category->exclude_from_local_holds_priority;
 456
 457             my $local_hold_match;
 458             foreach my $item (@$available_items) {
 459                 next if $item->{_object}->exclude_from_local_holds_priority;
 460
 461                 next unless _checkHoldPolicy($item, $request);
 462
 463                 next if $request->{itemnumber} && $request->{itemnumber} != $item->{itemnumber};
 464
 465                 next unless $item->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 466
 467                 my $local_holds_priority_item_branchcode =
 468                   $item->{$LocalHoldsPriorityItemControl};
 469
 470                 my $local_holds_priority_patron_branchcode =
 471                   ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 472                   ? $request->{branchcode}
 473                   : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 474                   ? $request->{borrowerbranch}
 475                   : undef;
 476
 477                 $local_hold_match =
 478                   $local_holds_priority_item_branchcode eq
 479                   $local_holds_priority_patron_branchcode;
 480
 481                 if ($local_hold_match) {
 482                     if ( exists $items_by_itemnumber{ $item->{itemnumber} }
 483                         and not exists $allocated_items{ $item->{itemnumber} }
 484                         and not $request->{allocated})
 485                     {
 486                         $item_map{ $item->{itemnumber} } = {
 487                             borrowernumber => $request->{borrowernumber},
 488                             biblionumber   => $request->{biblionumber},
 489                             holdingbranch  => $item->{holdingbranch},
 490                             pickup_branch  => $request->{branchcode}
 491                               || $request->{borrowerbranch},
 492                             reserve_id   => $request->{reserve_id},
 493                             item_level   => $request->{item_level_hold},
 494                             reservedate  => $request->{reservedate},
 495                             reservenotes => $request->{reservenotes},
 496                         };
 497                         $allocated_items{ $item->{itemnumber} }++;
 498                         $request->{allocated} = 1;
 499                         $num_items_remaining--;
 500                     }
 501                 }
 502             }
 503         }
 504     }
 505
 506     foreach my $request (@$hold_requests) {
 507         last if $num_items_remaining == 0;
 508         next if $request->{allocated};
 509
 510         # is this an item-level request?
 511         if (defined($request->{itemnumber})) {
 512             # fill it if possible; if not skip it
 513             if (
 514                     exists $items_by_itemnumber{ $request->{itemnumber} }
 515                 and not exists $allocated_items{ $request->{itemnumber} }
 516                 and  _checkHoldPolicy($items_by_itemnumber{ $request->{itemnumber} }, $request) # Don't fill item level holds that contravene the hold pickup policy at this time
 517                 and ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 518                     || $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} )
 519
 520                 and $items_by_itemnumber{ $request->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } )
 521
 522               )
 523             {
 524
 525                 $item_map{ $request->{itemnumber} } = {
 526                     borrowernumber => $request->{borrowernumber},
 527                     biblionumber   => $request->{biblionumber},
 528                     holdingbranch  => $items_by_itemnumber{ $request->{itemnumber} }->{holdingbranch},
 529                     pickup_branch  => $request->{branchcode} || $request->{borrowerbranch},
 530                     reserve_id     => $request->{reserve_id},
 531                     item_level     => $request->{item_level_hold},
 532                     reservedate    => $request->{reservedate},
 533                     reservenotes   => $request->{reservenotes},
 534                 };
 535                 $allocated_items{ $request->{itemnumber} }++;
 536                 $num_items_remaining--;
 537             }
 538         } else {
 539             # it's title-level request that will take up one item
 540             $num_items_remaining--;
 541         }
 542     }
 543
 544     # group available items by branch
 545     my %items_by_branch = ();
 546     foreach my $item (@$available_items) {
 547         next unless $item->{holdallowed};
 548
 549         push @{ $items_by_branch{ $item->{holdingbranch} } }, $item
 550           unless exists $allocated_items{ $item->{itemnumber} };
 551     }
 552     return \%item_map unless keys %items_by_branch;
 553
 554     # now handle the title-level requests
 555     $num_items_remaining = scalar(@$available_items) - scalar(keys %allocated_items);
 556     my $pull_branches;
 557     foreach my $request (@$hold_requests) {
 558         last if $num_items_remaining == 0;
 559         next if $request->{allocated};
 560         next if defined($request->{itemnumber}); # already handled these
 561
 562         # look for local match first
 563         my $pickup_branch = $request->{branchcode} || $request->{borrowerbranch};
 564         my ($itemnumber, $holdingbranch);
 565
 566         my $holding_branch_items = $items_by_branch{$pickup_branch};
 567         if ( $holding_branch_items ) {
 568             foreach my $item (@$holding_branch_items) {
 569                 next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 570
 571                 if (
 572                     $request->{borrowerbranch} eq $item->{homebranch}
 573                     && _checkHoldPolicy($item, $request) # Don't fill item level holds that contravene the hold pickup policy at this time
 574                     && ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 575                         || ( $request->{itemnumber} && ( $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} ) ) )
 576                   )
 577                 {
 578                     $itemnumber = $item->{itemnumber};
 579                     last;
 580                 }
 581             }
 582             $holdingbranch = $pickup_branch;
 583         }
 584         elsif ($transport_cost_matrix) {
 585             $pull_branches = [keys %items_by_branch];
 586             $holdingbranch = least_cost_branch( $pickup_branch, $pull_branches, $transport_cost_matrix );
 587             if ( $holdingbranch ) {
 588
 589                 my $holding_branch_items = $items_by_branch{$holdingbranch};
 590                 foreach my $item (@$holding_branch_items) {
 591                     next if $request->{borrowerbranch} ne $item->{homebranch};
 592                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 593
 594                     # Don't fill item level holds that contravene the hold pickup policy at this time
 595                     next unless _checkHoldPolicy($item, $request);
 596
 597                     # If hold itemtype is set, item's itemtype must match
 598                     next unless ( !$request->{itemtype}
 599                         || $item->{itype} eq $request->{itemtype} );
 600
 601                     $itemnumber = $item->{itemnumber};
 602                     last;
 603                 }
 604             }
 605             else {
 606                 next;
 607             }
 608         }
 609
 610         unless ($itemnumber) {
 611             # not found yet, fall back to basics
 612             if ($branches_to_use) {
 613                 $pull_branches = $branches_to_use;
 614             } else {
 615                 $pull_branches = [keys %items_by_branch];
 616             }
 617
 618             # Try picking items where the home and pickup branch match first
 619             PULL_BRANCHES:
 620             foreach my $branch (@$pull_branches) {
 621                 my $holding_branch_items = $items_by_branch{$branch}
 622                   or next;
 623
 624                 $holdingbranch ||= $branch;
 625                 foreach my $item (@$holding_branch_items) {
 626                     next if $pickup_branch ne $item->{homebranch};
 627                     next unless _checkHoldPolicy($item, $request);
 628                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 629
 630                     # Don't fill item level holds that contravene the hold pickup policy at this time
 631                     next unless $item->{hold_fulfillment_policy} eq 'any'
 632                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 633
 634                     # If hold itemtype is set, item's itemtype must match
 635                     next unless ( !$request->{itemtype}
 636                         || $item->{itype} eq $request->{itemtype} );
 637
 638                     $itemnumber = $item->{itemnumber};
 639                     $holdingbranch = $branch;
 640                     last PULL_BRANCHES;
 641                 }
 642             }
 643
 644             # Now try items from the least cost branch based on the transport cost matrix or StaticHoldsQueueWeight
 645             unless ( $itemnumber || !$holdingbranch) {
 646                 foreach my $current_item ( @{ $items_by_branch{$holdingbranch} } ) {
 647                     next unless _checkHoldPolicy($current_item, $request); # Don't fill item level holds that contravene the hold pickup policy at this time
 648
 649                     # If hold itemtype is set, item's itemtype must match
 650                     next unless ( !$request->{itemtype}
 651                         || $current_item->{itype} eq $request->{itemtype} );
 652
 653                     next unless $items_by_itemnumber{ $current_item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 654
 655                     $itemnumber = $current_item->{itemnumber};
 656                     last; # quit this loop as soon as we have a suitable item
 657                 }
 658             }
 659
 660             # Now try for items for any item that can fill this hold
 661             unless ( $itemnumber ) {
 662                 PULL_BRANCHES2:
 663                 foreach my $branch (@$pull_branches) {
 664                     my $holding_branch_items = $items_by_branch{$branch}
 665                       or next;
 666
 667                     foreach my $item (@$holding_branch_items) {
 668                         # Don't fill item level holds that contravene the hold pickup policy at this time
 669                         next unless _checkHoldPolicy($item, $request);
 670
 671                         # If hold itemtype is set, item's itemtype must match
 672                         next unless ( !$request->{itemtype}
 673                             || $item->{itype} eq $request->{itemtype} );
 674
 675                         next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 676
 677                         $itemnumber = $item->{itemnumber};
 678                         $holdingbranch = $branch;
 679                         last PULL_BRANCHES2;
 680                     }
 681                 }
 682             }
 683         }
 684
 685         if ($itemnumber) {
 686             my $holding_branch_items = $items_by_branch{$holdingbranch}
 687               or die "Have $itemnumber, $holdingbranch, but no items!";
 688             @$holding_branch_items = grep { $_->{itemnumber} != $itemnumber } @$holding_branch_items;
 689             delete $items_by_branch{$holdingbranch} unless @$holding_branch_items;
 690
 691             $item_map{$itemnumber} = {
 692                 borrowernumber => $request->{borrowernumber},
 693                 biblionumber => $request->{biblionumber},
 694                 holdingbranch => $holdingbranch,
 695                 pickup_branch => $pickup_branch,
 696                 reserve_id => $request->{reserve_id},
 697                 item_level => $request->{item_level_hold},
 698                 reservedate => $request->{reservedate},
 699                 reservenotes => $request->{reservenotes},
 700             };
 701             $num_items_remaining--;
 702         }
 703     }
 704     return \%item_map;
 705 }
 706
 707 =head2 CreatePickListFromItemMap
 708
 709 =cut
 710
 711 sub CreatePicklistFromItemMap {
 712     my $item_map = shift;
 713
 714     my $dbh = C4::Context->dbh;
 715
 716     my $sth_load=$dbh->prepare("
 717         INSERT INTO tmp_holdsqueue (biblionumber,itemnumber,barcode,surname,firstname,phone,borrowernumber,
 718                                     cardnumber,reservedate,title, itemcallnumber,
 719                                     holdingbranch,pickbranch,notes, item_level_request)
 720         VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 721     ");
 722
 723     foreach my $itemnumber  (sort keys %$item_map) {
 724         my $mapped_item = $item_map->{$itemnumber};
 725         my $biblionumber = $mapped_item->{biblionumber};
 726         my $borrowernumber = $mapped_item->{borrowernumber};
 727         my $pickbranch = $mapped_item->{pickup_branch};
 728         my $holdingbranch = $mapped_item->{holdingbranch};
 729         my $reservedate = $mapped_item->{reservedate};
 730         my $reservenotes = $mapped_item->{reservenotes};
 731         my $item_level = $mapped_item->{item_level};
 732
 733         my $item = Koha::Items->find($itemnumber);
 734         my $barcode = $item->barcode;
 735         my $itemcallnumber = $item->itemcallnumber;
 736
 737         my $patron = Koha::Patrons->find( $borrowernumber );
 738         my $cardnumber = $patron->cardnumber;
 739         my $surname = $patron->surname;
 740         my $firstname = $patron->firstname;
 741         my $phone = $patron->phone;
 742
 743         my $biblio = Koha::Biblios->find( $biblionumber );
 744         my $title = $biblio->title;
 745
 746         $sth_load->execute($biblionumber, $itemnumber, $barcode, $surname, $firstname, $phone, $borrowernumber,
 747                            $cardnumber, $reservedate, $title, $itemcallnumber,
 748                            $holdingbranch, $pickbranch, $reservenotes, $item_level);
 749     }
 750 }
 751
 752 =head2 AddToHoldTargetMap
 753
 754 =cut
 755
 756 sub AddToHoldTargetMap {
 757     my $item_map = shift;
 758
 759     my $dbh = C4::Context->dbh;
 760
 761     my $insert_sql = q(
 762         INSERT INTO hold_fill_targets (borrowernumber, biblionumber, itemnumber, source_branchcode, item_level_request, reserve_id)
 763                                VALUES (?, ?, ?, ?, ?, ?)
 764     );
 765     my $sth_insert = $dbh->prepare($insert_sql);
 766
 767     foreach my $itemnumber (keys %$item_map) {
 768         my $mapped_item = $item_map->{$itemnumber};
 769         $sth_insert->execute($mapped_item->{borrowernumber}, $mapped_item->{biblionumber}, $itemnumber,
 770                              $mapped_item->{holdingbranch}, $mapped_item->{item_level}, $mapped_item->{reserve_id});
 771     }
 772 }
 773
 774 # Helper functions, not part of any interface
 775
 776 sub _trim {
 777     return $_[0] unless $_[0];
 778     $_[0] =~ s/^\s+//;
 779     $_[0] =~ s/\s+$//;
 780     $_[0];
 781 }
 782
 783 sub load_branches_to_pull_from {
 784     my @branches_to_use;
 785
 786     my $static_branch_list = C4::Context->preference("StaticHoldsQueueWeight");
 787     @branches_to_use = map { _trim($_) } split( /,/, $static_branch_list )
 788       if $static_branch_list;
 789
 790     @branches_to_use =
 791       Koha::Database->new()->schema()->resultset('Branch')
 792       ->get_column('branchcode')->all()
 793       unless (@branches_to_use);
 794
 795     @branches_to_use = shuffle(@branches_to_use)
 796       if C4::Context->preference("RandomizeHoldsQueueWeight");
 797
 798     my $today = dt_from_string();
 799     if ( C4::Context->preference('HoldsQueueSkipClosed') ) {
 800         @branches_to_use = grep {
 801             !Koha::Calendar->new( branchcode => $_ )
 802               ->is_holiday( $today )
 803         } @branches_to_use;
 804     }
 805
 806     return \@branches_to_use;
 807 }
 808
 809 sub least_cost_branch {
 810
 811     #$from - arrayref
 812     my ($to, $from, $transport_cost_matrix) = @_;
 813
 814     # Nothing really spectacular: supply to branch, a list of potential from branches
 815     # and find the minimum from - to value from the transport_cost_matrix
 816     return $from->[0] if ( @$from == 1 && $transport_cost_matrix->{$to}{$from->[0]}->{disable_transfer} != 1 );
 817
 818     # If the pickup library is in the list of libraries to pull from,
 819     # return that library right away, it is obviously the least costly
 820     return ($to) if any { $_ eq $to } @$from;
 821
 822     my ($least_cost, @branch);
 823     foreach (@$from) {
 824         my $cell = $transport_cost_matrix->{$to}{$_};
 825         next if $cell->{disable_transfer};
 826
 827         my $cost = $cell->{cost};
 828         next unless defined $cost; # XXX should this be reported?
 829
 830         unless (defined $least_cost) {
 831             $least_cost = $cost;
 832             push @branch, $_;
 833             next;
 834         }
 835
 836         next if $cost > $least_cost;
 837
 838         if ($cost == $least_cost) {
 839             push @branch, $_;
 840             next;
 841         }
 842
 843         @branch = ($_);
 844         $least_cost = $cost;
 845     }
 846
 847     return $branch[0];
 848
 849     # XXX return a random @branch with minimum cost instead of the first one;
 850     # return $branch[0] if @branch == 1;
 851 }
 852
 853
 854 1;