C4/HoldsQueue.pm

   1 package C4::HoldsQueue;
   2
   3 # Copyright 2011 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 # FIXME: expand perldoc, explain intended logic
  21
  22 use strict;
  23 use warnings;
  24
  25 use C4::Context;
  26 use C4::Search;
  27 use C4::Items;
  28 use C4::Circulation;
  29 use C4::Members;
  30 use C4::Biblio;
  31 use Koha::DateUtils;
  32 use Koha::Items;
  33 use Koha::Patrons;
  34 use Koha::Libraries;
  35
  36 use List::Util qw(shuffle);
  37 use List::MoreUtils qw(any);
  38 use Data::Dumper;
  39
  40 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  41 BEGIN {
  42     require Exporter;
  43     @ISA = qw(Exporter);
  44     @EXPORT_OK = qw(
  45         &CreateQueue
  46         &GetHoldsQueueItems
  47
  48         &TransportCostMatrix
  49         &UpdateTransportCostMatrix
  50      );
  51 }
  52
  53
  54 =head1 FUNCTIONS
  55
  56 =head2 TransportCostMatrix
  57
  58   TransportCostMatrix();
  59
  60 Returns Transport Cost Matrix as a hashref <to branch code> => <from branch code> => cost
  61
  62 =cut
  63
  64 sub TransportCostMatrix {
  65     my ( $params ) = @_;
  66     my $ignore_holds_queue_skip_closed = $params->{ignore_holds_queue_skip_closed};
  67
  68     my $dbh   = C4::Context->dbh;
  69     my $transport_costs = $dbh->selectall_arrayref("SELECT * FROM transport_cost",{ Slice => {} });
  70
  71     my $today = dt_from_string();
  72     my $calendars;
  73     my %transport_cost_matrix;
  74     foreach (@$transport_costs) {
  75         my $from     = $_->{frombranch};
  76         my $to       = $_->{tobranch};
  77         my $cost     = $_->{cost};
  78         my $disabled = $_->{disable_transfer};
  79         $transport_cost_matrix{$to}{$from} = {
  80             cost             => $cost,
  81             disable_transfer => $disabled
  82         };
  83
  84         if ( !$ignore_holds_queue_skip_closed && C4::Context->preference("HoldsQueueSkipClosed") ) {
  85             $calendars->{$from} ||= Koha::Calendar->new( branchcode => $from );
  86             $transport_cost_matrix{$to}{$from}{disable_transfer} ||=
  87               $calendars->{$from}->is_holiday( $today );
  88         }
  89
  90     }
  91     return \%transport_cost_matrix;
  92 }
  93
  94 =head2 UpdateTransportCostMatrix
  95
  96   UpdateTransportCostMatrix($records);
  97
  98 Updates full Transport Cost Matrix table. $records is an arrayref of records.
  99 Records: { frombranch => <code>, tobranch => <code>, cost => <figure>, disable_transfer => <0,1> }
 100
 101 =cut
 102
 103 sub UpdateTransportCostMatrix {
 104     my ($records) = @_;
 105     my $dbh   = C4::Context->dbh;
 106
 107     my $sth = $dbh->prepare("INSERT INTO transport_cost (frombranch, tobranch, cost, disable_transfer) VALUES (?, ?, ?, ?)");
 108
 109     $dbh->do("DELETE FROM transport_cost");
 110     foreach (@$records) {
 111         my $cost = $_->{cost};
 112         my $from = $_->{frombranch};
 113         my $to = $_->{tobranch};
 114         if ($_->{disable_transfer}) {
 115             $cost ||= 0;
 116         }
 117         elsif ( !defined ($cost) || ($cost !~ m/(0|[1-9][0-9]*)(\.[0-9]*)?/o) ) {
 118             warn  "Invalid $from -> $to cost $cost - must be a number >= 0, disabling";
 119             $cost = 0;
 120             $_->{disable_transfer} = 1;
 121         }
 122         $sth->execute( $from, $to, $cost, $_->{disable_transfer} ? 1 : 0 );
 123     }
 124 }
 125
 126 =head2 GetHoldsQueueItems
 127
 128   GetHoldsQueueItems($branch);
 129
 130 Returns hold queue for a holding branch. If branch is omitted, then whole queue is returned
 131
 132 =cut
 133
 134 sub GetHoldsQueueItems {
 135     my ($branchlimit) = @_;
 136     my $dbh   = C4::Context->dbh;
 137
 138     my @bind_params = ();
 139     my $query = q/SELECT tmp_holdsqueue.*, biblio.author, items.ccode, items.itype, biblioitems.itemtype, items.location,
 140                          items.enumchron, items.cn_sort, biblioitems.publishercode,
 141                          biblio.copyrightdate, biblio.subtitle, biblio.medium,
 142                          biblio.part_number, biblio.part_name,
 143                          biblioitems.publicationyear, biblioitems.pages, biblioitems.size,
 144                          biblioitems.isbn, biblioitems.editionstatement, items.copynumber
 145                   FROM tmp_holdsqueue
 146                        JOIN biblio      USING (biblionumber)
 147                   LEFT JOIN biblioitems USING (biblionumber)
 148                   LEFT JOIN items       USING (  itemnumber)
 149                 /;
 150     if ($branchlimit) {
 151         $query .=" WHERE tmp_holdsqueue.holdingbranch = ?";
 152         push @bind_params, $branchlimit;
 153     }
 154     $query .= " ORDER BY ccode, location, cn_sort, author, title, pickbranch, reservedate";
 155     my $sth = $dbh->prepare($query);
 156     $sth->execute(@bind_params);
 157     my $items = [];
 158     while ( my $row = $sth->fetchrow_hashref ){
 159         # return the bib-level or item-level itype per syspref
 160         if (!C4::Context->preference('item-level_itypes')) {
 161             $row->{itype} = $row->{itemtype};
 162         }
 163         delete $row->{itemtype};
 164
 165         push @$items, $row;
 166     }
 167     return $items;
 168 }
 169
 170 =head2 CreateQueue
 171
 172   CreateQueue();
 173
 174 Top level function that turns reserves into tmp_holdsqueue and hold_fill_targets.
 175
 176 =cut
 177
 178 sub CreateQueue {
 179     my $dbh   = C4::Context->dbh;
 180
 181     $dbh->do("DELETE FROM tmp_holdsqueue");  # clear the old table for new info
 182     $dbh->do("DELETE FROM hold_fill_targets");
 183
 184     my $total_bibs            = 0;
 185     my $total_requests        = 0;
 186     my $total_available_items = 0;
 187     my $num_items_mapped      = 0;
 188
 189     my $branches_to_use;
 190     my $transport_cost_matrix;
 191     my $use_transport_cost_matrix = C4::Context->preference("UseTransportCostMatrix");
 192     if ($use_transport_cost_matrix) {
 193         $transport_cost_matrix = TransportCostMatrix();
 194         unless (keys %$transport_cost_matrix) {
 195             warn "UseTransportCostMatrix set to yes, but matrix not populated";
 196             undef $transport_cost_matrix;
 197         }
 198     }
 199     unless ($transport_cost_matrix) {
 200         $branches_to_use = load_branches_to_pull_from();
 201     }
 202
 203     my $bibs_with_pending_requests = GetBibsWithPendingHoldRequests();
 204
 205     foreach my $biblionumber (@$bibs_with_pending_requests) {
 206         $total_bibs++;
 207         my $hold_requests   = GetPendingHoldRequestsForBib($biblionumber);
 208         my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_to_use);
 209         $total_requests        += scalar(@$hold_requests);
 210         $total_available_items += scalar(@$available_items);
 211
 212         my $item_map = MapItemsToHoldRequests($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix);
 213         $item_map  or next;
 214         my $item_map_size = scalar(keys %$item_map)
 215           or next;
 216
 217         $num_items_mapped += $item_map_size;
 218         CreatePicklistFromItemMap($item_map);
 219         AddToHoldTargetMap($item_map);
 220         if (($item_map_size < scalar(@$hold_requests  )) and
 221             ($item_map_size < scalar(@$available_items))) {
 222             # DOUBLE CHECK, but this is probably OK - unfilled item-level requests
 223             # FIXME
 224             #warn "unfilled requests for $biblionumber";
 225             #warn Dumper($hold_requests), Dumper($available_items), Dumper($item_map);
 226         }
 227     }
 228 }
 229
 230 =head2 GetBibsWithPendingHoldRequests
 231
 232   my $biblionumber_aref = GetBibsWithPendingHoldRequests();
 233
 234 Return an arrayref of the biblionumbers of all bibs
 235 that have one or more unfilled hold requests.
 236
 237 =cut
 238
 239 sub GetBibsWithPendingHoldRequests {
 240     my $dbh = C4::Context->dbh;
 241
 242     my $bib_query = "SELECT DISTINCT biblionumber
 243                      FROM reserves
 244                      WHERE found IS NULL
 245                      AND priority > 0
 246                      AND reservedate <= CURRENT_DATE()
 247                      AND suspend = 0
 248                      ";
 249     my $sth = $dbh->prepare($bib_query);
 250
 251     $sth->execute();
 252     my $biblionumbers = $sth->fetchall_arrayref();
 253
 254     return [ map { $_->[0] } @$biblionumbers ];
 255 }
 256
 257 =head2 GetPendingHoldRequestsForBib
 258
 259   my $requests = GetPendingHoldRequestsForBib($biblionumber);
 260
 261 Returns an arrayref of hashrefs to pending, unfilled hold requests
 262 on the bib identified by $biblionumber.  The following keys
 263 are present in each hashref:
 264
 265     biblionumber
 266     borrowernumber
 267     itemnumber
 268     priority
 269     branchcode
 270     reservedate
 271     reservenotes
 272     borrowerbranch
 273
 274 The arrayref is sorted in order of increasing priority.
 275
 276 =cut
 277
 278 sub GetPendingHoldRequestsForBib {
 279     my $biblionumber = shift;
 280
 281     my $dbh = C4::Context->dbh;
 282
 283     my $request_query = "SELECT biblionumber, borrowernumber, itemnumber, priority, reserve_id, reserves.branchcode,
 284                                 reservedate, reservenotes, borrowers.branchcode AS borrowerbranch, itemtype, item_level_hold
 285                          FROM reserves
 286                          JOIN borrowers USING (borrowernumber)
 287                          WHERE biblionumber = ?
 288                          AND found IS NULL
 289                          AND priority > 0
 290                          AND reservedate <= CURRENT_DATE()
 291                          AND suspend = 0
 292                          ORDER BY priority";
 293     my $sth = $dbh->prepare($request_query);
 294     $sth->execute($biblionumber);
 295
 296     my $requests = $sth->fetchall_arrayref({});
 297     return $requests;
 298
 299 }
 300
 301 =head2 GetItemsAvailableToFillHoldRequestsForBib
 302
 303   my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_ar);
 304
 305 Returns an arrayref of items available to fill hold requests
 306 for the bib identified by C<$biblionumber>.  An item is available
 307 to fill a hold request if and only if:
 308
 309     * it is not on loan
 310     * it is not withdrawn
 311     * it is not marked notforloan
 312     * it is not currently in transit
 313     * it is not lost
 314     * it is not sitting on the hold shelf
 315     * it is not damaged (unless AllowHoldsOnDamagedItems is on)
 316
 317 =cut
 318
 319 sub GetItemsAvailableToFillHoldRequestsForBib {
 320     my ($biblionumber, $branches_to_use) = @_;
 321
 322     my $dbh = C4::Context->dbh;
 323     my $items_query = "SELECT itemnumber, homebranch, holdingbranch, itemtypes.itemtype AS itype
 324                        FROM items ";
 325
 326     if (C4::Context->preference('item-level_itypes')) {
 327         $items_query .=   "LEFT JOIN itemtypes ON (itemtypes.itemtype = items.itype) ";
 328     } else {
 329         $items_query .=   "JOIN biblioitems USING (biblioitemnumber)
 330                            LEFT JOIN itemtypes USING (itemtype) ";
 331     }
 332     $items_query .=   "WHERE items.notforloan = 0
 333                        AND holdingbranch IS NOT NULL
 334                        AND itemlost = 0
 335                        AND withdrawn = 0";
 336     $items_query .= "  AND damaged = 0" unless C4::Context->preference('AllowHoldsOnDamagedItems');
 337     $items_query .= "  AND items.onloan IS NULL
 338                        AND (itemtypes.notforloan IS NULL OR itemtypes.notforloan = 0)
 339                        AND itemnumber NOT IN (
 340                            SELECT itemnumber
 341                            FROM reserves
 342                            WHERE biblionumber = ?
 343                            AND itemnumber IS NOT NULL
 344                            AND (found IS NOT NULL OR priority = 0)
 345                         )
 346                        AND items.biblionumber = ?";
 347
 348     my @params = ($biblionumber, $biblionumber);
 349     if ($branches_to_use && @$branches_to_use) {
 350         $items_query .= " AND holdingbranch IN (" . join (",", map { "?" } @$branches_to_use) . ")";
 351         push @params, @$branches_to_use;
 352     }
 353     my $sth = $dbh->prepare($items_query);
 354     $sth->execute(@params);
 355
 356     my $itm = $sth->fetchall_arrayref({});
 357     my @items = grep { ! scalar GetTransfers($_->{itemnumber}) } @$itm;
 358     return [ grep {
 359         my $rule = GetBranchItemRule($_->{homebranch}, $_->{itype});
 360         $_->{holdallowed} = $rule->{holdallowed};
 361         $_->{hold_fulfillment_policy} = $rule->{hold_fulfillment_policy};
 362     } @items ];
 363 }
 364
 365 =head2 _checkHoldPolicy
 366
 367     _checkHoldPolicy($item, $request)
 368
 369     check if item agrees with hold policies
 370
 371 =cut
 372
 373 sub _checkHoldPolicy {
 374     my ($item, $request) = @_;
 375
 376     return 0 unless $item->{holdallowed};
 377     return 0 if $item->{holdallowed} == 1 && $item->{homebranch} ne $request->{borrowerbranch};
 378
 379     my $library = Koha::Libraries->find($item->{homebranch});
 380
 381     return 0 if $item->{'holdallowed'} == 3 && !$library->validate_hold_sibling({branchcode => $request->{borrowerbranch}});
 382
 383     my $hold_fulfillment_policy = $item->{hold_fulfillment_policy};
 384
 385     return 0 if $hold_fulfillment_policy eq 'holdgroup' && !$library->validate_hold_sibling({branchcode => $request->{branchcode}});
 386     return 0 if $hold_fulfillment_policy eq 'homebranch' && $request->{branchcode} ne $item->$hold_fulfillment_policy;
 387     return 0 if $hold_fulfillment_policy eq 'holdingbranch' && $request->{branchcode} ne $item->$hold_fulfillment_policy;
 388
 389     my $patronLibrary = Koha::Libraries->find($request->{borrowerbranch});
 390
 391     return 0 if $hold_fulfillment_policy eq 'patrongroup' && !patronLibrary->validate_hold_sibling({branchcode => $request->{branchcode}});
 392
 393     return 1;
 394
 395 }
 396
 397 =head2 MapItemsToHoldRequests
 398
 399   MapItemsToHoldRequests($hold_requests, $available_items, $branches, $transport_cost_matrix)
 400
 401 =cut
 402
 403 sub MapItemsToHoldRequests {
 404     my ($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix) = @_;
 405
 406     # handle trival cases
 407     return unless scalar(@$hold_requests) > 0;
 408     return unless scalar(@$available_items) > 0;
 409
 410     # identify item-level requests
 411     my %specific_items_requested = map { $_->{itemnumber} => 1 }
 412                                    grep { defined($_->{itemnumber}) }
 413                                    @$hold_requests;
 414
 415     map { $_->{_object} = Koha::Items->find( $_->{itemnumber} ) } @$available_items;
 416     my $libraries = {};
 417     map { $libraries->{$_->id} = $_ } Koha::Libraries->search();
 418
 419     # group available items by itemnumber
 420     my %items_by_itemnumber = map { $_->{itemnumber} => $_ } @$available_items;
 421
 422     # items already allocated
 423     my %allocated_items = ();
 424
 425     # map of items to hold requests
 426     my %item_map = ();
 427
 428     # figure out which item-level requests can be filled
 429     my $num_items_remaining = scalar(@$available_items);
 430
 431     # Look for Local Holds Priority matches first
 432     if ( C4::Context->preference('LocalHoldsPriority') ) {
 433         my $LocalHoldsPriorityPatronControl =
 434           C4::Context->preference('LocalHoldsPriorityPatronControl');
 435         my $LocalHoldsPriorityItemControl =
 436           C4::Context->preference('LocalHoldsPriorityItemControl');
 437
 438         foreach my $request (@$hold_requests) {
 439             last if $num_items_remaining == 0;
 440             my $patron = Koha::Patrons->find($request->{borrowernumber});
 441             next if $patron->category->exclude_from_local_holds_priority;
 442
 443             my $local_hold_match;
 444             foreach my $item (@$available_items) {
 445                 next if $item->{_object}->exclude_from_local_holds_priority;
 446
 447                 next unless _checkHoldPolicy($item, $request);
 448
 449                 next if $request->{itemnumber} && $request->{itemnumber} != $item->{itemnumber};
 450
 451                 next unless $item->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 452
 453                 my $local_holds_priority_item_branchcode =
 454                   $item->{$LocalHoldsPriorityItemControl};
 455
 456                 my $local_holds_priority_patron_branchcode =
 457                   ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 458                   ? $request->{branchcode}
 459                   : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 460                   ? $request->{borrowerbranch}
 461                   : undef;
 462
 463                 $local_hold_match =
 464                   $local_holds_priority_item_branchcode eq
 465                   $local_holds_priority_patron_branchcode;
 466
 467                 if ($local_hold_match) {
 468                     if ( exists $items_by_itemnumber{ $item->{itemnumber} }
 469                         and not exists $allocated_items{ $item->{itemnumber} }
 470                         and not $request->{allocated})
 471                     {
 472                         $item_map{ $item->{itemnumber} } = {
 473                             borrowernumber => $request->{borrowernumber},
 474                             biblionumber   => $request->{biblionumber},
 475                             holdingbranch  => $item->{holdingbranch},
 476                             pickup_branch  => $request->{branchcode}
 477                               || $request->{borrowerbranch},
 478                             reserve_id   => $request->{reserve_id},
 479                             item_level   => $request->{item_level_hold},
 480                             reservedate  => $request->{reservedate},
 481                             reservenotes => $request->{reservenotes},
 482                         };
 483                         $allocated_items{ $item->{itemnumber} }++;
 484                         $request->{allocated} = 1;
 485                         $num_items_remaining--;
 486                     }
 487                 }
 488             }
 489         }
 490     }
 491
 492     foreach my $request (@$hold_requests) {
 493         last if $num_items_remaining == 0;
 494         next if $request->{allocated};
 495
 496         # is this an item-level request?
 497         if (defined($request->{itemnumber})) {
 498             # fill it if possible; if not skip it
 499             if (
 500                     exists $items_by_itemnumber{ $request->{itemnumber} }
 501                 and not exists $allocated_items{ $request->{itemnumber} }
 502                 and  _checkHoldPolicy($items_by_itemnumber{ $request->{itemnumber} }, $request) # Don't fill item level holds that contravene the hold pickup policy at this time
 503                 and ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 504                     || $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} )
 505
 506                 and $items_by_itemnumber{ $request->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } )
 507
 508               )
 509             {
 510
 511                 $item_map{ $request->{itemnumber} } = {
 512                     borrowernumber => $request->{borrowernumber},
 513                     biblionumber   => $request->{biblionumber},
 514                     holdingbranch  => $items_by_itemnumber{ $request->{itemnumber} }->{holdingbranch},
 515                     pickup_branch  => $request->{branchcode} || $request->{borrowerbranch},
 516                     reserve_id     => $request->{reserve_id},
 517                     item_level     => $request->{item_level_hold},
 518                     reservedate    => $request->{reservedate},
 519                     reservenotes   => $request->{reservenotes},
 520                 };
 521                 $allocated_items{ $request->{itemnumber} }++;
 522                 $num_items_remaining--;
 523             }
 524         } else {
 525             # it's title-level request that will take up one item
 526             $num_items_remaining--;
 527         }
 528     }
 529
 530     # group available items by branch
 531     my %items_by_branch = ();
 532     foreach my $item (@$available_items) {
 533         next unless $item->{holdallowed};
 534
 535         push @{ $items_by_branch{ $item->{holdingbranch} } }, $item
 536           unless exists $allocated_items{ $item->{itemnumber} };
 537     }
 538     return \%item_map unless keys %items_by_branch;
 539
 540     # now handle the title-level requests
 541     $num_items_remaining = scalar(@$available_items) - scalar(keys %allocated_items);
 542     my $pull_branches;
 543     foreach my $request (@$hold_requests) {
 544         last if $num_items_remaining == 0;
 545         next if $request->{allocated};
 546         next if defined($request->{itemnumber}); # already handled these
 547
 548         # look for local match first
 549         my $pickup_branch = $request->{branchcode} || $request->{borrowerbranch};
 550         my ($itemnumber, $holdingbranch);
 551
 552         my $holding_branch_items = $items_by_branch{$pickup_branch};
 553         if ( $holding_branch_items ) {
 554             foreach my $item (@$holding_branch_items) {
 555                 next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 556
 557                 if (
 558                     $request->{borrowerbranch} eq $item->{homebranch}
 559                     && _checkHoldPolicy($item, $request) # Don't fill item level holds that contravene the hold pickup policy at this time
 560                     && ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 561                         || ( $request->{itemnumber} && ( $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} ) ) )
 562                   )
 563                 {
 564                     $itemnumber = $item->{itemnumber};
 565                     last;
 566                 }
 567             }
 568             $holdingbranch = $pickup_branch;
 569         }
 570         elsif ($transport_cost_matrix) {
 571             $pull_branches = [keys %items_by_branch];
 572             $holdingbranch = least_cost_branch( $pickup_branch, $pull_branches, $transport_cost_matrix );
 573             if ( $holdingbranch ) {
 574
 575                 my $holding_branch_items = $items_by_branch{$holdingbranch};
 576                 foreach my $item (@$holding_branch_items) {
 577                     next if $request->{borrowerbranch} ne $item->{homebranch};
 578                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 579
 580                     # Don't fill item level holds that contravene the hold pickup policy at this time
 581                     next unless _checkHoldPolicy($item, $request);
 582
 583                     # If hold itemtype is set, item's itemtype must match
 584                     next unless ( !$request->{itemtype}
 585                         || $item->{itype} eq $request->{itemtype} );
 586
 587                     $itemnumber = $item->{itemnumber};
 588                     last;
 589                 }
 590             }
 591             else {
 592                 next;
 593             }
 594         }
 595
 596         unless ($itemnumber) {
 597             # not found yet, fall back to basics
 598             if ($branches_to_use) {
 599                 $pull_branches = $branches_to_use;
 600             } else {
 601                 $pull_branches = [keys %items_by_branch];
 602             }
 603
 604             # Try picking items where the home and pickup branch match first
 605             PULL_BRANCHES:
 606             foreach my $branch (@$pull_branches) {
 607                 my $holding_branch_items = $items_by_branch{$branch}
 608                   or next;
 609
 610                 $holdingbranch ||= $branch;
 611                 foreach my $item (@$holding_branch_items) {
 612                     next if $pickup_branch ne $item->{homebranch};
 613                     next unless _checkHoldPolicy($item, $request);
 614                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 615
 616                     # Don't fill item level holds that contravene the hold pickup policy at this time
 617                     next unless $item->{hold_fulfillment_policy} eq 'any'
 618                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 619
 620                     # If hold itemtype is set, item's itemtype must match
 621                     next unless ( !$request->{itemtype}
 622                         || $item->{itype} eq $request->{itemtype} );
 623
 624                     $itemnumber = $item->{itemnumber};
 625                     $holdingbranch = $branch;
 626                     last PULL_BRANCHES;
 627                 }
 628             }
 629
 630             # Now try items from the least cost branch based on the transport cost matrix or StaticHoldsQueueWeight
 631             unless ( $itemnumber || !$holdingbranch) {
 632                 foreach my $current_item ( @{ $items_by_branch{$holdingbranch} } ) {
 633                     next unless _checkHoldPolicy($current_item, $request); # Don't fill item level holds that contravene the hold pickup policy at this time
 634
 635                     # If hold itemtype is set, item's itemtype must match
 636                     next unless ( !$request->{itemtype}
 637                         || $current_item->{itype} eq $request->{itemtype} );
 638
 639                     next unless $items_by_itemnumber{ $current_item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 640
 641                     $itemnumber = $current_item->{itemnumber};
 642                     last; # quit this loop as soon as we have a suitable item
 643                 }
 644             }
 645
 646             # Now try for items for any item that can fill this hold
 647             unless ( $itemnumber ) {
 648                 PULL_BRANCHES2:
 649                 foreach my $branch (@$pull_branches) {
 650                     my $holding_branch_items = $items_by_branch{$branch}
 651                       or next;
 652
 653                     foreach my $item (@$holding_branch_items) {
 654                         # Don't fill item level holds that contravene the hold pickup policy at this time
 655                         next unless _checkHoldPolicy($item, $request);
 656
 657                         # If hold itemtype is set, item's itemtype must match
 658                         next unless ( !$request->{itemtype}
 659                             || $item->{itype} eq $request->{itemtype} );
 660
 661                         next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 662
 663                         $itemnumber = $item->{itemnumber};
 664                         $holdingbranch = $branch;
 665                         last PULL_BRANCHES2;
 666                     }
 667                 }
 668             }
 669         }
 670
 671         if ($itemnumber) {
 672             my $holding_branch_items = $items_by_branch{$holdingbranch}
 673               or die "Have $itemnumber, $holdingbranch, but no items!";
 674             @$holding_branch_items = grep { $_->{itemnumber} != $itemnumber } @$holding_branch_items;
 675             delete $items_by_branch{$holdingbranch} unless @$holding_branch_items;
 676
 677             $item_map{$itemnumber} = {
 678                 borrowernumber => $request->{borrowernumber},
 679                 biblionumber => $request->{biblionumber},
 680                 holdingbranch => $holdingbranch,
 681                 pickup_branch => $pickup_branch,
 682                 reserve_id => $request->{reserve_id},
 683                 item_level => $request->{item_level_hold},
 684                 reservedate => $request->{reservedate},
 685                 reservenotes => $request->{reservenotes},
 686             };
 687             $num_items_remaining--;
 688         }
 689     }
 690     return \%item_map;
 691 }
 692
 693 =head2 CreatePickListFromItemMap
 694
 695 =cut
 696
 697 sub CreatePicklistFromItemMap {
 698     my $item_map = shift;
 699
 700     my $dbh = C4::Context->dbh;
 701
 702     my $sth_load=$dbh->prepare("
 703         INSERT INTO tmp_holdsqueue (biblionumber,itemnumber,barcode,surname,firstname,phone,borrowernumber,
 704                                     cardnumber,reservedate,title, itemcallnumber,
 705                                     holdingbranch,pickbranch,notes, item_level_request)
 706         VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 707     ");
 708
 709     foreach my $itemnumber  (sort keys %$item_map) {
 710         my $mapped_item = $item_map->{$itemnumber};
 711         my $biblionumber = $mapped_item->{biblionumber};
 712         my $borrowernumber = $mapped_item->{borrowernumber};
 713         my $pickbranch = $mapped_item->{pickup_branch};
 714         my $holdingbranch = $mapped_item->{holdingbranch};
 715         my $reservedate = $mapped_item->{reservedate};
 716         my $reservenotes = $mapped_item->{reservenotes};
 717         my $item_level = $mapped_item->{item_level};
 718
 719         my $item = Koha::Items->find($itemnumber);
 720         my $barcode = $item->barcode;
 721         my $itemcallnumber = $item->itemcallnumber;
 722
 723         my $patron = Koha::Patrons->find( $borrowernumber );
 724         my $cardnumber = $patron->cardnumber;
 725         my $surname = $patron->surname;
 726         my $firstname = $patron->firstname;
 727         my $phone = $patron->phone;
 728
 729         my $biblio = Koha::Biblios->find( $biblionumber );
 730         my $title = $biblio->title;
 731
 732         $sth_load->execute($biblionumber, $itemnumber, $barcode, $surname, $firstname, $phone, $borrowernumber,
 733                            $cardnumber, $reservedate, $title, $itemcallnumber,
 734                            $holdingbranch, $pickbranch, $reservenotes, $item_level);
 735     }
 736 }
 737
 738 =head2 AddToHoldTargetMap
 739
 740 =cut
 741
 742 sub AddToHoldTargetMap {
 743     my $item_map = shift;
 744
 745     my $dbh = C4::Context->dbh;
 746
 747     my $insert_sql = q(
 748         INSERT INTO hold_fill_targets (borrowernumber, biblionumber, itemnumber, source_branchcode, item_level_request, reserve_id)
 749                                VALUES (?, ?, ?, ?, ?, ?)
 750     );
 751     my $sth_insert = $dbh->prepare($insert_sql);
 752
 753     foreach my $itemnumber (keys %$item_map) {
 754         my $mapped_item = $item_map->{$itemnumber};
 755         $sth_insert->execute($mapped_item->{borrowernumber}, $mapped_item->{biblionumber}, $itemnumber,
 756                              $mapped_item->{holdingbranch}, $mapped_item->{item_level}, $mapped_item->{reserve_id});
 757     }
 758 }
 759
 760 # Helper functions, not part of any interface
 761
 762 sub _trim {
 763     return $_[0] unless $_[0];
 764     $_[0] =~ s/^\s+//;
 765     $_[0] =~ s/\s+$//;
 766     $_[0];
 767 }
 768
 769 sub load_branches_to_pull_from {
 770     my @branches_to_use;
 771
 772     my $static_branch_list = C4::Context->preference("StaticHoldsQueueWeight");
 773     @branches_to_use = map { _trim($_) } split( /,/, $static_branch_list )
 774       if $static_branch_list;
 775
 776     @branches_to_use =
 777       Koha::Database->new()->schema()->resultset('Branch')
 778       ->get_column('branchcode')->all()
 779       unless (@branches_to_use);
 780
 781     @branches_to_use = shuffle(@branches_to_use)
 782       if C4::Context->preference("RandomizeHoldsQueueWeight");
 783
 784     my $today = dt_from_string();
 785     if ( C4::Context->preference('HoldsQueueSkipClosed') ) {
 786         @branches_to_use = grep {
 787             !Koha::Calendar->new( branchcode => $_ )
 788               ->is_holiday( $today )
 789         } @branches_to_use;
 790     }
 791
 792     return \@branches_to_use;
 793 }
 794
 795 sub least_cost_branch {
 796
 797     #$from - arrayref
 798     my ($to, $from, $transport_cost_matrix) = @_;
 799
 800     # Nothing really spectacular: supply to branch, a list of potential from branches
 801     # and find the minimum from - to value from the transport_cost_matrix
 802     return $from->[0] if ( @$from == 1 && $transport_cost_matrix->{$to}{$from->[0]}->{disable_transfer} != 1 );
 803
 804     # If the pickup library is in the list of libraries to pull from,
 805     # return that library right away, it is obviously the least costly
 806     return ($to) if any { $_ eq $to } @$from;
 807
 808     my ($least_cost, @branch);
 809     foreach (@$from) {
 810         my $cell = $transport_cost_matrix->{$to}{$_};
 811         next if $cell->{disable_transfer};
 812
 813         my $cost = $cell->{cost};
 814         next unless defined $cost; # XXX should this be reported?
 815
 816         unless (defined $least_cost) {
 817             $least_cost = $cost;
 818             push @branch, $_;
 819             next;
 820         }
 821
 822         next if $cost > $least_cost;
 823
 824         if ($cost == $least_cost) {
 825             push @branch, $_;
 826             next;
 827         }
 828
 829         @branch = ($_);
 830         $least_cost = $cost;
 831     }
 832
 833     return $branch[0];
 834
 835     # XXX return a random @branch with minimum cost instead of the first one;
 836     # return $branch[0] if @branch == 1;
 837 }
 838
 839
 840 1;