C4/HoldsQueue.pm

   1 package C4::HoldsQueue;
   2
   3 # Copyright 2011 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 # FIXME: expand perldoc, explain intended logic
  21
  22 use strict;
  23 use warnings;
  24
  25 use C4::Context;
  26 use C4::Search;
  27 use C4::Items;
  28 use C4::Circulation;
  29 use C4::Members;
  30 use C4::Biblio;
  31 use Koha::DateUtils;
  32 use Koha::Items;
  33 use Koha::Patrons;
  34 use Koha::Libraries;
  35
  36 use List::Util qw(shuffle);
  37 use List::MoreUtils qw(any);
  38 use Data::Dumper;
  39
  40 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  41 BEGIN {
  42     require Exporter;
  43     @ISA = qw(Exporter);
  44     @EXPORT_OK = qw(
  45         &CreateQueue
  46         &GetHoldsQueueItems
  47
  48         &TransportCostMatrix
  49         &UpdateTransportCostMatrix
  50      );
  51 }
  52
  53
  54 =head1 FUNCTIONS
  55
  56 =head2 TransportCostMatrix
  57
  58   TransportCostMatrix();
  59
  60 Returns Transport Cost Matrix as a hashref <to branch code> => <from branch code> => cost
  61
  62 =cut
  63
  64 sub TransportCostMatrix {
  65     my ( $params ) = @_;
  66     my $ignore_holds_queue_skip_closed = $params->{ignore_holds_queue_skip_closed};
  67
  68     my $dbh   = C4::Context->dbh;
  69     my $transport_costs = $dbh->selectall_arrayref("SELECT * FROM transport_cost",{ Slice => {} });
  70
  71     my $today = dt_from_string();
  72     my $calendars;
  73     my %transport_cost_matrix;
  74     foreach (@$transport_costs) {
  75         my $from     = $_->{frombranch};
  76         my $to       = $_->{tobranch};
  77         my $cost     = $_->{cost};
  78         my $disabled = $_->{disable_transfer};
  79         $transport_cost_matrix{$to}{$from} = {
  80             cost             => $cost,
  81             disable_transfer => $disabled
  82         };
  83
  84         if ( !$ignore_holds_queue_skip_closed && C4::Context->preference("HoldsQueueSkipClosed") ) {
  85             $calendars->{$from} ||= Koha::Calendar->new( branchcode => $from );
  86             $transport_cost_matrix{$to}{$from}{disable_transfer} ||=
  87               $calendars->{$from}->is_holiday( $today );
  88         }
  89
  90     }
  91     return \%transport_cost_matrix;
  92 }
  93
  94 =head2 UpdateTransportCostMatrix
  95
  96   UpdateTransportCostMatrix($records);
  97
  98 Updates full Transport Cost Matrix table. $records is an arrayref of records.
  99 Records: { frombranch => <code>, tobranch => <code>, cost => <figure>, disable_transfer => <0,1> }
 100
 101 =cut
 102
 103 sub UpdateTransportCostMatrix {
 104     my ($records) = @_;
 105     my $dbh   = C4::Context->dbh;
 106
 107     my $sth = $dbh->prepare("INSERT INTO transport_cost (frombranch, tobranch, cost, disable_transfer) VALUES (?, ?, ?, ?)");
 108
 109     $dbh->do("DELETE FROM transport_cost");
 110     foreach (@$records) {
 111         my $cost = $_->{cost};
 112         my $from = $_->{frombranch};
 113         my $to = $_->{tobranch};
 114         if ($_->{disable_transfer}) {
 115             $cost ||= 0;
 116         }
 117         elsif ( !defined ($cost) || ($cost !~ m/(0|[1-9][0-9]*)(\.[0-9]*)?/o) ) {
 118             warn  "Invalid $from -> $to cost $cost - must be a number >= 0, disabling";
 119             $cost = 0;
 120             $_->{disable_transfer} = 1;
 121         }
 122         $sth->execute( $from, $to, $cost, $_->{disable_transfer} ? 1 : 0 );
 123     }
 124 }
 125
 126 =head2 GetHoldsQueueItems
 127
 128   GetHoldsQueueItems($branch);
 129
 130 Returns hold queue for a holding branch. If branch is omitted, then whole queue is returned
 131
 132 =cut
 133
 134 sub GetHoldsQueueItems {
 135     my ($branchlimit) = @_;
 136     my $dbh   = C4::Context->dbh;
 137
 138     my @bind_params = ();
 139     my $query = q/SELECT tmp_holdsqueue.*, biblio.author, items.ccode, items.itype, biblioitems.itemtype, items.location,
 140                          items.enumchron, items.cn_sort, biblioitems.publishercode,
 141                          biblio.copyrightdate, biblio.subtitle, biblio.medium,
 142                          biblio.part_number, biblio.part_name,
 143                          biblioitems.publicationyear, biblioitems.pages, biblioitems.size,
 144                          biblioitems.isbn, biblioitems.editionstatement, items.copynumber
 145                   FROM tmp_holdsqueue
 146                        JOIN biblio      USING (biblionumber)
 147                   LEFT JOIN biblioitems USING (biblionumber)
 148                   LEFT JOIN items       USING (  itemnumber)
 149                 /;
 150     if ($branchlimit) {
 151         $query .=" WHERE tmp_holdsqueue.holdingbranch = ?";
 152         push @bind_params, $branchlimit;
 153     }
 154     $query .= " ORDER BY ccode, location, cn_sort, author, title, pickbranch, reservedate";
 155     my $sth = $dbh->prepare($query);
 156     $sth->execute(@bind_params);
 157     my $items = [];
 158     while ( my $row = $sth->fetchrow_hashref ){
 159         # return the bib-level or item-level itype per syspref
 160         if (!C4::Context->preference('item-level_itypes')) {
 161             $row->{itype} = $row->{itemtype};
 162         }
 163         delete $row->{itemtype};
 164
 165         push @$items, $row;
 166     }
 167     return $items;
 168 }
 169
 170 =head2 CreateQueue
 171
 172   CreateQueue();
 173
 174 Top level function that turns reserves into tmp_holdsqueue and hold_fill_targets.
 175
 176 =cut
 177
 178 sub CreateQueue {
 179     my $dbh   = C4::Context->dbh;
 180
 181     $dbh->do("DELETE FROM tmp_holdsqueue");  # clear the old table for new info
 182     $dbh->do("DELETE FROM hold_fill_targets");
 183
 184     my $total_bibs            = 0;
 185     my $total_requests        = 0;
 186     my $total_available_items = 0;
 187     my $num_items_mapped      = 0;
 188
 189     my $branches_to_use;
 190     my $transport_cost_matrix;
 191     my $use_transport_cost_matrix = C4::Context->preference("UseTransportCostMatrix");
 192     if ($use_transport_cost_matrix) {
 193         $transport_cost_matrix = TransportCostMatrix();
 194         unless (keys %$transport_cost_matrix) {
 195             warn "UseTransportCostMatrix set to yes, but matrix not populated";
 196             undef $transport_cost_matrix;
 197         }
 198     }
 199     unless ($transport_cost_matrix) {
 200         $branches_to_use = load_branches_to_pull_from();
 201     }
 202
 203     my $bibs_with_pending_requests = GetBibsWithPendingHoldRequests();
 204
 205     foreach my $biblionumber (@$bibs_with_pending_requests) {
 206         $total_bibs++;
 207         my $hold_requests   = GetPendingHoldRequestsForBib($biblionumber);
 208         my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_to_use);
 209         $total_requests        += scalar(@$hold_requests);
 210         $total_available_items += scalar(@$available_items);
 211
 212         my $item_map = MapItemsToHoldRequests($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix);
 213         $item_map  or next;
 214         my $item_map_size = scalar(keys %$item_map)
 215           or next;
 216
 217         $num_items_mapped += $item_map_size;
 218         CreatePicklistFromItemMap($item_map);
 219         AddToHoldTargetMap($item_map);
 220         if (($item_map_size < scalar(@$hold_requests  )) and
 221             ($item_map_size < scalar(@$available_items))) {
 222             # DOUBLE CHECK, but this is probably OK - unfilled item-level requests
 223             # FIXME
 224             #warn "unfilled requests for $biblionumber";
 225             #warn Dumper($hold_requests), Dumper($available_items), Dumper($item_map);
 226         }
 227     }
 228 }
 229
 230 =head2 GetBibsWithPendingHoldRequests
 231
 232   my $biblionumber_aref = GetBibsWithPendingHoldRequests();
 233
 234 Return an arrayref of the biblionumbers of all bibs
 235 that have one or more unfilled hold requests.
 236
 237 =cut
 238
 239 sub GetBibsWithPendingHoldRequests {
 240     my $dbh = C4::Context->dbh;
 241
 242     my $bib_query = "SELECT DISTINCT biblionumber
 243                      FROM reserves
 244                      WHERE found IS NULL
 245                      AND priority > 0
 246                      AND reservedate <= CURRENT_DATE()
 247                      AND suspend = 0
 248                      ";
 249     my $sth = $dbh->prepare($bib_query);
 250
 251     $sth->execute();
 252     my $biblionumbers = $sth->fetchall_arrayref();
 253
 254     return [ map { $_->[0] } @$biblionumbers ];
 255 }
 256
 257 =head2 GetPendingHoldRequestsForBib
 258
 259   my $requests = GetPendingHoldRequestsForBib($biblionumber);
 260
 261 Returns an arrayref of hashrefs to pending, unfilled hold requests
 262 on the bib identified by $biblionumber.  The following keys
 263 are present in each hashref:
 264
 265     biblionumber
 266     borrowernumber
 267     itemnumber
 268     priority
 269     branchcode
 270     reservedate
 271     reservenotes
 272     borrowerbranch
 273
 274 The arrayref is sorted in order of increasing priority.
 275
 276 =cut
 277
 278 sub GetPendingHoldRequestsForBib {
 279     my $biblionumber = shift;
 280
 281     my $dbh = C4::Context->dbh;
 282
 283     my $request_query = "SELECT biblionumber, borrowernumber, itemnumber, priority, reserve_id, reserves.branchcode,
 284                                 reservedate, reservenotes, borrowers.branchcode AS borrowerbranch, itemtype, item_level_hold
 285                          FROM reserves
 286                          JOIN borrowers USING (borrowernumber)
 287                          WHERE biblionumber = ?
 288                          AND found IS NULL
 289                          AND priority > 0
 290                          AND reservedate <= CURRENT_DATE()
 291                          AND suspend = 0
 292                          ORDER BY priority";
 293     my $sth = $dbh->prepare($request_query);
 294     $sth->execute($biblionumber);
 295
 296     my $requests = $sth->fetchall_arrayref({});
 297     return $requests;
 298
 299 }
 300
 301 =head2 GetItemsAvailableToFillHoldRequestsForBib
 302
 303   my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_ar);
 304
 305 Returns an arrayref of items available to fill hold requests
 306 for the bib identified by C<$biblionumber>.  An item is available
 307 to fill a hold request if and only if:
 308
 309     * it is not on loan
 310     * it is not withdrawn
 311     * it is not marked notforloan
 312     * it is not currently in transit
 313     * it is not lost
 314     * it is not sitting on the hold shelf
 315     * it is not damaged (unless AllowHoldsOnDamagedItems is on)
 316
 317 =cut
 318
 319 sub GetItemsAvailableToFillHoldRequestsForBib {
 320     my ($biblionumber, $branches_to_use) = @_;
 321
 322     my $dbh = C4::Context->dbh;
 323     my $items_query = "SELECT itemnumber, homebranch, holdingbranch, itemtypes.itemtype AS itype
 324                        FROM items ";
 325
 326     if (C4::Context->preference('item-level_itypes')) {
 327         $items_query .=   "LEFT JOIN itemtypes ON (itemtypes.itemtype = items.itype) ";
 328     } else {
 329         $items_query .=   "JOIN biblioitems USING (biblioitemnumber)
 330                            LEFT JOIN itemtypes USING (itemtype) ";
 331     }
 332     $items_query .=   "WHERE items.notforloan = 0
 333                        AND holdingbranch IS NOT NULL
 334                        AND itemlost = 0
 335                        AND withdrawn = 0";
 336     $items_query .= "  AND damaged = 0" unless C4::Context->preference('AllowHoldsOnDamagedItems');
 337     $items_query .= "  AND items.onloan IS NULL
 338                        AND (itemtypes.notforloan IS NULL OR itemtypes.notforloan = 0)
 339                        AND itemnumber NOT IN (
 340                            SELECT itemnumber
 341                            FROM reserves
 342                            WHERE biblionumber = ?
 343                            AND itemnumber IS NOT NULL
 344                            AND (found IS NOT NULL OR priority = 0)
 345                         )
 346                        AND items.biblionumber = ?";
 347
 348     my @params = ($biblionumber, $biblionumber);
 349     if ($branches_to_use && @$branches_to_use) {
 350         $items_query .= " AND holdingbranch IN (" . join (",", map { "?" } @$branches_to_use) . ")";
 351         push @params, @$branches_to_use;
 352     }
 353     my $sth = $dbh->prepare($items_query);
 354     $sth->execute(@params);
 355
 356     my $itm = $sth->fetchall_arrayref({});
 357     my @items = grep { ! scalar GetTransfers($_->{itemnumber}) } @$itm;
 358     return [ grep {
 359         my $rule = GetBranchItemRule($_->{homebranch}, $_->{itype});
 360         $_->{holdallowed} = $rule->{holdallowed};
 361         $_->{hold_fulfillment_policy} = $rule->{hold_fulfillment_policy};
 362     } @items ];
 363 }
 364
 365 =head2 _checkHoldPolicy
 366
 367     _checkHoldPolicy($item, $request)
 368
 369     check if item agrees with hold policies
 370
 371 =cut
 372
 373 our $libraries = {};
 374 sub _checkHoldPolicy {
 375     my ($item, $request) = @_;
 376
 377     return 0 unless $item->{holdallowed};
 378     return 0 if $item->{holdallowed} == 1 && $item->{homebranch} ne $request->{borrowerbranch};
 379
 380     $libraries->{$item->{homebranch}} ||= Koha::Libraries->find($item->{homebranch});
 381     my $library = $libraries->{$item->{homebranch}};
 382
 383     return 0 if $item->{'holdallowed'} == 3 && !$library->validate_hold_sibling({branchcode => $request->{borrowerbranch}});
 384
 385     my $hold_fulfillment_policy = $item->{hold_fulfillment_policy};
 386
 387     return 0 if $hold_fulfillment_policy eq 'holdgroup' && !$library->validate_hold_sibling({branchcode => $request->{branchcode}});
 388     return 0 if $hold_fulfillment_policy eq 'homebranch' && $request->{branchcode} ne $item->{$hold_fulfillment_policy};
 389     return 0 if $hold_fulfillment_policy eq 'holdingbranch' && $request->{branchcode} ne $item->{$hold_fulfillment_policy};
 390
 391     $libraries->{$request->{borrowerbranch}} ||= Koha::Libraries->find($request->{borrowerbranch});
 392     my $patronLibrary = $libraries->{$request->{borrowerbranch}};
 393
 394     return 0 if $hold_fulfillment_policy eq 'patrongroup' && !$patronLibrary->validate_hold_sibling({branchcode => $request->{branchcode}});
 395
 396     return 1;
 397
 398 }
 399
 400 =head2 MapItemsToHoldRequests
 401
 402   MapItemsToHoldRequests($hold_requests, $available_items, $branches, $transport_cost_matrix)
 403
 404 =cut
 405
 406 sub MapItemsToHoldRequests {
 407     my ($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix) = @_;
 408
 409     # handle trival cases
 410     return unless scalar(@$hold_requests) > 0;
 411     return unless scalar(@$available_items) > 0;
 412
 413     # identify item-level requests
 414     my %specific_items_requested = map { $_->{itemnumber} => 1 }
 415                                    grep { defined($_->{itemnumber}) }
 416                                    @$hold_requests;
 417
 418     map { $_->{_object} = Koha::Items->find( $_->{itemnumber} ) } @$available_items;
 419     my $libraries = {};
 420     map { $libraries->{$_->id} = $_ } Koha::Libraries->search();
 421
 422     # group available items by itemnumber
 423     my %items_by_itemnumber = map { $_->{itemnumber} => $_ } @$available_items;
 424
 425     # items already allocated
 426     my %allocated_items = ();
 427
 428     # map of items to hold requests
 429     my %item_map = ();
 430
 431     # figure out which item-level requests can be filled
 432     my $num_items_remaining = scalar(@$available_items);
 433
 434     # Look for Local Holds Priority matches first
 435     if ( C4::Context->preference('LocalHoldsPriority') ) {
 436         my $LocalHoldsPriorityPatronControl =
 437           C4::Context->preference('LocalHoldsPriorityPatronControl');
 438         my $LocalHoldsPriorityItemControl =
 439           C4::Context->preference('LocalHoldsPriorityItemControl');
 440
 441         foreach my $request (@$hold_requests) {
 442             last if $num_items_remaining == 0;
 443             my $patron = Koha::Patrons->find($request->{borrowernumber});
 444             next if $patron->category->exclude_from_local_holds_priority;
 445
 446             my $local_hold_match;
 447             foreach my $item (@$available_items) {
 448                 next if $item->{_object}->exclude_from_local_holds_priority;
 449
 450                 next unless _checkHoldPolicy($item, $request);
 451
 452                 next if $request->{itemnumber} && $request->{itemnumber} != $item->{itemnumber};
 453
 454                 next unless $item->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 455
 456                 my $local_holds_priority_item_branchcode =
 457                   $item->{$LocalHoldsPriorityItemControl};
 458
 459                 my $local_holds_priority_patron_branchcode =
 460                   ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 461                   ? $request->{branchcode}
 462                   : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 463                   ? $request->{borrowerbranch}
 464                   : undef;
 465
 466                 $local_hold_match =
 467                   $local_holds_priority_item_branchcode eq
 468                   $local_holds_priority_patron_branchcode;
 469
 470                 if ($local_hold_match) {
 471                     if ( exists $items_by_itemnumber{ $item->{itemnumber} }
 472                         and not exists $allocated_items{ $item->{itemnumber} }
 473                         and not $request->{allocated})
 474                     {
 475                         $item_map{ $item->{itemnumber} } = {
 476                             borrowernumber => $request->{borrowernumber},
 477                             biblionumber   => $request->{biblionumber},
 478                             holdingbranch  => $item->{holdingbranch},
 479                             pickup_branch  => $request->{branchcode}
 480                               || $request->{borrowerbranch},
 481                             reserve_id   => $request->{reserve_id},
 482                             item_level   => $request->{item_level_hold},
 483                             reservedate  => $request->{reservedate},
 484                             reservenotes => $request->{reservenotes},
 485                         };
 486                         $allocated_items{ $item->{itemnumber} }++;
 487                         $request->{allocated} = 1;
 488                         $num_items_remaining--;
 489                     }
 490                 }
 491             }
 492         }
 493     }
 494
 495     foreach my $request (@$hold_requests) {
 496         last if $num_items_remaining == 0;
 497         next if $request->{allocated};
 498
 499         # is this an item-level request?
 500         if (defined($request->{itemnumber})) {
 501             # fill it if possible; if not skip it
 502             if (
 503                     exists $items_by_itemnumber{ $request->{itemnumber} }
 504                 and not exists $allocated_items{ $request->{itemnumber} }
 505                 and  _checkHoldPolicy($items_by_itemnumber{ $request->{itemnumber} }, $request) # Don't fill item level holds that contravene the hold pickup policy at this time
 506                 and ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 507                     || $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} )
 508
 509                 and $items_by_itemnumber{ $request->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } )
 510
 511               )
 512             {
 513
 514                 $item_map{ $request->{itemnumber} } = {
 515                     borrowernumber => $request->{borrowernumber},
 516                     biblionumber   => $request->{biblionumber},
 517                     holdingbranch  => $items_by_itemnumber{ $request->{itemnumber} }->{holdingbranch},
 518                     pickup_branch  => $request->{branchcode} || $request->{borrowerbranch},
 519                     reserve_id     => $request->{reserve_id},
 520                     item_level     => $request->{item_level_hold},
 521                     reservedate    => $request->{reservedate},
 522                     reservenotes   => $request->{reservenotes},
 523                 };
 524                 $allocated_items{ $request->{itemnumber} }++;
 525                 $num_items_remaining--;
 526             }
 527         } else {
 528             # it's title-level request that will take up one item
 529             $num_items_remaining--;
 530         }
 531     }
 532
 533     # group available items by branch
 534     my %items_by_branch = ();
 535     foreach my $item (@$available_items) {
 536         next unless $item->{holdallowed};
 537
 538         push @{ $items_by_branch{ $item->{holdingbranch} } }, $item
 539           unless exists $allocated_items{ $item->{itemnumber} };
 540     }
 541     return \%item_map unless keys %items_by_branch;
 542
 543     # now handle the title-level requests
 544     $num_items_remaining = scalar(@$available_items) - scalar(keys %allocated_items);
 545     my $pull_branches;
 546     foreach my $request (@$hold_requests) {
 547         last if $num_items_remaining == 0;
 548         next if $request->{allocated};
 549         next if defined($request->{itemnumber}); # already handled these
 550
 551         # look for local match first
 552         my $pickup_branch = $request->{branchcode} || $request->{borrowerbranch};
 553         my ($itemnumber, $holdingbranch);
 554
 555         my $holding_branch_items = $items_by_branch{$pickup_branch};
 556         if ( $holding_branch_items ) {
 557             foreach my $item (@$holding_branch_items) {
 558                 next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 559
 560                 if (
 561                     $request->{borrowerbranch} eq $item->{homebranch}
 562                     && _checkHoldPolicy($item, $request) # Don't fill item level holds that contravene the hold pickup policy at this time
 563                     && ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 564                         || ( $request->{itemnumber} && ( $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} ) ) )
 565                   )
 566                 {
 567                     $itemnumber = $item->{itemnumber};
 568                     last;
 569                 }
 570             }
 571             $holdingbranch = $pickup_branch;
 572         }
 573         elsif ($transport_cost_matrix) {
 574             $pull_branches = [keys %items_by_branch];
 575             $holdingbranch = least_cost_branch( $pickup_branch, $pull_branches, $transport_cost_matrix );
 576             if ( $holdingbranch ) {
 577
 578                 my $holding_branch_items = $items_by_branch{$holdingbranch};
 579                 foreach my $item (@$holding_branch_items) {
 580                     next if $request->{borrowerbranch} ne $item->{homebranch};
 581                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 582
 583                     # Don't fill item level holds that contravene the hold pickup policy at this time
 584                     next unless _checkHoldPolicy($item, $request);
 585
 586                     # If hold itemtype is set, item's itemtype must match
 587                     next unless ( !$request->{itemtype}
 588                         || $item->{itype} eq $request->{itemtype} );
 589
 590                     $itemnumber = $item->{itemnumber};
 591                     last;
 592                 }
 593             }
 594             else {
 595                 next;
 596             }
 597         }
 598
 599         unless ($itemnumber) {
 600             # not found yet, fall back to basics
 601             if ($branches_to_use) {
 602                 $pull_branches = $branches_to_use;
 603             } else {
 604                 $pull_branches = [keys %items_by_branch];
 605             }
 606
 607             # Try picking items where the home and pickup branch match first
 608             PULL_BRANCHES:
 609             foreach my $branch (@$pull_branches) {
 610                 my $holding_branch_items = $items_by_branch{$branch}
 611                   or next;
 612
 613                 $holdingbranch ||= $branch;
 614                 foreach my $item (@$holding_branch_items) {
 615                     next if $pickup_branch ne $item->{homebranch};
 616                     next unless _checkHoldPolicy($item, $request);
 617                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 618
 619                     # Don't fill item level holds that contravene the hold pickup policy at this time
 620                     next unless $item->{hold_fulfillment_policy} eq 'any'
 621                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 622
 623                     # If hold itemtype is set, item's itemtype must match
 624                     next unless ( !$request->{itemtype}
 625                         || $item->{itype} eq $request->{itemtype} );
 626
 627                     $itemnumber = $item->{itemnumber};
 628                     $holdingbranch = $branch;
 629                     last PULL_BRANCHES;
 630                 }
 631             }
 632
 633             # Now try items from the least cost branch based on the transport cost matrix or StaticHoldsQueueWeight
 634             unless ( $itemnumber || !$holdingbranch) {
 635                 foreach my $current_item ( @{ $items_by_branch{$holdingbranch} } ) {
 636                     next unless _checkHoldPolicy($current_item, $request); # Don't fill item level holds that contravene the hold pickup policy at this time
 637
 638                     # If hold itemtype is set, item's itemtype must match
 639                     next unless ( !$request->{itemtype}
 640                         || $current_item->{itype} eq $request->{itemtype} );
 641
 642                     next unless $items_by_itemnumber{ $current_item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 643
 644                     $itemnumber = $current_item->{itemnumber};
 645                     last; # quit this loop as soon as we have a suitable item
 646                 }
 647             }
 648
 649             # Now try for items for any item that can fill this hold
 650             unless ( $itemnumber ) {
 651                 PULL_BRANCHES2:
 652                 foreach my $branch (@$pull_branches) {
 653                     my $holding_branch_items = $items_by_branch{$branch}
 654                       or next;
 655
 656                     foreach my $item (@$holding_branch_items) {
 657                         # Don't fill item level holds that contravene the hold pickup policy at this time
 658                         next unless _checkHoldPolicy($item, $request);
 659
 660                         # If hold itemtype is set, item's itemtype must match
 661                         next unless ( !$request->{itemtype}
 662                             || $item->{itype} eq $request->{itemtype} );
 663
 664                         next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 665
 666                         $itemnumber = $item->{itemnumber};
 667                         $holdingbranch = $branch;
 668                         last PULL_BRANCHES2;
 669                     }
 670                 }
 671             }
 672         }
 673
 674         if ($itemnumber) {
 675             my $holding_branch_items = $items_by_branch{$holdingbranch}
 676               or die "Have $itemnumber, $holdingbranch, but no items!";
 677             @$holding_branch_items = grep { $_->{itemnumber} != $itemnumber } @$holding_branch_items;
 678             delete $items_by_branch{$holdingbranch} unless @$holding_branch_items;
 679
 680             $item_map{$itemnumber} = {
 681                 borrowernumber => $request->{borrowernumber},
 682                 biblionumber => $request->{biblionumber},
 683                 holdingbranch => $holdingbranch,
 684                 pickup_branch => $pickup_branch,
 685                 reserve_id => $request->{reserve_id},
 686                 item_level => $request->{item_level_hold},
 687                 reservedate => $request->{reservedate},
 688                 reservenotes => $request->{reservenotes},
 689             };
 690             $num_items_remaining--;
 691         }
 692     }
 693     return \%item_map;
 694 }
 695
 696 =head2 CreatePickListFromItemMap
 697
 698 =cut
 699
 700 sub CreatePicklistFromItemMap {
 701     my $item_map = shift;
 702
 703     my $dbh = C4::Context->dbh;
 704
 705     my $sth_load=$dbh->prepare("
 706         INSERT INTO tmp_holdsqueue (biblionumber,itemnumber,barcode,surname,firstname,phone,borrowernumber,
 707                                     cardnumber,reservedate,title, itemcallnumber,
 708                                     holdingbranch,pickbranch,notes, item_level_request)
 709         VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 710     ");
 711
 712     foreach my $itemnumber  (sort keys %$item_map) {
 713         my $mapped_item = $item_map->{$itemnumber};
 714         my $biblionumber = $mapped_item->{biblionumber};
 715         my $borrowernumber = $mapped_item->{borrowernumber};
 716         my $pickbranch = $mapped_item->{pickup_branch};
 717         my $holdingbranch = $mapped_item->{holdingbranch};
 718         my $reservedate = $mapped_item->{reservedate};
 719         my $reservenotes = $mapped_item->{reservenotes};
 720         my $item_level = $mapped_item->{item_level};
 721
 722         my $item = Koha::Items->find($itemnumber);
 723         my $barcode = $item->barcode;
 724         my $itemcallnumber = $item->itemcallnumber;
 725
 726         my $patron = Koha::Patrons->find( $borrowernumber );
 727         my $cardnumber = $patron->cardnumber;
 728         my $surname = $patron->surname;
 729         my $firstname = $patron->firstname;
 730         my $phone = $patron->phone;
 731
 732         my $biblio = Koha::Biblios->find( $biblionumber );
 733         my $title = $biblio->title;
 734
 735         $sth_load->execute($biblionumber, $itemnumber, $barcode, $surname, $firstname, $phone, $borrowernumber,
 736                            $cardnumber, $reservedate, $title, $itemcallnumber,
 737                            $holdingbranch, $pickbranch, $reservenotes, $item_level);
 738     }
 739 }
 740
 741 =head2 AddToHoldTargetMap
 742
 743 =cut
 744
 745 sub AddToHoldTargetMap {
 746     my $item_map = shift;
 747
 748     my $dbh = C4::Context->dbh;
 749
 750     my $insert_sql = q(
 751         INSERT INTO hold_fill_targets (borrowernumber, biblionumber, itemnumber, source_branchcode, item_level_request, reserve_id)
 752                                VALUES (?, ?, ?, ?, ?, ?)
 753     );
 754     my $sth_insert = $dbh->prepare($insert_sql);
 755
 756     foreach my $itemnumber (keys %$item_map) {
 757         my $mapped_item = $item_map->{$itemnumber};
 758         $sth_insert->execute($mapped_item->{borrowernumber}, $mapped_item->{biblionumber}, $itemnumber,
 759                              $mapped_item->{holdingbranch}, $mapped_item->{item_level}, $mapped_item->{reserve_id});
 760     }
 761 }
 762
 763 # Helper functions, not part of any interface
 764
 765 sub _trim {
 766     return $_[0] unless $_[0];
 767     $_[0] =~ s/^\s+//;
 768     $_[0] =~ s/\s+$//;
 769     $_[0];
 770 }
 771
 772 sub load_branches_to_pull_from {
 773     my @branches_to_use;
 774
 775     my $static_branch_list = C4::Context->preference("StaticHoldsQueueWeight");
 776     @branches_to_use = map { _trim($_) } split( /,/, $static_branch_list )
 777       if $static_branch_list;
 778
 779     @branches_to_use =
 780       Koha::Database->new()->schema()->resultset('Branch')
 781       ->get_column('branchcode')->all()
 782       unless (@branches_to_use);
 783
 784     @branches_to_use = shuffle(@branches_to_use)
 785       if C4::Context->preference("RandomizeHoldsQueueWeight");
 786
 787     my $today = dt_from_string();
 788     if ( C4::Context->preference('HoldsQueueSkipClosed') ) {
 789         @branches_to_use = grep {
 790             !Koha::Calendar->new( branchcode => $_ )
 791               ->is_holiday( $today )
 792         } @branches_to_use;
 793     }
 794
 795     return \@branches_to_use;
 796 }
 797
 798 sub least_cost_branch {
 799
 800     #$from - arrayref
 801     my ($to, $from, $transport_cost_matrix) = @_;
 802
 803     # Nothing really spectacular: supply to branch, a list of potential from branches
 804     # and find the minimum from - to value from the transport_cost_matrix
 805     return $from->[0] if ( @$from == 1 && $transport_cost_matrix->{$to}{$from->[0]}->{disable_transfer} != 1 );
 806
 807     # If the pickup library is in the list of libraries to pull from,
 808     # return that library right away, it is obviously the least costly
 809     return ($to) if any { $_ eq $to } @$from;
 810
 811     my ($least_cost, @branch);
 812     foreach (@$from) {
 813         my $cell = $transport_cost_matrix->{$to}{$_};
 814         next if $cell->{disable_transfer};
 815
 816         my $cost = $cell->{cost};
 817         next unless defined $cost; # XXX should this be reported?
 818
 819         unless (defined $least_cost) {
 820             $least_cost = $cost;
 821             push @branch, $_;
 822             next;
 823         }
 824
 825         next if $cost > $least_cost;
 826
 827         if ($cost == $least_cost) {
 828             push @branch, $_;
 829             next;
 830         }
 831
 832         @branch = ($_);
 833         $least_cost = $cost;
 834     }
 835
 836     return $branch[0];
 837
 838     # XXX return a random @branch with minimum cost instead of the first one;
 839     # return $branch[0] if @branch == 1;
 840 }
 841
 842
 843 1;