C4/ImportBatch.pm

   1 package C4::ImportBatch;
   2
   3 # Copyright (C) 2007 LibLime, 2012 C & P Bibliography Services
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use C4::Context;
  24 use C4::Koha qw( GetNormalizedISBN );
  25 use C4::Biblio qw(
  26     AddBiblio
  27     DelBiblio
  28     GetMarcFromKohaField
  29     GetXmlBiblio
  30     ModBiblio
  31     TransformMarcToKoha
  32 );
  33 use C4::Items qw( AddItemFromMarc ModItemFromMarc );
  34 use C4::Charset qw( MarcToUTF8Record SetUTF8Flag StripNonXmlChars );
  35 use C4::AuthoritiesMarc qw( AddAuthority GuessAuthTypeCode GetAuthorityXML ModAuthority DelAuthority );
  36 use C4::MarcModificationTemplates qw( ModifyRecordWithTemplate );
  37 use Koha::Items;
  38 use Koha::Plugins::Handler;
  39 use Koha::Logger;
  40
  41 our (@ISA, @EXPORT_OK);
  42 BEGIN {
  43     require Exporter;
  44     @ISA       = qw(Exporter);
  45     @EXPORT_OK = qw(
  46       GetZ3950BatchId
  47       GetWebserviceBatchId
  48       GetImportRecordMarc
  49       GetImportRecordMarcXML
  50       GetRecordFromImportBiblio
  51       AddImportBatch
  52       GetImportBatch
  53       AddAuthToBatch
  54       AddBiblioToBatch
  55       AddItemsToImportBiblio
  56       ModAuthorityInBatch
  57       ModBiblioInBatch
  58
  59       BatchStageMarcRecords
  60       BatchFindDuplicates
  61       BatchCommitRecords
  62       BatchRevertRecords
  63       CleanBatch
  64       DeleteBatch
  65
  66       GetAllImportBatches
  67       GetStagedWebserviceBatches
  68       GetImportBatchRangeDesc
  69       GetNumberOfNonZ3950ImportBatches
  70       GetImportBiblios
  71       GetImportRecordsRange
  72       GetItemNumbersFromImportBatch
  73
  74       GetImportBatchStatus
  75       SetImportBatchStatus
  76       GetImportBatchOverlayAction
  77       SetImportBatchOverlayAction
  78       GetImportBatchNoMatchAction
  79       SetImportBatchNoMatchAction
  80       GetImportBatchItemAction
  81       SetImportBatchItemAction
  82       GetImportBatchMatcher
  83       SetImportBatchMatcher
  84       GetImportRecordOverlayStatus
  85       SetImportRecordOverlayStatus
  86       GetImportRecordStatus
  87       SetImportRecordStatus
  88       SetMatchedBiblionumber
  89       GetImportRecordMatches
  90       SetImportRecordMatches
  91
  92       RecordsFromMARCXMLFile
  93       RecordsFromISO2709File
  94       RecordsFromMarcPlugin
  95     );
  96 }
  97
  98 =head1 NAME
  99
 100 C4::ImportBatch - manage batches of imported MARC records
 101
 102 =head1 SYNOPSIS
 103
 104 use C4::ImportBatch;
 105
 106 =head1 FUNCTIONS
 107
 108 =head2 GetZ3950BatchId
 109
 110   my $batchid = GetZ3950BatchId($z3950server);
 111
 112 Retrieves the ID of the import batch for the Z39.50
 113 reservoir for the given target.  If necessary,
 114 creates the import batch.
 115
 116 =cut
 117
 118 sub GetZ3950BatchId {
 119     my ($z3950server) = @_;
 120
 121     my $dbh = C4::Context->dbh;
 122     my $sth = $dbh->prepare("SELECT import_batch_id FROM import_batches
 123                              WHERE  batch_type = 'z3950'
 124                              AND    file_name = ?");
 125     $sth->execute($z3950server);
 126     my $rowref = $sth->fetchrow_arrayref();
 127     $sth->finish();
 128     if (defined $rowref) {
 129         return $rowref->[0];
 130     } else {
 131         my $batch_id = AddImportBatch( {
 132                 overlay_action => 'create_new',
 133                 import_status => 'staged',
 134                 batch_type => 'z3950',
 135                 file_name => $z3950server,
 136             } );
 137         return $batch_id;
 138     }
 139
 140 }
 141
 142 =head2 GetWebserviceBatchId
 143
 144   my $batchid = GetWebserviceBatchId();
 145
 146 Retrieves the ID of the import batch for webservice.
 147 If necessary, creates the import batch.
 148
 149 =cut
 150
 151 my $WEBSERVICE_BASE_QRY = <<EOQ;
 152 SELECT import_batch_id FROM import_batches
 153 WHERE  batch_type = 'webservice'
 154 AND    import_status = 'staged'
 155 EOQ
 156 sub GetWebserviceBatchId {
 157     my ($params) = @_;
 158
 159     my $dbh = C4::Context->dbh;
 160     my $sql = $WEBSERVICE_BASE_QRY;
 161     my @args;
 162     foreach my $field (qw(matcher_id overlay_action nomatch_action item_action)) {
 163         if (my $val = $params->{$field}) {
 164             $sql .= " AND $field = ?";
 165             push @args, $val;
 166         }
 167     }
 168     my $id = $dbh->selectrow_array($sql, undef, @args);
 169     return $id if $id;
 170
 171     $params->{batch_type} = 'webservice';
 172     $params->{import_status} = 'staged';
 173     return AddImportBatch($params);
 174 }
 175
 176 =head2 GetImportRecordMarc
 177
 178   my ($marcblob, $encoding) = GetImportRecordMarc($import_record_id);
 179
 180 =cut
 181
 182 sub GetImportRecordMarc {
 183     my ($import_record_id) = @_;
 184
 185     my $dbh = C4::Context->dbh;
 186     my ( $marc, $encoding ) = $dbh->selectrow_array(q|
 187         SELECT marc, encoding
 188         FROM import_records
 189         WHERE import_record_id = ?
 190     |, undef, $import_record_id );
 191
 192     return $marc, $encoding;
 193 }
 194
 195 sub GetRecordFromImportBiblio {
 196     my ( $import_record_id, $embed_items ) = @_;
 197
 198     my ($marc) = GetImportRecordMarc($import_record_id);
 199     my $record = MARC::Record->new_from_usmarc($marc);
 200
 201     EmbedItemsInImportBiblio( $record, $import_record_id ) if $embed_items;
 202
 203     return $record;
 204 }
 205
 206 sub EmbedItemsInImportBiblio {
 207     my ( $record, $import_record_id ) = @_;
 208     my ( $itemtag, $itemsubfield ) = GetMarcFromKohaField( "items.itemnumber" );
 209     my $dbh = C4::Context->dbh;
 210     my $import_items = $dbh->selectall_arrayref(q|
 211         SELECT import_items.marcxml
 212         FROM import_items
 213         WHERE import_record_id = ?
 214     |, { Slice => {} }, $import_record_id );
 215     my @item_fields;
 216     for my $import_item ( @$import_items ) {
 217         my $item_marc = MARC::Record::new_from_xml($import_item->{marcxml}, 'UTF-8');
 218         push @item_fields, $item_marc->field($itemtag);
 219     }
 220     $record->append_fields(@item_fields);
 221     return $record;
 222 }
 223
 224 =head2 GetImportRecordMarcXML
 225
 226   my $marcxml = GetImportRecordMarcXML($import_record_id);
 227
 228 =cut
 229
 230 sub GetImportRecordMarcXML {
 231     my ($import_record_id) = @_;
 232
 233     my $dbh = C4::Context->dbh;
 234     my $sth = $dbh->prepare("SELECT marcxml FROM import_records WHERE import_record_id = ?");
 235     $sth->execute($import_record_id);
 236     my ($marcxml) = $sth->fetchrow();
 237     $sth->finish();
 238     return $marcxml;
 239
 240 }
 241
 242 =head2 AddImportBatch
 243
 244   my $batch_id = AddImportBatch($params_hash);
 245
 246 =cut
 247
 248 sub AddImportBatch {
 249     my ($params) = @_;
 250
 251     my (@fields, @vals);
 252     foreach (qw( matcher_id template_id branchcode
 253                  overlay_action nomatch_action item_action
 254                  import_status batch_type file_name comments record_type )) {
 255         if (exists $params->{$_}) {
 256             push @fields, $_;
 257             push @vals, $params->{$_};
 258         }
 259     }
 260     my $dbh = C4::Context->dbh;
 261     $dbh->do("INSERT INTO import_batches (".join( ',', @fields).")
 262                                   VALUES (".join( ',', map '?', @fields).")",
 263              undef,
 264              @vals);
 265     return $dbh->{'mysql_insertid'};
 266 }
 267
 268 =head2 GetImportBatch
 269
 270   my $row = GetImportBatch($batch_id);
 271
 272 Retrieve a hashref of an import_batches row.
 273
 274 =cut
 275
 276 sub GetImportBatch {
 277     my ($batch_id) = @_;
 278
 279     my $dbh = C4::Context->dbh;
 280     my $sth = $dbh->prepare_cached("SELECT b.*, p.name as profile FROM import_batches b LEFT JOIN import_batch_profiles p ON p.id = b.profile_id WHERE import_batch_id = ?");
 281     $sth->bind_param(1, $batch_id);
 282     $sth->execute();
 283     my $result = $sth->fetchrow_hashref;
 284     $sth->finish();
 285     return $result;
 286
 287 }
 288
 289 =head2 AddBiblioToBatch
 290
 291   my $import_record_id = AddBiblioToBatch($batch_id, $record_sequence,
 292                 $marc_record, $encoding, $update_counts);
 293
 294 =cut
 295
 296 sub AddBiblioToBatch {
 297     my $batch_id = shift;
 298     my $record_sequence = shift;
 299     my $marc_record = shift;
 300     my $encoding = shift;
 301     my $update_counts = @_ ? shift : 1;
 302
 303     my $import_record_id = _create_import_record($batch_id, $record_sequence, $marc_record, 'biblio', $encoding, C4::Context->preference('marcflavour'));
 304     _add_biblio_fields($import_record_id, $marc_record);
 305     _update_batch_record_counts($batch_id) if $update_counts;
 306     return $import_record_id;
 307 }
 308
 309 =head2 ModBiblioInBatch
 310
 311   ModBiblioInBatch($import_record_id, $marc_record);
 312
 313 =cut
 314
 315 sub ModBiblioInBatch {
 316     my ($import_record_id, $marc_record) = @_;
 317
 318     _update_import_record_marc($import_record_id, $marc_record, C4::Context->preference('marcflavour'));
 319     _update_biblio_fields($import_record_id, $marc_record);
 320
 321 }
 322
 323 =head2 AddAuthToBatch
 324
 325   my $import_record_id = AddAuthToBatch($batch_id, $record_sequence,
 326                 $marc_record, $encoding, $update_counts, [$marc_type]);
 327
 328 =cut
 329
 330 sub AddAuthToBatch {
 331     my $batch_id = shift;
 332     my $record_sequence = shift;
 333     my $marc_record = shift;
 334     my $encoding = shift;
 335     my $update_counts = @_ ? shift : 1;
 336     my $marc_type = shift || C4::Context->preference('marcflavour');
 337
 338     $marc_type = 'UNIMARCAUTH' if $marc_type eq 'UNIMARC';
 339
 340     my $import_record_id = _create_import_record($batch_id, $record_sequence, $marc_record, 'auth', $encoding, $marc_type);
 341     _add_auth_fields($import_record_id, $marc_record);
 342     _update_batch_record_counts($batch_id) if $update_counts;
 343     return $import_record_id;
 344 }
 345
 346 =head2 ModAuthInBatch
 347
 348   ModAuthInBatch($import_record_id, $marc_record);
 349
 350 =cut
 351
 352 sub ModAuthInBatch {
 353     my ($import_record_id, $marc_record) = @_;
 354
 355     my $marcflavour = C4::Context->preference('marcflavour');
 356     _update_import_record_marc($import_record_id, $marc_record, $marcflavour eq 'UNIMARC' ? 'UNIMARCAUTH' : 'USMARC');
 357
 358 }
 359
 360 =head2 BatchStageMarcRecords
 361
 362 ( $batch_id, $num_records, $num_items, @invalid_records ) =
 363   BatchStageMarcRecords(
 364     $record_type,                $encoding,
 365     $marc_records,               $file_name,
 366     $marc_modification_template, $comments,
 367     $branch_code,                $parse_items,
 368     $leave_as_staging,           $progress_interval,
 369     $progress_callback
 370   );
 371
 372 =cut
 373
 374 sub BatchStageMarcRecords {
 375     my $record_type = shift;
 376     my $encoding = shift;
 377     my $marc_records = shift;
 378     my $file_name = shift;
 379     my $marc_modification_template = shift;
 380     my $comments = shift;
 381     my $branch_code = shift;
 382     my $parse_items = shift;
 383     my $leave_as_staging = shift;
 384
 385     # optional callback to monitor status
 386     # of job
 387     my $progress_interval = 0;
 388     my $progress_callback = undef;
 389     if ($#_ == 1) {
 390         $progress_interval = shift;
 391         $progress_callback = shift;
 392         $progress_interval = 0 unless $progress_interval =~ /^\d+$/ and $progress_interval > 0;
 393         $progress_interval = 0 unless 'CODE' eq ref $progress_callback;
 394     }
 395
 396     my $batch_id = AddImportBatch( {
 397             overlay_action => 'create_new',
 398             import_status => 'staging',
 399             batch_type => 'batch',
 400             file_name => $file_name,
 401             comments => $comments,
 402             record_type => $record_type,
 403         } );
 404     if ($parse_items) {
 405         SetImportBatchItemAction($batch_id, 'always_add');
 406     } else {
 407         SetImportBatchItemAction($batch_id, 'ignore');
 408     }
 409
 410
 411     my $marc_type = C4::Context->preference('marcflavour');
 412     $marc_type .= 'AUTH' if ($marc_type eq 'UNIMARC' && $record_type eq 'auth');
 413     my @invalid_records = ();
 414     my $num_valid = 0;
 415     my $num_items = 0;
 416     # FIXME - for now, we're dealing only with bibs
 417     my $rec_num = 0;
 418     foreach my $marc_record (@$marc_records) {
 419         $rec_num++;
 420         if ($progress_interval and (0 == ($rec_num % $progress_interval))) {
 421             &$progress_callback($rec_num);
 422         }
 423
 424         ModifyRecordWithTemplate( $marc_modification_template, $marc_record ) if ( $marc_modification_template );
 425
 426         my $import_record_id;
 427         if (scalar($marc_record->fields()) == 0) {
 428             push @invalid_records, $marc_record;
 429         } else {
 430
 431             # Normalize the record so it doesn't have separated diacritics
 432             SetUTF8Flag($marc_record);
 433
 434             $num_valid++;
 435             if ($record_type eq 'biblio') {
 436                 $import_record_id = AddBiblioToBatch($batch_id, $rec_num, $marc_record, $encoding, int(rand(99999)), 0);
 437                 if ($parse_items) {
 438                     my @import_items_ids = AddItemsToImportBiblio($batch_id, $import_record_id, $marc_record, 0);
 439                     $num_items += scalar(@import_items_ids);
 440                 }
 441             } elsif ($record_type eq 'auth') {
 442                 $import_record_id = AddAuthToBatch($batch_id, $rec_num, $marc_record, $encoding, int(rand(99999)), 0, $marc_type);
 443             }
 444         }
 445     }
 446     unless ($leave_as_staging) {
 447         SetImportBatchStatus($batch_id, 'staged');
 448     }
 449     # FIXME branch_code, number of bibs, number of items
 450     _update_batch_record_counts($batch_id);
 451     return ($batch_id, $num_valid, $num_items, @invalid_records);
 452 }
 453
 454 =head2 AddItemsToImportBiblio
 455
 456   my @import_items_ids = AddItemsToImportBiblio($batch_id,
 457                 $import_record_id, $marc_record, $update_counts);
 458
 459 =cut
 460
 461 sub AddItemsToImportBiblio {
 462     my $batch_id = shift;
 463     my $import_record_id = shift;
 464     my $marc_record = shift;
 465     my $update_counts = @_ ? shift : 0;
 466
 467     my @import_items_ids = ();
 468
 469     my $dbh = C4::Context->dbh;
 470     my ($item_tag,$item_subfield) = &GetMarcFromKohaField( "items.itemnumber" );
 471     foreach my $item_field ($marc_record->field($item_tag)) {
 472         my $item_marc = MARC::Record->new();
 473         $item_marc->leader("00000    a              "); # must set Leader/09 to 'a'
 474         $item_marc->append_fields($item_field);
 475         $marc_record->delete_field($item_field);
 476         my $sth = $dbh->prepare_cached("INSERT INTO import_items (import_record_id, status, marcxml)
 477                                         VALUES (?, ?, ?)");
 478         $sth->bind_param(1, $import_record_id);
 479         $sth->bind_param(2, 'staged');
 480         $sth->bind_param(3, $item_marc->as_xml("USMARC"));
 481         $sth->execute();
 482         push @import_items_ids, $dbh->{'mysql_insertid'};
 483         $sth->finish();
 484     }
 485
 486     if ($#import_items_ids > -1) {
 487         _update_batch_record_counts($batch_id) if $update_counts;
 488         _update_import_record_marc($import_record_id, $marc_record, C4::Context->preference('marcflavour'));
 489     }
 490     return @import_items_ids;
 491 }
 492
 493 =head2 BatchFindDuplicates
 494
 495   my $num_with_matches = BatchFindDuplicates($batch_id, $matcher,
 496              $max_matches, $progress_interval, $progress_callback);
 497
 498 Goes through the records loaded in the batch and attempts to
 499 find duplicates for each one.  Sets the matching status
 500 of each record to "no_match" or "auto_match" as appropriate.
 501
 502 The $max_matches parameter is optional; if it is not supplied,
 503 it defaults to 10.
 504
 505 The $progress_interval and $progress_callback parameters are
 506 optional; if both are supplied, the sub referred to by
 507 $progress_callback will be invoked every $progress_interval
 508 records using the number of records processed as the
 509 singular argument.
 510
 511 =cut
 512
 513 sub BatchFindDuplicates {
 514     my $batch_id = shift;
 515     my $matcher = shift;
 516     my $max_matches = @_ ? shift : 10;
 517
 518     # optional callback to monitor status
 519     # of job
 520     my $progress_interval = 0;
 521     my $progress_callback = undef;
 522     if ($#_ == 1) {
 523         $progress_interval = shift;
 524         $progress_callback = shift;
 525         $progress_interval = 0 unless $progress_interval =~ /^\d+$/ and $progress_interval > 0;
 526         $progress_interval = 0 unless 'CODE' eq ref $progress_callback;
 527     }
 528
 529     my $dbh = C4::Context->dbh;
 530
 531     my $sth = $dbh->prepare("SELECT import_record_id, record_type, marc
 532                              FROM import_records
 533                              WHERE import_batch_id = ?");
 534     $sth->execute($batch_id);
 535     my $num_with_matches = 0;
 536     my $rec_num = 0;
 537     while (my $rowref = $sth->fetchrow_hashref) {
 538         $rec_num++;
 539         if ($progress_interval and (0 == ($rec_num % $progress_interval))) {
 540             &$progress_callback($rec_num);
 541         }
 542         my $marc_record = MARC::Record->new_from_usmarc($rowref->{'marc'});
 543         my @matches = ();
 544         if (defined $matcher) {
 545             @matches = $matcher->get_matches($marc_record, $max_matches);
 546         }
 547         if (scalar(@matches) > 0) {
 548             $num_with_matches++;
 549             SetImportRecordMatches($rowref->{'import_record_id'}, @matches);
 550             SetImportRecordOverlayStatus($rowref->{'import_record_id'}, 'auto_match');
 551         } else {
 552             SetImportRecordMatches($rowref->{'import_record_id'}, ());
 553             SetImportRecordOverlayStatus($rowref->{'import_record_id'}, 'no_match');
 554         }
 555     }
 556     $sth->finish();
 557     return $num_with_matches;
 558 }
 559
 560 =head2 BatchCommitRecords
 561
 562   my ($num_added, $num_updated, $num_items_added, $num_items_replaced, $num_items_errored, $num_ignored) =
 563         BatchCommitRecords($batch_id, $framework,
 564         $progress_interval, $progress_callback);
 565
 566 =cut
 567
 568 sub BatchCommitRecords {
 569     my $batch_id = shift;
 570     my $framework = shift;
 571
 572     # optional callback to monitor status
 573     # of job
 574     my $progress_interval = 0;
 575     my $progress_callback = undef;
 576     if ($#_ == 1) {
 577         $progress_interval = shift;
 578         $progress_callback = shift;
 579         $progress_interval = 0 unless $progress_interval =~ /^\d+$/ and $progress_interval > 0;
 580         $progress_interval = 0 unless 'CODE' eq ref $progress_callback;
 581     }
 582
 583     my $record_type;
 584     my $num_added = 0;
 585     my $num_updated = 0;
 586     my $num_items_added = 0;
 587     my $num_items_replaced = 0;
 588     my $num_items_errored = 0;
 589     my $num_ignored = 0;
 590     # commit (i.e., save, all records in the batch)
 591     SetImportBatchStatus($batch_id, 'importing');
 592     my $overlay_action = GetImportBatchOverlayAction($batch_id);
 593     my $nomatch_action = GetImportBatchNoMatchAction($batch_id);
 594     my $item_action = GetImportBatchItemAction($batch_id);
 595     my $item_tag;
 596     my $item_subfield;
 597     my $dbh = C4::Context->dbh;
 598     my $sth = $dbh->prepare("SELECT import_records.import_record_id, record_type, status, overlay_status, marc, encoding
 599                              FROM import_records
 600                              LEFT JOIN import_auths ON (import_records.import_record_id=import_auths.import_record_id)
 601                              LEFT JOIN import_biblios ON (import_records.import_record_id=import_biblios.import_record_id)
 602                              WHERE import_batch_id = ?");
 603     $sth->execute($batch_id);
 604     my $marcflavour = C4::Context->preference('marcflavour');
 605
 606     my $userenv = C4::Context->userenv;
 607     my $logged_in_patron = Koha::Patrons->find( $userenv->{number} );
 608
 609     my $rec_num = 0;
 610     while (my $rowref = $sth->fetchrow_hashref) {
 611         $record_type = $rowref->{'record_type'};
 612         $rec_num++;
 613         if ($progress_interval and (0 == ($rec_num % $progress_interval))) {
 614             &$progress_callback($rec_num);
 615         }
 616         if ($rowref->{'status'} eq 'error' or $rowref->{'status'} eq 'imported') {
 617             $num_ignored++;
 618             next;
 619         }
 620
 621         my $marc_type;
 622         if ($marcflavour eq 'UNIMARC' && $record_type eq 'auth') {
 623             $marc_type = 'UNIMARCAUTH';
 624         } elsif ($marcflavour eq 'UNIMARC') {
 625             $marc_type = 'UNIMARC';
 626         } else {
 627             $marc_type = 'USMARC';
 628         }
 629         my $marc_record = MARC::Record->new_from_usmarc($rowref->{'marc'});
 630
 631         if ($record_type eq 'biblio') {
 632             # remove any item tags - rely on BatchCommitItems
 633             ($item_tag,$item_subfield) = &GetMarcFromKohaField( "items.itemnumber" );
 634             foreach my $item_field ($marc_record->field($item_tag)) {
 635                 $marc_record->delete_field($item_field);
 636             }
 637         }
 638
 639         my ($record_result, $item_result, $record_match) =
 640             _get_commit_action($overlay_action, $nomatch_action, $item_action,
 641                                $rowref->{'overlay_status'}, $rowref->{'import_record_id'}, $record_type);
 642
 643         my $recordid;
 644         my $query;
 645         if ($record_result eq 'create_new') {
 646             $num_added++;
 647             if ($record_type eq 'biblio') {
 648                 my $biblioitemnumber;
 649                 ($recordid, $biblioitemnumber) = AddBiblio($marc_record, $framework);
 650                 $query = "UPDATE import_biblios SET matched_biblionumber = ? WHERE import_record_id = ?"; # FIXME call SetMatchedBiblionumber instead
 651                 if ($item_result eq 'create_new' || $item_result eq 'replace') {
 652                     my ($bib_items_added, $bib_items_replaced, $bib_items_errored) = BatchCommitItems($rowref->{'import_record_id'}, $recordid, $item_result);
 653                     $num_items_added += $bib_items_added;
 654                     $num_items_replaced += $bib_items_replaced;
 655                     $num_items_errored += $bib_items_errored;
 656                 }
 657             } else {
 658                 $recordid = AddAuthority($marc_record, undef, GuessAuthTypeCode($marc_record));
 659                 $query = "UPDATE import_auths SET matched_authid = ? WHERE import_record_id = ?";
 660             }
 661             my $sth = $dbh->prepare_cached($query);
 662             $sth->execute($recordid, $rowref->{'import_record_id'});
 663             $sth->finish();
 664             SetImportRecordStatus($rowref->{'import_record_id'}, 'imported');
 665         } elsif ($record_result eq 'replace') {
 666             $num_updated++;
 667             $recordid = $record_match;
 668             my $oldxml;
 669             if ($record_type eq 'biblio') {
 670                 my $oldbiblio = Koha::Biblios->find( $recordid );
 671                 $oldxml = GetXmlBiblio($recordid);
 672
 673                 # remove item fields so that they don't get
 674                 # added again if record is reverted
 675                 # FIXME: GetXmlBiblio output should not contain item info any more! So the next foreach should not be needed. Does not hurt either; may remove old 952s that should not have been there anymore.
 676                 my $old_marc = MARC::Record->new_from_xml(StripNonXmlChars($oldxml), 'UTF-8', $rowref->{'encoding'}, $marc_type);
 677                 foreach my $item_field ($old_marc->field($item_tag)) {
 678                     $old_marc->delete_field($item_field);
 679                 }
 680                 $oldxml = $old_marc->as_xml($marc_type);
 681
 682                 my $context = { source => 'batchimport' };
 683                 if ($logged_in_patron) {
 684                     $context->{categorycode} = $logged_in_patron->categorycode;
 685                     $context->{userid} = $logged_in_patron->userid;
 686                 }
 687
 688                 ModBiblio($marc_record, $recordid, $oldbiblio->frameworkcode, {
 689                     overlay_context => $context
 690                 });
 691                 $query = "UPDATE import_biblios SET matched_biblionumber = ? WHERE import_record_id = ?"; # FIXME call SetMatchedBiblionumber instead
 692
 693                 if ($item_result eq 'create_new' || $item_result eq 'replace') {
 694                     my ($bib_items_added, $bib_items_replaced, $bib_items_errored) = BatchCommitItems($rowref->{'import_record_id'}, $recordid, $item_result);
 695                     $num_items_added += $bib_items_added;
 696                     $num_items_replaced += $bib_items_replaced;
 697                     $num_items_errored += $bib_items_errored;
 698                 }
 699             } else {
 700                 $oldxml = GetAuthorityXML($recordid);
 701
 702                 ModAuthority($recordid, $marc_record, GuessAuthTypeCode($marc_record));
 703                 $query = "UPDATE import_auths SET matched_authid = ? WHERE import_record_id = ?";
 704             }
 705             my $sth = $dbh->prepare_cached("UPDATE import_records SET marcxml_old = ? WHERE import_record_id = ?");
 706             $sth->execute($oldxml, $rowref->{'import_record_id'});
 707             $sth->finish();
 708             my $sth2 = $dbh->prepare_cached($query);
 709             $sth2->execute($recordid, $rowref->{'import_record_id'});
 710             $sth2->finish();
 711             SetImportRecordOverlayStatus($rowref->{'import_record_id'}, 'match_applied');
 712             SetImportRecordStatus($rowref->{'import_record_id'}, 'imported');
 713         } elsif ($record_result eq 'ignore') {
 714             $recordid = $record_match;
 715             $num_ignored++;
 716             if ($record_type eq 'biblio' and defined $recordid and ( $item_result eq 'create_new' || $item_result eq 'replace' ) ) {
 717                 my ($bib_items_added, $bib_items_replaced, $bib_items_errored) = BatchCommitItems($rowref->{'import_record_id'}, $recordid, $item_result);
 718                 $num_items_added += $bib_items_added;
 719          $num_items_replaced += $bib_items_replaced;
 720                 $num_items_errored += $bib_items_errored;
 721                 # still need to record the matched biblionumber so that the
 722                 # items can be reverted
 723                 my $sth2 = $dbh->prepare_cached("UPDATE import_biblios SET matched_biblionumber = ? WHERE import_record_id = ?"); # FIXME call SetMatchedBiblionumber instead
 724                 $sth2->execute($recordid, $rowref->{'import_record_id'});
 725                 SetImportRecordOverlayStatus($rowref->{'import_record_id'}, 'match_applied');
 726             }
 727             SetImportRecordStatus($rowref->{'import_record_id'}, 'ignored');
 728         }
 729     }
 730     $sth->finish();
 731     SetImportBatchStatus($batch_id, 'imported');
 732     return ($num_added, $num_updated, $num_items_added, $num_items_replaced, $num_items_errored, $num_ignored);
 733 }
 734
 735 =head2 BatchCommitItems
 736
 737   ($num_items_added, $num_items_errored) =
 738          BatchCommitItems($import_record_id, $biblionumber);
 739
 740 =cut
 741
 742 sub BatchCommitItems {
 743     my ( $import_record_id, $biblionumber, $action ) = @_;
 744
 745     my $dbh = C4::Context->dbh;
 746
 747     my $num_items_added = 0;
 748     my $num_items_errored = 0;
 749     my $num_items_replaced = 0;
 750
 751     my $sth = $dbh->prepare( "
 752         SELECT import_items_id, import_items.marcxml, encoding
 753         FROM import_items
 754         JOIN import_records USING (import_record_id)
 755         WHERE import_record_id = ?
 756         ORDER BY import_items_id
 757     " );
 758     $sth->bind_param( 1, $import_record_id );
 759     $sth->execute();
 760
 761     while ( my $row = $sth->fetchrow_hashref() ) {
 762         my $item_marc = MARC::Record->new_from_xml( StripNonXmlChars( $row->{'marcxml'} ), 'UTF-8', $row->{'encoding'} );
 763
 764         # Delete date_due subfield as to not accidentally delete item checkout due dates
 765         my ( $MARCfield, $MARCsubfield ) = GetMarcFromKohaField( 'items.onloan' );
 766         $item_marc->field($MARCfield)->delete_subfield( code => $MARCsubfield );
 767
 768         my $item = TransformMarcToKoha( $item_marc );
 769
 770         my $duplicate_barcode = exists( $item->{'barcode'} ) && Koha::Items->find({ barcode => $item->{'barcode'} });
 771         my $duplicate_itemnumber = exists( $item->{'itemnumber'} );
 772
 773         my $updsth = $dbh->prepare("UPDATE import_items SET status = ?, itemnumber = ? WHERE import_items_id = ?");
 774         if ( $action eq "replace" && $duplicate_itemnumber ) {
 775             # Duplicate itemnumbers have precedence, that way we can update barcodes by overlaying
 776             ModItemFromMarc( $item_marc, $biblionumber, $item->{itemnumber} );
 777             $updsth->bind_param( 1, 'imported' );
 778             $updsth->bind_param( 2, $item->{itemnumber} );
 779             $updsth->bind_param( 3, $row->{'import_items_id'} );
 780             $updsth->execute();
 781             $updsth->finish();
 782             $num_items_replaced++;
 783         } elsif ( $action eq "replace" && $duplicate_barcode ) {
 784             my $itemnumber = $duplicate_barcode->itemnumber;
 785             ModItemFromMarc( $item_marc, $biblionumber, $itemnumber );
 786             $updsth->bind_param( 1, 'imported' );
 787             $updsth->bind_param( 2, $item->{itemnumber} );
 788             $updsth->bind_param( 3, $row->{'import_items_id'} );
 789             $updsth->execute();
 790             $updsth->finish();
 791             $num_items_replaced++;
 792         } elsif ($duplicate_barcode) {
 793             $updsth->bind_param( 1, 'error' );
 794             $updsth->bind_param( 2, undef );
 795             $updsth->bind_param( 3, $row->{'import_items_id'} );
 796             $updsth->execute();
 797             $num_items_errored++;
 798         } else {
 799             # Remove the itemnumber if it exists, we want to create a new item
 800             my ( $itemtag, $itemsubfield ) = GetMarcFromKohaField( "items.itemnumber" );
 801             $item_marc->field($itemtag)->delete_subfield( code => $itemsubfield );
 802
 803             my ( $item_biblionumber, $biblioitemnumber, $itemnumber ) = AddItemFromMarc( $item_marc, $biblionumber );
 804             if( $itemnumber ) {
 805                 $updsth->bind_param( 1, 'imported' );
 806                 $updsth->bind_param( 2, $itemnumber );
 807                 $updsth->bind_param( 3, $row->{'import_items_id'} );
 808                 $updsth->execute();
 809                 $updsth->finish();
 810                 $num_items_added++;
 811             }
 812         }
 813     }
 814
 815     return ( $num_items_added, $num_items_replaced, $num_items_errored );
 816 }
 817
 818 =head2 BatchRevertRecords
 819
 820   my ($num_deleted, $num_errors, $num_reverted, $num_items_deleted,
 821       $num_ignored) = BatchRevertRecords($batch_id);
 822
 823 =cut
 824
 825 sub BatchRevertRecords {
 826     my $batch_id = shift;
 827
 828     my $logger = Koha::Logger->get( { category => 'C4.ImportBatch' } );
 829
 830     $logger->trace("C4::ImportBatch::BatchRevertRecords( $batch_id )");
 831
 832     my $record_type;
 833     my $num_deleted = 0;
 834     my $num_errors = 0;
 835     my $num_reverted = 0;
 836     my $num_ignored = 0;
 837     my $num_items_deleted = 0;
 838     # commit (i.e., save, all records in the batch)
 839     SetImportBatchStatus($batch_id, 'reverting');
 840     my $overlay_action = GetImportBatchOverlayAction($batch_id);
 841     my $nomatch_action = GetImportBatchNoMatchAction($batch_id);
 842     my $dbh = C4::Context->dbh;
 843     my $sth = $dbh->prepare("SELECT import_records.import_record_id, record_type, status, overlay_status, marcxml_old, encoding, matched_biblionumber, matched_authid
 844                              FROM import_records
 845                              LEFT JOIN import_auths ON (import_records.import_record_id=import_auths.import_record_id)
 846                              LEFT JOIN import_biblios ON (import_records.import_record_id=import_biblios.import_record_id)
 847                              WHERE import_batch_id = ?");
 848     $sth->execute($batch_id);
 849     my $marc_type;
 850     my $marcflavour = C4::Context->preference('marcflavour');
 851     while (my $rowref = $sth->fetchrow_hashref) {
 852         $record_type = $rowref->{'record_type'};
 853         if ($rowref->{'status'} eq 'error' or $rowref->{'status'} eq 'reverted') {
 854             $num_ignored++;
 855             next;
 856         }
 857         if ($marcflavour eq 'UNIMARC' && $record_type eq 'auth') {
 858             $marc_type = 'UNIMARCAUTH';
 859         } elsif ($marcflavour eq 'UNIMARC') {
 860             $marc_type = 'UNIMARC';
 861         } else {
 862             $marc_type = 'USMARC';
 863         }
 864
 865         my $record_result = _get_revert_action($overlay_action, $rowref->{'overlay_status'}, $rowref->{'status'});
 866
 867         if ($record_result eq 'delete') {
 868             my $error = undef;
 869             if  ($record_type eq 'biblio') {
 870                 $num_items_deleted += BatchRevertItems($rowref->{'import_record_id'}, $rowref->{'matched_biblionumber'});
 871                 $error = DelBiblio($rowref->{'matched_biblionumber'});
 872             } else {
 873                 DelAuthority({ authid => $rowref->{'matched_authid'} });
 874             }
 875             if (defined $error) {
 876                 $num_errors++;
 877             } else {
 878                 $num_deleted++;
 879                 SetImportRecordStatus($rowref->{'import_record_id'}, 'reverted');
 880             }
 881         } elsif ($record_result eq 'restore') {
 882             $num_reverted++;
 883             my $old_record = MARC::Record->new_from_xml(StripNonXmlChars($rowref->{'marcxml_old'}), 'UTF-8', $rowref->{'encoding'}, $marc_type);
 884             if ($record_type eq 'biblio') {
 885                 my $biblionumber = $rowref->{'matched_biblionumber'};
 886                 my $oldbiblio = Koha::Biblios->find( $biblionumber );
 887
 888                 $logger->info("C4::ImportBatch::BatchRevertRecords: Biblio record $biblionumber does not exist, restoration of this record was skipped") unless $oldbiblio;
 889                 next unless $oldbiblio; # Record has since been deleted. Deleted records should stay deleted.
 890
 891                 $num_items_deleted += BatchRevertItems($rowref->{'import_record_id'}, $rowref->{'matched_biblionumber'});
 892                 ModBiblio($old_record, $biblionumber, $oldbiblio->frameworkcode);
 893             } else {
 894                 my $authid = $rowref->{'matched_authid'};
 895                 ModAuthority($authid, $old_record, GuessAuthTypeCode($old_record));
 896             }
 897             SetImportRecordStatus($rowref->{'import_record_id'}, 'reverted');
 898         } elsif ($record_result eq 'ignore') {
 899             if ($record_type eq 'biblio') {
 900                 $num_items_deleted += BatchRevertItems($rowref->{'import_record_id'}, $rowref->{'matched_biblionumber'});
 901             }
 902             SetImportRecordStatus($rowref->{'import_record_id'}, 'reverted');
 903         }
 904         my $query;
 905         if ($record_type eq 'biblio') {
 906             # remove matched_biblionumber only if there is no 'imported' item left
 907             $query = "UPDATE import_biblios SET matched_biblionumber = NULL WHERE import_record_id = ?"; # FIXME Remove me
 908             $query = "UPDATE import_biblios SET matched_biblionumber = NULL WHERE import_record_id = ?  AND NOT EXISTS (SELECT * FROM import_items WHERE import_items.import_record_id=import_biblios.import_record_id and status='imported')";
 909         } else {
 910             $query = "UPDATE import_auths SET matched_authid = NULL WHERE import_record_id = ?";
 911         }
 912         my $sth2 = $dbh->prepare_cached($query);
 913         $sth2->execute($rowref->{'import_record_id'});
 914     }
 915
 916     $sth->finish();
 917     SetImportBatchStatus($batch_id, 'reverted');
 918     return ($num_deleted, $num_errors, $num_reverted, $num_items_deleted, $num_ignored);
 919 }
 920
 921 =head2 BatchRevertItems
 922
 923   my $num_items_deleted = BatchRevertItems($import_record_id, $biblionumber);
 924
 925 =cut
 926
 927 sub BatchRevertItems {
 928     my ($import_record_id, $biblionumber) = @_;
 929
 930     my $dbh = C4::Context->dbh;
 931     my $num_items_deleted = 0;
 932
 933     my $sth = $dbh->prepare_cached("SELECT import_items_id, itemnumber
 934                                    FROM import_items
 935                                    JOIN items USING (itemnumber)
 936                                    WHERE import_record_id = ?");
 937     $sth->bind_param(1, $import_record_id);
 938     $sth->execute();
 939     while (my $row = $sth->fetchrow_hashref()) {
 940         my $item = Koha::Items->find($row->{itemnumber});
 941         if ($item->safe_delete){
 942             my $updsth = $dbh->prepare("UPDATE import_items SET status = ? WHERE import_items_id = ?");
 943             $updsth->bind_param(1, 'reverted');
 944             $updsth->bind_param(2, $row->{'import_items_id'});
 945             $updsth->execute();
 946             $updsth->finish();
 947             $num_items_deleted++;
 948         }
 949         else {
 950             next;
 951         }
 952     }
 953     $sth->finish();
 954     return $num_items_deleted;
 955 }
 956
 957 =head2 CleanBatch
 958
 959   CleanBatch($batch_id)
 960
 961 Deletes all staged records from the import batch
 962 and sets the status of the batch to 'cleaned'.  Note
 963 that deleting a stage record does *not* affect
 964 any record that has been committed to the database.
 965
 966 =cut
 967
 968 sub CleanBatch {
 969     my $batch_id = shift;
 970     return unless defined $batch_id;
 971
 972     C4::Context->dbh->do('DELETE FROM import_records WHERE import_batch_id = ?', {}, $batch_id);
 973     SetImportBatchStatus($batch_id, 'cleaned');
 974 }
 975
 976 =head2 DeleteBatch
 977
 978   DeleteBatch($batch_id)
 979
 980 Deletes the record from the database. This can only be done
 981 once the batch has been cleaned.
 982
 983 =cut
 984
 985 sub DeleteBatch {
 986     my $batch_id = shift;
 987     return unless defined $batch_id;
 988
 989     my $dbh = C4::Context->dbh;
 990     my $sth = $dbh->prepare('DELETE FROM import_batches WHERE import_batch_id = ?');
 991     $sth->execute( $batch_id );
 992 }
 993
 994 =head2 GetAllImportBatches
 995
 996   my $results = GetAllImportBatches();
 997
 998 Returns a references to an array of hash references corresponding
 999 to all import_batches rows (of batch_type 'batch'), sorted in
1000 ascending order by import_batch_id.
1001
1002 =cut
1003
1004 sub  GetAllImportBatches {
1005     my $dbh = C4::Context->dbh;
1006     my $sth = $dbh->prepare_cached("SELECT * FROM import_batches
1007                                     WHERE batch_type IN ('batch', 'webservice')
1008                                     ORDER BY import_batch_id ASC");
1009
1010     my $results = [];
1011     $sth->execute();
1012     while (my $row = $sth->fetchrow_hashref) {
1013         push @$results, $row;
1014     }
1015     $sth->finish();
1016     return $results;
1017 }
1018
1019 =head2 GetStagedWebserviceBatches
1020
1021   my $batch_ids = GetStagedWebserviceBatches();
1022
1023 Returns a references to an array of batch id's
1024 of batch_type 'webservice' that are not imported
1025
1026 =cut
1027
1028 my $PENDING_WEBSERVICE_BATCHES_QRY = <<EOQ;
1029 SELECT import_batch_id FROM import_batches
1030 WHERE batch_type = 'webservice'
1031 AND import_status = 'staged'
1032 EOQ
1033 sub  GetStagedWebserviceBatches {
1034     my $dbh = C4::Context->dbh;
1035     return $dbh->selectcol_arrayref($PENDING_WEBSERVICE_BATCHES_QRY);
1036 }
1037
1038 =head2 GetImportBatchRangeDesc
1039
1040   my $results = GetImportBatchRangeDesc($offset, $results_per_group);
1041
1042 Returns a reference to an array of hash references corresponding to
1043 import_batches rows (sorted in descending order by import_batch_id)
1044 start at the given offset.
1045
1046 =cut
1047
1048 sub GetImportBatchRangeDesc {
1049     my ($offset, $results_per_group) = @_;
1050
1051     my $dbh = C4::Context->dbh;
1052     my $query = "SELECT b.*, p.name as profile FROM import_batches b
1053                                     LEFT JOIN import_batch_profiles p
1054                                     ON b.profile_id = p.id
1055                                     WHERE b.batch_type IN ('batch', 'webservice')
1056                                     ORDER BY b.import_batch_id DESC";
1057     my @params;
1058     if ($results_per_group){
1059         $query .= " LIMIT ?";
1060         push(@params, $results_per_group);
1061     }
1062     if ($offset){
1063         $query .= " OFFSET ?";
1064         push(@params, $offset);
1065     }
1066     my $sth = $dbh->prepare_cached($query);
1067     $sth->execute(@params);
1068     my $results = $sth->fetchall_arrayref({});
1069     $sth->finish();
1070     return $results;
1071 }
1072
1073 =head2 GetItemNumbersFromImportBatch
1074
1075   my @itemsnos = GetItemNumbersFromImportBatch($batch_id);
1076
1077 =cut
1078
1079 sub GetItemNumbersFromImportBatch {
1080     my ($batch_id) = @_;
1081     my $dbh = C4::Context->dbh;
1082     my $sql = q|
1083 SELECT itemnumber FROM import_items
1084 INNER JOIN items USING (itemnumber)
1085 INNER JOIN import_records USING (import_record_id)
1086 WHERE import_batch_id = ?|;
1087     my  $sth = $dbh->prepare( $sql );
1088     $sth->execute($batch_id);
1089     my @items ;
1090     while ( my ($itm) = $sth->fetchrow_array ) {
1091         push @items, $itm;
1092     }
1093     return @items;
1094 }
1095
1096 =head2 GetNumberOfImportBatches
1097
1098   my $count = GetNumberOfImportBatches();
1099
1100 =cut
1101
1102 sub GetNumberOfNonZ3950ImportBatches {
1103     my $dbh = C4::Context->dbh;
1104     my $sth = $dbh->prepare("SELECT COUNT(*) FROM import_batches WHERE batch_type != 'z3950'");
1105     $sth->execute();
1106     my ($count) = $sth->fetchrow_array();
1107     $sth->finish();
1108     return $count;
1109 }
1110
1111 =head2 GetImportBiblios
1112
1113   my $results = GetImportBiblios($importid);
1114
1115 =cut
1116
1117 sub GetImportBiblios {
1118     my ($import_record_id) = @_;
1119
1120     my $dbh = C4::Context->dbh;
1121     my $query = "SELECT * FROM import_biblios WHERE import_record_id = ?";
1122     return $dbh->selectall_arrayref(
1123         $query,
1124         { Slice => {} },
1125         $import_record_id
1126     );
1127
1128 }
1129
1130 =head2 GetImportRecordsRange
1131
1132   my $results = GetImportRecordsRange($batch_id, $offset, $results_per_group);
1133
1134 Returns a reference to an array of hash references corresponding to
1135 import_biblios/import_auths/import_records rows for a given batch
1136 starting at the given offset.
1137
1138 =cut
1139
1140 sub GetImportRecordsRange {
1141     my ( $batch_id, $offset, $results_per_group, $status, $parameters ) = @_;
1142
1143     my $dbh = C4::Context->dbh;
1144
1145     my $order_by = $parameters->{order_by} || 'import_record_id';
1146     ( $order_by ) = grep( { $_ eq $order_by } qw( import_record_id title status overlay_status ) ) ? $order_by : 'import_record_id';
1147
1148     my $order_by_direction =
1149       uc( $parameters->{order_by_direction} // 'ASC' ) eq 'DESC' ? 'DESC' : 'ASC';
1150
1151     $order_by .= " $order_by_direction, authorized_heading" if $order_by eq 'title';
1152
1153     my $query = "SELECT title, author, isbn, issn, authorized_heading, import_records.import_record_id,
1154                                            record_sequence, status, overlay_status,
1155                                            matched_biblionumber, matched_authid, record_type
1156                                     FROM   import_records
1157                                     LEFT JOIN import_auths ON (import_records.import_record_id=import_auths.import_record_id)
1158                                     LEFT JOIN import_biblios ON (import_records.import_record_id=import_biblios.import_record_id)
1159                                     WHERE  import_batch_id = ?";
1160     my @params;
1161     push(@params, $batch_id);
1162     if ($status) {
1163         $query .= " AND status=?";
1164         push(@params,$status);
1165     }
1166
1167     $query.=" ORDER BY $order_by $order_by_direction";
1168
1169     if($results_per_group){
1170         $query .= " LIMIT ?";
1171         push(@params, $results_per_group);
1172     }
1173     if($offset){
1174         $query .= " OFFSET ?";
1175         push(@params, $offset);
1176     }
1177     my $sth = $dbh->prepare_cached($query);
1178     $sth->execute(@params);
1179     my $results = $sth->fetchall_arrayref({});
1180     $sth->finish();
1181     return $results;
1182
1183 }
1184
1185 =head2 GetBestRecordMatch
1186
1187   my $record_id = GetBestRecordMatch($import_record_id);
1188
1189 =cut
1190
1191 sub GetBestRecordMatch {
1192     my ($import_record_id) = @_;
1193
1194     my $dbh = C4::Context->dbh;
1195     my $sth = $dbh->prepare("SELECT candidate_match_id
1196                              FROM   import_record_matches
1197                              JOIN   import_records ON ( import_record_matches.import_record_id = import_records.import_record_id )
1198                              LEFT JOIN biblio ON ( candidate_match_id = biblio.biblionumber )
1199                              LEFT JOIN auth_header ON ( candidate_match_id = auth_header.authid )
1200                              WHERE  import_record_matches.import_record_id = ? AND
1201                              (  (import_records.record_type = 'biblio' AND biblio.biblionumber IS NOT NULL) OR
1202                                 (import_records.record_type = 'auth' AND auth_header.authid IS NOT NULL) )
1203                              AND chosen = 1
1204                              ORDER BY score DESC, candidate_match_id DESC");
1205     $sth->execute($import_record_id);
1206     my ($record_id) = $sth->fetchrow_array();
1207     $sth->finish();
1208     return $record_id;
1209 }
1210
1211 =head2 GetImportBatchStatus
1212
1213   my $status = GetImportBatchStatus($batch_id);
1214
1215 =cut
1216
1217 sub GetImportBatchStatus {
1218     my ($batch_id) = @_;
1219
1220     my $dbh = C4::Context->dbh;
1221     my $sth = $dbh->prepare("SELECT import_status FROM import_batches WHERE import_batch_id = ?");
1222     $sth->execute($batch_id);
1223     my ($status) = $sth->fetchrow_array();
1224     $sth->finish();
1225     return $status;
1226
1227 }
1228
1229 =head2 SetImportBatchStatus
1230
1231   SetImportBatchStatus($batch_id, $new_status);
1232
1233 =cut
1234
1235 sub SetImportBatchStatus {
1236     my ($batch_id, $new_status) = @_;
1237
1238     my $dbh = C4::Context->dbh;
1239     my $sth = $dbh->prepare("UPDATE import_batches SET import_status = ? WHERE import_batch_id = ?");
1240     $sth->execute($new_status, $batch_id);
1241     $sth->finish();
1242
1243 }
1244
1245 =head2 SetMatchedBiblionumber
1246
1247   SetMatchedBiblionumber($import_record_id, $biblionumber);
1248
1249 =cut
1250
1251 sub SetMatchedBiblionumber {
1252     my ($import_record_id, $biblionumber) = @_;
1253
1254     my $dbh = C4::Context->dbh;
1255     $dbh->do(
1256         q|UPDATE import_biblios SET matched_biblionumber = ? WHERE import_record_id = ?|,
1257         undef, $biblionumber, $import_record_id
1258     );
1259 }
1260
1261 =head2 GetImportBatchOverlayAction
1262
1263   my $overlay_action = GetImportBatchOverlayAction($batch_id);
1264
1265 =cut
1266
1267 sub GetImportBatchOverlayAction {
1268     my ($batch_id) = @_;
1269
1270     my $dbh = C4::Context->dbh;
1271     my $sth = $dbh->prepare("SELECT overlay_action FROM import_batches WHERE import_batch_id = ?");
1272     $sth->execute($batch_id);
1273     my ($overlay_action) = $sth->fetchrow_array();
1274     $sth->finish();
1275     return $overlay_action;
1276
1277 }
1278
1279
1280 =head2 SetImportBatchOverlayAction
1281
1282   SetImportBatchOverlayAction($batch_id, $new_overlay_action);
1283
1284 =cut
1285
1286 sub SetImportBatchOverlayAction {
1287     my ($batch_id, $new_overlay_action) = @_;
1288
1289     my $dbh = C4::Context->dbh;
1290     my $sth = $dbh->prepare("UPDATE import_batches SET overlay_action = ? WHERE import_batch_id = ?");
1291     $sth->execute($new_overlay_action, $batch_id);
1292     $sth->finish();
1293
1294 }
1295
1296 =head2 GetImportBatchNoMatchAction
1297
1298   my $nomatch_action = GetImportBatchNoMatchAction($batch_id);
1299
1300 =cut
1301
1302 sub GetImportBatchNoMatchAction {
1303     my ($batch_id) = @_;
1304
1305     my $dbh = C4::Context->dbh;
1306     my $sth = $dbh->prepare("SELECT nomatch_action FROM import_batches WHERE import_batch_id = ?");
1307     $sth->execute($batch_id);
1308     my ($nomatch_action) = $sth->fetchrow_array();
1309     $sth->finish();
1310     return $nomatch_action;
1311
1312 }
1313
1314
1315 =head2 SetImportBatchNoMatchAction
1316
1317   SetImportBatchNoMatchAction($batch_id, $new_nomatch_action);
1318
1319 =cut
1320
1321 sub SetImportBatchNoMatchAction {
1322     my ($batch_id, $new_nomatch_action) = @_;
1323
1324     my $dbh = C4::Context->dbh;
1325     my $sth = $dbh->prepare("UPDATE import_batches SET nomatch_action = ? WHERE import_batch_id = ?");
1326     $sth->execute($new_nomatch_action, $batch_id);
1327     $sth->finish();
1328
1329 }
1330
1331 =head2 GetImportBatchItemAction
1332
1333   my $item_action = GetImportBatchItemAction($batch_id);
1334
1335 =cut
1336
1337 sub GetImportBatchItemAction {
1338     my ($batch_id) = @_;
1339
1340     my $dbh = C4::Context->dbh;
1341     my $sth = $dbh->prepare("SELECT item_action FROM import_batches WHERE import_batch_id = ?");
1342     $sth->execute($batch_id);
1343     my ($item_action) = $sth->fetchrow_array();
1344     $sth->finish();
1345     return $item_action;
1346
1347 }
1348
1349
1350 =head2 SetImportBatchItemAction
1351
1352   SetImportBatchItemAction($batch_id, $new_item_action);
1353
1354 =cut
1355
1356 sub SetImportBatchItemAction {
1357     my ($batch_id, $new_item_action) = @_;
1358
1359     my $dbh = C4::Context->dbh;
1360     my $sth = $dbh->prepare("UPDATE import_batches SET item_action = ? WHERE import_batch_id = ?");
1361     $sth->execute($new_item_action, $batch_id);
1362     $sth->finish();
1363
1364 }
1365
1366 =head2 GetImportBatchMatcher
1367
1368   my $matcher_id = GetImportBatchMatcher($batch_id);
1369
1370 =cut
1371
1372 sub GetImportBatchMatcher {
1373     my ($batch_id) = @_;
1374
1375     my $dbh = C4::Context->dbh;
1376     my $sth = $dbh->prepare("SELECT matcher_id FROM import_batches WHERE import_batch_id = ?");
1377     $sth->execute($batch_id);
1378     my ($matcher_id) = $sth->fetchrow_array();
1379     $sth->finish();
1380     return $matcher_id;
1381
1382 }
1383
1384
1385 =head2 SetImportBatchMatcher
1386
1387   SetImportBatchMatcher($batch_id, $new_matcher_id);
1388
1389 =cut
1390
1391 sub SetImportBatchMatcher {
1392     my ($batch_id, $new_matcher_id) = @_;
1393
1394     my $dbh = C4::Context->dbh;
1395     my $sth = $dbh->prepare("UPDATE import_batches SET matcher_id = ? WHERE import_batch_id = ?");
1396     $sth->execute($new_matcher_id, $batch_id);
1397     $sth->finish();
1398
1399 }
1400
1401 =head2 GetImportRecordOverlayStatus
1402
1403   my $overlay_status = GetImportRecordOverlayStatus($import_record_id);
1404
1405 =cut
1406
1407 sub GetImportRecordOverlayStatus {
1408     my ($import_record_id) = @_;
1409
1410     my $dbh = C4::Context->dbh;
1411     my $sth = $dbh->prepare("SELECT overlay_status FROM import_records WHERE import_record_id = ?");
1412     $sth->execute($import_record_id);
1413     my ($overlay_status) = $sth->fetchrow_array();
1414     $sth->finish();
1415     return $overlay_status;
1416
1417 }
1418
1419
1420 =head2 SetImportRecordOverlayStatus
1421
1422   SetImportRecordOverlayStatus($import_record_id, $new_overlay_status);
1423
1424 =cut
1425
1426 sub SetImportRecordOverlayStatus {
1427     my ($import_record_id, $new_overlay_status) = @_;
1428
1429     my $dbh = C4::Context->dbh;
1430     my $sth = $dbh->prepare("UPDATE import_records SET overlay_status = ? WHERE import_record_id = ?");
1431     $sth->execute($new_overlay_status, $import_record_id);
1432     $sth->finish();
1433
1434 }
1435
1436 =head2 GetImportRecordStatus
1437
1438   my $status = GetImportRecordStatus($import_record_id);
1439
1440 =cut
1441
1442 sub GetImportRecordStatus {
1443     my ($import_record_id) = @_;
1444
1445     my $dbh = C4::Context->dbh;
1446     my $sth = $dbh->prepare("SELECT status FROM import_records WHERE import_record_id = ?");
1447     $sth->execute($import_record_id);
1448     my ($status) = $sth->fetchrow_array();
1449     $sth->finish();
1450     return $status;
1451
1452 }
1453
1454
1455 =head2 SetImportRecordStatus
1456
1457   SetImportRecordStatus($import_record_id, $new_status);
1458
1459 =cut
1460
1461 sub SetImportRecordStatus {
1462     my ($import_record_id, $new_status) = @_;
1463
1464     my $dbh = C4::Context->dbh;
1465     my $sth = $dbh->prepare("UPDATE import_records SET status = ? WHERE import_record_id = ?");
1466     $sth->execute($new_status, $import_record_id);
1467     $sth->finish();
1468
1469 }
1470
1471 =head2 GetImportRecordMatches
1472
1473   my $results = GetImportRecordMatches($import_record_id, $best_only);
1474
1475 =cut
1476
1477 sub GetImportRecordMatches {
1478     my $import_record_id = shift;
1479     my $best_only = @_ ? shift : 0;
1480
1481     my $dbh = C4::Context->dbh;
1482     # FIXME currently biblio only
1483     my $sth = $dbh->prepare_cached("SELECT title, author, biblionumber,
1484                                     candidate_match_id, score, record_type,
1485                                     chosen
1486                                     FROM import_records
1487                                     JOIN import_record_matches USING (import_record_id)
1488                                     LEFT JOIN biblio ON (biblionumber = candidate_match_id)
1489                                     WHERE import_record_id = ?
1490                                     ORDER BY score DESC, biblionumber DESC");
1491     $sth->bind_param(1, $import_record_id);
1492     my $results = [];
1493     $sth->execute();
1494     while (my $row = $sth->fetchrow_hashref) {
1495         if ($row->{'record_type'} eq 'auth') {
1496             $row->{'authorized_heading'} = C4::AuthoritiesMarc::GetAuthorizedHeading( { authid => $row->{'candidate_match_id'} } );
1497         }
1498         next if ($row->{'record_type'} eq 'biblio' && not $row->{'biblionumber'});
1499         push @$results, $row;
1500         last if $best_only;
1501     }
1502     $sth->finish();
1503
1504     return $results;
1505
1506 }
1507
1508 =head2 SetImportRecordMatches
1509
1510   SetImportRecordMatches($import_record_id, @matches);
1511
1512 =cut
1513
1514 sub SetImportRecordMatches {
1515     my $import_record_id = shift;
1516     my @matches = @_;
1517
1518     my $dbh = C4::Context->dbh;
1519     my $delsth = $dbh->prepare("DELETE FROM import_record_matches WHERE import_record_id = ?");
1520     $delsth->execute($import_record_id);
1521     $delsth->finish();
1522
1523     my $sth = $dbh->prepare("INSERT INTO import_record_matches (import_record_id, candidate_match_id, score, chosen)
1524                                     VALUES (?, ?, ?, ?)");
1525     my $chosen = 1; #The first match is defaulted to be chosen
1526     foreach my $match (@matches) {
1527         $sth->execute($import_record_id, $match->{'record_id'}, $match->{'score'}, $chosen);
1528         $chosen = 0; #After the first we do not default to other matches
1529     }
1530 }
1531
1532 =head2 RecordsFromISO2709File
1533
1534     my ($errors, $records) = C4::ImportBatch::RecordsFromISO2709File($input_file, $record_type, $encoding);
1535
1536 Reads ISO2709 binary porridge from the given file and creates MARC::Record-objects out of it.
1537
1538 @PARAM1, String, absolute path to the ISO2709 file.
1539 @PARAM2, String, see stage_file.pl
1540 @PARAM3, String, should be utf8
1541
1542 Returns two array refs.
1543
1544 =cut
1545
1546 sub RecordsFromISO2709File {
1547     my ($input_file, $record_type, $encoding) = @_;
1548     my @errors;
1549
1550     my $marc_type = C4::Context->preference('marcflavour');
1551     $marc_type .= 'AUTH' if ($marc_type eq 'UNIMARC' && $record_type eq 'auth');
1552
1553     open my $fh, '<', $input_file or die "$0: cannot open input file $input_file: $!\n";
1554     my @marc_records;
1555     $/ = "\035";
1556     while (<$fh>) {
1557         s/^\s+//;
1558         s/\s+$//;
1559         next unless $_; # skip if record has only whitespace, as might occur
1560                         # if file includes newlines between each MARC record
1561         my ($marc_record, $charset_guessed, $char_errors) = MarcToUTF8Record($_, $marc_type, $encoding);
1562         push @marc_records, $marc_record;
1563         if ($charset_guessed ne $encoding) {
1564             push @errors,
1565                 "Unexpected charset $charset_guessed, expecting $encoding";
1566         }
1567     }
1568     close $fh;
1569     return ( \@errors, \@marc_records );
1570 }
1571
1572 =head2 RecordsFromMARCXMLFile
1573
1574     my ($errors, $records) = C4::ImportBatch::RecordsFromMARCXMLFile($input_file, $encoding);
1575
1576 Creates MARC::Record-objects out of the given MARCXML-file.
1577
1578 @PARAM1, String, absolute path to the ISO2709 file.
1579 @PARAM2, String, should be utf8
1580
1581 Returns two array refs.
1582
1583 =cut
1584
1585 sub RecordsFromMARCXMLFile {
1586     my ( $filename, $encoding ) = @_;
1587     my $batch = MARC::File::XML->in( $filename );
1588     my ( @marcRecords, @errors, $record );
1589     do {
1590         eval { $record = $batch->next( $encoding ); };
1591         if ($@) {
1592             push @errors, $@;
1593         }
1594         push @marcRecords, $record if $record;
1595     } while( $record );
1596     return (\@errors, \@marcRecords);
1597 }
1598
1599 =head2 RecordsFromMarcPlugin
1600
1601     Converts text of input_file into array of MARC records with to_marc plugin
1602
1603 =cut
1604
1605 sub RecordsFromMarcPlugin {
1606     my ($input_file, $plugin_class, $encoding) = @_;
1607     my ( $text, @return );
1608     return \@return if !$input_file || !$plugin_class;
1609
1610     # Read input file
1611     open my $fh, '<', $input_file or die "$0: cannot open input file $input_file: $!\n";
1612     $/ = "\035";
1613     while (<$fh>) {
1614         s/^\s+//;
1615         s/\s+$//;
1616         next unless $_;
1617         $text .= $_;
1618     }
1619     close $fh;
1620
1621     # Convert to large MARC blob with plugin
1622     $text = Koha::Plugins::Handler->run({
1623         class  => $plugin_class,
1624         method => 'to_marc',
1625         params => { data => $text },
1626     }) if $text;
1627
1628     # Convert to array of MARC records
1629     if( $text ) {
1630         my $marc_type = C4::Context->preference('marcflavour');
1631         foreach my $blob ( split(/\x1D/, $text) ) {
1632             next if $blob =~ /^\s*$/;
1633             my ($marcrecord) = MarcToUTF8Record($blob, $marc_type, $encoding);
1634             push @return, $marcrecord;
1635         }
1636     }
1637     return \@return;
1638 }
1639
1640 # internal functions
1641
1642 sub _create_import_record {
1643     my ($batch_id, $record_sequence, $marc_record, $record_type, $encoding, $marc_type) = @_;
1644
1645     my $dbh = C4::Context->dbh;
1646     my $sth = $dbh->prepare("INSERT INTO import_records (import_batch_id, record_sequence, marc, marcxml, marcxml_old,
1647                                                          record_type, encoding)
1648                                     VALUES (?, ?, ?, ?, ?, ?, ?)");
1649     $sth->execute($batch_id, $record_sequence, $marc_record->as_usmarc(), $marc_record->as_xml($marc_type), '',
1650                   $record_type, $encoding);
1651     my $import_record_id = $dbh->{'mysql_insertid'};
1652     $sth->finish();
1653     return $import_record_id;
1654 }
1655
1656 sub _update_import_record_marc {
1657     my ($import_record_id, $marc_record, $marc_type) = @_;
1658
1659     my $dbh = C4::Context->dbh;
1660     my $sth = $dbh->prepare("UPDATE import_records SET marc = ?, marcxml = ?
1661                              WHERE  import_record_id = ?");
1662     $sth->execute($marc_record->as_usmarc(), $marc_record->as_xml($marc_type), $import_record_id);
1663     $sth->finish();
1664 }
1665
1666 sub _add_auth_fields {
1667     my ($import_record_id, $marc_record) = @_;
1668
1669     my $controlnumber;
1670     if ($marc_record->field('001')) {
1671         $controlnumber = $marc_record->field('001')->data();
1672     }
1673     my $authorized_heading = C4::AuthoritiesMarc::GetAuthorizedHeading({ record => $marc_record });
1674     my $dbh = C4::Context->dbh;
1675     my $sth = $dbh->prepare("INSERT INTO import_auths (import_record_id, control_number, authorized_heading) VALUES (?, ?, ?)");
1676     $sth->execute($import_record_id, $controlnumber, $authorized_heading);
1677     $sth->finish();
1678 }
1679
1680 sub _add_biblio_fields {
1681     my ($import_record_id, $marc_record) = @_;
1682
1683     my ($title, $author, $isbn, $issn) = _parse_biblio_fields($marc_record);
1684     my $dbh = C4::Context->dbh;
1685     # FIXME no controlnumber, originalsource
1686     $isbn = C4::Koha::GetNormalizedISBN($isbn);
1687     my $sth = $dbh->prepare("INSERT INTO import_biblios (import_record_id, title, author, isbn, issn) VALUES (?, ?, ?, ?, ?)");
1688     $sth->execute($import_record_id, $title, $author, $isbn, $issn) or die $sth->errstr;
1689     $sth->finish();
1690
1691 }
1692
1693 sub _update_biblio_fields {
1694     my ($import_record_id, $marc_record) = @_;
1695
1696     my ($title, $author, $isbn, $issn) = _parse_biblio_fields($marc_record);
1697     my $dbh = C4::Context->dbh;
1698     # FIXME no controlnumber, originalsource
1699     # FIXME 2 - should regularize normalization of ISBN wherever it is done
1700     $isbn =~ s/\(.*$//;
1701     $isbn =~ tr/ -_//;
1702     $isbn = uc $isbn;
1703     my $sth = $dbh->prepare("UPDATE import_biblios SET title = ?, author = ?, isbn = ?, issn = ?
1704                              WHERE  import_record_id = ?");
1705     $sth->execute($title, $author, $isbn, $issn, $import_record_id);
1706     $sth->finish();
1707 }
1708
1709 sub _parse_biblio_fields {
1710     my ($marc_record) = @_;
1711
1712     my $dbh = C4::Context->dbh;
1713     my $bibliofields = TransformMarcToKoha($marc_record, '');
1714     return ($bibliofields->{'title'}, $bibliofields->{'author'}, $bibliofields->{'isbn'}, $bibliofields->{'issn'});
1715
1716 }
1717
1718 sub _update_batch_record_counts {
1719     my ($batch_id) = @_;
1720
1721     my $dbh = C4::Context->dbh;
1722     my $sth = $dbh->prepare_cached("UPDATE import_batches SET
1723                                         num_records = (
1724                                             SELECT COUNT(*)
1725                                             FROM import_records
1726                                             WHERE import_batch_id = import_batches.import_batch_id),
1727                                         num_items = (
1728                                             SELECT COUNT(*)
1729                                             FROM import_records
1730                                             JOIN import_items USING (import_record_id)
1731                                             WHERE import_batch_id = import_batches.import_batch_id
1732                                             AND record_type = 'biblio')
1733                                     WHERE import_batch_id = ?");
1734     $sth->bind_param(1, $batch_id);
1735     $sth->execute();
1736     $sth->finish();
1737 }
1738
1739 sub _get_commit_action {
1740     my ($overlay_action, $nomatch_action, $item_action, $overlay_status, $import_record_id, $record_type) = @_;
1741
1742     if ($record_type eq 'biblio') {
1743         my ($bib_result, $bib_match, $item_result);
1744
1745         $bib_match = GetBestRecordMatch($import_record_id);
1746         if ($overlay_status ne 'no_match' && defined($bib_match)) {
1747
1748             $bib_result = $overlay_action;
1749
1750             if($item_action eq 'always_add' or $item_action eq 'add_only_for_matches'){
1751                 $item_result = 'create_new';
1752             } elsif($item_action eq 'replace'){
1753                 $item_result = 'replace';
1754             } else {
1755                 $item_result = 'ignore';
1756             }
1757
1758         } else {
1759             $bib_result = $nomatch_action;
1760             $item_result = ($item_action eq 'always_add' or $item_action eq 'add_only_for_new') ? 'create_new' : 'ignore';
1761         }
1762         return ($bib_result, $item_result, $bib_match);
1763     } else { # must be auths
1764         my ($auth_result, $auth_match);
1765
1766         $auth_match = GetBestRecordMatch($import_record_id);
1767         if ($overlay_status ne 'no_match' && defined($auth_match)) {
1768             $auth_result = $overlay_action;
1769         } else {
1770             $auth_result = $nomatch_action;
1771         }
1772
1773         return ($auth_result, undef, $auth_match);
1774
1775     }
1776 }
1777
1778 sub _get_revert_action {
1779     my ($overlay_action, $overlay_status, $status) = @_;
1780
1781     my $bib_result;
1782
1783     if ($status eq 'ignored') {
1784         $bib_result = 'ignore';
1785     } else {
1786         if ($overlay_action eq 'create_new') {
1787             $bib_result = 'delete';
1788         } else {
1789             $bib_result = ($overlay_status eq 'match_applied') ? 'restore' : 'delete';
1790         }
1791     }
1792     return $bib_result;
1793 }
1794
1795 1;
1796 __END__
1797
1798 =head1 AUTHOR
1799
1800 Koha Development Team <http://koha-community.org/>
1801
1802 Galen Charlton <galen.charlton@liblime.com>
1803
1804 =cut