C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 # Portions Copyright 2009 Chris Cormack and the Koha Dev Team
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use CGI;
  27 use List::MoreUtils qw( any );
  28 use C4::Context;
  29 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $DEBUG);
  30
  31 eval {
  32     if (C4::Context->ismemcached) {
  33         require Memoize::Memcached;
  34         import Memoize::Memcached qw(memoize_memcached);
  35
  36         memoize_memcached('getTranslatedLanguages', memcached => C4::Context->memcached);
  37         memoize_memcached('getFrameworkLanguages' , memcached => C4::Context->memcached);
  38         memoize_memcached('getAllLanguages',        memcached => C4::Context->memcached);
  39     }
  40 };
  41
  42 BEGIN {
  43     $VERSION = 3.07.00.049;
  44     require Exporter;
  45     @ISA    = qw(Exporter);
  46     @EXPORT = qw(
  47         &getFrameworkLanguages
  48         &getTranslatedLanguages
  49         &getLanguages
  50         &getAllLanguages
  51     );
  52     @EXPORT_OK = qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages getLanguages get_bidi regex_lang_subtags language_get_description accept_language getlanguage);
  53     $DEBUG = 0;
  54 }
  55
  56 =head1 NAME
  57
  58 C4::Languages - Perl Module containing language list functions for Koha
  59
  60 =head1 SYNOPSIS
  61
  62 use C4::Languages;
  63
  64 =head1 DESCRIPTION
  65
  66 =cut
  67
  68 =head1 FUNCTIONS
  69
  70 =head2 getFrameworkLanguages
  71
  72 Returns a reference to an array of hashes:
  73
  74  my $languages = getFrameworkLanguages();
  75  for my $language(@$languages) {
  76     print "$language->{language_code}\n"; # language code in iso 639-2
  77     print "$language->{language_name}\n"; # language name in native script
  78     print "$language->{language_locale_name}\n"; # language name in current locale
  79  }
  80
  81 =cut
  82
  83 sub getFrameworkLanguages {
  84     # get a hash with all language codes, names, and locale names
  85     my $all_languages = getAllLanguages();
  86     my @languages;
  87
  88     # find the available directory names
  89     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  90     opendir (MYDIR,$dir);
  91     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);
  92     closedir MYDIR;
  93
  94     # pull out all data for the dir names that exist
  95     for my $dirname (@listdir) {
  96         for my $language_set (@$all_languages) {
  97
  98             if ($dirname eq $language_set->{language_code}) {
  99                 push @languages, {
 100                     'language_code'=>$dirname,
 101                     'language_description'=>$language_set->{language_description},
 102                     'native_descrition'=>$language_set->{language_native_description} }
 103             }
 104         }
 105     }
 106     return \@languages;
 107 }
 108
 109 =head2 getTranslatedLanguages
 110
 111 Returns a reference to an array of hashes:
 112
 113  my $languages = getTranslatedLanguages();
 114  print "Available translated languages:\n";
 115  for my $language(@$trlanguages) {
 116     print "$language->{language_code}\n"; # language code in iso 639-2
 117     print "$language->{language_name}\n"; # language name in native script
 118     print "$language->{language_locale_name}\n"; # language name in current locale
 119  }
 120
 121 =cut
 122
 123 sub getTranslatedLanguages {
 124     my ($interface, $theme, $current_language, $which) = @_;
 125     my $htdocs;
 126     my @languages;
 127     my @enabled_languages;
 128
 129     if ($interface && $interface eq 'opac' ) {
 130         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 131         $htdocs = C4::Context->config('opachtdocs');
 132         if ( $theme and -d "$htdocs/$theme" ) {
 133             (@languages) = _get_language_dirs($htdocs,$theme);
 134         }
 135         else {
 136             for my $theme ( _get_themes('opac') ) {
 137                 push @languages, _get_language_dirs($htdocs,$theme);
 138             }
 139         }
 140     }
 141     elsif ($interface && $interface eq 'intranet' ) {
 142         @enabled_languages = split ",", C4::Context->preference('language');
 143         $htdocs = C4::Context->config('intrahtdocs');
 144         if ( $theme and -d "$htdocs/$theme" ) {
 145             @languages = _get_language_dirs($htdocs,$theme);
 146         }
 147         else {
 148             foreach my $theme ( _get_themes('intranet') ) {
 149                 push @languages, _get_language_dirs($htdocs,$theme);
 150             }
 151         }
 152     }
 153     else {
 154         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 155         my $htdocs = C4::Context->config('intrahtdocs');
 156         foreach my $theme ( _get_themes('intranet') ) {
 157             push @languages, _get_language_dirs($htdocs,$theme);
 158         }
 159         $htdocs = C4::Context->config('opachtdocs');
 160         foreach my $theme ( _get_themes('opac') ) {
 161             push @languages, _get_language_dirs($htdocs,$theme);
 162         }
 163         my %seen;
 164         $seen{$_}++ for @languages;
 165         @languages = keys %seen;
 166     }
 167     return _build_languages_arrayref(\@languages,$current_language,\@enabled_languages);
 168 }
 169
 170 =head2 getAllLanguages
 171
 172 Returns a reference to an array of hashes:
 173
 174  my $alllanguages = getAllLanguages();
 175  print "Available translated languages:\n";
 176  for my $language(@$alllanguages) {
 177     print "$language->{language_code}\n";
 178     print "$language->{language_name}\n";
 179     print "$language->{language_locale_name}\n";
 180  }
 181
 182 This routine is a wrapper for getLanguages().
 183
 184 =cut
 185
 186 sub getAllLanguages {
 187     return getLanguages(shift);
 188 }
 189
 190 =head2 getLanguages
 191
 192     my $lang_arrayref = getLanguages([$lang[, $isFiltered]]);
 193
 194 Returns a reference to an array of hashes of languages.
 195
 196 - If no parameter is passed to the function, it returns english languages names
 197 - If a $lang parameter conforming to RFC4646 syntax is passed, the function returns languages names translated in $lang
 198   If a language name is not translated in $lang in database, the function returns english language name
 199 - If $isFiltered is set to true, only the detail of the languages selected in system preferences AdvanceSearchLanguages is returned.
 200
 201 =cut
 202
 203 sub getLanguages {
 204     my $lang = shift;
 205     my $isFiltered = shift;
 206
 207     my @languages_loop;
 208     my $dbh=C4::Context->dbh;
 209     my $default_language = 'en';
 210     my $current_language = $default_language;
 211     my $language_list = $isFiltered ? C4::Context->preference("AdvancedSearchLanguages") : undef;
 212     if ($lang) {
 213         $current_language = regex_lang_subtags($lang)->{'language'};
 214     }
 215     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\'');
 216     $sth->execute();
 217     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 218         my $desc;
 219         # check if language name is stored in current language
 220         my $sth4= $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag =? AND lang = ?");
 221         $sth4->execute($language_subtag_registry->{subtag},$current_language);
 222         while (my $language_desc = $sth4->fetchrow_hashref) {
 223              $desc=$language_desc->{description};
 224         }
 225         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =? AND language_descriptions.lang = ?");
 226         if ($desc) {
 227             $sth2->execute($language_subtag_registry->{subtag},$current_language);
 228         }
 229         else {
 230             $sth2->execute($language_subtag_registry->{subtag},$default_language);
 231         }
 232         my $sth3 = $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag=? AND lang=?");
 233         # add the correct description info
 234         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 235             $sth3->execute($language_subtag_registry->{subtag},$language_subtag_registry->{subtag});
 236             my $native_description;
 237             while (my $description = $sth3->fetchrow_hashref) {
 238                 $native_description = $description->{description};
 239             }
 240
 241             # fill in the ISO6329 code
 242             $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 243             # fill in the native description of the language, as well as the current language's translation of that if it exists
 244             if ($native_description) {
 245                 $language_subtag_registry->{language_description} = $native_description;
 246                 $language_subtag_registry->{language_description}.=" ($language_descriptions->{description})" if $language_descriptions->{description};
 247             }
 248             else {
 249                 $language_subtag_registry->{language_description} = $language_descriptions->{description};
 250             }
 251         }
 252         if ( !$language_list || index (  $language_list, $language_subtag_registry->{ iso639_2_code } ) >= 0) {
 253             push @languages_loop, $language_subtag_registry;
 254         }
 255     }
 256     return \@languages_loop;
 257 }
 258
 259 =head2 _get_themes
 260
 261 Internal function, returns an array of all available themes.
 262
 263   (@themes) = &_get_themes('opac');
 264   (@themes) = &_get_themes('intranet');
 265
 266 =cut
 267
 268 sub _get_themes {
 269     my $interface = shift;
 270     my $htdocs;
 271     my @themes;
 272     if ( $interface eq 'intranet' ) {
 273         $htdocs = C4::Context->config('intrahtdocs');
 274     }
 275     else {
 276         $htdocs = C4::Context->config('opachtdocs');
 277     }
 278     opendir D, "$htdocs";
 279     my @dirlist = readdir D;
 280     foreach my $directory (@dirlist) {
 281         # if there's an en dir, it's a valid theme
 282         -d "$htdocs/$directory/en" and push @themes, $directory;
 283     }
 284     return @themes;
 285 }
 286
 287 =head2 _get_language_dirs
 288
 289 Internal function, returns an array of directory names, excluding non-language directories
 290
 291 =cut
 292
 293 sub _get_language_dirs {
 294     my ($htdocs,$theme) = @_;
 295     my @lang_strings;
 296     opendir D, "$htdocs/$theme";
 297     for my $lang_string ( readdir D ) {
 298         next if $lang_string =~/^\./;
 299         next if $lang_string eq 'all';
 300         next if $lang_string =~/png$/;
 301         next if $lang_string =~/js$/;
 302         next if $lang_string =~/css$/;
 303         next if $lang_string =~/CVS$/;
 304         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 305         next if $lang_string =~/img|images|famfam|js|less|lib|sound|pdf/;
 306         push @lang_strings, $lang_string;
 307     }
 308         return (@lang_strings);
 309 }
 310
 311 =head2 _build_languages_arrayref
 312
 313 Internal function for building the ref to array of hashes
 314
 315 FIXME: this could be rewritten and simplified using map
 316
 317 =cut
 318
 319 sub _build_languages_arrayref {
 320         my ($translated_languages,$current_language,$enabled_languages) = @_;
 321         my @translated_languages = @$translated_languages;
 322         my @languages_loop; # the final reference to an array of hashrefs
 323         my @enabled_languages = @$enabled_languages;
 324         # how many languages are enabled, if one, take note, some contexts won't need to display it
 325         my %seen_languages; # the language tags we've seen
 326         my %found_languages;
 327         my $language_groups;
 328         my $track_language_groups;
 329         my $current_language_regex = regex_lang_subtags($current_language);
 330         # Loop through the translated languages
 331         for my $translated_language (@translated_languages) {
 332             # separate the language string into its subtag types
 333             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 334
 335             # is this language string 'enabled'?
 336             for my $enabled_language (@enabled_languages) {
 337                 #warn "Checking out if $translated_language eq $enabled_language";
 338                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 339             }
 340
 341             # group this language, key by langtag
 342             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 343             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 344             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 345             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 346             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 347             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 348             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 349             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 350         }
 351         # $key is a language subtag like 'en'
 352         while( my ($key, $value) = each %$language_groups) {
 353
 354             # is this language group enabled? are any of the languages within it enabled?
 355             my $enabled;
 356             for my $enabled_language (@enabled_languages) {
 357                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 358                 $enabled = 1 if $key eq $regex_enabled_language->{language};
 359             }
 360             push @languages_loop,  {
 361                             # this is only use if there is one
 362                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 363                             native_description => language_get_description($key,$key,'language'),
 364                             language => $key,
 365                             sublanguages_loop => $value,
 366                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 367                             current => $current_language_regex->{language} eq $key ? 1 : 0,
 368                             group_enabled => $enabled,
 369                            };
 370         }
 371         return \@languages_loop;
 372 }
 373
 374 sub language_get_description {
 375     my ($script,$lang,$type) = @_;
 376     my $dbh = C4::Context->dbh;
 377     my $desc;
 378     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 379     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 380     $sth->execute($script,$lang,$type);
 381     while (my $descriptions = $sth->fetchrow_hashref) {
 382         $desc = $descriptions->{'description'};
 383     }
 384     unless ($desc) {
 385         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 386         $sth->execute($script,'en',$type);
 387         while (my $descriptions = $sth->fetchrow_hashref) {
 388             $desc = $descriptions->{'description'};
 389         }
 390     }
 391     return $desc;
 392 }
 393 =head2 regex_lang_subtags
 394
 395 This internal sub takes a string composed according to RFC 4646 as
 396 an input and returns a reference to a hash containing keys and values
 397 for ( language, script, region, variant, extension, privateuse )
 398
 399 =cut
 400
 401 sub regex_lang_subtags {
 402     my $string = shift;
 403
 404     # Regex for recognizing RFC 4646 well-formed tags
 405     # http://www.rfc-editor.org/rfc/rfc4646.txt
 406
 407     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 408     # The structure requires no forward references, so it reverses the order.
 409     # The uppercase comments are fragments copied from RFC 4646
 410     #
 411     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 412
 413     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 414     my $digit   = qr/[0-9]/ ;   # DIGIT
 415     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 416     my $x   = qr/[xX]/ ;    # private use singleton
 417     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 418     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 419
 420     # Now do the components. The structure is slightly different to allow for capturing the right components.
 421     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 422
 423     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 424     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 425     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 426
 427     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 428
 429     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 430
 431     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 432     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 433
 434     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 435     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 436
 437     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 438
 439     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 440     # Since these are limited, this is safe even later changes to the registry --
 441     # the only oddity is that it might change the type of the tag, and thus
 442     # the results from the capturing groups.
 443     # http://www.iana.org/assignments/language-subtag-registry
 444     # Note that these have to be compared case insensitively, requiring (?i) below.
 445
 446     my $grandfathered   = qr{(?: (?i)
 447         en $s GB $s oed
 448     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 449     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 450 )}x;
 451
 452     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 453
 454     #   |   art $s lojban
 455     #   |   cel $s gaulish
 456     #   |   en $s (?: boont | GB $s oed | scouse )
 457     #   |   no $s (?: bok | nyn)
 458     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 459
 460     # Here is the final breakdown, with capturing groups for each of these components
 461     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 462
 463     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 464
 465     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 466     my %subtag = (
 467         'rfc4646_subtag' => $string,
 468         'language' => $1,
 469         'script' => $2,
 470         'region' => $3,
 471         'variant' => $4,
 472         'extension' => $5,
 473         'privateuse' => $6,
 474     );
 475     return \%subtag;
 476 }
 477
 478 # Script Direction Resources:
 479 # http://www.w3.org/International/questions/qa-scripts
 480 sub get_bidi {
 481     my ($language_script)= @_;
 482     my $dbh = C4::Context->dbh;
 483     my $bidi;
 484     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 485     $sth->execute($language_script);
 486     while (my $result = $sth->fetchrow_hashref) {
 487         $bidi = $result->{'bidi'};
 488     }
 489     return $bidi;
 490 };
 491
 492 sub accept_language {
 493     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 494     my ($clientPreferences,$supportedLanguages) = @_;
 495     my @languages = ();
 496     if ($clientPreferences) {
 497         # There should be no whitespace anways, but a cleanliness/sanity check
 498         $clientPreferences =~ s/\s//g;
 499         # Prepare the list of client-acceptable languages
 500         foreach my $tag (split(/,/, $clientPreferences)) {
 501             my ($language, $quality) = split(/\;/, $tag);
 502             $quality =~ s/^q=//i if $quality;
 503             $quality = 1 unless $quality;
 504             next if $quality <= 0;
 505             # We want to force the wildcard to be last
 506             $quality = 0 if ($language eq '*');
 507             # Pushing lowercase language here saves processing later
 508             push(@languages, { quality => $quality,
 509                language => $language,
 510                lclanguage => lc($language) });
 511         }
 512     } else {
 513         carp "accept_language(x,y) called with no clientPreferences (x).";
 514     }
 515     # Prepare the list of server-supported languages
 516     my %supportedLanguages = ();
 517     my %secondaryLanguages = ();
 518     foreach my $language (@$supportedLanguages) {
 519         # warn "Language supported: " . $language->{language};
 520         my $subtag = $language->{rfc4646_subtag};
 521         $supportedLanguages{lc($subtag)} = $subtag;
 522         if ( $subtag =~ /^([^-]+)-?/ ) {
 523             $secondaryLanguages{lc($1)} = $subtag;
 524         }
 525     }
 526
 527     # Reverse sort the list, making best quality at the front of the array
 528     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 529     my $secondaryMatch = '';
 530     foreach my $tag (@languages) {
 531         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 532             # Client en-us eq server en-us
 533             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 534             return $supportedLanguages{$tag->{lclanguage}};
 535         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 536             # Client en eq server en-us
 537             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 538             return $supportedLanguages{$tag->{lclanguage}};
 539         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 540             # Client en-gb eq server en-us
 541             $secondaryMatch = $secondaryLanguages{$1};
 542         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 543             # FIXME: We just checked the exact same conditional!
 544             # Client en-us eq server en
 545             $secondaryMatch = $supportedLanguages{$1};
 546         } elsif ($tag->{lclanguage} eq '*') {
 547         # * matches every language not already specified.
 548         # It doesn't care which we pick, so let's pick the default,
 549         # if available, then the first in the array.
 550         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 551         return $supportedLanguages->[0];
 552         }
 553     }
 554     # No primary matches. Secondary? (ie, en-us requested and en supported)
 555     return $secondaryMatch if $secondaryMatch;
 556     return undef;   # else, we got nothing.
 557 }
 558
 559 =head2 getlanguage
 560
 561     Select a language based on the URL parameter 'language', a cookie,
 562     syspref available languages & browser
 563
 564 =cut
 565
 566 sub getlanguage {
 567     my ($cgi) = @_;
 568
 569     $cgi //= new CGI;
 570     my $interface = C4::Context->interface;
 571     my $language;
 572
 573     my $preference_to_check =
 574       $interface eq 'intranet' ? 'language' : 'opaclanguages';
 575     # Get the available/valid languages list
 576     my @languages = split /,/, C4::Context->preference($preference_to_check);
 577
 578     # Chose language from the URL
 579     $language = $cgi->param( 'language' );
 580     if ( defined $language && any { $_ eq $language } @languages) {
 581         return $language;
 582     }
 583
 584     # cookie
 585     if ($language = $cgi->cookie('KohaOpacLanguage') ) {
 586         $language =~ s/[^a-zA-Z_-]*//; # sanitize cookie
 587     }
 588
 589     # HTTP_ACCEPT_LANGUAGE
 590     if ( !$language && $ENV{HTTP_ACCEPT_LANGUAGE} ) {
 591         $language = accept_language( $ENV{HTTP_ACCEPT_LANGUAGE},
 592             getTranslatedLanguages( $interface, 'prog' ) );
 593     }
 594
 595     # Ignore a lang not selected in sysprefs
 596     if ( $language && any { $_ eq $language } @languages ) {
 597         return $language;
 598     }
 599
 600     # Pick the first selected syspref language
 601     $language = shift @languages;
 602     return $language if $language;
 603
 604     # Fall back to English if necessary
 605     return 'en';
 606 }
 607
 608 1;
 609
 610 __END__
 611
 612 =head1 AUTHOR
 613
 614 Joshua Ferraro
 615
 616 =cut