C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 # Portions Copyright 2009 Chris Cormack and the Koha Dev Team
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21
  22 use strict;
  23 #use warnings; FIXME - Bug 2505
  24 use Carp;
  25 use C4::Context;
  26 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $DEBUG);
  27
  28 eval {
  29     my $servers = C4::Context->config('memcached_servers');
  30     if ($servers) {
  31         require Memoize::Memcached;
  32         import Memoize::Memcached qw(memoize_memcached);
  33
  34         my $memcached = {
  35             servers     => [$servers],
  36             key_prefix  => C4::Context->config('memcached_namespace') || 'koha',
  37             expire_time => 600
  38         };    # cache for 10 mins
  39
  40         memoize_memcached( 'getTranslatedLanguages', memcached => $memcached );
  41         memoize_memcached( 'getFrameworkLanguages',  memcached => $memcached );
  42         memoize_memcached( 'getAllLanguages',        memcached => $memcached );
  43     }
  44 };
  45
  46 BEGIN {
  47     $VERSION = 3.00;
  48     require Exporter;
  49     @ISA    = qw(Exporter);
  50     @EXPORT = qw(
  51         &getFrameworkLanguages
  52         &getTranslatedLanguages
  53         &getAllLanguages
  54     );
  55     @EXPORT_OK = qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages get_bidi regex_lang_subtags language_get_description accept_language);
  56     $DEBUG = 0;
  57 }
  58
  59 =head1 NAME
  60
  61 C4::Languages - Perl Module containing language list functions for Koha
  62
  63 =head1 SYNOPSIS
  64
  65 use C4::Languages;
  66
  67 =head1 DESCRIPTION
  68
  69 =cut
  70
  71 =head1 FUNCTIONS
  72
  73 =head2 getFrameworkLanguages
  74
  75 Returns a reference to an array of hashes:
  76
  77  my $languages = getFrameworkLanguages();
  78  for my $language(@$languages) {
  79     print "$language->{language_code}\n"; # language code in iso 639-2
  80     print "$language->{language_name}\n"; # language name in native script
  81     print "$language->{language_locale_name}\n"; # language name in current locale
  82  }
  83
  84 =cut
  85
  86 sub getFrameworkLanguages {
  87     # get a hash with all language codes, names, and locale names
  88     my $all_languages = getAllLanguages();
  89     my @languages;
  90
  91     # find the available directory names
  92     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  93     opendir (MYDIR,$dir);
  94     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);
  95     closedir MYDIR;
  96
  97     # pull out all data for the dir names that exist
  98     for my $dirname (@listdir) {
  99         for my $language_set (@$all_languages) {
 100
 101             if ($dirname eq $language_set->{language_code}) {
 102                 push @languages, {
 103                     'language_code'=>$dirname,
 104                     'language_description'=>$language_set->{language_description},
 105                     'native_descrition'=>$language_set->{language_native_description} }
 106             }
 107         }
 108     }
 109     return \@languages;
 110 }
 111
 112 =head2 getTranslatedLanguages
 113
 114 Returns a reference to an array of hashes:
 115
 116  my $languages = getTranslatedLanguages();
 117  print "Available translated languages:\n";
 118  for my $language(@$trlanguages) {
 119     print "$language->{language_code}\n"; # language code in iso 639-2
 120     print "$language->{language_name}\n"; # language name in native script
 121     print "$language->{language_locale_name}\n"; # language name in current locale
 122  }
 123
 124 =cut
 125
 126 sub getTranslatedLanguages {
 127     my ($interface, $theme, $current_language, $which) = @_;
 128     my $htdocs;
 129     my $all_languages = getAllLanguages();
 130     my @languages;
 131     my @enabled_languages;
 132
 133     if ($interface && $interface eq 'opac' ) {
 134         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 135         $htdocs = C4::Context->config('opachtdocs');
 136         if ( $theme and -d "$htdocs/$theme" ) {
 137             (@languages) = _get_language_dirs($htdocs,$theme);
 138         }
 139         else {
 140             for my $theme ( _get_themes('opac') ) {
 141                 push @languages, _get_language_dirs($htdocs,$theme);
 142             }
 143         }
 144     }
 145     elsif ($interface && $interface eq 'intranet' ) {
 146         @enabled_languages = split ",", C4::Context->preference('language');
 147         $htdocs = C4::Context->config('intrahtdocs');
 148         if ( $theme and -d "$htdocs/$theme" ) {
 149             @languages = _get_language_dirs($htdocs,$theme);
 150         }
 151         else {
 152             foreach my $theme ( _get_themes('intranet') ) {
 153                 push @languages, _get_language_dirs($htdocs,$theme);
 154             }
 155         }
 156     }
 157     else {
 158         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 159         my $htdocs = C4::Context->config('intrahtdocs');
 160         foreach my $theme ( _get_themes('intranet') ) {
 161             push @languages, _get_language_dirs($htdocs,$theme);
 162         }
 163         $htdocs = C4::Context->config('opachtdocs');
 164         foreach my $theme ( _get_themes('opac') ) {
 165             push @languages, _get_language_dirs($htdocs,$theme);
 166         }
 167         my %seen;
 168         $seen{$_}++ for @languages;
 169         @languages = keys %seen;
 170     }
 171     return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
 172 }
 173
 174 =head2 getAllLanguages
 175
 176 Returns a reference to an array of hashes:
 177
 178  my $alllanguages = getAllLanguages();
 179  print "Available translated languages:\n";
 180  for my $language(@$alllanguages) {
 181     print "$language->{language_code}\n";
 182     print "$language->{language_name}\n";
 183     print "$language->{language_locale_name}\n";
 184  }
 185
 186 =cut
 187
 188 sub getAllLanguages {
 189     my @languages_loop;
 190     my $dbh=C4::Context->dbh;
 191     my $current_language = shift || 'en';
 192     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\'');
 193     $sth->execute();
 194     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 195
 196         # pull out all the script descriptions for each language
 197         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =? AND language_descriptions.lang = ?");
 198         $sth2->execute($language_subtag_registry->{subtag},$current_language);
 199
 200         my $sth3 = $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag=? AND lang=?");
 201
 202         # add the correct description info
 203         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 204             $sth3->execute($language_subtag_registry->{subtag},$language_subtag_registry->{subtag});
 205             my $native_description;
 206             while (my $description = $sth3->fetchrow_hashref) {
 207                 $native_description = $description->{description};
 208             }
 209
 210             # fill in the ISO6329 code
 211             $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 212             # fill in the native description of the language, as well as the current language's translation of that if it exists
 213             if ($native_description) {
 214                 $language_subtag_registry->{language_description} = $native_description;
 215                 $language_subtag_registry->{language_description}.=" ($language_descriptions->{description})" if $language_descriptions->{description};
 216             }
 217             else {
 218                 $language_subtag_registry->{language_description} = $language_descriptions->{description};
 219             }
 220         }
 221         push @languages_loop, $language_subtag_registry;
 222     }
 223     return \@languages_loop;
 224 }
 225
 226 =head2 _get_themes
 227
 228 Internal function, returns an array of all available themes.
 229
 230   (@themes) = &_get_themes('opac');
 231   (@themes) = &_get_themes('intranet');
 232
 233 =cut
 234
 235 sub _get_themes {
 236     my $interface = shift;
 237     my $htdocs;
 238     my @themes;
 239     if ( $interface eq 'intranet' ) {
 240         $htdocs = C4::Context->config('intrahtdocs');
 241     }
 242     else {
 243         $htdocs = C4::Context->config('opachtdocs');
 244     }
 245     opendir D, "$htdocs";
 246     my @dirlist = readdir D;
 247     foreach my $directory (@dirlist) {
 248         # if there's an en dir, it's a valid theme
 249         -d "$htdocs/$directory/en" and push @themes, $directory;
 250     }
 251     return @themes;
 252 }
 253
 254 =head2 _get_language_dirs
 255
 256 Internal function, returns an array of directory names, excluding non-language directories
 257
 258 =cut
 259
 260 sub _get_language_dirs {
 261     my ($htdocs,$theme) = @_;
 262     my @lang_strings;
 263     opendir D, "$htdocs/$theme";
 264     for my $lang_string ( readdir D ) {
 265         next if $lang_string =~/^\./;
 266         next if $lang_string eq 'all';
 267         next if $lang_string =~/png$/;
 268         next if $lang_string =~/css$/;
 269         next if $lang_string =~/CVS$/;
 270         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 271         next if $lang_string =~/img|images|famfam|sound|pdf/;
 272         push @lang_strings, $lang_string;
 273     }
 274         return (@lang_strings);
 275 }
 276
 277 =head2 _build_languages_arrayref
 278
 279 Internal function for building the ref to array of hashes
 280
 281 FIXME: this could be rewritten and simplified using map
 282
 283 =cut
 284
 285 sub _build_languages_arrayref {
 286         my ($all_languages,$translated_languages,$current_language,$enabled_languages) = @_;
 287         my @translated_languages = @$translated_languages;
 288         my @languages_loop; # the final reference to an array of hashrefs
 289         my @enabled_languages = @$enabled_languages;
 290         # how many languages are enabled, if one, take note, some contexts won't need to display it
 291         my %seen_languages; # the language tags we've seen
 292         my %found_languages;
 293         my $language_groups;
 294         my $track_language_groups;
 295         my $current_language_regex = regex_lang_subtags($current_language);
 296         # Loop through the translated languages
 297         for my $translated_language (@translated_languages) {
 298             # separate the language string into its subtag types
 299             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 300
 301             # is this language string 'enabled'?
 302             for my $enabled_language (@enabled_languages) {
 303                 #warn "Checking out if $translated_language eq $enabled_language";
 304                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 305             }
 306
 307             # group this language, key by langtag
 308             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 309             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 310             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 311             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 312             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 313             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 314             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 315             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 316         }
 317         # $key is a language subtag like 'en'
 318         while( my ($key, $value) = each %$language_groups) {
 319
 320             # is this language group enabled? are any of the languages within it enabled?
 321             my $enabled;
 322             for my $enabled_language (@enabled_languages) {
 323                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 324                 $enabled = 1 if $key eq $regex_enabled_language->{language};
 325             }
 326             push @languages_loop,  {
 327                             # this is only use if there is one
 328                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 329                             native_description => language_get_description($key,$key,'language'),
 330                             language => $key,
 331                             sublanguages_loop => $value,
 332                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 333                             current => $current_language_regex->{language} eq $key ? 1 : 0,
 334                             group_enabled => $enabled,
 335                            };
 336         }
 337         return \@languages_loop;
 338 }
 339
 340 sub language_get_description {
 341     my ($script,$lang,$type) = @_;
 342     my $dbh = C4::Context->dbh;
 343     my $desc;
 344     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 345     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 346     $sth->execute($script,$lang,$type);
 347     while (my $descriptions = $sth->fetchrow_hashref) {
 348         $desc = $descriptions->{'description'};
 349     }
 350     unless ($desc) {
 351         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 352         $sth->execute($script,'en',$type);
 353         while (my $descriptions = $sth->fetchrow_hashref) {
 354             $desc = $descriptions->{'description'};
 355         }
 356     }
 357     return $desc;
 358 }
 359 =head2 regex_lang_subtags
 360
 361 This internal sub takes a string composed according to RFC 4646 as
 362 an input and returns a reference to a hash containing keys and values
 363 for ( language, script, region, variant, extension, privateuse )
 364
 365 =cut
 366
 367 sub regex_lang_subtags {
 368     my $string = shift;
 369
 370     # Regex for recognizing RFC 4646 well-formed tags
 371     # http://www.rfc-editor.org/rfc/rfc4646.txt
 372
 373     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 374     # The structure requires no forward references, so it reverses the order.
 375     # The uppercase comments are fragments copied from RFC 4646
 376     #
 377     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 378
 379     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 380     my $digit   = qr/[0-9]/ ;   # DIGIT
 381     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 382     my $x   = qr/[xX]/ ;    # private use singleton
 383     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 384     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 385
 386     # Now do the components. The structure is slightly different to allow for capturing the right components.
 387     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 388
 389     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 390     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 391     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 392
 393     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 394
 395     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 396
 397     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 398     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 399
 400     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 401     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 402
 403     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 404
 405     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 406     # Since these are limited, this is safe even later changes to the registry --
 407     # the only oddity is that it might change the type of the tag, and thus
 408     # the results from the capturing groups.
 409     # http://www.iana.org/assignments/language-subtag-registry
 410     # Note that these have to be compared case insensitively, requiring (?i) below.
 411
 412     my $grandfathered   = qr{(?: (?i)
 413         en $s GB $s oed
 414     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 415     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 416 )}x;
 417
 418     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 419
 420     #   |   art $s lojban
 421     #   |   cel $s gaulish
 422     #   |   en $s (?: boont | GB $s oed | scouse )
 423     #   |   no $s (?: bok | nyn)
 424     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 425
 426     # Here is the final breakdown, with capturing groups for each of these components
 427     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 428
 429     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 430
 431     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 432     my %subtag = (
 433         'rfc4646_subtag' => $string,
 434         'language' => $1,
 435         'script' => $2,
 436         'region' => $3,
 437         'variant' => $4,
 438         'extension' => $5,
 439         'privateuse' => $6,
 440     );
 441     return \%subtag;
 442 }
 443
 444 # Script Direction Resources:
 445 # http://www.w3.org/International/questions/qa-scripts
 446 sub get_bidi {
 447     my ($language_script)= @_;
 448     my $dbh = C4::Context->dbh;
 449     my $bidi;
 450     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 451     $sth->execute($language_script);
 452     while (my $result = $sth->fetchrow_hashref) {
 453         $bidi = $result->{'bidi'};
 454     }
 455     return $bidi;
 456 };
 457
 458 sub accept_language {
 459     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 460     my ($clientPreferences,$supportedLanguages) = @_;
 461     my @languages = ();
 462     if ($clientPreferences) {
 463         # There should be no whitespace anways, but a cleanliness/sanity check
 464         $clientPreferences =~ s/\s//g;
 465         # Prepare the list of client-acceptable languages
 466         foreach my $tag (split(/,/, $clientPreferences)) {
 467             my ($language, $quality) = split(/\;/, $tag);
 468             $quality =~ s/^q=//i if $quality;
 469             $quality = 1 unless $quality;
 470             next if $quality <= 0;
 471             # We want to force the wildcard to be last
 472             $quality = 0 if ($language eq '*');
 473             # Pushing lowercase language here saves processing later
 474             push(@languages, { quality => $quality,
 475                language => $language,
 476                lclanguage => lc($language) });
 477         }
 478     } else {
 479         carp "accept_language(x,y) called with no clientPreferences (x).";
 480     }
 481     # Prepare the list of server-supported languages
 482     my %supportedLanguages = ();
 483     my %secondaryLanguages = ();
 484     foreach my $language (@$supportedLanguages) {
 485         # warn "Language supported: " . $language->{language};
 486         my $subtag = $language->{rfc4646_subtag};
 487         $supportedLanguages{lc($subtag)} = $subtag;
 488         if ( $subtag =~ /^([^-]+)-?/ ) {
 489             $secondaryLanguages{lc($1)} = $subtag;
 490         }
 491     }
 492
 493     # Reverse sort the list, making best quality at the front of the array
 494     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 495     my $secondaryMatch = '';
 496     foreach my $tag (@languages) {
 497         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 498             # Client en-us eq server en-us
 499             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 500             return $supportedLanguages{$tag->{lclanguage}};
 501         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 502             # Client en eq server en-us
 503             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 504             return $supportedLanguages{$tag->{lclanguage}};
 505         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 506             # Client en-gb eq server en-us
 507             $secondaryMatch = $secondaryLanguages{$1};
 508         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 509             # FIXME: We just checked the exact same conditional!
 510             # Client en-us eq server en
 511             $secondaryMatch = $supportedLanguages{$1};
 512         } elsif ($tag->{lclanguage} eq '*') {
 513         # * matches every language not already specified.
 514         # It doesn't care which we pick, so let's pick the default,
 515         # if available, then the first in the array.
 516         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 517         return $supportedLanguages->[0];
 518         }
 519     }
 520     # No primary matches. Secondary? (ie, en-us requested and en supported)
 521     return $secondaryMatch if $secondaryMatch;
 522     return undef;   # else, we got nothing.
 523 }
 524 1;
 525
 526 __END__
 527
 528 =head1 AUTHOR
 529
 530 Joshua Ferraro
 531
 532 =cut