C4/Letters.pm

   1 package C4::Letters;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp qw( carp croak );
  23 use Template;
  24 use Module::Load::Conditional qw( can_load );
  25
  26 use Try::Tiny qw( catch try );
  27
  28 use C4::Members;
  29 use C4::Log qw( logaction );
  30 use C4::SMS;
  31 use C4::Templates;
  32 use Koha::SMS::Providers;
  33
  34 use Koha::Email;
  35 use Koha::Notice::Messages;
  36 use Koha::Notice::Templates;
  37 use Koha::DateUtils qw( dt_from_string output_pref );
  38 use Koha::Auth::TwoFactorAuth;
  39 use Koha::Patrons;
  40 use Koha::SMTP::Servers;
  41 use Koha::Subscriptions;
  42
  43 use constant SERIALIZED_EMAIL_CONTENT_TYPE => 'message/rfc822';
  44
  45 our (@ISA, @EXPORT_OK);
  46 BEGIN {
  47     require Exporter;
  48     @ISA = qw(Exporter);
  49     @EXPORT_OK = qw(
  50       GetLetters
  51       GetLettersAvailableForALibrary
  52       GetLetterTemplates
  53       DelLetter
  54       GetPreparedLetter
  55       GetWrappedLetter
  56       SendAlerts
  57       GetPrintMessages
  58       GetQueuedMessages
  59       GetMessage
  60       GetMessageTransportTypes
  61
  62       EnqueueLetter
  63       SendQueuedMessages
  64       ResendMessage
  65     );
  66 }
  67
  68 =head1 NAME
  69
  70 C4::Letters - Give functions for Letters management
  71
  72 =head1 SYNOPSIS
  73
  74   use C4::Letters;
  75
  76 =head1 DESCRIPTION
  77
  78   "Letters" is the tool used in Koha to manage informations sent to the patrons and/or the library. This include some cron jobs like
  79   late issues, as well as other tasks like sending a mail to users that have subscribed to a "serial issue alert" (= being warned every time a new issue has arrived at the library)
  80
  81   Letters are managed through "alerts" sent by Koha on some events. All "alert" related functions are in this module too.
  82
  83 =head2 GetLetters([$module])
  84
  85   $letters = &GetLetters($module);
  86   returns informations about letters.
  87   if needed, $module filters for letters given module
  88
  89   DEPRECATED - You must use Koha::Notice::Templates instead
  90   The group by clause is confusing and can lead to issues
  91
  92 =cut
  93
  94 sub GetLetters {
  95     my ($filters) = @_;
  96     my $module    = $filters->{module};
  97     my $code      = $filters->{code};
  98     my $branchcode = $filters->{branchcode};
  99     my $dbh       = C4::Context->dbh;
 100     my $letters   = $dbh->selectall_arrayref(
 101         q|
 102             SELECT code, module, name
 103             FROM letter
 104             WHERE 1
 105         |
 106           . ( $module ? q| AND module = ?| : q|| )
 107           . ( $code   ? q| AND code = ?|   : q|| )
 108           . ( defined $branchcode   ? q| AND branchcode = ?|   : q|| )
 109           . q| GROUP BY code, module, name ORDER BY name|, { Slice => {} }
 110         , ( $module ? $module : () )
 111         , ( $code ? $code : () )
 112         , ( defined $branchcode ? $branchcode : () )
 113     );
 114
 115     return $letters;
 116 }
 117
 118 =head2 GetLetterTemplates
 119
 120     my $letter_templates = GetLetterTemplates(
 121         {
 122             module => 'circulation',
 123             code => 'my code',
 124             branchcode => 'CPL', # '' for default,
 125         }
 126     );
 127
 128     Return a hashref of letter templates.
 129
 130 =cut
 131
 132 sub GetLetterTemplates {
 133     my ( $params ) = @_;
 134
 135     my $module    = $params->{module};
 136     my $code      = $params->{code};
 137     my $branchcode = $params->{branchcode} // '';
 138     my $dbh       = C4::Context->dbh;
 139     return Koha::Notice::Templates->search(
 140         {
 141             module     => $module,
 142             code       => $code,
 143             branchcode => $branchcode,
 144             (
 145                 C4::Context->preference('TranslateNotices')
 146                 ? ()
 147                 : ( lang => 'default' )
 148             )
 149         }
 150     )->unblessed;
 151 }
 152
 153 =head2 GetLettersAvailableForALibrary
 154
 155     my $letters = GetLettersAvailableForALibrary(
 156         {
 157             branchcode => 'CPL', # '' for default
 158             module => 'circulation',
 159         }
 160     );
 161
 162     Return an arrayref of letters, sorted by name.
 163     If a specific letter exist for the given branchcode, it will be retrieve.
 164     Otherwise the default letter will be.
 165
 166 =cut
 167
 168 sub GetLettersAvailableForALibrary {
 169     my ($filters)  = @_;
 170     my $branchcode = $filters->{branchcode};
 171     my $module     = $filters->{module};
 172
 173     croak "module should be provided" unless $module;
 174
 175     my $dbh             = C4::Context->dbh;
 176     my $default_letters = $dbh->selectall_arrayref(
 177         q|
 178             SELECT module, code, branchcode, name
 179             FROM letter
 180             WHERE 1
 181         |
 182           . q| AND branchcode = ''|
 183           . ( $module ? q| AND module = ?| : q|| )
 184           . q| ORDER BY name|, { Slice => {} }
 185         , ( $module ? $module : () )
 186     );
 187
 188     my $specific_letters;
 189     if ($branchcode) {
 190         $specific_letters = $dbh->selectall_arrayref(
 191             q|
 192                 SELECT module, code, branchcode, name
 193                 FROM letter
 194                 WHERE 1
 195             |
 196               . q| AND branchcode = ?|
 197               . ( $module ? q| AND module = ?| : q|| )
 198               . q| ORDER BY name|, { Slice => {} }
 199             , $branchcode
 200             , ( $module ? $module : () )
 201         );
 202     }
 203
 204     my %letters;
 205     for my $l (@$default_letters) {
 206         $letters{ $l->{code} } = $l;
 207     }
 208     for my $l (@$specific_letters) {
 209         # Overwrite the default letter with the specific one.
 210         $letters{ $l->{code} } = $l;
 211     }
 212
 213     return [ map { $letters{$_} }
 214           sort { $letters{$a}->{name} cmp $letters{$b}->{name} }
 215           keys %letters ];
 216
 217 }
 218
 219 =head2 DelLetter
 220
 221     DelLetter(
 222         {
 223             branchcode => 'CPL',
 224             module => 'circulation',
 225             code => 'my code',
 226             [ mtt => 'email', ]
 227         }
 228     );
 229
 230     Delete the letter. The mtt parameter is facultative.
 231     If not given, all templates mathing the other parameters will be removed.
 232
 233 =cut
 234
 235 sub DelLetter {
 236     my ($params)   = @_;
 237     my $branchcode = $params->{branchcode};
 238     my $module     = $params->{module};
 239     my $code       = $params->{code};
 240     my $mtt        = $params->{mtt};
 241     my $lang       = $params->{lang};
 242     my $dbh        = C4::Context->dbh;
 243     $dbh->do(q|
 244         DELETE FROM letter
 245         WHERE branchcode = ?
 246           AND module = ?
 247           AND code = ?
 248     |
 249     . ( $mtt ? q| AND message_transport_type = ?| : q|| )
 250     . ( $lang? q| AND lang = ?| : q|| )
 251     , undef, $branchcode, $module, $code, ( $mtt ? $mtt : () ), ( $lang ? $lang : () ) );
 252 }
 253
 254 =head2 SendAlerts
 255
 256     my $err = &SendAlerts($type, $externalid, $letter_code);
 257
 258     Parameters:
 259       - $type : the type of alert
 260       - $externalid : the id of the "object" to query
 261       - $letter_code : the notice template to use
 262
 263     C<&SendAlerts> sends an email notice directly to a patron or a vendor.
 264
 265     Currently it supports ($type):
 266       - claim serial issues (claimissues)
 267       - claim acquisition orders (claimacquisition)
 268       - send acquisition orders to the vendor (orderacquisition)
 269       - notify patrons about newly received serial issues (issue)
 270       - notify patrons when their account is created (members)
 271
 272     Returns undef or { error => 'message } on failure.
 273     Returns true on success.
 274
 275 =cut
 276
 277 sub SendAlerts {
 278     my ( $type, $externalid, $letter_code ) = @_;
 279     my $dbh = C4::Context->dbh;
 280     my $error;
 281
 282     if ( $type eq 'issue' ) {
 283
 284         # prepare the letter...
 285         # search the subscriptionid
 286         my $sth =
 287           $dbh->prepare(
 288             "SELECT subscriptionid FROM serial WHERE serialid=?");
 289         $sth->execute($externalid);
 290         my ($subscriptionid) = $sth->fetchrow
 291           or warn( "No subscription for '$externalid'" ),
 292              return;
 293
 294         # search the biblionumber
 295         $sth =
 296           $dbh->prepare(
 297             "SELECT biblionumber FROM subscription WHERE subscriptionid=?");
 298         $sth->execute($subscriptionid);
 299         my ($biblionumber) = $sth->fetchrow
 300           or warn( "No biblionumber for '$subscriptionid'" ),
 301              return;
 302
 303         # find the list of subscribers to notify
 304         my $subscription = Koha::Subscriptions->find( $subscriptionid );
 305         my $subscribers = $subscription->subscribers;
 306         while ( my $patron = $subscribers->next ) {
 307             my $email = $patron->email or next;
 308
 309 #                    warn "sending issues...";
 310             my $userenv = C4::Context->userenv;
 311             my $library = $patron->library;
 312             my $letter = GetPreparedLetter (
 313                 module => 'serial',
 314                 letter_code => $letter_code,
 315                 branchcode => $userenv->{branch},
 316                 tables => {
 317                     'branches'    => $library->branchcode,
 318                     'biblio'      => $biblionumber,
 319                     'biblioitems' => $biblionumber,
 320                     'borrowers'   => $patron->unblessed,
 321                     'subscription' => $subscriptionid,
 322                     'serial' => $externalid,
 323                 },
 324                 want_librarian => 1,
 325             ) or return;
 326
 327             # FIXME: This 'default' behaviour should be moved to Koha::Email
 328             my $mail = Koha::Email->create(
 329                 {
 330                     to       => $email,
 331                     from     => $library->branchemail,
 332                     reply_to => $library->branchreplyto,
 333                     sender   => $library->branchreturnpath,
 334                     subject  => "" . $letter->{title},
 335                 }
 336             );
 337
 338             if ( $letter->{is_html} ) {
 339                 $mail->html_body( _wrap_html( $letter->{content}, "" . $letter->{title} ) );
 340             }
 341             else {
 342                 $mail->text_body( $letter->{content} );
 343             }
 344
 345             my $success = try {
 346                 $mail->send_or_die({ transport => $library->smtp_server->transport });
 347             }
 348             catch {
 349                 # We expect ref($_) eq 'Email::Sender::Failure'
 350                 $error = $_->message;
 351
 352                 carp "$_";
 353                 return;
 354             };
 355
 356             return { error => $error }
 357                 unless $success;
 358         }
 359     }
 360     elsif ( $type eq 'claimacquisition' or $type eq 'claimissues' or $type eq 'orderacquisition' ) {
 361
 362         # prepare the letter...
 363         my $strsth;
 364         my $sthorders;
 365         my $dataorders;
 366         my $action;
 367         my $basketno;
 368         if ( $type eq 'claimacquisition') {
 369             $strsth = qq{
 370             SELECT aqorders.*,aqbasket.*,biblio.*,biblioitems.*
 371             FROM aqorders
 372             LEFT JOIN aqbasket ON aqbasket.basketno=aqorders.basketno
 373             LEFT JOIN biblio ON aqorders.biblionumber=biblio.biblionumber
 374             LEFT JOIN biblioitems ON aqorders.biblionumber=biblioitems.biblionumber
 375             WHERE aqorders.ordernumber IN (
 376             };
 377
 378             if (!@$externalid){
 379                 carp "No order selected";
 380                 return { error => "no_order_selected" };
 381             }
 382             $strsth .= join( ",", ('?') x @$externalid ) . ")";
 383             $action = "ACQUISITION CLAIM";
 384             $sthorders = $dbh->prepare($strsth);
 385             $sthorders->execute( @$externalid );
 386             $dataorders = $sthorders->fetchall_arrayref( {} );
 387         }
 388
 389         if ($type eq 'claimissues') {
 390             $strsth = qq{
 391             SELECT serial.*,subscription.*, biblio.*, biblioitems.*, aqbooksellers.*,
 392             aqbooksellers.id AS booksellerid
 393             FROM serial
 394             LEFT JOIN subscription ON serial.subscriptionid=subscription.subscriptionid
 395             LEFT JOIN biblio ON serial.biblionumber=biblio.biblionumber
 396             LEFT JOIN biblioitems ON serial.biblionumber = biblioitems.biblionumber
 397             LEFT JOIN aqbooksellers ON subscription.aqbooksellerid=aqbooksellers.id
 398             WHERE serial.serialid IN (
 399             };
 400
 401             if (!@$externalid){
 402                 carp "No issues selected";
 403                 return { error => "no_issues_selected" };
 404             }
 405
 406             $strsth .= join( ",", ('?') x @$externalid ) . ")";
 407             $action = "SERIAL CLAIM";
 408             $sthorders = $dbh->prepare($strsth);
 409             $sthorders->execute( @$externalid );
 410             $dataorders = $sthorders->fetchall_arrayref( {} );
 411         }
 412
 413         if ( $type eq 'orderacquisition') {
 414             $basketno = $externalid;
 415             $strsth = qq{
 416             SELECT aqorders.*,aqbasket.*,biblio.*,biblioitems.*
 417             FROM aqorders
 418             LEFT JOIN aqbasket ON aqbasket.basketno=aqorders.basketno
 419             LEFT JOIN biblio ON aqorders.biblionumber=biblio.biblionumber
 420             LEFT JOIN biblioitems ON aqorders.biblionumber=biblioitems.biblionumber
 421             WHERE aqbasket.basketno = ?
 422             AND orderstatus IN ('new','ordered')
 423             };
 424
 425             unless ( $basketno ) {
 426                 carp "No basketnumber given";
 427                 return { error => "no_basketno" };
 428             }
 429             $action = "ACQUISITION ORDER";
 430             $sthorders = $dbh->prepare($strsth);
 431             $sthorders->execute($basketno);
 432             $dataorders = $sthorders->fetchall_arrayref( {} );
 433         }
 434
 435         my $sthbookseller =
 436           $dbh->prepare("select * from aqbooksellers where id=?");
 437         $sthbookseller->execute( $dataorders->[0]->{booksellerid} );
 438         my $databookseller = $sthbookseller->fetchrow_hashref;
 439
 440         my $addressee =  $type eq 'claimacquisition' || $type eq 'orderacquisition' ? 'acqprimary' : 'serialsprimary';
 441
 442         my $sthcontact =
 443           $dbh->prepare("SELECT * FROM aqcontacts WHERE booksellerid=? AND $type=1 ORDER BY $addressee DESC");
 444         $sthcontact->execute( $dataorders->[0]->{booksellerid} );
 445         my $datacontact = $sthcontact->fetchrow_hashref;
 446
 447         my @email;
 448         my @cc;
 449         push @email, $datacontact->{email}           if ( $datacontact && $datacontact->{email} );
 450         unless (@email) {
 451             warn "Bookseller $dataorders->[0]->{booksellerid} without emails";
 452             return { error => "no_email" };
 453         }
 454         my $addlcontact;
 455         while ($addlcontact = $sthcontact->fetchrow_hashref) {
 456             push @cc, $addlcontact->{email} if ( $addlcontact && $addlcontact->{email} );
 457         }
 458
 459         my $userenv = C4::Context->userenv;
 460         my $letter = GetPreparedLetter (
 461             module => $type,
 462             letter_code => $letter_code,
 463             branchcode => $userenv->{branch},
 464             tables => {
 465                 'branches'      => $userenv->{branch},
 466                 'aqbooksellers' => $databookseller,
 467                 'aqcontacts'    => $datacontact,
 468                 'aqbasket'      => $basketno,
 469             },
 470             repeat => $dataorders,
 471             want_librarian => 1,
 472         ) or return { error => "no_letter" };
 473
 474         # Remove the order tag
 475         $letter->{content} =~ s/<order>(.*?)<\/order>/$1/gxms;
 476
 477         # ... then send mail
 478         my $library = Koha::Libraries->find( $userenv->{branch} );
 479         my $mail = Koha::Email->create(
 480             {
 481                 to => join( ',', @email ),
 482                 cc => join( ',', @cc ),
 483                 (
 484                     (
 485                         C4::Context->preference("ClaimsBccCopy")
 486                           && ( $type eq 'claimacquisition'
 487                             || $type eq 'claimissues' )
 488                     )
 489                     ? ( bcc => $userenv->{emailaddress} )
 490                     : ()
 491                 ),
 492                 from => $library->branchemail
 493                   || C4::Context->preference('KohaAdminEmailAddress'),
 494                 subject => "" . $letter->{title},
 495             }
 496         );
 497
 498         if ( $letter->{is_html} ) {
 499             $mail->html_body( _wrap_html( $letter->{content}, "" . $letter->{title} ) );
 500         }
 501         else {
 502             $mail->text_body( "" . $letter->{content} );
 503         }
 504
 505         my $success = try {
 506             $mail->send_or_die({ transport => $library->smtp_server->transport });
 507         }
 508         catch {
 509             # We expect ref($_) eq 'Email::Sender::Failure'
 510             $error = $_->message;
 511
 512             carp "$_";
 513             return;
 514         };
 515
 516         return { error => $error }
 517             unless $success;
 518
 519         my $log_object = $action eq 'ACQUISITION ORDER' ? $externalid : undef;
 520         my $module = $action eq 'ACQUISITION ORDER' ? 'ACQUISITIONS' : 'CLAIMS';
 521         logaction(
 522             $module,
 523             $action,
 524             $log_object,
 525             "To="
 526                 . join( ',', @email )
 527                 . " Title="
 528                 . $letter->{title}
 529                 . " Content="
 530                 . $letter->{content}
 531         ) if C4::Context->preference("ClaimsLog");
 532     }
 533
 534     # If we come here, return an OK status
 535     return 1;
 536 }
 537
 538 =head2 GetPreparedLetter( %params )
 539
 540     %params hash:
 541       module => letter module, mandatory
 542       letter_code => letter code, mandatory
 543       branchcode => for letter selection, if missing default system letter taken
 544       tables => a hashref with table names as keys. Values are either:
 545         - a scalar - primary key value
 546         - an arrayref - primary key values
 547         - a hashref - full record
 548       substitute => custom substitution key/value pairs
 549       repeat => records to be substituted on consecutive lines:
 550         - an arrayref - tries to guess what needs substituting by
 551           taking remaining << >> tokensr; not recommended
 552         - a hashref token => @tables - replaces <token> << >> << >> </token>
 553           subtemplate for each @tables row; table is a hashref as above
 554       want_librarian => boolean,  if set to true triggers librarian details
 555         substitution from the userenv
 556     Return value:
 557       letter fields hashref (title & content useful)
 558
 559 =cut
 560
 561 sub GetPreparedLetter {
 562     my %params = @_;
 563
 564     my $letter = $params{letter};
 565     my $lang   = $params{lang} || 'default';
 566
 567     unless ( $letter ) {
 568         my $module      = $params{module} or croak "No module";
 569         my $letter_code = $params{letter_code} or croak "No letter_code";
 570         my $branchcode  = $params{branchcode} || '';
 571         my $mtt         = $params{message_transport_type} || 'email';
 572
 573         my $template = Koha::Notice::Templates->find_effective_template(
 574             {
 575                 module                 => $module,
 576                 code                   => $letter_code,
 577                 branchcode             => $branchcode,
 578                 message_transport_type => $mtt,
 579                 lang                   => $lang
 580             }
 581         );
 582
 583         unless ( $template ) {
 584             warn( "No $module $letter_code letter transported by " . $mtt );
 585             return;
 586         }
 587
 588         $letter = $template->unblessed;
 589         $letter->{'content-type'} = 'text/html; charset="UTF-8"' if $letter->{is_html};
 590     }
 591
 592     my $objects = $params{objects} || {};
 593     my $tables = $params{tables} || {};
 594     my $substitute = $params{substitute} || {};
 595     my $loops  = $params{loops} || {}; # loops is not supported for historical notices syntax
 596     my $repeat = $params{repeat};
 597     %$tables || %$substitute || $repeat || %$loops || %$objects
 598       or carp( "ERROR: nothing to substitute - all of 'objects', 'tables', 'loops' and 'substitute' are empty" ),
 599          return;
 600     my $want_librarian = $params{want_librarian};
 601
 602     if (%$substitute) {
 603         while ( my ($token, $val) = each %$substitute ) {
 604             $val //= q{};
 605             if ( $token eq 'items.content' ) {
 606                 $val =~ s|\n|<br/>|g if $letter->{is_html};
 607             }
 608
 609             $letter->{title} =~ s/<<$token>>/$val/g;
 610             $letter->{content} =~ s/<<$token>>/$val/g;
 611        }
 612     }
 613
 614     my $OPACBaseURL = C4::Context->preference('OPACBaseURL');
 615     $letter->{content} =~ s/<<OPACBaseURL>>/$OPACBaseURL/go;
 616
 617     if ($want_librarian) {
 618         # parsing librarian name
 619         my $userenv = C4::Context->userenv;
 620         $letter->{content} =~ s/<<LibrarianFirstname>>/$userenv->{firstname}/go;
 621         $letter->{content} =~ s/<<LibrarianSurname>>/$userenv->{surname}/go;
 622         $letter->{content} =~ s/<<LibrarianEmailaddress>>/$userenv->{emailaddress}/go;
 623     }
 624
 625     my ($repeat_no_enclosing_tags, $repeat_enclosing_tags);
 626
 627     if ($repeat) {
 628         if (ref ($repeat) eq 'ARRAY' ) {
 629             $repeat_no_enclosing_tags = $repeat;
 630         } else {
 631             $repeat_enclosing_tags = $repeat;
 632         }
 633     }
 634
 635     if ($repeat_enclosing_tags) {
 636         while ( my ($tag, $tag_tables) = each %$repeat_enclosing_tags ) {
 637             if ( $letter->{content} =~ m!<$tag>(.*)</$tag>!s ) {
 638                 my $subcontent = $1;
 639                 my @lines = map {
 640                     my %subletter = ( title => '', content => $subcontent );
 641                     _substitute_tables( \%subletter, $_ );
 642                     $subletter{content};
 643                 } @$tag_tables;
 644                 $letter->{content} =~ s!<$tag>.*</$tag>!join( "\n", @lines )!se;
 645             }
 646         }
 647     }
 648
 649     if (%$tables) {
 650         _substitute_tables( $letter, $tables );
 651     }
 652
 653     if ($repeat_no_enclosing_tags) {
 654         if ( $letter->{content} =~ m/[^\n]*<<.*>>[^\n]*/so ) {
 655             my $line = $&;
 656             my $i = 1;
 657             my @lines = map {
 658                 my $c = $line;
 659                 $c =~ s/<<count>>/$i/go;
 660                 foreach my $field ( keys %{$_} ) {
 661                     $c =~ s/(<<[^\.]+.$field>>)/$_->{$field}/;
 662                 }
 663                 $i++;
 664                 $c;
 665             } @$repeat_no_enclosing_tags;
 666
 667             my $replaceby = join( "\n", @lines );
 668             $letter->{content} =~ s/\Q$line\E/$replaceby/s;
 669         }
 670     }
 671
 672     $letter->{content} = _process_tt(
 673         {
 674             content    => $letter->{content},
 675             lang       => $lang,
 676             loops      => $loops,
 677             objects    => $objects,
 678             substitute => $substitute,
 679             tables     => $tables,
 680         }
 681     );
 682
 683     $letter->{title} = _process_tt(
 684         {
 685             content    => $letter->{title},
 686             lang       => $lang,
 687             loops      => $loops,
 688             objects    => $objects,
 689             substitute => $substitute,
 690             tables     => $tables,
 691         }
 692     );
 693
 694     $letter->{content} =~ s/<<\S*>>//go; #remove any stragglers
 695
 696     return $letter;
 697 }
 698
 699 sub _substitute_tables {
 700     my ( $letter, $tables ) = @_;
 701     while ( my ($table, $param) = each %$tables ) {
 702         next unless $param;
 703
 704         my $ref = ref $param;
 705
 706         my $values;
 707         if ($ref && $ref eq 'HASH') {
 708             $values = $param;
 709         }
 710         else {
 711             my $sth = _parseletter_sth($table);
 712             unless ($sth) {
 713                 warn "_parseletter_sth('$table') failed to return a valid sth.  No substitution will be done for that table.";
 714                 return;
 715             }
 716             $sth->execute( $ref ? @$param : $param );
 717
 718             $values = $sth->fetchrow_hashref;
 719             $sth->finish();
 720         }
 721
 722         _parseletter ( $letter, $table, $values );
 723     }
 724 }
 725
 726 sub _parseletter_sth {
 727     my $table = shift;
 728     my $sth;
 729     unless ($table) {
 730         carp "ERROR: _parseletter_sth() called without argument (table)";
 731         return;
 732     }
 733     # NOTE: we used to check whether we had a statement handle cached in
 734     #       a %handles module-level variable. This was a dumb move and
 735     #       broke things for the rest of us. prepare_cached is a better
 736     #       way to cache statement handles anyway.
 737     my $query =
 738     ($table eq 'accountlines' )    ? "SELECT * FROM $table WHERE   accountlines_id = ?"                               :
 739     ($table eq 'biblio'       )    ? "SELECT * FROM $table WHERE   biblionumber = ?"                                  :
 740     ($table eq 'biblioitems'  )    ? "SELECT * FROM $table WHERE   biblionumber = ?"                                  :
 741     ($table eq 'credits'      )    ? "SELECT * FROM accountlines WHERE   accountlines_id = ?"                         :
 742     ($table eq 'debits'       )    ? "SELECT * FROM accountlines WHERE   accountlines_id = ?"                         :
 743     ($table eq 'items'        )    ? "SELECT * FROM $table WHERE     itemnumber = ?"                                  :
 744     ($table eq 'issues'       )    ? "SELECT * FROM $table WHERE     itemnumber = ?"                                  :
 745     ($table eq 'old_issues'   )    ? "SELECT * FROM $table WHERE     issue_id = ?"  :
 746     ($table eq 'reserves'     )    ? "SELECT * FROM $table WHERE borrowernumber = ? and biblionumber = ?"             :
 747     ($table eq 'borrowers'    )    ? "SELECT * FROM $table WHERE borrowernumber = ?"                                  :
 748     ($table eq 'branches'     )    ? "SELECT * FROM $table WHERE     branchcode = ?"                                  :
 749     ($table eq 'suggestions'  )    ? "SELECT * FROM $table WHERE   suggestionid = ?"                                  :
 750     ($table eq 'aqbooksellers')    ? "SELECT * FROM $table WHERE             id = ?"                                  :
 751     ($table eq 'aqorders'     )    ? "SELECT * FROM $table WHERE    ordernumber = ?"                                  :
 752     ($table eq 'aqbasket'     )    ? "SELECT * FROM $table WHERE       basketno = ?"                                  :
 753     ($table eq 'illrequests'  )    ? "SELECT * FROM $table WHERE  illrequest_id = ?"                                  :
 754     ($table eq 'article_requests') ? "SELECT * FROM $table WHERE             id = ?"                                  :
 755     ($table eq 'borrower_modifications') ? "SELECT * FROM $table WHERE verification_token = ?" :
 756     ($table eq 'subscription') ? "SELECT * FROM $table WHERE subscriptionid = ?" :
 757     ($table eq 'serial') ? "SELECT * FROM $table WHERE serialid = ?" :
 758     ($table eq 'problem_reports') ? "SELECT * FROM $table WHERE reportid = ?" :
 759     ($table eq 'additional_contents' || $table eq 'opac_news') ? "SELECT * FROM additional_contents WHERE idnew = ?" :
 760     ($table eq 'recalls') ? "SELECT * FROM $table WHERE recall_id = ?" :
 761     undef ;
 762     unless ($query) {
 763         warn "ERROR: No _parseletter_sth query for table '$table'";
 764         return;     # nothing to get
 765     }
 766     unless ($sth = C4::Context->dbh->prepare_cached($query)) {
 767         warn "ERROR: Failed to prepare query: '$query'";
 768         return;
 769     }
 770     return $sth;    # now cache is populated for that $table
 771 }
 772
 773 =head2 _parseletter($letter, $table, $values)
 774
 775     parameters :
 776     - $letter : a hash to letter fields (title & content useful)
 777     - $table : the Koha table to parse.
 778     - $values_in : table record hashref
 779     parse all fields from a table, and replace values in title & content with the appropriate value
 780     (not exported sub, used only internally)
 781
 782 =cut
 783
 784 sub _parseletter {
 785     my ( $letter, $table, $values_in ) = @_;
 786
 787     # Work on a local copy of $values_in (passed by reference) to avoid side effects
 788     # in callers ( by changing / formatting values )
 789     my $values = $values_in ? { %$values_in } : {};
 790
 791     # FIXME Dates formatting must be done in notice's templates
 792     if ( $table eq 'borrowers' && $values->{'dateexpiry'} ){
 793         $values->{'dateexpiry'} = output_pref({ dt => dt_from_string( $values->{'dateexpiry'} ), dateonly => 1 });
 794     }
 795
 796     if ( $table eq 'reserves' && $values->{'waitingdate'} ) {
 797         $values->{'waitingdate'} = output_pref({ dt => dt_from_string( $values->{'waitingdate'} ), dateonly => 1 });
 798     }
 799
 800     if ($letter->{content} && $letter->{content} =~ /<<today>>/) {
 801         my $todaysdate = output_pref( dt_from_string() );
 802         $letter->{content} =~ s/<<today>>/$todaysdate/go;
 803     }
 804
 805     while ( my ($field, $val) = each %$values ) {
 806         $val =~ s/\p{P}$// if $val && $table=~/biblio/;
 807             #BZ 9886: Assuming that we want to eliminate ISBD punctuation here
 808             #Therefore adding the test on biblio. This includes biblioitems,
 809             #but excludes items. Removed unneeded global and lookahead.
 810
 811         if ( $table=~/^borrowers$/ && $field=~/^streettype$/ ) {
 812             my $av = Koha::AuthorisedValues->search({ category => 'ROADTYPE', authorised_value => $val });
 813             $val = $av->count ? $av->next->lib : '';
 814         }
 815
 816         # Dates replacement
 817         my $replacedby   = defined ($val) ? $val : '';
 818         if (    $replacedby
 819             and not $replacedby =~ m|9999-12-31|
 820             and $replacedby =~ m|^\d{4}-\d{2}-\d{2}( \d{2}:\d{2}:\d{2})?$| )
 821         {
 822             # If the value is XXXX-YY-ZZ[ AA:BB:CC] we assume it is a date
 823             my $dateonly = defined $1 ? 0 : 1; #$1 refers to the capture group wrapped in parentheses. In this case, that's the hours, minutes, seconds.
 824             my $re_dateonly_filter = qr{ $field( \s* \| \s* dateonly\s*)?>> }xms;
 825
 826             for my $letter_field ( qw( title content ) ) {
 827                 my $filter_string_used = q{};
 828                 if ( $letter->{ $letter_field } =~ $re_dateonly_filter ) {
 829                     # We overwrite $dateonly if the filter exists and we have a time in the datetime
 830                     $filter_string_used = $1 || q{};
 831                     $dateonly = $1 unless $dateonly;
 832                 }
 833                 my $replacedby_date = eval {
 834                     output_pref({ dt => scalar dt_from_string( $replacedby ), dateonly => $dateonly });
 835                 };
 836                 $replacedby_date //= q{};
 837
 838                 if ( $letter->{ $letter_field } ) {
 839                     $letter->{ $letter_field } =~ s/\Q<<$table.$field$filter_string_used>>\E/$replacedby_date/g;
 840                     $letter->{ $letter_field } =~ s/\Q<<$field$filter_string_used>>\E/$replacedby_date/g;
 841                 }
 842             }
 843         }
 844         # Other fields replacement
 845         else {
 846             for my $letter_field ( qw( title content ) ) {
 847                 if ( $letter->{ $letter_field } ) {
 848                     $letter->{ $letter_field }   =~ s/<<$table.$field>>/$replacedby/g;
 849                     $letter->{ $letter_field }   =~ s/<<$field>>/$replacedby/g;
 850                 }
 851             }
 852         }
 853     }
 854
 855     if ($table eq 'borrowers' && $letter->{content}) {
 856         my $patron = Koha::Patrons->find( $values->{borrowernumber} );
 857         if ( $patron ) {
 858             my $attributes = $patron->extended_attributes;
 859             my %attr;
 860             while ( my $attribute = $attributes->next ) {
 861                 my $code = $attribute->code;
 862                 my $val  = $attribute->description; # FIXME - we always display intranet description here!
 863                 $val =~ s/\p{P}(?=$)//g if $val;
 864                 next unless $val gt '';
 865                 $attr{$code} ||= [];
 866                 push @{ $attr{$code} }, $val;
 867             }
 868             while ( my ($code, $val_ar) = each %attr ) {
 869                 my $replacefield = "<<borrower-attribute:$code>>";
 870                 my $replacedby   = join ',', @$val_ar;
 871                 $letter->{content} =~ s/$replacefield/$replacedby/g;
 872             }
 873         }
 874     }
 875     return $letter;
 876 }
 877
 878 =head2 EnqueueLetter
 879
 880   my $success = EnqueueLetter( { letter => $letter,
 881         borrowernumber => '12', message_transport_type => 'email' } )
 882
 883 Places a letter in the message_queue database table, which will
 884 eventually get processed (sent) by the process_message_queue.pl
 885 cronjob when it calls SendQueuedMessages.
 886
 887 Return message_id on success
 888
 889 Parameters
 890 * letter - required; A letter hashref as returned from GetPreparedLetter
 891 * message_transport_type - required; One of the available mtts
 892 * borrowernumber - optional if 'to_address' is passed; The borrowernumber of the patron we enqueuing the notice for
 893 * to_address - optional if 'borrowernumber' is passed; The destination email address for the notice (defaults to patron->notice_email_address)
 894 * from_address - optional; The from address for the notice, defaults to patron->library->from_email_address
 895 * reply_address - optional; The reply address for the notice, defaults to patron->library->reply_to
 896
 897 =cut
 898
 899 sub EnqueueLetter {
 900     my $params = shift or return;
 901
 902     return unless exists $params->{'letter'};
 903 #   return unless exists $params->{'borrowernumber'};
 904     return unless exists $params->{'message_transport_type'};
 905
 906     my $content = $params->{letter}->{content};
 907     $content =~ s/\s+//g if(defined $content);
 908     if ( not defined $content or $content eq '' ) {
 909         Koha::Logger->get->info("Trying to add an empty message to the message queue");
 910         return;
 911     }
 912
 913     # If we have any attachments we should encode then into the body.
 914     if ( $params->{'attachments'} ) {
 915         $params->{'letter'} = _add_attachments(
 916             {   letter      => $params->{'letter'},
 917                 attachments => $params->{'attachments'},
 918             }
 919         );
 920     }
 921
 922     my $dbh       = C4::Context->dbh();
 923     my $statement = << 'ENDSQL';
 924 INSERT INTO message_queue
 925 ( letter_id, borrowernumber, subject, content, metadata, letter_code, message_transport_type, status, time_queued, to_address, from_address, reply_address, content_type, failure_code )
 926 VALUES ( ?, ?, ?, ?, ?, ?, ?, ?, CAST(NOW() AS DATETIME), ?, ?, ?, ?, ? )
 927 ENDSQL
 928
 929     my $sth    = $dbh->prepare($statement);
 930     my $result = $sth->execute(
 931         $params->{letter}->{id} || undef,         # letter.id
 932         $params->{'borrowernumber'},              # borrowernumber
 933         $params->{'letter'}->{'title'},           # subject
 934         $params->{'letter'}->{'content'},         # content
 935         $params->{'letter'}->{'metadata'} || '',  # metadata
 936         $params->{'letter'}->{'code'}     || '',  # letter_code
 937         $params->{'message_transport_type'},      # message_transport_type
 938         'pending',                                # status
 939         $params->{'to_address'},                  # to_address
 940         $params->{'from_address'},                # from_address
 941         $params->{'reply_address'},               # reply_address
 942         $params->{'letter'}->{'content-type'},    # content_type
 943         $params->{'failure_code'}        || '',   # failure_code
 944     );
 945     return $dbh->last_insert_id(undef,undef,'message_queue', undef);
 946 }
 947
 948 =head2 SendQueuedMessages ([$hashref])
 949
 950     my $sent = SendQueuedMessages({
 951         letter_code => $letter_code,
 952         borrowernumber => $who_letter_is_for,
 953         limit => 50,
 954         verbose => 1,
 955         type => 'sms',
 956     });
 957
 958 Sends all of the 'pending' items in the message queue, unless
 959 parameters are passed.
 960
 961 The letter_code, borrowernumber and limit parameters are used
 962 to build a parameter set for _get_unsent_messages, thus limiting
 963 which pending messages will be processed. They are all optional.
 964
 965 The verbose parameter can be used to generate debugging output.
 966 It is also optional.
 967
 968 Returns number of messages sent.
 969
 970 =cut
 971
 972 sub SendQueuedMessages {
 973     my $params = shift;
 974
 975     my $which_unsent_messages  = {
 976         'message_id'     => $params->{'message_id'},
 977         'limit'          => $params->{'limit'} // 0,
 978         'borrowernumber' => $params->{'borrowernumber'} // q{},
 979         'letter_code'    => $params->{'letter_code'} // q{},
 980         'message_transport_type'           => $params->{'type'} // q{},
 981     };
 982     my $unsent_messages = _get_unsent_messages( $which_unsent_messages );
 983     MESSAGE: foreach my $message ( @$unsent_messages ) {
 984         my $message_object = Koha::Notice::Messages->find( $message->{message_id} );
 985         # If this fails the database is unwritable and we won't manage to send a message that continues to be marked 'pending'
 986         $message_object->make_column_dirty('status');
 987         return unless $message_object->store;
 988
 989         # warn Data::Dumper->Dump( [ $message ], [ 'message' ] );
 990         warn sprintf( 'sending %s message to patron: %s',
 991                       $message->{'message_transport_type'},
 992                       $message->{'borrowernumber'} || 'Admin' )
 993           if $params->{'verbose'};
 994         # This is just begging for subclassing
 995         next MESSAGE if ( lc($message->{'message_transport_type'}) eq 'rss' );
 996         if ( lc( $message->{'message_transport_type'} ) eq 'email' ) {
 997             _send_message_by_email( $message, $params->{'username'}, $params->{'password'}, $params->{'method'} );
 998         }
 999         elsif ( lc( $message->{'message_transport_type'} ) eq 'sms' ) {
1000             if ( C4::Context->preference('SMSSendDriver') eq 'Email' ) {
1001                 my $patron = Koha::Patrons->find( $message->{borrowernumber} );
1002                 my $sms_provider = Koha::SMS::Providers->find( $patron->sms_provider_id );
1003                 unless ( $sms_provider ) {
1004                     warn sprintf( "Patron %s has no sms provider id set!", $message->{'borrowernumber'} ) if $params->{'verbose'};
1005                     _set_message_status( { message_id => $message->{'message_id'}, status => 'failed' } );
1006                     next MESSAGE;
1007                 }
1008                 unless ( $patron->smsalertnumber ) {
1009                     _set_message_status( { message_id => $message->{'message_id'}, status => 'failed' } );
1010                     warn sprintf( "No smsalertnumber found for patron %s!", $message->{'borrowernumber'} ) if $params->{'verbose'};
1011                     next MESSAGE;
1012                 }
1013                 $message->{to_address}  = $patron->smsalertnumber; #Sometime this is set to email - sms should always use smsalertnumber
1014                 $message->{to_address} .= '@' . $sms_provider->domain();
1015
1016                 # Check for possible from_address override
1017                 my $from_address = C4::Context->preference('EmailSMSSendDriverFromAddress');
1018                 if ($from_address && $message->{from_address} ne $from_address) {
1019                     $message->{from_address} = $from_address;
1020                     _update_message_from_address($message->{'message_id'}, $message->{from_address});
1021                 }
1022
1023                 _update_message_to_address($message->{'message_id'}, $message->{to_address});
1024                 _send_message_by_email( $message, $params->{'username'}, $params->{'password'}, $params->{'method'} );
1025             } else {
1026                 _send_message_by_sms( $message );
1027             }
1028         }
1029     }
1030     return scalar( @$unsent_messages );
1031 }
1032
1033 =head2 GetRSSMessages
1034
1035   my $message_list = GetRSSMessages( { limit => 10, borrowernumber => '14' } )
1036
1037 returns a listref of all queued RSS messages for a particular person.
1038
1039 =cut
1040
1041 sub GetRSSMessages {
1042     my $params = shift;
1043
1044     return unless $params;
1045     return unless ref $params;
1046     return unless $params->{'borrowernumber'};
1047
1048     return _get_unsent_messages( { message_transport_type => 'rss',
1049                                    limit                  => $params->{'limit'},
1050                                    borrowernumber         => $params->{'borrowernumber'}, } );
1051 }
1052
1053 =head2 GetPrintMessages
1054
1055   my $message_list = GetPrintMessages( { borrowernumber => $borrowernumber } )
1056
1057 Returns a arrayref of all queued print messages (optionally, for a particular
1058 person).
1059
1060 =cut
1061
1062 sub GetPrintMessages {
1063     my $params = shift || {};
1064
1065     return _get_unsent_messages( { message_transport_type => 'print',
1066                                    borrowernumber         => $params->{'borrowernumber'},
1067                                  } );
1068 }
1069
1070 =head2 GetQueuedMessages ([$hashref])
1071
1072   my $messages = GetQueuedMessage( { borrowernumber => '123', limit => 20 } );
1073
1074 Fetches a list of messages from the message queue optionally filtered by borrowernumber
1075 and limited to specified limit.
1076
1077 Return is an arrayref of hashes, each has represents a message in the message queue.
1078
1079 =cut
1080
1081 sub GetQueuedMessages {
1082     my $params = shift;
1083
1084     my $dbh = C4::Context->dbh();
1085     my $statement = << 'ENDSQL';
1086 SELECT message_id, borrowernumber, subject, content, message_transport_type, status, time_queued, updated_on, failure_code
1087 FROM message_queue
1088 ENDSQL
1089
1090     my @query_params;
1091     my @whereclauses;
1092     if ( exists $params->{'borrowernumber'} ) {
1093         push @whereclauses, ' borrowernumber = ? ';
1094         push @query_params, $params->{'borrowernumber'};
1095     }
1096
1097     if ( @whereclauses ) {
1098         $statement .= ' WHERE ' . join( 'AND', @whereclauses );
1099     }
1100
1101     if ( defined $params->{'limit'} ) {
1102         $statement .= ' LIMIT ? ';
1103         push @query_params, $params->{'limit'};
1104     }
1105
1106     my $sth = $dbh->prepare( $statement );
1107     my $result = $sth->execute( @query_params );
1108     return $sth->fetchall_arrayref({});
1109 }
1110
1111 =head2 GetMessageTransportTypes
1112
1113   my @mtt = GetMessageTransportTypes();
1114
1115   returns an arrayref of transport types
1116
1117 =cut
1118
1119 sub GetMessageTransportTypes {
1120     my $dbh = C4::Context->dbh();
1121     my $mtts = $dbh->selectcol_arrayref("
1122         SELECT message_transport_type
1123         FROM message_transport_types
1124         ORDER BY message_transport_type
1125     ");
1126     return $mtts;
1127 }
1128
1129 =head2 GetMessage
1130
1131     my $message = C4::Letters::Message($message_id);
1132
1133 =cut
1134
1135 sub GetMessage {
1136     my ( $message_id ) = @_;
1137     return unless $message_id;
1138     my $dbh = C4::Context->dbh;
1139     return $dbh->selectrow_hashref(q|
1140         SELECT message_id, borrowernumber, subject, content, metadata, letter_code, message_transport_type, status, time_queued, updated_on, to_address, from_address, reply_address, content_type, failure_code
1141         FROM message_queue
1142         WHERE message_id = ?
1143     |, {}, $message_id );
1144 }
1145
1146 =head2 ResendMessage
1147
1148   Attempt to resend a message which has failed previously.
1149
1150   my $has_been_resent = C4::Letters::ResendMessage($message_id);
1151
1152   Updates the message to 'pending' status so that
1153   it will be resent later on.
1154
1155   returns 1 on success, 0 on failure, undef if no message was found
1156
1157 =cut
1158
1159 sub ResendMessage {
1160     my $message_id = shift;
1161     return unless $message_id;
1162
1163     my $message = GetMessage( $message_id );
1164     return unless $message;
1165     my $rv = 0;
1166     if ( $message->{status} ne 'pending' ) {
1167         $rv = C4::Letters::_set_message_status({
1168             message_id => $message_id,
1169             status => 'pending',
1170         });
1171         $rv = $rv > 0? 1: 0;
1172         # Clear destination email address to force address update
1173         _update_message_to_address( $message_id, undef ) if $rv &&
1174             $message->{message_transport_type} eq 'email';
1175     }
1176     return $rv;
1177 }
1178
1179 =head2 _add_attachements
1180
1181   _add_attachments({ letter => $letter, attachments => $attachments });
1182
1183   named parameters:
1184   letter - the standard letter hashref
1185   attachments - listref of attachments. each attachment is a hashref of:
1186     type - the mime type, like 'text/plain'
1187     content - the actual attachment
1188     filename - the name of the attachment.
1189
1190   returns your letter object, with the content updated.
1191   This routine picks the I<content> of I<letter> and generates a MIME
1192   email, attaching the passed I<attachments> using Koha::Email. The
1193   content is replaced by the string representation of the MIME object,
1194   and the content-type is updated for later handling.
1195
1196 =cut
1197
1198 sub _add_attachments {
1199     my $params = shift;
1200
1201     my $letter = $params->{letter};
1202     my $attachments = $params->{attachments};
1203     return $letter unless @$attachments;
1204
1205     my $message = Koha::Email->new;
1206
1207     if ( $letter->{is_html} ) {
1208         $message->html_body( _wrap_html( $letter->{content}, $letter->{title} ) );
1209     }
1210     else {
1211         $message->text_body( $letter->{content} );
1212     }
1213
1214     foreach my $attachment ( @$attachments ) {
1215         $message->attach(
1216             Encode::encode( "UTF-8", $attachment->{content} ),
1217             content_type => $attachment->{type} || 'application/octet-stream',
1218             name         => $attachment->{filename},
1219             disposition  => 'attachment',
1220         );
1221     }
1222
1223     $letter->{'content-type'} = SERIALIZED_EMAIL_CONTENT_TYPE;
1224     $letter->{content} = $message->as_string;
1225
1226     return $letter;
1227
1228 }
1229
1230 =head2 _get_unsent_messages
1231
1232   This function's parameter hash reference takes the following
1233   optional named parameters:
1234    message_transport_type: method of message sending (e.g. email, sms, etc.)
1235                            Can be a single string, or an arrayref of strings
1236    borrowernumber        : who the message is to be sent
1237    letter_code           : type of message being sent (e.g. PASSWORD_RESET)
1238                            Can be a single string, or an arrayref of strings
1239    message_id            : the message_id of the message. In that case the sub will return only 1 result
1240    limit                 : maximum number of messages to send
1241
1242   This function returns an array of matching hash referenced rows from
1243   message_queue with some borrower information added.
1244
1245 =cut
1246
1247 sub _get_unsent_messages {
1248     my $params = shift;
1249
1250     my $dbh = C4::Context->dbh();
1251     my $statement = qq{
1252         SELECT mq.message_id, mq.borrowernumber, mq.subject, mq.content, mq.message_transport_type, mq.status, mq.time_queued, mq.from_address, mq.reply_address, mq.to_address, mq.content_type, b.branchcode, mq.letter_code, mq.failure_code
1253         FROM message_queue mq
1254         LEFT JOIN borrowers b ON b.borrowernumber = mq.borrowernumber
1255         WHERE status = ?
1256     };
1257
1258     my @query_params = ('pending');
1259     if ( ref $params ) {
1260         if ( $params->{'borrowernumber'} ) {
1261             $statement .= ' AND mq.borrowernumber = ? ';
1262             push @query_params, $params->{'borrowernumber'};
1263         }
1264         if ( $params->{'letter_code'} ) {
1265             my @letter_codes = ref $params->{'letter_code'} eq "ARRAY" ? @{$params->{'letter_code'}} : $params->{'letter_code'};
1266             if ( @letter_codes ) {
1267                 my $q = join( ",", ("?") x @letter_codes );
1268                 $statement .= " AND mq.letter_code IN ( $q ) ";
1269                 push @query_params, @letter_codes;
1270             }
1271         }
1272         if ( $params->{'message_transport_type'} ) {
1273             my @types = ref $params->{'message_transport_type'} eq "ARRAY" ? @{$params->{'message_transport_type'}} : $params->{'message_transport_type'};
1274             if ( @types ) {
1275                 my $q = join( ",", ("?") x @types );
1276                 $statement .= " AND message_transport_type IN ( $q ) ";
1277                 push @query_params, @types;
1278             }
1279         }
1280         if ( $params->{message_id} ) {
1281             $statement .= ' AND message_id = ?';
1282             push @query_params, $params->{message_id};
1283         }
1284         if ( $params->{'limit'} ) {
1285             $statement .= ' limit ? ';
1286             push @query_params, $params->{'limit'};
1287         }
1288     }
1289
1290     my $sth = $dbh->prepare( $statement );
1291     my $result = $sth->execute( @query_params );
1292     return $sth->fetchall_arrayref({});
1293 }
1294
1295 sub _send_message_by_email {
1296     my $message = shift or return;
1297     my ($username, $password, $method) = @_;
1298
1299     my $patron = Koha::Patrons->find( $message->{borrowernumber} );
1300     my $to_address = $message->{'to_address'};
1301     unless ($to_address) {
1302         unless ($patron) {
1303             warn "FAIL: No 'to_address' and INVALID borrowernumber ($message->{borrowernumber})";
1304             _set_message_status(
1305                 {
1306                     message_id   => $message->{'message_id'},
1307                     status       => 'failed',
1308                     failure_code => 'INVALID_BORNUMBER'
1309                 }
1310             );
1311             return;
1312         }
1313         $to_address = $patron->notice_email_address;
1314         unless ($to_address) {
1315             # warn "FAIL: No 'to_address' and no email for " . ($member->{surname} ||'') . ", borrowernumber ($message->{borrowernumber})";
1316             # warning too verbose for this more common case?
1317             _set_message_status(
1318                 {
1319                     message_id   => $message->{'message_id'},
1320                     status       => 'failed',
1321                     failure_code => 'NO_EMAIL'
1322                 }
1323             );
1324             return;
1325         }
1326     }
1327
1328     my $subject = $message->{'subject'};
1329
1330     my $content = $message->{'content'};
1331     my $content_type = $message->{'content_type'} || 'text/plain; charset="UTF-8"';
1332     my $is_html = $content_type =~ m/html/io;
1333
1334     my $branch_email = undef;
1335     my $branch_replyto = undef;
1336     my $branch_returnpath = undef;
1337     my $library;
1338
1339     if ($patron) {
1340         $library           = $patron->library;
1341         $branch_email      = $library->from_email_address;
1342         $branch_replyto    = $library->branchreplyto;
1343         $branch_returnpath = $library->branchreturnpath;
1344     }
1345
1346     # NOTE: Patron may not be defined above so branch_email may be undefined still
1347     # so we need to fallback to KohaAdminEmailAddress as a last resort.
1348     my $from_address =
1349          $message->{'from_address'}
1350       || $branch_email
1351       || C4::Context->preference('KohaAdminEmailAddress');
1352     if( !$from_address ) {
1353         _set_message_status(
1354             {
1355                 message_id   => $message->{'message_id'},
1356                 status       => 'failed',
1357                 failure_code => 'NO_FROM',
1358             }
1359         );
1360         return;
1361     };
1362     my $email;
1363
1364     try {
1365
1366         my $params = {
1367             to => $to_address,
1368             (
1369                 C4::Context->preference('NoticeBcc')
1370                 ? ( bcc => C4::Context->preference('NoticeBcc') )
1371                 : ()
1372             ),
1373             from     => $from_address,
1374             reply_to => $message->{'reply_address'} || $branch_replyto,
1375             sender   => $branch_returnpath,
1376             subject  => "" . $message->{subject}
1377         };
1378
1379         if ( $message->{'content_type'} && $message->{'content_type'} eq SERIALIZED_EMAIL_CONTENT_TYPE ) {
1380
1381             # The message has been previously composed as a valid MIME object
1382             # and serialized as a string on the DB
1383             $email = Koha::Email->new_from_string($content);
1384             $email->create($params);
1385         } else {
1386             $email = Koha::Email->create($params);
1387             if ($is_html) {
1388                 $email->html_body( _wrap_html( $content, $subject ) );
1389             } else {
1390                 $email->text_body($content);
1391             }
1392         }
1393     }
1394     catch {
1395         if ( ref($_) eq 'Koha::Exceptions::BadParameter' ) {
1396             _set_message_status(
1397                 {
1398                     message_id   => $message->{'message_id'},
1399                     status       => 'failed',
1400                     failure_code => "INVALID_EMAIL:".$_->parameter
1401                 }
1402             );
1403         } else {
1404             _set_message_status(
1405                 {
1406                     message_id   => $message->{'message_id'},
1407                     status       => 'failed',
1408                     failure_code => 'UNKNOWN_ERROR'
1409                 }
1410             );
1411         }
1412         return 0;
1413     };
1414     return unless $email;
1415
1416     my $smtp_server;
1417     if ( $library ) {
1418         $smtp_server = $library->smtp_server;
1419     }
1420     else {
1421         $smtp_server = Koha::SMTP::Servers->get_default;
1422     }
1423
1424     if ( $username ) {
1425         $smtp_server->set(
1426             {
1427                 sasl_username => $username,
1428                 sasl_password => $password,
1429             }
1430         );
1431     }
1432
1433 # if initial message address was empty, coming here means that a to address was found and
1434 # queue should be updated; same if to address was overriden by Koha::Email->create
1435     _update_message_to_address( $message->{'message_id'}, $email->email->header('To') )
1436       if !$message->{to_address}
1437       || $message->{to_address} ne $email->email->header('To');
1438
1439     try {
1440         $email->send_or_die({ transport => $smtp_server->transport });
1441
1442         _set_message_status(
1443             {
1444                 message_id => $message->{'message_id'},
1445                 status     => 'sent',
1446                 failure_code => ''
1447             }
1448         );
1449         return 1;
1450     }
1451     catch {
1452         _set_message_status(
1453             {
1454                 message_id => $message->{'message_id'},
1455                 status     => 'failed',
1456                 failure_code => 'SENDMAIL'
1457             }
1458         );
1459         carp "$_";
1460         carp "$Mail::Sendmail::error";
1461         return;
1462     };
1463 }
1464
1465 sub _wrap_html {
1466     my ($content, $title) = @_;
1467
1468     my $css = C4::Context->preference("NoticeCSS") || '';
1469     $css = qq{<link rel="stylesheet" type="text/css" href="$css">} if $css;
1470     return <<EOS;
1471 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1472     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1473 <html lang="en" xml:lang="en" xmlns="http://www.w3.org/1999/xhtml">
1474 <head>
1475 <title>$title</title>
1476 <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1477 $css
1478 </head>
1479 <body>
1480 $content
1481 </body>
1482 </html>
1483 EOS
1484 }
1485
1486 sub _is_duplicate {
1487     my ( $message ) = @_;
1488     my $dbh = C4::Context->dbh;
1489     my $count = $dbh->selectrow_array(q|
1490         SELECT COUNT(*)
1491         FROM message_queue
1492         WHERE message_transport_type = ?
1493         AND borrowernumber = ?
1494         AND letter_code = ?
1495         AND CAST(updated_on AS date) = CAST(NOW() AS date)
1496         AND status="sent"
1497         AND content = ?
1498     |, {}, $message->{message_transport_type}, $message->{borrowernumber}, $message->{letter_code}, $message->{content} );
1499     return $count;
1500 }
1501
1502 sub _send_message_by_sms {
1503     my $message = shift or return;
1504     my $patron = Koha::Patrons->find( $message->{borrowernumber} );
1505     _update_message_to_address($message->{message_id}, $patron->smsalertnumber) if $patron;
1506
1507     unless ( $patron and $patron->smsalertnumber ) {
1508         _set_message_status( { message_id => $message->{'message_id'},
1509                                status     => 'failed',
1510                                failure_code => 'MISSING_SMS' } );
1511         return;
1512     }
1513
1514     if ( _is_duplicate( $message ) ) {
1515         _set_message_status(
1516             {
1517                 message_id   => $message->{'message_id'},
1518                 status       => 'failed',
1519                 failure_code => 'DUPLICATE_MESSAGE'
1520             }
1521         );
1522         return;
1523     }
1524
1525     my $success = C4::SMS->send_sms(
1526         {
1527             destination => $patron->smsalertnumber,
1528             message     => $message->{'content'},
1529         }
1530     );
1531
1532     if ($success) {
1533         _set_message_status(
1534             {
1535                 message_id   => $message->{'message_id'},
1536                 status       => 'sent',
1537                 failure_code => ''
1538             }
1539         );
1540     }
1541     else {
1542         _set_message_status(
1543             {
1544                 message_id   => $message->{'message_id'},
1545                 status       => 'failed',
1546                 failure_code => 'NO_NOTES'
1547             }
1548         );
1549     }
1550
1551     return $success;
1552 }
1553
1554 sub _update_message_to_address {
1555     my ($id, $to)= @_;
1556     my $dbh = C4::Context->dbh();
1557     $dbh->do('UPDATE message_queue SET to_address=? WHERE message_id=?',undef,($to,$id));
1558 }
1559
1560 sub _update_message_from_address {
1561     my ($message_id, $from_address) = @_;
1562     my $dbh = C4::Context->dbh();
1563     $dbh->do('UPDATE message_queue SET from_address = ? WHERE message_id = ?', undef, ($from_address, $message_id));
1564 }
1565
1566 sub _set_message_status {
1567     my $params = shift or return;
1568
1569     foreach my $required_parameter ( qw( message_id status ) ) {
1570         return unless exists $params->{ $required_parameter };
1571     }
1572
1573     my $dbh = C4::Context->dbh();
1574     my $statement = 'UPDATE message_queue SET status= ?, failure_code= ? WHERE message_id = ?';
1575     my $sth = $dbh->prepare( $statement );
1576     my $result = $sth->execute( $params->{'status'},
1577                                 $params->{'failure_code'} || '',
1578                                 $params->{'message_id'} );
1579     return $result;
1580 }
1581
1582 sub _process_tt {
1583     my ( $params ) = @_;
1584
1585     my $content    = $params->{content};
1586     my $tables     = $params->{tables};
1587     my $loops      = $params->{loops};
1588     my $objects    = $params->{objects} || {};
1589     my $substitute = $params->{substitute} || {};
1590     my $lang = defined($params->{lang}) && $params->{lang} ne 'default' ? $params->{lang} : 'en';
1591     my ($theme, $availablethemes);
1592
1593     my $htdocs = C4::Context->config('intrahtdocs');
1594     ($theme, $lang, $availablethemes)= C4::Templates::availablethemes( $htdocs, 'about.tt', 'intranet', $lang);
1595     my @includes;
1596     foreach (@$availablethemes) {
1597         push @includes, "$htdocs/$_/$lang/includes";
1598         push @includes, "$htdocs/$_/en/includes" unless $lang eq 'en';
1599     }
1600
1601     my $use_template_cache = C4::Context->config('template_cache_dir') && defined $ENV{GATEWAY_INTERFACE};
1602     my $template           = Template->new(
1603         {
1604             EVAL_PERL    => 1,
1605             ABSOLUTE     => 1,
1606             PLUGIN_BASE  => 'Koha::Template::Plugin',
1607             COMPILE_EXT  => $use_template_cache ? '.ttc' : '',
1608             COMPILE_DIR  => $use_template_cache ? C4::Context->config('template_cache_dir') : '',
1609             INCLUDE_PATH => \@includes,
1610             FILTERS      => {},
1611             ENCODING     => 'UTF-8',
1612         }
1613     ) or die Template->error();
1614
1615     my $tt_params = { %{ _get_tt_params( $tables ) }, %{ _get_tt_params( $loops, 'is_a_loop' ) }, %$substitute, %$objects };
1616
1617     $content = add_tt_filters( $content );
1618     $content = qq|[% USE KohaDates %][% USE Remove_MARC_punctuation %]$content|;
1619
1620     my $output;
1621     my $schema = Koha::Database->new->schema;
1622     $schema->txn_begin;
1623     $template->process( \$content, $tt_params, \$output ) || croak "ERROR PROCESSING TEMPLATE: " . $template->error();
1624     $schema->txn_rollback;
1625
1626     return $output;
1627 }
1628
1629 sub _get_tt_params {
1630     my ($tables, $is_a_loop) = @_;
1631
1632     my $params;
1633     $is_a_loop ||= 0;
1634
1635     my $config = {
1636         article_requests => {
1637             module   => 'Koha::ArticleRequests',
1638             singular => 'article_request',
1639             plural   => 'article_requests',
1640             pk       => 'id',
1641         },
1642         aqbasket => {
1643             module   => 'Koha::Acquisition::Baskets',
1644             singular => 'basket',
1645             plural   => 'baskets',
1646             pk       => 'basketno',
1647         },
1648         biblio => {
1649             module   => 'Koha::Biblios',
1650             singular => 'biblio',
1651             plural   => 'biblios',
1652             pk       => 'biblionumber',
1653         },
1654         biblioitems => {
1655             module   => 'Koha::Biblioitems',
1656             singular => 'biblioitem',
1657             plural   => 'biblioitems',
1658             pk       => 'biblioitemnumber',
1659         },
1660         borrowers => {
1661             module   => 'Koha::Patrons',
1662             singular => 'borrower',
1663             plural   => 'borrowers',
1664             pk       => 'borrowernumber',
1665         },
1666         branches => {
1667             module   => 'Koha::Libraries',
1668             singular => 'branch',
1669             plural   => 'branches',
1670             pk       => 'branchcode',
1671         },
1672         credits => {
1673             module => 'Koha::Account::Lines',
1674             singular => 'credit',
1675             plural => 'credits',
1676             pk => 'accountlines_id',
1677         },
1678         debits => {
1679             module => 'Koha::Account::Lines',
1680             singular => 'debit',
1681             plural => 'debits',
1682             pk => 'accountlines_id',
1683         },
1684         items => {
1685             module   => 'Koha::Items',
1686             singular => 'item',
1687             plural   => 'items',
1688             pk       => 'itemnumber',
1689         },
1690         additional_contents => {
1691             module   => 'Koha::AdditionalContents',
1692             singular => 'additional_content',
1693             plural   => 'additional_contents',
1694             pk       => 'idnew',
1695         },
1696         opac_news => {
1697             module   => 'Koha::AdditionalContents',
1698             singular => 'news',
1699             plural   => 'news',
1700             pk       => 'idnew',
1701         },
1702         aqorders => {
1703             module   => 'Koha::Acquisition::Orders',
1704             singular => 'order',
1705             plural   => 'orders',
1706             pk       => 'ordernumber',
1707         },
1708         reserves => {
1709             module   => 'Koha::Holds',
1710             singular => 'hold',
1711             plural   => 'holds',
1712             pk       => 'reserve_id',
1713         },
1714         serial => {
1715             module   => 'Koha::Serials',
1716             singular => 'serial',
1717             plural   => 'serials',
1718             pk       => 'serialid',
1719         },
1720         subscription => {
1721             module   => 'Koha::Subscriptions',
1722             singular => 'subscription',
1723             plural   => 'subscriptions',
1724             pk       => 'subscriptionid',
1725         },
1726         suggestions => {
1727             module   => 'Koha::Suggestions',
1728             singular => 'suggestion',
1729             plural   => 'suggestions',
1730             pk       => 'suggestionid',
1731         },
1732         issues => {
1733             module   => 'Koha::Checkouts',
1734             singular => 'checkout',
1735             plural   => 'checkouts',
1736             fk       => 'itemnumber',
1737         },
1738         old_issues => {
1739             module   => 'Koha::Old::Checkouts',
1740             singular => 'old_checkout',
1741             plural   => 'old_checkouts',
1742             pk       => 'issue_id',
1743         },
1744         overdues => {
1745             module   => 'Koha::Checkouts',
1746             singular => 'overdue',
1747             plural   => 'overdues',
1748             fk       => 'itemnumber',
1749         },
1750         borrower_modifications => {
1751             module   => 'Koha::Patron::Modifications',
1752             singular => 'patron_modification',
1753             plural   => 'patron_modifications',
1754             fk       => 'verification_token',
1755         },
1756         illrequests => {
1757             module   => 'Koha::Illrequests',
1758             singular => 'illrequest',
1759             plural   => 'illrequests',
1760             pk       => 'illrequest_id'
1761         }
1762     };
1763
1764     foreach my $table ( keys %$tables ) {
1765         next unless $config->{$table};
1766
1767         my $ref = ref( $tables->{$table} ) || q{};
1768         my $module = $config->{$table}->{module};
1769
1770         if ( can_load( modules => { $module => undef } ) ) {
1771             my $pk = $config->{$table}->{pk};
1772             my $fk = $config->{$table}->{fk};
1773
1774             if ( $is_a_loop ) {
1775                 my $values = $tables->{$table} || [];
1776                 unless ( ref( $values ) eq 'ARRAY' ) {
1777                     croak "ERROR processing table $table. Wrong API call.";
1778                 }
1779                 my $key = $pk ? $pk : $fk;
1780                 # $key does not come from user input
1781                 my $objects = $module->search(
1782                     { $key => $values },
1783                     {
1784                             # We want to retrieve the data in the same order
1785                             # FIXME MySQLism
1786                             # field is a MySQLism, but they are no other way to do it
1787                             # To be generic we could do it in perl, but we will need to fetch
1788                             # all the data then order them
1789                         @$values ? ( order_by => \[ "field($key, " . join( ', ', @$values ) . ")" ] ) : ()
1790                     }
1791                 );
1792                 $params->{ $config->{$table}->{plural} } = $objects;
1793             }
1794             elsif ( $ref eq q{} || $ref eq 'HASH' ) {
1795                 my $id = ref $ref eq 'HASH' ? $tables->{$table}->{$pk} : $tables->{$table};
1796                 my $object;
1797                 if ( $fk ) { # Using a foreign key for lookup
1798                     if ( ref( $fk ) eq 'ARRAY' ) { # Foreign key is multi-column
1799                         my $search;
1800                         foreach my $key ( @$fk ) {
1801                             $search->{$key} = $id->{$key};
1802                         }
1803                         $object = $module->search( $search )->last();
1804                     } else { # Foreign key is single column
1805                         $object = $module->search( { $fk => $id } )->last();
1806                     }
1807                 } else { # using the table's primary key for lookup
1808                     $object = $module->find($id);
1809                 }
1810                 $params->{ $config->{$table}->{singular} } = $object;
1811             }
1812             else {    # $ref eq 'ARRAY'
1813                 my $object;
1814                 if ( @{ $tables->{$table} } == 1 ) {    # Param is a single key
1815                     $object = $module->search( { $pk => $tables->{$table} } )->last();
1816                 }
1817                 else {                                  # Params are mutliple foreign keys
1818                     croak "Multiple foreign keys (table $table) should be passed using an hashref";
1819                 }
1820                 $params->{ $config->{$table}->{singular} } = $object;
1821             }
1822         }
1823         else {
1824             croak "ERROR LOADING MODULE $module: $Module::Load::Conditional::ERROR";
1825         }
1826     }
1827
1828     $params->{today} = output_pref({ dt => dt_from_string, dateformat => 'iso' });
1829
1830     return $params;
1831 }
1832
1833 =head3 add_tt_filters
1834
1835 $content = add_tt_filters( $content );
1836
1837 Add TT filters to some specific fields if needed.
1838
1839 For now we only add the Remove_MARC_punctuation TT filter to biblio and biblioitem fields
1840
1841 =cut
1842
1843 sub add_tt_filters {
1844     my ( $content ) = @_;
1845     $content =~ s|\[%\s*biblio\.(.*?)\s*%\]|[% biblio.$1 \| \$Remove_MARC_punctuation %]|gxms;
1846     $content =~ s|\[%\s*biblioitem\.(.*?)\s*%\]|[% biblioitem.$1 \| \$Remove_MARC_punctuation %]|gxms;
1847     return $content;
1848 }
1849
1850 =head2 get_item_content
1851
1852     my $item = Koha::Items->find(...)->unblessed;
1853     my @item_content_fields = qw( date_due title barcode author itemnumber );
1854     my $item_content = C4::Letters::get_item_content({
1855                              item => $item,
1856                              item_content_fields => \@item_content_fields
1857                        });
1858
1859 This function generates a tab-separated list of values for the passed item. Dates
1860 are formatted following the current setup.
1861
1862 =cut
1863
1864 sub get_item_content {
1865     my ( $params ) = @_;
1866     my $item = $params->{item};
1867     my $dateonly = $params->{dateonly} || 0;
1868     my $item_content_fields = $params->{item_content_fields} || [];
1869
1870     return unless $item;
1871
1872     my @item_info = map {
1873         $_ =~ /^date|date$/
1874           ? eval {
1875             output_pref(
1876                 { dt => dt_from_string( $item->{$_} ), dateonly => $dateonly } );
1877           }
1878           : $item->{$_}
1879           || ''
1880     } @$item_content_fields;
1881     return join( "\t", @item_info ) . "\n";
1882 }
1883
1884 1;
1885 __END__