C4/Record.pm

   1 package C4::Record;
   2 #
   3 # Copyright 2006 (C) LibLime
   4 # Parts copyright 2010 BibLibre
   5 # Part copyright 2015 Universidad de El Salvador
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23
  24 # please specify in which methods a given module is used
  25 use MARC::Record; # marc2marcxml, marcxml2marc, changeEncoding
  26 use MARC::File::XML; # marc2marcxml, marcxml2marc, changeEncoding
  27 use Biblio::EndnoteStyle;
  28 use Unicode::Normalize qw( NFC ); # _entity_encode
  29 use C4::Biblio qw( GetFrameworkCode GetMarcBiblio );
  30 use C4::Koha; #marc2csv
  31 use C4::XSLT;
  32 use YAML::XS; #marcrecords2csv
  33 use Encode;
  34 use Template;
  35 use Text::CSV::Encoded; #marc2csv
  36 use Koha::Items;
  37 use Koha::SimpleMARC qw( read_field );
  38 use Koha::XSLT::Base;
  39 use Koha::CsvProfiles;
  40 use Koha::AuthorisedValues;
  41 use Carp qw( carp croak );
  42
  43 use vars qw(@ISA @EXPORT);
  44
  45
  46 @ISA = qw(Exporter);
  47
  48 # only export API methods
  49
  50 @EXPORT = qw(
  51   marc2endnote
  52   marc2marc
  53   marc2marcxml
  54   marcxml2marc
  55   marc2dcxml
  56   marc2modsxml
  57   marc2madsxml
  58   marc2bibtex
  59   marc2csv
  60   marcrecord2csv
  61   changeEncoding
  62 );
  63
  64 =head1 NAME
  65
  66 C4::Record - MARC, MARCXML, DC, MODS, XML, etc. Record Management Functions and API
  67
  68 =head1 SYNOPSIS
  69
  70 New in Koha 3.x. This module handles all record-related management functions.
  71
  72 =head1 API (EXPORTED FUNCTIONS)
  73
  74 =head2 marc2marc - Convert from one flavour of ISO-2709 to another
  75
  76   my ($error,$newmarc) = marc2marc($marc,$to_flavour,$from_flavour,$encoding);
  77
  78 Returns an ISO-2709 scalar
  79
  80 =cut
  81
  82 sub marc2marc {
  83         my ($marc,$to_flavour,$from_flavour,$encoding) = @_;
  84         my $error;
  85     if ($to_flavour && $to_flavour =~ m/marcstd/) {
  86         my $marc_record_obj;
  87         if ($marc =~ /^MARC::Record/) { # it's already a MARC::Record object
  88             $marc_record_obj = $marc;
  89         } else { # it's not a MARC::Record object, make it one
  90             eval { $marc_record_obj = MARC::Record->new_from_usmarc($marc) }; # handle exceptions
  91
  92 # conversion to MARC::Record object failed, populate $error
  93                 if ($@) { $error .="\nCreation of MARC::Record object failed: ".$MARC::File::ERROR };
  94         }
  95         unless ($error) {
  96             my @privatefields;
  97             foreach my $field ($marc_record_obj->fields()) {
  98                 if ($field->tag() =~ m/9/ && ($field->tag() != '490' || C4::Context->preference("marcflavour") eq 'UNIMARC')) {
  99                     push @privatefields, $field;
 100                 } elsif (! ($field->is_control_field())) {
 101                     $field->delete_subfield(code => '9') if ($field->subfield('9'));
 102                 }
 103             }
 104             $marc_record_obj->delete_field($_) for @privatefields;
 105             $marc = $marc_record_obj->as_usmarc();
 106         }
 107     } else {
 108         $error = "Feature not yet implemented\n";
 109     }
 110         return ($error,$marc);
 111 }
 112
 113 =head2 marc2marcxml - Convert from ISO-2709 to MARCXML
 114
 115   my ($error,$marcxml) = marc2marcxml($marc,$encoding,$flavour);
 116
 117 Returns a MARCXML scalar
 118
 119 C<$marc> - an ISO-2709 scalar or MARC::Record object
 120
 121 C<$encoding> - UTF-8 or MARC-8 [UTF-8]
 122
 123 C<$flavour> - MARC21 or UNIMARC
 124
 125 C<$dont_entity_encode> - a flag that instructs marc2marcxml not to entity encode the xml before returning (optional)
 126
 127 =cut
 128
 129 sub marc2marcxml {
 130         my ($marc,$encoding,$flavour,$dont_entity_encode) = @_;
 131         my $error; # the error string
 132         my $marcxml; # the final MARCXML scalar
 133
 134         # test if it's already a MARC::Record object, if not, make it one
 135         my $marc_record_obj;
 136         if ($marc =~ /^MARC::Record/) { # it's already a MARC::Record object
 137                 $marc_record_obj = $marc;
 138         } else { # it's not a MARC::Record object, make it one
 139                 eval { $marc_record_obj = MARC::Record->new_from_usmarc($marc) }; # handle exceptions
 140
 141                 # conversion to MARC::Record object failed, populate $error
 142                 if ($@) { $error .="\nCreation of MARC::Record object failed: ".$MARC::File::ERROR };
 143         }
 144         # only proceed if no errors so far
 145         unless ($error) {
 146
 147                 # check the record for warnings
 148                 my @warnings = $marc_record_obj->warnings();
 149                 if (@warnings) {
 150                         warn "\nWarnings encountered while processing ISO-2709 record with title \"".$marc_record_obj->title()."\":\n";
 151                         foreach my $warn (@warnings) { warn "\t".$warn };
 152                 }
 153                 unless($encoding) {$encoding = "UTF-8"}; # set default encoding
 154                 unless($flavour) {$flavour = C4::Context->preference("marcflavour")}; # set default MARC flavour
 155
 156                 # attempt to convert the record to MARCXML
 157                 eval { $marcxml = $marc_record_obj->as_xml_record($flavour) }; #handle exceptions
 158
 159                 # record creation failed, populate $error
 160                 if ($@) {
 161                         $error .= "Creation of MARCXML failed:".$MARC::File::ERROR;
 162                         $error .= "Additional information:\n";
 163                         my @warnings = $@->warnings();
 164                         foreach my $warn (@warnings) { $error.=$warn."\n" };
 165
 166                 # record creation was successful
 167         } else {
 168
 169                         # check the record for warning flags again (warnings() will be cleared already if there was an error, see above block
 170                         @warnings = $marc_record_obj->warnings();
 171                         if (@warnings) {
 172                                 warn "\nWarnings encountered while processing ISO-2709 record with title \"".$marc_record_obj->title()."\":\n";
 173                                 foreach my $warn (@warnings) { warn "\t".$warn };
 174                         }
 175                 }
 176
 177                 # only proceed if no errors so far
 178                 unless ($error) {
 179
 180                         # entity encode the XML unless instructed not to
 181                 unless ($dont_entity_encode) {
 182                         my ($marcxml_entity_encoded) = _entity_encode($marcxml);
 183                         $marcxml = $marcxml_entity_encoded;
 184                 }
 185                 }
 186         }
 187         # return result to calling program
 188         return ($error,$marcxml);
 189 }
 190
 191 =head2 marcxml2marc - Convert from MARCXML to ISO-2709
 192
 193   my ($error,$marc) = marcxml2marc($marcxml,$encoding,$flavour);
 194
 195 Returns an ISO-2709 scalar
 196
 197 C<$marcxml> - a MARCXML record
 198
 199 C<$encoding> - UTF-8 or MARC-8 [UTF-8]
 200
 201 C<$flavour> - MARC21 or UNIMARC
 202
 203 =cut
 204
 205 sub marcxml2marc {
 206     my ($marcxml,$encoding,$flavour) = @_;
 207         my $error; # the error string
 208         my $marc; # the final ISO-2709 scalar
 209         unless($encoding) {$encoding = "UTF-8"}; # set the default encoding
 210         unless($flavour) {$flavour = C4::Context->preference("marcflavour")}; # set the default MARC flavour
 211
 212         # attempt to do the conversion
 213         eval { $marc = MARC::Record->new_from_xml($marcxml,$encoding,$flavour) }; # handle exceptions
 214
 215         # record creation failed, populate $error
 216         if ($@) {$error .="\nCreation of MARCXML Record failed: ".$@;
 217                 $error.=$MARC::File::ERROR if ($MARC::File::ERROR);
 218                 };
 219         # return result to calling program
 220         return ($error,$marc);
 221 }
 222
 223 =head2 marc2dcxml - Convert from ISO-2709 to Dublin Core
 224
 225     my dcxml = marc2dcxml ($marc, $xml, $biblionumber, $format);
 226
 227 EXAMPLE
 228
 229     my dcxml = marc2dcxml (undef, undef, 1, "oaidc");
 230
 231 Convert MARC or MARCXML to Dublin Core metadata (XSLT Transformation),
 232 optionally can get an XML directly from biblio_metadata
 233 without item information. This method take into consideration the syspref
 234 'marcflavour' (UNIMARC, MARC21 and NORMARC).
 235 Return an XML file with the format defined in C<$format>
 236
 237 C<$marc> - an ISO-2709 scalar or MARC::Record object
 238
 239 C<$xml> - a MARCXML file
 240
 241 C<$biblionumber> - biblionumber for database access
 242
 243 C<$format> - accept three type of DC formats (oaidc, srwdc, and rdfdc )
 244
 245 =cut
 246
 247 sub marc2dcxml {
 248     my ( $marc, $xml, $biblionumber, $format ) = @_;
 249
 250     # global variables
 251     my ( $marcxml, $record, $output );
 252
 253     # set the default path for intranet xslts
 254     # differents xslts to process (OAIDC, SRWDC and RDFDC)
 255     my $xsl = C4::Context->config('intrahtdocs') . '/prog/en/xslt/' .
 256               C4::Context->preference('marcflavour') . 'slim2' . uc ( $format ) . '.xsl';
 257
 258     if ( defined $marc ) {
 259         # no need to catch errors or warnings marc2marcxml do it instead
 260         $marcxml = C4::Record::marc2marcxml( $marc );
 261     } elsif ( not defined $xml and defined $biblionumber ) {
 262         # get MARCXML biblio directly without item information
 263         $marcxml = C4::Biblio::GetXmlBiblio( $biblionumber );
 264     } else {
 265         $marcxml = $xml;
 266     }
 267
 268     # only proceed if MARC21 or UNIMARC; else clause is executed if marcflavour set it to NORMARC
 269     # generate MARC::Record object to see if not a marcxml record
 270     unless ( C4::Context->preference('marcflavour') eq 'NORMARC' ) {
 271         eval { $record = MARC::Record->new_from_xml(
 272                          $marcxml,
 273                          'UTF-8',
 274                          C4::Context->preference('marcflavour')
 275                );
 276         };
 277     } else {
 278         eval { $record = MARC::Record->new_from_xml(
 279                          $marcxml,
 280                         'UTF-8',
 281                         'MARC21'
 282                );
 283         };
 284     }
 285
 286     # conversion to MARC::Record object failed
 287     if ( $@ ) {
 288         croak "Creation of MARC::Record object failed.";
 289     } elsif ( $record->warnings() ) {
 290         carp "Warnings encountered while processing ISO-2709 record.\n";
 291         my @warnings = $record->warnings();
 292         foreach my $warn (@warnings) {
 293             carp "\t". $warn;
 294         };
 295     } elsif ( $record =~ /^MARC::Record/ ) { # if OK makes xslt transformation
 296         my $xslt_engine = Koha::XSLT::Base->new;
 297         if ( $format =~ /^(dc|oaidc|srwdc|rdfdc)$/i ) {
 298             $output = $xslt_engine->transform( $marcxml, $xsl );
 299         } else {
 300             croak "The format argument ($format) not accepted.\n" .
 301                   "Please pass a valid format (oaidc, srwdc, or rdfdc)\n";
 302         }
 303         my $err = $xslt_engine->err; # error code
 304         if ( $err ) {
 305             croak "Error $err while processing\n";
 306         } else {
 307             return $output;
 308         }
 309     }
 310 }
 311
 312 =head2 marc2modsxml - Convert from ISO-2709 to MODS
 313
 314   my $modsxml = marc2modsxml($marc);
 315
 316 Returns a MODS scalar
 317
 318 =cut
 319
 320 sub marc2modsxml {
 321     my ($marc) = @_;
 322     return _transformWithStylesheet($marc, "/prog/en/xslt/MARC21slim2MODS3-1.xsl");
 323 }
 324
 325 =head2 marc2madsxml - Convert from ISO-2709 to MADS
 326
 327   my $madsxml = marc2madsxml($marc);
 328
 329 Returns a MADS scalar
 330
 331 =cut
 332
 333 sub marc2madsxml {
 334     my ($marc) = @_;
 335     return _transformWithStylesheet($marc, "/prog/en/xslt/MARC21slim2MADS.xsl");
 336 }
 337
 338 =head2 _transformWithStylesheet - Transform a MARC record with a stylesheet
 339
 340     my $xml = _transformWithStylesheet($marc, $stylesheet)
 341
 342 Returns the XML scalar result of the transformation. $stylesheet should
 343 contain the path to a stylesheet under intrahtdocs.
 344
 345 =cut
 346
 347 sub _transformWithStylesheet {
 348     my ($marc, $stylesheet) = @_;
 349     # grab the XML, run it through our stylesheet, push it out to the browser
 350     my $xmlrecord = marc2marcxml($marc);
 351     my $xslfile = C4::Context->config('intrahtdocs') . $stylesheet;
 352     return C4::XSLT::engine->transform($xmlrecord, $xslfile);
 353 }
 354
 355 sub marc2endnote {
 356     my ($marc) = @_;
 357         my $marc_rec_obj =  MARC::Record->new_from_usmarc($marc);
 358     my ( $abstract, $f260a, $f710a );
 359     my $f260 = $marc_rec_obj->field('260');
 360     if ($f260) {
 361         $f260a = $f260->subfield('a') if $f260;
 362     }
 363     my $f710 = $marc_rec_obj->field('710');
 364     if ($f710) {
 365         $f710a = $f710->subfield('a');
 366     }
 367     my $f500 = $marc_rec_obj->field('500');
 368     if ($f500) {
 369         $abstract = $f500->subfield('a');
 370     }
 371     my $fields = {
 372         DB => C4::Context->preference("LibraryName"),
 373         Title => $marc_rec_obj->title(),
 374         Author => $marc_rec_obj->author(),
 375         Publisher => $f710a,
 376         City => $f260a,
 377         Year => $marc_rec_obj->publication_date,
 378         Abstract => $abstract,
 379     };
 380     my $style = Biblio::EndnoteStyle->new();
 381     my $template;
 382     $template.= "DB - DB\n" if C4::Context->preference("LibraryName");
 383     $template.="T1 - Title\n" if $marc_rec_obj->title();
 384     $template.="A1 - Author\n" if $marc_rec_obj->author();
 385     $template.="PB - Publisher\n" if  $f710a;
 386     $template.="CY - City\n" if $f260a;
 387     $template.="Y1 - Year\n" if $marc_rec_obj->publication_date;
 388     $template.="AB - Abstract\n" if $abstract;
 389     my ($text, $errmsg) = $style->format($template, $fields);
 390     return ($text);
 391
 392 }
 393
 394 =head2 marc2csv - Convert several records from UNIMARC to CSV
 395
 396   my ($csv) = marc2csv($biblios, $csvprofileid, $itemnumbers);
 397
 398 Pre and postprocessing can be done through a YAML file
 399
 400 Returns a CSV scalar
 401
 402 C<$biblio> - a list of biblionumbers
 403
 404 C<$csvprofileid> - the id of the CSV profile to use for the export (see export_format.export_format_id)
 405
 406 C<$itemnumbers> - a list of itemnumbers to export
 407
 408 =cut
 409
 410 sub marc2csv {
 411     my ($biblios, $id, $itemnumbers) = @_;
 412     $itemnumbers ||= [];
 413     my $output;
 414     my $csv = Text::CSV::Encoded->new();
 415
 416     # Getting yaml file
 417     my $configfile = "../tools/csv-profiles/$id.yaml";
 418     my ($preprocess, $postprocess, $fieldprocessing);
 419     if (-e $configfile){
 420         ($preprocess,$postprocess, $fieldprocessing) = YAML::XS::LoadFile($configfile);
 421     }
 422
 423     # Preprocessing
 424     eval $preprocess if ($preprocess); ## no critic (StringyEval)
 425
 426     my $firstpass = 1;
 427     if ( @$itemnumbers ) {
 428         for my $itemnumber ( @$itemnumbers) {
 429             my $item = Koha::Items->find( $itemnumber );
 430             my $biblionumber = $item->biblio->biblionumber;
 431             $output .= marcrecord2csv( $biblionumber, $id, $firstpass, $csv, $fieldprocessing, [$itemnumber] ) // '';
 432             $firstpass = 0;
 433         }
 434     } else {
 435         foreach my $biblio (@$biblios) {
 436             $output .= marcrecord2csv( $biblio, $id, $firstpass, $csv, $fieldprocessing ) // '';
 437             $firstpass = 0;
 438         }
 439     }
 440
 441     # Postprocessing
 442     eval $postprocess if ($postprocess); ## no critic (StringyEval)
 443
 444     return $output;
 445 }
 446
 447 =head2 marcrecord2csv - Convert a single record from UNIMARC to CSV
 448
 449   my ($csv) = marcrecord2csv($biblio, $csvprofileid, $header);
 450
 451 Returns a CSV scalar
 452
 453 C<$biblio> - a biblionumber
 454
 455 C<$csvprofileid> - the id of the CSV profile to use for the export (see export_format.export_format_id)
 456
 457 C<$header> - true if the headers are to be printed (typically at first pass)
 458
 459 C<$csv> - an already initialised Text::CSV object
 460
 461 C<$fieldprocessing>
 462
 463 C<$itemnumbers> a list of itemnumbers to export
 464
 465 =cut
 466
 467 sub marcrecord2csv {
 468     my ($biblio, $id, $header, $csv, $fieldprocessing, $itemnumbers) = @_;
 469     my $output;
 470
 471     # Getting the record
 472     my $record = GetMarcBiblio({ biblionumber => $biblio });
 473     return unless $record;
 474     C4::Biblio::EmbedItemsInMarcBiblio({
 475         marc_record  => $record,
 476         biblionumber => $biblio,
 477         item_numbers => $itemnumbers });
 478     # Getting the framework
 479     my $frameworkcode = GetFrameworkCode($biblio);
 480
 481     # Getting information about the csv profile
 482     my $profile = Koha::CsvProfiles->find($id);
 483
 484     # Getting output encoding
 485     my $encoding          = $profile->encoding || 'utf8';
 486     # Getting separators
 487     my $csvseparator      = $profile->csv_separator      || ',';
 488     my $fieldseparator    = $profile->field_separator    || '#';
 489     my $subfieldseparator = $profile->subfield_separator || '|';
 490
 491     # TODO: Be more generic (in case we have to handle other protected chars or more separators)
 492     if ($csvseparator eq '\t') { $csvseparator = "\t" }
 493     if ($fieldseparator eq '\t') { $fieldseparator = "\t" }
 494     if ($subfieldseparator eq '\t') { $subfieldseparator = "\t" }
 495     if ($csvseparator eq '\n') { $csvseparator = "\n" }
 496     if ($fieldseparator eq '\n') { $fieldseparator = "\n" }
 497     if ($subfieldseparator eq '\n') { $subfieldseparator = "\n" }
 498
 499     $csv = $csv->encoding_out($encoding) ;
 500     $csv->sep_char($csvseparator);
 501
 502     # Getting the marcfields
 503     my $marcfieldslist = $profile->content;
 504
 505     # Getting the marcfields as an array
 506     my @marcfieldsarray = split('\|', $marcfieldslist);
 507
 508    # Separating the marcfields from the user-supplied headers
 509     my @csv_structures;
 510     foreach (@marcfieldsarray) {
 511         my @result = split('=', $_, 2);
 512         my $content = ( @result == 2 )
 513             ? $result[1]
 514             : $result[0];
 515         my @fields;
 516         while ( $content =~ m|(\d{3})\$?(.)?|g ) {
 517             my $fieldtag = $1;
 518             my $subfieldtag = $2;
 519             push @fields, { fieldtag => $fieldtag, subfieldtag => $subfieldtag };
 520         }
 521         if ( @result == 2) {
 522            push @csv_structures, { header => $result[0], content => $content, fields => \@fields };
 523         } else {
 524            push @csv_structures, { content => $content, fields => \@fields }
 525         }
 526     }
 527
 528     my ( @marcfieldsheaders, @csv_rows );
 529     my $dbh = C4::Context->dbh;
 530
 531     my $field_list;
 532     for my $field ( $record->fields ) {
 533         my $fieldtag = $field->tag;
 534         my $values;
 535         if ( $field->is_control_field ) {
 536             $values = $field->data();
 537         } else {
 538             $values->{indicator}{1} = $field->indicator(1);
 539             $values->{indicator}{2} = $field->indicator(2);
 540             for my $subfield ( $field->subfields ) {
 541                 my $subfieldtag = $subfield->[0];
 542                 my $value = $subfield->[1];
 543                 push @{ $values->{$subfieldtag} }, $value;
 544             }
 545         }
 546         # We force the key as an integer (trick for 00X and OXX fields)
 547         push @{ $field_list->{fields}{0+$fieldtag} }, $values;
 548     }
 549
 550     # For each field or subfield
 551     foreach my $csv_structure (@csv_structures) {
 552         my @field_values;
 553         my $tags = $csv_structure->{fields};
 554         my $content = $csv_structure->{content};
 555
 556         if ( $header ) {
 557             # If we have a user-supplied header, we use it
 558             if ( exists $csv_structure->{header} ) {
 559                 push @marcfieldsheaders, $csv_structure->{header};
 560             } else {
 561                 # If not, we get the matching tag name from koha
 562                 my $tag = $tags->[0];
 563                 if (defined $tag->{subfieldtag} ) {
 564                     my $query = "SELECT liblibrarian FROM marc_subfield_structure WHERE tagfield=? AND tagsubfield=?";
 565                     my @results = $dbh->selectrow_array( $query, {}, $tag->{fieldtag}, $tag->{subfieldtag} );
 566                     push @marcfieldsheaders, $results[0];
 567                 } else {
 568                     my $query = "SELECT liblibrarian FROM marc_tag_structure WHERE tagfield=?";
 569                     my @results = $dbh->selectrow_array( $query, {}, $tag->{fieldtag} );
 570                     push @marcfieldsheaders, $results[0];
 571                 }
 572             }
 573         }
 574
 575         # TT tags exist
 576         if ( $content =~ m|\[\%.*\%\]| ) {
 577             my $tt = Template->new();
 578             my $template = $content;
 579             # Replace 00X and 0XX with X or XX
 580             $content =~ s|fields.00(\d)|fields.$1|g;
 581             $content =~ s|fields.0(\d{2})|fields.$1|g;
 582             my $tt_output;
 583             $tt->process( \$content, $field_list, \$tt_output );
 584             push @csv_rows, $tt_output;
 585         } else {
 586             for my $tag ( @$tags ) {
 587                 my @fields = $record->field( $tag->{fieldtag} );
 588                 # If it is a subfield
 589                 my @loop_values;
 590                 if (defined $tag->{subfieldtag} ) {
 591                     my $av = Koha::AuthorisedValues->search_by_marc_field({ frameworkcode => $frameworkcode, tagfield => $tag->{fieldtag}, tagsubfield => $tag->{subfieldtag}, });
 592                     $av = $av->count ? $av->unblessed : [];
 593                     my $av_description_mapping = { map { ( $_->{authorised_value} => $_->{lib} ) } @$av };
 594                     # For each field
 595                     foreach my $field (@fields) {
 596                         my @subfields = $field->subfield( $tag->{subfieldtag} );
 597                         foreach my $subfield (@subfields) {
 598                             push @loop_values, (defined $av_description_mapping->{$subfield}) ? $av_description_mapping->{$subfield} : $subfield;
 599                         }
 600                     }
 601
 602                 # Or a field
 603                 } else {
 604                     my $av = Koha::AuthorisedValues->search_by_marc_field({ frameworkcode => $frameworkcode, tagfield => $tag->{fieldtag}, });
 605                     $av = $av->count ? $av->unblessed : [];
 606                     my $authvalues = { map { ( $_->{authorised_value} => $_->{lib} ) } @$av };
 607
 608                     foreach my $field ( @fields ) {
 609                         my $value;
 610
 611                         # If it is a control field
 612                         if ($field->is_control_field) {
 613                             $value = defined $authvalues->{$field->as_string} ? $authvalues->{$field->as_string} : $field->as_string;
 614                         } else {
 615                             # If it is a field, we gather all subfields, joined by the subfield separator
 616                             my @subvaluesarray;
 617                             my @subfields = $field->subfields;
 618                             foreach my $subfield (@subfields) {
 619                                 push (@subvaluesarray, defined $authvalues->{$subfield->[1]} ? $authvalues->{$subfield->[1]} : $subfield->[1]);
 620                             }
 621                             $value = join ($subfieldseparator, @subvaluesarray);
 622                         }
 623
 624                         # Field processing
 625                         my $marcfield = $tag->{fieldtag}; # This line fixes a retrocompatibility concern
 626                                                           # The "processing" could be based on the $marcfield variable.
 627                         eval $fieldprocessing if ($fieldprocessing); ## no critic (StringyEval)
 628
 629                         push @loop_values, $value;
 630                     }
 631
 632                 }
 633                 push @field_values, {
 634                     fieldtag => $tag->{fieldtag},
 635                     subfieldtag => $tag->{subfieldtag},
 636                     values => \@loop_values,
 637                 };
 638             }
 639             for my $field_value ( @field_values ) {
 640                 if ( $field_value->{subfieldtag} ) {
 641                     push @csv_rows, join( $subfieldseparator, @{ $field_value->{values} } );
 642                 } else {
 643                     push @csv_rows, join( $fieldseparator, @{ $field_value->{values} } );
 644                 }
 645             }
 646         }
 647     }
 648
 649
 650     if ( $header ) {
 651         $csv->combine(@marcfieldsheaders);
 652         $output = $csv->string() . "\n";
 653     }
 654     $csv->combine(@csv_rows);
 655     $output .= $csv->string() . "\n";
 656
 657     return $output;
 658
 659 }
 660
 661
 662 =head2 changeEncoding - Change the encoding of a record
 663
 664   my ($error, $newrecord) = changeEncoding($record,$format,$flavour,$to_encoding,$from_encoding);
 665
 666 Changes the encoding of a record
 667
 668 C<$record> - the record itself can be in ISO-2709, a MARC::Record object, or MARCXML for now (required)
 669
 670 C<$format> - MARC or MARCXML (required)
 671
 672 C<$flavour> - MARC21 or UNIMARC, if MARC21, it will change the leader (optional) [defaults to Koha system preference]
 673
 674 C<$to_encoding> - the encoding you want the record to end up in (optional) [UTF-8]
 675
 676 C<$from_encoding> - the encoding the record is currently in (optional, it will probably be able to tell unless there's a problem with the record)
 677
 678 FIXME: the from_encoding doesn't work yet
 679
 680 FIXME: better handling for UNIMARC, it should allow management of 100 field
 681
 682 FIXME: shouldn't have to convert to and from xml/marc just to change encoding someone needs to re-write MARC::Record's 'encoding' method to actually alter the encoding rather than just changing the leader
 683
 684 =cut
 685
 686 sub changeEncoding {
 687         my ($record,$format,$flavour,$to_encoding,$from_encoding) = @_;
 688         my $newrecord;
 689         my $error;
 690         unless($flavour) {$flavour = C4::Context->preference("marcflavour")};
 691         unless($to_encoding) {$to_encoding = "UTF-8"};
 692
 693         # ISO-2709 Record (MARC21 or UNIMARC)
 694         if (lc($format) =~ /^marc$/o) {
 695                 # if we're converting encoding of an ISO2709 file, we need to roundtrip through XML
 696                 #       because MARC::Record doesn't directly provide us with an encoding method
 697                 #       It's definitely less than idea and should be fixed eventually - kados
 698                 my $marcxml; # temporary storage of MARCXML scalar
 699                 ($error,$marcxml) = marc2marcxml($record,$to_encoding,$flavour);
 700                 unless ($error) {
 701                         ($error,$newrecord) = marcxml2marc($marcxml,$to_encoding,$flavour);
 702                 }
 703
 704         # MARCXML Record
 705         } elsif (lc($format) =~ /^marcxml$/o) { # MARCXML Record
 706                 my $marc;
 707                 ($error,$marc) = marcxml2marc($record,$to_encoding,$flavour);
 708                 unless ($error) {
 709                         ($error,$newrecord) = marc2marcxml($record,$to_encoding,$flavour);
 710                 }
 711         } else {
 712                 $error.="Unsupported record format:".$format;
 713         }
 714         return ($error,$newrecord);
 715 }
 716
 717 =head2 marc2bibtex - Convert from MARC21 and UNIMARC to BibTex
 718
 719   my ($bibtex) = marc2bibtex($record, $id);
 720
 721 Returns a BibTex scalar
 722
 723 C<$record> - a MARC::Record object
 724
 725 C<$id> - an id for the BibTex record (might be the biblionumber)
 726
 727 =cut
 728
 729
 730 sub marc2bibtex {
 731     my ($record, $id) = @_;
 732     my $tex;
 733     my $marcflavour = C4::Context->preference("marcflavour");
 734
 735     # Authors
 736     my $author;
 737     my @texauthors;
 738     my @authorFields = ('100','110','111','700','710','711');
 739     @authorFields = ('700','701','702','710','711','721') if ( $marcflavour eq "UNIMARC" );
 740
 741     foreach my $field ( @authorFields ) {
 742         # author formatted surname, firstname
 743         my $texauthor = '';
 744         if ( $marcflavour eq "UNIMARC" ) {
 745            $texauthor = join ', ',
 746            ( $record->subfield($field,"a"), $record->subfield($field,"b") );
 747        } else {
 748            $texauthor = $record->subfield($field,"a");
 749        }
 750        push @texauthors, $texauthor if $texauthor;
 751     }
 752     $author = join ' and ', @texauthors;
 753
 754     # Defining the conversion array according to the marcflavour
 755     my @bh;
 756     if ( $marcflavour eq "UNIMARC" ) {
 757
 758         # FIXME, TODO : handle repeatable fields
 759         # TODO : handle more types of documents
 760
 761         # Unimarc to bibtex array
 762         @bh = (
 763
 764             # Mandatory
 765             author    => $author,
 766             title     => $record->subfield("200", "a") || "",
 767             editor    => $record->subfield("210", "g") || "",
 768             publisher => $record->subfield("210", "c") || "",
 769             year      => $record->subfield("210", "d") || $record->subfield("210", "h") || "",
 770
 771             # Optional
 772             volume  =>  $record->subfield("200", "v") || "",
 773             series  =>  $record->subfield("225", "a") || "",
 774             address =>  $record->subfield("210", "a") || "",
 775             edition =>  $record->subfield("205", "a") || "",
 776             note    =>  $record->subfield("300", "a") || "",
 777             url     =>  $record->subfield("856", "u") || ""
 778         );
 779     } else {
 780
 781         # Marc21 to bibtex array
 782         @bh = (
 783
 784             # Mandatory
 785             author    => $author,
 786             title     => $record->subfield("245", "a") || "",
 787             editor    => $record->subfield("260", "f") || "",
 788             publisher => $record->subfield("264", "b") || $record->subfield("260", "b") || "",
 789             year      => $record->subfield("264", "c") || $record->subfield("260", "c") || $record->subfield("260", "g") || "",
 790
 791             # Optional
 792             # unimarc to marc21 specification says not to convert 200$v to marc21
 793             series  =>  $record->subfield("490", "a") || "",
 794             address =>  $record->subfield("264", "a") || $record->subfield("260", "a") || "",
 795             edition =>  $record->subfield("250", "a") || "",
 796             note    =>  $record->subfield("500", "a") || "",
 797             url     =>  $record->subfield("856", "u") || ""
 798         );
 799     }
 800
 801     my $BibtexExportAdditionalFields = C4::Context->preference('BibtexExportAdditionalFields');
 802     my $additional_fields;
 803     if ($BibtexExportAdditionalFields) {
 804         $BibtexExportAdditionalFields = "$BibtexExportAdditionalFields\n\n";
 805         $additional_fields = eval { YAML::XS::Load(Encode::encode_utf8($BibtexExportAdditionalFields)); };
 806         if ($@) {
 807             warn "Unable to parse BibtexExportAdditionalFields : $@";
 808             $additional_fields = undef;
 809         }
 810     }
 811
 812     if ( $additional_fields && $additional_fields->{'@'} ) {
 813         my ( $f, $sf ) = split( /\$/, $additional_fields->{'@'} );
 814         my ( $type ) = read_field( { record => $record, field => $f, subfield => $sf, field_numbers => [1] } );
 815
 816         if ($type) {
 817             $tex .= '@' . $type . '{';
 818         }
 819         else {
 820             $tex .= "\@book{";
 821         }
 822     }
 823     else {
 824         $tex .= "\@book{";
 825     }
 826
 827     my @elt;
 828     for ( my $i = 0 ; $i < scalar( @bh ) ; $i = $i + 2 ) {
 829         next unless $bh[$i+1];
 830         push @elt, qq|\t$bh[$i] = {$bh[$i+1]}|;
 831     }
 832     $tex .= join(",\n", $id, @elt);
 833
 834     if ($additional_fields) {
 835         $tex .= ",\n";
 836         foreach my $bibtex_tag ( keys %$additional_fields ) {
 837             next if $bibtex_tag eq '@';
 838
 839             my @fields =
 840               ref( $additional_fields->{$bibtex_tag} ) eq 'ARRAY'
 841               ? @{ $additional_fields->{$bibtex_tag} }
 842               : $additional_fields->{$bibtex_tag};
 843
 844             for my $tag (@fields) {
 845                 my ( $f, $sf ) = split( /\$/, $tag );
 846                 my @values = read_field( { record => $record, field => $f, subfield => $sf } );
 847                 foreach my $v (@values) {
 848                     $tex .= qq(\t$bibtex_tag = {$v}\n);
 849                 }
 850             }
 851         }
 852     }
 853     else {
 854         $tex .= "\n";
 855     }
 856
 857     $tex .= "}\n";
 858
 859     return $tex;
 860 }
 861
 862
 863 =head1 INTERNAL FUNCTIONS
 864
 865 =head2 _entity_encode - Entity-encode an array of strings
 866
 867   my ($entity_encoded_string) = _entity_encode($string);
 868
 869 or
 870
 871   my (@entity_encoded_strings) = _entity_encode(@strings);
 872
 873 Entity-encode an array of strings
 874
 875 =cut
 876
 877 sub _entity_encode {
 878         my @strings = @_;
 879         my @strings_entity_encoded;
 880         foreach my $string (@strings) {
 881                 my $nfc_string = NFC($string);
 882                 $nfc_string =~ s/([\x{0080}-\x{fffd}])/sprintf('&#x%X;',ord($1))/sgoe;
 883                 push @strings_entity_encoded, $nfc_string;
 884         }
 885         return @strings_entity_encoded;
 886 }
 887
 888 END { }       # module clean-up code here (global destructor)
 889 1;
 890 __END__
 891
 892 =head1 AUTHOR
 893
 894 Joshua Ferraro <jmf@liblime.com>
 895
 896 =head1 MODIFICATIONS
 897
 898
 899 =cut