C4/Reports/Guided.pm

   1 package C4::Reports::Guided;
   2
   3 # Copyright 2007 Liblime Ltd
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use CGI qw ( -utf8 );
  22 use Carp;
  23 use JSON qw( from_json );
  24
  25 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  26 use C4::Context;
  27 use C4::Templates qw/themelanguage/;
  28 use C4::Koha;
  29 use Koha::DateUtils;
  30 use Koha::Patrons;
  31 use Koha::Reports;
  32 use C4::Output;
  33 use C4::Log;
  34 use Koha::Notice::Templates;
  35 use C4::Letters;
  36
  37 use Koha::Logger;
  38 use Koha::AuthorisedValues;
  39 use Koha::Patron::Categories;
  40 use Koha::SharedContent;
  41
  42 BEGIN {
  43     require Exporter;
  44     @ISA    = qw(Exporter);
  45     @EXPORT = qw(
  46       get_report_types get_report_areas get_report_groups get_columns build_query get_criteria
  47       save_report get_saved_reports execute_query
  48       get_column_type get_distinct_values save_dictionary get_from_dictionary
  49       delete_definition delete_report format_results get_sql
  50       nb_rows update_sql
  51       GetReservedAuthorisedValues
  52       GetParametersFromSQL
  53       IsAuthorisedValueValid
  54       ValidateSQLParameters
  55       nb_rows update_sql
  56     );
  57 }
  58
  59 =head1 NAME
  60
  61 C4::Reports::Guided - Module for generating guided reports
  62
  63 =head1 SYNOPSIS
  64
  65   use C4::Reports::Guided;
  66
  67 =head1 DESCRIPTION
  68
  69 =cut
  70
  71 =head1 METHODS
  72
  73 =head2 get_report_areas
  74
  75 This will return a list of all the available report areas
  76
  77 =cut
  78
  79 sub get_area_name_sql_snippet {
  80     my @REPORT_AREA = (
  81         [CIRC => "Circulation"],
  82         [CAT  => "Catalogue"],
  83         [PAT  => "Patrons"],
  84         [ACQ  => "Acquisition"],
  85         [ACC  => "Accounts"],
  86         [SER  => "Serials"],
  87     );
  88
  89     return "CASE report_area " .
  90     join (" ", map "WHEN '$_->[0]' THEN '$_->[1]'", @REPORT_AREA) .
  91     " END AS areaname";
  92 }
  93
  94 sub get_report_areas {
  95
  96     my $report_areas = [ 'CIRC', 'CAT', 'PAT', 'ACQ', 'ACC', 'SER' ];
  97
  98     return $report_areas;
  99 }
 100
 101 sub get_table_areas {
 102     return (
 103     CIRC => [ 'borrowers', 'statistics', 'items', 'biblioitems' ],
 104     CAT  => [ 'items', 'biblioitems', 'biblio' ],
 105     PAT  => ['borrowers'],
 106     ACQ  => [ 'aqorders', 'biblio', 'items' ],
 107     ACC  => [ 'borrowers', 'accountlines' ],
 108     SER  => [ 'serial', 'serialitems', 'subscription', 'subscriptionhistory', 'subscriptionroutinglist', 'biblioitems', 'biblio', 'aqbooksellers' ],
 109     );
 110 }
 111
 112 =head2 get_report_types
 113
 114 This will return a list of all the available report types
 115
 116 =cut
 117
 118 sub get_report_types {
 119     my $dbh = C4::Context->dbh();
 120
 121     # FIXME these should be in the database perhaps
 122     my @reports = ( 'Tabular', 'Summary', 'Matrix' );
 123     my @reports2;
 124     for ( my $i = 0 ; $i < 3 ; $i++ ) {
 125         my %hashrep;
 126         $hashrep{id}   = $i + 1;
 127         $hashrep{name} = $reports[$i];
 128         push @reports2, \%hashrep;
 129     }
 130     return ( \@reports2 );
 131
 132 }
 133
 134 =head2 get_report_groups
 135
 136 This will return a list of all the available report areas with groups
 137
 138 =cut
 139
 140 sub get_report_groups {
 141     my $dbh = C4::Context->dbh();
 142
 143     my $groups = GetAuthorisedValues('REPORT_GROUP');
 144     my $subgroups = GetAuthorisedValues('REPORT_SUBGROUP');
 145
 146     my %groups_with_subgroups = map { $_->{authorised_value} => {
 147                         name => $_->{lib},
 148                         groups => {}
 149                     } } @$groups;
 150     foreach (@$subgroups) {
 151         my $sg = $_->{authorised_value};
 152         my $g = $_->{lib_opac}
 153           or warn( qq{REPORT_SUBGROUP "$sg" without REPORT_GROUP (lib_opac)} ),
 154              next;
 155         my $g_sg = $groups_with_subgroups{$g}
 156           or warn( qq{REPORT_SUBGROUP "$sg" with invalid REPORT_GROUP "$g"} ),
 157              next;
 158         $g_sg->{subgroups}{$sg} = $_->{lib};
 159     }
 160     return \%groups_with_subgroups
 161 }
 162
 163 =head2 get_all_tables
 164
 165 This will return a list of all tables in the database
 166
 167 =cut
 168
 169 sub get_all_tables {
 170     my $dbh   = C4::Context->dbh();
 171     my $query = "SHOW TABLES";
 172     my $sth   = $dbh->prepare($query);
 173     $sth->execute();
 174     my @tables;
 175     while ( my $data = $sth->fetchrow_arrayref() ) {
 176         push @tables, $data->[0];
 177     }
 178     $sth->finish();
 179     return ( \@tables );
 180
 181 }
 182
 183 =head2 get_columns($area)
 184
 185 This will return a list of all columns for a report area
 186
 187 =cut
 188
 189 sub get_columns {
 190
 191     # this calls the internal function _get_columns
 192     my ( $area, $cgi ) = @_;
 193     my %table_areas = get_table_areas;
 194     my $tables = $table_areas{$area}
 195       or die qq{Unsuported report area "$area"};
 196
 197     my @allcolumns;
 198     my $first = 1;
 199     foreach my $table (@$tables) {
 200         my @columns = _get_columns($table,$cgi, $first);
 201         $first = 0;
 202         push @allcolumns, @columns;
 203     }
 204     return ( \@allcolumns );
 205 }
 206
 207 sub _get_columns {
 208     my ($tablename,$cgi, $first) = @_;
 209     my $dbh         = C4::Context->dbh();
 210     my $sth         = $dbh->prepare("show columns from $tablename");
 211     $sth->execute();
 212     my @columns;
 213         my $column_defs = _get_column_defs($cgi);
 214         my %tablehash;
 215         $tablehash{'table'}=$tablename;
 216     $tablehash{'__first__'} = $first;
 217         push @columns, \%tablehash;
 218     while ( my $data = $sth->fetchrow_arrayref() ) {
 219         my %temphash;
 220         $temphash{'name'}        = "$tablename.$data->[0]";
 221         $temphash{'description'} = $column_defs->{"$tablename.$data->[0]"};
 222         push @columns, \%temphash;
 223     }
 224     $sth->finish();
 225     return (@columns);
 226 }
 227
 228 =head2 build_query($columns,$criteria,$orderby,$area)
 229
 230 This will build the sql needed to return the results asked for,
 231 $columns is expected to be of the format tablename.columnname.
 232 This is what get_columns returns.
 233
 234 =cut
 235
 236 sub build_query {
 237     my ( $columns, $criteria, $orderby, $area, $totals, $definition ) = @_;
 238
 239     my %keys = (
 240         CIRC => [ 'statistics.borrowernumber=borrowers.borrowernumber',
 241                   'items.itemnumber = statistics.itemnumber',
 242                   'biblioitems.biblioitemnumber = items.biblioitemnumber' ],
 243         CAT  => [ 'items.biblioitemnumber=biblioitems.biblioitemnumber',
 244                   'biblioitems.biblionumber=biblio.biblionumber' ],
 245         PAT  => [],
 246         ACQ  => [ 'aqorders.biblionumber=biblio.biblionumber',
 247                   'biblio.biblionumber=items.biblionumber' ],
 248         ACC  => ['borrowers.borrowernumber=accountlines.borrowernumber'],
 249         SER  => [ 'serial.serialid=serialitems.serialid', 'serial.subscriptionid=subscription.subscriptionid', 'serial.subscriptionid=subscriptionhistory.subscriptionid', 'serial.subscriptionid=subscriptionroutinglist.subscriptionid', 'biblioitems.biblionumber=serial.biblionumber', 'biblio.biblionumber=biblioitems.biblionumber', 'subscription.aqbooksellerid=aqbooksellers.id'],
 250     );
 251
 252
 253 ### $orderby
 254     my $keys   = $keys{$area};
 255     my %table_areas = get_table_areas;
 256     my $tables = $table_areas{$area};
 257
 258     my $sql =
 259       _build_query( $tables, $columns, $criteria, $keys, $orderby, $totals, $definition );
 260     return ($sql);
 261 }
 262
 263 sub _build_query {
 264     my ( $tables, $columns, $criteria, $keys, $orderby, $totals, $definition) = @_;
 265 ### $orderby
 266     # $keys is an array of joining constraints
 267     my $dbh           = C4::Context->dbh();
 268     my $joinedtables  = join( ',', @$tables );
 269     my $joinedcolumns = join( ',', @$columns );
 270     my $query =
 271       "SELECT $totals $joinedcolumns FROM $tables->[0] ";
 272         for (my $i=1;$i<@$tables;$i++){
 273                 $query .= "LEFT JOIN $tables->[$i] on ($keys->[$i-1]) ";
 274         }
 275
 276     if ($criteria) {
 277                 $criteria =~ s/AND/WHERE/;
 278         $query .= " $criteria";
 279     }
 280         if ($definition){
 281                 my @definitions = split(',',$definition);
 282                 my $deftext;
 283                 foreach my $def (@definitions){
 284                         my $defin=get_from_dictionary('',$def);
 285                         $deftext .=" ".$defin->[0]->{'saved_sql'};
 286                 }
 287                 if ($query =~ /WHERE/i){
 288                         $query .= $deftext;
 289                 }
 290                 else {
 291                         $deftext  =~ s/AND/WHERE/;
 292                         $query .= $deftext;
 293                 }
 294         }
 295     if ($totals) {
 296         my $groupby;
 297         my @totcolumns = split( ',', $totals );
 298         foreach my $total (@totcolumns) {
 299             if ( $total =~ /\((.*)\)/ ) {
 300                 if ( $groupby eq '' ) {
 301                     $groupby = " GROUP BY $1";
 302                 }
 303                 else {
 304                     $groupby .= ",$1";
 305                 }
 306             }
 307         }
 308         $query .= $groupby;
 309     }
 310     if ($orderby) {
 311         $query .= $orderby;
 312     }
 313     return ($query);
 314 }
 315
 316 =head2 get_criteria($area,$cgi);
 317
 318 Returns an arraref to hashrefs suitable for using in a tmpl_loop. With the criteria and available values.
 319
 320 =cut
 321
 322 sub get_criteria {
 323     my ($area,$cgi) = @_;
 324     my $dbh    = C4::Context->dbh();
 325
 326     # have to do someting here to know if its dropdown, free text, date etc
 327     my %criteria = (
 328         CIRC => [ 'statistics.type', 'borrowers.categorycode', 'statistics.branch',
 329                   'biblioitems.publicationyear|date', 'items.dateaccessioned|date' ],
 330         CAT  => [ 'items.itemnumber|textrange', 'items.biblionumber|textrange',
 331                   'items.barcode|textrange', 'biblio.frameworkcode',
 332                   'items.holdingbranch', 'items.homebranch',
 333                   'biblio.datecreated|daterange', 'biblio.timestamp|daterange',
 334                   'items.onloan|daterange', 'items.ccode',
 335                   'items.itemcallnumber|textrange', 'items.itype', 'items.itemlost',
 336                   'items.location' ],
 337         PAT  => [ 'borrowers.branchcode', 'borrowers.categorycode' ],
 338         ACQ  => ['aqorders.datereceived|date'],
 339         ACC  => [ 'borrowers.branchcode', 'borrowers.categorycode' ],
 340         SER  => ['subscription.startdate|date', 'subscription.enddate|date', 'subscription.periodicity', 'subscription.callnumber', 'subscription.location', 'subscription.branchcode'],
 341     );
 342
 343     # Adds itemtypes to criteria, according to the syspref
 344     if ( C4::Context->preference('item-level_itypes') ) {
 345         unshift @{ $criteria{'CIRC'} }, 'items.itype';
 346         unshift @{ $criteria{'CAT'} }, 'items.itype';
 347     } else {
 348         unshift @{ $criteria{'CIRC'} }, 'biblioitems.itemtype';
 349         unshift @{ $criteria{'CAT'} }, 'biblioitems.itemtype';
 350     }
 351
 352
 353     my $crit   = $criteria{$area};
 354     my $column_defs = _get_column_defs($cgi);
 355     my @criteria_array;
 356     foreach my $localcrit (@$crit) {
 357         my ( $value, $type )   = split( /\|/, $localcrit );
 358         my ( $table, $column ) = split( /\./, $value );
 359         if ($type eq 'textrange') {
 360             my %temp;
 361             $temp{'name'}        = $value;
 362             $temp{'from'}        = "from_" . $value;
 363             $temp{'to'}          = "to_" . $value;
 364             $temp{'textrange'}   = 1;
 365             $temp{'description'} = $column_defs->{$value};
 366             push @criteria_array, \%temp;
 367         }
 368         elsif ($type eq 'date') {
 369             my %temp;
 370             $temp{'name'}        = $value;
 371             $temp{'date'}        = 1;
 372             $temp{'description'} = $column_defs->{$value};
 373             push @criteria_array, \%temp;
 374         }
 375         elsif ($type eq 'daterange') {
 376             my %temp;
 377             $temp{'name'}        = $value;
 378             $temp{'from'}        = "from_" . $value;
 379             $temp{'to'}          = "to_" . $value;
 380             $temp{'daterange'}   = 1;
 381             $temp{'description'} = $column_defs->{$value};
 382             push @criteria_array, \%temp;
 383         }
 384         else {
 385             my $query =
 386             "SELECT distinct($column) as availablevalues FROM $table";
 387             my $sth = $dbh->prepare($query);
 388             $sth->execute();
 389             my @values;
 390             # push the runtime choosing option
 391             my $list;
 392             $list='branches' if $column eq 'branchcode' or $column eq 'holdingbranch' or $column eq 'homebranch';
 393             $list='categorycode' if $column eq 'categorycode';
 394             $list='itemtypes' if $column eq 'itype';
 395             $list='ccode' if $column eq 'ccode';
 396             # TODO : improve to let the librarian choose the description at runtime
 397             push @values, {
 398                 availablevalues => "<<$column" . ( $list ? "|$list" : '' ) . ">>",
 399                 display_value   => "<<$column" . ( $list ? "|$list" : '' ) . ">>",
 400             };
 401             while ( my $row = $sth->fetchrow_hashref() ) {
 402                 if ($row->{'availablevalues'} eq '') { $row->{'default'} = 1 }
 403                 else { $row->{display_value} = _get_display_value( $row->{'availablevalues'}, $column ); }
 404                 push @values, $row;
 405             }
 406             $sth->finish();
 407
 408             my %temp;
 409             $temp{'name'}        = $value;
 410             $temp{'description'} = $column_defs->{$value};
 411             $temp{'values'}      = \@values;
 412
 413             push @criteria_array, \%temp;
 414         }
 415     }
 416     return ( \@criteria_array );
 417 }
 418
 419 sub nb_rows {
 420     my $sql = shift or return;
 421
 422     my $derived_name = 'xxx';
 423     # make sure the derived table name is not already used
 424     while ( $sql =~ m/$derived_name/ ) {
 425         $derived_name .= 'x';
 426     }
 427
 428
 429     my $dbh = C4::Context->dbh;
 430     my $sth;
 431     my $n = 0;
 432
 433     my $RaiseError = $dbh->{RaiseError};
 434     my $PrintError = $dbh->{PrintError};
 435     $dbh->{RaiseError} = 1;
 436     $dbh->{PrintError} = 0;
 437     eval {
 438         $sth = $dbh->prepare(qq{
 439             SELECT COUNT(*) FROM
 440             ( $sql ) $derived_name
 441         });
 442
 443         $sth->execute();
 444     };
 445     $dbh->{RaiseError} = $RaiseError;
 446     $dbh->{PrintError} = $PrintError;
 447     if ($@) { # To catch "Duplicate column name" caused by the derived table, or any other syntax error
 448         eval {
 449             $sth = $dbh->prepare($sql);
 450             $sth->execute;
 451         };
 452         warn $@ if $@;
 453         # Loop through the complete results, fetching 1,000 rows at a time.  This
 454         # lowers memory requirements but increases execution time.
 455         while (my $rows = $sth->fetchall_arrayref(undef, 1000)) {
 456             $n += @$rows;
 457         }
 458         return $n;
 459     }
 460
 461     my $results = $sth->fetch;
 462     return $results ? $results->[0] : 0;
 463 }
 464
 465 =head2 execute_query
 466
 467   ($sth, $error) = execute_query($sql, $offset, $limit[, \@sql_params])
 468
 469
 470 This function returns a DBI statement handler from which the caller can
 471 fetch the results of the SQL passed via C<$sql>.
 472
 473 If passed any query other than a SELECT, or if there is a DB error,
 474 C<$errors> is returned, and is a hashref containing the error after this
 475 manner:
 476
 477 C<$error->{'sqlerr'}> contains the offending SQL keyword.
 478 C<$error->{'queryerr'}> contains the native db engine error returned
 479 for the query.
 480
 481 C<$offset>, and C<$limit> are required parameters.
 482
 483 C<\@sql_params> is an optional list of parameter values to paste in.
 484 The caller is responsible for making sure that C<$sql> has placeholders
 485 and that the number placeholders matches the number of parameters.
 486
 487 =cut
 488
 489 # returns $sql, $offset, $limit
 490 # $sql returned will be transformed to:
 491 #  ~ remove any LIMIT clause
 492 #  ~ repace SELECT clause w/ SELECT count(*)
 493
 494 sub select_2_select_count {
 495     # Modify the query passed in to create a count query... (I think this covers all cases -crn)
 496     my ($sql) = strip_limit(shift) or return;
 497     $sql =~ s/\bSELECT\W+(?:\w+\W+){1,}?FROM\b|\bSELECT\W\*\WFROM\b/SELECT count(*) FROM /ig;
 498     return $sql;
 499 }
 500
 501 # This removes the LIMIT from the query so that a custom one can be specified.
 502 # Usage:
 503 #   ($new_sql, $offset, $limit) = strip_limit($sql);
 504 #
 505 # Where:
 506 #   $sql is the query to modify
 507 #   $new_sql is the resulting query
 508 #   $offset is the offset value, if the LIMIT was the two-argument form,
 509 #       0 if it wasn't otherwise given.
 510 #   $limit is the limit value
 511 #
 512 # Notes:
 513 #   * This makes an effort to not break subqueries that have their own
 514 #     LIMIT specified. It does that by only removing a LIMIT if it comes after
 515 #     a WHERE clause (which isn't perfect, but at least should make more cases
 516 #     work - subqueries with a limit in the WHERE will still break.)
 517 #   * If your query doesn't have a WHERE clause then all LIMITs will be
 518 #     removed. This may break some subqueries, but is hopefully rare enough
 519 #     to not be a big issue.
 520 sub strip_limit {
 521     my ($sql) = @_;
 522
 523     return unless $sql;
 524     return ($sql, 0, undef) unless $sql =~ /\bLIMIT\b/i;
 525
 526     # Two options: if there's no WHERE clause in the SQL, we simply capture
 527     # any LIMIT that's there. If there is a WHERE, we make sure that we only
 528     # capture a LIMIT after the last one. This prevents stomping on subqueries.
 529     if ($sql !~ /\bWHERE\b/i) {
 530         (my $res = $sql) =~ s/\bLIMIT\b\s*(\d+)(\s*\,\s*(\d+))?\s*/ /ig;
 531         return ($res, (defined $2 ? $1 : 0), (defined $3 ? $3 : $1));
 532     } else {
 533         my $res = $sql;
 534         $res =~ m/.*\bWHERE\b/gsi;
 535         $res =~ s/\G(.*)\bLIMIT\b\s*(\d+)(\s*\,\s*(\d+))?\s*/$1 /is;
 536         return ($res, (defined $3 ? $2 : 0), (defined $4 ? $4 : $2));
 537     }
 538 }
 539
 540 sub execute_query {
 541
 542     my ( $sql, $offset, $limit, $sql_params, $report_id ) = @_;
 543
 544     $sql_params = [] unless defined $sql_params;
 545
 546     # check parameters
 547     unless ($sql) {
 548         carp "execute_query() called without SQL argument";
 549         return;
 550     }
 551     $offset = 0    unless $offset;
 552     $limit  = 999999 unless $limit;
 553
 554     Koha::Logger->get->debug("Report - execute_query($sql, $offset, $limit)");
 555
 556     my ( $is_sql_valid, $errors ) = Koha::Report->new({ savedsql => $sql })->is_sql_valid;
 557     return (undef, @{$errors}[0]) unless $is_sql_valid;
 558
 559     foreach my $sql_param ( @$sql_params ){
 560         if ( $sql_param =~ m/\n/ ){
 561             my @list = split /\n/, $sql_param;
 562             my @quoted_list;
 563             foreach my $item ( @list ){
 564                 $item =~ s/\r//;
 565               push @quoted_list, C4::Context->dbh->quote($item);
 566             }
 567             $sql_param = "(".join(",",@quoted_list).")";
 568         }
 569     }
 570
 571     my ($useroffset, $userlimit);
 572
 573     # Grab offset/limit from user supplied LIMIT and drop the LIMIT so we can control pagination
 574     ($sql, $useroffset, $userlimit) = strip_limit($sql);
 575
 576     Koha::Logger->get->debug(
 577         sprintf "User has supplied (OFFSET,) LIMIT = %s, %s",
 578         $useroffset, ( defined($userlimit) ? $userlimit : 'UNDEF' ) );
 579
 580     $offset += $useroffset;
 581     if (defined($userlimit)) {
 582         if ($offset + $limit > $userlimit ) {
 583             $limit = $userlimit - $offset;
 584         } elsif ( ! $offset && $limit < $userlimit ) {
 585             $limit = $userlimit;
 586         }
 587     }
 588     $sql .= " LIMIT ?, ?";
 589
 590     my $dbh = C4::Context->dbh;
 591
 592     $dbh->do( 'UPDATE saved_sql SET last_run = NOW() WHERE id = ?', undef, $report_id ) if $report_id;
 593
 594     my $sth = $dbh->prepare($sql);
 595     eval {
 596         $sth->execute(@$sql_params, $offset, $limit);
 597     };
 598     warn $@ if $@;
 599
 600     return ( $sth, { queryerr => $sth->errstr } ) if ($sth->err);
 601     return ( $sth );
 602 }
 603
 604 =head2 save_report($sql,$name,$type,$notes)
 605
 606 Given some sql and a name this will saved it so that it can reused
 607 Returns id of the newly created report
 608
 609 =cut
 610
 611 sub save_report {
 612     my ($fields) = @_;
 613     my $borrowernumber = $fields->{borrowernumber};
 614     my $sql = $fields->{sql};
 615     my $name = $fields->{name};
 616     my $type = $fields->{type};
 617     my $notes = $fields->{notes};
 618     my $area = $fields->{area};
 619     my $group = $fields->{group};
 620     my $subgroup = $fields->{subgroup};
 621     my $cache_expiry = $fields->{cache_expiry};
 622     my $public = $fields->{public};
 623
 624     $sql =~ s/(\s*\;\s*)$//;    # removes trailing whitespace and /;/
 625     my $now = dt_from_string;
 626     my $report = Koha::Report->new(
 627         {
 628             borrowernumber  => $borrowernumber,
 629             date_created    => $now, # Must be moved to Koha::Report->store
 630             last_modified   => $now, # Must be moved to Koha::Report->store
 631             savedsql        => $sql,
 632             report_name     => $name,
 633             report_area     => $area,
 634             report_group    => $group,
 635             report_subgroup => $subgroup,
 636             type            => $type,
 637             notes           => $notes,
 638             cache_expiry    => $cache_expiry,
 639             public          => $public,
 640         }
 641     )->store;
 642
 643     return $report->id;
 644 }
 645
 646 sub update_sql {
 647     my $id         = shift || croak "No Id given";
 648     my $fields     = shift;
 649     my $sql = $fields->{sql};
 650     my $name = $fields->{name};
 651     my $notes = $fields->{notes};
 652     my $group = $fields->{group};
 653     my $subgroup = $fields->{subgroup};
 654     my $cache_expiry = $fields->{cache_expiry};
 655     my $public = $fields->{public};
 656
 657     $sql =~ s/(\s*\;\s*)$//;    # removes trailing whitespace and /;/
 658     my $report = Koha::Reports->find($id);
 659     $report->last_modified(dt_from_string);
 660     $report->savedsql($sql);
 661     $report->report_name($name);
 662     $report->notes($notes);
 663     $report->report_group($group);
 664     $report->report_subgroup($subgroup);
 665     $report->cache_expiry($cache_expiry) if defined $cache_expiry;
 666     $report->public($public);
 667     $report->store();
 668     if( $cache_expiry >= 2592000 ){
 669       die "Please specify a cache expiry less than 30 days\n"; # That's a bit harsh
 670     }
 671
 672     return $report;
 673 }
 674
 675 sub store_results {
 676     my ( $id, $json ) = @_;
 677     my $dbh = C4::Context->dbh();
 678     $dbh->do(q|
 679         INSERT INTO saved_reports ( report_id, report, date_run ) VALUES ( ?, ?, NOW() );
 680     |, undef, $id, $json );
 681 }
 682
 683 sub format_results {
 684     my ( $id ) = @_;
 685     my $dbh = C4::Context->dbh();
 686     my ( $report_name, $notes, $json, $date_run ) = $dbh->selectrow_array(q|
 687        SELECT ss.report_name, ss.notes, sr.report, sr.date_run
 688        FROM saved_sql ss
 689        LEFT JOIN saved_reports sr ON sr.report_id = ss.id
 690        WHERE sr.id = ?
 691     |, undef, $id);
 692     return {
 693         report_name => $report_name,
 694         notes => $notes,
 695         results => from_json( $json ),
 696         date_run => $date_run,
 697     };
 698 }
 699
 700 sub delete_report {
 701     my (@ids) = @_;
 702     return unless @ids;
 703     foreach my $id (@ids) {
 704         my $data = Koha::Reports->find($id);
 705         logaction( "REPORTS", "DELETE", $id, $data->report_name." | ".$data->savedsql ) if C4::Context->preference("ReportsLog");
 706     }
 707     my $dbh = C4::Context->dbh;
 708     my $query = 'DELETE FROM saved_sql WHERE id IN (' . join( ',', ('?') x @ids ) . ')';
 709     my $sth = $dbh->prepare($query);
 710     return $sth->execute(@ids);
 711 }
 712
 713 sub get_saved_reports_base_query {
 714     my $area_name_sql_snippet = get_area_name_sql_snippet;
 715     return <<EOQ;
 716 SELECT s.*, $area_name_sql_snippet, av_g.lib AS groupname, av_sg.lib AS subgroupname,
 717 b.firstname AS borrowerfirstname, b.surname AS borrowersurname
 718 FROM saved_sql s
 719 LEFT JOIN saved_reports r ON r.report_id = s.id
 720 LEFT OUTER JOIN authorised_values av_g ON (av_g.category = 'REPORT_GROUP' AND av_g.authorised_value = s.report_group)
 721 LEFT OUTER JOIN authorised_values av_sg ON (av_sg.category = 'REPORT_SUBGROUP' AND av_sg.lib_opac = s.report_group AND av_sg.authorised_value = s.report_subgroup)
 722 LEFT OUTER JOIN borrowers b USING (borrowernumber)
 723 EOQ
 724 }
 725
 726 sub get_saved_reports {
 727 # $filter is either { date => $d, author => $a, keyword => $kw, }
 728 # or $keyword. Optional.
 729     my ($filter) = @_;
 730     $filter = { keyword => $filter } if $filter && !ref( $filter );
 731     my ($group, $subgroup) = @_;
 732
 733     my $dbh   = C4::Context->dbh();
 734     my $query = get_saved_reports_base_query;
 735     my (@cond,@args);
 736     if ($filter) {
 737         if (my $date = $filter->{date}) {
 738             $date = eval { output_pref( { dt => dt_from_string( $date ), dateonly => 1, dateformat => 'iso' }); };
 739             push @cond, "DATE(last_modified) = ? OR
 740                          DATE(last_run) = ?";
 741             push @args, $date, $date, $date;
 742         }
 743         if (my $author = $filter->{author}) {
 744             $author = "%$author%";
 745             push @cond, "surname LIKE ? OR
 746                          firstname LIKE ?";
 747             push @args, $author, $author;
 748         }
 749         if (my $keyword = $filter->{keyword}) {
 750             push @cond, q|
 751                        report LIKE ?
 752                     OR report_name LIKE ?
 753                     OR notes LIKE ?
 754                     OR savedsql LIKE ?
 755                     OR s.id = ?
 756             |;
 757             push @args, "%$keyword%", "%$keyword%", "%$keyword%", "%$keyword%", $keyword;
 758         }
 759         if ($filter->{group}) {
 760             push @cond, "report_group = ?";
 761             push @args, $filter->{group};
 762         }
 763         if ($filter->{subgroup}) {
 764             push @cond, "report_subgroup = ?";
 765             push @args, $filter->{subgroup};
 766         }
 767     }
 768     $query .= " WHERE ".join( " AND ", map "($_)", @cond ) if @cond;
 769     $query .= " GROUP BY s.id, s.borrowernumber, s.date_created, s.last_modified, s.savedsql, s.last_run, s.report_name, s.type, s.notes, s.cache_expiry, s.public, s.report_area, s.report_group, s.report_subgroup, s.mana_id, av_g.lib, av_sg.lib, b.firstname, b.surname";
 770     $query .= " ORDER by date_created";
 771
 772     my $result = $dbh->selectall_arrayref($query, {Slice => {}}, @args);
 773
 774     return $result;
 775 }
 776
 777 =head2 get_column_type($column)
 778
 779 This takes a column name of the format table.column and will return what type it is
 780 (free text, set values, date)
 781
 782 =cut
 783
 784 sub get_column_type {
 785         my ($tablecolumn) = @_;
 786         my ($table,$column) = split(/\./,$tablecolumn);
 787         my $dbh = C4::Context->dbh();
 788         my $catalog;
 789         my $schema;
 790
 791     # mysql doesn't support a column selection, set column to %
 792         my $tempcolumn='%';
 793         my $sth = $dbh->column_info( $catalog, $schema, $table, $tempcolumn ) || die $dbh->errstr;
 794         while (my $info = $sth->fetchrow_hashref()){
 795                 if ($info->{'COLUMN_NAME'} eq $column){
 796                         #column we want
 797                         if ($info->{'TYPE_NAME'} eq 'CHAR' || $info->{'TYPE_NAME'} eq 'VARCHAR'){
 798                                 $info->{'TYPE_NAME'} = 'distinct';
 799                         }
 800                         return $info->{'TYPE_NAME'};
 801                 }
 802         }
 803 }
 804
 805 =head2 get_distinct_values($column)
 806
 807 Given a column name, return an arrary ref of hashrefs suitable for use as a tmpl_loop
 808 with the distinct values of the column
 809
 810 =cut
 811
 812 sub get_distinct_values {
 813         my ($tablecolumn) = @_;
 814         my ($table,$column) = split(/\./,$tablecolumn);
 815         my $dbh = C4::Context->dbh();
 816         my $query =
 817           "SELECT distinct($column) as availablevalues FROM $table";
 818         my $sth = $dbh->prepare($query);
 819         $sth->execute();
 820     return $sth->fetchall_arrayref({});
 821 }
 822
 823 sub save_dictionary {
 824     my ( $name, $description, $sql, $area ) = @_;
 825     my $dbh   = C4::Context->dbh();
 826     my $query = "INSERT INTO reports_dictionary (name,description,saved_sql,report_area,date_created,date_modified)
 827   VALUES (?,?,?,?,now(),now())";
 828     my $sth = $dbh->prepare($query);
 829     $sth->execute($name,$description,$sql,$area) || return 0;
 830     return 1;
 831 }
 832
 833 sub get_from_dictionary {
 834     my ( $area, $id ) = @_;
 835     my $dbh   = C4::Context->dbh();
 836     my $area_name_sql_snippet = get_area_name_sql_snippet;
 837     my $query = <<EOQ;
 838 SELECT d.*, $area_name_sql_snippet
 839 FROM reports_dictionary d
 840 EOQ
 841
 842     if ($area) {
 843         $query .= " WHERE report_area = ?";
 844     } elsif ($id) {
 845         $query .= " WHERE id = ?";
 846     }
 847     my $sth = $dbh->prepare($query);
 848     if ($id) {
 849         $sth->execute($id);
 850     } elsif ($area) {
 851         $sth->execute($area);
 852     } else {
 853         $sth->execute();
 854     }
 855     my @loop;
 856     while ( my $data = $sth->fetchrow_hashref() ) {
 857         push @loop, $data;
 858     }
 859     return ( \@loop );
 860 }
 861
 862 sub delete_definition {
 863         my ($id) = @_ or return;
 864         my $dbh = C4::Context->dbh();
 865         my $query = "DELETE FROM reports_dictionary WHERE id = ?";
 866         my $sth = $dbh->prepare($query);
 867         $sth->execute($id);
 868 }
 869
 870 =head2 get_sql($report_id)
 871
 872 Given a report id, return the SQL statement for that report.
 873 Otherwise, it just returns.
 874
 875 =cut
 876
 877 sub get_sql {
 878         my ($id) = @_ or return;
 879         my $dbh = C4::Context->dbh();
 880         my $query = "SELECT * FROM saved_sql WHERE id = ?";
 881         my $sth = $dbh->prepare($query);
 882         $sth->execute($id);
 883         my $data=$sth->fetchrow_hashref();
 884         return $data->{'savedsql'};
 885 }
 886
 887 sub get_results {
 888     my ( $report_id ) = @_;
 889     my $dbh = C4::Context->dbh;
 890     return $dbh->selectall_arrayref(q|
 891         SELECT id, report, date_run
 892         FROM saved_reports
 893         WHERE report_id = ?
 894     |, { Slice => {} }, $report_id);
 895 }
 896
 897 sub _get_column_defs {
 898     my ($cgi) = @_;
 899     my %columns;
 900     my $columns_def_file = "columns.def";
 901     my $htdocs = C4::Context->config('intrahtdocs');
 902     my $section = 'intranet';
 903
 904     # We need the theme and the lang
 905     # Since columns.def is not in the modules directory, we cannot sent it for the $tmpl var
 906     my ($theme, $lang, $availablethemes) = C4::Templates::themelanguage($htdocs, 'about.tt', $section, $cgi);
 907
 908     my $full_path_to_columns_def_file="$htdocs/$theme/$lang/$columns_def_file";
 909     open (my $fh, '<:encoding(utf-8)', $full_path_to_columns_def_file);
 910     while ( my $input = <$fh> ){
 911         chomp $input;
 912         if ( $input =~ m|<field name="(.*)">(.*)</field>| ) {
 913             my ( $field, $translation ) = ( $1, $2 );
 914             $columns{$field} = $translation;
 915         }
 916     }
 917     close $fh;
 918     return \%columns;
 919 }
 920
 921 =head2 GetReservedAuthorisedValues
 922
 923     my %reserved_authorised_values = GetReservedAuthorisedValues();
 924
 925 Returns a hash containig all reserved words
 926
 927 =cut
 928
 929 sub GetReservedAuthorisedValues {
 930     my %reserved_authorised_values =
 931             map { $_ => 1 } ( 'date',
 932                               'list',
 933                               'branches',
 934                               'itemtypes',
 935                               'cn_source',
 936                               'categorycode',
 937                               'biblio_framework' );
 938
 939    return \%reserved_authorised_values;
 940 }
 941
 942
 943 =head2 IsAuthorisedValueValid
 944
 945     my $is_valid_ath_value = IsAuthorisedValueValid($authorised_value)
 946
 947 Returns 1 if $authorised_value is on the reserved authorised values list or
 948 in the authorised value categories defined in
 949
 950 =cut
 951
 952 sub IsAuthorisedValueValid {
 953
 954     my $authorised_value = shift;
 955     my $reserved_authorised_values = GetReservedAuthorisedValues();
 956
 957     if ( exists $reserved_authorised_values->{$authorised_value} ||
 958          Koha::AuthorisedValues->search({ category => $authorised_value })->count ) {
 959         return 1;
 960     }
 961
 962     return 0;
 963 }
 964
 965 =head2 GetParametersFromSQL
 966
 967     my @sql_parameters = GetParametersFromSQL($sql)
 968
 969 Returns an arrayref of hashes containing the keys name and authval
 970
 971 =cut
 972
 973 sub GetParametersFromSQL {
 974
 975     my $sql = shift ;
 976     my @split = split(/<<|>>/,$sql);
 977     my @sql_parameters = ();
 978
 979     for ( my $i = 0; $i < ($#split/2) ; $i++ ) {
 980         my ($name,$authval) = split(/\|/,$split[$i*2+1]);
 981         $authval =~ s/\:all$// if $authval;
 982         push @sql_parameters, { 'name' => $name, 'authval' => $authval };
 983     }
 984
 985     return \@sql_parameters;
 986 }
 987
 988 =head2 ValidateSQLParameters
 989
 990     my @problematic_parameters = ValidateSQLParameters($sql)
 991
 992 Returns an arrayref of hashes containing the keys name and authval of
 993 those SQL parameters that do not correspond to valid authorised names
 994
 995 =cut
 996
 997 sub ValidateSQLParameters {
 998
 999     my $sql = shift;
1000     my @problematic_parameters = ();
1001     my $sql_parameters = GetParametersFromSQL($sql);
1002
1003     foreach my $sql_parameter (@$sql_parameters) {
1004         if ( defined $sql_parameter->{'authval'} ) {
1005             push @problematic_parameters, $sql_parameter unless
1006                 IsAuthorisedValueValid($sql_parameter->{'authval'});
1007         }
1008     }
1009
1010     return \@problematic_parameters;
1011 }
1012
1013 =head2 EmailReport
1014
1015     my ( $emails, $arrayrefs ) = EmailReport($report_id, $letter_code, $module, $branch, $email)
1016
1017 Take a report and use it to process a Template Toolkit formatted notice
1018 Returns arrayrefs containing prepared letters and errors respectively
1019
1020 =cut
1021
1022 sub EmailReport {
1023
1024     my $params     = shift;
1025     my $report_id  = $params->{report_id};
1026     my $from       = $params->{from};
1027     my $email_col  = $params->{email} || 'email';
1028     my $module     = $params->{module};
1029     my $code       = $params->{code};
1030     my $branch     = $params->{branch} || "";
1031
1032     my @errors = ();
1033     my @emails = ();
1034
1035     return ( undef, [{ FATAL => "MISSING_PARAMS" }] ) unless ($report_id && $module && $code);
1036
1037     return ( undef, [{ FATAL => "NO_LETTER" }] ) unless
1038     my $letter = Koha::Notice::Templates->find({
1039         module     => $module,
1040         code       => $code,
1041         branchcode => $branch,
1042         message_transport_type => 'email',
1043     });
1044     $letter = $letter->unblessed;
1045
1046     my $report = Koha::Reports->find( $report_id );
1047     my $sql = $report->savedsql;
1048     return ( { FATAL => "NO_REPORT" } ) unless $sql;
1049
1050     my ( $sth, $errors ) = execute_query( $sql ); #don't pass offset or limit, hardcoded limit of 999,999 will be used
1051     return ( undef, [{ FATAL => "REPORT_FAIL" }] ) if $errors;
1052
1053     my $counter = 1;
1054     my $template = $letter->{content};
1055
1056     while ( my $row = $sth->fetchrow_hashref() ) {
1057         my $email;
1058         my $err_count = scalar @errors;
1059         push ( @errors, { NO_BOR_COL => $counter } ) unless defined $row->{borrowernumber};
1060         push ( @errors, { NO_EMAIL_COL => $counter } ) unless ( defined $row->{$email_col} );
1061         push ( @errors, { NO_FROM_COL => $counter } ) unless defined ( $from || $row->{from} );
1062         push ( @errors, { NO_BOR => $row->{borrowernumber} } ) unless Koha::Patrons->find({borrowernumber=>$row->{borrowernumber}});
1063
1064         my $from_address = $from || $row->{from};
1065         my $to_address = $row->{$email_col};
1066         push ( @errors, { NOT_PARSE => $counter } ) unless my $content = _process_row_TT( $row, $template );
1067         $counter++;
1068         next if scalar @errors > $err_count; #If any problems, try next
1069
1070         $letter->{content}       = $content;
1071         $email->{borrowernumber} = $row->{borrowernumber};
1072         $email->{letter}         = { %$letter };
1073         $email->{from_address}   = $from_address;
1074         $email->{to_address}     = $to_address;
1075
1076         push ( @emails, $email );
1077     }
1078
1079     return ( \@emails, \@errors );
1080
1081 }
1082
1083
1084
1085 =head2 ProcessRowTT
1086
1087    my $content = ProcessRowTT($row_hashref, $template);
1088
1089 Accepts a hashref containing values and processes them against Template Toolkit
1090 to produce content
1091
1092 =cut
1093
1094 sub _process_row_TT {
1095
1096     my ($row, $template) = @_;
1097
1098     return 0 unless ($row && $template);
1099     my $content;
1100     my $processor = Template->new();
1101     $processor->process( \$template, $row, \$content);
1102     return $content;
1103
1104 }
1105
1106 sub _get_display_value {
1107     my ( $original_value, $column ) = @_;
1108     if ( $column eq 'periodicity' ) {
1109         my $dbh = C4::Context->dbh();
1110         my $query = "SELECT description FROM subscription_frequencies WHERE id = ?";
1111         my $sth   = $dbh->prepare($query);
1112         $sth->execute($original_value);
1113         return $sth->fetchrow;
1114     }
1115     return $original_value;
1116 }
1117
1118
1119 =head3 convert_sql
1120
1121 my $updated_sql = C4::Reports::Guided::convert_sql( $sql );
1122
1123 Convert a sql query using biblioitems.marcxml to use the new
1124 biblio_metadata.metadata field instead
1125
1126 =cut
1127
1128 sub convert_sql {
1129     my ( $sql ) = @_;
1130     my $updated_sql = $sql;
1131     if ( $sql =~ m|biblioitems| and $sql =~ m|marcxml| ) {
1132         $updated_sql =~ s|biblioitems|biblio_metadata|g;
1133         $updated_sql =~ s|marcxml|metadata|g;
1134     }
1135     return $updated_sql;
1136 }
1137
1138 1;
1139 __END__
1140
1141 =head1 AUTHOR
1142
1143 Chris Cormack <crc@liblime.com>
1144
1145 =cut