C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use Modern::Perl;
  25
  26 use C4::Accounts;
  27 use C4::Biblio;
  28 use C4::Circulation;
  29 use C4::Context;
  30 use C4::Items;
  31 use C4::Letters;
  32 use C4::Log;
  33 use C4::Members::Messaging;
  34 use C4::Members;
  35 use Koha::Account::Lines;
  36 use Koha::Biblios;
  37 use Koha::Calendar;
  38 use Koha::CirculationRules;
  39 use Koha::Database;
  40 use Koha::DateUtils;
  41 use Koha::Hold;
  42 use Koha::Holds;
  43 use Koha::ItemTypes;
  44 use Koha::Items;
  45 use Koha::Libraries;
  46 use Koha::Old::Hold;
  47 use Koha::Patrons;
  48 use Koha::Plugins;
  49
  50 use Carp;
  51 use Data::Dumper;
  52 use List::MoreUtils qw( firstidx any );
  53
  54 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  55
  56 =head1 NAME
  57
  58 C4::Reserves - Koha functions for dealing with reservation.
  59
  60 =head1 SYNOPSIS
  61
  62   use C4::Reserves;
  63
  64 =head1 DESCRIPTION
  65
  66 This modules provides somes functions to deal with reservations.
  67
  68   Reserves are stored in reserves table.
  69   The following columns contains important values :
  70   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  71              =0      : then the reserve is being dealed
  72   - found : NULL         : means the patron requested the 1st available, and we haven't chosen the item
  73             T(ransit)    : the reserve is linked to an item but is in transit to the pickup branch
  74             W(aiting)    : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  75             F(inished)   : the reserve has been completed, and is done
  76             P(rocessing) : reserved item has been returned using self-check machine and reserve needs to be confirmed
  77                            by librarian before notice is send and status changed to waiting.
  78                            Applicable only if HoldsNeedProcessingSIP system preference is set.
  79   - itemnumber : empty : the reserve is still unaffected to an item
  80                  filled: the reserve is attached to an item
  81   The complete workflow is :
  82   ==== 1st use case ====
  83   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  84   a library having it run "transfertodo", and clic on the list
  85          if there is no transfer to do, the reserve waiting
  86          patron can pick it up                                    P =0, F=W,    I=filled
  87          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  88            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  89   The patron borrow the book                                      P =0, F=F,    I=filled
  90
  91   ==== 2nd use case ====
  92   patron requests a document, a given item,
  93     If pickup is holding branch                                   P =0, F=W,   I=filled
  94     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  95         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  96   The patron borrow the book                                      P =0, F=F,    I=filled
  97
  98 =head1 FUNCTIONS
  99
 100 =cut
 101
 102 BEGIN {
 103     require Exporter;
 104     @ISA = qw(Exporter);
 105     @EXPORT = qw(
 106         &AddReserve
 107
 108         &GetReserveStatus
 109
 110         &GetOtherReserves
 111
 112         &ModReserveFill
 113         &ModReserveAffect
 114         &ModReserve
 115         &ModReserveStatus
 116         &ModReserveCancelAll
 117         &ModReserveMinusPriority
 118         &MoveReserve
 119
 120         &CheckReserves
 121         &CanBookBeReserved
 122         &CanItemBeReserved
 123         &CanReserveBeCanceledFromOpac
 124         &CancelExpiredReserves
 125
 126         &AutoUnsuspendReserves
 127
 128         &IsAvailableForItemLevelRequest
 129         ItemsAnyAvailableAndNotRestricted
 130
 131         &AlterPriority
 132         &ToggleLowestPriority
 133
 134         &ReserveSlip
 135         &ToggleSuspend
 136         &SuspendAll
 137
 138         &GetReservesControlBranch
 139
 140         IsItemOnHoldAndFound
 141
 142         GetMaxPatronHoldsForRecord
 143     );
 144     @EXPORT_OK = qw( MergeHolds );
 145 }
 146
 147 =head2 AddReserve
 148
 149     AddReserve(
 150         {
 151             branchcode       => $branchcode,
 152             borrowernumber   => $borrowernumber,
 153             biblionumber     => $biblionumber,
 154             priority         => $priority,
 155             reservation_date => $reservation_date,
 156             expiration_date  => $expiration_date,
 157             notes            => $notes,
 158             title            => $title,
 159             itemnumber       => $itemnumber,
 160             found            => $found,
 161             itemtype         => $itemtype,
 162         }
 163     );
 164
 165 Adds reserve and generates HOLDPLACED message.
 166
 167 The following tables are available witin the HOLDPLACED message:
 168
 169     branches
 170     borrowers
 171     biblio
 172     biblioitems
 173     items
 174     reserves
 175
 176 =cut
 177
 178 sub AddReserve {
 179     my ($params)       = @_;
 180     my $branch         = $params->{branchcode};
 181     my $borrowernumber = $params->{borrowernumber};
 182     my $biblionumber   = $params->{biblionumber};
 183     my $priority       = $params->{priority};
 184     my $resdate        = $params->{reservation_date};
 185     my $expdate        = $params->{expiration_date};
 186     my $notes          = $params->{notes};
 187     my $title          = $params->{title};
 188     my $checkitem      = $params->{itemnumber};
 189     my $found          = $params->{found};
 190     my $itemtype       = $params->{itemtype};
 191     my $non_priority   = $params->{non_priority};
 192
 193     $resdate = output_pref( { str => dt_from_string( $resdate ), dateonly => 1, dateformat => 'iso' })
 194         or output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 195
 196     $expdate = output_pref({ str => $expdate, dateonly => 1, dateformat => 'iso' });
 197
 198     # if we have an item selectionned, and the pickup branch is the same as the holdingbranch
 199     # of the document, we force the value $priority and $found .
 200     if ( $checkitem and not C4::Context->preference('ReservesNeedReturns') ) {
 201         my $item = Koha::Items->find( $checkitem ); # FIXME Prevent bad calls
 202
 203         if (
 204             # If item is already checked out, it cannot be set waiting
 205             !$item->onloan
 206
 207             # The item can't be waiting if it needs a transfer
 208             && $item->holdingbranch eq $branch
 209
 210             # Similarly, if in transit it can't be waiting
 211             && !$item->get_transfer
 212
 213             # If we can't hold damaged items, and it is damaged, it can't be waiting
 214             && ( $item->damaged && C4::Context->preference('AllowHoldsOnDamagedItems') || !$item->damaged )
 215
 216             # Lastly, if this already has holds, we shouldn't make it waiting for the new hold
 217             && !$item->current_holds->count )
 218         {
 219             $priority = 0;
 220             $found = 'W';
 221         }
 222     }
 223
 224     if ( C4::Context->preference('AllowHoldDateInFuture') ) {
 225
 226         # Make room in reserves for this before those of a later reserve date
 227         $priority = _ShiftPriorityByDateAndPriority( $biblionumber, $resdate, $priority );
 228     }
 229
 230     my $waitingdate;
 231
 232     # If the reserv had the waiting status, we had the value of the resdate
 233     if ( $found && $found eq 'W' ) {
 234         $waitingdate = $resdate;
 235     }
 236
 237     # Don't add itemtype limit if specific item is selected
 238     $itemtype = undef if $checkitem;
 239
 240     # updates take place here
 241     my $hold = Koha::Hold->new(
 242         {
 243             borrowernumber => $borrowernumber,
 244             biblionumber   => $biblionumber,
 245             reservedate    => $resdate,
 246             branchcode     => $branch,
 247             priority       => $priority,
 248             reservenotes   => $notes,
 249             itemnumber     => $checkitem,
 250             found          => $found,
 251             waitingdate    => $waitingdate,
 252             expirationdate => $expdate,
 253             itemtype       => $itemtype,
 254             item_level_hold => $checkitem ? 1 : 0,
 255             non_priority   => $non_priority ? 1 : 0,
 256         }
 257     )->store();
 258     $hold->set_waiting() if $found && $found eq 'W';
 259
 260     logaction( 'HOLDS', 'CREATE', $hold->id, Dumper($hold->unblessed) )
 261         if C4::Context->preference('HoldsLog');
 262
 263     my $reserve_id = $hold->id();
 264
 265     # add a reserve fee if needed
 266     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 267         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 268         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 269     }
 270
 271     _FixPriority({ biblionumber => $biblionumber});
 272
 273     # Send e-mail to librarian if syspref is active
 274     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 275         my $patron = Koha::Patrons->find( $borrowernumber );
 276         my $library = $patron->library;
 277         if ( my $letter =  C4::Letters::GetPreparedLetter (
 278             module => 'reserves',
 279             letter_code => 'HOLDPLACED',
 280             branchcode => $branch,
 281             lang => $patron->lang,
 282             tables => {
 283                 'branches'    => $library->unblessed,
 284                 'borrowers'   => $patron->unblessed,
 285                 'biblio'      => $biblionumber,
 286                 'biblioitems' => $biblionumber,
 287                 'items'       => $checkitem,
 288                 'reserves'    => $hold->unblessed,
 289             },
 290         ) ) {
 291
 292             my $branch_email_address = $library->inbound_email_address;
 293
 294             C4::Letters::EnqueueLetter(
 295                 {
 296                     letter                 => $letter,
 297                     borrowernumber         => $borrowernumber,
 298                     message_transport_type => 'email',
 299                     to_address             => $branch_email_address,
 300                 }
 301             );
 302         }
 303     }
 304
 305     Koha::Plugins->call('after_hold_create', $hold);
 306
 307     return $reserve_id;
 308 }
 309
 310 =head2 CanBookBeReserved
 311
 312   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber, $branchcode, $params)
 313   if ($canReserve eq 'OK') { #We can reserve this Item! }
 314
 315   $params are passed directly through to CanItemBeReserved
 316
 317 See CanItemBeReserved() for possible return values.
 318
 319 =cut
 320
 321 sub CanBookBeReserved{
 322     my ($borrowernumber, $biblionumber, $pickup_branchcode, $params) = @_;
 323
 324     # Check that patron have not checked out this biblio (if AllowHoldsOnPatronsPossessions set)
 325     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 326         && C4::Circulation::CheckIfIssuedToPatron( $borrowernumber, $biblionumber ) ) {
 327         return { status =>'alreadypossession' };
 328     }
 329
 330     my @itemnumbers = Koha::Items->search({ biblionumber => $biblionumber})->get_column("itemnumber");
 331     #get items linked via host records
 332     my @hostitems = get_hostitemnumbers_of($biblionumber);
 333     if (@hostitems){
 334         push (@itemnumbers, @hostitems);
 335     }
 336
 337     my $canReserve = { status => '' };
 338     foreach my $itemnumber (@itemnumbers) {
 339         $canReserve = CanItemBeReserved( $borrowernumber, $itemnumber, $pickup_branchcode, $params );
 340         return { status => 'OK' } if $canReserve->{status} eq 'OK';
 341     }
 342     return $canReserve;
 343 }
 344
 345 =head2 CanItemBeReserved
 346
 347   $canReserve = &CanItemBeReserved($borrowernumber, $itemnumber, $branchcode, $params)
 348   if ($canReserve->{status} eq 'OK') { #We can reserve this Item! }
 349
 350   current params are 'ignore_found_holds' - if true holds that have been trapped are not counted
 351   toward the patron limit, used by checkHighHolds to avoid counting the hold we will fill with the
 352   current checkout against the high holds threshold
 353
 354 @RETURNS { status => OK },              if the Item can be reserved.
 355          { status => ageRestricted },   if the Item is age restricted for this borrower.
 356          { status => damaged },         if the Item is damaged.
 357          { status => cannotReserveFromOtherBranches }, if syspref 'canreservefromotherbranches' is OK.
 358          { status => branchNotInHoldGroup }, if borrower home library is not in hold group, and holds are only allowed from hold groups.
 359          { status => tooManyReserves, limit => $limit }, if the borrower has exceeded their maximum reserve amount.
 360          { status => notReservable },   if holds on this item are not allowed
 361          { status => libraryNotFound },   if given branchcode is not an existing library
 362          { status => libraryNotPickupLocation },   if given branchcode is not configured to be a pickup location
 363          { status => cannotBeTransferred }, if branch transfer limit applies on given item and branchcode
 364          { status => pickupNotInHoldGroup }, pickup location is not in hold group, and pickup locations are only allowed from hold groups.
 365
 366 =cut
 367
 368 sub CanItemBeReserved {
 369     my ( $borrowernumber, $itemnumber, $pickup_branchcode, $params ) = @_;
 370
 371     my $dbh = C4::Context->dbh;
 372     my $ruleitemtype;    # itemtype of the matching issuing rule
 373     my $allowedreserves  = 0; # Total number of holds allowed across all records, default to none
 374
 375     # we retrieve borrowers and items informations #
 376     # item->{itype} will come for biblioitems if necessery
 377     my $item       = Koha::Items->find($itemnumber);
 378     my $biblio     = $item->biblio;
 379     my $patron = Koha::Patrons->find( $borrowernumber );
 380     my $borrower = $patron->unblessed;
 381
 382     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 383     return { status =>'damaged' }
 384       if ( $item->damaged
 385         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 386
 387     # Check for the age restriction
 388     my ( $ageRestriction, $daysToAgeRestriction ) =
 389       C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 390     return { status => 'ageRestricted' } if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 391
 392     # Check that the patron doesn't have an item level hold on this item already
 393     return { status =>'itemAlreadyOnHold' }
 394       if Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->count();
 395
 396     # Check that patron have not checked out this biblio (if AllowHoldsOnPatronsPossessions set)
 397     if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 398         && C4::Circulation::CheckIfIssuedToPatron( $patron->borrowernumber, $biblio->biblionumber ) ) {
 399         return { status =>'alreadypossession' };
 400     }
 401
 402     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 403
 404     my $querycount = q{
 405         SELECT count(*) AS count
 406           FROM reserves
 407      LEFT JOIN items USING (itemnumber)
 408      LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 409      LEFT JOIN borrowers USING (borrowernumber)
 410          WHERE borrowernumber = ?
 411     };
 412
 413     my $branchcode  = "";
 414     my $branchfield = "reserves.branchcode";
 415
 416     if ( $controlbranch eq "ItemHomeLibrary" ) {
 417         $branchfield = "items.homebranch";
 418         $branchcode  = $item->homebranch;
 419     }
 420     elsif ( $controlbranch eq "PatronLibrary" ) {
 421         $branchfield = "borrowers.branchcode";
 422         $branchcode  = $borrower->{branchcode};
 423     }
 424
 425     # we retrieve rights
 426     if (
 427         my $reservesallowed = Koha::CirculationRules->get_effective_rule({
 428                 itemtype     => $item->effective_itemtype,
 429                 categorycode => $borrower->{categorycode},
 430                 branchcode   => $branchcode,
 431                 rule_name    => 'reservesallowed',
 432         })
 433     ) {
 434         $ruleitemtype     = $reservesallowed->itemtype;
 435         $allowedreserves  = $reservesallowed->rule_value // 0; #undefined is 0, blank is unlimited
 436     }
 437     else {
 438         $ruleitemtype = undef;
 439     }
 440
 441     my $rights = Koha::CirculationRules->get_effective_rules({
 442         categorycode => $borrower->{'categorycode'},
 443         itemtype     => $item->effective_itemtype,
 444         branchcode   => $branchcode,
 445         rules        => ['holds_per_record','holds_per_day']
 446     });
 447     my $holds_per_record = $rights->{holds_per_record} // 1;
 448     my $holds_per_day    = $rights->{holds_per_day};
 449
 450     my $search_params = {
 451         borrowernumber => $borrowernumber,
 452         biblionumber   => $item->biblionumber,
 453     };
 454     $search_params->{found} = undef if $params->{ignore_found_holds};
 455
 456     my $holds = Koha::Holds->search($search_params);
 457     if (   defined $holds_per_record && $holds_per_record ne ''
 458         && $holds->count() >= $holds_per_record ) {
 459         return { status => "tooManyHoldsForThisRecord", limit => $holds_per_record };
 460     }
 461
 462     my $today_holds = Koha::Holds->search({
 463         borrowernumber => $borrowernumber,
 464         reservedate    => dt_from_string->date
 465     });
 466
 467     if (   defined $holds_per_day && $holds_per_day ne ''
 468         && $today_holds->count() >= $holds_per_day )
 469     {
 470         return { status => 'tooManyReservesToday', limit => $holds_per_day };
 471     }
 472
 473     # we retrieve count
 474
 475     $querycount .= "AND ( $branchfield = ? OR $branchfield IS NULL )";
 476
 477     # If using item-level itypes, fall back to the record
 478     # level itemtype if the hold has no associated item
 479     $querycount .=
 480       C4::Context->preference('item-level_itypes')
 481       ? " AND COALESCE( items.itype, biblioitems.itemtype ) = ?"
 482       : " AND biblioitems.itemtype = ?"
 483       if defined $ruleitemtype;
 484
 485     my $sthcount = $dbh->prepare($querycount);
 486
 487     if ( defined $ruleitemtype ) {
 488         $sthcount->execute( $borrowernumber, $branchcode, $ruleitemtype );
 489     }
 490     else {
 491         $sthcount->execute( $borrowernumber, $branchcode );
 492     }
 493
 494     my $reservecount = "0";
 495     if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 496         $reservecount = $rowcount->{count};
 497     }
 498
 499     # we check if it's ok or not
 500     if (   defined  $allowedreserves && $allowedreserves ne ''
 501         && $reservecount >= $allowedreserves ) {
 502         return { status => 'tooManyReserves', limit => $allowedreserves };
 503     }
 504
 505     # Now we need to check hold limits by patron category
 506     my $rule = Koha::CirculationRules->get_effective_rule(
 507         {
 508             categorycode => $borrower->{categorycode},
 509             branchcode   => $branchcode,
 510             rule_name    => 'max_holds',
 511         }
 512     );
 513     if ( $rule && defined( $rule->rule_value ) && $rule->rule_value ne '' ) {
 514         my $total_holds_count = Koha::Holds->search(
 515             {
 516                 borrowernumber => $borrower->{borrowernumber}
 517             }
 518         )->count();
 519
 520         return { status => 'tooManyReserves', limit => $rule->rule_value} if $total_holds_count >= $rule->rule_value;
 521     }
 522
 523     my $reserves_control_branch =
 524       GetReservesControlBranch( $item->unblessed(), $borrower );
 525     my $branchitemrule =
 526       C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype ); # FIXME Should not be item->effective_itemtype?
 527
 528     if ( $branchitemrule->{holdallowed} == 0 ) {
 529         return { status => 'notReservable' };
 530     }
 531
 532     if (   $branchitemrule->{holdallowed} == 1
 533         && $borrower->{branchcode} ne $item->homebranch )
 534     {
 535         return { status => 'cannotReserveFromOtherBranches' };
 536     }
 537
 538     my $item_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
 539     if ( $branchitemrule->{holdallowed} == 3) {
 540         if($borrower->{branchcode} ne $item->homebranch && !$item_library->validate_hold_sibling( {branchcode => $borrower->{branchcode}} )) {
 541             return { status => 'branchNotInHoldGroup' };
 542         }
 543     }
 544
 545     # If reservecount is ok, we check item branch if IndependentBranches is ON
 546     # and canreservefromotherbranches is OFF
 547     if ( C4::Context->preference('IndependentBranches')
 548         and !C4::Context->preference('canreservefromotherbranches') )
 549     {
 550         if ( $item->homebranch ne $borrower->{branchcode} ) {
 551             return { status => 'cannotReserveFromOtherBranches' };
 552         }
 553     }
 554
 555     if ($pickup_branchcode) {
 556         my $destination = Koha::Libraries->find({
 557             branchcode => $pickup_branchcode,
 558         });
 559
 560         unless ($destination) {
 561             return { status => 'libraryNotFound' };
 562         }
 563         unless ($destination->pickup_location) {
 564             return { status => 'libraryNotPickupLocation' };
 565         }
 566         unless ($item->can_be_transferred({ to => $destination })) {
 567             return { status => 'cannotBeTransferred' };
 568         }
 569         if ($branchitemrule->{hold_fulfillment_policy} eq 'holdgroup' && !$item_library->validate_hold_sibling( {branchcode => $pickup_branchcode} )) {
 570             return { status => 'pickupNotInHoldGroup' };
 571         }
 572         if ($branchitemrule->{hold_fulfillment_policy} eq 'patrongroup' && !Koha::Libraries->find({branchcode => $borrower->{branchcode}})->validate_hold_sibling({branchcode => $pickup_branchcode})) {
 573             return { status => 'pickupNotInHoldGroup' };
 574         }
 575     }
 576
 577     return { status => 'OK' };
 578 }
 579
 580 =head2 CanReserveBeCanceledFromOpac
 581
 582     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 583
 584     returns 1 if reserve can be cancelled by user from OPAC.
 585     First check if reserve belongs to user, next checks if reserve is not in
 586     transfer or waiting status
 587
 588 =cut
 589
 590 sub CanReserveBeCanceledFromOpac {
 591     my ($reserve_id, $borrowernumber) = @_;
 592
 593     return unless $reserve_id and $borrowernumber;
 594     my $reserve = Koha::Holds->find($reserve_id);
 595
 596     return 0 unless $reserve->borrowernumber == $borrowernumber;
 597     return $reserve->is_cancelable_from_opac;
 598 }
 599
 600 =head2 GetOtherReserves
 601
 602   ($messages,$nextreservinfo)=$GetOtherReserves(itemnumber);
 603
 604 Check queued list of this document and check if this document must be transferred
 605
 606 =cut
 607
 608 sub GetOtherReserves {
 609     my ($itemnumber) = @_;
 610     my $messages;
 611     my $nextreservinfo;
 612     my ( undef, $checkreserves, undef ) = CheckReserves($itemnumber);
 613     if ($checkreserves) {
 614         my $item = Koha::Items->find($itemnumber);
 615         if ( $item->holdingbranch ne $checkreserves->{'branchcode'} ) {
 616             $messages->{'transfert'} = $checkreserves->{'branchcode'};
 617             #minus priorities of others reservs
 618             ModReserveMinusPriority(
 619                 $itemnumber,
 620                 $checkreserves->{'reserve_id'},
 621             );
 622
 623             #launch the subroutine dotransfer
 624             C4::Items::ModItemTransfer(
 625                 $itemnumber,
 626                 $item->holdingbranch,
 627                 $checkreserves->{'branchcode'},
 628                 'Reserve'
 629               ),
 630               ;
 631         }
 632
 633      #step 2b : case of a reservation on the same branch, set the waiting status
 634         else {
 635             $messages->{'waiting'} = 1;
 636             ModReserveMinusPriority(
 637                 $itemnumber,
 638                 $checkreserves->{'reserve_id'},
 639             );
 640             ModReserveStatus($itemnumber,'W');
 641         }
 642
 643         $nextreservinfo = $checkreserves;
 644     }
 645
 646     return ( $messages, $nextreservinfo );
 647 }
 648
 649 =head2 ChargeReserveFee
 650
 651     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 652
 653     Charge the fee for a reserve (if $fee > 0)
 654
 655 =cut
 656
 657 sub ChargeReserveFee {
 658     my ( $borrowernumber, $fee, $title ) = @_;
 659     return if !$fee || $fee == 0;    # the last test is needed to include 0.00
 660     Koha::Account->new( { patron_id => $borrowernumber } )->add_debit(
 661         {
 662             amount       => $fee,
 663             description  => $title,
 664             note         => undef,
 665             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 666             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 667             interface    => C4::Context->interface,
 668             invoice_type => undef,
 669             type         => 'RESERVE',
 670             item_id      => undef
 671         }
 672     );
 673 }
 674
 675 =head2 GetReserveFee
 676
 677     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 678
 679     Calculate the fee for a reserve (if applicable).
 680
 681 =cut
 682
 683 sub GetReserveFee {
 684     my ( $borrowernumber, $biblionumber ) = @_;
 685     my $borquery = qq{
 686 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 687     };
 688     my $issue_qry = qq{
 689 SELECT COUNT(*) FROM items
 690 LEFT JOIN issues USING (itemnumber)
 691 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 692     };
 693     my $holds_qry = qq{
 694 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 695     };
 696
 697     my $dbh = C4::Context->dbh;
 698     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 699     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 700     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 701         # This is a reconstruction of the old code:
 702         # Compare number of items with items issued, and optionally check holds
 703         # If not all items are issued and there are no holds: charge no fee
 704         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 705         my ( $notissued, $reserved );
 706         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 707             ( $biblionumber ) );
 708         if( $notissued ) {
 709             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 710                 ( $biblionumber, $borrowernumber ) );
 711             $fee = 0 if $reserved == 0;
 712         }
 713     }
 714     return $fee;
 715 }
 716
 717 =head2 GetReserveStatus
 718
 719   $reservestatus = GetReserveStatus($itemnumber);
 720
 721 Takes an itemnumber and returns the status of the reserve placed on it.
 722 If several reserves exist, the reserve with the lower priority is given.
 723
 724 =cut
 725
 726 ## FIXME: I don't think this does what it thinks it does.
 727 ## It only ever checks the first reserve result, even though
 728 ## multiple reserves for that bib can have the itemnumber set
 729 ## the sub is only used once in the codebase.
 730 sub GetReserveStatus {
 731     my ($itemnumber) = @_;
 732
 733     my $dbh = C4::Context->dbh;
 734
 735     my ($sth, $found, $priority);
 736     if ( $itemnumber ) {
 737         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 738         $sth->execute($itemnumber);
 739         ($found, $priority) = $sth->fetchrow_array;
 740     }
 741
 742     if(defined $found) {
 743         return 'Waiting'  if $found eq 'W' and $priority == 0;
 744         return 'Processing'  if $found eq 'P';
 745         return 'Finished' if $found eq 'F';
 746     }
 747
 748     return 'Reserved' if defined $priority && $priority > 0;
 749
 750     return ''; # empty string here will remove need for checking undef, or less log lines
 751 }
 752
 753 =head2 CheckReserves
 754
 755   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber);
 756   ($status, $matched_reserve, $possible_reserves) = &CheckReserves(undef, $barcode);
 757   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber,undef,$lookahead);
 758
 759 Find a book in the reserves.
 760
 761 C<$itemnumber> is the book's item number.
 762 C<$lookahead> is the number of days to look in advance for future reserves.
 763
 764 As I understand it, C<&CheckReserves> looks for the given item in the
 765 reserves. If it is found, that's a match, and C<$status> is set to
 766 C<Waiting>.
 767
 768 Otherwise, it finds the most important item in the reserves with the
 769 same biblio number as this book (I'm not clear on this) and returns it
 770 with C<$status> set to C<Reserved>.
 771
 772 C<&CheckReserves> returns a two-element list:
 773
 774 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 775
 776 C<$reserve> is the reserve item that matched. It is a
 777 reference-to-hash whose keys are mostly the fields of the reserves
 778 table in the Koha database.
 779
 780 =cut
 781
 782 sub CheckReserves {
 783     my ( $item, $barcode, $lookahead_days, $ignore_borrowers) = @_;
 784     my $dbh = C4::Context->dbh;
 785     my $sth;
 786     my $select;
 787     if (C4::Context->preference('item-level_itypes')){
 788         $select = "
 789            SELECT items.biblionumber,
 790            items.biblioitemnumber,
 791            itemtypes.notforloan,
 792            items.notforloan AS itemnotforloan,
 793            items.itemnumber,
 794            items.damaged,
 795            items.homebranch,
 796            items.holdingbranch
 797            FROM   items
 798            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 799            LEFT JOIN itemtypes   ON items.itype   = itemtypes.itemtype
 800         ";
 801     }
 802     else {
 803         $select = "
 804            SELECT items.biblionumber,
 805            items.biblioitemnumber,
 806            itemtypes.notforloan,
 807            items.notforloan AS itemnotforloan,
 808            items.itemnumber,
 809            items.damaged,
 810            items.homebranch,
 811            items.holdingbranch
 812            FROM   items
 813            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 814            LEFT JOIN itemtypes   ON biblioitems.itemtype   = itemtypes.itemtype
 815         ";
 816     }
 817
 818     if ($item) {
 819         $sth = $dbh->prepare("$select WHERE itemnumber = ?");
 820         $sth->execute($item);
 821     }
 822     else {
 823         $sth = $dbh->prepare("$select WHERE barcode = ?");
 824         $sth->execute($barcode);
 825     }
 826     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 827     my ( $biblio, $bibitem, $notforloan_per_itemtype, $notforloan_per_item, $itemnumber, $damaged, $item_homebranch, $item_holdingbranch ) = $sth->fetchrow_array;
 828     return if ( $damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 829
 830     return unless $itemnumber; # bail if we got nothing.
 831     # if item is not for loan it cannot be reserved either.....
 832     # except where items.notforloan < 0 :  This indicates the item is holdable.
 833
 834     my @SkipHoldTrapOnNotForLoanValue = split( '\|', C4::Context->preference('SkipHoldTrapOnNotForLoanValue') );
 835     return if grep { $_ eq $notforloan_per_item } @SkipHoldTrapOnNotForLoanValue;
 836
 837     my $dont_trap = C4::Context->preference('TrapHoldsOnOrder') ? ($notforloan_per_item > 0) : ($notforloan_per_item && 1 );
 838     return if $dont_trap or $notforloan_per_itemtype;
 839
 840     # Find this item in the reserves
 841     my @reserves = _Findgroupreserve( $bibitem, $biblio, $itemnumber, $lookahead_days, $ignore_borrowers);
 842
 843     # $priority and $highest are used to find the most important item
 844     # in the list returned by &_Findgroupreserve. (The lower $priority,
 845     # the more important the item.)
 846     # $highest is the most important item we've seen so far.
 847     my $highest;
 848
 849     if (scalar @reserves) {
 850         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 851         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 852         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 853
 854         my $priority = 10000000;
 855         foreach my $res (@reserves) {
 856             if ($res->{'found'} && $res->{'found'} eq 'W') {
 857                 return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 858             } elsif ($res->{'found'} && $res->{'found'} eq 'P') {
 859                 return ( "Processing", $res, \@reserves ); # Found determinated hold, e. g. the transferred one
 860             } elsif ($res->{'found'} && $res->{'found'} eq 'T') {
 861                 return ( "Transferred", $res, \@reserves ); # Found determinated hold, e. g. the transferred one
 862             } else {
 863                 my $patron;
 864                 my $item;
 865                 my $local_hold_match;
 866
 867                 if ($LocalHoldsPriority) {
 868                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 869                     $item = Koha::Items->find($itemnumber);
 870
 871                     unless ($item->exclude_from_local_holds_priority || $patron->category->exclude_from_local_holds_priority) {
 872                         my $local_holds_priority_item_branchcode =
 873                             $item->$LocalHoldsPriorityItemControl;
 874                         my $local_holds_priority_patron_branchcode =
 875                             ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 876                             ? $res->{branchcode}
 877                             : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 878                             ? $patron->branchcode
 879                             : undef;
 880                         $local_hold_match =
 881                             $local_holds_priority_item_branchcode eq
 882                             $local_holds_priority_patron_branchcode;
 883                     }
 884                 }
 885
 886                 # See if this item is more important than what we've got so far
 887                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 888                     $item ||= Koha::Items->find($itemnumber);
 889                     next if $res->{itemtype} && $res->{itemtype} ne $item->effective_itemtype;
 890                     $patron ||= Koha::Patrons->find( $res->{borrowernumber} );
 891                     my $branch = GetReservesControlBranch( $item->unblessed, $patron->unblessed );
 892                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$item->effective_itemtype);
 893                     next if ($branchitemrule->{'holdallowed'} == 0);
 894                     next if (($branchitemrule->{'holdallowed'} == 1) && ($branch ne $patron->branchcode));
 895                     my $library = Koha::Libraries->find({branchcode=>$item->homebranch});
 896                     next if (($branchitemrule->{'holdallowed'} == 3) && (!$library->validate_hold_sibling({branchcode => $patron->branchcode}) ));
 897                     my $hold_fulfillment_policy = $branchitemrule->{hold_fulfillment_policy};
 898                     next if ( ($hold_fulfillment_policy eq 'holdgroup') && (!$library->validate_hold_sibling({branchcode => $res->{branchcode}})) );
 899                     next if ( ($hold_fulfillment_policy eq 'homebranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 900                     next if ( ($hold_fulfillment_policy eq 'holdingbranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 901                     next unless $item->can_be_transferred( { to => Koha::Libraries->find( $res->{branchcode} ) } );
 902                     $priority = $res->{'priority'};
 903                     $highest  = $res;
 904                     last if $local_hold_match;
 905                 }
 906             }
 907         }
 908     }
 909
 910     # If we get this far, then no exact match was found.
 911     # We return the most important (i.e. next) reservation.
 912     if ($highest) {
 913         $highest->{'itemnumber'} = $item;
 914         return ( "Reserved", $highest, \@reserves );
 915     }
 916
 917     return ( '' );
 918 }
 919
 920 =head2 CancelExpiredReserves
 921
 922   CancelExpiredReserves();
 923
 924 Cancels all reserves with an expiration date from before today.
 925
 926 =cut
 927
 928 sub CancelExpiredReserves {
 929     my $cancellation_reason = shift;
 930     my $today = dt_from_string();
 931     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 932     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 933
 934     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 935     my $params = { expirationdate => { '<', $dtf->format_date($today) } };
 936     $params->{found} = [ { '!=', 'W' }, undef ]  unless $expireWaiting;
 937
 938     # FIXME To move to Koha::Holds->search_expired (?)
 939     my $holds = Koha::Holds->search( $params );
 940
 941     while ( my $hold = $holds->next ) {
 942         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
 943
 944         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
 945
 946         my $cancel_params = {};
 947         $cancel_params->{cancellation_reason} = $cancellation_reason if defined($cancellation_reason);
 948         if ( defined($hold->found) && $hold->found eq 'W' ) {
 949             $cancel_params->{charge_cancel_fee} = 1;
 950         }
 951         $hold->cancel( $cancel_params );
 952     }
 953 }
 954
 955 =head2 AutoUnsuspendReserves
 956
 957   AutoUnsuspendReserves();
 958
 959 Unsuspends all suspended reserves with a suspend_until date from before today.
 960
 961 =cut
 962
 963 sub AutoUnsuspendReserves {
 964     my $today = dt_from_string();
 965
 966     my @holds = Koha::Holds->search( { suspend_until => { '<=' => $today->ymd() } } );
 967
 968     map { $_->resume() } @holds;
 969 }
 970
 971 =head2 ModReserve
 972
 973   ModReserve({ rank => $rank,
 974                reserve_id => $reserve_id,
 975                branchcode => $branchcode
 976                [, itemnumber => $itemnumber ]
 977                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
 978               });
 979
 980 Change a hold request's priority or cancel it.
 981
 982 C<$rank> specifies the effect of the change.  If C<$rank>
 983 is 'W' or 'n', nothing happens.  This corresponds to leaving a
 984 request alone when changing its priority in the holds queue
 985 for a bib.
 986
 987 If C<$rank> is 'del', the hold request is cancelled.
 988
 989 If C<$rank> is an integer greater than zero, the priority of
 990 the request is set to that value.  Since priority != 0 means
 991 that the item is not waiting on the hold shelf, setting the
 992 priority to a non-zero value also sets the request's found
 993 status and waiting date to NULL.
 994
 995 The optional C<$itemnumber> parameter is used only when
 996 C<$rank> is a non-zero integer; if supplied, the itemnumber
 997 of the hold request is set accordingly; if omitted, the itemnumber
 998 is cleared.
 999
1000 B<FIXME:> Note that the forgoing can have the effect of causing
1001 item-level hold requests to turn into title-level requests.  This
1002 will be fixed once reserves has separate columns for requested
1003 itemnumber and supplying itemnumber.
1004
1005 =cut
1006
1007 sub ModReserve {
1008     my ( $params ) = @_;
1009
1010     my $rank = $params->{'rank'};
1011     my $reserve_id = $params->{'reserve_id'};
1012     my $branchcode = $params->{'branchcode'};
1013     my $itemnumber = $params->{'itemnumber'};
1014     my $suspend_until = $params->{'suspend_until'};
1015     my $borrowernumber = $params->{'borrowernumber'};
1016     my $biblionumber = $params->{'biblionumber'};
1017     my $cancellation_reason = $params->{'cancellation_reason'};
1018
1019     return if $rank eq "W";
1020     return if $rank eq "n";
1021
1022     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
1023
1024     my $hold;
1025     unless ( $reserve_id ) {
1026         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
1027         return unless $holds->count; # FIXME Should raise an exception
1028         $hold = $holds->next;
1029         $reserve_id = $hold->reserve_id;
1030     }
1031
1032     $hold ||= Koha::Holds->find($reserve_id);
1033
1034     if ( $rank eq "del" ) {
1035         $hold->cancel({ cancellation_reason => $cancellation_reason });
1036     }
1037     elsif ($rank =~ /^\d+/ and $rank > 0) {
1038         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
1039             if C4::Context->preference('HoldsLog');
1040
1041         my $properties = {
1042             priority    => $rank,
1043             branchcode  => $branchcode,
1044             itemnumber  => $itemnumber,
1045             found       => undef,
1046             waitingdate => undef
1047         };
1048         if (exists $params->{reservedate}) {
1049             $properties->{reservedate} = $params->{reservedate} || undef;
1050         }
1051         if (exists $params->{expirationdate}) {
1052             $properties->{expirationdate} = $params->{expirationdate} || undef;
1053         }
1054
1055         $hold->set($properties)->store();
1056
1057         if ( defined( $suspend_until ) ) {
1058             if ( $suspend_until ) {
1059                 $suspend_until = eval { dt_from_string( $suspend_until ) };
1060                 $hold->suspend_hold( $suspend_until );
1061             } else {
1062                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
1063                 # If the hold is not suspended, this does nothing.
1064                 $hold->set( { suspend_until => undef } )->store();
1065             }
1066         }
1067
1068         _FixPriority({ reserve_id => $reserve_id, rank =>$rank });
1069     }
1070 }
1071
1072 =head2 ModReserveFill
1073
1074   &ModReserveFill($reserve);
1075
1076 Fill a reserve. If I understand this correctly, this means that the
1077 reserved book has been found and given to the patron who reserved it.
1078
1079 C<$reserve> specifies the reserve to fill. It is a reference-to-hash
1080 whose keys are fields from the reserves table in the Koha database.
1081
1082 =cut
1083
1084 sub ModReserveFill {
1085     my ($res) = @_;
1086     my $reserve_id = $res->{'reserve_id'};
1087
1088     my $hold = Koha::Holds->find($reserve_id);
1089     # get the priority on this record....
1090     my $priority = $hold->priority;
1091
1092     # update the hold statuses, no need to store it though, we will be deleting it anyway
1093     $hold->set(
1094         {
1095             found    => 'F',
1096             priority => 0,
1097         }
1098     );
1099
1100     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
1101         if C4::Context->preference('HoldsLog');
1102
1103     # FIXME Must call Koha::Hold->cancel ? => No, should call ->filled and add the correct log
1104     Koha::Old::Hold->new( $hold->unblessed() )->store();
1105
1106     $hold->delete();
1107
1108     if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
1109         my $reserve_fee = GetReserveFee( $hold->borrowernumber, $hold->biblionumber );
1110         ChargeReserveFee( $hold->borrowernumber, $reserve_fee, $hold->biblio->title );
1111     }
1112
1113     # now fix the priority on the others (if the priority wasn't
1114     # already sorted!)....
1115     unless ( $priority == 0 ) {
1116         _FixPriority( { reserve_id => $reserve_id, biblionumber => $hold->biblionumber } );
1117     }
1118 }
1119
1120 =head2 ModReserveStatus
1121
1122   &ModReserveStatus($itemnumber, $newstatus);
1123
1124 Update the reserve status for the active (priority=0) reserve.
1125
1126 $itemnumber is the itemnumber the reserve is on
1127
1128 $newstatus is the new status.
1129
1130 =cut
1131
1132 sub ModReserveStatus {
1133
1134     #first : check if we have a reservation for this item .
1135     my ($itemnumber, $newstatus) = @_;
1136     my $dbh = C4::Context->dbh;
1137
1138     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
1139     my $sth_set = $dbh->prepare($query);
1140     $sth_set->execute( $newstatus, $itemnumber );
1141
1142     my $item = Koha::Items->find($itemnumber);
1143     if ( $item->location && $item->location eq 'CART'
1144         && ( !$item->permanent_location || $item->permanent_location ne 'CART' )
1145         && $newstatus ) {
1146       CartToShelf( $itemnumber );
1147     }
1148 }
1149
1150 =head2 ModReserveAffect
1151
1152   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id, $desk_id);
1153
1154 This function affect an item and a status for a given reserve, either fetched directly
1155 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
1156 is given, only first reserve returned is affected, which is ok for anything but
1157 multi-item holds.
1158
1159 if $transferToDo is not set, then the status is set to "Waiting" as well.
1160 otherwise, a transfer is on the way, and the end of the transfer will
1161 take care of the waiting status
1162
1163 This function also removes any entry of the hold in holds queue table.
1164
1165 =cut
1166
1167 sub ModReserveAffect {
1168     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id, $desk_id ) = @_;
1169     my $dbh = C4::Context->dbh;
1170
1171     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
1172     # attached to $itemnumber
1173     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
1174     $sth->execute($itemnumber);
1175     my ($biblionumber) = $sth->fetchrow;
1176
1177     # get request - need to find out if item is already
1178     # waiting in order to not send duplicate hold filled notifications
1179
1180     my $hold;
1181     # Find hold by id if we have it
1182     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
1183     # Find item level hold for this item if there is one
1184     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1185     # Find record level hold if there is no item level hold
1186     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1187
1188     return unless $hold;
1189
1190     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1191
1192     $hold->itemnumber($itemnumber);
1193
1194     if ($transferToDo) {
1195         $hold->set_transfer();
1196     } elsif (C4::Context->preference('HoldsNeedProcessingSIP')
1197              && C4::Context->interface eq 'sip'
1198              && !$already_on_shelf) {
1199         $hold->set_processing();
1200     } else {
1201         $hold->set_waiting($desk_id);
1202         _koha_notify_reserve( $hold->reserve_id ) unless $already_on_shelf;
1203         # Complete transfer if one exists
1204         my $transfer = $hold->item->get_transfer;
1205         $transfer->receive if $transfer;
1206     }
1207
1208     _FixPriority( { biblionumber => $biblionumber } );
1209     my $item = Koha::Items->find($itemnumber);
1210     if ( $item->location && $item->location eq 'CART'
1211         && ( !$item->permanent_location || $item->permanent_location ne 'CART' ) ) {
1212       CartToShelf( $itemnumber );
1213     }
1214
1215     my $std = $dbh->prepare(q{
1216         DELETE  q, t
1217         FROM    tmp_holdsqueue q
1218         INNER JOIN hold_fill_targets t
1219         ON  q.borrowernumber = t.borrowernumber
1220             AND q.biblionumber = t.biblionumber
1221             AND q.itemnumber = t.itemnumber
1222             AND q.item_level_request = t.item_level_request
1223             AND q.holdingbranch = t.source_branchcode
1224         WHERE t.reserve_id = ?
1225     });
1226     $std->execute($hold->reserve_id);
1227
1228     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->get_from_storage->unblessed) )
1229         if C4::Context->preference('HoldsLog');
1230
1231     return;
1232 }
1233
1234 =head2 ModReserveCancelAll
1235
1236   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber,$reason);
1237
1238 function to cancel reserv,check other reserves, and transfer document if it's necessary
1239
1240 =cut
1241
1242 sub ModReserveCancelAll {
1243     my $messages;
1244     my $nextreservinfo;
1245     my ( $itemnumber, $borrowernumber, $cancellation_reason ) = @_;
1246
1247     #step 1 : cancel the reservation
1248     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1249     return unless $holds->count;
1250     $holds->next->cancel({ cancellation_reason => $cancellation_reason });
1251
1252     #step 2 launch the subroutine of the others reserves
1253     ( $messages, $nextreservinfo ) = GetOtherReserves($itemnumber);
1254
1255     return ( $messages, $nextreservinfo->{borrowernumber} );
1256 }
1257
1258 =head2 ModReserveMinusPriority
1259
1260   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1261
1262 Reduce the values of queued list
1263
1264 =cut
1265
1266 sub ModReserveMinusPriority {
1267     my ( $itemnumber, $reserve_id ) = @_;
1268
1269     #first step update the value of the first person on reserv
1270     my $dbh   = C4::Context->dbh;
1271     my $query = "
1272         UPDATE reserves
1273         SET    priority = 0 , itemnumber = ?
1274         WHERE  reserve_id = ?
1275     ";
1276     my $sth_upd = $dbh->prepare($query);
1277     $sth_upd->execute( $itemnumber, $reserve_id );
1278     # second step update all others reserves
1279     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1280 }
1281
1282 =head2 IsAvailableForItemLevelRequest
1283
1284   my $is_available = IsAvailableForItemLevelRequest( $item_record, $borrower_record, $pickup_branchcode );
1285
1286 Checks whether a given item record is available for an
1287 item-level hold request.  An item is available if
1288
1289 * it is not lost AND
1290 * it is not damaged AND
1291 * it is not withdrawn AND
1292 * a waiting or in transit reserve is placed on
1293 * does not have a not for loan value > 0
1294
1295 Need to check the issuingrules onshelfholds column,
1296 if this is set items on the shelf can be placed on hold
1297
1298 Note that IsAvailableForItemLevelRequest() does not
1299 check if the staff operator is authorized to place
1300 a request on the item - in particular,
1301 this routine does not check IndependentBranches
1302 and canreservefromotherbranches.
1303
1304 Note also that this subroutine does not checks smart
1305 rules limits for item by reservesallowed/holds_per_record
1306 values, this complemented in calling code with calls and
1307 checks with CanItemBeReserved or CanBookBeReserved.
1308
1309 =cut
1310
1311 sub IsAvailableForItemLevelRequest {
1312     my $item                = shift;
1313     my $patron              = shift;
1314     my $pickup_branchcode   = shift;
1315     # items_any_available is precalculated status passed from request.pl when set of items
1316     # looped outside of IsAvailableForItemLevelRequest to avoid nested loops:
1317     my $items_any_available = shift;
1318
1319     my $dbh = C4::Context->dbh;
1320     # must check the notforloan setting of the itemtype
1321     # FIXME - a lot of places in the code do this
1322     #         or something similar - need to be
1323     #         consolidated
1324     my $itemtype = $item->effective_itemtype;
1325     my $notforloan_per_itemtype = Koha::ItemTypes->find($itemtype)->notforloan;
1326
1327     return 0 if
1328         $notforloan_per_itemtype ||
1329         $item->itemlost        ||
1330         $item->notforloan > 0  || # item with negative or zero notforloan value is holdable
1331         $item->withdrawn        ||
1332         ($item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1333
1334     if ($pickup_branchcode) {
1335         my $destination = Koha::Libraries->find($pickup_branchcode);
1336         return 0 unless $destination;
1337         return 0 unless $destination->pickup_location;
1338         return 0 unless $item->can_be_transferred( { to => $destination } );
1339         my $reserves_control_branch =
1340             GetReservesControlBranch( $item->unblessed(), $patron->unblessed() );
1341         my $branchitemrule =
1342             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype );
1343         my $home_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
1344         return 0 unless $branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $home_library->validate_hold_sibling( {branchcode => $pickup_branchcode} );
1345     }
1346
1347     my $on_shelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
1348
1349     if ( $on_shelf_holds == 1 ) {
1350         return 1;
1351     } elsif ( $on_shelf_holds == 2 ) {
1352
1353         # if we have this param predefined from outer caller sub, we just need
1354         # to return it, so we saving from having loop inside other loop:
1355         return  $items_any_available ? 0 : 1
1356             if defined $items_any_available;
1357
1358         my $any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron });
1359         return $any_available ? 0 : 1;
1360     } else { # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1361         return $item->onloan || IsItemOnHoldAndFound( $item->itemnumber );
1362     }
1363 }
1364
1365 =head2 ItemsAnyAvailableAndNotRestricted
1366
1367   ItemsAnyAvailableAndNotRestricted( { biblionumber => $biblionumber, patron => $patron });
1368
1369 This function checks all items for specified biblionumber (numeric) against patron (object)
1370 and returns true (1) if at least one item available for loan/check out/present/not held
1371 and also checks other parameters logic which not restricts item for hold at all (for ex.
1372 AllowHoldsOnDamagedItems or 'holdallowed' own/sibling library)
1373
1374 =cut
1375
1376 sub ItemsAnyAvailableAndNotRestricted {
1377     my $param = shift;
1378
1379     my @items = Koha::Items->search( { biblionumber => $param->{biblionumber} } );
1380
1381     foreach my $i (@items) {
1382         my $reserves_control_branch =
1383             GetReservesControlBranch( $i->unblessed(), $param->{patron}->unblessed );
1384         my $branchitemrule =
1385             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $i->itype );
1386         my $item_library = Koha::Libraries->find( { branchcode => $i->homebranch } );
1387
1388         # we can return (end the loop) when first one found:
1389         return 1
1390             unless $i->itemlost
1391             || $i->notforloan # items with non-zero notforloan cannot be checked out
1392             || $i->withdrawn
1393             || $i->onloan
1394             || IsItemOnHoldAndFound( $i->id )
1395             || ( $i->damaged
1396                  && ! C4::Context->preference('AllowHoldsOnDamagedItems') )
1397             || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1398             || $branchitemrule->{holdallowed} == 1 && $param->{patron}->branchcode ne $i->homebranch
1399             || $branchitemrule->{holdallowed} == 3 && ! $item_library->validate_hold_sibling( { branchcode => $param->{patron}->branchcode } )
1400             || CanItemBeReserved( $param->{patron}->borrowernumber, $i->id )->{status} ne 'OK';
1401     }
1402
1403     return 0;
1404 }
1405
1406 =head2 AlterPriority
1407
1408   AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
1409
1410 This function changes a reserve's priority up, down, to the top, or to the bottom.
1411 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1412
1413 =cut
1414
1415 sub AlterPriority {
1416     my ( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority ) = @_;
1417
1418     my $hold = Koha::Holds->find( $reserve_id );
1419     return unless $hold;
1420
1421     if ( $hold->cancellationdate ) {
1422         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1423         return;
1424     }
1425
1426     if ( $where eq 'up' ) {
1427       return unless $prev_priority;
1428       _FixPriority({ reserve_id => $reserve_id, rank => $prev_priority })
1429     } elsif ( $where eq 'down' ) {
1430       return unless $next_priority;
1431       _FixPriority({ reserve_id => $reserve_id, rank => $next_priority })
1432     } elsif ( $where eq 'top' ) {
1433       _FixPriority({ reserve_id => $reserve_id, rank => $first_priority })
1434     } elsif ( $where eq 'bottom' ) {
1435       _FixPriority({ reserve_id => $reserve_id, rank => $last_priority });
1436     }
1437
1438     # FIXME Should return the new priority
1439 }
1440
1441 =head2 ToggleLowestPriority
1442
1443   ToggleLowestPriority( $borrowernumber, $biblionumber );
1444
1445 This function sets the lowestPriority field to true if is false, and false if it is true.
1446
1447 =cut
1448
1449 sub ToggleLowestPriority {
1450     my ( $reserve_id ) = @_;
1451
1452     my $dbh = C4::Context->dbh;
1453
1454     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1455     $sth->execute( $reserve_id );
1456
1457     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1458 }
1459
1460 =head2 ToggleSuspend
1461
1462   ToggleSuspend( $reserve_id );
1463
1464 This function sets the suspend field to true if is false, and false if it is true.
1465 If the reserve is currently suspended with a suspend_until date, that date will
1466 be cleared when it is unsuspended.
1467
1468 =cut
1469
1470 sub ToggleSuspend {
1471     my ( $reserve_id, $suspend_until ) = @_;
1472
1473     $suspend_until = dt_from_string($suspend_until) if ($suspend_until);
1474
1475     my $hold = Koha::Holds->find( $reserve_id );
1476
1477     if ( $hold->is_suspended ) {
1478         $hold->resume()
1479     } else {
1480         $hold->suspend_hold( $suspend_until );
1481     }
1482 }
1483
1484 =head2 SuspendAll
1485
1486   SuspendAll(
1487       borrowernumber   => $borrowernumber,
1488       [ biblionumber   => $biblionumber, ]
1489       [ suspend_until  => $suspend_until, ]
1490       [ suspend        => $suspend ]
1491   );
1492
1493   This function accepts a set of hash keys as its parameters.
1494   It requires either borrowernumber or biblionumber, or both.
1495
1496   suspend_until is wholly optional.
1497
1498 =cut
1499
1500 sub SuspendAll {
1501     my %params = @_;
1502
1503     my $borrowernumber = $params{'borrowernumber'} || undef;
1504     my $biblionumber   = $params{'biblionumber'}   || undef;
1505     my $suspend_until  = $params{'suspend_until'}  || undef;
1506     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1507
1508     $suspend_until = eval { dt_from_string($suspend_until) }
1509       if ( defined($suspend_until) );
1510
1511     return unless ( $borrowernumber || $biblionumber );
1512
1513     my $params;
1514     $params->{found}          = undef;
1515     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1516     $params->{biblionumber}   = $biblionumber if $biblionumber;
1517
1518     my @holds = Koha::Holds->search($params);
1519
1520     if ($suspend) {
1521         map { $_->suspend_hold($suspend_until) } @holds;
1522     }
1523     else {
1524         map { $_->resume() } @holds;
1525     }
1526 }
1527
1528
1529 =head2 _FixPriority
1530
1531   _FixPriority({
1532     reserve_id => $reserve_id,
1533     [rank => $rank,]
1534     [ignoreSetLowestRank => $ignoreSetLowestRank]
1535   });
1536
1537   or
1538
1539   _FixPriority({ biblionumber => $biblionumber});
1540
1541 This routine adjusts the priority of a hold request and holds
1542 on the same bib.
1543
1544 In the first form, where a reserve_id is passed, the priority of the
1545 hold is set to supplied rank, and other holds for that bib are adjusted
1546 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1547 is supplied, all of the holds on that bib have their priority adjusted
1548 as if the second form had been used.
1549
1550 In the second form, where a biblionumber is passed, the holds on that
1551 bib (that are not captured) are sorted in order of increasing priority,
1552 then have reserves.priority set so that the first non-captured hold
1553 has its priority set to 1, the second non-captured hold has its priority
1554 set to 2, and so forth.
1555
1556 In both cases, holds that have the lowestPriority flag on are have their
1557 priority adjusted to ensure that they remain at the end of the line.
1558
1559 Note that the ignoreSetLowestRank parameter is meant to be used only
1560 when _FixPriority calls itself.
1561
1562 =cut
1563
1564 sub _FixPriority {
1565     my ( $params ) = @_;
1566     my $reserve_id = $params->{reserve_id};
1567     my $rank = $params->{rank} // '';
1568     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1569     my $biblionumber = $params->{biblionumber};
1570
1571     my $dbh = C4::Context->dbh;
1572
1573     my $hold;
1574     if ( $reserve_id ) {
1575         $hold = Koha::Holds->find( $reserve_id );
1576         if (!defined $hold){
1577             # may have already been checked out and hold fulfilled
1578             $hold = Koha::Old::Holds->find( $reserve_id );
1579         }
1580         return unless $hold;
1581     }
1582
1583     unless ( $biblionumber ) { # FIXME This is a very weird API
1584         $biblionumber = $hold->biblionumber;
1585     }
1586
1587     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1588         $hold->cancel;
1589     }
1590     elsif ( $reserve_id && ( $rank eq "W" || $rank eq "0" ) ) {
1591
1592         # make sure priority for waiting or in-transit items is 0
1593         my $query = "
1594             UPDATE reserves
1595             SET    priority = 0
1596             WHERE reserve_id = ?
1597             AND found IN ('W', 'T', 'P')
1598         ";
1599         my $sth = $dbh->prepare($query);
1600         $sth->execute( $reserve_id );
1601     }
1602     my @priority;
1603
1604     # get whats left
1605     my $query = "
1606         SELECT reserve_id, borrowernumber, reservedate
1607         FROM   reserves
1608         WHERE  biblionumber   = ?
1609           AND  ((found <> 'W' AND found <> 'T' AND found <> 'P') OR found IS NULL)
1610         ORDER BY priority ASC
1611     ";
1612     my $sth = $dbh->prepare($query);
1613     $sth->execute( $biblionumber );
1614     while ( my $line = $sth->fetchrow_hashref ) {
1615         push( @priority,     $line );
1616     }
1617
1618     # FIXME This whole sub must be rewritten, especially to highlight what is done when reserve_id is not given
1619     # To find the matching index
1620     my $i;
1621     my $key = -1;    # to allow for 0 to be a valid result
1622     for ( $i = 0 ; $i < @priority ; $i++ ) {
1623         if ( $reserve_id && $reserve_id == $priority[$i]->{'reserve_id'} ) {
1624             $key = $i;    # save the index
1625             last;
1626         }
1627     }
1628
1629     # if index exists in array then move it to new position
1630     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1631         my $new_rank = $rank -
1632           1;    # $new_rank is what you want the new index to be in the array
1633         my $moving_item = splice( @priority, $key, 1 );
1634         splice( @priority, $new_rank, 0, $moving_item );
1635     }
1636
1637     # now fix the priority on those that are left....
1638     $query = "
1639         UPDATE reserves
1640         SET    priority = ?
1641         WHERE  reserve_id = ?
1642     ";
1643     $sth = $dbh->prepare($query);
1644     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1645         $sth->execute(
1646             $j + 1,
1647             $priority[$j]->{'reserve_id'}
1648         );
1649     }
1650
1651     $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 ORDER BY priority" );
1652     $sth->execute();
1653
1654     unless ( $ignoreSetLowestRank ) {
1655       while ( my $res = $sth->fetchrow_hashref() ) {
1656         _FixPriority({
1657             reserve_id => $res->{'reserve_id'},
1658             rank => '999999',
1659             ignoreSetLowestRank => 1
1660         });
1661       }
1662     }
1663 }
1664
1665 =head2 _Findgroupreserve
1666
1667   @results = &_Findgroupreserve($biblioitemnumber, $biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1668
1669 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1670 first match found.  If neither, then we look for non-holds-queue based holds.
1671 Lookahead is the number of days to look in advance.
1672
1673 C<&_Findgroupreserve> returns :
1674 C<@results> is an array of references-to-hash whose keys are mostly
1675 fields from the reserves table of the Koha database, plus
1676 C<biblioitemnumber>.
1677
1678 This routine with either return:
1679 1 - Item specific holds from the holds queue
1680 2 - Title level holds from the holds queue
1681 3 - All holds for this biblionumber
1682
1683 All return values will respect any borrowernumbers passed as arrayref in $ignore_borrowers
1684
1685 =cut
1686
1687 sub _Findgroupreserve {
1688     my ( $bibitem, $biblio, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1689     my $dbh   = C4::Context->dbh;
1690
1691     # TODO: consolidate at least the SELECT portion of the first 2 queries to a common $select var.
1692     # check for exact targeted match
1693     my $item_level_target_query = qq{
1694         SELECT reserves.biblionumber        AS biblionumber,
1695                reserves.borrowernumber      AS borrowernumber,
1696                reserves.reservedate         AS reservedate,
1697                reserves.branchcode          AS branchcode,
1698                reserves.cancellationdate    AS cancellationdate,
1699                reserves.found               AS found,
1700                reserves.reservenotes        AS reservenotes,
1701                reserves.priority            AS priority,
1702                reserves.timestamp           AS timestamp,
1703                biblioitems.biblioitemnumber AS biblioitemnumber,
1704                reserves.itemnumber          AS itemnumber,
1705                reserves.reserve_id          AS reserve_id,
1706                reserves.itemtype            AS itemtype,
1707                reserves.non_priority        AS non_priority
1708         FROM reserves
1709         JOIN biblioitems USING (biblionumber)
1710         JOIN hold_fill_targets USING (reserve_id)
1711         WHERE found IS NULL
1712         AND priority > 0
1713         AND item_level_request = 1
1714         AND hold_fill_targets.itemnumber = ?
1715         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1716         AND suspend = 0
1717         ORDER BY priority
1718     };
1719     my $sth = $dbh->prepare($item_level_target_query);
1720     $sth->execute($itemnumber, $lookahead||0);
1721     my @results;
1722     if ( my $data = $sth->fetchrow_hashref ) {
1723         push( @results, $data )
1724           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1725     }
1726     return @results if @results;
1727
1728     # check for title-level targeted match
1729     my $title_level_target_query = qq{
1730         SELECT reserves.biblionumber        AS biblionumber,
1731                reserves.borrowernumber      AS borrowernumber,
1732                reserves.reservedate         AS reservedate,
1733                reserves.branchcode          AS branchcode,
1734                reserves.cancellationdate    AS cancellationdate,
1735                reserves.found               AS found,
1736                reserves.reservenotes        AS reservenotes,
1737                reserves.priority            AS priority,
1738                reserves.timestamp           AS timestamp,
1739                biblioitems.biblioitemnumber AS biblioitemnumber,
1740                reserves.itemnumber          AS itemnumber,
1741                reserves.reserve_id          AS reserve_id,
1742                reserves.itemtype            AS itemtype,
1743                reserves.non_priority        AS non_priority
1744         FROM reserves
1745         JOIN biblioitems USING (biblionumber)
1746         JOIN hold_fill_targets USING (reserve_id)
1747         WHERE found IS NULL
1748         AND priority > 0
1749         AND item_level_request = 0
1750         AND hold_fill_targets.itemnumber = ?
1751         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1752         AND suspend = 0
1753         ORDER BY priority
1754     };
1755     $sth = $dbh->prepare($title_level_target_query);
1756     $sth->execute($itemnumber, $lookahead||0);
1757     @results = ();
1758     if ( my $data = $sth->fetchrow_hashref ) {
1759         push( @results, $data )
1760           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1761     }
1762     return @results if @results;
1763
1764     my $query = qq{
1765         SELECT reserves.biblionumber               AS biblionumber,
1766                reserves.borrowernumber             AS borrowernumber,
1767                reserves.reservedate                AS reservedate,
1768                reserves.waitingdate                AS waitingdate,
1769                reserves.branchcode                 AS branchcode,
1770                reserves.cancellationdate           AS cancellationdate,
1771                reserves.found                      AS found,
1772                reserves.reservenotes               AS reservenotes,
1773                reserves.priority                   AS priority,
1774                reserves.timestamp                  AS timestamp,
1775                reserves.itemnumber                 AS itemnumber,
1776                reserves.reserve_id                 AS reserve_id,
1777                reserves.itemtype                   AS itemtype,
1778                reserves.non_priority        AS non_priority
1779         FROM reserves
1780         WHERE reserves.biblionumber = ?
1781           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1782           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1783           AND suspend = 0
1784           ORDER BY priority
1785     };
1786     $sth = $dbh->prepare($query);
1787     $sth->execute( $biblio, $itemnumber, $lookahead||0);
1788     @results = ();
1789     while ( my $data = $sth->fetchrow_hashref ) {
1790         push( @results, $data )
1791           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1792     }
1793     return @results;
1794 }
1795
1796 =head2 _koha_notify_reserve
1797
1798   _koha_notify_reserve( $hold->reserve_id );
1799
1800 Sends a notification to the patron that their hold has been filled (through
1801 ModReserveAffect, _not_ ModReserveFill)
1802
1803 The letter code for this notice may be found using the following query:
1804
1805     select distinct letter_code
1806     from message_transports
1807     inner join message_attributes using (message_attribute_id)
1808     where message_name = 'Hold_Filled'
1809
1810 This will probably sipmly be 'HOLD', but because it is defined in the database,
1811 it is subject to addition or change.
1812
1813 The following tables are availalbe witin the notice:
1814
1815     branches
1816     borrowers
1817     biblio
1818     biblioitems
1819     reserves
1820     items
1821
1822 =cut
1823
1824 sub _koha_notify_reserve {
1825     my $reserve_id = shift;
1826     my $hold = Koha::Holds->find($reserve_id);
1827     my $borrowernumber = $hold->borrowernumber;
1828
1829     my $patron = Koha::Patrons->find( $borrowernumber );
1830
1831     # Try to get the borrower's email address
1832     my $to_address = $patron->notice_email_address;
1833
1834     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1835             borrowernumber => $borrowernumber,
1836             message_name => 'Hold_Filled'
1837     } );
1838
1839     my $library = Koha::Libraries->find( $hold->branchcode )->unblessed;
1840
1841     my $admin_email_address = $library->{branchemail} || C4::Context->preference('KohaAdminEmailAddress');
1842
1843     my %letter_params = (
1844         module => 'reserves',
1845         branchcode => $hold->branchcode,
1846         lang => $patron->lang,
1847         tables => {
1848             'branches'       => $library,
1849             'borrowers'      => $patron->unblessed,
1850             'biblio'         => $hold->biblionumber,
1851             'biblioitems'    => $hold->biblionumber,
1852             'reserves'       => $hold->unblessed,
1853             'items'          => $hold->itemnumber,
1854         },
1855     );
1856
1857     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1858     my $send_notification = sub {
1859         my ( $mtt, $letter_code ) = (@_);
1860         return unless defined $letter_code;
1861         $letter_params{letter_code} = $letter_code;
1862         $letter_params{message_transport_type} = $mtt;
1863         my $letter =  C4::Letters::GetPreparedLetter ( %letter_params );
1864         unless ($letter) {
1865             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1866             return;
1867         }
1868
1869         C4::Letters::EnqueueLetter( {
1870             letter => $letter,
1871             borrowernumber => $borrowernumber,
1872             from_address => $admin_email_address,
1873             message_transport_type => $mtt,
1874         } );
1875     };
1876
1877     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1878         next if (
1879                ( $mtt eq 'email' and not $to_address ) # No email address
1880             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1881             or ( $mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1882             or ( $mtt eq 'phone' and not $patron->phone ) # No phone number to call
1883         );
1884
1885         &$send_notification($mtt, $letter_code);
1886         $notification_sent++;
1887     }
1888     #Making sure that a print notification is sent if no other transport types can be utilized.
1889     if (! $notification_sent) {
1890         &$send_notification('print', 'HOLD');
1891     }
1892
1893 }
1894
1895 =head2 _ShiftPriorityByDateAndPriority
1896
1897   $new_priority = _ShiftPriorityByDateAndPriority( $biblionumber, $reservedate, $priority );
1898
1899 This increments the priority of all reserves after the one
1900 with either the lowest date after C<$reservedate>
1901 or the lowest priority after C<$priority>.
1902
1903 It effectively makes room for a new reserve to be inserted with a certain
1904 priority, which is returned.
1905
1906 This is most useful when the reservedate can be set by the user.  It allows
1907 the new reserve to be placed before other reserves that have a later
1908 reservedate.  Since priority also is set by the form in reserves/request.pl
1909 the sub accounts for that too.
1910
1911 =cut
1912
1913 sub _ShiftPriorityByDateAndPriority {
1914     my ( $biblio, $resdate, $new_priority ) = @_;
1915
1916     my $dbh = C4::Context->dbh;
1917     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND ( reservedate > ? OR priority > ? ) ORDER BY priority ASC LIMIT 1";
1918     my $sth = $dbh->prepare( $query );
1919     $sth->execute( $biblio, $resdate, $new_priority );
1920     my $min_priority = $sth->fetchrow;
1921     # if no such matches are found, $new_priority remains as original value
1922     $new_priority = $min_priority if ( $min_priority );
1923
1924     # Shift the priority up by one; works in conjunction with the next SQL statement
1925     $query = "UPDATE reserves
1926               SET priority = priority+1
1927               WHERE biblionumber = ?
1928               AND borrowernumber = ?
1929               AND reservedate = ?
1930               AND found IS NULL";
1931     my $sth_update = $dbh->prepare( $query );
1932
1933     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
1934     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
1935     $sth = $dbh->prepare( $query );
1936     $sth->execute( $new_priority, $biblio );
1937     while ( my $row = $sth->fetchrow_hashref ) {
1938         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
1939     }
1940
1941     return $new_priority;  # so the caller knows what priority they wind up receiving
1942 }
1943
1944 =head2 MoveReserve
1945
1946   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
1947
1948 Use when checking out an item to handle reserves
1949 If $cancelreserve boolean is set to true, it will remove existing reserve
1950
1951 =cut
1952
1953 sub MoveReserve {
1954     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
1955
1956     $cancelreserve //= 0;
1957
1958     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
1959     my ( $restype, $res, undef ) = CheckReserves( $itemnumber, undef, $lookahead );
1960     return unless $res;
1961
1962     my $biblionumber     =  $res->{biblionumber};
1963
1964     if ($res->{borrowernumber} == $borrowernumber) {
1965         ModReserveFill($res);
1966     }
1967     else {
1968         # warn "Reserved";
1969         # The item is reserved by someone else.
1970         # Find this item in the reserves
1971
1972         my $borr_res  = Koha::Holds->search({
1973             borrowernumber => $borrowernumber,
1974             biblionumber   => $biblionumber,
1975         },{
1976             order_by       => 'priority'
1977         })->next();
1978
1979         if ( $borr_res ) {
1980             # The item is reserved by the current patron
1981             ModReserveFill($borr_res->unblessed);
1982         }
1983
1984         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
1985             RevertWaitingStatus({ itemnumber => $itemnumber });
1986         }
1987         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
1988             my $hold = Koha::Holds->find( $res->{reserve_id} );
1989             $hold->cancel;
1990         }
1991     }
1992 }
1993
1994 =head2 MergeHolds
1995
1996   MergeHolds($dbh,$to_biblio, $from_biblio);
1997
1998 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
1999
2000 =cut
2001
2002 sub MergeHolds {
2003     my ( $dbh, $to_biblio, $from_biblio ) = @_;
2004     my $sth = $dbh->prepare(
2005         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
2006     );
2007     $sth->execute($from_biblio);
2008     if ( my $data = $sth->fetchrow_hashref() ) {
2009
2010         # holds exist on old record, if not we don't need to do anything
2011         $sth = $dbh->prepare(
2012             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
2013         $sth->execute( $to_biblio, $from_biblio );
2014
2015         # Reorder by date
2016         # don't reorder those already waiting
2017
2018         $sth = $dbh->prepare(
2019 "SELECT * FROM reserves WHERE biblionumber = ? AND (found NOT IN ('W', 'T', 'P') OR found is NULL) ORDER BY reservedate ASC"
2020         );
2021         my $upd_sth = $dbh->prepare(
2022 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
2023         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
2024         );
2025         $sth->execute( $to_biblio );
2026         my $priority = 1;
2027         while ( my $reserve = $sth->fetchrow_hashref() ) {
2028             $upd_sth->execute(
2029                 $priority,                    $to_biblio,
2030                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
2031                 $reserve->{'itemnumber'}
2032             );
2033             $priority++;
2034         }
2035     }
2036 }
2037
2038 =head2 RevertWaitingStatus
2039
2040   RevertWaitingStatus({ itemnumber => $itemnumber });
2041
2042   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
2043
2044   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
2045           item level hold, even if it was only a bibliolevel hold to
2046           begin with. This is because we can no longer know if a hold
2047           was item-level or bib-level after a hold has been set to
2048           waiting status.
2049
2050 =cut
2051
2052 sub RevertWaitingStatus {
2053     my ( $params ) = @_;
2054     my $itemnumber = $params->{'itemnumber'};
2055
2056     return unless ( $itemnumber );
2057
2058     my $dbh = C4::Context->dbh;
2059
2060     ## Get the waiting reserve we want to revert
2061     my $hold = Koha::Holds->search(
2062         {
2063             itemnumber => $itemnumber,
2064             found => { not => undef },
2065         }
2066     )->next;
2067
2068     ## Increment the priority of all other non-waiting
2069     ## reserves for this bib record
2070     my $holds = Koha::Holds->search({ biblionumber => $hold->biblionumber, priority => { '>' => 0 } })
2071                            ->update({ priority => \'priority + 1' }, { no_triggers => 1 });
2072
2073     ## Fix up the currently waiting reserve
2074     $hold->set(
2075         {
2076             priority    => 1,
2077             found       => undef,
2078             waitingdate => undef,
2079             itemnumber  => $hold->item_level_hold ? $hold->itemnumber : undef,
2080         }
2081     )->store();
2082
2083     _FixPriority( { biblionumber => $hold->biblionumber } );
2084
2085     return $hold;
2086 }
2087
2088 =head2 ReserveSlip
2089
2090 ReserveSlip(
2091     {
2092         branchcode     => $branchcode,
2093         borrowernumber => $borrowernumber,
2094         biblionumber   => $biblionumber,
2095         [ itemnumber   => $itemnumber, ]
2096         [ barcode      => $barcode, ]
2097     }
2098   )
2099
2100 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
2101
2102 The letter code will be HOLD_SLIP, and the following tables are
2103 available within the slip:
2104
2105     reserves
2106     branches
2107     borrowers
2108     biblio
2109     biblioitems
2110     items
2111
2112 =cut
2113
2114 sub ReserveSlip {
2115     my ($args) = @_;
2116     my $branchcode     = $args->{branchcode};
2117     my $reserve_id = $args->{reserve_id};
2118
2119     my $hold = Koha::Holds->find($reserve_id);
2120     return unless $hold;
2121
2122     my $patron = $hold->borrower;
2123     my $reserve = $hold->unblessed;
2124
2125     return  C4::Letters::GetPreparedLetter (
2126         module => 'circulation',
2127         letter_code => 'HOLD_SLIP',
2128         branchcode => $branchcode,
2129         lang => $patron->lang,
2130         tables => {
2131             'reserves'    => $reserve,
2132             'branches'    => $reserve->{branchcode},
2133             'borrowers'   => $reserve->{borrowernumber},
2134             'biblio'      => $reserve->{biblionumber},
2135             'biblioitems' => $reserve->{biblionumber},
2136             'items'       => $reserve->{itemnumber},
2137         },
2138     );
2139 }
2140
2141 =head2 GetReservesControlBranch
2142
2143   my $reserves_control_branch = GetReservesControlBranch($item, $borrower);
2144
2145   Return the branchcode to be used to determine which reserves
2146   policy applies to a transaction.
2147
2148   C<$item> is a hashref for an item. Only 'homebranch' is used.
2149
2150   C<$borrower> is a hashref to borrower. Only 'branchcode' is used.
2151
2152 =cut
2153
2154 sub GetReservesControlBranch {
2155     my ( $item, $borrower ) = @_;
2156
2157     my $reserves_control = C4::Context->preference('ReservesControlBranch');
2158
2159     my $branchcode =
2160         ( $reserves_control eq 'ItemHomeLibrary' ) ? $item->{'homebranch'}
2161       : ( $reserves_control eq 'PatronLibrary' )   ? $borrower->{'branchcode'}
2162       :                                              undef;
2163
2164     return $branchcode;
2165 }
2166
2167 =head2 CalculatePriority
2168
2169     my $p = CalculatePriority($biblionumber, $resdate);
2170
2171 Calculate priority for a new reserve on biblionumber, placing it at
2172 the end of the line of all holds whose start date falls before
2173 the current system time and that are neither on the hold shelf
2174 or in transit.
2175
2176 The reserve date parameter is optional; if it is supplied, the
2177 priority is based on the set of holds whose start date falls before
2178 the parameter value.
2179
2180 After calculation of this priority, it is recommended to call
2181 _ShiftPriorityByDateAndPriority. Note that this is currently done in
2182 AddReserves.
2183
2184 =cut
2185
2186 sub CalculatePriority {
2187     my ( $biblionumber, $resdate ) = @_;
2188
2189     my $sql = q{
2190         SELECT COUNT(*) FROM reserves
2191         WHERE biblionumber = ?
2192         AND   priority > 0
2193         AND   (found IS NULL OR found = '')
2194     };
2195     #skip found==W or found==T or found==P (waiting, transit or processing holds)
2196     if( $resdate ) {
2197         $sql.= ' AND ( reservedate <= ? )';
2198     }
2199     else {
2200         $sql.= ' AND ( reservedate < NOW() )';
2201     }
2202     my $dbh = C4::Context->dbh();
2203     my @row = $dbh->selectrow_array(
2204         $sql,
2205         undef,
2206         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
2207     );
2208
2209     return @row ? $row[0]+1 : 1;
2210 }
2211
2212 =head2 IsItemOnHoldAndFound
2213
2214     my $bool = IsItemFoundHold( $itemnumber );
2215
2216     Returns true if the item is currently on hold
2217     and that hold has a non-null found status ( W, T, etc. )
2218
2219 =cut
2220
2221 sub IsItemOnHoldAndFound {
2222     my ($itemnumber) = @_;
2223
2224     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
2225
2226     my $found = $rs->count(
2227         {
2228             itemnumber => $itemnumber,
2229             found      => { '!=' => undef }
2230         }
2231     );
2232
2233     return $found;
2234 }
2235
2236 =head2 GetMaxPatronHoldsForRecord
2237
2238 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2239
2240 For multiple holds on a given record for a given patron, the max
2241 number of record level holds that a patron can be placed is the highest
2242 value of the holds_per_record rule for each item if the record for that
2243 patron. This subroutine finds and returns the highest holds_per_record
2244 rule value for a given patron id and record id.
2245
2246 =cut
2247
2248 sub GetMaxPatronHoldsForRecord {
2249     my ( $borrowernumber, $biblionumber ) = @_;
2250
2251     my $patron = Koha::Patrons->find($borrowernumber);
2252     my @items = Koha::Items->search( { biblionumber => $biblionumber } );
2253
2254     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2255
2256     my $categorycode = $patron->categorycode;
2257     my $branchcode;
2258     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2259
2260     my $max = 0;
2261     foreach my $item (@items) {
2262         my $itemtype = $item->effective_itemtype();
2263
2264         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2265
2266         my $rule = Koha::CirculationRules->get_effective_rule({
2267             categorycode => $categorycode,
2268             itemtype     => $itemtype,
2269             branchcode   => $branchcode,
2270             rule_name    => 'holds_per_record'
2271         });
2272         my $holds_per_record = $rule ? $rule->rule_value : 0;
2273         $max = $holds_per_record if $holds_per_record > $max;
2274     }
2275
2276     return $max;
2277 }
2278
2279 =head1 AUTHOR
2280
2281 Koha Development Team <http://koha-community.org/>
2282
2283 =cut
2284
2285 1;