C4/SIP/ILS/Patron.pm

   1 #
   2 # ILS::Patron.pm
   3 #
   4 # A Class for hiding the ILS's concept of the patron from the OpenSIP
   5 # system
   6 #
   7
   8 package C4::SIP::ILS::Patron;
   9
  10 use strict;
  11 use warnings;
  12 use Exporter;
  13 use Carp;
  14
  15 use Sys::Syslog qw(syslog);
  16 use Data::Dumper;
  17
  18 use C4::Debug;
  19 use C4::Context;
  20 use C4::Koha;
  21 use C4::Members;
  22 use C4::Reserves;
  23 use C4::Items qw( GetBarcodeFromItemnumber GetItemnumbersForBiblio);
  24 use C4::Auth qw(checkpw);
  25
  26 use Koha::Libraries;
  27 use Koha::Patrons;
  28
  29 our $kp;    # koha patron
  30
  31 sub new {
  32     my ($class, $patron_id) = @_;
  33     my $type = ref($class) || $class;
  34     my $self;
  35     $kp = Koha::Patrons->find( { cardnumber => $patron_id } )
  36       or Koha::Patrons->find( { userid => $patron_id } );
  37     $debug and warn "new Patron: " . Dumper($kp->unblessed) if $kp;
  38     unless ($kp) {
  39         syslog("LOG_DEBUG", "new ILS::Patron(%s): no such patron", $patron_id);
  40         return;
  41     }
  42     $kp = $kp->unblessed;
  43     my $pw        = $kp->{password};
  44     my $flags     = C4::Members::patronflags( $kp );
  45     my $debarred  = defined($flags->{DBARRED});
  46     $debug and warn sprintf("Debarred = %s : ", ($debarred||'undef')) . Dumper(%$flags);
  47     my ($day, $month, $year) = (localtime)[3,4,5];
  48     my $today    = sprintf '%04d-%02d-%02d', $year+1900, $month+1, $day;
  49     my $expired  = ($today gt $kp->{dateexpiry}) ? 1 : 0;
  50     if ($expired) {
  51         if ($kp->{opacnote} ) {
  52             $kp->{opacnote} .= q{ };
  53         }
  54         $kp->{opacnote} .= 'PATRON EXPIRED';
  55     }
  56     my %ilspatron;
  57     my $adr     = _get_address($kp);
  58     my $dob     = $kp->{dateofbirth};
  59     $dob and $dob =~ s/-//g;    # YYYYMMDD
  60     my $dexpiry     = $kp->{dateexpiry};
  61     $dexpiry and $dexpiry =~ s/-//g;    # YYYYMMDD
  62     my $fines_amount = $flags->{CHARGES}->{amount};
  63     $fines_amount = ($fines_amount and $fines_amount > 0) ? $fines_amount : 0;
  64     my $fee_limit = _fee_limit();
  65     my $fine_blocked = $fines_amount > $fee_limit;
  66     {
  67     no warnings;    # any of these $kp->{fields} being concat'd could be undef
  68     %ilspatron = (
  69         getmemberdetails_object => $kp,
  70         name => $kp->{firstname} . " " . $kp->{surname},
  71         id   => $kp->{cardnumber},    # to SIP, the id is the BARCODE, not userid
  72         password        => $pw,
  73         ptype           => $kp->{categorycode},     # 'A'dult.  Whatever.
  74         dateexpiry      => $dexpiry,
  75         dateexpiry_iso  => $kp->{dateexpiry},
  76         birthdate       => $dob,
  77         birthdate_iso   => $kp->{dateofbirth},
  78         branchcode      => $kp->{branchcode},
  79         library_name    => "",                      # only populated if needed, cached here
  80         borrowernumber  => $kp->{borrowernumber},
  81         address         => $adr,
  82         home_phone      => $kp->{phone},
  83         email_addr      => $kp->{email},
  84         charge_ok       => ( !$debarred && !$expired && !$fine_blocked),
  85         renew_ok        => ( !$debarred && !$expired && !$fine_blocked),
  86         recall_ok       => ( !$debarred && !$expired && !$fine_blocked),
  87         hold_ok         => ( !$debarred && !$expired && !$fine_blocked),
  88         card_lost       => ( $kp->{lost} || $kp->{gonenoaddress} || $flags->{LOST} ),
  89         claims_returned => 0,
  90         fines           => $fines_amount, # GetMemberAccountRecords($kp->{borrowernumber})
  91         fees            => 0,             # currently not distinct from fines
  92         recall_overdue  => 0,
  93         items_billed    => 0,
  94         screen_msg      => 'Greetings from Koha. ' . $kp->{opacnote},
  95         print_line      => '',
  96         items           => [],
  97         hold_items      => $flags->{WAITING}->{itemlist},
  98         overdue_items   => $flags->{ODUES}->{itemlist},
  99         fine_items      => [],
 100         recall_items    => [],
 101         unavail_holds   => [],
 102         inet            => ( !$debarred && !$expired ),
 103         expired         => $expired,
 104         fee_limit       => $fee_limit,
 105         userid          => $kp->{userid},
 106     );
 107     }
 108     $debug and warn "patron fines: $ilspatron{fines} ... amountoutstanding: $kp->{amountoutstanding} ... CHARGES->amount: $flags->{CHARGES}->{amount}";
 109     for (qw(EXPIRED CHARGES CREDITS GNA LOST DBARRED NOTES)) {
 110         ($flags->{$_}) or next;
 111         if ($_ ne 'NOTES' and $flags->{$_}->{message}) {
 112             $ilspatron{screen_msg} .= " -- " . $flags->{$_}->{message};  # show all but internal NOTES
 113         }
 114         if ($flags->{$_}->{noissues}) {
 115             foreach my $toggle (qw(charge_ok renew_ok recall_ok hold_ok inet)) {
 116                 $ilspatron{$toggle} = 0;    # if we get noissues, disable everything
 117             }
 118         }
 119     }
 120
 121     # FIXME: populate fine_items recall_items
 122     $ilspatron{unavail_holds} = _get_outstanding_holds($kp->{borrowernumber});
 123     $ilspatron{items} = GetPendingIssues($kp->{borrowernumber});
 124     $self = \%ilspatron;
 125     $debug and warn Dumper($self);
 126     syslog("LOG_DEBUG", "new ILS::Patron(%s): found patron '%s'", $patron_id,$self->{id});
 127     bless $self, $type;
 128     return $self;
 129 }
 130
 131
 132 # 0 means read-only
 133 # 1 means read/write
 134
 135 my %fields = (
 136     id                      => 0,
 137     name                    => 0,
 138     address                 => 0,
 139     email_addr              => 0,
 140     home_phone              => 0,
 141     birthdate               => 0,
 142     birthdate_iso           => 0,
 143     dateexpiry              => 0,
 144     dateexpiry_iso          => 0,
 145     ptype                   => 0,
 146     charge_ok               => 0,   # for patron_status[0] (inverted)
 147     renew_ok                => 0,   # for patron_status[1] (inverted)
 148     recall_ok               => 0,   # for patron_status[2] (inverted)
 149     hold_ok                 => 0,   # for patron_status[3] (inverted)
 150     card_lost               => 0,   # for patron_status[4]
 151     recall_overdue          => 0,
 152     currency                => 1,
 153     fee_limit               => 0,
 154     screen_msg              => 1,
 155     print_line              => 1,
 156     too_many_charged        => 0,   # for patron_status[5]
 157     too_many_overdue        => 0,   # for patron_status[6]
 158     too_many_renewal        => 0,   # for patron_status[7]
 159     too_many_claim_return   => 0,   # for patron_status[8]
 160     too_many_lost           => 0,   # for patron_status[9]
 161 #   excessive_fines         => 0,   # for patron_status[10]
 162 #   excessive_fees          => 0,   # for patron_status[11]
 163     recall_overdue          => 0,   # for patron_status[12]
 164     too_many_billed         => 0,   # for patron_status[13]
 165     inet                    => 0,   # EnvisionWare extension
 166     getmemberdetails_object => 0,
 167 );
 168
 169 our $AUTOLOAD;
 170
 171 sub DESTROY {
 172     # be cool.  needed for AUTOLOAD(?)
 173 }
 174
 175 sub AUTOLOAD {
 176     my $self = shift;
 177     my $class = ref($self) or croak "$self is not an object";
 178     my $name = $AUTOLOAD;
 179
 180     $name =~ s/.*://;
 181
 182     unless (exists $fields{$name}) {
 183         croak "Cannot access '$name' field of class '$class'";
 184     }
 185
 186     if (@_) {
 187         $fields{$name} or croak "Field '$name' of class '$class' is READ ONLY.";
 188         return $self->{$name} = shift;
 189     } else {
 190         return $self->{$name};
 191     }
 192 }
 193
 194 sub name {
 195     my ( $self, $template ) = @_;
 196
 197     if ($template) {
 198         require Template;
 199         require Koha::Patrons;
 200
 201         my $tt = Template->new();
 202
 203         my $patron = Koha::Patrons->find( $self->{borrowernumber} );
 204
 205         my $output;
 206         $tt->process( \$template, { patron => $patron }, \$output );
 207         return $output;
 208     }
 209     else {
 210         return $self->{name};
 211     }
 212 }
 213
 214 sub check_password {
 215     my ( $self, $pwd ) = @_;
 216
 217     # you gotta give me something (at least ''), or no deal
 218     return 0 unless defined $pwd;
 219
 220     # If the record has a NULL password, accept '' as match
 221     return $pwd eq q{} unless $self->{password};
 222
 223     my $dbh = C4::Context->dbh;
 224     my $ret = 0;
 225     ($ret) = checkpw( $dbh, $self->{userid}, $pwd, undef, undef, 1 ); # dbh, userid, query, type, no_set_userenv
 226     return $ret;
 227 }
 228
 229 # A few special cases, not in AUTOLOADed %fields
 230 sub fee_amount {
 231     my $self = shift;
 232     if ( $self->{fines} ) {
 233         return $self->{fines};
 234     }
 235     return;
 236 }
 237
 238 sub fines_amount {
 239     my $self = shift;
 240     return $self->fee_amount;
 241 }
 242
 243 sub language {
 244     my $self = shift;
 245     return $self->{language} || '000'; # Unspecified
 246 }
 247
 248 sub expired {
 249     my $self = shift;
 250     return $self->{expired};
 251 }
 252
 253 #
 254 # remove the hold on item item_id from my hold queue.
 255 # return true if I was holding the item, false otherwise.
 256 #
 257 sub drop_hold {
 258     my ($self, $item_id) = @_;
 259     return if !$item_id;
 260     my $result = 0;
 261     foreach (qw(hold_items unavail_holds)) {
 262         $self->{$_} or next;
 263         for (my $i = 0; $i < scalar @{$self->{$_}}; $i++) {
 264             my $held_item = $self->{$_}[$i]->{item_id} or next;
 265             if ($held_item eq $item_id) {
 266                 splice @{$self->{$_}}, $i, 1;
 267                 $result++;
 268             }
 269         }
 270     }
 271     return $result;
 272 }
 273
 274 # Accessor method for array_ref values, designed to get the "start" and "end" values
 275 # from the SIP request.  Note those incoming values are 1-indexed, not 0-indexed.
 276 #
 277 sub x_items {
 278     my $self      = shift;
 279     my $array_var = shift or return;
 280     my ($start, $end) = @_;
 281
 282     my $item_list = [];
 283     if ($self->{$array_var}) {
 284         if ($start && $start > 1) {
 285             --$start;
 286         }
 287         else {
 288             $start = 0;
 289         }
 290         if ( $end && $end < @{$self->{$array_var}} ) {
 291         }
 292         else {
 293             $end = @{$self->{$array_var}};
 294             --$end;
 295         }
 296         @{$item_list} = @{$self->{$array_var}}[ $start .. $end ];
 297
 298     }
 299     return $item_list;
 300 }
 301
 302 #
 303 # List of outstanding holds placed
 304 #
 305 sub hold_items {
 306     my $self = shift;
 307     my $item_arr = $self->x_items('hold_items', @_);
 308     foreach my $item (@{$item_arr}) {
 309         $item->{barcode} = GetBarcodeFromItemnumber($item->{itemnumber});
 310     }
 311     return $item_arr;
 312 }
 313
 314 sub overdue_items {
 315     my $self = shift;
 316     return $self->x_items('overdue_items', @_);
 317 }
 318 sub charged_items {
 319     my $self = shift;
 320     return $self->x_items('items', @_);
 321 }
 322 sub fine_items {
 323     require Koha::Database;
 324     require Template;
 325
 326     my $self = shift;
 327     my $start = shift;
 328     my $end = shift;
 329     my $server = shift;
 330
 331     my @fees = Koha::Database->new()->schema()->resultset('Accountline')->search(
 332         {
 333             borrowernumber    => $self->{borrowernumber},
 334             amountoutstanding => { '>' => '0' },
 335         }
 336     );
 337
 338     $start = $start ? $start - 1 : 0;
 339     $end   = $end   ? $end       : scalar @fees - 1;
 340
 341     my $av_field_template = $server ? $server->{account}->{av_field_template} : undef;
 342     $av_field_template ||= "[% accountline.description %] [% accountline.amountoutstanding | format('%.2f') %]";
 343
 344     my $tt = Template->new();
 345
 346     my @return_values;
 347     for ( my $i = $start; $i <= $end; $i++ ) {
 348         my $fee = $fees[$i];
 349
 350         my $output;
 351         $tt->process( \$av_field_template, { accountline => $fee }, \$output );
 352         push( @return_values, { barcode => $output } );
 353     }
 354
 355     return \@return_values;
 356 }
 357 sub recall_items {
 358     my $self = shift;
 359     return $self->x_items('recall_items', @_);
 360 }
 361 sub unavail_holds {
 362     my $self = shift;
 363     return $self->x_items('unavail_holds', @_);
 364 }
 365
 366 sub block {
 367     my ($self, $card_retained, $blocked_card_msg) = @_;
 368     foreach my $field ('charge_ok', 'renew_ok', 'recall_ok', 'hold_ok', 'inet') {
 369         $self->{$field} = 0;
 370     }
 371     $self->{screen_msg} = "Block feature not implemented";  # $blocked_card_msg || "Card Blocked.  Please contact library staff";
 372     # TODO: not really affecting patron record
 373     return $self;
 374 }
 375
 376 sub enable {
 377     my $self = shift;
 378     foreach my $field ('charge_ok', 'renew_ok', 'recall_ok', 'hold_ok', 'inet') {
 379         $self->{$field} = 1;
 380     }
 381     syslog("LOG_DEBUG", "Patron(%s)->enable: charge: %s, renew:%s, recall:%s, hold:%s",
 382        $self->{id}, $self->{charge_ok}, $self->{renew_ok},
 383        $self->{recall_ok}, $self->{hold_ok});
 384     $self->{screen_msg} = "Enable feature not implemented."; # "All privileges restored.";   # TODO: not really affecting patron record
 385     return $self;
 386 }
 387
 388 sub inet_privileges {
 389     my $self = shift;
 390     return $self->{inet} ? 'Y' : 'N';
 391 }
 392
 393 sub _fee_limit {
 394     return C4::Context->preference('noissuescharge') || 5;
 395 }
 396
 397 sub excessive_fees {
 398     my $self = shift;
 399     return ($self->fee_amount and $self->fee_amount > $self->fee_limit);
 400 }
 401
 402 sub excessive_fines {
 403     my $self = shift;
 404     return $self->excessive_fees;   # excessive_fines is the same thing as excessive_fees for Koha
 405 }
 406
 407 sub holds_blocked_by_excessive_fees {
 408     my $self = shift;
 409     return ( $self->fee_amount
 410           && $self->fee_amount > C4::Context->preference("maxoutstanding") );
 411 }
 412
 413 sub library_name {
 414     my $self = shift;
 415     unless ($self->{library_name}) {
 416         my $library = Koha::Libraries->find( $self->{branchcode} );
 417         $self->{library_name} = $library ? $library->branchname : '';
 418     }
 419     return $self->{library_name};
 420 }
 421 #
 422 # Messages
 423 #
 424
 425 sub invalid_patron {
 426     my $self = shift;
 427     return "Please contact library staff";
 428 }
 429
 430 sub charge_denied {
 431     my $self = shift;
 432     return "Please contact library staff";
 433 }
 434
 435 sub _get_address {
 436     my $patron = shift;
 437
 438     my $address = $patron->{streetnumber} || q{};
 439     for my $field (qw( roaddetails address address2 city state zipcode country))
 440     {
 441         next unless $patron->{$field};
 442         if ($address) {
 443             $address .= q{ };
 444             $address .= $patron->{$field};
 445         }
 446         else {
 447             $address .= $patron->{$field};
 448         }
 449     }
 450     return $address;
 451 }
 452
 453 sub _get_outstanding_holds {
 454     my $borrowernumber = shift;
 455
 456     my $patron = Koha::Patrons->find( $borrowernumber );
 457     my $holds = $patron->holds->search( { -or => [ { found => undef }, { found => { '!=' => 'W' } } ] } );
 458     my @holds;
 459     while ( my $hold = $holds->next ) {
 460         my $item;
 461         if ($hold->itemnumber) {
 462             $item = $hold->itemnumber;
 463         }
 464         else {
 465             # We need to return a barcode for the biblio so the client
 466             # can request the biblio info
 467             $item = ( GetItemnumbersForBiblio($hold->biblionumber) )->[0];
 468         }
 469         my $unblessed_hold = $hold->unblessed;
 470         $unblessed_hold->{barcode} = GetBarcodeFromItemnumber($item);
 471         push @holds, $unblessed_hold;
 472     }
 473     return \@holds;
 474 }
 475
 476 1;
 477 __END__
 478
 479 =head1 EXAMPLES
 480
 481   our %patron_example = (
 482           djfiander => {
 483               name => "David J. Fiander",
 484               id => 'djfiander',
 485               password => '6789',
 486               ptype => 'A', # 'A'dult.  Whatever.
 487               birthdate => '19640925',
 488               address => '2 Meadowvale Dr. St Thomas, ON',
 489               home_phone => '(519) 555 1234',
 490               email_addr => 'djfiander@hotmail.com',
 491               charge_ok => 1,
 492               renew_ok => 1,
 493               recall_ok => 0,
 494               hold_ok => 1,
 495               card_lost => 0,
 496               claims_returned => 0,
 497               fines => 100,
 498               fees => 0,
 499               recall_overdue => 0,
 500               items_billed => 0,
 501               screen_msg => '',
 502               print_line => '',
 503               items => [],
 504               hold_items => [],
 505               overdue_items => [],
 506               fine_items => ['Computer Time'],
 507               recall_items => [],
 508               unavail_holds => [],
 509               inet => 1,
 510           },
 511   );
 512
 513  From borrowers table:
 514 +---------------------+--------------+------+-----+---------+----------------+
 515 | Field               | Type         | Null | Key | Default | Extra          |
 516 +---------------------+--------------+------+-----+---------+----------------+
 517 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 518 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 519 | surname             | mediumtext   | NO   |     | NULL    |                |
 520 | firstname           | text         | YES  |     | NULL    |                |
 521 | title               | mediumtext   | YES  |     | NULL    |                |
 522 | othernames          | mediumtext   | YES  |     | NULL    |                |
 523 | initials            | text         | YES  |     | NULL    |                |
 524 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 525 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 526 | address             | mediumtext   | NO   |     | NULL    |                |
 527 | address2            | text         | YES  |     | NULL    |                |
 528 | city                | mediumtext   | NO   |     | NULL    |                |
 529 | state               | mediumtext   | YES  |     | NULL    |                |
 530 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 531 | country             | text         | YES  |     | NULL    |                |
 532 | email               | mediumtext   | YES  |     | NULL    |                |
 533 | phone               | text         | YES  |     | NULL    |                |
 534 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 535 | fax                 | mediumtext   | YES  |     | NULL    |                |
 536 | emailpro            | text         | YES  |     | NULL    |                |
 537 | phonepro            | text         | YES  |     | NULL    |                |
 538 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 539 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 540 | B_address           | varchar(100) | YES  |     | NULL    |                |
 541 | B_address2          | text         | YES  |     | NULL    |                |
 542 | B_city              | mediumtext   | YES  |     | NULL    |                |
 543 | B_state             | mediumtext   | YES  |     | NULL    |                |
 544 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 545 | B_country           | text         | YES  |     | NULL    |                |
 546 | B_email             | text         | YES  |     | NULL    |                |
 547 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 548 | dateofbirth         | date         | YES  |     | NULL    |                |
 549 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 550 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 551 | dateenrolled        | date         | YES  |     | NULL    |                |
 552 | dateexpiry          | date         | YES  |     | NULL    |                |
 553 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 554 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 555 | debarred            | tinyint(1)   | YES  |     | NULL    |                |
 556 | contactname         | mediumtext   | YES  |     | NULL    |                |
 557 | contactfirstname    | text         | YES  |     | NULL    |                |
 558 | contacttitle        | text         | YES  |     | NULL    |                |
 559 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 560 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 561 | relationship        | varchar(100) | YES  |     | NULL    |                |
 562 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 563 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 564 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 565 | password            | varchar(30)  | YES  |     | NULL    |                |
 566 | flags               | int(11)      | YES  |     | NULL    |                |
 567 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 568 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 569 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 570 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 571 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 572 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 573 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 574 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 575 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 576 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 577 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 578 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 579 | altcontactcountry   | text         | YES  |     | NULL    |                |
 580 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 581 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 582 | privacy             | int(11)      | NO   |     | 1       |                |
 583 +---------------------+--------------+------+-----+---------+----------------+
 584
 585
 586  From C4::Members
 587
 588  $flags->{KEY}
 589  {CHARGES}
 590     {message}     Message showing patron's credit or debt
 591     {noissues}    Set if patron owes >$5.00
 592  {GNA}             Set if patron gone w/o address
 593     {message}     "Borrower has no valid address"
 594     {noissues}    Set.
 595  {LOST}            Set if patron's card reported lost
 596     {message}     Message to this effect
 597     {noissues}    Set.
 598  {DBARRED}         Set if patron is debarred
 599     {message}     Message to this effect
 600     {noissues}    Set.
 601  {NOTES}           Set if patron has notes
 602     {message}     Notes about patron
 603  {ODUES}           Set if patron has overdue books
 604     {message}     "Yes"
 605     {itemlist}    ref-to-array: list of overdue books
 606     {itemlisttext}    Text list of overdue items
 607  {WAITING}         Set if there are items available that the patron reserved
 608     {message}     Message to this effect
 609     {itemlist}    ref-to-array: list of available items
 610
 611 =cut
 612