C4/SIP/Sip.pm

   1 #
   2 # Sip.pm: General Sip utility functions
   3 #
   4
   5 package C4::SIP::Sip;
   6
   7 use strict;
   8 use warnings;
   9 use Exporter;
  10 use Encode;
  11 use POSIX qw(strftime);
  12 use Socket qw(:crlf);
  13 use IO::Handle;
  14 use List::Util qw(first);
  15
  16 use C4::SIP::Sip::Constants qw(SIP_DATETIME FID_SCREEN_MSG);
  17 use C4::SIP::Sip::Checksum qw(checksum);
  18 use C4::SIP::Logger qw( get_logger );
  19
  20 use base qw(Exporter);
  21
  22 our @EXPORT_OK = qw(y_or_n timestamp add_field maybe_add add_count
  23     denied sipbool boolspace write_msg
  24     $error_detection $protocol_version $field_delimiter
  25     $last_response siplog);
  26
  27 our %EXPORT_TAGS = (
  28     all => [qw(y_or_n timestamp add_field maybe_add
  29         add_count denied sipbool boolspace write_msg
  30         $error_detection $protocol_version
  31         $field_delimiter $last_response siplog)]);
  32
  33 our $error_detection = 0;
  34 our $protocol_version = 1;
  35 our $field_delimiter = '|'; # Protocol Default
  36
  37 # We need to keep a copy of the last message we sent to the SC,
  38 # in case there's a transmission error and the SC sends us a
  39 # REQUEST_ACS_RESEND.  If we receive a REQUEST_ACS_RESEND before
  40 # we've ever sent anything, then we are to respond with a
  41 # REQUEST_SC_RESEND (p.16)
  42
  43 our $last_response = '';
  44
  45 sub timestamp {
  46     my $time = $_[0] || time();
  47     if ( ref $time eq 'DateTime') {
  48         return $time->strftime(SIP_DATETIME);
  49     } elsif ($time=~m/^(\d{4})\-(\d{2})\-(\d{2})/) {
  50         # passing a db returned date as is + bogus time
  51         return sprintf( '%04d%02d%02d    235900', $1, $2, $3);
  52     }
  53     return strftime(SIP_DATETIME, localtime($time));
  54 }
  55
  56 #
  57 # add_field(field_id, value)
  58 #    return constructed field value
  59 #
  60 sub add_field {
  61     my ($field_id, $value, $server) = @_;
  62
  63     if ( my $hide_fields = $server->{account}->{hide_fields} ) {
  64         my @fields = split( ',', $hide_fields );
  65         return q{} if first { $_ eq $field_id } @fields;
  66     }
  67
  68     my ($i, $ent);
  69
  70     if (!defined($value)) {
  71     siplog("LOG_DEBUG", "add_field: Undefined value being added to '%s'",
  72            $field_id);
  73         $value = '';
  74     }
  75     $value=~s/\r/ /g; # CR terminates a sip message
  76                       # Protect against them in sip text fields
  77
  78     # Replace any occurrences of the field delimiter in the
  79     # field value with the HTML character entity
  80     $ent = sprintf("&#%d;", ord($field_delimiter));
  81
  82     while (($i = index($value, $field_delimiter)) != ($[-1)) {
  83         substr($value, $i, 1) = $ent;
  84     }
  85
  86     return $field_id . $value . $field_delimiter;
  87 }
  88 #
  89 # maybe_add(field_id, value):
  90 #    If value is defined and non-empty, then return the
  91 #    constructed field value, otherwise return the empty string.
  92 #    NOTE: if zero is a valid value for your field, don't use maybe_add!
  93 #
  94 sub maybe_add {
  95     my ($fid, $value, $server) = @_;
  96
  97     if ( my $hide_fields = $server->{account}->{hide_fields} ) {
  98         my @fields = split( ',', $hide_fields );
  99         return q{} if first { $_ eq $fid } @fields;
 100     }
 101
 102     if ( $fid eq FID_SCREEN_MSG && $server->{account}->{screen_msg_regex} && defined($value)) {
 103         foreach my $regex (
 104             ref $server->{account}->{screen_msg_regex} eq "ARRAY"
 105             ? @{ $server->{account}->{screen_msg_regex} }
 106             : $server->{account}->{screen_msg_regex} )
 107         {
 108             $value =~ s/$regex->{find}/$regex->{replace}/g;
 109         }
 110     }
 111
 112     return ( defined($value) && length($value) )
 113       ? add_field( $fid, $value )
 114       : '';
 115 }
 116
 117 #
 118 # add_count()  produce fixed four-character count field,
 119 # or a string of four spaces if the count is invalid for some
 120 # reason
 121 #
 122 sub add_count {
 123     my ($label, $count) = @_;
 124
 125     # If the field is unsupported, it will be undef, return blanks
 126     # as per the spec.
 127     if (!defined($count)) {
 128         return ' ' x 4;
 129     }
 130
 131     $count = sprintf("%04d", $count);
 132     if (length($count) != 4) {
 133         siplog("LOG_WARNING", "handle_patron_info: %s wrong size: '%s'",
 134            $label, $count);
 135         $count = ' ' x 4;
 136     }
 137     return $count;
 138 }
 139
 140 #
 141 # denied($bool)
 142 # if $bool is false, return true.  This is because SIP statuses
 143 # are inverted:  we report that something has been denied, not that
 144 # it's permitted.  For example, 'renewal priv. denied' of 'Y' means
 145 # that the user's not permitted to renew.  I assume that the ILS has
 146 # real positive tests.
 147 #
 148 sub denied {
 149     my $bool = shift;
 150     return boolspace(!$bool);
 151 }
 152
 153 sub sipbool {
 154     my $bool = shift;
 155     return $bool ? 'Y' : 'N';
 156 }
 157
 158 #
 159 # boolspace: ' ' is false, 'Y' is true. (don't ask)
 160 #
 161 sub boolspace {
 162     my $bool = shift;
 163     return $bool ? 'Y' : ' ';
 164 }
 165
 166 #
 167 # write_msg($msg, $file)
 168 #
 169 # Send $msg to the SC.  If error detection is active, then
 170 # add the sequence number (if $seqno is non-zero) and checksum
 171 # to the message, and save the whole thing as $last_response
 172 #
 173 # If $file is set, then it's a file handle: write to it, otherwise
 174 # just write to the default destination.
 175 #
 176
 177 sub write_msg {
 178     my ($self, $msg, $file, $terminator, $encoding) = @_;
 179
 180     $terminator ||= q{};
 181     $terminator = ( $terminator eq 'CR' ) ? $CR : $CRLF;
 182
 183     $msg = encode($encoding, $msg) if ( $encoding );
 184
 185     my $cksum;
 186
 187     # $msg = encode_utf8($msg);
 188     if ($error_detection) {
 189         if (defined($self->{seqno})) {
 190             $msg .= 'AY' . $self->{seqno};
 191         }
 192         $msg .= 'AZ';
 193         $cksum = checksum($msg);
 194         $msg .= sprintf('%04.4X', $cksum);
 195     }
 196
 197
 198     if ($file) {
 199         $file->autoflush(1);
 200         print $file $msg, $terminator;
 201     } else {
 202         STDOUT->autoflush(1);
 203         print $msg, $terminator;
 204         siplog("LOG_INFO", "OUTPUT MSG: '$msg'");
 205     }
 206
 207     $last_response = $msg;
 208 }
 209
 210 sub siplog {
 211     my ( $level, $mask, @args ) = @_;
 212
 213     my $method =
 214         $level eq 'LOG_ERR'     ? 'error'
 215       : $level eq 'LOG_DEBUG'   ? 'debug'
 216       : $level eq 'LOG_INFO'    ? 'info'
 217       : $level eq 'LOG_WARNING' ? 'warn'
 218       :                           'error';
 219
 220     my $message = @args ? sprintf($mask, @args) : $mask;
 221
 222     my $logger = C4::SIP::Logger::get_logger();
 223     $logger->$method($message) if $logger;
 224 }
 225
 226 1;