C4/ShelfBrowser.pm

   1 #!/usr/bin/perl
   2
   3 package C4::ShelfBrowser;
   4
   5 # Copyright 2010 Catalyst IT
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use strict;
  23 use warnings;
  24
  25 use C4::Biblio;
  26 use C4::Branch;
  27 use C4::Context;
  28 use C4::Koha;
  29
  30 use vars qw(@ISA @EXPORT @EXPORT_OK);
  31
  32 BEGIN {
  33         require Exporter;
  34         @ISA    = qw(Exporter);
  35         @EXPORT = qw(
  36             &GetNearbyItems
  37     );
  38     @EXPORT_OK = qw(
  39     );
  40 }
  41
  42 =head1 NAME
  43
  44 C4::ShelfBrowser - functions that deal with the shelf browser feature found in
  45 the OPAC.
  46
  47 =head1 SYNOPSIS
  48
  49   use C4::ShelfBrowser;
  50
  51 =head1 DESCRIPTION
  52
  53 This module provides functions to get items nearby to another item, for use
  54 in the shelf browser function.
  55
  56 'Nearby' is controlled by a handful of system preferences that specify what
  57 to take into account.
  58
  59 =head1 FUNCTIONS
  60
  61 =head2 GetNearbyItems($itemnumber, [$num_each_side])
  62
  63   $nearby = GetNearbyItems($itemnumber, [$num_each_side]);
  64
  65   @items = @{ $nearby->{items} };
  66
  67   foreach (@items) {
  68       # These won't format well like this, but here are the fields
  69           print $_->{title};
  70           print $_->{biblionumber};
  71           print $_->{itemnumber};
  72           print $_->{browser_normalized_upc};
  73           print $_->{browser_normalized_oclc};
  74           print $_->{browser_normalized_isbn};
  75       print $_->{browser_normalized_ean};
  76   }
  77
  78   # This is the information required to scroll the browser to the next left
  79   # or right set. Can be derived from next/prev, but it's here for convenience.
  80   print $nearby->{prev_item}{itemnumber};
  81   print $nearby->{next_item}{itemnumber};
  82   print $nearby->{prev_item}{biblionumber};
  83   print $nearby->{next_item}{biblionumber};
  84
  85   # These will be undef if the values are not used to calculate the
  86   # nearby items.
  87   print $nearby->{starting_homebranch}->{code};
  88   print $nearby->{starting_homebranch}->{description};
  89   print $nearby->{starting_location}->{code};
  90   print $nearby->{starting_location}->{description};
  91   print $nearby->{starting_ccode}->{code};
  92   print $nearby->{starting_ccode}->{description};
  93
  94 This finds the items that are nearby to the supplied item, and supplies
  95 those previous and next, along with the other useful information for displaying
  96 the shelf browser.
  97
  98 It automatically applies the following user preferences to work out how to
  99 calculate things: C<ShelfBrowserUsesLocation>, C<ShelfBrowserUsesHomeBranch>,
 100 C<ShelfBrowserUsesCcode>.
 101
 102 The option C<$num_each_side> value determines how many items will be fetched
 103 each side of the supplied item. Note that the item itself is the first entry
 104 in the 'next' set, and counts towards this limit (this is to keep the
 105 behaviour consistent with the code that this is a refactor of.) Default is
 106 3.
 107
 108 This will throw an exception if something went wrong.
 109
 110 =cut
 111
 112 sub GetNearbyItems {
 113     my ( $itemnumber, $num_each_side, $gap) = @_;
 114     $num_each_side ||= 3;
 115     $gap ||= 7; # Should be > $num_each_side
 116     die "BAD CALL in C4::ShelfBrowser::GetNearbyItems, gap should be > num_each_side"
 117         if $gap <= $num_each_side;
 118
 119     my $dbh         = C4::Context->dbh;
 120     my $branches = GetBranches();
 121
 122     my $sth_get_item_details = $dbh->prepare("SELECT cn_sort,homebranch,location,ccode from items where itemnumber=?");
 123     $sth_get_item_details->execute($itemnumber);
 124     my $item_details_result = $sth_get_item_details->fetchrow_hashref();
 125     die "Unable to find item '$itemnumber' for shelf browser" if (!$sth_get_item_details);
 126     my $start_cn_sort = $item_details_result->{'cn_sort'};
 127
 128     my ($start_homebranch, $start_location, $start_ccode);
 129     if (C4::Context->preference('ShelfBrowserUsesHomeBranch') &&
 130         defined($item_details_result->{'homebranch'})) {
 131         $start_homebranch->{code} = $item_details_result->{'homebranch'};
 132         $start_homebranch->{description} = $branches->{$item_details_result->{'homebranch'}}{branchname};
 133     }
 134     if (C4::Context->preference('ShelfBrowserUsesLocation') &&
 135         defined($item_details_result->{'location'})) {
 136         $start_location->{code} = $item_details_result->{'location'};
 137         $start_location->{description} = GetAuthorisedValueDesc('','',$item_details_result->{'location'},'','','LOC','opac');
 138     }
 139     if (C4::Context->preference('ShelfBrowserUsesCcode') &&
 140         defined($item_details_result->{'ccode'})) {
 141         $start_ccode->{code} = $item_details_result->{'ccode'};
 142         $start_ccode->{description} = GetAuthorisedValueDesc('', '', $item_details_result->{'ccode'}, '', '', 'CCODE', 'opac');
 143     }
 144
 145     # Build the query for previous and next items
 146     my $prev_query ='
 147         SELECT itemnumber, biblionumber, cn_sort, itemcallnumber
 148         FROM items
 149         WHERE
 150             ((cn_sort = ? AND itemnumber < ?) OR cn_sort < ?) ';
 151     my $next_query ='
 152         SELECT itemnumber, biblionumber, cn_sort, itemcallnumber
 153         FROM items
 154         WHERE
 155             ((cn_sort = ? AND itemnumber >= ?) OR cn_sort > ?) ';
 156     my @params;
 157     my $query_cond;
 158     push @params, ($start_cn_sort, $itemnumber, $start_cn_sort);
 159     if ($start_homebranch) {
 160         $query_cond .= 'AND homebranch = ? ';
 161         push @params, $start_homebranch->{code};
 162     }
 163     if ($start_location) {
 164         $query_cond .= 'AND location = ? ';
 165         push @params, $start_location->{code};
 166     }
 167     if ($start_ccode) {
 168         $query_cond .= 'AND ccode = ? ';
 169         push @params, $start_ccode->{code};
 170     }
 171
 172     my @prev_items = @{
 173         $dbh->selectall_arrayref(
 174             $prev_query . $query_cond . ' ORDER BY cn_sort DESC, itemnumber DESC LIMIT ?',
 175             { Slice => {} },
 176             ( @params, $gap )
 177         )
 178     };
 179     my @next_items = @{
 180         $dbh->selectall_arrayref(
 181             $next_query . $query_cond . ' ORDER BY cn_sort, itemnumber LIMIT ?',
 182             { Slice => {} },
 183             ( @params, $gap + 1 )
 184         )
 185     };
 186
 187     my $prev_item = $prev_items[-1];
 188     my $next_item = $next_items[-1];
 189     @next_items = splice( @next_items, 0, $num_each_side + 1 );
 190     @prev_items = reverse splice( @prev_items, 0, $num_each_side );
 191     my @items = ( @prev_items, @next_items );
 192
 193     $next_item = undef
 194         if not $next_item
 195             or ( $next_item->{itemnumber} == $items[-1]->{itemnumber}
 196                 and ( @prev_items or @next_items <= 1 )
 197             );
 198     $prev_item = undef
 199         if not $prev_item
 200             or ( $prev_item->{itemnumber} == $items[0]->{itemnumber}
 201                 and ( @next_items or @prev_items <= 1 )
 202             );
 203
 204     # populate the items
 205     @items = GetShelfInfo( @items );
 206
 207     return {
 208         items               => \@items,
 209         next_item           => $next_item,
 210         prev_item           => $prev_item,
 211         starting_homebranch => $start_homebranch,
 212         starting_location   => $start_location,
 213         starting_ccode      => $start_ccode,
 214     };
 215 }
 216
 217 # populate an item list with its title and upc, oclc and isbn normalized.
 218 # Not really intended to be exported.
 219 sub GetShelfInfo {
 220     my @items = @_;
 221     my $marcflavour = C4::Context->preference("marcflavour");
 222     my @valid_items;
 223     for my $item ( @items ) {
 224         my $this_biblio = GetBibData($item->{biblionumber});
 225         next unless defined $this_biblio;
 226         $item->{'title'} = $this_biblio->{'title'};
 227         my $this_record = GetMarcBiblio($this_biblio->{'biblionumber'});
 228         $item->{'browser_normalized_upc'} = GetNormalizedUPC($this_record,$marcflavour);
 229         $item->{'browser_normalized_oclc'} = GetNormalizedOCLCNumber($this_record,$marcflavour);
 230         $item->{'browser_normalized_isbn'} = GetNormalizedISBN(undef,$this_record,$marcflavour);
 231         $item->{'browser_normalized_ean'} = GetNormalizedEAN($this_record,$marcflavour);
 232         $item->{'subtitle'} = GetRecordValue('subtitle', $this_record, GetFrameworkCode( $item->{biblionumber} ));
 233         push @valid_items, $item;
 234     }
 235     return @valid_items;
 236 }
 237
 238 # Fetches some basic biblio data needed by the shelf stuff
 239 sub GetBibData {
 240         my ($bibnum) = @_;
 241
 242     my $dbh         = C4::Context->dbh;
 243     my $sth = $dbh->prepare("SELECT biblionumber, title FROM biblio WHERE biblionumber=?");
 244     $sth->execute($bibnum);
 245     my $bib = $sth->fetchrow_hashref();
 246     return $bib;
 247 }
 248
 249 1;