C4/VirtualShelves/Page.pm

   1 package C4::VirtualShelves::Page;
   2
   3 #
   4 # Copyright 2000-2002 Katipo Communications
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 # perldoc at the end of the file, per convention.
  22
  23 use strict;
  24 use warnings;
  25
  26 use CGI;
  27 use Exporter;
  28 use Data::Dumper;
  29
  30 use C4::VirtualShelves qw/:DEFAULT ShelvesMax/;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Koha;
  34 use C4::Auth qw/get_session/;
  35 use C4::Members;
  36 use C4::Output;
  37 use C4::Dates qw/format_date/;
  38 use C4::Tags qw(get_tags);
  39 use C4::Csv;
  40 use C4::XSLT;
  41
  42 use constant VIRTUALSHELVES_COUNT => 20;
  43
  44 use vars qw($debug @EXPORT @ISA $VERSION);
  45
  46 BEGIN {
  47     $VERSION = 3.07.00.049;
  48     @ISA     = qw(Exporter);
  49     @EXPORT  = qw(&shelfpage);
  50     $debug   = $ENV{DEBUG} || 0;
  51 }
  52
  53 our %pages = (
  54     intranet => { redirect => '/cgi-bin/koha/virtualshelves/shelves.pl', },
  55     opac     => { redirect => '/cgi-bin/koha/opac-shelves.pl', },
  56 );
  57
  58 sub shelfpage {
  59     my ( $type, $query, $template, $loggedinuser, $cookie ) = @_;
  60     ( $pages{$type} ) or $type = 'opac';
  61     $query            or die "No query";
  62     $template         or die "No template";
  63     $template->param(
  64     loggedinuser => $loggedinuser,
  65     OpacAllowPublicListCreation => C4::Context->preference('OpacAllowPublicListCreation'),
  66     );
  67     my $edit;
  68     my $shelves;
  69     my @paramsloop;
  70     my $totitems;
  71     my $shelfoff    = ( $query->param('shelfoff') ? $query->param('shelfoff') : 1 );
  72     $template->{VARS}->{'shelfoff'} = $shelfoff;
  73     my $itemoff     = ( $query->param('itemoff')  ? $query->param('itemoff')  : 1 );
  74     my $displaymode = ( $query->param('display')  ? $query->param('display')  : 'publicshelves' );
  75     my ( $shelflimit, $shelfoffset, $shelveslimit, $shelvesoffset );
  76     my $marcflavour = C4::Context->preference("marcflavour");
  77
  78     # get biblionumbers stored in the cart
  79     my @cart_list;
  80     my $cart_cookie = ( $type eq 'opac' ? "bib_list" : "intranet_bib_list" );
  81     if($query->cookie($cart_cookie)){
  82         my $cart_list = $query->cookie($cart_cookie);
  83         @cart_list = split(/\//, $cart_list);
  84     }
  85
  86     $shelflimit = ( $type eq 'opac' ? C4::Context->preference('OPACnumSearchResults') : C4::Context->preference('numSearchResults') );
  87     $shelflimit = $shelflimit || ShelvesMax('MGRPAGE');
  88     $shelfoffset   = ( $itemoff - 1 ) * $shelflimit;     # Sets the offset to begin retrieving items at
  89     $shelveslimit  = $shelflimit;                        # Limits number of shelves returned for a given query (row_count)
  90     $shelvesoffset = ( $shelfoff - 1 ) * $shelflimit;    # Sets the offset to begin retrieving shelves at (offset)
  91                                                 # getting the Shelves list
  92     my $category = ( ( $displaymode eq 'privateshelves' ) ? 1 : 2 );
  93     my ( $shelflist, $totshelves ) = GetShelves( $category, $shelveslimit, $shelvesoffset, $loggedinuser );
  94
  95     #Get a list of private shelves for possible deletion. Only do this when we've defaulted to public shelves
  96     my ( $privshelflist, $privtotshelves );
  97     if ( $category == 2 ) {
  98         ( $privshelflist, $privtotshelves ) = GetShelves( 1, $shelveslimit, $shelvesoffset, $loggedinuser );
  99     }
 100     my $op = $query->param('op');
 101
 102     # the format of this is unindented for ease of diff comparison to the old script
 103     # Note: do not mistake the assignment statements below for comparisons!
 104     if ( $query->param('modifyshelfcontents') ) {
 105         my ( $shelfnumber, $barcode, $item, $biblio );
 106         if ( $shelfnumber = $query->param('viewshelf') ) {
 107             #add to shelf
 108             if($barcode = $query->param('addbarcode') ) {
 109                 if(ShelfPossibleAction( $loggedinuser, $shelfnumber, 'add')) {
 110                     $item = GetItem( 0, $barcode);
 111                     if (defined $item && $item->{'itemnumber'}) {
 112                         $biblio = GetBiblioFromItemNumber( $item->{'itemnumber'} );
 113                         AddToShelf( $biblio->{'biblionumber'}, $shelfnumber, $loggedinuser)
 114                           or push @paramsloop, { duplicatebiblio => $barcode };
 115                     }
 116                     else {
 117                         push @paramsloop, { failgetitem => $barcode };
 118                     }
 119                 }
 120                 else {
 121                     push @paramsloop, { nopermission => $shelfnumber };
 122                 }
 123             }
 124             elsif(grep { /REM-(\d+)/ } $query->param) {
 125             #remove item(s) from shelf
 126                 if(ShelfPossibleAction($loggedinuser, $shelfnumber, 'delete')) {
 127                 #This is just a general okay; DelFromShelf checks further
 128                     my @bib;
 129                     foreach($query->param) {
 130                         /REM-(\d+)/ or next;
 131                         push @bib, $1; #$1 is biblionumber
 132                     }
 133                     my $t= DelFromShelf(\@bib, $shelfnumber, $loggedinuser);
 134                     if($t==0) {
 135                         push @paramsloop, {nothingdeleted => $shelfnumber};
 136                     }
 137                     elsif($t<@bib) {
 138                         push @paramsloop, {somedeleted => $shelfnumber};
 139                     }
 140                 }
 141                 else {
 142                     push @paramsloop, { nopermission => $shelfnumber };
 143                 }
 144             }
 145         }
 146         else {
 147             push @paramsloop, { noshelfnumber => 1 };
 148         }
 149     }
 150
 151     my $showadd = 1;
 152
 153     # set the default tab, etc. (for OPAC)
 154     my $shelf_type = ( $query->param('display') ? $query->param('display') : 'publicshelves' );
 155     if ( defined $shelf_type ) {
 156         if ( $shelf_type eq 'privateshelves' ) {
 157             $template->param( showprivateshelves => 1 );
 158         } elsif ( $shelf_type eq 'publicshelves' ) {
 159             $template->param( showpublicshelves => 1 );
 160             $showadd = 0;
 161         } else {
 162             $debug and warn "Invalid 'display' param ($shelf_type)";
 163         }
 164     } elsif ( $loggedinuser == -1 ) {
 165         $template->param( showpublicshelves => 1 );
 166     } else {
 167         $template->param( showprivateshelves => 1 );
 168     }
 169
 170     my ( $okmanage, $okview );
 171     my $shelfnumber = $query->param('shelfnumber') || $query->param('viewshelf');
 172     if ($shelfnumber) {
 173         $okmanage = ShelfPossibleAction( $loggedinuser, $shelfnumber, 'manage' );
 174         $okview   = ShelfPossibleAction( $loggedinuser, $shelfnumber, 'view' );
 175     }
 176
 177     my $delflag = 0;
 178
 179   SWITCH: {
 180         if ($op) {
 181         #Saving modified shelf
 182             if ( $op eq 'modifsave' ) {
 183                 unless ($okmanage) {
 184                         push @paramsloop, { nopermission => $shelfnumber };
 185                         last SWITCH;
 186                 }
 187                 my $shelf = {
 188                     shelfname          => $query->param('shelfname'),
 189                     sortfield          => $query->param('sortfield'),
 190                     allow_add          => $query->param('allow_add'),
 191                     allow_delete_own   => $query->param('allow_delete_own'),
 192                     allow_delete_other => $query->param('allow_delete_other'),
 193                 };
 194                 if($query->param('category')) { #optional
 195                     $shelf->{category}= $query->param('category');
 196                 }
 197                 unless(ModShelf($shelfnumber, $shelf )) {
 198                   push @paramsloop, {modifyfailure => $shelf->{shelfname}};
 199                   last SWITCH;
 200                 }
 201
 202                 if($displaymode eq "viewshelf"){
 203                     print $query->redirect( $pages{$type}->{redirect} . "?viewshelf=$shelfnumber" );
 204                 } elsif($displaymode eq "publicshelves"){
 205                     print $query->redirect( $pages{$type}->{redirect} );
 206                 } else {
 207                     print $query->redirect( $pages{$type}->{redirect} . "?display=privateshelves" );
 208                 }
 209                 exit;
 210             }
 211         #Editing a shelf
 212         elsif ( $op eq 'modif' ) {
 213                 my ( $shelfnumber2, $shelfname, $owner, $category, $sortfield, $allow_add, $allow_delete_own, $allow_delete_other) = GetShelf($shelfnumber);
 214                 my $member = GetMember( 'borrowernumber' => $owner );
 215                 my $ownername = defined($member) ? $member->{firstname} . " " . $member->{surname} : '';
 216                 $edit = 1;
 217                 $template->param(
 218                     edit                => 1,
 219                     display             => $displaymode,
 220                     shelfnumber         => $shelfnumber2,
 221                     shelfname           => $shelfname,
 222                     owner               => $owner,
 223                     ownername           => $ownername,
 224                     "category$category" => 1,
 225                     category            => $category,
 226                     sortfield           => $sortfield,
 227                     allow_add           => $allow_add,
 228                     allow_delete_own    => $allow_delete_own,
 229                     allow_delete_other  => $allow_delete_other,
 230                 );
 231             }
 232             last SWITCH;
 233         }
 234
 235         #View a shelf
 236         if ( $shelfnumber = $query->param('viewshelf') ) {
 237             # explicitly fetch this shelf
 238             my ($shelfnumber2,$shelfname,$owner,$category,$sorton) = GetShelf($shelfnumber);
 239
 240             $template->param( 'AllowOnShelfHolds' => C4::Context->preference('AllowOnShelfHolds') );
 241             if (C4::Context->preference('TagsEnabled')) {
 242                 $template->param(TagsEnabled => 1);
 243                     foreach (qw(TagsShowOnList TagsInputOnList)) {
 244                     C4::Context->preference($_) and $template->param($_ => 1);
 245                 }
 246             }
 247             #check that the user can view the shelf
 248             if ( ShelfPossibleAction( $loggedinuser, $shelfnumber, 'view' ) ) {
 249                 my $items;
 250                 my $tag_quantity;
 251                 my $sortfield = ( $sorton ? $sorton : 'title' );
 252                 ( $items, $totitems ) = GetShelfContents( $shelfnumber, $shelflimit, $shelfoffset, $sortfield );
 253                 for my $this_item (@$items) {
 254                     my $biblionumber = $this_item->{'biblionumber'};
 255                     my $record = GetMarcBiblio($biblionumber);
 256                     $this_item->{XSLTBloc} =
 257                         XSLTParse4Display($biblionumber, $record, "OPACXSLTResultsDisplay")
 258                             if C4::Context->preference("OPACXSLTResultsDisplay") && $type eq 'opac';
 259
 260                     # the virtualshelfcontents table does not store these columns nor are they retrieved from the items
 261                     # and itemtypes tables, so I'm commenting them out for now to quiet the log -crn
 262                     #$this_item->{imageurl} = $imgdir."/".$itemtypes->{ $this_item->{itemtype}  }->{'imageurl'};
 263                     #$this_item->{'description'} = $itemtypes->{ $this_item->{itemtype} }->{'description'};
 264                     $this_item->{'dateadded'} = format_date( $this_item->{'dateadded'} );
 265                     $this_item->{'imageurl'}  = getitemtypeinfo( $this_item->{'itemtype'}, $type )->{'imageurl'};
 266                     $this_item->{'coins'}     = GetCOinSBiblio( $record );
 267                     $this_item->{'subtitle'} = GetRecordValue('subtitle', $record, GetFrameworkCode($this_item->{'biblionumber'}));
 268                     $this_item->{'normalized_upc'}  = GetNormalizedUPC(       $record,$marcflavour);
 269                     $this_item->{'normalized_ean'}  = GetNormalizedEAN(       $record,$marcflavour);
 270                     $this_item->{'normalized_oclc'} = GetNormalizedOCLCNumber($record,$marcflavour);
 271                     $this_item->{'normalized_isbn'} = GetNormalizedISBN(undef,$record,$marcflavour);
 272                     # Getting items infos for location display
 273                     my @items_infos = &GetItemsLocationInfo( $this_item->{'biblionumber'});
 274                     $this_item->{'itemsissued'} = CountItemsIssued( $this_item->{'biblionumber'} );
 275                     $this_item->{'ITEM_RESULTS'} = \@items_infos;
 276                     if ( grep {$_ eq $biblionumber} @cart_list) {
 277                         $this_item->{'incart'} = 1;
 278                     }
 279
 280                     if (C4::Context->preference('TagsEnabled') and $tag_quantity = C4::Context->preference('TagsShowOnList')) {
 281                         $this_item->{'TagLoop'} = get_tags({
 282                             biblionumber=>$this_item->{'biblionumber'}, approved=>1, 'sort'=>'-weight',
 283                             limit=>$tag_quantity
 284                             });
 285                     }
 286
 287                 }
 288                 push @paramsloop, { display => 'privateshelves' } if $category == 1;
 289                 $showadd = 1;
 290                 my $i = 0;
 291                 my $manageshelf = ShelfPossibleAction( $loggedinuser, $shelfnumber, 'manage' );
 292                 $template->param(
 293                     shelfname           => $shelfname,
 294                     shelfnumber         => $shelfnumber,
 295                     viewshelf           => $shelfnumber,
 296                     sortfield           => $sortfield,
 297                     manageshelf         => $manageshelf,
 298                     allowremovingitems  => ShelfPossibleAction( $loggedinuser, $shelfnumber, 'delete'),
 299                     allowaddingitem     => ShelfPossibleAction( $loggedinuser, $shelfnumber, 'add'),
 300                     "category$category" => 1,
 301                     category            => $category,
 302                     itemsloop           => $items,
 303                     showprivateshelves  => $category==1,
 304                 );
 305             } else {
 306                 push @paramsloop, { nopermission => $shelfnumber };
 307             }
 308             last SWITCH;
 309         }
 310
 311         if ( $query->param('shelves') ) {
 312             my $stay = 1;
 313
 314         #Add a shelf
 315             if ( my $newshelf = $query->param('addshelf') ) {
 316
 317                 # note: a user can always add a new shelf
 318                 my $shelfnumber = AddShelf( {
 319                     shelfname => $newshelf,
 320                     sortfield => $query->param('sortfield'),
 321                     category => $query->param('category'),
 322                     allow_add => $query->param('allow_add'),
 323                     allow_delete_own => $query->param('allow_delete_own'),
 324                     allow_delete_other => $query->param('allow_delete_other'),
 325                     },
 326                     $query->param('owner') );
 327                 $stay = 1;
 328                 if ( $shelfnumber == -1 ) {    #shelf already exists.
 329                     $showadd = 1;
 330                     push @paramsloop, { already => $newshelf };
 331                     $template->param( shelfnumber => $shelfnumber );
 332                 } else {
 333                     print $query->redirect( $pages{$type}->{redirect} . "?viewshelf=$shelfnumber" );
 334                     exit;
 335                 }
 336             }
 337
 338         #Deleting a shelf (asking for confirmation if it has entries)
 339             foreach ( $query->param() ) {
 340                 /DEL-(\d+)/ or next;
 341                 $delflag = 1;
 342                 my $number = $1;
 343                 unless ( defined $shelflist->{$number} || defined $privshelflist->{$number} ) {
 344                     push( @paramsloop, { unrecognized => $number } );
 345                     last;
 346                 }
 347                 unless ( ShelfPossibleAction( $loggedinuser, $number, 'manage' ) ) {
 348                     push( @paramsloop, { nopermission => $shelfnumber } );
 349                     last;
 350                 }
 351                 my $contents;
 352                 ( $contents, $totshelves ) = GetShelfContents( $number, $shelveslimit, $shelvesoffset );
 353                 if ( my $count = scalar @$contents ) {
 354                     unless ( scalar grep { /^CONFIRM-$number$/ } $query->param() ) {
 355                         if ( defined $shelflist->{$number} ) {
 356                             push( @paramsloop, { need_confirm => $shelflist->{$number}->{shelfname}, count => $count, single => ($count eq 1 ? 1:0) } );
 357                             $shelflist->{$number}->{confirm} = $number;
 358                         } else {
 359                             push( @paramsloop, { need_confirm => $privshelflist->{$number}->{shelfname}, count => $count } );
 360                             $privshelflist->{$number}->{confirm} = $number;
 361                         }
 362                         $stay = 0;
 363                         next;
 364                     }
 365                 }
 366                 my $name;
 367                 if ( defined $shelflist->{$number} ) {
 368                     $name = $shelflist->{$number}->{'shelfname'};
 369                     delete $shelflist->{$number};
 370                 } else {
 371                     $name = $privshelflist->{$number}->{'shelfname'};
 372                     delete $privshelflist->{$number};
 373                 }
 374                 unless ( DelShelf($number) ) {
 375                     push( @paramsloop, { delete_fail => $name } );
 376                     last;
 377                 }
 378                 push( @paramsloop, { delete_ok => $name } );
 379
 380                 $stay = 0;
 381             }
 382             $showadd = 1;
 383             if ($stay){
 384                 $template->param( shelves => 1 );
 385                 $shelves = 1;
 386             }
 387             last SWITCH;
 388         }
 389     } # end of SWITCH block
 390
 391     (@paramsloop) and $template->param( paramsloop => \@paramsloop );
 392     $showadd      and $template->param( showadd    => 1 );
 393     my @shelvesloop;
 394     my @shelveslooppriv;
 395     my $numberCanManage = 0;
 396
 397     # rebuild shelflist in case a shelf has been added
 398     ( $shelflist, $totshelves ) = GetShelves( $category, $shelveslimit, $shelvesoffset, $loggedinuser ) unless $delflag;
 399     foreach my $element ( sort { lc( $shelflist->{$a}->{'shelfname'} ) cmp lc( $shelflist->{$b}->{'shelfname'} ) } keys %$shelflist ) {
 400         my %line;
 401         $shelflist->{$element}->{shelf} = $element;
 402         my $category  = $shelflist->{$element}->{'category'};
 403         my $owner     = $shelflist->{$element}->{'owner'}||0;
 404         my $canmanage = ShelfPossibleAction( $loggedinuser, $element, 'manage' );
 405         $shelflist->{$element}->{"viewcategory$category"} = 1;
 406         $shelflist->{$element}->{manageshelf} = $canmanage;
 407         if($canmanage || ($loggedinuser && $owner==$loggedinuser)) {
 408             $shelflist->{$element}->{'mine'} = 1;
 409         }
 410         my $member = GetMember( 'borrowernumber' => $owner );
 411         $shelflist->{$element}->{ownername} = defined($member) ? $member->{firstname} . " " . $member->{surname} : '';
 412         $numberCanManage++ if $canmanage;    # possibly outmoded
 413         if ( $shelflist->{$element}->{'category'} eq '1' ) {
 414             push( @shelveslooppriv, $shelflist->{$element} );
 415         } else {
 416             push( @shelvesloop, $shelflist->{$element} );
 417         }
 418     }
 419
 420     my $url = $type eq 'opac' ? "/cgi-bin/koha/opac-shelves.pl" : "/cgi-bin/koha/virtualshelves/shelves.pl";
 421     my %qhash = ();
 422     foreach (qw(display viewshelf sortfield)) {
 423         $qhash{$_} = $query->param($_) if $query->param($_);
 424     }
 425     ( scalar keys %qhash ) and $url .= '?' . join '&', map { "$_=$qhash{$_}" } keys %qhash;
 426     if ( $shelfnumber && $totitems ) {
 427         $template->param(  pagination_bar => pagination_bar( $url, ( int( $totitems / $shelflimit ) ) + ( ( $totitems % $shelflimit ) > 0 ? 1 : 0 ), $itemoff, "itemoff" )  );
 428     } elsif ( $totshelves ) {
 429         $template->param(
 430              pagination_bar => pagination_bar( $url, ( int( $totshelves / $shelveslimit ) ) + ( ( $totshelves % $shelveslimit ) > 0 ? 1 : 0 ), $shelfoff, "shelfoff" )  );
 431     }
 432     $template->param(
 433         shelveslooppriv                                                    => \@shelveslooppriv,
 434         shelvesloop                                                        => \@shelvesloop,
 435         shelvesloopall                                                     => [ ( @shelvesloop, @shelveslooppriv ) ],
 436         numberCanManage                                                    => $numberCanManage,
 437         "BiblioDefaultView" . C4::Context->preference("BiblioDefaultView") => 1,
 438         csv_profiles                                                       => GetCsvProfilesLoop()
 439     );
 440     if (   $shelfnumber
 441         or $shelves
 442         or $edit ) {
 443         $template->param( vseflag => 1 );
 444     }
 445     if ($shelves or    # note: this part looks duplicative, but is intentional
 446         $edit
 447       ) {
 448         $template->param( seflag => 1 );
 449         #This hack is just another argument for refactoring this script one day
 450         #At this point you are adding or editing a list; if you add, then you add a private list (by default) with permissions as below; if you edit, do not pass these permissions, they must come from the database
 451         $template->param( allow_add => 0, allow_delete_own => 1, allow_delete_other => 0) unless $shelfnumber;
 452     }
 453
 454 #Next call updates the shelves for the Lists button.
 455 #May not always be needed (when nothing changed), but doesn't take much.
 456     my ($total, $pubshelves, $barshelves) = C4::VirtualShelves::GetSomeShelfNames($loggedinuser, 'MASTHEAD');
 457     $template->param(
 458             barshelves     => $total->{bartotal},
 459             barshelvesloop => $barshelves,
 460             pubshelves     => $total->{pubtotal},
 461             pubshelvesloop => $pubshelves,
 462     );
 463
 464     output_html_with_http_headers $query, $cookie, $template->output;
 465 }
 466
 467 1;
 468 __END__
 469
 470 =head1 NAME
 471
 472 VirtualShelves/Page.pm
 473
 474 =head1 DESCRIPTION
 475
 476 Module used for both OPAC and intranet pages.
 477
 478 =head1 CGI PARAMETERS
 479
 480 =over 4
 481
 482 =item C<modifyshelfcontents>
 483
 484 If this script has to modify the shelf content.
 485
 486 =item C<shelfnumber>
 487
 488 To know on which shelf to work.
 489
 490 =item C<addbarcode>
 491
 492 =item C<op>
 493
 494  Op can be:
 495     * modif: show the template allowing modification of the shelves;
 496     * modifsave: save changes from modif mode.
 497
 498 =item C<viewshelf>
 499
 500 Load template with 'viewshelves param' displaying the shelf's information.
 501
 502 =item C<shelves>
 503
 504 If the param shelves == 1, then add or delete a shelf.
 505
 506 =item C<addshelf>
 507
 508 If the param shelves == 1, then addshelf is the name of the shelf to add.
 509
 510 =back
 511
 512 =cut