Koha/BackgroundJob/BatchUpdateBiblio.pm

   1 package Koha::BackgroundJob::BatchUpdateBiblio;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use JSON qw( decode_json encode_json );
  20
  21 use Koha::BackgroundJobs;
  22 use Koha::DateUtils qw( dt_from_string );
  23 use Koha::Virtualshelves;
  24
  25 use C4::Context;
  26 use C4::Biblio;
  27 use C4::MarcModificationTemplates;
  28
  29 use base 'Koha::BackgroundJob';
  30
  31 =head1 NAME
  32
  33 Koha::BackgroundJob::BatchUpdateBiblio - Batch update bibliographic records
  34
  35 This is a subclass of Koha::BackgroundJob.
  36
  37 =head1 API
  38
  39 =head2 Class methods
  40
  41 =head3 job_type
  42
  43 Define the job type of this job: batch_biblio_record_modification
  44
  45 =cut
  46
  47 sub job_type {
  48     return 'batch_biblio_record_modification';
  49 }
  50
  51 =head3 process
  52
  53 Process the modification.
  54
  55 =cut
  56
  57 sub process {
  58     my ( $self, $args ) = @_;
  59
  60     my $job = Koha::BackgroundJobs->find( $args->{job_id} );
  61
  62     if ( !exists $args->{job_id} || !$job || $job->status eq 'cancelled' ) {
  63         return;
  64     }
  65
  66     # FIXME If the job has already been started, but started again (worker has been restart for instance)
  67     # Then we will start from scratch and so double process the same records
  68
  69     my $job_progress = 0;
  70     $job->started_on(dt_from_string)
  71         ->progress($job_progress)
  72         ->status('started')
  73         ->store;
  74
  75     my $mmtid = $args->{mmtid};
  76     my @record_ids = @{ $args->{record_ids} };
  77
  78     my $report = {
  79         total_records => scalar @record_ids,
  80         total_success => 0,
  81     };
  82     my @messages;
  83     RECORD_IDS: for my $biblionumber ( sort { $a <=> $b } @record_ids ) {
  84
  85         last if $job->get_from_storage->status eq 'cancelled';
  86
  87         next unless $biblionumber;
  88
  89         # Modify the biblio
  90         my $error = eval {
  91             my $record = C4::Biblio::GetMarcBiblio({ biblionumber => $biblionumber });
  92             C4::MarcModificationTemplates::ModifyRecordWithTemplate( $mmtid, $record );
  93             my $frameworkcode = C4::Biblio::GetFrameworkCode( $biblionumber );
  94             C4::Biblio::ModBiblio( $record, $biblionumber, $frameworkcode, {
  95                 overlay_context => $args->{overlay_context},
  96             });
  97         };
  98         if ( $error and $error != 1 or $@ ) { # ModBiblio returns 1 if everything as gone well
  99             push @messages, {
 100                 type => 'error',
 101                 code => 'biblio_not_modified',
 102                 biblionumber => $biblionumber,
 103                 error => ($@ ? "$@" : $error),
 104             };
 105         } else {
 106             push @messages, {
 107                 type => 'success',
 108                 code => 'biblio_modified',
 109                 biblionumber => $biblionumber,
 110             };
 111             $report->{total_success}++;
 112         }
 113         $job->progress( ++$job_progress )->store;
 114     }
 115
 116     my $job_data = decode_json $job->data;
 117     $job_data->{messages} = \@messages;
 118     $job_data->{report} = $report;
 119
 120     $job->ended_on(dt_from_string)
 121         ->data(encode_json $job_data);
 122     $job->status('finished') if $job->status ne 'cancelled';
 123     $job->store;
 124 }
 125
 126 =head3 enqueue
 127
 128 Enqueue the new job
 129
 130 =cut
 131
 132 sub enqueue {
 133     my ( $self, $args) = @_;
 134
 135     # TODO Raise exception instead
 136     return unless exists $args->{mmtid};
 137     return unless exists $args->{record_ids};
 138
 139     $self->SUPER::enqueue({
 140         job_size => scalar @{$args->{record_ids}},
 141         job_args => $args,
 142     });
 143 }
 144
 145 =head3 additional_report
 146
 147 Pass the list of lists/virtual shelves the logged in user has write permissions.
 148
 149 It will enable the "add modified records to list" feature.
 150
 151 =cut
 152
 153 sub additional_report {
 154     my ($self) = @_;
 155
 156     my $loggedinuser = C4::Context->userenv ? C4::Context->userenv->{'number'} : undef;
 157     return {
 158         lists => scalar Koha::Virtualshelves->search(
 159             [
 160                 { public => 0, owner => $loggedinuser },
 161                 { public => 1 }
 162             ]
 163         ),
 164     };
 165 }
 166
 167 1;