Koha/BackgroundJob/BatchUpdateBiblioHoldsQueue.pm

   1 package Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Try::Tiny;
  21
  22 use Koha::Biblios;
  23 use Koha::Exceptions;
  24
  25 use C4::HoldsQueue
  26   qw(load_branches_to_pull_from TransportCostMatrix update_queue_for_biblio);
  27
  28 use base 'Koha::BackgroundJob';
  29
  30 =head1 NAME
  31
  32 Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue - Update the holds queue
  33 for a specified list of biblios.
  34
  35 This is a subclass of Koha::BackgroundJob.
  36
  37 =head1 API
  38
  39 =head2 Class methods
  40
  41 =head3 job_type
  42
  43 Returns a string representing the job type. In this case I<update_holds_queue_for_biblios>.
  44
  45 =cut
  46
  47 sub job_type {
  48     return 'update_holds_queue_for_biblios';
  49 }
  50
  51 =head3 process
  52
  53 Perform the expected action.
  54
  55 =cut
  56
  57 sub process {
  58     my ( $self, $args ) = @_;
  59
  60     my $schema = Koha::Database->new->schema;
  61
  62     $self->set(
  63         {
  64             started_on => \'NOW()',
  65             progress   => 0,
  66             status     => 'started',
  67         }
  68     )->store;
  69
  70     my @biblio_ids = @{ $args->{biblio_ids} };
  71
  72     my $report = {
  73         total_biblios => scalar @biblio_ids,
  74         total_success => 0,
  75     };
  76
  77     my $use_transport_cost_matrix = C4::Context->preference("UseTransportCostMatrix");
  78     my $transport_cost_matrix = $use_transport_cost_matrix ? TransportCostMatrix() : undef;
  79     my $branches_to_use = load_branches_to_pull_from($use_transport_cost_matrix);
  80
  81     my @messages;
  82
  83     foreach my $biblio_id (@biblio_ids) {
  84         try {
  85
  86             $schema->storage->txn_begin;
  87
  88             my $result = update_queue_for_biblio(
  89                 {
  90                     biblio_id             => $biblio_id,
  91                     branches_to_use       => $branches_to_use,
  92                     delete                => 1,
  93                     transport_cost_matrix => $transport_cost_matrix
  94                 }
  95             );
  96             push @messages,
  97               {
  98                 type           => 'success',
  99                 code           => 'holds_queue_updated',
 100                 biblio_id      => $biblio_id,
 101               };
 102             $report->{total_success}++;
 103
 104             $schema->storage->txn_commit;
 105         }
 106         catch {
 107
 108             push @messages,
 109               {
 110                 type      => 'error',
 111                 code      => 'holds_queue_update_error',
 112                 biblio_id => $biblio_id,
 113                 error     => "$_",
 114               };
 115
 116             $schema->storage->txn_rollback;
 117         };
 118
 119         $self->progress( $self->progress + 1 )->store;
 120     }
 121
 122     my $json = $self->json;
 123     my $job_data = $json->decode($self->data);
 124     $job_data->{messages} = \@messages;
 125     $job_data->{report}   = $report;
 126
 127     $self->set(
 128         {
 129             ended_on => \'NOW()',
 130             data     => $json->encode($job_data),
 131             status   => 'finished',
 132         }
 133     )->store;
 134 }
 135
 136 =head3 enqueue
 137
 138 Enqueue the new job
 139
 140 =cut
 141
 142 sub enqueue {
 143     my ( $self, $args ) = @_;
 144
 145     Koha::Exceptions::MissingParameter->throw(
 146         "Missing biblio_ids parameter is mandatory")
 147       unless exists $args->{biblio_ids};
 148
 149     my @biblio_ids = @{ $args->{biblio_ids} };
 150
 151     $self->SUPER::enqueue(
 152         {
 153             job_size => scalar @biblio_ids,
 154             job_args => { biblio_ids => \@biblio_ids }
 155         }
 156     );
 157 }
 158
 159 =head3 additional_report
 160
 161 Pass the biblio's title and patron's name
 162
 163 =cut
 164
 165 sub additional_report {
 166     my ( $self, $args ) = @_;
 167
 168     my $messages = $self->messages;
 169     for my $m (@$messages) {
 170         $m->{biblio} = Koha::Biblios->find( $m->{biblio_id} );
 171     }
 172     return { report_messages => $messages };
 173 }
 174
 175 1;