Koha/BackgroundJob.pm

   1 package Koha::BackgroundJob;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use JSON qw( encode_json decode_json );
  20 use Carp qw( croak );
  21 use Net::Stomp;
  22
  23 use C4::Context;
  24 use Koha::DateUtils qw( dt_from_string );
  25 use Koha::Exceptions;
  26 use Koha::BackgroundJob::BatchUpdateBiblio;
  27 use Koha::BackgroundJob::BatchUpdateAuthority;
  28
  29 use base qw( Koha::Object );
  30
  31 =head1 NAME
  32
  33 Koha::BackgroundJob - Koha BackgroundJob Object class
  34
  35 This is a base class for BackgroundJob, some methods must be subclassed.
  36
  37 Example of usage:
  38
  39 Producer:
  40 my $job_id = Koha::BackgroundJob->enqueue(
  41     {
  42         job_type => $job_type,
  43         job_size => $job_size,
  44         job_args => $job_args
  45     }
  46 );
  47
  48 Consumer:
  49 Koha::BackgrounJobs->find($job_id)->process;
  50 See also C<misc/background_jobs_worker.pl> for a full example
  51
  52 =head1 API
  53
  54 =head2 Class methods
  55
  56 =head3 connect
  57
  58 Connect to the message broker using default guest/guest credential
  59
  60 =cut
  61
  62 sub connect {
  63     my ( $self );
  64     my $stomp = Net::Stomp->new( { hostname => 'localhost', port => '61613' } );
  65     $stomp->connect( { login => 'guest', passcode => 'guest' } );
  66     return $stomp;
  67 }
  68
  69 =head3 enqueue
  70
  71 Enqueue a new job. It will insert a new row in the DB table and notify the broker that a new job has been enqueued.
  72
  73 C<job_size> is the size of the job
  74 C<job_args> is the arguments of the job. It's a structure that will be JSON encoded.
  75
  76 Return the job_id of the newly created job.
  77
  78 =cut
  79
  80 sub enqueue {
  81     my ( $self, $params ) = @_;
  82
  83     my $job_type = $self->job_type;
  84     my $job_size = $params->{job_size};
  85     my $job_args = $params->{job_args};
  86
  87     my $borrowernumber = C4::Context->userenv->{number}; # FIXME Handle non GUI calls
  88     my $json_args = encode_json $job_args;
  89     my $job_id;
  90     $self->_result->result_source->schema->txn_do(
  91         sub {
  92             $self->set(
  93                 {
  94                     status         => 'new',
  95                     type           => $job_type,
  96                     size           => $job_size,
  97                     data           => $json_args,
  98                     enqueued_on    => dt_from_string,
  99                     borrowernumber => $borrowernumber,
 100                 }
 101             )->store;
 102
 103             $job_id = $self->id;
 104             $job_args->{job_id} = $job_id;
 105             $json_args = encode_json $job_args;
 106
 107             my $conn = $self->connect;
 108             # This namespace is wrong, it must be a vhost instead.
 109             # But to do so it needs to be created on the server => much more work when a new Koha instance is created.
 110             # Also, here we just want the Koha instance's name, but it's not in the config...
 111             # Picking a random id (memcached_namespace) from the config
 112             my $namespace = C4::Context->config('memcached_namespace');
 113             $conn->send_with_receipt( { destination => sprintf("/queue/%s-%s", $namespace, $job_type), body => $json_args } )
 114               or Koha::Exceptions::Exception->throw('Job has not been enqueued');
 115         }
 116     );
 117
 118     return $job_id;
 119 }
 120
 121 =head3 process
 122
 123 Process the job!
 124
 125 =cut
 126
 127 sub process {
 128     my ( $self, $args ) = @_;
 129
 130     my $job_type = $self->type;
 131     return $job_type eq 'batch_biblio_record_modification'
 132       ? Koha::BackgroundJob::BatchUpdateBiblio->process($args)
 133       : $job_type eq 'batch_authority_record_modification'
 134       ? Koha::BackgroundJob::BatchUpdateAuthority->process($args)
 135       : Koha::Exceptions::Exception->throw('->process called without valid job_type');
 136 }
 137
 138 =head3 job_type
 139
 140 Return the job type of the job. Must be a string.
 141
 142 =cut
 143
 144 sub job_type { croak "This method must be subclassed" }
 145
 146 =head3 messages
 147
 148 Messages let during the processing of the job.
 149
 150 =cut
 151
 152 sub messages {
 153     my ( $self ) = @_;
 154
 155     my @messages;
 156     my $data_dump = decode_json $self->data;
 157     if ( exists $data_dump->{messages} ) {
 158         @messages = @{ $data_dump->{messages} };
 159     }
 160
 161     return @messages;
 162 }
 163
 164 =head3 report
 165
 166 Report of the job.
 167
 168 =cut
 169
 170 sub report {
 171     my ( $self ) = @_;
 172
 173     my $data_dump = decode_json $self->data;
 174     return $data_dump->{report};
 175 }
 176
 177 =head3 cancel
 178
 179 Cancel a job.
 180
 181 =cut
 182
 183 sub cancel {
 184     my ( $self ) = @_;
 185     $self->status('cancelled')->store;
 186 }
 187
 188 sub _type {
 189     return 'BackgroundJob';
 190 }
 191
 192 1;