Koha/BackgroundJob.pm

   1 package Koha::BackgroundJob;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use JSON;
  20 use Carp qw( croak );
  21 use Net::Stomp;
  22 use Try::Tiny qw( catch try );
  23
  24 use C4::Context;
  25 use Koha::DateUtils qw( dt_from_string );
  26 use Koha::Exceptions;
  27 use Koha::Plugins;
  28 use Koha::Exceptions::BackgroundJob;
  29
  30 use base qw( Koha::Object );
  31
  32 =head1 NAME
  33
  34 Koha::BackgroundJob - Koha BackgroundJob Object class
  35
  36 This is a base class for BackgroundJob, some methods must be subclassed.
  37
  38 Example of usage:
  39
  40 Producer:
  41 my $job_id = Koha::BackgroundJob->enqueue(
  42     {
  43         job_type => $job_type,
  44         job_size => $job_size,
  45         job_args => $job_args
  46     }
  47 );
  48
  49 Consumer:
  50 Koha::BackgrounJobs->find($job_id)->process;
  51 See also C<misc/background_jobs_worker.pl> for a full example
  52
  53 =head1 API
  54
  55 =head2 Class methods
  56
  57 =head3 connect
  58
  59 Connect to the message broker using default guest/guest credential
  60
  61 =cut
  62
  63 sub connect {
  64     my ( $self );
  65     my $hostname = 'localhost';
  66     my $port = '61613';
  67     my $config = C4::Context->config('message_broker');
  68     my $credentials = {
  69         login => 'guest',
  70         passcode => 'guest',
  71     };
  72     if ($config){
  73         $hostname = $config->{hostname} if $config->{hostname};
  74         $port = $config->{port} if $config->{port};
  75         $credentials->{login} = $config->{username} if $config->{username};
  76         $credentials->{passcode} = $config->{password} if $config->{password};
  77         $credentials->{host} = $config->{vhost} if $config->{vhost};
  78     }
  79     my $stomp = Net::Stomp->new( { hostname => $hostname, port => $port } );
  80     $stomp->connect( $credentials );
  81     return $stomp;
  82 }
  83
  84 =head3 enqueue
  85
  86 Enqueue a new job. It will insert a new row in the DB table and notify the broker that a new job has been enqueued.
  87
  88 C<job_size> is the size of the job
  89 C<job_args> is the arguments of the job. It's a structure that will be JSON encoded.
  90
  91 Return the job_id of the newly created job.
  92
  93 =cut
  94
  95 sub enqueue {
  96     my ( $self, $params ) = @_;
  97
  98     my $job_type    = $self->job_type;
  99     my $job_size    = $params->{job_size};
 100     my $job_args    = $params->{job_args};
 101     my $job_context = $params->{job_context} // C4::Context->userenv;
 102     my $job_queue   = $params->{job_queue}  // 'default';
 103     my $json = $self->json;
 104
 105     my $borrowernumber = (C4::Context->userenv) ? C4::Context->userenv->{number} : undef;
 106     $job_context->{interface} = C4::Context->interface;
 107     my $json_context = $json->encode($job_context);
 108     my $json_args = $json->encode($job_args);
 109
 110     $self->set(
 111         {
 112             status         => 'new',
 113             type           => $job_type,
 114             queue          => $job_queue,
 115             size           => $job_size,
 116             data           => $json_args,
 117             context        => $json_context,
 118             enqueued_on    => dt_from_string,
 119             borrowernumber => $borrowernumber,
 120         }
 121     )->store;
 122
 123     $job_args->{job_id} = $self->id;
 124
 125     my $conn;
 126     try {
 127         $conn = $self->connect;
 128     } catch {
 129         warn "Cannot connect to broker " . $_;
 130     };
 131     return unless $conn;
 132
 133     $json_args = $json->encode($job_args);
 134     try {
 135         # This namespace is wrong, it must be a vhost instead.
 136         # But to do so it needs to be created on the server => much more work when a new Koha instance is created.
 137         # Also, here we just want the Koha instance's name, but it's not in the config...
 138         # Picking a random id (memcached_namespace) from the config
 139         my $namespace = C4::Context->config('memcached_namespace');
 140         $conn->send_with_receipt( { destination => sprintf("/queue/%s-%s", $namespace, $job_queue), body => $json_args } )
 141           or Koha::Exceptions::Exception->throw('Job has not been enqueued');
 142     } catch {
 143         $self->status('failed')->store;
 144         if ( ref($_) eq 'Koha::Exceptions::Exception' ) {
 145             $_->rethrow;
 146         } else {
 147             warn sprintf "The job has not been sent to the message broker: (%s)", $_;
 148         }
 149     };
 150
 151     return $self->id;
 152 }
 153
 154 =head3 process
 155
 156 Process the job!
 157
 158 =cut
 159
 160 sub process {
 161     my ( $self, $args ) = @_;
 162
 163     return {} if ref($self) ne 'Koha::BackgroundJob';
 164
 165     my $derived_class = $self->_derived_class;
 166
 167     $args ||= {};
 168
 169     if ( $self->context ) {
 170         my $context = $self->json->decode($self->context);
 171         C4::Context->_new_userenv(-1);
 172         C4::Context->interface( $context->{interface} );
 173         C4::Context->set_userenv(
 174             $context->{number},       $context->{id},
 175             $context->{cardnumber},   $context->{firstname},
 176             $context->{surname},      $context->{branch},
 177             $context->{branchname},   $context->{flags},
 178             $context->{emailaddress}, undef,
 179             $context->{desk_id},      $context->{desk_name},
 180             $context->{register_id},  $context->{register_name}
 181         );
 182     }
 183     else {
 184         Koha::Logger->get->warn("A background job didn't have context defined (" . $self->id . ")");
 185     }
 186
 187     return $derived_class->process( $args );
 188 }
 189
 190 =head3 start
 191
 192     $self->start;
 193
 194 Marks the job as started.
 195
 196 =cut
 197
 198 sub start {
 199     my ($self) = @_;
 200
 201     Koha::Exceptions::BackgroundJob::InconsistentStatus->throw(
 202         current_status  => $self->status,
 203         expected_status => 'new'
 204     ) unless $self->status eq 'new';
 205
 206     return $self->set(
 207         {
 208             started_on => \'NOW()',
 209             progress   => 0,
 210             status     => 'started',
 211         }
 212     )->store;
 213 }
 214
 215 =head3 step
 216
 217     $self->step;
 218
 219 Makes the job record a step has taken place.
 220
 221 =cut
 222
 223 sub step {
 224     my ($self) = @_;
 225
 226     Koha::Exceptions::BackgroundJob::InconsistentStatus->throw(
 227         current_status  => $self->status,
 228         expected_status => 'started'
 229     ) unless $self->status eq 'started';
 230
 231     # reached the end of the tasks already
 232     Koha::Exceptions::BackgroundJob::StepOutOfBounds->throw()
 233         unless $self->progress < $self->size;
 234
 235     return $self->progress( $self->progress + 1 )->store;
 236 }
 237
 238 =head3 finish
 239
 240     $self->finish;
 241
 242 Makes the job record as finished. If the job status is I<cancelled>, it is kept.
 243
 244 =cut
 245
 246 sub finish {
 247     my ( $self, $data ) = @_;
 248
 249     $self->status('finished') unless $self->status eq 'cancelled';
 250
 251     return $self->set(
 252         {
 253             ended_on => \'NOW()',
 254             data     => $self->json->encode($data),
 255         }
 256     )->store;
 257 }
 258
 259 =head3 json
 260
 261    my $JSON_object = $self->json;
 262
 263 Returns a JSON object with utf8 disabled. Encoding to UTF-8 should be
 264 done later.
 265
 266 =cut
 267
 268 sub json {
 269     my ( $self ) = @_;
 270     $self->{_json} //= JSON->new->utf8(0); # TODO Should we allow_nonref ?
 271     return $self->{_json};
 272 }
 273
 274 =head3 decoded_data
 275
 276     my $job_data = $self->decoded_data;
 277
 278 Returns the decoded JSON contents from $self->data.
 279
 280 =cut
 281
 282 sub decoded_data {
 283     my ($self) = @_;
 284
 285     return $self->data ? $self->json->decode( $self->data ) : undef;
 286 }
 287
 288 =head3 set_encoded_data
 289
 290     $self->set_encoded_data( $data );
 291
 292 Serializes I<$data> as a JSON string and sets the I<data> attribute with it.
 293
 294 =cut
 295
 296 sub set_encoded_data {
 297     my ( $self, $data ) = @_;
 298
 299     return $self->data( $data ? $self->json->encode($data) : undef );
 300 }
 301
 302 =head3 job_type
 303
 304 Return the job type of the job. Must be a string.
 305
 306 =cut
 307
 308 sub job_type { croak "This method must be subclassed" }
 309
 310 =head3 messages
 311
 312 Messages let during the processing of the job.
 313
 314 =cut
 315
 316 sub messages {
 317     my ( $self ) = @_;
 318
 319     my @messages;
 320     my $data_dump = $self->json->decode($self->data);
 321     if ( exists $data_dump->{messages} ) {
 322         @messages = @{ $data_dump->{messages} };
 323     }
 324
 325     return \@messages;
 326 }
 327
 328 =head3 report
 329
 330 Report of the job.
 331
 332 =cut
 333
 334 sub report {
 335     my ( $self ) = @_;
 336
 337     my $data_dump = $self->json->decode($self->data);
 338     return $data_dump->{report} || {};
 339 }
 340
 341 =head3 additional_report
 342
 343 Build additional variables for the job detail view.
 344
 345 =cut
 346
 347 sub additional_report {
 348     my ( $self ) = @_;
 349
 350     return {} if ref($self) ne 'Koha::BackgroundJob';
 351
 352     my $derived_class = $self->_derived_class;
 353
 354     return $derived_class->additional_report;
 355 }
 356
 357 =head3 cancel
 358
 359 Cancel a job.
 360
 361 =cut
 362
 363 sub cancel {
 364     my ( $self ) = @_;
 365     $self->status('cancelled')->store;
 366 }
 367
 368 =head2 Internal methods
 369
 370 =head3 _derived_class
 371
 372 =cut
 373
 374 sub _derived_class {
 375     my ( $self ) = @_;
 376     my $job_type = $self->type;
 377
 378     my $class = $self->type_to_class_mapping->{$job_type};
 379
 380     Koha::Exception->throw($job_type . ' is not a valid job_type')
 381         unless $class;
 382
 383     eval "require $class";
 384     return $class->_new_from_dbic( $self->_result );
 385 }
 386
 387 =head3 type_to_class_mapping
 388
 389     my $mapping = Koha::BackgrounJob->new->type_to_class_mapping;
 390
 391 Returns the available types to class mappings.
 392
 393 =cut
 394
 395 sub type_to_class_mapping {
 396     my ($self) = @_;
 397
 398     my $plugins_mapping = ( C4::Context->config("enable_plugins") ) ? $self->plugin_types_to_classes : {};
 399
 400     return ($plugins_mapping)
 401       ? { %{ $self->core_types_to_classes }, %$plugins_mapping }
 402       : $self->core_types_to_classes;
 403 }
 404
 405 =head3 core_types_to_classes
 406
 407     my $mappings = Koha::BackgrounJob->new->core_types_to_classes
 408
 409 Returns the core background jobs types to class mappings.
 410
 411 =cut
 412
 413 sub core_types_to_classes {
 414     return {
 415         batch_authority_record_deletion     => 'Koha::BackgroundJob::BatchDeleteAuthority',
 416         batch_authority_record_modification => 'Koha::BackgroundJob::BatchUpdateAuthority',
 417         batch_biblio_record_deletion        => 'Koha::BackgroundJob::BatchDeleteBiblio',
 418         batch_biblio_record_modification    => 'Koha::BackgroundJob::BatchUpdateBiblio',
 419         batch_item_record_deletion          => 'Koha::BackgroundJob::BatchDeleteItem',
 420         batch_item_record_modification      => 'Koha::BackgroundJob::BatchUpdateItem',
 421         batch_hold_cancel                   => 'Koha::BackgroundJob::BatchCancelHold',
 422         update_elastic_index                => 'Koha::BackgroundJob::UpdateElasticIndex',
 423         update_holds_queue_for_biblios      => 'Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue',
 424         stage_marc_for_import               => 'Koha::BackgroundJob::StageMARCForImport',
 425         marc_import_commit_batch            => 'Koha::BackgroundJob::MARCImportCommitBatch',
 426         marc_import_revert_batch            => 'Koha::BackgroundJob::MARCImportRevertBatch',
 427     };
 428 }
 429
 430 =head3 plugin_types_to_classes
 431
 432     my $mappings = Koha::BackgroundJob->new->plugin_types_to_classes
 433
 434 Returns the plugin-defined background jobs types to class mappings.
 435
 436 =cut
 437
 438 sub plugin_types_to_classes {
 439     my ($self) = @_;
 440
 441     unless ( exists $self->{_plugin_mapping} ) {
 442         my @plugins = Koha::Plugins->new()->GetPlugins( { method => 'background_tasks', } );
 443
 444         foreach my $plugin (@plugins) {
 445
 446             my $tasks    = $plugin->background_tasks;
 447             my $metadata = $plugin->get_metadata;
 448
 449             unless ( $metadata->{namespace} ) {
 450                 Koha::Logger->get->warn(
 451                         q{A plugin includes the 'background_tasks' method, }
 452                       . q{but doesn't provide the required 'namespace' }
 453                       . qq{method ($plugin->{class})} );
 454                 next;
 455             }
 456
 457             my $namespace = $metadata->{namespace};
 458
 459             foreach my $type ( keys %{$tasks} ) {
 460                 my $class = $tasks->{$type};
 461
 462                 # skip if conditions not met
 463                 next unless $type and $class;
 464
 465                 my $key = "plugin_$namespace" . "_$type";
 466
 467                 $self->{_plugin_mapping}->{$key} = $tasks->{$type};
 468             }
 469         }
 470     }
 471
 472     return $self->{_plugin_mapping};
 473 }
 474
 475 =head3 _type
 476
 477 =cut
 478
 479 sub _type {
 480     return 'BackgroundJob';
 481 }
 482
 483 1;