Koha/Checkouts/ReturnClaim.pm

   1 package Koha::Checkouts::ReturnClaim;
   2
   3 # Copyright ByWater Solutions 2019
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use base qw(Koha::Object);
  23
  24 use Koha::Checkouts;
  25 use Koha::Exceptions;
  26 use Koha::Exceptions::Checkouts::ReturnClaims;
  27 use Koha::Old::Checkouts;
  28 use Koha::Patrons;
  29
  30 =head1 NAME
  31
  32 Koha::Checkouts::ReturnClaim - Koha ReturnClaim object class
  33
  34 =head1 API
  35
  36 =head2 Class methods
  37
  38 =cut
  39
  40 =head3 store
  41
  42     my $return_claim = Koha::Checkout::ReturnClaim->new($args)->store;
  43
  44 Overloaded I<store> method that validates the attributes and raises relevant
  45 exceptions as needed.
  46
  47 =cut
  48
  49 sub store {
  50     my ( $self ) = @_;
  51
  52     unless ( $self->in_storage || $self->created_by ) {
  53         Koha::Exceptions::Checkouts::ReturnClaims::NoCreatedBy->throw();
  54     }
  55
  56     return $self->SUPER::store;
  57 }
  58
  59 =head3 checkout
  60
  61 =cut
  62
  63 sub checkout {
  64     my ($self) = @_;
  65
  66     my $checkout = Koha::Checkouts->find( $self->issue_id )
  67       || Koha::Old::Checkouts->find( $self->issue_id );
  68
  69     return $checkout;
  70 }
  71
  72 =head3 patron
  73
  74 =cut
  75
  76 sub patron {
  77     my ( $self ) = @_;
  78
  79     my $borrower = $self->_result->borrowernumber;
  80     return Koha::Patron->_new_from_dbic( $borrower ) if $borrower;
  81 }
  82
  83 =head3 resolve
  84
  85     $claim->resolve(
  86         {
  87             resolution      => $resolution,
  88             resolved_by     => $patron_id,
  89           [ resolved_on     => $dt
  90             new_lost_status => $status, ]
  91         }
  92     );
  93
  94 Resolve the claim.
  95
  96 =cut
  97
  98 sub resolve {
  99     my ( $self, $params ) = @_;
 100
 101     my @mandatory = ( 'resolution', 'resolved_by' );
 102     for my $param (@mandatory) {
 103         unless ( defined( $params->{$param} ) ) {
 104             Koha::Exceptions::MissingParameter->throw( error => "The $param parameter is mandatory" );
 105         }
 106     }
 107
 108     $self->_result->result_source->schema->txn_do(
 109         sub {
 110             $self->set(
 111                 {   resolution  => $params->{resolution},
 112                     resolved_by => $params->{resolved_by},
 113                     resolved_on => $params->{resolved_on} // \'NOW()',
 114                     updated_by  => $params->{resolved_by}
 115                 }
 116             )->store;
 117
 118             if ( defined $params->{new_lost_status} ) {
 119                 $self->checkout->item->itemlost( $params->{new_lost_status} )->store;
 120             }
 121         }
 122     );
 123
 124     return $self;
 125 }
 126
 127 =head3 to_api_mapping
 128
 129 This method returns the mapping for representing a Koha::Checkouts::ReturnClaim object
 130 on the API.
 131
 132 =cut
 133
 134 sub to_api_mapping {
 135     return {
 136         id             => 'claim_id',
 137         itemnumber     => 'item_id',
 138         borrowernumber => 'patron_id',
 139     };
 140 }
 141
 142 =head2 Internal methods
 143
 144 =head3 _type
 145
 146 =cut
 147
 148 sub _type {
 149     return 'ReturnClaim';
 150 }
 151
 152 =head1 AUTHOR
 153
 154 Kyle M Hall <kyle@bywatersolutions.com>
 155
 156 =cut
 157
 158 1;