Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use Modern::Perl;
  20 use DateTime;
  21 use C4::Context;
  22 use Carp;
  23
  24 use base 'Exporter';
  25 use version; our $VERSION = qv('1.0.0');
  26
  27 our @EXPORT = (
  28     qw( dt_from_string output_pref format_sqldatetime )
  29 );
  30
  31 =head1 DateUtils
  32
  33 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  34
  35 =head1 DESCRIPTION
  36
  37 Koha has historically only used dates not datetimes and been content to
  38 handle these as strings. It also has confused formatting with actual dates
  39 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  40
  41 =cut
  42
  43 =head2 dt_ftom_string
  44
  45 $dt = dt_from_string($date_string, [$format, $timezone ]);
  46
  47 Passed a date string returns a DateTime object format and timezone default
  48 to the system preferences. If the date string is empty DateTime->now is returned
  49
  50 =cut
  51
  52 sub dt_from_string {
  53     my ( $date_string, $date_format, $tz ) = @_;
  54
  55     return if $date_string and $date_string =~ m|^0000-0|;
  56
  57     $tz = C4::Context->tz unless $tz;;
  58
  59     return DateTime->now( time_zone => $tz ) unless $date_string;
  60
  61     $date_format = C4::Context->preference('dateformat') unless $date_format;
  62
  63     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  64         return $date_string;
  65     }
  66
  67     my $regex;
  68
  69     # The fallback format is sql/iso
  70     my $fallback_re = qr|
  71         (?<year>\d{4})
  72         -
  73         (?<month>\d{2})
  74         -
  75         (?<day>\d{2})
  76     |xms;
  77
  78     if ( $date_format eq 'metric' ) {
  79         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  80         $regex = qr|
  81             (?<day>\d{2})
  82             /
  83             (?<month>\d{2})
  84             /
  85             (?<year>\d{4})
  86         |xms;
  87     }
  88     elsif ( $date_format eq 'us' ) {
  89         # us format is "mm/dd/yyyy[ hh:mm:ss]"
  90         $regex = qr|
  91             (?<month>\d{2})
  92             /
  93             (?<day>\d{2})
  94             /
  95             (?<year>\d{4})
  96         |xms;
  97     }
  98     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
  99         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 100         $regex = $fallback_re;
 101     }
 102     else {
 103         die "Invalid dateformat parameter ($date_format)";
 104     }
 105
 106     # Add the faculative time part [hh:mm[:ss]]
 107     my $time_re .= qr|
 108             (
 109                 \s*
 110                 (?<hour>\d{2})
 111                 :
 112                 (?<minute>\d{2})
 113                 (
 114                     :
 115                     (?<second>\d{2})
 116                 )?
 117             )?
 118     |xms;
 119     $regex .= $time_re;
 120     $fallback_re .= $time_re;
 121
 122     my %dt_params;
 123     if ( $date_string =~ $regex ) {
 124         %dt_params = (
 125             year   => $+{year},
 126             month  => $+{month},
 127             day    => $+{day},
 128             hour   => $+{hour},
 129             minute => $+{minute},
 130             second => $+{second},
 131         );
 132     } elsif ( $date_string =~ $fallback_re ) {
 133         %dt_params = (
 134             year   => $+{year},
 135             month  => $+{month},
 136             day    => $+{day},
 137             hour   => $+{hour},
 138             minute => $+{minute},
 139             second => $+{second},
 140         );
 141     }
 142     else {
 143         die "The given date ($date_string) does not match the date format ($date_format)";
 144     }
 145
 146     # system allows the 0th of the month
 147     $dt_params{day} = '01' if $dt_params{day} eq '00';
 148
 149     # Set default hh:mm:ss to 00:00:00
 150     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 151     $dt_params{minute} = 00 unless defined $dt_params{minute};
 152     $dt_params{second} = 00 unless defined $dt_params{second};
 153
 154     my $dt = eval {
 155         DateTime->new(
 156             %dt_params,
 157             # No TZ for dates 'infinite' => see bug 13242
 158             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 159         );
 160     };
 161     if ($@) {
 162         $tz = DateTime::TimeZone->new( name => 'floating' );
 163         $dt = DateTime->new(
 164             %dt_params,
 165             # No TZ for dates 'infinite' => see bug 13242
 166             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 167         );
 168     }
 169     return $dt;
 170 }
 171
 172 =head2 output_pref
 173
 174 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 175 $date_string = output_pref( $dt );
 176
 177 Returns a string containing the time & date formatted as per the C4::Context setting,
 178 or C<undef> if C<undef> was provided.
 179
 180 This routine can either be passed a DateTime object or or a hashref.  If it is
 181 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 182 an optional 'dateformat' to override the dateformat system preference, an
 183 optional 'timeformat' to override the TimeFormat system preference value,
 184 and an optional 'dateonly' to specify that only the formatted date string
 185 should be returned without the time.
 186
 187 =cut
 188
 189 sub output_pref {
 190     my $params = shift;
 191     my ( $dt, $str, $force_pref, $force_time, $dateonly, $as_due_date );
 192     if ( ref $params eq 'HASH' ) {
 193         $dt         = $params->{dt};
 194         $str        = $params->{str};
 195         $force_pref = $params->{dateformat};         # if testing we want to override Context
 196         $force_time = $params->{timeformat};
 197         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 198         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 199     } else {
 200         $dt = $params;
 201     }
 202
 203     carp "output_pref should not be called with both dt and str parameters"
 204         and return
 205             if $dt and $str;
 206
 207     $dt = eval { dt_from_string( $str ) } if $str;
 208     carp "Invalid date '$str' passed to output_pref\n" if $@;
 209
 210     return unless defined $dt;
 211
 212     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 213     if ( $dt->ymd !~ /^9999/ ) {
 214         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 215         $dt->set_time_zone( $tz );
 216     }
 217
 218     my $pref =
 219       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 220
 221     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 222     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 223     my $date;
 224     if ( $pref =~ m/^iso/ ) {
 225         $date = $dateonly
 226           ? $dt->strftime("%Y-%m-%d")
 227           : $dt->strftime("%Y-%m-%d $time");
 228     }
 229     elsif ( $pref =~ m/^metric/ ) {
 230         $date = $dateonly
 231           ? $dt->strftime("%d/%m/%Y")
 232           : $dt->strftime("%d/%m/%Y $time");
 233     }
 234     elsif ( $pref =~ m/^us/ ) {
 235         $date = $dateonly
 236           ? $dt->strftime("%m/%d/%Y")
 237           : $dt->strftime("%m/%d/%Y $time");
 238     }
 239     else {
 240         $date = $dateonly
 241           ? $dt->strftime("%Y-%m-%d")
 242           : $dt->strftime("%Y-%m-%d $time");
 243     }
 244
 245     if ( $as_due_date ) {
 246         $time_format eq '12hr'
 247             ? $date =~ s| 11:59 PM$||
 248             : $date =~ s| 23:59$||;
 249     }
 250
 251     return $date;
 252 }
 253
 254 =head2 format_sqldatetime
 255
 256 $string = format_sqldatetime( $string_as_returned_from_db );
 257
 258 a convenience routine for calling dt_from_string and formatting the result
 259 with output_pref as it is a frequent activity in scripts
 260
 261 =cut
 262
 263 sub format_sqldatetime {
 264     my $str        = shift;
 265     my $force_pref = shift;    # if testing we want to override Context
 266     my $force_time = shift;
 267     my $dateonly   = shift;
 268
 269     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 270         my $dt = dt_from_string( $str, 'sql' );
 271         return q{} unless $dt;
 272         $dt->truncate( to => 'minute' );
 273         return output_pref({
 274             dt => $dt,
 275             dateformat => $force_pref,
 276             timeformat => $force_time,
 277             dateonly => $dateonly
 278         });
 279     }
 280     return q{};
 281 }
 282
 283 1;