Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use C4::Context;
  24
  25 use base 'Exporter';
  26 use version; our $VERSION = qv('1.0.0');
  27
  28 our @EXPORT = (
  29     qw( dt_from_string output_pref format_sqldatetime )
  30 );
  31
  32 =head1 DateUtils
  33
  34 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  35
  36 =head1 DESCRIPTION
  37
  38 Koha has historically only used dates not datetimes and been content to
  39 handle these as strings. It also has confused formatting with actual dates
  40 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  41
  42 =cut
  43
  44 =head2 dt_ftom_string
  45
  46 $dt = dt_from_string($date_string, [$format, $timezone ]);
  47
  48 Passed a date string returns a DateTime object format and timezone default
  49 to the system preferences. If the date string is empty DateTime->now is returned
  50
  51 =cut
  52
  53 sub dt_from_string {
  54     my ( $date_string, $date_format, $tz ) = @_;
  55
  56     return if $date_string and $date_string =~ m|^0000-0|;
  57
  58     $tz = C4::Context->tz unless $tz;;
  59
  60     return DateTime->now( time_zone => $tz ) unless $date_string;
  61
  62     $date_format = C4::Context->preference('dateformat') unless $date_format;
  63
  64     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  65         return $date_string;
  66     }
  67
  68     my $regex;
  69
  70     # The fallback format is sql/iso
  71     my $fallback_re = qr|
  72         (?<year>\d{4})
  73         -
  74         (?<month>\d{2})
  75         -
  76         (?<day>\d{2})
  77     |xms;
  78
  79     if ( $date_format eq 'metric' ) {
  80         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  81         $regex = qr|
  82             (?<day>\d{2})
  83             /
  84             (?<month>\d{2})
  85             /
  86             (?<year>\d{4})
  87         |xms;
  88     }
  89     elsif ( $date_format eq 'us' ) {
  90         # us format is "mm/dd/yyyy[ hh:mm:ss]"
  91         $regex = qr|
  92             (?<month>\d{2})
  93             /
  94             (?<day>\d{2})
  95             /
  96             (?<year>\d{4})
  97         |xms;
  98     }
  99     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 100         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 101         $regex = $fallback_re;
 102     }
 103     else {
 104         die "Invalid dateformat parameter ($date_format)";
 105     }
 106
 107     # Add the faculative time part [hh:mm[:ss]]
 108     $regex .= qr|
 109             (
 110                 \s*
 111                 (?<hour>\d{2})
 112                 :
 113                 (?<minute>\d{2})
 114                 (
 115                     :
 116                     (?<second>\d{2})
 117                 )?
 118             )?
 119     |xms;
 120
 121     my %dt_params;
 122     if ( $date_string =~ $regex ) {
 123         %dt_params = (
 124             year   => $+{year},
 125             month  => $+{month},
 126             day    => $+{day},
 127             hour   => $+{hour},
 128             minute => $+{minute},
 129             second => $+{second},
 130         );
 131     } elsif ( $date_string =~ $fallback_re ) {
 132         %dt_params = (
 133             year   => $+{year},
 134             month  => $+{month},
 135             day    => $+{day},
 136             hour   => $+{hour},
 137             minute => $+{minute},
 138             second => $+{second},
 139         );
 140     }
 141     else {
 142         die "The given date ($date_string) does not match the date format ($date_format)";
 143     }
 144
 145     # system allows the 0th of the month
 146     $dt_params{day} = '01' if $dt_params{day} eq '00';
 147
 148     # Set default hh:mm:ss to 00:00:00
 149     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 150     $dt_params{minute} = 00 unless defined $dt_params{minute};
 151     $dt_params{second} = 00 unless defined $dt_params{second};
 152
 153     my $dt = eval {
 154         DateTime->new(
 155             %dt_params,
 156             # No TZ for dates 'infinite' => see bug 13242
 157             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 158         );
 159     };
 160     if ($@) {
 161         $tz = DateTime::TimeZone->new( name => 'floating' );
 162         $dt = DateTime->new(
 163             %dt_params,
 164             # No TZ for dates 'infinite' => see bug 13242
 165             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 166         );
 167     }
 168     return $dt;
 169 }
 170
 171 =head2 output_pref
 172
 173 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 174 $date_string = output_pref( $dt );
 175
 176 Returns a string containing the time & date formatted as per the C4::Context setting,
 177 or C<undef> if C<undef> was provided.
 178
 179 This routine can either be passed a DateTime object or or a hashref.  If it is
 180 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 181 an optional 'dateformat' to override the dateformat system preference, an
 182 optional 'timeformat' to override the TimeFormat system preference value,
 183 and an optional 'dateonly' to specify that only the formatted date string
 184 should be returned without the time.
 185
 186 =cut
 187
 188 sub output_pref {
 189     my $params = shift;
 190     my ( $dt, $force_pref, $force_time, $dateonly, $as_due_date );
 191     if ( ref $params eq 'HASH' ) {
 192         $dt         = $params->{dt};
 193         $force_pref = $params->{dateformat};         # if testing we want to override Context
 194         $force_time = $params->{timeformat};
 195         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 196         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 197     } else {
 198         $dt = $params;
 199     }
 200
 201     return unless defined $dt;
 202
 203     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 204     if ( $dt->ymd !~ /^9999/ ) {
 205         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 206         $dt->set_time_zone( $tz );
 207     }
 208
 209     my $pref =
 210       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 211
 212     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 213     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 214     my $date;
 215     if ( $pref =~ m/^iso/ ) {
 216         $date = $dateonly
 217           ? $dt->strftime("%Y-%m-%d")
 218           : $dt->strftime("%Y-%m-%d $time");
 219     }
 220     elsif ( $pref =~ m/^metric/ ) {
 221         $date = $dateonly
 222           ? $dt->strftime("%d/%m/%Y")
 223           : $dt->strftime("%d/%m/%Y $time");
 224     }
 225     elsif ( $pref =~ m/^us/ ) {
 226         $date = $dateonly
 227           ? $dt->strftime("%m/%d/%Y")
 228           : $dt->strftime("%m/%d/%Y $time");
 229     }
 230     else {
 231         $date = $dateonly
 232           ? $dt->strftime("%Y-%m-%d")
 233           : $dt->strftime("%Y-%m-%d $time");
 234     }
 235
 236     if ( $as_due_date ) {
 237         $time_format eq '12hr'
 238             ? $date =~ s| 11:59 PM$||
 239             : $date =~ s| 23:59$||;
 240     }
 241
 242     return $date;
 243 }
 244
 245 =head2 format_sqldatetime
 246
 247 $string = format_sqldatetime( $string_as_returned_from_db );
 248
 249 a convenience routine for calling dt_from_string and formatting the result
 250 with output_pref as it is a frequent activity in scripts
 251
 252 =cut
 253
 254 sub format_sqldatetime {
 255     my $str        = shift;
 256     my $force_pref = shift;    # if testing we want to override Context
 257     my $force_time = shift;
 258     my $dateonly   = shift;
 259
 260     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 261         my $dt = dt_from_string( $str, 'sql' );
 262         return q{} unless $dt;
 263         $dt->truncate( to => 'minute' );
 264         return output_pref({
 265             dt => $dt,
 266             dateformat => $force_pref,
 267             timeformat => $force_time,
 268             dateonly => $dateonly
 269         });
 270     }
 271     return q{};
 272 }
 273
 274 1;