Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use DateTime;
  21 use C4::Context;
  22 use Koha::Exceptions;
  23
  24 use vars qw(@ISA @EXPORT_OK);
  25 BEGIN {
  26     require Exporter;
  27     @ISA = qw(Exporter);
  28
  29     @EXPORT_OK = qw(
  30         dt_from_string
  31         output_pref
  32         format_sqldatetime
  33     );
  34 }
  35
  36 =head1 DateUtils
  37
  38 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  39
  40 =head1 DESCRIPTION
  41
  42 Koha has historically only used dates not datetimes and been content to
  43 handle these as strings. It also has confused formatting with actual dates
  44 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  45
  46 =cut
  47
  48 =head2 dt_ftom_string
  49
  50 $dt = dt_from_string($date_string, [$format, $timezone ]);
  51
  52 Passed a date string returns a DateTime object format and timezone default
  53 to the system preferences. If the date string is empty DateTime->now is returned
  54
  55 =cut
  56
  57 sub dt_from_string {
  58     my ( $date_string, $date_format, $tz ) = @_;
  59
  60     return if $date_string and $date_string =~ m|^0000-0|;
  61
  62     my $do_fallback = defined($date_format) ? 0 : 1;
  63     my $server_tz = C4::Context->tz;
  64     $tz = C4::Context->tz unless $tz;
  65
  66     return DateTime->now( time_zone => $tz ) unless $date_string;
  67
  68     $date_format = C4::Context->preference('dateformat') unless $date_format;
  69
  70     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  71         return $date_string;
  72     }
  73
  74     my $regex;
  75
  76     # The fallback format is sql/iso
  77     my $fallback_re = qr|
  78         (?<year>\d{4})
  79         -
  80         (?<month>\d{2})
  81         -
  82         (?<day>\d{2})
  83     |xms;
  84
  85     if ( $date_format eq 'metric' ) {
  86         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  87         $regex = qr|
  88             (?<day>\d{2})
  89             /
  90             (?<month>\d{2})
  91             /
  92             (?<year>\d{4})
  93         |xms;
  94     }
  95     elsif ( $date_format eq 'dmydot' ) {
  96         # dmydot format is "dd.mm.yyyy[ hh:mm:ss]"
  97         $regex = qr|
  98             (?<day>\d{2})
  99             .
 100             (?<month>\d{2})
 101             .
 102             (?<year>\d{4})
 103         |xms;
 104     }
 105     elsif ( $date_format eq 'us' ) {
 106         # us format is "mm/dd/yyyy[ hh:mm:ss]"
 107         $regex = qr|
 108             (?<month>\d{2})
 109             /
 110             (?<day>\d{2})
 111             /
 112             (?<year>\d{4})
 113         |xms;
 114     }
 115     elsif ( $date_format eq 'rfc3339' ) {
 116         $regex = qr/
 117             (?<year>\d{4})
 118             -
 119             (?<month>\d{2})
 120             -
 121             (?<day>\d{2})
 122             ([Tt\s])
 123             (?<hour>\d{2})
 124             :
 125             (?<minute>\d{2})
 126             :
 127             (?<second>\d{2})
 128             (\.\d{1,3})?(([Zz]$)|((?<offset>[\+|\-])(?<hours>[01][0-9]|2[0-3]):(?<minutes>[0-5][0-9])))
 129         /xms;
 130
 131         # Default to UTC (when 'Z' is passed) for inbound timezone.
 132         # The regex above succeeds for both 'z', 'Z' and '+/-' offset.
 133         # We set tz as though Z was passed by default and then correct it later if an offset is detected
 134         # by the presence fo the <offset> variable.
 135         $tz = DateTime::TimeZone->new( name => 'UTC' );
 136     }
 137     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 138         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 139         $regex = $fallback_re;
 140     }
 141     else {
 142         die "Invalid dateformat parameter ($date_format)";
 143     }
 144
 145     # Add the faculative time part [hh:mm[:ss]]
 146     my $time_re .= qr|
 147             (
 148                 \s*
 149                 (?<hour>\d{2})
 150                 :
 151                 (?<minute>\d{2})
 152                 (
 153                     :
 154                     (?<second>\d{2})
 155                 )?
 156                 (
 157                     \s
 158                     (?<ampm>\w{2})
 159                 )?
 160             )?
 161     |xms;
 162     $regex .= $time_re unless ( $date_format eq 'rfc3339' );
 163     $fallback_re .= $time_re;
 164
 165     my %dt_params;
 166     my $ampm;
 167     if ( $date_string =~ $regex ) {
 168         %dt_params = (
 169             year   => $+{year},
 170             month  => $+{month},
 171             day    => $+{day},
 172             hour   => $+{hour},
 173             minute => $+{minute},
 174             second => $+{second},
 175         );
 176         $ampm = $+{ampm};
 177         if ( $+{offset} ) {
 178             # If offset given, set inbound timezone using it.
 179             $tz = DateTime::TimeZone->new( name => $+{offset} . $+{hours} . $+{minutes} );
 180         }
 181     } elsif ( $do_fallback && $date_string =~ $fallback_re ) {
 182         %dt_params = (
 183             year   => $+{year},
 184             month  => $+{month},
 185             day    => $+{day},
 186             hour   => $+{hour},
 187             minute => $+{minute},
 188             second => $+{second},
 189         );
 190         $ampm = $+{ampm};
 191     }
 192     else {
 193         die "The given date ($date_string) does not match the date format ($date_format)";
 194     }
 195
 196     # system allows the 0th of the month
 197     $dt_params{day} = '01' if $dt_params{day} eq '00';
 198
 199     # Set default hh:mm:ss to 00:00:00
 200     my $date_only = ( !defined( $dt_params{hour} )
 201         && !defined( $dt_params{minute} )
 202         && !defined( $dt_params{second} ) );
 203     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 204     $dt_params{minute} = 00 unless defined $dt_params{minute};
 205     $dt_params{second} = 00 unless defined $dt_params{second};
 206
 207     if ( $ampm ) {
 208         if ( $ampm eq 'AM' ) {
 209             $dt_params{hour} = 00 if $dt_params{hour} == 12;
 210         } elsif ( $dt_params{hour} != 12 ) { # PM
 211             $dt_params{hour} += 12;
 212             $dt_params{hour} = 00 if $dt_params{hour} == 24;
 213         }
 214     }
 215
 216     my $floating = 0;
 217     my $dt = eval {
 218         DateTime->new(
 219             %dt_params,
 220             # No TZ for dates 'infinite' => see bug 13242
 221             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 222         );
 223     };
 224     if ($@) {
 225         $tz = DateTime::TimeZone->new( name => 'floating' );
 226         $floating = 1;
 227         $dt = DateTime->new(
 228             %dt_params,
 229             # No TZ for dates 'infinite' => see bug 13242
 230             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 231         );
 232     }
 233
 234     # Convert to configured timezone (unless we started with a dateonly string or had to drop to floating time)
 235     $dt->set_time_zone($server_tz) unless ( $date_only || $floating );
 236
 237     return $dt;
 238 }
 239
 240 =head2 output_pref
 241
 242 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 243 $date_string = output_pref( $dt );
 244
 245 Returns a string containing the time & date formatted as per the C4::Context setting,
 246 or C<undef> if C<undef> was provided.
 247
 248 This routine can either be passed a DateTime object or or a hashref.  If it is
 249 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 250 an optional 'dateformat' to override the dateformat system preference, an
 251 optional 'timeformat' to override the TimeFormat system preference value,
 252 and an optional 'dateonly' to specify that only the formatted date string
 253 should be returned without the time.
 254
 255 =cut
 256
 257 sub output_pref {
 258     my $params = shift;
 259     my ( $dt, $str, $force_pref, $force_time, $dateonly, $as_due_date );
 260     if ( ref $params eq 'HASH' ) {
 261         $dt         = $params->{dt};
 262         $str        = $params->{str};
 263         $force_pref = $params->{dateformat};         # if testing we want to override Context
 264         $force_time = $params->{timeformat};
 265         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 266         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 267     } else {
 268         $dt = $params;
 269     }
 270
 271     Koha::Exceptions::WrongParameter->throw( 'output_pref should not be called with both dt and str parameter' ) if $dt and $str;
 272
 273     if ( $str ) {
 274         local $@;
 275         $dt = eval { dt_from_string( $str ) };
 276         Koha::Exceptions::WrongParameter->throw("Invalid date '$str' passed to output_pref" ) if $@;
 277     }
 278
 279     return if !defined $dt; # NULL date
 280     Koha::Exceptions::WrongParameter->throw( "output_pref is called with '$dt' (ref ". ( ref($dt) ? ref($dt):'SCALAR')."), not a DateTime object")  if ref($dt) ne 'DateTime';
 281
 282     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 283     if ( $dt->ymd !~ /^9999/ ) {
 284         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 285         $dt->set_time_zone( $tz );
 286     }
 287
 288     my $pref =
 289       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 290
 291     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 292     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 293     my $date;
 294     if ( $pref =~ m/^iso/ ) {
 295         $date = $dateonly
 296           ? $dt->strftime("%Y-%m-%d")
 297           : $dt->strftime("%Y-%m-%d $time");
 298     }
 299     elsif ( $pref =~ m/^rfc3339/ ) {
 300         if (!$dateonly) {
 301             $date = $dt->strftime('%FT%T%z');
 302             substr($date, -2, 0, ':'); # timezone "HHmm" => "HH:mm"
 303         }
 304         else {
 305             $date = $dt->strftime("%Y-%m-%d");
 306         }
 307     }
 308     elsif ( $pref =~ m/^metric/ ) {
 309         $date = $dateonly
 310           ? $dt->strftime("%d/%m/%Y")
 311           : $dt->strftime("%d/%m/%Y $time");
 312     }
 313     elsif ( $pref =~ m/^dmydot/ ) {
 314         $date = $dateonly
 315           ? $dt->strftime("%d.%m.%Y")
 316           : $dt->strftime("%d.%m.%Y $time");
 317     }
 318
 319     elsif ( $pref =~ m/^us/ ) {
 320         $date = $dateonly
 321           ? $dt->strftime("%m/%d/%Y")
 322           : $dt->strftime("%m/%d/%Y $time");
 323     }
 324     else {
 325         $date = $dateonly
 326           ? $dt->strftime("%Y-%m-%d")
 327           : $dt->strftime("%Y-%m-%d $time");
 328     }
 329
 330     if ( $as_due_date ) {
 331         $time_format eq '12hr'
 332             ? $date =~ s| 11:59 PM$||
 333             : $date =~ s| 23:59$||;
 334     }
 335
 336     return $date;
 337 }
 338
 339 =head2 format_sqldatetime
 340
 341 $string = format_sqldatetime( $string_as_returned_from_db );
 342
 343 a convenience routine for calling dt_from_string and formatting the result
 344 with output_pref as it is a frequent activity in scripts
 345
 346 =cut
 347
 348 sub format_sqldatetime {
 349     my $str        = shift;
 350     my $force_pref = shift;    # if testing we want to override Context
 351     my $force_time = shift;
 352     my $dateonly   = shift;
 353
 354     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 355         my $dt = dt_from_string( $str, 'sql' );
 356         return q{} unless $dt;
 357         $dt->truncate( to => 'minute' );
 358         return output_pref({
 359             dt => $dt,
 360             dateformat => $force_pref,
 361             timeformat => $force_time,
 362             dateonly => $dateonly
 363         });
 364     }
 365     return q{};
 366 }
 367
 368 1;