Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use DateTime;
  21 use C4::Context;
  22 use Koha::Exceptions;
  23
  24 use vars qw(@ISA @EXPORT_OK);
  25 BEGIN {
  26     require Exporter;
  27     @ISA = qw(Exporter);
  28
  29     @EXPORT_OK = qw(
  30         dt_from_string
  31         output_pref
  32         format_sqldatetime
  33     );
  34 }
  35
  36 =head1 DateUtils
  37
  38 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  39
  40 =head1 DESCRIPTION
  41
  42 Koha has historically only used dates not datetimes and been content to
  43 handle these as strings. It also has confused formatting with actual dates
  44 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  45
  46 =cut
  47
  48 =head2 dt_ftom_string
  49
  50 $dt = dt_from_string($date_string, [$format, $timezone ]);
  51
  52 Passed a date string returns a DateTime object format and timezone default
  53 to the system preferences. If the date string is empty DateTime->now is returned
  54
  55 =cut
  56
  57 sub dt_from_string {
  58     my ( $date_string, $date_format, $tz ) = @_;
  59
  60     return if $date_string and $date_string =~ m|^0000-0|;
  61
  62     my $do_fallback = defined($date_format) ? 0 : 1;
  63     my $server_tz = C4::Context->tz;
  64     $tz = C4::Context->tz unless $tz;
  65
  66     return DateTime->now( time_zone => $tz ) unless $date_string;
  67
  68     $date_format = C4::Context->preference('dateformat') unless $date_format;
  69
  70     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  71         return $date_string;
  72     }
  73
  74     my $regex;
  75
  76     # The fallback format is sql/iso
  77     my $fallback_re = qr|
  78         (?<year>\d{4})
  79         -
  80         (?<month>\d{2})
  81         -
  82         (?<day>\d{2})
  83     |xms;
  84
  85     if ( $date_format eq 'metric' ) {
  86         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  87         $regex = qr|
  88             (?<day>\d{2})
  89             /
  90             (?<month>\d{2})
  91             /
  92             (?<year>\d{4})
  93         |xms;
  94     }
  95     elsif ( $date_format eq 'dmydot' ) {
  96         # dmydot format is "dd.mm.yyyy[ hh:mm:ss]"
  97         $regex = qr|
  98             (?<day>\d{2})
  99             .
 100             (?<month>\d{2})
 101             .
 102             (?<year>\d{4})
 103         |xms;
 104     }
 105     elsif ( $date_format eq 'us' ) {
 106         # us format is "mm/dd/yyyy[ hh:mm:ss]"
 107         $regex = qr|
 108             (?<month>\d{2})
 109             /
 110             (?<day>\d{2})
 111             /
 112             (?<year>\d{4})
 113         |xms;
 114     }
 115     elsif ( $date_format eq 'rfc3339' ) {
 116         $regex = qr/
 117             (?<year>\d{4})
 118             -
 119             (?<month>\d{2})
 120             -
 121             (?<day>\d{2})
 122             ([Tt\s])
 123             (?<hour>\d{2})
 124             :
 125             (?<minute>\d{2})
 126             :
 127             (?<second>\d{2})
 128             (\.\d{1,3})?(([Zz]$)|((?<offset>[\+|\-])(?<hours>[01][0-9]|2[0-3]):(?<minutes>[0-5][0-9])))
 129         /xms;
 130
 131         # Default to UTC (when 'Z' is passed) for inbound timezone.
 132         # The regex above succeeds for both 'z', 'Z' and '+/-' offset.
 133         # We set tz as though Z was passed by default and then correct it later if an offset is detected
 134         # by the presence fo the <offset> variable.
 135         $tz = DateTime::TimeZone->new( name => 'UTC' );
 136     }
 137     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 138         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 139         $regex = $fallback_re;
 140     }
 141     else {
 142         die "Invalid dateformat parameter ($date_format)";
 143     }
 144
 145     # Add the facultative time part including time zone offset; ISO8601 allows +02 or +0200 too
 146     my $time_re .= qr{
 147             (
 148                 [Tt]?
 149                 \s*
 150                 (?<hour>\d{2})
 151                 :
 152                 (?<minute>\d{2})
 153                 (
 154                     :
 155                     (?<second>\d{2})
 156                 )?
 157                 (
 158                     \s
 159                     (?<ampm>\w{2})
 160                 )?
 161                 (
 162                     (?<utc>[Zz]$)|((?<offset>[\+|\-])(?<hours>[01][0-9]|2[0-3]):?(?<minutes>[0-5][0-9])?)
 163                 )?
 164             )?
 165     }xms;
 166     $regex .= $time_re unless ( $date_format eq 'rfc3339' );
 167     $fallback_re .= $time_re;
 168
 169     my %dt_params;
 170     my $ampm;
 171     if ( $date_string =~ $regex ) {
 172         %dt_params = (
 173             year   => $+{year},
 174             month  => $+{month},
 175             day    => $+{day},
 176             hour   => $+{hour},
 177             minute => $+{minute},
 178             second => $+{second},
 179         );
 180         $ampm = $+{ampm};
 181         if ( $+{utc} ) {
 182             $tz = DateTime::TimeZone->new( name => 'UTC' );
 183         }
 184         if ( $+{offset} ) {
 185             # If offset given, set inbound timezone using it.
 186             $tz = DateTime::TimeZone->new( name => $+{offset} . $+{hours} . ( $+{minutes} || '00' ) );
 187         }
 188     } elsif ( $do_fallback && $date_string =~ $fallback_re ) {
 189         %dt_params = (
 190             year   => $+{year},
 191             month  => $+{month},
 192             day    => $+{day},
 193             hour   => $+{hour},
 194             minute => $+{minute},
 195             second => $+{second},
 196         );
 197         $ampm = $+{ampm};
 198     }
 199     else {
 200         die "The given date ($date_string) does not match the date format ($date_format)";
 201     }
 202
 203     # system allows the 0th of the month
 204     $dt_params{day} = '01' if $dt_params{day} eq '00';
 205
 206     # Set default hh:mm:ss to 00:00:00
 207     my $date_only = ( !defined( $dt_params{hour} )
 208         && !defined( $dt_params{minute} )
 209         && !defined( $dt_params{second} ) );
 210     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 211     $dt_params{minute} = 00 unless defined $dt_params{minute};
 212     $dt_params{second} = 00 unless defined $dt_params{second};
 213
 214     if ( $ampm ) {
 215         if ( $ampm eq 'AM' ) {
 216             $dt_params{hour} = 00 if $dt_params{hour} == 12;
 217         } elsif ( $dt_params{hour} != 12 ) { # PM
 218             $dt_params{hour} += 12;
 219             $dt_params{hour} = 00 if $dt_params{hour} == 24;
 220         }
 221     }
 222
 223     my $floating = 0;
 224     my $dt = eval {
 225         DateTime->new(
 226             %dt_params,
 227             # No TZ for dates 'infinite' => see bug 13242
 228             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 229         );
 230     };
 231     if ($@) {
 232         $tz = DateTime::TimeZone->new( name => 'floating' );
 233         $floating = 1;
 234         $dt = DateTime->new(
 235             %dt_params,
 236             # No TZ for dates 'infinite' => see bug 13242
 237             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 238         );
 239     }
 240
 241     # Convert to configured timezone (unless we started with a dateonly string or had to drop to floating time)
 242     $dt->set_time_zone($server_tz) unless ( $date_only || $floating );
 243
 244     return $dt;
 245 }
 246
 247 =head2 output_pref
 248
 249 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 250 $date_string = output_pref( $dt );
 251
 252 Returns a string containing the time & date formatted as per the C4::Context setting,
 253 or C<undef> if C<undef> was provided.
 254
 255 This routine can either be passed a DateTime object or or a hashref.  If it is
 256 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 257 an optional 'dateformat' to override the dateformat system preference, an
 258 optional 'timeformat' to override the TimeFormat system preference value,
 259 and an optional 'dateonly' to specify that only the formatted date string
 260 should be returned without the time.
 261
 262 =cut
 263
 264 sub output_pref {
 265     my $params = shift;
 266     my ( $dt, $str, $force_pref, $force_time, $dateonly, $as_due_date );
 267     if ( ref $params eq 'HASH' ) {
 268         $dt         = $params->{dt};
 269         $str        = $params->{str};
 270         $force_pref = $params->{dateformat};         # if testing we want to override Context
 271         $force_time = $params->{timeformat};
 272         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 273         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 274     } else {
 275         $dt = $params;
 276     }
 277
 278     Koha::Exceptions::WrongParameter->throw( 'output_pref should not be called with both dt and str parameter' ) if $dt and $str;
 279
 280     if ( $str ) {
 281         local $@;
 282         $dt = eval { dt_from_string( $str ) };
 283         Koha::Exceptions::WrongParameter->throw("Invalid date '$str' passed to output_pref" ) if $@;
 284     }
 285
 286     return if !defined $dt; # NULL date
 287     Koha::Exceptions::WrongParameter->throw( "output_pref is called with '$dt' (ref ". ( ref($dt) ? ref($dt):'SCALAR')."), not a DateTime object")  if ref($dt) ne 'DateTime';
 288
 289     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 290     if ( $dt->ymd !~ /^9999/ ) {
 291         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 292         $dt->set_time_zone( $tz );
 293     }
 294
 295     my $pref =
 296       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 297
 298     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 299     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 300     my $date;
 301     if ( $pref =~ m/^iso/ ) {
 302         $date = $dateonly
 303           ? $dt->strftime("%Y-%m-%d")
 304           : $dt->strftime("%Y-%m-%d $time");
 305     }
 306     elsif ( $pref =~ m/^rfc3339/ ) {
 307         if (!$dateonly) {
 308             $date = $dt->strftime('%FT%T%z');
 309             substr($date, -2, 0, ':'); # timezone "HHmm" => "HH:mm"
 310         }
 311         else {
 312             $date = $dt->strftime("%Y-%m-%d");
 313         }
 314     }
 315     elsif ( $pref =~ m/^metric/ ) {
 316         $date = $dateonly
 317           ? $dt->strftime("%d/%m/%Y")
 318           : $dt->strftime("%d/%m/%Y $time");
 319     }
 320     elsif ( $pref =~ m/^dmydot/ ) {
 321         $date = $dateonly
 322           ? $dt->strftime("%d.%m.%Y")
 323           : $dt->strftime("%d.%m.%Y $time");
 324     }
 325
 326     elsif ( $pref =~ m/^us/ ) {
 327         $date = $dateonly
 328           ? $dt->strftime("%m/%d/%Y")
 329           : $dt->strftime("%m/%d/%Y $time");
 330     }
 331     else {
 332         $date = $dateonly
 333           ? $dt->strftime("%Y-%m-%d")
 334           : $dt->strftime("%Y-%m-%d $time");
 335     }
 336
 337     if ( $as_due_date ) {
 338         $time_format eq '12hr'
 339             ? $date =~ s| 11:59 PM$||
 340             : $date =~ s| 23:59$||;
 341     }
 342
 343     return $date;
 344 }
 345
 346 =head2 format_sqldatetime
 347
 348 $string = format_sqldatetime( $string_as_returned_from_db );
 349
 350 a convenience routine for calling dt_from_string and formatting the result
 351 with output_pref as it is a frequent activity in scripts
 352
 353 =cut
 354
 355 sub format_sqldatetime {
 356     my $str        = shift;
 357     my $force_pref = shift;    # if testing we want to override Context
 358     my $force_time = shift;
 359     my $dateonly   = shift;
 360
 361     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 362         my $dt = dt_from_string( $str, 'sql' );
 363         return q{} unless $dt;
 364         $dt->truncate( to => 'minute' );
 365         return output_pref({
 366             dt => $dt,
 367             dateformat => $force_pref,
 368             timeformat => $force_time,
 369             dateonly => $dateonly
 370         });
 371     }
 372     return q{};
 373 }
 374
 375 1;