Koha/Hold.pm

   1 package Koha::Hold;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright 2017 Koha Development team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use Data::Dumper qw(Dumper);
  25
  26 use C4::Context qw(preference);
  27 use C4::Letters;
  28 use C4::Log;
  29
  30 use Koha::AuthorisedValues;
  31 use Koha::DateUtils qw(dt_from_string output_pref);
  32 use Koha::Patrons;
  33 use Koha::Biblios;
  34 use Koha::Items;
  35 use Koha::Libraries;
  36 use Koha::Old::Holds;
  37 use Koha::Calendar;
  38
  39 use Koha::Exceptions::Hold;
  40
  41 use base qw(Koha::Object);
  42
  43 =head1 NAME
  44
  45 Koha::Hold - Koha Hold object class
  46
  47 =head1 API
  48
  49 =head2 Class Methods
  50
  51 =cut
  52
  53 =head3 age
  54
  55 returns the number of days since a hold was placed, optionally
  56 using the calendar
  57
  58 my $age = $hold->age( $use_calendar );
  59
  60 =cut
  61
  62 sub age {
  63     my ( $self, $use_calendar ) = @_;
  64
  65     my $today = dt_from_string;
  66     my $age;
  67
  68     if ( $use_calendar ) {
  69         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode );
  70         $age = $calendar->days_between( dt_from_string( $self->reservedate ), $today );
  71     }
  72     else {
  73         $age = $today->delta_days( dt_from_string( $self->reservedate ) );
  74     }
  75
  76     $age = $age->in_units( 'days' );
  77
  78     return $age;
  79 }
  80
  81 =head3 suspend_hold
  82
  83 my $hold = $hold->suspend_hold( $suspend_until_dt );
  84
  85 =cut
  86
  87 sub suspend_hold {
  88     my ( $self, $dt ) = @_;
  89
  90     my $date = $dt ? $dt->clone()->truncate( to => 'day' )->datetime : undef;
  91
  92     if ( $self->is_found ) {    # We can't suspend found holds
  93         if ( $self->is_waiting ) {
  94             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'W' );
  95         }
  96         elsif ( $self->is_in_transit ) {
  97             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'T' );
  98         }
  99         elsif ( $self->is_in_processing ) {
 100             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'P' );
 101         }
 102         else {
 103             Koha::Exceptions::Hold::CannotSuspendFound->throw(
 104                       'Unhandled data exception on found hold (id='
 105                     . $self->id
 106                     . ', found='
 107                     . $self->found
 108                     . ')' );
 109         }
 110     }
 111
 112     $self->suspend(1);
 113     $self->suspend_until($date);
 114     $self->store();
 115
 116     logaction( 'HOLDS', 'SUSPEND', $self->reserve_id, Dumper( $self->unblessed ) )
 117         if C4::Context->preference('HoldsLog');
 118
 119     return $self;
 120 }
 121
 122 =head3 resume
 123
 124 my $hold = $hold->resume();
 125
 126 =cut
 127
 128 sub resume {
 129     my ( $self ) = @_;
 130
 131     $self->suspend(0);
 132     $self->suspend_until( undef );
 133
 134     $self->store();
 135
 136     logaction( 'HOLDS', 'RESUME', $self->reserve_id, Dumper($self->unblessed) )
 137         if C4::Context->preference('HoldsLog');
 138
 139     return $self;
 140 }
 141
 142 =head3 delete
 143
 144 $hold->delete();
 145
 146 =cut
 147
 148 sub delete {
 149     my ( $self ) = @_;
 150
 151     my $deleted = $self->SUPER::delete($self);
 152
 153     logaction( 'HOLDS', 'DELETE', $self->reserve_id, Dumper($self->unblessed) )
 154         if C4::Context->preference('HoldsLog');
 155
 156     return $deleted;
 157 }
 158
 159 =head3 set_transfer
 160
 161 =cut
 162
 163 sub set_transfer {
 164     my ( $self ) = @_;
 165
 166     $self->priority(0);
 167     $self->found('T');
 168     $self->store();
 169
 170     return $self;
 171 }
 172
 173 =head3 set_waiting
 174
 175 =cut
 176
 177 sub set_waiting {
 178     my ( $self, $desk_id ) = @_;
 179
 180     $self->priority(0);
 181
 182     my $today = dt_from_string();
 183     my $values = {
 184         found => 'W',
 185         waitingdate => $today->ymd,
 186         desk_id => $desk_id,
 187     };
 188
 189     my $requested_expiration;
 190     if ($self->expirationdate) {
 191         $requested_expiration = dt_from_string($self->expirationdate);
 192     }
 193
 194     my $max_pickup_delay = C4::Context->preference("ReservesMaxPickUpDelay");
 195     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 196
 197     my $expirationdate = $today->clone;
 198     $expirationdate->add(days => $max_pickup_delay);
 199
 200     if ( C4::Context->preference("ExcludeHolidaysFromMaxPickUpDelay") ) {
 201         my $itemtype = $self->item ? $self->item->effective_itemtype : $self->biblio->itemtype;
 202         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
 203             {
 204                 categorycode => $self->borrower->categorycode,
 205                 itemtype     => $itemtype,
 206                 branchcode   => $self->branchcode,
 207             }
 208         );
 209         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode, days_mode => $daysmode );
 210
 211         $expirationdate = $calendar->days_forward( dt_from_string(), $max_pickup_delay );
 212     }
 213
 214     # If patron's requested expiration date is prior to the
 215     # calculated one, we keep the patron's one.
 216     my $cmp = $requested_expiration ? DateTime->compare($requested_expiration, $expirationdate) : 0;
 217     $values->{expirationdate} = $cmp == -1 ? $requested_expiration->ymd : $expirationdate->ymd;
 218
 219     $self->set($values)->store();
 220
 221     return $self;
 222 }
 223
 224 =head3 set_processing
 225
 226 $hold->set_processing;
 227
 228 Mark the hold as in processing.
 229
 230 =cut
 231
 232 sub set_processing {
 233     my ( $self ) = @_;
 234
 235     $self->priority(0);
 236     $self->found('P');
 237     $self->store();
 238
 239     return $self;
 240 }
 241
 242 =head3 is_found
 243
 244 Returns true if hold is waiting, in transit or in processing
 245
 246 =cut
 247
 248 sub is_found {
 249     my ($self) = @_;
 250
 251     return 0 unless $self->found();
 252     return 1 if $self->found() eq 'W';
 253     return 1 if $self->found() eq 'T';
 254     return 1 if $self->found() eq 'P';
 255 }
 256
 257 =head3 is_waiting
 258
 259 Returns true if hold is a waiting hold
 260
 261 =cut
 262
 263 sub is_waiting {
 264     my ($self) = @_;
 265
 266     my $found = $self->found;
 267     return $found && $found eq 'W';
 268 }
 269
 270 =head3 is_in_transit
 271
 272 Returns true if hold is a in_transit hold
 273
 274 =cut
 275
 276 sub is_in_transit {
 277     my ($self) = @_;
 278
 279     return 0 unless $self->found();
 280     return $self->found() eq 'T';
 281 }
 282
 283 =head3 is_in_processing
 284
 285 Returns true if hold is a in_processing hold
 286
 287 =cut
 288
 289 sub is_in_processing {
 290     my ($self) = @_;
 291
 292     return 0 unless $self->found();
 293     return $self->found() eq 'P';
 294 }
 295
 296 =head3 is_cancelable_from_opac
 297
 298 Returns true if hold is a cancelable hold
 299
 300 Holds may be only canceled if they are not found.
 301
 302 This is used from the OPAC.
 303
 304 =cut
 305
 306 sub is_cancelable_from_opac {
 307     my ($self) = @_;
 308
 309     return 1 unless $self->is_found();
 310     return 0; # if ->is_in_transit or if ->is_waiting or ->is_in_processing
 311 }
 312
 313 =head3 is_at_destination
 314
 315 Returns true if hold is waiting
 316 and the hold's pickup branch matches
 317 the hold item's holding branch
 318
 319 =cut
 320
 321 sub is_at_destination {
 322     my ($self) = @_;
 323
 324     return $self->is_waiting() && ( $self->branchcode() eq $self->item()->holdingbranch() );
 325 }
 326
 327 =head3 biblio
 328
 329 Returns the related Koha::Biblio object for this hold
 330
 331 =cut
 332
 333 sub biblio {
 334     my ($self) = @_;
 335
 336     $self->{_biblio} ||= Koha::Biblios->find( $self->biblionumber() );
 337
 338     return $self->{_biblio};
 339 }
 340
 341 =head3 item
 342
 343 Returns the related Koha::Item object for this Hold
 344
 345 =cut
 346
 347 sub item {
 348     my ($self) = @_;
 349
 350     $self->{_item} ||= Koha::Items->find( $self->itemnumber() );
 351
 352     return $self->{_item};
 353 }
 354
 355 =head3 branch
 356
 357 Returns the related Koha::Library object for this Hold
 358
 359 =cut
 360
 361 sub branch {
 362     my ($self) = @_;
 363
 364     $self->{_branch} ||= Koha::Libraries->find( $self->branchcode() );
 365
 366     return $self->{_branch};
 367 }
 368
 369 =head3 desk
 370
 371 Returns the related Koha::Desk object for this Hold
 372
 373 =cut
 374
 375 sub desk {
 376     my $self = shift;
 377     my $desk_rs = $self->_result->desk;
 378     return unless $desk_rs;
 379     return Koha::Desk->_new_from_dbic($desk_rs);
 380 }
 381
 382 =head3 borrower
 383
 384 Returns the related Koha::Patron object for this Hold
 385
 386 =cut
 387
 388 # FIXME Should be renamed with ->patron
 389 sub borrower {
 390     my ($self) = @_;
 391
 392     $self->{_borrower} ||= Koha::Patrons->find( $self->borrowernumber() );
 393
 394     return $self->{_borrower};
 395 }
 396
 397 =head3 is_suspended
 398
 399 my $bool = $hold->is_suspended();
 400
 401 =cut
 402
 403 sub is_suspended {
 404     my ( $self ) = @_;
 405
 406     return $self->suspend();
 407 }
 408
 409
 410 =head3 cancel
 411
 412 my $cancel_hold = $hold->cancel(
 413     {
 414         [ charge_cancel_fee => 1||0, ]
 415         [ cancellation_reason => $cancellation_reason, ]
 416     }
 417 );
 418
 419 Cancel a hold:
 420 - The hold will be moved to the old_reserves table with a priority=0
 421 - The priority of other holds will be updated
 422 - The patron will be charge (see ExpireReservesMaxPickUpDelayCharge) if the charge_cancel_fee parameter is set
 423 - The canceled hold will have the cancellation reason added to old_reserves.cancellation_reason if one is passed in
 424 - a CANCEL HOLDS log will be done if the pref HoldsLog is on
 425
 426 =cut
 427
 428 sub cancel {
 429     my ( $self, $params ) = @_;
 430     $self->_result->result_source->schema->txn_do(
 431         sub {
 432             $self->cancellationdate( dt_from_string->strftime( '%Y-%m-%d %H:%M:%S' ) );
 433             $self->priority(0);
 434             $self->cancellation_reason( $params->{cancellation_reason} );
 435             $self->store();
 436
 437             if ( $params->{cancellation_reason} ) {
 438                 my $letter = C4::Letters::GetPreparedLetter(
 439                     module                 => 'reserves',
 440                     letter_code            => 'HOLD_CANCELLATION',
 441                     message_transport_type => 'email',
 442                     branchcode             => $self->borrower->branchcode,
 443                     lang                   => $self->borrower->lang,
 444                     tables => {
 445                         branches    => $self->borrower->branchcode,
 446                         borrowers   => $self->borrowernumber,
 447                         items       => $self->itemnumber,
 448                         biblio      => $self->biblionumber,
 449                         biblioitems => $self->biblionumber,
 450                         reserves    => $self->unblessed,
 451                     }
 452                 );
 453
 454                 if ($letter) {
 455                     C4::Letters::EnqueueLetter(
 456                         {
 457                             letter                   => $letter,
 458                             borrowernumber         => $self->borrowernumber,
 459                             message_transport_type => 'email',
 460                         }
 461                     );
 462                 }
 463             }
 464
 465             $self->_move_to_old;
 466             $self->SUPER::delete(); # Do not add a DELETE log
 467
 468             # now fix the priority on the others....
 469             C4::Reserves::_FixPriority({ biblionumber => $self->biblionumber });
 470
 471             # and, if desired, charge a cancel fee
 472             my $charge = C4::Context->preference("ExpireReservesMaxPickUpDelayCharge");
 473             if ( $charge && $params->{'charge_cancel_fee'} ) {
 474                 my $account =
 475                   Koha::Account->new( { patron_id => $self->borrowernumber } );
 476                 $account->add_debit(
 477                     {
 478                         amount     => $charge,
 479                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 480                         interface  => C4::Context->interface,
 481                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 482                         type       => 'RESERVE_EXPIRED',
 483                         item_id    => $self->itemnumber
 484                     }
 485                 );
 486             }
 487
 488             C4::Log::logaction( 'HOLDS', 'CANCEL', $self->reserve_id, Dumper($self->unblessed) )
 489                 if C4::Context->preference('HoldsLog');
 490         }
 491     );
 492     return $self;
 493 }
 494
 495 =head3 _move_to_old
 496
 497 my $is_moved = $hold->_move_to_old;
 498
 499 Move a hold to the old_reserve table following the same pattern as Koha::Patron->move_to_deleted
 500
 501 =cut
 502
 503 sub _move_to_old {
 504     my ($self) = @_;
 505     my $hold_infos = $self->unblessed;
 506     return Koha::Old::Hold->new( $hold_infos )->store;
 507 }
 508
 509 =head3 to_api_mapping
 510
 511 This method returns the mapping for representing a Koha::Hold object
 512 on the API.
 513
 514 =cut
 515
 516 sub to_api_mapping {
 517     return {
 518         reserve_id       => 'hold_id',
 519         borrowernumber   => 'patron_id',
 520         reservedate      => 'hold_date',
 521         biblionumber     => 'biblio_id',
 522         branchcode       => 'pickup_library_id',
 523         notificationdate => undef,
 524         reminderdate     => undef,
 525         cancellationdate => 'cancellation_date',
 526         reservenotes     => 'notes',
 527         found            => 'status',
 528         itemnumber       => 'item_id',
 529         waitingdate      => 'waiting_date',
 530         expirationdate   => 'expiration_date',
 531         lowestPriority   => 'lowest_priority',
 532         suspend          => 'suspended',
 533         suspend_until    => 'suspended_until',
 534         itemtype         => 'item_type',
 535         item_level_hold  => 'item_level',
 536     };
 537 }
 538
 539 =head2 Internal methods
 540
 541 =head3 _type
 542
 543 =cut
 544
 545 sub _type {
 546     return 'Reserve';
 547 }
 548
 549 =head1 AUTHORS
 550
 551 Kyle M Hall <kyle@bywatersolutions.com>
 552 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 553 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 554
 555 =cut
 556
 557 1;