Koha/Hold.pm

   1 package Koha::Hold;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright 2017 Koha Development team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use Data::Dumper qw(Dumper);
  25 use List::MoreUtils qw(any);
  26
  27 use C4::Context qw(preference);
  28 use C4::Letters;
  29 use C4::Log;
  30
  31 use Koha::AuthorisedValues;
  32 use Koha::DateUtils qw(dt_from_string output_pref);
  33 use Koha::Patrons;
  34 use Koha::Biblios;
  35 use Koha::Items;
  36 use Koha::Libraries;
  37 use Koha::Old::Holds;
  38 use Koha::Calendar;
  39
  40 use Koha::Exceptions::Hold;
  41
  42 use base qw(Koha::Object);
  43
  44 =head1 NAME
  45
  46 Koha::Hold - Koha Hold object class
  47
  48 =head1 API
  49
  50 =head2 Class Methods
  51
  52 =cut
  53
  54 =head3 age
  55
  56 returns the number of days since a hold was placed, optionally
  57 using the calendar
  58
  59 my $age = $hold->age( $use_calendar );
  60
  61 =cut
  62
  63 sub age {
  64     my ( $self, $use_calendar ) = @_;
  65
  66     my $today = dt_from_string;
  67     my $age;
  68
  69     if ( $use_calendar ) {
  70         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode );
  71         $age = $calendar->days_between( dt_from_string( $self->reservedate ), $today );
  72     }
  73     else {
  74         $age = $today->delta_days( dt_from_string( $self->reservedate ) );
  75     }
  76
  77     $age = $age->in_units( 'days' );
  78
  79     return $age;
  80 }
  81
  82 =head3 suspend_hold
  83
  84 my $hold = $hold->suspend_hold( $suspend_until_dt );
  85
  86 =cut
  87
  88 sub suspend_hold {
  89     my ( $self, $dt ) = @_;
  90
  91     my $date = $dt ? $dt->clone()->truncate( to => 'day' )->datetime : undef;
  92
  93     if ( $self->is_found ) {    # We can't suspend found holds
  94         if ( $self->is_waiting ) {
  95             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'W' );
  96         }
  97         elsif ( $self->is_in_transit ) {
  98             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'T' );
  99         }
 100         elsif ( $self->is_in_processing ) {
 101             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'P' );
 102         }
 103         else {
 104             Koha::Exceptions::Hold::CannotSuspendFound->throw(
 105                       'Unhandled data exception on found hold (id='
 106                     . $self->id
 107                     . ', found='
 108                     . $self->found
 109                     . ')' );
 110         }
 111     }
 112
 113     $self->suspend(1);
 114     $self->suspend_until($date);
 115     $self->store();
 116
 117     logaction( 'HOLDS', 'SUSPEND', $self->reserve_id, Dumper( $self->unblessed ) )
 118         if C4::Context->preference('HoldsLog');
 119
 120     return $self;
 121 }
 122
 123 =head3 resume
 124
 125 my $hold = $hold->resume();
 126
 127 =cut
 128
 129 sub resume {
 130     my ( $self ) = @_;
 131
 132     $self->suspend(0);
 133     $self->suspend_until( undef );
 134
 135     $self->store();
 136
 137     logaction( 'HOLDS', 'RESUME', $self->reserve_id, Dumper($self->unblessed) )
 138         if C4::Context->preference('HoldsLog');
 139
 140     return $self;
 141 }
 142
 143 =head3 delete
 144
 145 $hold->delete();
 146
 147 =cut
 148
 149 sub delete {
 150     my ( $self ) = @_;
 151
 152     my $deleted = $self->SUPER::delete($self);
 153
 154     logaction( 'HOLDS', 'DELETE', $self->reserve_id, Dumper($self->unblessed) )
 155         if C4::Context->preference('HoldsLog');
 156
 157     return $deleted;
 158 }
 159
 160 =head3 set_transfer
 161
 162 =cut
 163
 164 sub set_transfer {
 165     my ( $self ) = @_;
 166
 167     $self->priority(0);
 168     $self->found('T');
 169     $self->store();
 170
 171     return $self;
 172 }
 173
 174 =head3 set_waiting
 175
 176 =cut
 177
 178 sub set_waiting {
 179     my ( $self, $desk_id ) = @_;
 180
 181     $self->priority(0);
 182
 183     my $today = dt_from_string();
 184     my $values = {
 185         found => 'W',
 186         waitingdate => $today->ymd,
 187         desk_id => $desk_id,
 188     };
 189
 190     my $requested_expiration;
 191     if ($self->expirationdate) {
 192         $requested_expiration = dt_from_string($self->expirationdate);
 193     }
 194
 195     my $max_pickup_delay = C4::Context->preference("ReservesMaxPickUpDelay");
 196     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 197
 198     my $expirationdate = $today->clone;
 199     $expirationdate->add(days => $max_pickup_delay);
 200
 201     if ( C4::Context->preference("ExcludeHolidaysFromMaxPickUpDelay") ) {
 202         my $itemtype = $self->item ? $self->item->effective_itemtype : $self->biblio->itemtype;
 203         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
 204             {
 205                 categorycode => $self->borrower->categorycode,
 206                 itemtype     => $itemtype,
 207                 branchcode   => $self->branchcode,
 208             }
 209         );
 210         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode, days_mode => $daysmode );
 211
 212         $expirationdate = $calendar->days_forward( dt_from_string(), $max_pickup_delay );
 213     }
 214
 215     # If patron's requested expiration date is prior to the
 216     # calculated one, we keep the patron's one.
 217     my $cmp = $requested_expiration ? DateTime->compare($requested_expiration, $expirationdate) : 0;
 218     $values->{expirationdate} = $cmp == -1 ? $requested_expiration->ymd : $expirationdate->ymd;
 219
 220     $self->set($values)->store();
 221
 222     return $self;
 223 }
 224
 225 =head3 is_pickup_location_valid
 226
 227     if ($hold->is_pickup_location_valid({ library_id => $library->id }) ) {
 228         ...
 229     }
 230
 231 Returns a I<boolean> representing if the passed pickup location is valid for the hold.
 232 It throws a I<Koha::Exceptions::_MissingParameter> if the library_id parameter is not
 233 passed.
 234
 235 =cut
 236
 237 sub is_pickup_location_valid {
 238     my ( $self, $params ) = @_;
 239
 240     Koha::Exceptions::MissingParameter->throw('The library_id parameter is mandatory')
 241         unless $params->{library_id};
 242
 243     my @pickup_locations;
 244
 245     if ( $self->itemnumber ) { # item-level
 246         @pickup_locations = $self->item->pickup_locations({ patron => $self->patron });
 247     }
 248     else { # biblio-level
 249         @pickup_locations = $self->biblio->pickup_locations({ patron => $self->patron });
 250     }
 251
 252     return any { $_->branchcode eq $params->{library_id} } @pickup_locations;
 253 }
 254
 255 =head3 set_pickup_location
 256
 257     $hold->set_pickup_location({ library_id => $library->id });
 258
 259 Updates the hold pickup location. It throws a I<Koha::Exceptions::Hold::InvalidPickupLocation> if
 260 the passed pickup location is not valid.
 261
 262 =cut
 263
 264 sub set_pickup_location {
 265     my ( $self, $params ) = @_;
 266
 267     Koha::Exceptions::MissingParameter->throw('The library_id parameter is mandatory')
 268         unless $params->{library_id};
 269
 270     if ( $self->is_pickup_location_valid({ library_id => $params->{library_id} }) ) {
 271         # all good, set the new pickup location
 272         $self->branchcode( $params->{library_id} )->store;
 273     }
 274     else {
 275         Koha::Exceptions::Hold::InvalidPickupLocation->throw;
 276     }
 277
 278     return $self;
 279 }
 280
 281 =head3 set_processing
 282
 283 $hold->set_processing;
 284
 285 Mark the hold as in processing.
 286
 287 =cut
 288
 289 sub set_processing {
 290     my ( $self ) = @_;
 291
 292     $self->priority(0);
 293     $self->found('P');
 294     $self->store();
 295
 296     return $self;
 297 }
 298
 299 =head3 is_found
 300
 301 Returns true if hold is waiting, in transit or in processing
 302
 303 =cut
 304
 305 sub is_found {
 306     my ($self) = @_;
 307
 308     return 0 unless $self->found();
 309     return 1 if $self->found() eq 'W';
 310     return 1 if $self->found() eq 'T';
 311     return 1 if $self->found() eq 'P';
 312 }
 313
 314 =head3 is_waiting
 315
 316 Returns true if hold is a waiting hold
 317
 318 =cut
 319
 320 sub is_waiting {
 321     my ($self) = @_;
 322
 323     my $found = $self->found;
 324     return $found && $found eq 'W';
 325 }
 326
 327 =head3 is_in_transit
 328
 329 Returns true if hold is a in_transit hold
 330
 331 =cut
 332
 333 sub is_in_transit {
 334     my ($self) = @_;
 335
 336     return 0 unless $self->found();
 337     return $self->found() eq 'T';
 338 }
 339
 340 =head3 is_in_processing
 341
 342 Returns true if hold is a in_processing hold
 343
 344 =cut
 345
 346 sub is_in_processing {
 347     my ($self) = @_;
 348
 349     return 0 unless $self->found();
 350     return $self->found() eq 'P';
 351 }
 352
 353 =head3 is_cancelable_from_opac
 354
 355 Returns true if hold is a cancelable hold
 356
 357 Holds may be only canceled if they are not found.
 358
 359 This is used from the OPAC.
 360
 361 =cut
 362
 363 sub is_cancelable_from_opac {
 364     my ($self) = @_;
 365
 366     return 1 unless $self->is_found();
 367     return 0; # if ->is_in_transit or if ->is_waiting or ->is_in_processing
 368 }
 369
 370 =head3 is_at_destination
 371
 372 Returns true if hold is waiting
 373 and the hold's pickup branch matches
 374 the hold item's holding branch
 375
 376 =cut
 377
 378 sub is_at_destination {
 379     my ($self) = @_;
 380
 381     return $self->is_waiting() && ( $self->branchcode() eq $self->item()->holdingbranch() );
 382 }
 383
 384 =head3 biblio
 385
 386 Returns the related Koha::Biblio object for this hold
 387
 388 =cut
 389
 390 sub biblio {
 391     my ($self) = @_;
 392
 393     $self->{_biblio} ||= Koha::Biblios->find( $self->biblionumber() );
 394
 395     return $self->{_biblio};
 396 }
 397
 398 =head3 patron
 399
 400 Returns the related Koha::Patron object for this hold
 401
 402 =cut
 403
 404 sub patron {
 405     my ($self) = @_;
 406
 407     my $patron_rs = $self->_result->patron;
 408     return Koha::Patron->_new_from_dbic($patron_rs);
 409 }
 410
 411 =head3 item
 412
 413 Returns the related Koha::Item object for this Hold
 414
 415 =cut
 416
 417 sub item {
 418     my ($self) = @_;
 419
 420     $self->{_item} ||= Koha::Items->find( $self->itemnumber() );
 421
 422     return $self->{_item};
 423 }
 424
 425 =head3 branch
 426
 427 Returns the related Koha::Library object for this Hold
 428
 429 =cut
 430
 431 sub branch {
 432     my ($self) = @_;
 433
 434     $self->{_branch} ||= Koha::Libraries->find( $self->branchcode() );
 435
 436     return $self->{_branch};
 437 }
 438
 439 =head3 desk
 440
 441 Returns the related Koha::Desk object for this Hold
 442
 443 =cut
 444
 445 sub desk {
 446     my $self = shift;
 447     my $desk_rs = $self->_result->desk;
 448     return unless $desk_rs;
 449     return Koha::Desk->_new_from_dbic($desk_rs);
 450 }
 451
 452 =head3 borrower
 453
 454 Returns the related Koha::Patron object for this Hold
 455
 456 =cut
 457
 458 # FIXME Should be renamed with ->patron
 459 sub borrower {
 460     my ($self) = @_;
 461
 462     $self->{_borrower} ||= Koha::Patrons->find( $self->borrowernumber() );
 463
 464     return $self->{_borrower};
 465 }
 466
 467 =head3 is_suspended
 468
 469 my $bool = $hold->is_suspended();
 470
 471 =cut
 472
 473 sub is_suspended {
 474     my ( $self ) = @_;
 475
 476     return $self->suspend();
 477 }
 478
 479
 480 =head3 cancel
 481
 482 my $cancel_hold = $hold->cancel(
 483     {
 484         [ charge_cancel_fee => 1||0, ]
 485         [ cancellation_reason => $cancellation_reason, ]
 486     }
 487 );
 488
 489 Cancel a hold:
 490 - The hold will be moved to the old_reserves table with a priority=0
 491 - The priority of other holds will be updated
 492 - The patron will be charge (see ExpireReservesMaxPickUpDelayCharge) if the charge_cancel_fee parameter is set
 493 - The canceled hold will have the cancellation reason added to old_reserves.cancellation_reason if one is passed in
 494 - a CANCEL HOLDS log will be done if the pref HoldsLog is on
 495
 496 =cut
 497
 498 sub cancel {
 499     my ( $self, $params ) = @_;
 500     $self->_result->result_source->schema->txn_do(
 501         sub {
 502             $self->cancellationdate( dt_from_string->strftime( '%Y-%m-%d %H:%M:%S' ) );
 503             $self->priority(0);
 504             $self->cancellation_reason( $params->{cancellation_reason} );
 505             $self->store();
 506
 507             if ( $params->{cancellation_reason} ) {
 508                 my $letter = C4::Letters::GetPreparedLetter(
 509                     module                 => 'reserves',
 510                     letter_code            => 'HOLD_CANCELLATION',
 511                     message_transport_type => 'email',
 512                     branchcode             => $self->borrower->branchcode,
 513                     lang                   => $self->borrower->lang,
 514                     tables => {
 515                         branches    => $self->borrower->branchcode,
 516                         borrowers   => $self->borrowernumber,
 517                         items       => $self->itemnumber,
 518                         biblio      => $self->biblionumber,
 519                         biblioitems => $self->biblionumber,
 520                         reserves    => $self->unblessed,
 521                     }
 522                 );
 523
 524                 if ($letter) {
 525                     C4::Letters::EnqueueLetter(
 526                         {
 527                             letter                   => $letter,
 528                             borrowernumber         => $self->borrowernumber,
 529                             message_transport_type => 'email',
 530                         }
 531                     );
 532                 }
 533             }
 534
 535             $self->_move_to_old;
 536             $self->SUPER::delete(); # Do not add a DELETE log
 537
 538             # now fix the priority on the others....
 539             C4::Reserves::_FixPriority({ biblionumber => $self->biblionumber });
 540
 541             # and, if desired, charge a cancel fee
 542             my $charge = C4::Context->preference("ExpireReservesMaxPickUpDelayCharge");
 543             if ( $charge && $params->{'charge_cancel_fee'} ) {
 544                 my $account =
 545                   Koha::Account->new( { patron_id => $self->borrowernumber } );
 546                 $account->add_debit(
 547                     {
 548                         amount     => $charge,
 549                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 550                         interface  => C4::Context->interface,
 551                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 552                         type       => 'RESERVE_EXPIRED',
 553                         item_id    => $self->itemnumber
 554                     }
 555                 );
 556             }
 557
 558             C4::Log::logaction( 'HOLDS', 'CANCEL', $self->reserve_id, Dumper($self->unblessed) )
 559                 if C4::Context->preference('HoldsLog');
 560         }
 561     );
 562     return $self;
 563 }
 564
 565 =head3 _move_to_old
 566
 567 my $is_moved = $hold->_move_to_old;
 568
 569 Move a hold to the old_reserve table following the same pattern as Koha::Patron->move_to_deleted
 570
 571 =cut
 572
 573 sub _move_to_old {
 574     my ($self) = @_;
 575     my $hold_infos = $self->unblessed;
 576     return Koha::Old::Hold->new( $hold_infos )->store;
 577 }
 578
 579 =head3 to_api_mapping
 580
 581 This method returns the mapping for representing a Koha::Hold object
 582 on the API.
 583
 584 =cut
 585
 586 sub to_api_mapping {
 587     return {
 588         reserve_id       => 'hold_id',
 589         borrowernumber   => 'patron_id',
 590         reservedate      => 'hold_date',
 591         biblionumber     => 'biblio_id',
 592         branchcode       => 'pickup_library_id',
 593         notificationdate => undef,
 594         reminderdate     => undef,
 595         cancellationdate => 'cancellation_date',
 596         reservenotes     => 'notes',
 597         found            => 'status',
 598         itemnumber       => 'item_id',
 599         waitingdate      => 'waiting_date',
 600         expirationdate   => 'expiration_date',
 601         lowestPriority   => 'lowest_priority',
 602         suspend          => 'suspended',
 603         suspend_until    => 'suspended_until',
 604         itemtype         => 'item_type',
 605         item_level_hold  => 'item_level',
 606     };
 607 }
 608
 609 =head2 Internal methods
 610
 611 =head3 _type
 612
 613 =cut
 614
 615 sub _type {
 616     return 'Reserve';
 617 }
 618
 619 =head1 AUTHORS
 620
 621 Kyle M Hall <kyle@bywatersolutions.com>
 622 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 623 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 624
 625 =cut
 626
 627 1;