Koha/Hold.pm

   1 package Koha::Hold;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23 use Data::Dumper qw(Dumper);
  24
  25 use C4::Context qw(preference);
  26 use C4::Log;
  27
  28 use Koha::DateUtils qw(dt_from_string output_pref);
  29 use Koha::Patrons;
  30 use Koha::Biblios;
  31 use Koha::Items;
  32 use Koha::Libraries;
  33
  34 use base qw(Koha::Object);
  35
  36 =head1 NAME
  37
  38 Koha::Hold - Koha Hold object class
  39
  40 =head1 API
  41
  42 =head2 Class Methods
  43
  44 =cut
  45
  46 =head3 suspend_hold
  47
  48 my $hold = $hold->suspend_hold( $suspend_until_dt );
  49
  50 =cut
  51
  52 sub suspend_hold {
  53     my ( $self, $dt ) = @_;
  54
  55     $dt = $dt ? $dt->clone()->truncate( to => 'day' ) : undef;
  56
  57     if ( $self->is_waiting ) {    # We can't suspend waiting holds
  58         carp "Unable to suspend waiting hold!";
  59         return $self;
  60     }
  61
  62     $self->suspend(1);
  63     $self->suspend_until( $dt );
  64
  65     $self->store();
  66
  67     logaction( 'HOLDS', 'SUSPEND', $self->reserve_id, Dumper($self->unblessed) )
  68         if C4::Context->preference('HoldsLog');
  69
  70     return $self;
  71 }
  72
  73 =head3 resume
  74
  75 my $hold = $hold->resume();
  76
  77 =cut
  78
  79 sub resume {
  80     my ( $self ) = @_;
  81
  82     $self->suspend(0);
  83     $self->suspend_until( undef );
  84
  85     $self->store();
  86
  87     logaction( 'HOLDS', 'RESUME', $self->reserve_id, Dumper($self->unblessed) )
  88         if C4::Context->preference('HoldsLog');
  89
  90     return $self;
  91 }
  92
  93 =head3 delete
  94
  95 $hold->delete();
  96
  97 =cut
  98
  99 sub delete {
 100     my ( $self ) = @_;
 101
 102     my $deleted = $self->SUPER::delete($self);
 103
 104     logaction( 'HOLDS', 'DELETE', $self->reserve_id, Dumper($self->unblessed) )
 105         if C4::Context->preference('HoldsLog');
 106
 107     return $deleted;
 108 }
 109
 110 =head3 set_waiting
 111
 112 =cut
 113
 114 sub set_waiting {
 115     my ( $self, $transferToDo ) = @_;
 116
 117     $self->priority(0);
 118
 119     if ($transferToDo) {
 120         $self->found('T')->store();
 121         return $self;
 122     }
 123
 124     my $today = dt_from_string();
 125     my $values = {
 126         found => 'W',
 127         waitingdate => $today->ymd,
 128     };
 129
 130     my $requested_expiration;
 131     if ($self->expirationdate) {
 132         $requested_expiration = dt_from_string($self->expirationdate);
 133     }
 134
 135     my $max_pickup_delay = C4::Context->preference("ReservesMaxPickUpDelay");
 136     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 137     my $calendar = Koha::Calendar->new( branchcode => $self->branchcode );
 138
 139     my $expirationdate = $today->clone;
 140     $expirationdate->add(days => $max_pickup_delay);
 141
 142     if ( C4::Context->preference("ExcludeHolidaysFromMaxPickUpDelay") ) {
 143         $expirationdate = $calendar->days_forward( dt_from_string($self->waitingdate), $max_pickup_delay );
 144     }
 145
 146     # If patron's requested expiration date is prior to the
 147     # calculated one, we keep the patron's one.
 148     my $cmp = $requested_expiration ? DateTime->compare($requested_expiration, $expirationdate) : 0;
 149     $values->{expirationdate} = $cmp == -1 ? $requested_expiration->ymd : $expirationdate->ymd;
 150
 151     $self->set($values)->store();
 152
 153     return $self;
 154 }
 155
 156 =head3 is_found
 157
 158 Returns true if hold is a waiting or in transit
 159
 160 =cut
 161
 162 sub is_found {
 163     my ($self) = @_;
 164
 165     return 0 unless $self->found();
 166     return 1 if $self->found() eq 'W';
 167     return 1 if $self->found() eq 'T';
 168 }
 169
 170 =head3 is_waiting
 171
 172 Returns true if hold is a waiting hold
 173
 174 =cut
 175
 176 sub is_waiting {
 177     my ($self) = @_;
 178
 179     my $found = $self->found;
 180     return $found && $found eq 'W';
 181 }
 182
 183 =head3 is_in_transit
 184
 185 Returns true if hold is a in_transit hold
 186
 187 =cut
 188
 189 sub is_in_transit {
 190     my ($self) = @_;
 191
 192     return 0 unless $self->found();
 193     return $self->found() eq 'T';
 194 }
 195
 196 =head3 is_cancelable
 197
 198 Returns true if hold is a cancelable hold
 199
 200 Holds may be canceled if they not found, or
 201 are found and waiting. A hold found but in
 202 transit cannot be canceled.
 203
 204 =cut
 205
 206 sub is_cancelable {
 207     my ($self) = @_;
 208
 209     return 1 unless $self->is_found();
 210     return 0 if $self->is_in_transit();
 211     return 1 if $self->is_waiting();
 212     return 0;
 213 }
 214
 215 =head3 is_at_destination
 216
 217 Returns true if hold is waiting
 218 and the hold's pickup branch matches
 219 the hold item's holding branch
 220
 221 =cut
 222
 223 sub is_at_destination {
 224     my ($self) = @_;
 225
 226     return $self->is_waiting() && ( $self->branchcode() eq $self->item()->holdingbranch() );
 227 }
 228
 229 =head3 biblio
 230
 231 Returns the related Koha::Biblio object for this hold
 232
 233 =cut
 234
 235 sub biblio {
 236     my ($self) = @_;
 237
 238     $self->{_biblio} ||= Koha::Biblios->find( $self->biblionumber() );
 239
 240     return $self->{_biblio};
 241 }
 242
 243 =head3 item
 244
 245 Returns the related Koha::Item object for this Hold
 246
 247 =cut
 248
 249 sub item {
 250     my ($self) = @_;
 251
 252     $self->{_item} ||= Koha::Items->find( $self->itemnumber() );
 253
 254     return $self->{_item};
 255 }
 256
 257 =head3 branch
 258
 259 Returns the related Koha::Library object for this Hold
 260
 261 =cut
 262
 263 sub branch {
 264     my ($self) = @_;
 265
 266     $self->{_branch} ||= Koha::Libraries->find( $self->branchcode() );
 267
 268     return $self->{_branch};
 269 }
 270
 271 =head3 borrower
 272
 273 Returns the related Koha::Patron object for this Hold
 274
 275 =cut
 276
 277 sub borrower {
 278     my ($self) = @_;
 279
 280     $self->{_borrower} ||= Koha::Patrons->find( $self->borrowernumber() );
 281
 282     return $self->{_borrower};
 283 }
 284
 285 =head3 is_suspended
 286
 287 my $bool = $hold->is_suspended();
 288
 289 =cut
 290
 291 sub is_suspended {
 292     my ( $self ) = @_;
 293
 294     return $self->suspend();
 295 }
 296
 297 =head3 type
 298
 299 =cut
 300
 301 sub _type {
 302     return 'Reserve';
 303 }
 304
 305 =head1 AUTHOR
 306
 307 Kyle M Hall <kyle@bywatersolutions.com>
 308
 309 =cut
 310
 311 1;