Koha/Hold.pm

   1 package Koha::Hold;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright 2017 Koha Development team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use Data::Dumper qw(Dumper);
  25
  26 use C4::Context qw(preference);
  27 use C4::Letters;
  28 use C4::Log;
  29
  30 use Koha::AuthorisedValues;
  31 use Koha::DateUtils qw(dt_from_string output_pref);
  32 use Koha::Patrons;
  33 use Koha::Biblios;
  34 use Koha::Items;
  35 use Koha::Libraries;
  36 use Koha::Old::Holds;
  37 use Koha::Calendar;
  38
  39 use Koha::Exceptions::Hold;
  40
  41 use base qw(Koha::Object);
  42
  43 =head1 NAME
  44
  45 Koha::Hold - Koha Hold object class
  46
  47 =head1 API
  48
  49 =head2 Class Methods
  50
  51 =cut
  52
  53 =head3 age
  54
  55 returns the number of days since a hold was placed, optionally
  56 using the calendar
  57
  58 my $age = $hold->age( $use_calendar );
  59
  60 =cut
  61
  62 sub age {
  63     my ( $self, $use_calendar ) = @_;
  64
  65     my $today = dt_from_string;
  66     my $age;
  67
  68     if ( $use_calendar ) {
  69         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode );
  70         $age = $calendar->days_between( dt_from_string( $self->reservedate ), $today );
  71     }
  72     else {
  73         $age = $today->delta_days( dt_from_string( $self->reservedate ) );
  74     }
  75
  76     $age = $age->in_units( 'days' );
  77
  78     return $age;
  79 }
  80
  81 =head3 suspend_hold
  82
  83 my $hold = $hold->suspend_hold( $suspend_until_dt );
  84
  85 =cut
  86
  87 sub suspend_hold {
  88     my ( $self, $dt ) = @_;
  89
  90     my $date = $dt ? $dt->clone()->truncate( to => 'day' )->datetime : undef;
  91
  92     if ( $self->is_found ) {    # We can't suspend found holds
  93         if ( $self->is_waiting ) {
  94             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'W' );
  95         }
  96         elsif ( $self->is_in_transit ) {
  97             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'T' );
  98         }
  99         else {
 100             Koha::Exceptions::Hold::CannotSuspendFound->throw(
 101                       'Unhandled data exception on found hold (id='
 102                     . $self->id
 103                     . ', found='
 104                     . $self->found
 105                     . ')' );
 106         }
 107     }
 108
 109     $self->suspend(1);
 110     $self->suspend_until($date);
 111     $self->store();
 112
 113     logaction( 'HOLDS', 'SUSPEND', $self->reserve_id, Dumper( $self->unblessed ) )
 114         if C4::Context->preference('HoldsLog');
 115
 116     return $self;
 117 }
 118
 119 =head3 resume
 120
 121 my $hold = $hold->resume();
 122
 123 =cut
 124
 125 sub resume {
 126     my ( $self ) = @_;
 127
 128     $self->suspend(0);
 129     $self->suspend_until( undef );
 130
 131     $self->store();
 132
 133     logaction( 'HOLDS', 'RESUME', $self->reserve_id, Dumper($self->unblessed) )
 134         if C4::Context->preference('HoldsLog');
 135
 136     return $self;
 137 }
 138
 139 =head3 delete
 140
 141 $hold->delete();
 142
 143 =cut
 144
 145 sub delete {
 146     my ( $self ) = @_;
 147
 148     my $deleted = $self->SUPER::delete($self);
 149
 150     logaction( 'HOLDS', 'DELETE', $self->reserve_id, Dumper($self->unblessed) )
 151         if C4::Context->preference('HoldsLog');
 152
 153     return $deleted;
 154 }
 155
 156 =head3 set_waiting
 157
 158 =cut
 159
 160 sub set_waiting {
 161     my ( $self, $transferToDo ) = @_;
 162
 163     $self->priority(0);
 164
 165     if ($transferToDo) {
 166         $self->found('T')->store();
 167         return $self;
 168     }
 169
 170     my $today = dt_from_string();
 171     my $values = {
 172         found => 'W',
 173         waitingdate => $today->ymd,
 174     };
 175
 176     my $requested_expiration;
 177     if ($self->expirationdate) {
 178         $requested_expiration = dt_from_string($self->expirationdate);
 179     }
 180
 181     my $max_pickup_delay = C4::Context->preference("ReservesMaxPickUpDelay");
 182     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 183
 184     my $expirationdate = $today->clone;
 185     $expirationdate->add(days => $max_pickup_delay);
 186
 187     if ( C4::Context->preference("ExcludeHolidaysFromMaxPickUpDelay") ) {
 188         my $itemtype = $self->item ? $self->item->effective_itemtype : $self->biblio->itemtype;
 189         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
 190             {
 191                 categorycode => $self->borrower->categorycode,
 192                 itemtype     => $itemtype,
 193                 branchcode   => $self->branchcode,
 194             }
 195         );
 196         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode, days_mode => $daysmode );
 197
 198         $expirationdate = $calendar->days_forward( dt_from_string(), $max_pickup_delay );
 199     }
 200
 201     # If patron's requested expiration date is prior to the
 202     # calculated one, we keep the patron's one.
 203     my $cmp = $requested_expiration ? DateTime->compare($requested_expiration, $expirationdate) : 0;
 204     $values->{expirationdate} = $cmp == -1 ? $requested_expiration->ymd : $expirationdate->ymd;
 205
 206     $self->set($values)->store();
 207
 208     return $self;
 209 }
 210
 211 =head3 is_found
 212
 213 Returns true if hold is a waiting or in transit
 214
 215 =cut
 216
 217 sub is_found {
 218     my ($self) = @_;
 219
 220     return 0 unless $self->found();
 221     return 1 if $self->found() eq 'W';
 222     return 1 if $self->found() eq 'T';
 223 }
 224
 225 =head3 is_waiting
 226
 227 Returns true if hold is a waiting hold
 228
 229 =cut
 230
 231 sub is_waiting {
 232     my ($self) = @_;
 233
 234     my $found = $self->found;
 235     return $found && $found eq 'W';
 236 }
 237
 238 =head3 is_in_transit
 239
 240 Returns true if hold is a in_transit hold
 241
 242 =cut
 243
 244 sub is_in_transit {
 245     my ($self) = @_;
 246
 247     return 0 unless $self->found();
 248     return $self->found() eq 'T';
 249 }
 250
 251 =head3 is_cancelable_from_opac
 252
 253 Returns true if hold is a cancelable hold
 254
 255 Holds may be only canceled if they are not found.
 256
 257 This is used from the OPAC.
 258
 259 =cut
 260
 261 sub is_cancelable_from_opac {
 262     my ($self) = @_;
 263
 264     return 1 unless $self->is_found();
 265     return 0; # if ->is_in_transit or if ->is_waiting
 266 }
 267
 268 =head3 is_at_destination
 269
 270 Returns true if hold is waiting
 271 and the hold's pickup branch matches
 272 the hold item's holding branch
 273
 274 =cut
 275
 276 sub is_at_destination {
 277     my ($self) = @_;
 278
 279     return $self->is_waiting() && ( $self->branchcode() eq $self->item()->holdingbranch() );
 280 }
 281
 282 =head3 biblio
 283
 284 Returns the related Koha::Biblio object for this hold
 285
 286 =cut
 287
 288 sub biblio {
 289     my ($self) = @_;
 290
 291     $self->{_biblio} ||= Koha::Biblios->find( $self->biblionumber() );
 292
 293     return $self->{_biblio};
 294 }
 295
 296 =head3 item
 297
 298 Returns the related Koha::Item object for this Hold
 299
 300 =cut
 301
 302 sub item {
 303     my ($self) = @_;
 304
 305     $self->{_item} ||= Koha::Items->find( $self->itemnumber() );
 306
 307     return $self->{_item};
 308 }
 309
 310 =head3 branch
 311
 312 Returns the related Koha::Library object for this Hold
 313
 314 =cut
 315
 316 sub branch {
 317     my ($self) = @_;
 318
 319     $self->{_branch} ||= Koha::Libraries->find( $self->branchcode() );
 320
 321     return $self->{_branch};
 322 }
 323
 324 =head3 borrower
 325
 326 Returns the related Koha::Patron object for this Hold
 327
 328 =cut
 329
 330 # FIXME Should be renamed with ->patron
 331 sub borrower {
 332     my ($self) = @_;
 333
 334     $self->{_borrower} ||= Koha::Patrons->find( $self->borrowernumber() );
 335
 336     return $self->{_borrower};
 337 }
 338
 339 =head3 is_suspended
 340
 341 my $bool = $hold->is_suspended();
 342
 343 =cut
 344
 345 sub is_suspended {
 346     my ( $self ) = @_;
 347
 348     return $self->suspend();
 349 }
 350
 351
 352 =head3 cancel
 353
 354 my $cancel_hold = $hold->cancel(
 355     {
 356         [ charge_cancel_fee => 1||0, ]
 357         [ cancellation_reason => $cancellation_reason, ]
 358     }
 359 );
 360
 361 Cancel a hold:
 362 - The hold will be moved to the old_reserves table with a priority=0
 363 - The priority of other holds will be updated
 364 - The patron will be charge (see ExpireReservesMaxPickUpDelayCharge) if the charge_cancel_fee parameter is set
 365 - The canceled hold will have the cancellation reason added to old_reserves.cancellation_reason if one is passed in
 366 - a CANCEL HOLDS log will be done if the pref HoldsLog is on
 367
 368 =cut
 369
 370 sub cancel {
 371     my ( $self, $params ) = @_;
 372     $self->_result->result_source->schema->txn_do(
 373         sub {
 374             $self->cancellationdate( dt_from_string->strftime( '%Y-%m-%d %H:%M:%S' ) );
 375             $self->priority(0);
 376             $self->cancellation_reason( $params->{cancellation_reason} );
 377             $self->store();
 378
 379             if ( $params->{cancellation_reason} ) {
 380                 my $letter = C4::Letters::GetPreparedLetter(
 381                     module                 => 'reserves',
 382                     letter_code            => 'HOLD_CANCELLATION',
 383                     message_transport_type => 'email',
 384                     branchcode             => $self->borrower->branchcode,
 385                     lang                   => $self->borrower->lang,
 386                     tables => {
 387                         branches    => $self->borrower->branchcode,
 388                         borrowers   => $self->borrowernumber,
 389                         items       => $self->itemnumber,
 390                         biblio      => $self->biblionumber,
 391                         biblioitems => $self->biblionumber,
 392                         reserves    => $self->unblessed,
 393                     }
 394                 );
 395
 396                 if ($letter) {
 397                     C4::Letters::EnqueueLetter(
 398                         {
 399                             letter                   => $letter,
 400                             borrowernumber         => $self->borrowernumber,
 401                             message_transport_type => 'email',
 402                         }
 403                     );
 404                 }
 405             }
 406
 407             $self->_move_to_old;
 408             $self->SUPER::delete(); # Do not add a DELETE log
 409
 410             # now fix the priority on the others....
 411             C4::Reserves::_FixPriority({ biblionumber => $self->biblionumber });
 412
 413             # and, if desired, charge a cancel fee
 414             my $charge = C4::Context->preference("ExpireReservesMaxPickUpDelayCharge");
 415             if ( $charge && $params->{'charge_cancel_fee'} ) {
 416                 my $account =
 417                   Koha::Account->new( { patron_id => $self->borrowernumber } );
 418                 $account->add_debit(
 419                     {
 420                         amount     => $charge,
 421                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 422                         interface  => C4::Context->interface,
 423                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 424                         type       => 'RESERVE_EXPIRED',
 425                         item_id    => $self->itemnumber
 426                     }
 427                 );
 428             }
 429
 430             C4::Log::logaction( 'HOLDS', 'CANCEL', $self->reserve_id, Dumper($self->unblessed) )
 431                 if C4::Context->preference('HoldsLog');
 432         }
 433     );
 434     return $self;
 435 }
 436
 437 =head3 _move_to_old
 438
 439 my $is_moved = $hold->_move_to_old;
 440
 441 Move a hold to the old_reserve table following the same pattern as Koha::Patron->move_to_deleted
 442
 443 =cut
 444
 445 sub _move_to_old {
 446     my ($self) = @_;
 447     my $hold_infos = $self->unblessed;
 448     return Koha::Old::Hold->new( $hold_infos )->store;
 449 }
 450
 451 =head3 to_api_mapping
 452
 453 This method returns the mapping for representing a Koha::Hold object
 454 on the API.
 455
 456 =cut
 457
 458 sub to_api_mapping {
 459     return {
 460         reserve_id       => 'hold_id',
 461         borrowernumber   => 'patron_id',
 462         reservedate      => 'hold_date',
 463         biblionumber     => 'biblio_id',
 464         branchcode       => 'pickup_library_id',
 465         notificationdate => undef,
 466         reminderdate     => undef,
 467         cancellationdate => 'cancellation_date',
 468         reservenotes     => 'notes',
 469         found            => 'status',
 470         itemnumber       => 'item_id',
 471         waitingdate      => 'waiting_date',
 472         expirationdate   => 'expiration_date',
 473         lowestPriority   => 'lowest_priority',
 474         suspend          => 'suspended',
 475         suspend_until    => 'suspended_until',
 476         itemtype         => 'item_type',
 477         item_level_hold  => 'item_level',
 478     };
 479 }
 480
 481 =head2 Internal methods
 482
 483 =head3 _type
 484
 485 =cut
 486
 487 sub _type {
 488     return 'Reserve';
 489 }
 490
 491 =head1 AUTHORS
 492
 493 Kyle M Hall <kyle@bywatersolutions.com>
 494 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 495 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 496
 497 =cut
 498
 499 1;