Koha/Holds.pm

   1 package Koha::Holds;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22
  23 use Koha::Database;
  24
  25 use Koha::Hold;
  26
  27 use base qw(Koha::Objects);
  28
  29 =head1 NAME
  30
  31 Koha::Holds - Koha Hold object set class
  32
  33 =head1 API
  34
  35 =head2 Class methods
  36
  37 =cut
  38
  39 =head3 waiting
  40
  41 returns a set of holds that are waiting from an existing set
  42
  43 =cut
  44
  45 sub waiting {
  46     my ( $self ) = @_;
  47
  48     return $self->search( { found => 'W' } );
  49 }
  50
  51
  52 sub processing {
  53     my ( $self ) = @_;
  54
  55     return $self->search( { found => 'P' } );
  56 }
  57
  58 =head3 unfilled
  59
  60 returns a set of holds that are unfilled from an existing set
  61
  62 =cut
  63
  64 sub unfilled {
  65     my ( $self ) = @_;
  66
  67     return $self->search( { found => undef } );
  68 }
  69
  70 =head3 forced_hold_level
  71
  72 If a patron has multiple holds for a single record,
  73 those holds must be either all record level holds,
  74 or they must all be item level holds.
  75
  76 This method should be used with Hold sets where all
  77 Hold objects share the same patron and record.
  78
  79 This method will return 'item' if the patron has
  80 at least one item level hold. It will return 'record'
  81 if the patron has holds but none are item level,
  82 Finally, if the patron has no holds, it will return
  83 undef which indicates the patron may select either
  84 record or item level holds, barring any other rules
  85 that would prevent one or the other.
  86
  87 =cut
  88
  89 sub forced_hold_level {
  90     my ($self) = @_;
  91
  92     my $item_level_count = $self->search( { itemnumber => { '!=' => undef } } )->count();
  93     return 'item' if $item_level_count > 0;
  94
  95     my $item_group_level_count = $self->search( { item_group_id => { '!=' => undef } } )->count();
  96     return 'item_group' if $item_group_level_count > 0;
  97
  98     my $record_level_count = $self->search( { itemnumber => undef } )->count();
  99     return 'record' if $record_level_count > 0;
 100
 101     return;
 102 }
 103
 104 =head3 get_items_that_can_fill
 105
 106     my $items = $holds->get_items_that_can_fill();
 107
 108 Return the list of items that can fill the hold set.
 109
 110 Items that are not:
 111
 112   in transit
 113   waiting
 114   lost
 115   widthdrawn
 116   not for loan
 117   not on loan
 118
 119 =cut
 120
 121 sub get_items_that_can_fill {
 122     my ( $self ) = @_;
 123
 124     return Koha::Items->new->empty()
 125       unless $self->count() > 0;
 126
 127     my @itemnumbers = $self->search({ 'me.itemnumber' => { '!=' => undef } })->get_column('itemnumber');
 128     my @biblionumbers = $self->search({ 'me.itemnumber' => undef })->get_column('biblionumber');
 129     my @bibs_or_items;
 130     push @bibs_or_items, 'me.itemnumber' => { in => \@itemnumbers } if @itemnumbers;
 131     push @bibs_or_items, 'me.biblionumber' => { in => \@biblionumbers } if @biblionumbers;
 132
 133     my @branchtransfers = Koha::Item::Transfers->filter_by_current->search({}, {
 134             columns  => ['itemnumber'],
 135             collapse => 1,
 136         }
 137     )->get_column('itemnumber');
 138     my @waiting_holds = Koha::Holds->search(
 139         { 'found' => 'W' },
 140         {
 141             columns  => ['itemnumber'],
 142             collapse => 1,
 143         }
 144     )->get_column('itemnumber');
 145
 146     return Koha::Items->search(
 147         {
 148             -or => \@bibs_or_items,
 149             itemnumber   => { -not_in => [ @branchtransfers, @waiting_holds ] },
 150             onloan       => undef,
 151             notforloan   => 0,
 152         }
 153     )->filter_by_for_hold();
 154 }
 155
 156 =head3 filter_by_has_cancellation_requests
 157
 158     my $with_cancellation_reqs = $holds->filter_by_has_cancellation_requests;
 159
 160 Returns a filtered resultset only containing holds that have cancellation requests.
 161
 162 =cut
 163
 164 sub filter_by_has_cancellation_requests {
 165     my ($self) = @_;
 166
 167     return $self->search( { 'hold_cancellation_request_id' => { '!=' => undef } },
 168         { join => 'cancellation_requests' } );
 169 }
 170
 171 =head3 filter_out_has_cancellation_requests
 172
 173     my $holds_without_cancellation_requests = $holds->filter_out_has_cancellation_requests;
 174
 175 Returns a filtered resultset without holds with cancellation requests.
 176
 177 =cut
 178
 179 sub filter_out_has_cancellation_requests {
 180     my ($self) = @_;
 181
 182     return $self->search( { 'hold_cancellation_request_id' => { '=' => undef } },
 183         { join => 'cancellation_requests' } );
 184 }
 185
 186 =head2 Internal methods
 187
 188 =head3 _type
 189
 190 =cut
 191
 192 sub _type {
 193     return 'Reserve';
 194 }
 195
 196 =head3 object_class
 197
 198 =cut
 199
 200 sub object_class {
 201     return 'Koha::Hold';
 202 }
 203
 204 =head1 AUTHOR
 205
 206 Kyle M Hall <kyle@bywatersolutions.com>
 207
 208 =cut
 209
 210 1;