Koha/Holds.pm

   1 package Koha::Holds;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use Koha::Database;
  25
  26 use Koha::Hold;
  27
  28 use base qw(Koha::Objects);
  29
  30 =head1 NAME
  31
  32 Koha::Holds - Koha Hold object set class
  33
  34 =head1 API
  35
  36 =head2 Class Methods
  37
  38 =cut
  39
  40 =head3 waiting
  41
  42 returns a set of holds that are waiting from an existing set
  43
  44 =cut
  45
  46 sub waiting {
  47     my ( $self ) = @_;
  48
  49     return $self->search( { found => 'W' } );
  50 }
  51
  52 =head3 unfilled
  53
  54 returns a set of holds that are unfilled from an existing set
  55
  56 =cut
  57
  58 sub unfilled {
  59     my ( $self ) = @_;
  60
  61     return $self->search( { found => undef } );
  62 }
  63
  64 =head3 forced_hold_level
  65
  66 If a patron has multiple holds for a single record,
  67 those holds must be either all record level holds,
  68 or they must all be item level holds.
  69
  70 This method should be used with Hold sets where all
  71 Hold objects share the same patron and record.
  72
  73 This method will return 'item' if the patron has
  74 at least one item level hold. It will return 'record'
  75 if the patron has holds but none are item level,
  76 Finally, if the patron has no holds, it will return
  77 undef which indicates the patron may select either
  78 record or item level holds, barring any other rules
  79 that would prevent one or the other.
  80
  81 =cut
  82
  83 sub forced_hold_level {
  84     my ($self) = @_;
  85
  86     my $item_level_count = $self->search( { itemnumber => { '!=' => undef } } )->count();
  87     return 'item' if $item_level_count > 0;
  88
  89     my $record_level_count = $self->search( { itemnumber => undef } )->count();
  90     return 'record' if $record_level_count > 0;
  91
  92     return;
  93 }
  94
  95 =head3 get_items_that_can_fill
  96
  97     my $items = $holds->get_items_that_can_fill();
  98
  99 Return the list of items that can fill the hold set.
 100
 101 Items that are not:
 102
 103   in transit
 104   waiting
 105   lost
 106   widthdrawn
 107   not for loan
 108   not on loan
 109
 110 =cut
 111
 112 sub get_items_that_can_fill {
 113     my ( $self ) = @_;
 114
 115     my @biblionumbers = $self->get_column('biblionumber');
 116
 117     my @branchtransfers = map { $_->itemnumber }
 118       Koha::Item::Transfers->search(
 119           { datearrived => undef },
 120           {
 121               columns => ['itemnumber'],
 122               collapse => 1,
 123           }
 124       );
 125     my @waiting_holds = map { $_->itemnumber }
 126       Koha::Holds->search(
 127           { 'found' => 'W' },
 128           {
 129               columns => ['itemnumber'],
 130               collapse => 1,
 131           }
 132       );
 133
 134     my @hold_not_allowed_itypes = Koha::CirculationRules->search(
 135         {
 136             rule_name    => 'holdallowed',
 137             branchcode   => undef,
 138             categorycode => undef,
 139             rule_value   => 0,
 140         }
 141     )->get_column('itemtype');
 142
 143     return Koha::Items->search(
 144         {
 145             biblionumber => { in => \@biblionumbers },
 146             itemlost     => 0,
 147             withdrawn    => 0,
 148             notforloan   => 0,
 149             onloan       => undef,
 150             itemnumber   => { -not_in => [ @branchtransfers, @waiting_holds ] },
 151             itype        => { -not_in => \@hold_not_allowed_itypes },
 152         }
 153     );
 154 }
 155
 156 =head3 type
 157
 158 =cut
 159
 160 sub _type {
 161     return 'Reserve';
 162 }
 163
 164 =head3 object_class
 165
 166 =cut
 167
 168 sub object_class {
 169     return 'Koha::Hold';
 170 }
 171
 172 =head1 AUTHOR
 173
 174 Kyle M Hall <kyle@bywatersolutions.com>
 175
 176 =cut
 177
 178 1;