Koha/Holds.pm

   1 package Koha::Holds;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22
  23 use Koha::Database;
  24
  25 use Koha::Hold;
  26
  27 use base qw(Koha::Objects);
  28
  29 =head1 NAME
  30
  31 Koha::Holds - Koha Hold object set class
  32
  33 =head1 API
  34
  35 =head2 Class methods
  36
  37 =cut
  38
  39 =head3 waiting
  40
  41 returns a set of holds that are waiting from an existing set
  42
  43 =cut
  44
  45 sub waiting {
  46     my ( $self ) = @_;
  47
  48     return $self->search( { found => 'W' } );
  49 }
  50
  51 =head3 unfilled
  52
  53 returns a set of holds that are unfilled from an existing set
  54
  55 =cut
  56
  57 sub unfilled {
  58     my ( $self ) = @_;
  59
  60     return $self->search( { found => undef } );
  61 }
  62
  63 =head3 forced_hold_level
  64
  65 If a patron has multiple holds for a single record,
  66 those holds must be either all record level holds,
  67 or they must all be item level holds.
  68
  69 This method should be used with Hold sets where all
  70 Hold objects share the same patron and record.
  71
  72 This method will return 'item' if the patron has
  73 at least one item level hold. It will return 'record'
  74 if the patron has holds but none are item level,
  75 Finally, if the patron has no holds, it will return
  76 undef which indicates the patron may select either
  77 record or item level holds, barring any other rules
  78 that would prevent one or the other.
  79
  80 =cut
  81
  82 sub forced_hold_level {
  83     my ($self) = @_;
  84
  85     my $item_level_count = $self->search( { itemnumber => { '!=' => undef } } )->count();
  86     return 'item' if $item_level_count > 0;
  87
  88     my $record_level_count = $self->search( { itemnumber => undef } )->count();
  89     return 'record' if $record_level_count > 0;
  90
  91     return;
  92 }
  93
  94 =head3 get_items_that_can_fill
  95
  96     my $items = $holds->get_items_that_can_fill();
  97
  98 Return the list of items that can fill the hold set.
  99
 100 Items that are not:
 101
 102   in transit
 103   waiting
 104   lost
 105   widthdrawn
 106   not for loan
 107   not on loan
 108
 109 =cut
 110
 111 sub get_items_that_can_fill {
 112     my ( $self ) = @_;
 113
 114     return Koha::Items->new->empty()
 115       unless $self->count() > 0;
 116
 117     my @itemnumbers = $self->search({ 'me.itemnumber' => { '!=' => undef } })->get_column('itemnumber');
 118     my @biblionumbers = $self->search({ 'me.itemnumber' => undef })->get_column('biblionumber');
 119     my @bibs_or_items;
 120     push @bibs_or_items, 'me.itemnumber' => { in => \@itemnumbers } if @itemnumbers;
 121     push @bibs_or_items, 'me.biblionumber' => { in => \@biblionumbers } if @biblionumbers;
 122
 123     my @branchtransfers = Koha::Item::Transfers->filter_by_current->search({}, {
 124             columns  => ['itemnumber'],
 125             collapse => 1,
 126         }
 127     )->get_column('itemnumber');
 128     my @waiting_holds = Koha::Holds->search(
 129         { 'found' => 'W' },
 130         {
 131             columns  => ['itemnumber'],
 132             collapse => 1,
 133         }
 134     )->get_column('itemnumber');
 135
 136     return Koha::Items->search(
 137         {
 138             -or => \@bibs_or_items,
 139             itemnumber   => { -not_in => [ @branchtransfers, @waiting_holds ] },
 140             onloan       => undef,
 141             notforloan   => 0,
 142         }
 143     )->filter_by_for_hold();
 144 }
 145
 146 =head3 filter_by_has_cancellation_requests
 147
 148     my $with_cancellation_reqs = $holds->filter_by_has_cancellation_requests;
 149
 150 Returns a filtered resultset only containing holds that have cancellation requests.
 151
 152 =cut
 153
 154 sub filter_by_has_cancellation_requests {
 155     my ($self) = @_;
 156
 157     return $self->search( { 'hold_cancellation_request_id' => { '!=' => undef } },
 158         { join => 'cancellation_requests' } );
 159 }
 160
 161 =head3 filter_out_has_cancellation_requests
 162
 163     my $holds_without_cancellation_requests = $holds->filter_out_has_cancellation_requests;
 164
 165 Returns a filtered resultset without holds with cancellation requests.
 166
 167 =cut
 168
 169 sub filter_out_has_cancellation_requests {
 170     my ($self) = @_;
 171
 172     return $self->search( { 'hold_cancellation_request_id' => { '=' => undef } },
 173         { join => 'cancellation_requests' } );
 174 }
 175
 176 =head2 Internal methods
 177
 178 =head3 _type
 179
 180 =cut
 181
 182 sub _type {
 183     return 'Reserve';
 184 }
 185
 186 =head3 object_class
 187
 188 =cut
 189
 190 sub object_class {
 191     return 'Koha::Hold';
 192 }
 193
 194 =head1 AUTHOR
 195
 196 Kyle M Hall <kyle@bywatersolutions.com>
 197
 198 =cut
 199
 200 1;