Koha/Items.pm

   1 package Koha::Items;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Array::Utils qw( array_minus );
  22 use List::MoreUtils qw( uniq );
  23 use Try::Tiny;
  24
  25 use C4::Context;
  26 use C4::Biblio qw( GetMarcStructure GetMarcFromKohaField );
  27 use C4::Circulation;
  28
  29 use Koha::Database;
  30 use Koha::SearchEngine::Indexer;
  31
  32 use Koha::Item::Attributes;
  33 use Koha::Item;
  34 use Koha::CirculationRules;
  35
  36 use base qw(Koha::Objects);
  37
  38 use Koha::SearchEngine::Indexer;
  39
  40 =head1 NAME
  41
  42 Koha::Items - Koha Item object set class
  43
  44 =head1 API
  45
  46 =head2 Class methods
  47
  48 =cut
  49
  50 =head3 filter_by_for_hold
  51
  52     my $filtered_items = $items->filter_by_for_hold;
  53
  54 Return the items of the set that are *potentially* holdable.
  55
  56 Caller has the responsibility to call C4::Reserves::CanItemBeReserved before
  57 placing a hold on one of those items.
  58
  59 =cut
  60
  61 sub filter_by_for_hold {
  62     my ($self) = @_;
  63
  64     my @hold_not_allowed_itypes = Koha::CirculationRules->search(
  65         {
  66             rule_name    => 'holdallowed',
  67             branchcode   => undef,
  68             categorycode => undef,
  69             rule_value   => 'not_allowed',
  70         }
  71     )->get_column('itemtype');
  72     push @hold_not_allowed_itypes, Koha::ItemTypes->search({ notforloan => 1 })->get_column('itemtype');
  73
  74     my $params = {
  75         itemlost   => 0,
  76         withdrawn  => 0,
  77         notforloan => { '<=' => 0 },    # items with negative or zero notforloan value are holdable
  78         ( C4::Context->preference('AllowHoldsOnDamagedItems')? (): ( damaged => 0 ) ),
  79         ( C4::Context->only_my_library() ? ( homebranch => C4::Context::mybranch() ) : () ),
  80     };
  81
  82     if ( C4::Context->preference("item-level_itypes") ) {
  83         return $self->search(
  84             {
  85                 %$params,
  86                 itype        => { -not_in => \@hold_not_allowed_itypes },
  87             }
  88         );
  89     } else {
  90         return $self->search(
  91             {
  92                 %$params,
  93                 'biblioitem.itemtype' => { -not_in => \@hold_not_allowed_itypes },
  94             },
  95             {
  96                 join => 'biblioitem',
  97             }
  98         );
  99     }
 100 }
 101
 102 =head3 filter_by_visible_in_opac
 103
 104     my $filered_items = $items->filter_by_visible_in_opac(
 105         {
 106             [ patron => $patron ]
 107         }
 108     );
 109
 110 Returns a new resultset, containing those items that are not expected to be hidden in OPAC
 111 for the passed I<Koha::Patron> object that is passed.
 112
 113 The I<OpacHiddenItems>, I<hidelostitems> and I<OpacHiddenItemsExceptions> system preferences
 114 are honoured.
 115
 116 =cut
 117
 118 sub filter_by_visible_in_opac {
 119     my ($self, $params) = @_;
 120
 121     my $patron = $params->{patron};
 122
 123     my $result = $self;
 124
 125     # Filter out OpacHiddenItems unless disabled by OpacHiddenItemsExceptions
 126     unless ( $patron and $patron->category->override_hidden_items ) {
 127         my $rules = C4::Context->yaml_preference('OpacHiddenItems') // {};
 128
 129         my $rules_params;
 130         foreach my $field ( keys %$rules ) {
 131             $rules_params->{'me.'.$field} =
 132               [ { '-not_in' => $rules->{$field} }, undef ];
 133         }
 134
 135         $result = $result->search( $rules_params );
 136     }
 137
 138     if (C4::Context->preference('hidelostitems')) {
 139         $result = $result->filter_out_lost;
 140     }
 141
 142     return $result;
 143 }
 144
 145 =head3 filter_out_lost
 146
 147     my $filered_items = $items->filter_out_lost;
 148
 149 Returns a new resultset, containing those items that are not marked as lost.
 150
 151 =cut
 152
 153 sub filter_out_lost {
 154     my ($self) = @_;
 155
 156     my $params = { itemlost => 0 };
 157
 158     return $self->search( $params );
 159 }
 160
 161
 162 =head3 move_to_biblio
 163
 164  $items->move_to_biblio($to_biblio);
 165
 166 Move items to a given biblio.
 167
 168 =cut
 169
 170 sub move_to_biblio {
 171     my ( $self, $to_biblio ) = @_;
 172
 173     my $biblionumbers = { $to_biblio->biblionumber => 1 };
 174     while ( my $item = $self->next() ) {
 175         $biblionumbers->{ $item->biblionumber } = 1;
 176         $item->move_to_biblio( $to_biblio, { skip_record_index => 1 } );
 177     }
 178     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 179     for my $biblionumber ( keys %{$biblionumbers} ) {
 180         $indexer->index_records( $biblionumber, "specialUpdate", "biblioserver" );
 181     }
 182 }
 183
 184 =head3 batch_update
 185
 186     Koha::Items->search->batch_update
 187         {
 188             new_values => {
 189                 itemnotes => $new_item_notes,
 190                 k         => $k,
 191             },
 192             regex_mod => {
 193                 itemnotes_nonpublic => {
 194                     search => 'foo',
 195                     replace => 'bar',
 196                     modifiers => 'gi',
 197                 },
 198             },
 199             exclude_from_local_holds_priority => 1|0,
 200             callback => sub {
 201                 # increment something here
 202             },
 203         }
 204     );
 205
 206 Batch update the items.
 207
 208 Returns ( $report, $self )
 209 Report has 2 keys:
 210   * modified_itemnumbers - list of the modified itemnumbers
 211   * modified_fields - number of fields modified
 212
 213 Parameters:
 214
 215 =over
 216
 217 =item new_values
 218
 219 Allows to set a new value for given fields.
 220 The key can be one of the item's column name, or one subfieldcode of a MARC subfields not linked with a Koha field
 221
 222 =item regex_mod
 223
 224 Allows to modify existing subfield's values using a regular expression
 225
 226 =item exclude_from_local_holds_priority
 227
 228 Set the passed boolean value to items.exclude_from_local_holds_priority
 229
 230 =item mark_items_returned
 231
 232 Move issues on these items to the old issues table, do not mark items found, or
 233 adjust damaged/withdrawn statuses, or fines, or locations.
 234
 235 =item callback
 236
 237 Callback function to call after an item has been modified
 238
 239 =back
 240
 241 =cut
 242
 243 sub batch_update {
 244     my ( $self, $params ) = @_;
 245
 246     my $regex_mod = $params->{regex_mod} || {};
 247     my $new_values = $params->{new_values} || {};
 248     my $exclude_from_local_holds_priority = $params->{exclude_from_local_holds_priority};
 249     my $mark_items_returned = $params->{mark_items_returned};
 250     my $callback = $params->{callback};
 251
 252     my (@modified_itemnumbers, $modified_fields);
 253     my $i;
 254     my $schema = Koha::Database->new->schema;
 255     while ( my $item = $self->next ) {
 256
 257         try {$schema->txn_do(sub {
 258             my $modified_holds_priority = 0;
 259             my $item_returned = 0;
 260             if ( defined $exclude_from_local_holds_priority ) {
 261                 if(!defined $item->exclude_from_local_holds_priority || $item->exclude_from_local_holds_priority != $exclude_from_local_holds_priority) {
 262                     $item->exclude_from_local_holds_priority($exclude_from_local_holds_priority)->store;
 263                     $modified_holds_priority = 1;
 264                 }
 265             }
 266
 267             my $modified = 0;
 268             my $new_values = {%$new_values};    # Don't modify the original
 269
 270             my $old_values = $item->unblessed;
 271             if ( $item->more_subfields_xml ) {
 272                 $old_values = {
 273                     %$old_values,
 274                     %{$item->additional_attributes->to_hashref},
 275                 };
 276             }
 277
 278             for my $attr ( keys %$regex_mod ) {
 279                 my $old_value = $old_values->{$attr};
 280
 281                 next unless $old_value;
 282
 283                 my $value = apply_regex(
 284                     {
 285                         %{ $regex_mod->{$attr} },
 286                         value => $old_value,
 287                     }
 288                 );
 289
 290                 $new_values->{$attr} = $value;
 291             }
 292
 293             for my $attribute ( keys %$new_values ) {
 294                 next if $attribute eq 'more_subfields_xml'; # Already counted before
 295
 296                 my $old = $old_values->{$attribute};
 297                 my $new = $new_values->{$attribute};
 298                 $modified++
 299                   if ( defined $old xor defined $new )
 300                   || ( defined $old && defined $new && $new ne $old );
 301             }
 302
 303             { # Dealing with more_subfields_xml
 304
 305                 my $frameworkcode = $item->biblio->frameworkcode;
 306                 my $tagslib = C4::Biblio::GetMarcStructure( 1, $frameworkcode, { unsafe => 1 });
 307                 my ( $itemtag, $itemsubfield ) = C4::Biblio::GetMarcFromKohaField( "items.itemnumber" );
 308
 309                 my @more_subfield_tags = map {
 310                     (
 311                              ref($_)
 312                           && %$_
 313                           && !$_->{kohafield}    # Get subfields that are not mapped
 314                       )
 315                       ? $_->{tagsubfield}
 316                       : ()
 317                 } values %{ $tagslib->{$itemtag} };
 318
 319                 my $more_subfields_xml = Koha::Item::Attributes->new(
 320                     {
 321                         map {
 322                             exists $new_values->{$_} ? ( $_ => $new_values->{$_} )
 323                               : exists $old_values->{$_}
 324                               ? ( $_ => $old_values->{$_} )
 325                               : ()
 326                         } @more_subfield_tags
 327                     }
 328                 )->to_marcxml($frameworkcode);
 329
 330                 $new_values->{more_subfields_xml} = $more_subfields_xml;
 331
 332                 delete $new_values->{$_} for @more_subfield_tags; # Clean the hash
 333
 334             }
 335
 336             if ( $modified ) {
 337                 my $itemlost_pre = $item->itemlost;
 338                 $item->set($new_values)->store({skip_record_index => 1});
 339
 340                 C4::Circulation::LostItem(
 341                     $item->itemnumber, 'batchmod', undef,
 342                     { skip_record_index => 1 }
 343                 ) if $item->itemlost
 344                       and not $itemlost_pre;
 345             }
 346             if ( $mark_items_returned ){
 347                 my $issue = $item->checkout;
 348                 if( $issue ){
 349                         $item_returned = 1;
 350                         C4::Circulation::MarkIssueReturned(
 351                         $issue->borrowernumber,
 352                         $item->itemnumber,
 353                         undef,
 354                         $issue->patron->privacy,
 355                         {
 356                             skip_record_index => 1,
 357                             skip_holds_queue  => 1,
 358                         }
 359                     );
 360                 }
 361             }
 362
 363             push @modified_itemnumbers, $item->itemnumber if $modified || $modified_holds_priority || $item_returned;
 364             $modified_fields += $modified + $modified_holds_priority + $item_returned;
 365         })}
 366         catch {
 367             warn $_
 368         };
 369
 370         if ( $callback ) {
 371             $callback->(++$i);
 372         }
 373     }
 374
 375     if (@modified_itemnumbers) {
 376         my @biblionumbers = uniq(
 377             Koha::Items->search( { itemnumber => \@modified_itemnumbers } )
 378                        ->get_column('biblionumber'));
 379
 380         if ( @biblionumbers ) {
 381             my $indexer = Koha::SearchEngine::Indexer->new(
 382                 { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 383
 384             $indexer->index_records( \@biblionumbers, 'specialUpdate',
 385                 "biblioserver", undef );
 386         }
 387     }
 388
 389     return ( { modified_itemnumbers => \@modified_itemnumbers, modified_fields => $modified_fields }, $self );
 390 }
 391
 392 sub apply_regex {
 393     # FIXME Should be moved outside of Koha::Items
 394     # FIXME This is nearly identical to Koha::SimpleMARC::_modify_values
 395     my ($params) = @_;
 396     my $search   = $params->{search};
 397     my $replace  = $params->{replace};
 398     my $modifiers = $params->{modifiers} || q{};
 399     my $value = $params->{value};
 400
 401     $replace =~ s/"/\\"/g;                    # Protection from embedded code
 402     $replace = '"' . $replace . '"'; # Put in a string for /ee
 403     my @available_modifiers = qw( i g );
 404     my $retained_modifiers  = q||;
 405     for my $modifier ( split //, $modifiers ) {
 406         $retained_modifiers .= $modifier
 407           if grep { /$modifier/ } @available_modifiers;
 408     }
 409     if ( $retained_modifiers =~ m/^(ig|gi)$/ ) {
 410         $value =~ s/$search/$replace/igee;
 411     }
 412     elsif ( $retained_modifiers eq 'i' ) {
 413         $value =~ s/$search/$replace/iee;
 414     }
 415     elsif ( $retained_modifiers eq 'g' ) {
 416         $value =~ s/$search/$replace/gee;
 417     }
 418     else {
 419         $value =~ s/$search/$replace/ee;
 420     }
 421
 422     return $value;
 423 }
 424
 425 =head3 search_ordered
 426
 427  $items->search_ordered;
 428
 429 Search and sort items in a specific order, depending if serials are present or not
 430
 431 =cut
 432
 433 sub search_ordered {
 434     my ($self, $params, $attributes) = @_;
 435
 436     $self = $self->search($params, $attributes);
 437
 438     my @biblionumbers = uniq $self->get_column('biblionumber');
 439
 440     if ( scalar ( @biblionumbers ) == 1
 441         && Koha::Biblios->find( $biblionumbers[0] )->serial )
 442     {
 443         return $self->search(
 444             {},
 445             {
 446                 order_by => [ 'serialid.publisheddate', 'me.enumchron' ],
 447                 join     => { serialitem => 'serialid' }
 448             }
 449         );
 450     } else {
 451         return $self->search(
 452             {},
 453             {
 454                 order_by => [
 455                     'homebranch.branchname',
 456                     'me.enumchron',
 457                     \"LPAD( me.copynumber, 8, '0' )",
 458                     {-desc => 'me.dateaccessioned'}
 459                 ],
 460                 join => ['homebranch']
 461             }
 462         );
 463     }
 464 }
 465
 466 =head2 Internal methods
 467
 468 =head3 _type
 469
 470 =cut
 471
 472 sub _type {
 473     return 'Item';
 474 }
 475
 476 =head3 object_class
 477
 478 =cut
 479
 480 sub object_class {
 481     return 'Koha::Item';
 482 }
 483
 484 =head1 AUTHOR
 485
 486 Kyle M Hall <kyle@bywatersolutions.com>
 487 Tomas Cohen Arazi <tomascohen@theke.io>
 488 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 489
 490 =cut
 491
 492 1;