Koha/Items.pm

   1 package Koha::Items;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22
  23 use Koha::Database;
  24
  25 use Koha::Item;
  26 use Koha::CirculationRules;
  27
  28 use base qw(Koha::Objects);
  29
  30 use Koha::SearchEngine::Indexer;
  31
  32 =head1 NAME
  33
  34 Koha::Items - Koha Item object set class
  35
  36 =head1 API
  37
  38 =head2 Class methods
  39
  40 =cut
  41
  42 =head3 filter_by_for_hold
  43
  44     my $filtered_items = $items->filter_by_for_hold;
  45
  46 Return the items of the set that are holdable
  47
  48 =cut
  49
  50 sub filter_by_for_hold {
  51     my ($self) = @_;
  52
  53     my @hold_not_allowed_itypes = Koha::CirculationRules->search(
  54         {
  55             rule_name    => 'holdallowed',
  56             branchcode   => undef,
  57             categorycode => undef,
  58             rule_value   => 'not_allowed',
  59         }
  60     )->get_column('itemtype');
  61
  62     return $self->search(
  63         {
  64             itemlost   => 0,
  65             withdrawn  => 0,
  66             notforloan => { '<=' => 0 }
  67             ,    # items with negative or zero notforloan value are holdable
  68             ( ! C4::Context->preference('AllowHoldsOnDamagedItems' ) ? ( damaged => 0 ) : () ),
  69             itype        => { -not_in => \@hold_not_allowed_itypes },
  70         }
  71     );
  72 }
  73
  74 =head3 filter_by_visible_in_opac
  75
  76     my $filered_items = $items->filter_by_visible_in_opac(
  77         {
  78             [ patron => $patron ]
  79         }
  80     );
  81
  82 Returns a new resultset, containing those items that are not expected to be hidden in OPAC
  83 for the passed I<Koha::Patron> object that is passed.
  84
  85 The I<OpacHiddenItems>, I<hidelostitems> and I<OpacHiddenItemsExceptions> system preferences
  86 are honoured.
  87
  88 =cut
  89
  90 sub filter_by_visible_in_opac {
  91     my ($self, $params) = @_;
  92
  93     my $patron = $params->{patron};
  94
  95     my $result = $self;
  96
  97     # Filter out OpacHiddenItems unless disabled by OpacHiddenItemsExceptions
  98     unless ( $patron and $patron->category->override_hidden_items ) {
  99         my $rules = C4::Context->yaml_preference('OpacHiddenItems') // {};
 100
 101         my $rules_params;
 102         foreach my $field ( keys %$rules ) {
 103             $rules_params->{$field} =
 104               [ { '-not_in' => $rules->{$field} }, undef ];
 105         }
 106
 107         $result = $result->search( $rules_params );
 108     }
 109
 110     if (C4::Context->preference('hidelostitems')) {
 111         $result = $result->filter_out_lost;
 112     }
 113
 114     return $result;
 115 }
 116
 117 =head3 filter_out_lost
 118
 119     my $filered_items = $items->filter_out_lost;
 120
 121 Returns a new resultset, containing those items that are not marked as lost.
 122
 123 =cut
 124
 125 sub filter_out_lost {
 126     my ($self) = @_;
 127
 128     my $params = { itemlost => 0 };
 129
 130     return $self->search( $params );
 131 }
 132
 133 =head3 move_to_biblio
 134
 135  $items->move_to_biblio($to_biblio);
 136
 137 Move items to a given biblio.
 138
 139 =cut
 140
 141 sub move_to_biblio {
 142     my ( $self, $to_biblio ) = @_;
 143
 144     my $biblionumbers = { $to_biblio->biblionumber => 1 };
 145     while ( my $item = $self->next() ) {
 146         $biblionumbers->{ $item->biblionumber } = 1;
 147         $item->move_to_biblio( $to_biblio, { skip_record_index => 1 } );
 148     }
 149     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 150     for my $biblionumber ( keys %{$biblionumbers} ) {
 151         $indexer->index_records( $biblionumber, "specialUpdate", "biblioserver" );
 152     }
 153 }
 154
 155
 156 =head2 Internal methods
 157
 158 =head3 _type
 159
 160 =cut
 161
 162 sub _type {
 163     return 'Item';
 164 }
 165
 166 =head3 object_class
 167
 168 =cut
 169
 170 sub object_class {
 171     return 'Koha::Item';
 172 }
 173
 174 =head1 AUTHOR
 175
 176 Kyle M Hall <kyle@bywatersolutions.com>
 177 Tomas Cohen Arazi <tomascohen@theke.io>
 178 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 179
 180 =cut
 181
 182 1;