Koha/Library/Group.pm

   1 package Koha::Library::Group;
   2
   3 # Copyright ByWater Solutions 2016
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22
  23 use Koha::Database;
  24 use Koha::DateUtils qw( dt_from_string );
  25 use Koha::Libraries;
  26
  27 use base qw(Koha::Object);
  28
  29 =head1 NAME
  30
  31 Koha::Library::Group - Koha Library::Group object class
  32
  33 =head1 API
  34
  35 =head2 Class methods
  36
  37 =cut
  38
  39 =head3 my @parent = $self->parent()
  40
  41 =cut
  42
  43 sub parent {
  44     my ($self) = @_;
  45
  46     $self->{_parent} ||= Koha::Library::Groups->find( $self->parent_id );
  47
  48     return $self->{_parent};
  49 }
  50
  51 =head3 my @children = $self->children()
  52
  53 =cut
  54
  55 sub children {
  56     my ($self) = @_;
  57
  58     my $children =
  59       Koha::Library::Groups->search( { parent_id => $self->id }, { order_by => [ 'title', 'branchcode' ] } );
  60
  61     return wantarray ? $children->as_list : $children;
  62 }
  63
  64 =head3 has_child
  65
  66 my $has_child = $group->has_child( $branchcode );
  67
  68 Return true if the given branchcode library is a child of this group.
  69
  70 =cut
  71
  72 sub has_child {
  73     my ( $self, $branchcode ) = @_;
  74     return unless $branchcode; # Does not support group of libraries.
  75     return ( grep { $_ and $_ eq $branchcode }
  76           $self->children->get_column('branchcode') ) ? 1 : 0;
  77 }
  78
  79 =head3 library
  80
  81 my $library = $group->library();
  82
  83 Returns the library for this group if one exists
  84
  85 =cut
  86
  87 sub library {
  88     my ($self) = @_;
  89
  90     return unless $self->branchcode;
  91
  92     $self->{_library} ||= Koha::Libraries->find( $self->branchcode );
  93
  94     return $self->{_library};
  95 }
  96
  97 =head3 libraries
  98
  99 my $libraries = $group->libraries( { [invert => 1] } );
 100
 101 Returns the libraries set as direct children of this group.
 102
 103 If invert param is true, the returned list will be libraries
 104 that are *not* direct children of this group.
 105
 106 =cut
 107
 108 sub libraries {
 109     my ($self, $params) = @_;
 110     my $invert = $params->{invert};
 111
 112     my $in_or_not = $invert ? '-not_in' : '-in';
 113
 114     my @branchcodes = Koha::Library::Groups->search(
 115         {
 116             parent_id  => $self->id,
 117             branchcode => { '!=' => undef },
 118         },
 119         { order_by => 'branchcode' }
 120     )->get_column('branchcode');
 121
 122     return Koha::Libraries->search(
 123         {
 124             branchcode => { $in_or_not => \@branchcodes }
 125         },
 126         {
 127             order_by => 'branchname'
 128         }
 129     );
 130 }
 131
 132 =head3 all_libraries
 133
 134 my @libraries = $group->all_libraries( { [invert => 1] } );
 135
 136 Returns the libraries set as children of this group or any subgroup.
 137
 138 =cut
 139
 140 sub all_libraries {
 141     my ( $self, $params ) = @_;
 142
 143     my @libraries;
 144
 145     push (@libraries, $self->libraries->as_list);
 146     my @children = $self->children->search({ branchcode => undef })->as_list;
 147     foreach my $c (@children) {
 148         push( @libraries, $c->all_libraries );
 149     }
 150
 151     my %seen;
 152     @libraries =
 153       grep { !$seen{ $_->id }++ } @libraries;
 154
 155     return @libraries;
 156 }
 157
 158 =head3 libraries_not_direct_children
 159
 160 my $libraries = $group->libraries_not_direct_children();
 161
 162 Returns the libraries *not* set as direct children of this group
 163
 164 =cut
 165
 166 sub libraries_not_direct_children {
 167     my ($self) = @_;
 168
 169     return $self->libraries( { invert => 1 } );
 170 }
 171
 172 =head3 store
 173
 174 =cut
 175
 176 sub store {
 177     my ($self) = @_;
 178
 179     $self->created_on( dt_from_string() ) unless $self->in_storage();
 180
 181     return $self->SUPER::store(@_);
 182 }
 183
 184 =head2 Internal methods
 185
 186 =head3 _type
 187
 188 =cut
 189
 190 sub _type {
 191     return 'LibraryGroup';
 192 }
 193
 194 =head1 AUTHOR
 195
 196 Kyle M Hall <kyle@bywatersolutions.com>
 197
 198 =cut
 199
 200 1;